src/Pure/library.ML
author haftmann
Thu Oct 22 16:58:22 2009 +0200 (2009-10-22)
changeset 33079 06a48bbeb22a
parent 33078 3aea60ca3900
child 33081 fe29679cabc2
permissions -rw-r--r--
restored accidentally deleted submultiset
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf mem mem_int mem_string
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception SYS_ERROR of string
    33   val sys_error: string -> 'a
    34   exception ERROR of string
    35   val error: string -> 'a
    36   val cat_error: string -> string -> 'a
    37   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    38 
    39   (*pairs*)
    40   val pair: 'a -> 'b -> 'a * 'b
    41   val rpair: 'a -> 'b -> 'b * 'a
    42   val fst: 'a * 'b -> 'a
    43   val snd: 'a * 'b -> 'b
    44   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    46   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    47   val swap: 'a * 'b -> 'b * 'a
    48   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    49   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    50   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    51 
    52   (*booleans*)
    53   val equal: ''a -> ''a -> bool
    54   val not_equal: ''a -> ''a -> bool
    55   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    56   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    57   val exists: ('a -> bool) -> 'a list -> bool
    58   val forall: ('a -> bool) -> 'a list -> bool
    59   val setmp_noncritical: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    60   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    61   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    62 
    63   (*lists*)
    64   exception UnequalLengths
    65   val single: 'a -> 'a list
    66   val the_single: 'a list -> 'a
    67   val singleton: ('a list -> 'b list) -> 'a -> 'b
    68   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    69   val apply: ('a -> 'a) list -> 'a -> 'a
    70   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    71   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    72   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    73   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    74   val flat: 'a list list -> 'a list
    75   val unflat: 'a list list -> 'b list -> 'b list list
    76   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    77   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    78   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    79   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    80   val maps: ('a -> 'b list) -> 'a list -> 'b list
    81   val filter: ('a -> bool) -> 'a list -> 'a list
    82   val filter_out: ('a -> bool) -> 'a list -> 'a list
    83   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    84   val chop: int -> 'a list -> 'a list * 'a list
    85   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    86   val nth: 'a list -> int -> 'a
    87   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    88   val nth_drop: int -> 'a list -> 'a list
    89   val nth_list: 'a list list -> int -> 'a list
    90   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    91   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    92   val map_range: (int -> 'a) -> int -> 'a list
    93   val split_last: 'a list -> 'a list * 'a
    94   val find_index: ('a -> bool) -> 'a list -> int
    95   val find_first: ('a -> bool) -> 'a list -> 'a option
    96   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    97   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    98   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    99   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   100   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   101   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   102   val ~~ : 'a list * 'b list -> ('a * 'b) list
   103   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   104   val split_list: ('a * 'b) list -> 'a list * 'b list
   105   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   108   val separate: 'a -> 'a list -> 'a list
   109   val surround: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val first_field: string -> string -> (string * string) option
   138   val enclose: string -> string -> string -> string
   139   val unenclose: string -> string
   140   val quote: string -> string
   141   val space_implode: string -> string list -> string
   142   val commas: string list -> string
   143   val commas_quote: string list -> string
   144   val cat_lines: string list -> string
   145   val space_explode: string -> string -> string list
   146   val split_lines: string -> string list
   147   val prefix_lines: string -> string -> string
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val replicate_string: int -> string -> string
   153   val translate_string: (string -> string) -> string -> string
   154   val match_string: string -> string -> bool
   155 
   156   (*lists as sets -- see also Pure/General/ord_list.ML*)
   157   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   158   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   159   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   160   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   161   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   162   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   163   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   164   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   165   val mem: ''a * ''a list -> bool
   166   val mem_int: int * int list -> bool
   167   val mem_string: string * string list -> bool
   168   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   169   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   170   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   171   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   172   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   173 
   174   (*lists as multisets*)
   175   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   176   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   177   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   178 
   179   (*orders*)
   180   val is_equal: order -> bool
   181   val rev_order: order -> order
   182   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   183   val bool_ord: bool * bool -> order
   184   val int_ord: int * int -> order
   185   val string_ord: string * string -> order
   186   val fast_string_ord: string * string -> order
   187   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   188   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   189   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   190   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   191   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   192   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   193   val sort_strings: string list -> string list
   194   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   195   val tag_list: int -> 'a list -> (int * 'a) list
   196   val untag_list: (int * 'a) list -> 'a list
   197   val order_list: (int * 'a) list -> 'a list
   198 
   199   (*random numbers*)
   200   exception RANDOM
   201   val random: unit -> real
   202   val random_range: int -> int -> int
   203   val one_of: 'a list -> 'a
   204   val frequency: (int * 'a) list -> 'a
   205 
   206   (*misc*)
   207   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   208   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   209     'a -> 'b -> 'c * 'b
   210   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   211   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   212   val gensym: string -> string
   213   type stamp
   214   val stamp: unit -> stamp
   215   type serial
   216   val serial: unit -> serial
   217   val serial_string: unit -> string
   218   structure Object: sig type T end
   219 end;
   220 
   221 signature LIBRARY =
   222 sig
   223   include BASIC_LIBRARY
   224   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   225   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   226   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   227   val take: int * 'a list -> 'a list
   228   val drop: int * 'a list -> 'a list
   229   val last_elem: 'a list -> 'a
   230 end;
   231 
   232 structure Library: LIBRARY =
   233 struct
   234 
   235 (* functions *)
   236 
   237 fun undefined _ = raise Match;
   238 
   239 fun I x = x;
   240 fun K x = fn _ => x;
   241 fun curry f x y = f (x, y);
   242 fun uncurry f (x, y) = f x y;
   243 
   244 (*conditional application*)
   245 fun b ? f = fn x => if b then f x else x;
   246 
   247 (*composition with multiple args*)
   248 fun (f oo g) x y = f (g x y);
   249 fun (f ooo g) x y z = f (g x y z);
   250 fun (f oooo g) x y z w = f (g x y z w);
   251 
   252 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   253 fun funpow (0 : int) _ = I
   254   | funpow n f = f #> funpow (n - 1) f;
   255 
   256 fun funpow_yield (0 : int) _ x = ([], x)
   257   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   258 
   259 (* errors *)
   260 
   261 exception SYS_ERROR of string;
   262 fun sys_error msg = raise SYS_ERROR msg;
   263 
   264 exception ERROR of string;
   265 fun error msg = raise ERROR msg;
   266 
   267 fun cat_error "" msg = error msg
   268   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   269 
   270 fun assert_all pred list msg =
   271   let
   272     fun ass [] = ()
   273       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   274   in ass list end;
   275 
   276 
   277 (* pairs *)
   278 
   279 fun pair x y = (x, y);
   280 fun rpair x y = (y, x);
   281 
   282 fun fst (x, y) = x;
   283 fun snd (x, y) = y;
   284 
   285 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   286 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   287 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   288 
   289 fun swap (x, y) = (y, x);
   290 
   291 fun apfst f (x, y) = (f x, y);
   292 fun apsnd f (x, y) = (x, f y);
   293 fun pairself f (x, y) = (f x, f y);
   294 
   295 
   296 (* booleans *)
   297 
   298 (*polymorphic equality*)
   299 fun equal x y = x = y;
   300 fun not_equal x y = x <> y;
   301 
   302 (*combining predicates*)
   303 fun p orf q = fn x => p x orelse q x;
   304 fun p andf q = fn x => p x andalso q x;
   305 
   306 val exists = List.exists;
   307 val forall = List.all;
   308 
   309 
   310 (* flags *)
   311 
   312 (*temporarily set flag during execution*)
   313 fun setmp_noncritical flag value f x =
   314   uninterruptible (fn restore_attributes => fn () =>
   315     let
   316       val orig_value = ! flag;
   317       val _ = flag := value;
   318       val result = Exn.capture (restore_attributes f) x;
   319       val _ = flag := orig_value;
   320     in Exn.release result end) ();
   321 
   322 fun setmp_CRITICAL flag value f x =
   323   NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   324 
   325 fun setmp_thread_data tag orig_data data f x =
   326   uninterruptible (fn restore_attributes => fn () =>
   327     let
   328       val _ = Thread.setLocal (tag, data);
   329       val result = Exn.capture (restore_attributes f) x;
   330       val _ = Thread.setLocal (tag, orig_data);
   331     in Exn.release result end) ();
   332 
   333 
   334 
   335 (** lists **)
   336 
   337 exception UnequalLengths;
   338 
   339 fun single x = [x];
   340 
   341 fun the_single [x] = x
   342   | the_single _ = raise Empty;
   343 
   344 fun singleton f x = the_single (f [x]);
   345 
   346 fun yield_singleton f x = f [x] #>> the_single;
   347 
   348 fun apply [] x = x
   349   | apply (f :: fs) x = apply fs (f x);
   350 
   351 fun perhaps_apply funs arg =
   352   let
   353     fun app [] res = res
   354       | app (f :: fs) (changed, x) =
   355           (case f x of
   356             NONE => app fs (changed, x)
   357           | SOME x' => app fs (true, x'));
   358   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   359 
   360 fun perhaps_loop f arg =
   361   let
   362     fun loop (changed, x) =
   363       (case f x of
   364         NONE => (changed, x)
   365       | SOME x' => loop (true, x'));
   366   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   367 
   368 
   369 (* fold -- old versions *)
   370 
   371 (*the following versions of fold are designed to fit nicely with infixes*)
   372 
   373 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   376   let fun itl (e, [])  = e
   377         | itl (e, a::l) = itl (f(e, a), l)
   378   in  itl end;
   379 
   380 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   381     for operators that associate to the right (not tail recursive)*)
   382 fun foldr f (l, e) =
   383   let fun itr [] = e
   384         | itr (a::l) = f(a, itr l)
   385   in  itr l  end;
   386 
   387 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   388     for operators that associate to the left (TAIL RECURSIVE)*)
   389 fun foldl1 f [] = raise Empty
   390   | foldl1 f (x :: xs) = foldl f (x, xs);
   391 
   392 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   393     for n > 0, operators that associate to the right (not tail recursive)*)
   394 fun foldr1 f [] = raise Empty
   395   | foldr1 f l =
   396       let fun itr [x] = x
   397             | itr (x::l) = f(x, itr l)
   398       in  itr l  end;
   399 
   400 fun foldl_map f =
   401   let
   402     fun fold_aux (x, []) = (x, [])
   403       | fold_aux (x, y :: ys) =
   404           let
   405             val (x', y') = f (x, y);
   406             val (x'', ys') = fold_aux (x', ys);
   407           in (x'', y' :: ys') end;
   408   in fold_aux end;
   409 
   410 
   411 (* basic list functions *)
   412 
   413 fun eq_list eq (list1, list2) =
   414   let
   415     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   416       | eq_lst _ = true;
   417   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   418 
   419 fun maps f [] = []
   420   | maps f (x :: xs) = f x @ maps f xs;
   421 
   422 val filter = List.filter;
   423 fun filter_out f = filter (not o f);
   424 val map_filter = List.mapPartial;
   425 
   426 fun chop (0: int) xs = ([], xs)
   427   | chop _ [] = ([], [])
   428   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   429 
   430 (*take the first n elements from a list*)
   431 fun take (n: int, []) = []
   432   | take (n, x :: xs) =
   433       if n > 0 then x :: take (n - 1, xs) else [];
   434 
   435 (*drop the first n elements from a list*)
   436 fun drop (n: int, []) = []
   437   | drop (n, x :: xs) =
   438       if n > 0 then drop (n - 1, xs) else x :: xs;
   439 
   440 fun dropwhile P [] = []
   441   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   442 
   443 (*return nth element of a list, where 0 designates the first element;
   444   raise Subscript if list too short*)
   445 fun nth xs i = List.nth (xs, i);
   446 
   447 fun nth_list xss i = nth xss i handle Subscript => [];
   448 
   449 fun nth_map 0 f (x :: xs) = f x :: xs
   450   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   451   | nth_map (_: int) _ [] = raise Subscript;
   452 
   453 fun nth_drop n xs =
   454   List.take (xs, n) @ List.drop (xs, n + 1);
   455 
   456 fun map_index f =
   457   let
   458     fun mapp (_: int) [] = []
   459       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   460   in mapp 0 end;
   461 
   462 fun fold_index f =
   463   let
   464     fun fold_aux (_: int) [] y = y
   465       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   466   in fold_aux 0 end;
   467 
   468 fun map_range f i =
   469   let
   470     fun mapp k =
   471       if k < i then f k :: mapp (k + 1) else [];
   472   in mapp 0 end;
   473 
   474 val last_elem = List.last;
   475 
   476 (*rear decomposition*)
   477 fun split_last [] = raise Empty
   478   | split_last [x] = ([], x)
   479   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   480 
   481 (*find position of first element satisfying a predicate*)
   482 fun find_index pred =
   483   let fun find (_: int) [] = ~1
   484         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   485   in find 0 end;
   486 
   487 (*find first element satisfying predicate*)
   488 val find_first = List.find;
   489 
   490 (*get first element by lookup function*)
   491 fun get_first _ [] = NONE
   492   | get_first f (x :: xs) =
   493       (case f x of
   494         NONE => get_first f xs
   495       | some => some);
   496 
   497 fun get_index f =
   498   let
   499     fun get (_: int) [] = NONE
   500       | get i (x :: xs) =
   501           case f x
   502            of NONE => get (i + 1) xs
   503             | SOME y => SOME (i, y)
   504   in get 0 end;
   505 
   506 val flat = List.concat;
   507 
   508 fun unflat (xs :: xss) ys =
   509       let val (ps, qs) = chop (length xs) ys
   510       in ps :: unflat xss qs end
   511   | unflat [] [] = []
   512   | unflat _ _ = raise UnequalLengths;
   513 
   514 fun burrow f xss = unflat xss (f (flat xss));
   515 
   516 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   517 
   518 fun fold_burrow f xss s =
   519   apfst (unflat xss) (f (flat xss) s);
   520 
   521 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   522 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   523   | separate _ xs = xs;
   524 
   525 fun surround s (x :: xs) = s :: x :: surround s xs
   526   | surround s [] = [s];
   527 
   528 (*make the list [x, x, ..., x] of length n*)
   529 fun replicate (n: int) x =
   530   let fun rep (0, xs) = xs
   531         | rep (n, xs) = rep (n - 1, x :: xs)
   532   in
   533     if n < 0 then raise Subscript
   534     else rep (n, [])
   535   end;
   536 
   537 
   538 (* direct product *)
   539 
   540 fun map_product f _ [] = []
   541   | map_product f [] _ = []
   542   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   543 
   544 fun fold_product f _ [] z = z
   545   | fold_product f [] _ z = z
   546   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   547 
   548 
   549 (* lists of pairs *)
   550 
   551 exception UnequalLengths;
   552 
   553 fun map2 _ [] [] = []
   554   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   555   | map2 _ _ _ = raise UnequalLengths;
   556 
   557 fun fold2 f [] [] z = z
   558   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   559   | fold2 f _ _ _ = raise UnequalLengths;
   560 
   561 fun map_split f [] = ([], [])
   562   | map_split f (x :: xs) =
   563       let
   564         val (y, w) = f x;
   565         val (ys, ws) = map_split f xs;
   566       in (y :: ys, w :: ws) end;
   567 
   568 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   569   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   570   | zip_options _ [] = []
   571   | zip_options [] _ = raise UnequalLengths;
   572 
   573 (*combine two lists forming a list of pairs:
   574   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   575 fun [] ~~ [] = []
   576   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   577   | _ ~~ _ = raise UnequalLengths;
   578 
   579 (*inverse of ~~; the old 'split':
   580   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   581 val split_list = ListPair.unzip;
   582 
   583 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   584 
   585 
   586 (* prefixes, suffixes *)
   587 
   588 fun is_prefix _ [] _ = true
   589   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   590   | is_prefix eq _ _ = false;
   591 
   592 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   593    where xi is the first element that does not satisfy the predicate*)
   594 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   595   let fun take (rxs, []) = (rev rxs, [])
   596         | take (rxs, x :: xs) =
   597             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   598   in  take([], xs)  end;
   599 
   600 fun chop_prefix eq ([], ys) = ([], ([], ys))
   601   | chop_prefix eq (xs, []) = ([], (xs, []))
   602   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   603       if eq (x, y) then
   604         let val (ps', xys'') = chop_prefix eq (xs', ys')
   605         in (x :: ps', xys'') end
   606       else ([], (xs, ys));
   607 
   608 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   609    where xi is the last element that does not satisfy the predicate*)
   610 fun take_suffix _ [] = ([], [])
   611   | take_suffix pred (x :: xs) =
   612       (case take_suffix pred xs of
   613         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   614       | (prfx, sffx) => (x :: prfx, sffx));
   615 
   616 fun prefixes1 [] = []
   617   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   618 
   619 fun prefixes xs = [] :: prefixes1 xs;
   620 
   621 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   622 fun suffixes xs = [] :: suffixes1 xs;
   623 
   624 
   625 
   626 (** integers **)
   627 
   628 (* lists of integers *)
   629 
   630 (*make the list [from, from + 1, ..., to]*)
   631 fun ((i: int) upto j) =
   632   if i > j then [] else i :: (i + 1 upto j);
   633 
   634 (*make the list [from, from - 1, ..., to]*)
   635 fun ((i: int) downto j) =
   636   if i < j then [] else i :: (i - 1 downto j);
   637 
   638 
   639 (* convert integers to strings *)
   640 
   641 (*expand the number in the given base;
   642   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   643 fun radixpand (base, num) : int list =
   644   let
   645     fun radix (n, tail) =
   646       if n < base then n :: tail
   647       else radix (n div base, (n mod base) :: tail)
   648   in radix (num, []) end;
   649 
   650 (*expands a number into a string of characters starting from "zerochar";
   651   example: radixstring (2, "0", 8) gives "1000"*)
   652 fun radixstring (base, zerochar, num) =
   653   let val offset = ord zerochar;
   654       fun chrof n = chr (offset + n)
   655   in implode (map chrof (radixpand (base, num))) end;
   656 
   657 
   658 val string_of_int = Int.toString;
   659 
   660 fun signed_string_of_int i =
   661   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   662 
   663 fun string_of_indexname (a, 0) = a
   664   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   665 
   666 
   667 (* read integers *)
   668 
   669 fun read_radix_int radix cs =
   670   let
   671     val zero = ord "0";
   672     val limit = zero + radix;
   673     fun scan (num, []) = (num, [])
   674       | scan (num, c :: cs) =
   675         if zero <= ord c andalso ord c < limit then
   676           scan (radix * num + (ord c - zero), cs)
   677         else (num, c :: cs);
   678   in scan (0, cs) end;
   679 
   680 val read_int = read_radix_int 10;
   681 
   682 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   683 
   684 
   685 
   686 (** strings **)
   687 
   688 (* functions tuned for strings, avoiding explode *)
   689 
   690 fun nth_string str i =
   691   (case try String.substring (str, i, 1) of
   692     SOME s => s
   693   | NONE => raise Subscript);
   694 
   695 fun fold_string f str x0 =
   696   let
   697     val n = size str;
   698     fun iter (x, i) =
   699       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   700   in iter (x0, 0) end;
   701 
   702 fun exists_string pred str =
   703   let
   704     val n = size str;
   705     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   706   in ex 0 end;
   707 
   708 fun forall_string pred = not o exists_string (not o pred);
   709 
   710 fun first_field sep str =
   711   let
   712     val n = size sep;
   713     val len = size str;
   714     fun find i =
   715       if i + n > len then NONE
   716       else if String.substring (str, i, n) = sep then SOME i
   717       else find (i + 1);
   718   in
   719     (case find 0 of
   720       NONE => NONE
   721     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   722   end;
   723 
   724 (*enclose in brackets*)
   725 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   726 fun unenclose str = String.substring (str, 1, size str - 2);
   727 
   728 (*simple quoting (does not escape special chars)*)
   729 val quote = enclose "\"" "\"";
   730 
   731 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   732 fun space_implode a bs = implode (separate a bs);
   733 
   734 val commas = space_implode ", ";
   735 val commas_quote = commas o map quote;
   736 
   737 (*concatenate messages, one per line, into a string*)
   738 val cat_lines = space_implode "\n";
   739 
   740 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   741 fun space_explode _ "" = []
   742   | space_explode sep s = String.fields (fn c => str c = sep) s;
   743 
   744 val split_lines = space_explode "\n";
   745 
   746 fun prefix_lines "" txt = txt
   747   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   748 
   749 fun prefix prfx s = prfx ^ s;
   750 fun suffix sffx s = s ^ sffx;
   751 
   752 fun unprefix prfx s =
   753   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   754   else raise Fail "unprefix";
   755 
   756 fun unsuffix sffx s =
   757   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   758   else raise Fail "unsuffix";
   759 
   760 fun replicate_string (0: int) _ = ""
   761   | replicate_string 1 a = a
   762   | replicate_string k a =
   763       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   764       else replicate_string (k div 2) (a ^ a) ^ a;
   765 
   766 fun translate_string f = String.translate (f o String.str);
   767 
   768 (*crude matching of str against simple glob pat*)
   769 fun match_string pat str =
   770   let
   771     fun match [] _ = true
   772       | match (p :: ps) s =
   773           size p <= size s andalso
   774             (case try (unprefix p) s of
   775               SOME s' => match ps s'
   776             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   777   in match (space_explode "*" pat) str end;
   778 
   779 (** lists as sets -- see also Pure/General/ord_list.ML **)
   780 
   781 (* canonical operations *)
   782 
   783 fun member eq list x =
   784   let
   785     fun memb [] = false
   786       | memb (y :: ys) = eq (x, y) orelse memb ys;
   787   in memb list end;
   788 
   789 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   790 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   791 fun update eq x xs = cons x (remove eq x xs);
   792 
   793 fun inter eq xs = filter (member eq xs);
   794 
   795 fun union eq = fold (insert eq);
   796 fun subtract eq = fold (remove eq);
   797 
   798 fun merge eq (xs, ys) =
   799   if pointer_eq (xs, ys) then xs
   800   else if null xs then ys
   801   else fold_rev (insert eq) ys xs;
   802 
   803 
   804 (* old-style infixes *)
   805 
   806 fun x mem xs = member (op =) xs x;
   807 fun (x: int) mem_int xs = member (op =) xs x;
   808 fun (x: string) mem_string xs = member (op =) xs x;
   809 
   810 
   811 (* subset and set equality *)
   812 
   813 fun subset eq (xs, ys) = forall (member eq ys) xs;
   814 
   815 fun eq_set eq (xs, ys) =
   816   eq_list eq (xs, ys) orelse
   817     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   818 
   819 
   820 (*makes a list of the distinct members of the input; preserves order, takes
   821   first of equal elements*)
   822 fun distinct eq lst =
   823   let
   824     fun dist (rev_seen, []) = rev rev_seen
   825       | dist (rev_seen, x :: xs) =
   826           if member eq rev_seen x then dist (rev_seen, xs)
   827           else dist (x :: rev_seen, xs);
   828   in dist ([], lst) end;
   829 
   830 (*returns a list containing all repeated elements exactly once; preserves
   831   order, takes first of equal elements*)
   832 fun duplicates eq lst =
   833   let
   834     fun dups (rev_dups, []) = rev rev_dups
   835       | dups (rev_dups, x :: xs) =
   836           if member eq rev_dups x orelse not (member eq xs x) then
   837             dups (rev_dups, xs)
   838           else dups (x :: rev_dups, xs);
   839   in dups ([], lst) end;
   840 
   841 fun has_duplicates eq =
   842   let
   843     fun dups [] = false
   844       | dups (x :: xs) = member eq xs x orelse dups xs;
   845   in dups end;
   846 
   847 
   848 (* matrices *)
   849 
   850 fun map_transpose f xss =
   851   let
   852     val n = case distinct (op =) (map length xss)
   853      of [] => 0
   854       | [n] => n
   855       | _ => raise UnequalLengths;
   856   in map (fn m => f (map (fn xs => nth xs m) xss)) (0 upto n - 1) end;
   857 
   858 
   859 
   860 (** lists as multisets **)
   861 
   862 fun remove1 eq x [] = []
   863   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   864 
   865 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   866 
   867 fun submultiset _ ([], _)  = true
   868   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   869 
   870 
   871 
   872 (** orders **)
   873 
   874 fun is_equal EQUAL = true
   875   | is_equal _ = false;
   876 
   877 fun rev_order LESS = GREATER
   878   | rev_order EQUAL = EQUAL
   879   | rev_order GREATER = LESS;
   880 
   881 (*assume rel is a linear strict order*)
   882 fun make_ord rel (x, y) =
   883   if rel (x, y) then LESS
   884   else if rel (y, x) then GREATER
   885   else EQUAL;
   886 
   887 fun bool_ord (false, true) = LESS
   888   | bool_ord (true, false) = GREATER
   889   | bool_ord _ = EQUAL;
   890 
   891 val int_ord = Int.compare;
   892 val string_ord = String.compare;
   893 
   894 fun fast_string_ord (s1, s2) =
   895   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   896 
   897 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   898   | option_ord _ (NONE, NONE) = EQUAL
   899   | option_ord _ (NONE, SOME _) = LESS
   900   | option_ord _ (SOME _, NONE) = GREATER;
   901 
   902 (*lexicographic product*)
   903 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   904   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   905 
   906 (*dictionary order -- in general NOT well-founded!*)
   907 fun dict_ord elem_ord (x :: xs, y :: ys) =
   908       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   909   | dict_ord _ ([], []) = EQUAL
   910   | dict_ord _ ([], _ :: _) = LESS
   911   | dict_ord _ (_ :: _, []) = GREATER;
   912 
   913 (*lexicographic product of lists*)
   914 fun list_ord elem_ord (xs, ys) =
   915   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   916 
   917 
   918 (* sorting *)
   919 
   920 (*quicksort -- stable, i.e. does not reorder equal elements*)
   921 fun quicksort unique ord =
   922   let
   923     fun qsort [] = []
   924       | qsort (xs as [_]) = xs
   925       | qsort (xs as [x, y]) =
   926           (case ord (x, y) of
   927             LESS => xs
   928           | EQUAL => if unique then [x] else xs
   929           | GREATER => [y, x])
   930       | qsort xs =
   931           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   932           in qsort lts @ eqs @ qsort gts end
   933     and part _ [] = ([], [], [])
   934       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   935     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   936       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   937       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   938       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   939   in qsort end;
   940 
   941 fun sort ord = quicksort false ord;
   942 fun sort_distinct ord = quicksort true ord;
   943 
   944 val sort_strings = sort string_ord;
   945 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   946 
   947 
   948 (* items tagged by integer index *)
   949 
   950 (*insert tags*)
   951 fun tag_list k [] = []
   952   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   953 
   954 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   955 fun untag_list [] = []
   956   | untag_list [(k: int, x)] = [x]
   957   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   958       if k = k' then untag_list rest
   959       else x :: untag_list rest;
   960 
   961 (*return list elements in original order*)
   962 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   963 
   964 
   965 
   966 (** random numbers **)
   967 
   968 exception RANDOM;
   969 
   970 fun rmod x y = x - y * Real.realFloor (x / y);
   971 
   972 local
   973   val a = 16807.0;
   974   val m = 2147483647.0;
   975   val random_seed = Unsynchronized.ref 1.0;
   976 in
   977 
   978 fun random () = CRITICAL (fn () =>
   979   let val r = rmod (a * ! random_seed) m
   980   in (random_seed := r; r) end);
   981 
   982 end;
   983 
   984 fun random_range l h =
   985   if h < l orelse l < 0 then raise RANDOM
   986   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   987 
   988 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   989 
   990 fun frequency xs =
   991   let
   992     val sum = foldl op + (0, map fst xs);
   993     fun pick n ((k: int, x) :: xs) =
   994       if n <= k then x else pick (n - k) xs
   995   in pick (random_range 1 sum) xs end;
   996 
   997 
   998 
   999 (** misc **)
  1000 
  1001 fun divide_and_conquer decomp x =
  1002   let val (ys, recomb) = decomp x
  1003   in recomb (map (divide_and_conquer decomp) ys) end;
  1004 
  1005 fun divide_and_conquer' decomp x s =
  1006   let val ((ys, recomb), s') = decomp x s
  1007   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1008 
  1009 
  1010 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1011    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1012 fun partition_list p i j =
  1013   let fun part k xs =
  1014             if k>j then
  1015               (case xs of [] => []
  1016                          | _ => raise Fail "partition_list")
  1017             else
  1018             let val (ns, rest) = List.partition (p k) xs;
  1019             in  ns :: part(k+1)rest  end
  1020   in  part (i: int) end;
  1021 
  1022 fun partition_eq (eq:'a * 'a -> bool) =
  1023   let
  1024     fun part [] = []
  1025       | part (x :: ys) =
  1026           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1027           in (x::xs)::(part xs') end
  1028   in part end;
  1029 
  1030 
  1031 
  1032 (* generating identifiers *)
  1033 
  1034 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1035 local
  1036 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1037 fun gensym_char i =
  1038   if i<26 then chr (ord "A" + i)
  1039   else if i<52 then chr (ord "a" + i - 26)
  1040   else chr (ord "0" + i - 52);
  1041 
  1042 val char_vec = Vector.tabulate (62, gensym_char);
  1043 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1044 
  1045 val gensym_seed = Unsynchronized.ref (0: int);
  1046 
  1047 in
  1048   fun gensym pre =
  1049     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1050 end;
  1051 
  1052 
  1053 (* stamps and serial numbers *)
  1054 
  1055 type stamp = unit Unsynchronized.ref;
  1056 val stamp: unit -> stamp = Unsynchronized.ref;
  1057 
  1058 type serial = int;
  1059 val serial = Multithreading.serial;
  1060 val serial_string = string_of_int o serial;
  1061 
  1062 
  1063 (* generic objects *)
  1064 
  1065 (*note that the builtin exception datatype may be extended by new
  1066   constructors at any time*)
  1067 structure Object = struct type T = exn end;
  1068 
  1069 end;
  1070 
  1071 structure Basic_Library: BASIC_LIBRARY = Library;
  1072 open Basic_Library;