src/HOL/Set.ML
author paulson
Tue Oct 17 10:26:07 2000 +0200 (2000-10-17)
changeset 10233 08083bd2a64d
parent 9969 4753185f1dd2
child 10482 41de88cb2108
permissions -rw-r--r--
tidying; removed unused rev_contra_subsetD
     1 (*  Title:      HOL/Set.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 val [prem] = Goal "(!!x. (x:A) = (x:B)) ==> A = B";
    23 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    24 by (rtac Collect_mem_eq 1);
    25 by (rtac Collect_mem_eq 1);
    26 qed "set_ext";
    27 
    28 val [prem] = Goal "(!!x. P(x)=Q(x)) ==> {x. P(x)} = {x. Q(x)}";
    29 by (rtac (prem RS ext RS arg_cong) 1);
    30 qed "Collect_cong";
    31 
    32 bind_thm ("CollectE", make_elim CollectD);
    33 
    34 AddSIs [CollectI];
    35 AddSEs [CollectE];
    36 
    37 
    38 section "Bounded quantifiers";
    39 
    40 val prems = Goalw [Ball_def]
    41     "[| !!x. x:A ==> P(x) |] ==> ALL x:A. P(x)";
    42 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    43 qed "ballI";
    44 
    45 bind_thms ("strip", [impI, allI, ballI]);
    46 
    47 Goalw [Ball_def] "[| ALL x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ALL x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ALL x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> EX x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> EX x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ALL x:A. ~P(x) ==> P(a);  a:A |] ==> EX x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| EX x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(ALL x:A. P) = ((EX x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(EX x:A. P) = ((EX x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (ALL x:A. P(x)) = (ALL x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (EX x:A. P(x)) = (EX x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("image", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 (*Classical elimination rule*)
   156 val major::prems = Goalw [subset_def] 
   157     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   158 by (rtac (major RS ballE) 1);
   159 by (REPEAT (eresolve_tac prems 1));
   160 qed "subsetCE";
   161 
   162 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   163 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   164 
   165 AddSIs [subsetI];
   166 AddEs  [subsetD, subsetCE];
   167 
   168 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   169 by (Blast_tac 1);
   170 qed "contra_subsetD";
   171 
   172 Goal "A <= (A::'a set)";
   173 by (Fast_tac 1);
   174 qed "subset_refl";
   175 
   176 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   177 by (Blast_tac 1);
   178 qed "subset_trans";
   179 
   180 
   181 section "Equality";
   182 
   183 (*Anti-symmetry of the subset relation*)
   184 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   185 by (rtac set_ext 1);
   186 by (blast_tac (claset() addIs [subsetD]) 1);
   187 qed "subset_antisym";
   188 bind_thm ("equalityI", subset_antisym);
   189 
   190 AddSIs [equalityI];
   191 
   192 (* Equality rules from ZF set theory -- are they appropriate here? *)
   193 Goal "A = B ==> A<=(B::'a set)";
   194 by (etac ssubst 1);
   195 by (rtac subset_refl 1);
   196 qed "equalityD1";
   197 
   198 Goal "A = B ==> B<=(A::'a set)";
   199 by (etac ssubst 1);
   200 by (rtac subset_refl 1);
   201 qed "equalityD2";
   202 
   203 (*Be careful when adding this to the claset as subset_empty is in the simpset:
   204   A={} goes to {}<=A and A<={} and then back to A={} !*)
   205 val prems = Goal
   206     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   207 by (resolve_tac prems 1);
   208 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   209 qed "equalityE";
   210 
   211 val major::prems = Goal
   212     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   213 by (rtac (major RS equalityE) 1);
   214 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   215 qed "equalityCE";
   216 
   217 AddEs [equalityCE];
   218 
   219 (*Lemma for creating induction formulae -- for "pattern matching" on p
   220   To make the induction hypotheses usable, apply "spec" or "bspec" to
   221   put universal quantifiers over the free variables in p. *)
   222 val prems = Goal 
   223     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   224 by (rtac mp 1);
   225 by (REPEAT (resolve_tac (refl::prems) 1));
   226 qed "setup_induction";
   227 
   228 Goal "A = B ==> (x : A) = (x : B)";
   229 by (Asm_simp_tac 1);
   230 qed "eqset_imp_iff";
   231 
   232 
   233 section "The universal set -- UNIV";
   234 
   235 Goalw [UNIV_def] "x : UNIV";
   236 by (rtac CollectI 1);
   237 by (rtac TrueI 1);
   238 qed "UNIV_I";
   239 
   240 Addsimps [UNIV_I];
   241 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   242 
   243 Goal "A <= UNIV";
   244 by (rtac subsetI 1);
   245 by (rtac UNIV_I 1);
   246 qed "subset_UNIV";
   247 
   248 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   249     because of their interaction with congruence rules. **)
   250 
   251 Goalw [Ball_def] "Ball UNIV P = All P";
   252 by (Simp_tac 1);
   253 qed "ball_UNIV";
   254 
   255 Goalw [Bex_def] "Bex UNIV P = Ex P";
   256 by (Simp_tac 1);
   257 qed "bex_UNIV";
   258 Addsimps [ball_UNIV, bex_UNIV];
   259 
   260 
   261 section "The empty set -- {}";
   262 
   263 Goalw [empty_def] "(c : {}) = False";
   264 by (Blast_tac 1) ;
   265 qed "empty_iff";
   266 
   267 Addsimps [empty_iff];
   268 
   269 Goal "a:{} ==> P";
   270 by (Full_simp_tac 1);
   271 qed "emptyE";
   272 
   273 AddSEs [emptyE];
   274 
   275 Goal "{} <= A";
   276 by (Blast_tac 1) ;
   277 qed "empty_subsetI";
   278 
   279 (*One effect is to delete the ASSUMPTION {} <= A*)
   280 AddIffs [empty_subsetI];
   281 
   282 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   283 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   284 qed "equals0I";
   285 
   286 (*Use for reasoning about disjointness: A Int B = {} *)
   287 Goal "A={} ==> a ~: A";
   288 by (Blast_tac 1) ;
   289 qed "equals0D";
   290 
   291 Goalw [Ball_def] "Ball {} P = True";
   292 by (Simp_tac 1);
   293 qed "ball_empty";
   294 
   295 Goalw [Bex_def] "Bex {} P = False";
   296 by (Simp_tac 1);
   297 qed "bex_empty";
   298 Addsimps [ball_empty, bex_empty];
   299 
   300 Goal "UNIV ~= {}";
   301 by (blast_tac (claset() addEs [equalityE]) 1);
   302 qed "UNIV_not_empty";
   303 AddIffs [UNIV_not_empty];
   304 
   305 
   306 
   307 section "The Powerset operator -- Pow";
   308 
   309 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   310 by (Asm_simp_tac 1);
   311 qed "Pow_iff";
   312 
   313 AddIffs [Pow_iff]; 
   314 
   315 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   316 by (etac CollectI 1);
   317 qed "PowI";
   318 
   319 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   320 by (etac CollectD 1);
   321 qed "PowD";
   322 
   323 
   324 bind_thm ("Pow_bottom", empty_subsetI RS PowI);        (* {}: Pow(B) *)
   325 bind_thm ("Pow_top", subset_refl RS PowI);             (* A : Pow(A) *)
   326 
   327 
   328 section "Set complement";
   329 
   330 Goalw [Compl_def] "(c : -A) = (c~:A)";
   331 by (Blast_tac 1);
   332 qed "Compl_iff";
   333 
   334 Addsimps [Compl_iff];
   335 
   336 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   337 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   338 qed "ComplI";
   339 
   340 (*This form, with negated conclusion, works well with the Classical prover.
   341   Negated assumptions behave like formulae on the right side of the notional
   342   turnstile...*)
   343 Goalw [Compl_def] "c : -A ==> c~:A";
   344 by (etac CollectD 1);
   345 qed "ComplD";
   346 
   347 bind_thm ("ComplE", make_elim ComplD);
   348 
   349 AddSIs [ComplI];
   350 AddSEs [ComplE];
   351 
   352 
   353 section "Binary union -- Un";
   354 
   355 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   356 by (Blast_tac 1);
   357 qed "Un_iff";
   358 Addsimps [Un_iff];
   359 
   360 Goal "c:A ==> c : A Un B";
   361 by (Asm_simp_tac 1);
   362 qed "UnI1";
   363 
   364 Goal "c:B ==> c : A Un B";
   365 by (Asm_simp_tac 1);
   366 qed "UnI2";
   367 
   368 AddXIs [UnI1, UnI2];
   369 
   370 
   371 (*Classical introduction rule: no commitment to A vs B*)
   372 
   373 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   374 by (Simp_tac 1);
   375 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   376 qed "UnCI";
   377 
   378 val major::prems = Goalw [Un_def]
   379     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   380 by (rtac (major RS CollectD RS disjE) 1);
   381 by (REPEAT (eresolve_tac prems 1));
   382 qed "UnE";
   383 
   384 AddSIs [UnCI];
   385 AddSEs [UnE];
   386 
   387 
   388 section "Binary intersection -- Int";
   389 
   390 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   391 by (Blast_tac 1);
   392 qed "Int_iff";
   393 Addsimps [Int_iff];
   394 
   395 Goal "[| c:A;  c:B |] ==> c : A Int B";
   396 by (Asm_simp_tac 1);
   397 qed "IntI";
   398 
   399 Goal "c : A Int B ==> c:A";
   400 by (Asm_full_simp_tac 1);
   401 qed "IntD1";
   402 
   403 Goal "c : A Int B ==> c:B";
   404 by (Asm_full_simp_tac 1);
   405 qed "IntD2";
   406 
   407 val [major,minor] = Goal
   408     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   409 by (rtac minor 1);
   410 by (rtac (major RS IntD1) 1);
   411 by (rtac (major RS IntD2) 1);
   412 qed "IntE";
   413 
   414 AddSIs [IntI];
   415 AddSEs [IntE];
   416 
   417 section "Set difference";
   418 
   419 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   420 by (Blast_tac 1);
   421 qed "Diff_iff";
   422 Addsimps [Diff_iff];
   423 
   424 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   425 by (Asm_simp_tac 1) ;
   426 qed "DiffI";
   427 
   428 Goal "c : A - B ==> c : A";
   429 by (Asm_full_simp_tac 1) ;
   430 qed "DiffD1";
   431 
   432 Goal "[| c : A - B;  c : B |] ==> P";
   433 by (Asm_full_simp_tac 1) ;
   434 qed "DiffD2";
   435 
   436 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   437 by (resolve_tac prems 1);
   438 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   439 qed "DiffE";
   440 
   441 AddSIs [DiffI];
   442 AddSEs [DiffE];
   443 
   444 
   445 section "Augmenting a set -- insert";
   446 
   447 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   448 by (Blast_tac 1);
   449 qed "insert_iff";
   450 Addsimps [insert_iff];
   451 
   452 Goal "a : insert a B";
   453 by (Simp_tac 1);
   454 qed "insertI1";
   455 
   456 Goal "!!a. a : B ==> a : insert b B";
   457 by (Asm_simp_tac 1);
   458 qed "insertI2";
   459 
   460 val major::prems = Goalw [insert_def]
   461     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   462 by (rtac (major RS UnE) 1);
   463 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   464 qed "insertE";
   465 
   466 (*Classical introduction rule*)
   467 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   468 by (Simp_tac 1);
   469 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   470 qed "insertCI";
   471 
   472 AddSIs [insertCI]; 
   473 AddSEs [insertE];
   474 
   475 Goal "(A <= insert x B) = (if x:A then A-{x} <= B else A<=B)";
   476 by Auto_tac; 
   477 qed "subset_insert_iff";
   478 
   479 section "Singletons, using insert";
   480 
   481 Goal "a : {a}";
   482 by (rtac insertI1 1) ;
   483 qed "singletonI";
   484 
   485 Goal "b : {a} ==> b=a";
   486 by (Blast_tac 1);
   487 qed "singletonD";
   488 
   489 bind_thm ("singletonE", make_elim singletonD);
   490 
   491 Goal "(b : {a}) = (b=a)";
   492 by (Blast_tac 1);
   493 qed "singleton_iff";
   494 
   495 Goal "{a}={b} ==> a=b";
   496 by (blast_tac (claset() addEs [equalityE]) 1);
   497 qed "singleton_inject";
   498 
   499 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   500 AddSIs [singletonI];   
   501 AddSDs [singleton_inject];
   502 AddSEs [singletonE];
   503 
   504 Goal "{b} = insert a A = (a = b & A <= {b})";
   505 by (blast_tac (claset() addSEs [equalityE]) 1);
   506 qed "singleton_insert_inj_eq";
   507 
   508 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   509 by (blast_tac (claset() addSEs [equalityE]) 1);
   510 qed "singleton_insert_inj_eq'";
   511 
   512 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   513 
   514 Goal "A <= {x} ==> A={} | A = {x}";
   515 by (Fast_tac 1);
   516 qed "subset_singletonD";
   517 
   518 Goal "{x. x=a} = {a}";
   519 by (Blast_tac 1);
   520 qed "singleton_conv";
   521 Addsimps [singleton_conv];
   522 
   523 Goal "{x. a=x} = {a}";
   524 by (Blast_tac 1);
   525 qed "singleton_conv2";
   526 Addsimps [singleton_conv2];
   527 
   528 
   529 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   530 
   531 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   532 by (Blast_tac 1);
   533 qed "UN_iff";
   534 
   535 Addsimps [UN_iff];
   536 
   537 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   538 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   539 by Auto_tac;
   540 qed "UN_I";
   541 
   542 val major::prems = Goalw [UNION_def]
   543     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   544 by (rtac (major RS CollectD RS bexE) 1);
   545 by (REPEAT (ares_tac prems 1));
   546 qed "UN_E";
   547 
   548 AddIs  [UN_I];
   549 AddSEs [UN_E];
   550 
   551 val prems = Goalw [UNION_def]
   552     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   553 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   554 by (asm_simp_tac (simpset() addsimps prems) 1);
   555 qed "UN_cong";
   556 Addcongs [UN_cong];
   557 
   558 
   559 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   560 
   561 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   562 by Auto_tac;
   563 qed "INT_iff";
   564 
   565 Addsimps [INT_iff];
   566 
   567 val prems = Goalw [INTER_def]
   568     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   569 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   570 qed "INT_I";
   571 
   572 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   573 by Auto_tac;
   574 qed "INT_D";
   575 
   576 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   577 val major::prems = Goalw [INTER_def]
   578     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   579 by (rtac (major RS CollectD RS ballE) 1);
   580 by (REPEAT (eresolve_tac prems 1));
   581 qed "INT_E";
   582 
   583 AddSIs [INT_I];
   584 AddEs  [INT_D, INT_E];
   585 
   586 val prems = Goalw [INTER_def]
   587     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   588 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   589 by (asm_simp_tac (simpset() addsimps prems) 1);
   590 qed "INT_cong";
   591 Addcongs [INT_cong];
   592 
   593 
   594 section "Union";
   595 
   596 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   597 by (Blast_tac 1);
   598 qed "Union_iff";
   599 
   600 Addsimps [Union_iff];
   601 
   602 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   603 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   604 by Auto_tac;
   605 qed "UnionI";
   606 
   607 val major::prems = Goalw [Union_def]
   608     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   609 by (rtac (major RS UN_E) 1);
   610 by (REPEAT (ares_tac prems 1));
   611 qed "UnionE";
   612 
   613 AddIs  [UnionI];
   614 AddSEs [UnionE];
   615 
   616 
   617 section "Inter";
   618 
   619 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   620 by (Blast_tac 1);
   621 qed "Inter_iff";
   622 
   623 Addsimps [Inter_iff];
   624 
   625 val prems = Goalw [Inter_def]
   626     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   627 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   628 qed "InterI";
   629 
   630 (*A "destruct" rule -- every X in C contains A as an element, but
   631   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   632 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   633 by Auto_tac;
   634 qed "InterD";
   635 
   636 (*"Classical" elimination rule -- does not require proving X:C *)
   637 val major::prems = Goalw [Inter_def]
   638     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   639 by (rtac (major RS INT_E) 1);
   640 by (REPEAT (eresolve_tac prems 1));
   641 qed "InterE";
   642 
   643 AddSIs [InterI];
   644 AddEs  [InterD, InterE];
   645 
   646 
   647 (*** Image of a set under a function ***)
   648 
   649 (*Frequently b does not have the syntactic form of f(x).*)
   650 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   651 by (Blast_tac 1);
   652 qed "image_eqI";
   653 Addsimps [image_eqI];
   654 
   655 bind_thm ("imageI", refl RS image_eqI);
   656 
   657 (*This version's more effective when we already have the required x*)
   658 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   659 by (Blast_tac 1);
   660 qed "rev_image_eqI";
   661 
   662 (*The eta-expansion gives variable-name preservation.*)
   663 val major::prems = Goalw [image_def]
   664     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   665 by (rtac (major RS CollectD RS bexE) 1);
   666 by (REPEAT (ares_tac prems 1));
   667 qed "imageE";
   668 
   669 AddIs  [image_eqI];
   670 AddSEs [imageE]; 
   671 
   672 Goal "f``(A Un B) = f``A Un f``B";
   673 by (Blast_tac 1);
   674 qed "image_Un";
   675 
   676 Goal "(z : f``A) = (EX x:A. z = f x)";
   677 by (Blast_tac 1);
   678 qed "image_iff";
   679 
   680 (*This rewrite rule would confuse users if made default.*)
   681 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   682 by (Blast_tac 1);
   683 qed "image_subset_iff";
   684 
   685 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   686   many existing proofs.*)
   687 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   688 by (blast_tac (claset() addIs prems) 1);
   689 qed "image_subsetI";
   690 
   691 
   692 (*** Range of a function -- just a translation for image! ***)
   693 
   694 Goal "b=f(x) ==> b : range(f)";
   695 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   696 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   697 
   698 bind_thm ("rangeI", UNIV_I RS imageI);
   699 
   700 val [major,minor] = Goal 
   701     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   702 by (rtac (major RS imageE) 1);
   703 by (etac minor 1);
   704 qed "rangeE";
   705 
   706 
   707 (*** Set reasoning tools ***)
   708 
   709 
   710 (** Rewrite rules for boolean case-splitting: faster than 
   711 	addsplits[split_if]
   712 **)
   713 
   714 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   715 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   716 
   717 (*Split ifs on either side of the membership relation.
   718 	Not for Addsimps -- can cause goals to blow up!*)
   719 bind_thm ("split_if_mem1", inst "P" "%x. x : ?b" split_if);
   720 bind_thm ("split_if_mem2", inst "P" "%x. ?a : x" split_if);
   721 
   722 bind_thms ("split_ifs", [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   723 			 split_if_mem1, split_if_mem2]);
   724 
   725 
   726 (*Each of these has ALREADY been added to simpset() above.*)
   727 bind_thms ("mem_simps", [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   728                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff]);
   729 
   730 (*Would like to add these, but the existing code only searches for the 
   731   outer-level constant, which in this case is just "op :"; we instead need
   732   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   733   apply, then the formula should be kept.
   734   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]), 
   735    ("op Int", [IntD1,IntD2]),
   736    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   737  *)
   738 val mksimps_pairs =
   739   [("Ball",[bspec])] @ mksimps_pairs;
   740 
   741 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   742 
   743 Addsimps[subset_UNIV, subset_refl];
   744 
   745 
   746 (*** The 'proper subset' relation (<) ***)
   747 
   748 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   749 by (Blast_tac 1);
   750 qed "psubsetI";
   751 AddSIs [psubsetI];
   752 
   753 Goalw [psubset_def]
   754   "(A < insert x B) = (if x:B then A<B else if x:A then A-{x} < B else A<=B)";
   755 by (asm_simp_tac (simpset() addsimps [subset_insert_iff]) 1);
   756 by (Blast_tac 1); 
   757 qed "psubset_insert_iff";
   758 
   759 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   760 
   761 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   762 
   763 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   764 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   765 qed "psubset_subset_trans";
   766 
   767 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   768 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   769 qed "subset_psubset_trans";
   770 
   771 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   772 by (Blast_tac 1);
   773 qed "psubset_imp_ex_mem";
   774 
   775 
   776 (* rulify setup *)
   777 
   778 Goal "(!!x. x:A ==> P x) == Trueprop (ALL x:A. P x)";
   779 by (simp_tac (simpset () addsimps (Ball_def :: thms "atomize")) 1);
   780 qed "ball_eq";
   781 
   782 local
   783   val ss = HOL_basic_ss addsimps
   784     (Drule.norm_hhf_eq :: map Thm.symmetric (ball_eq :: thms "atomize"));
   785 in
   786 
   787 structure Rulify = RulifyFun
   788  (val make_meta = Simplifier.simplify ss
   789   val full_make_meta = Simplifier.full_simplify ss);
   790 
   791 structure BasicRulify: BASIC_RULIFY = Rulify;
   792 open BasicRulify;
   793 
   794 end;