src/HOL/Library/Multiset.thy
author haftmann
Mon Jul 27 22:44:02 2015 +0200 (2015-07-27)
changeset 60804 080a979a985b
parent 60752 b48830b670a1
child 61031 162bd20dae23
permissions -rw-r--r--
formal class for factorial (semi)rings
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section \<open>(Finite) multisets\<close>
    10 
    11 theory Multiset
    12 imports Main
    13 begin
    14 
    15 subsection \<open>The type of multisets\<close>
    16 
    17 definition "multiset = {f :: 'a \<Rightarrow> nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a \<Rightarrow> nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 abbreviation Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"  ("(_/ :# _)" [50, 51] 50) where
    29   "a :# M == 0 < count M a"
    30 
    31 notation (xsymbols)
    32   Melem (infix "\<in>#" 50)
    33 
    34 lemma multiset_eq_iff: "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    35   by (simp only: count_inject [symmetric] fun_eq_iff)
    36 
    37 lemma multiset_eqI: "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    38   using multiset_eq_iff by auto
    39 
    40 text \<open>Preservation of the representing set @{term multiset}.\<close>
    41 
    42 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    43   by (simp add: multiset_def)
    44 
    45 lemma only1_in_multiset: "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    46   by (simp add: multiset_def)
    47 
    48 lemma union_preserves_multiset: "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma diff_preserves_multiset:
    52   assumes "M \<in> multiset"
    53   shows "(\<lambda>a. M a - N a) \<in> multiset"
    54 proof -
    55   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    56     by auto
    57   with assms show ?thesis
    58     by (auto simp add: multiset_def intro: finite_subset)
    59 qed
    60 
    61 lemma filter_preserves_multiset:
    62   assumes "M \<in> multiset"
    63   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    64 proof -
    65   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    66     by auto
    67   with assms show ?thesis
    68     by (auto simp add: multiset_def intro: finite_subset)
    69 qed
    70 
    71 lemmas in_multiset = const0_in_multiset only1_in_multiset
    72   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    73 
    74 
    75 subsection \<open>Representing multisets\<close>
    76 
    77 text \<open>Multiset enumeration\<close>
    78 
    79 instantiation multiset :: (type) cancel_comm_monoid_add
    80 begin
    81 
    82 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    83 by (rule const0_in_multiset)
    84 
    85 abbreviation Mempty :: "'a multiset" ("{#}") where
    86   "Mempty \<equiv> 0"
    87 
    88 lift_definition plus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    89 by (rule union_preserves_multiset)
    90 
    91 lift_definition minus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    92 by (rule diff_preserves_multiset)
    93 
    94 instance
    95   by (standard; transfer; simp add: fun_eq_iff)
    96 
    97 end
    98 
    99 lift_definition single :: "'a \<Rightarrow> 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   100 by (rule only1_in_multiset)
   101 
   102 syntax
   103   "_multiset" :: "args \<Rightarrow> 'a multiset"    ("{#(_)#}")
   104 translations
   105   "{#x, xs#}" == "{#x#} + {#xs#}"
   106   "{#x#}" == "CONST single x"
   107 
   108 lemma count_empty [simp]: "count {#} a = 0"
   109   by (simp add: zero_multiset.rep_eq)
   110 
   111 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   112   by (simp add: single.rep_eq)
   113 
   114 
   115 subsection \<open>Basic operations\<close>
   116 
   117 subsubsection \<open>Union\<close>
   118 
   119 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   120   by (simp add: plus_multiset.rep_eq)
   121 
   122 
   123 subsubsection \<open>Difference\<close>
   124 
   125 instantiation multiset :: (type) comm_monoid_diff
   126 begin
   127 
   128 instance
   129   by (standard; transfer; simp add: fun_eq_iff)
   130 
   131 end
   132 
   133 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   134   by (simp add: minus_multiset.rep_eq)
   135 
   136 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   137   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   138 
   139 lemma diff_cancel[simp]: "A - A = {#}"
   140   by (fact Groups.diff_cancel)
   141 
   142 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   143   by (fact add_diff_cancel_right')
   144 
   145 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   146   by (fact add_diff_cancel_left')
   147 
   148 lemma diff_right_commute:
   149   fixes M N Q :: "'a multiset"
   150   shows "M - N - Q = M - Q - N"
   151   by (fact diff_right_commute)
   152 
   153 lemma diff_add:
   154   fixes M N Q :: "'a multiset"
   155   shows "M - (N + Q) = M - N - Q"
   156   by (rule sym) (fact diff_diff_add)
   157 
   158 lemma insert_DiffM: "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   159   by (clarsimp simp: multiset_eq_iff)
   160 
   161 lemma insert_DiffM2 [simp]: "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma diff_union_swap: "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   165   by (auto simp add: multiset_eq_iff)
   166 
   167 lemma diff_union_single_conv: "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   168   by (simp add: multiset_eq_iff)
   169 
   170 
   171 subsubsection \<open>Equality of multisets\<close>
   172 
   173 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   174   by (simp add: multiset_eq_iff)
   175 
   176 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   177   by (auto simp add: multiset_eq_iff)
   178 
   179 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   180   by (auto simp add: multiset_eq_iff)
   181 
   182 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma diff_single_trivial: "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma diff_single_eq_union: "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   192   by auto
   193 
   194 lemma union_single_eq_diff: "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   195   by (auto dest: sym)
   196 
   197 lemma union_single_eq_member: "M + {#x#} = N \<Longrightarrow> x \<in># N"
   198   by auto
   199 
   200 lemma union_is_single: "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}"
   201   (is "?lhs = ?rhs")
   202 proof
   203   show ?lhs if ?rhs using that by auto
   204   show ?rhs if ?lhs
   205     using that by (simp add: multiset_eq_iff split: if_splits) (metis add_is_1)
   206 qed
   207 
   208 lemma single_is_union: "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   209   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   210 
   211 lemma add_eq_conv_diff:
   212   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"
   213   (is "?lhs \<longleftrightarrow> ?rhs")
   214 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   215 proof
   216   show ?lhs if ?rhs
   217     using that
   218     by (auto simp add: add.assoc add.commute [of "{#b#}"])
   219       (drule sym, simp add: add.assoc [symmetric])
   220   show ?rhs if ?lhs
   221   proof (cases "a = b")
   222     case True with \<open>?lhs\<close> show ?thesis by simp
   223   next
   224     case False
   225     from \<open>?lhs\<close> have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   226     with False have "a \<in># N" by auto
   227     moreover from \<open>?lhs\<close> have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   228     moreover note False
   229     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   230   qed
   231 qed
   232 
   233 lemma insert_noteq_member:
   234   assumes BC: "B + {#b#} = C + {#c#}"
   235    and bnotc: "b \<noteq> c"
   236   shows "c \<in># B"
   237 proof -
   238   have "c \<in># C + {#c#}" by simp
   239   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   240   then have "c \<in># B + {#b#}" using BC by simp
   241   then show "c \<in># B" using nc by simp
   242 qed
   243 
   244 lemma add_eq_conv_ex:
   245   "(M + {#a#} = N + {#b#}) =
   246     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   247   by (auto simp add: add_eq_conv_diff)
   248 
   249 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   250   by (rule exI [where x = "M - {#x#}"]) simp
   251 
   252 lemma multiset_add_sub_el_shuffle:
   253   assumes "c \<in># B"
   254     and "b \<noteq> c"
   255   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   256 proof -
   257   from \<open>c \<in># B\<close> obtain A where B: "B = A + {#c#}"
   258     by (blast dest: multi_member_split)
   259   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   260   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
   261     by (simp add: ac_simps)
   262   then show ?thesis using B by simp
   263 qed
   264 
   265 
   266 subsubsection \<open>Pointwise ordering induced by count\<close>
   267 
   268 definition subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
   269 "subseteq_mset A B = (\<forall>a. count A a \<le> count B a)"
   270 
   271 definition subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
   272 "subset_mset A B = (A <=# B \<and> A \<noteq> B)"
   273 
   274 notation subseteq_mset (infix "\<le>#" 50)
   275 notation (xsymbols) subseteq_mset (infix "\<subseteq>#" 50)
   276 
   277 notation (xsymbols) subset_mset (infix "\<subset>#" 50)
   278 
   279 interpretation subset_mset: ordered_ab_semigroup_add_imp_le "op +" "op -" "op \<subseteq>#" "op \<subset>#"
   280   by standard (auto simp add: subset_mset_def subseteq_mset_def multiset_eq_iff intro: order_trans antisym)
   281 
   282 lemma mset_less_eqI: "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le># B"
   283   by (simp add: subseteq_mset_def)
   284 
   285 lemma mset_le_exists_conv: "(A::'a multiset) \<le># B \<longleftrightarrow> (\<exists>C. B = A + C)"
   286   unfolding subseteq_mset_def
   287   apply (rule iffI)
   288    apply (rule exI [where x = "B - A"])
   289    apply (auto intro: multiset_eq_iff [THEN iffD2])
   290   done
   291 
   292 interpretation subset_mset: ordered_cancel_comm_monoid_diff  "op +" "op -" 0 "op \<le>#" "op <#"
   293   by standard (simp, fact mset_le_exists_conv)
   294 
   295 lemma mset_le_mono_add_right_cancel [simp]: "(A::'a multiset) + C \<le># B + C \<longleftrightarrow> A \<le># B"
   296   by (fact subset_mset.add_le_cancel_right)
   297 
   298 lemma mset_le_mono_add_left_cancel [simp]: "C + (A::'a multiset) \<le># C + B \<longleftrightarrow> A \<le># B"
   299   by (fact subset_mset.add_le_cancel_left)
   300 
   301 lemma mset_le_mono_add: "(A::'a multiset) \<le># B \<Longrightarrow> C \<le># D \<Longrightarrow> A + C \<le># B + D"
   302   by (fact subset_mset.add_mono)
   303 
   304 lemma mset_le_add_left [simp]: "(A::'a multiset) \<le># A + B"
   305   unfolding subseteq_mset_def by auto
   306 
   307 lemma mset_le_add_right [simp]: "B \<le># (A::'a multiset) + B"
   308   unfolding subseteq_mset_def by auto
   309 
   310 lemma mset_le_single: "a \<in># B \<Longrightarrow> {#a#} \<le># B"
   311   by (simp add: subseteq_mset_def)
   312 
   313 lemma multiset_diff_union_assoc:
   314   fixes A B C D :: "'a multiset"
   315   shows "C \<le># B \<Longrightarrow> A + B - C = A + (B - C)"
   316   by (simp add: subset_mset.diff_add_assoc)
   317 
   318 lemma mset_le_multiset_union_diff_commute:
   319   fixes A B C D :: "'a multiset"
   320   shows "B \<le># A \<Longrightarrow> A - B + C = A + C - B"
   321 by (simp add: subset_mset.add_diff_assoc2)
   322 
   323 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le># M"
   324 by(simp add: subseteq_mset_def)
   325 
   326 lemma mset_lessD: "A <# B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   327 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   328 apply (erule allE [where x = x])
   329 apply auto
   330 done
   331 
   332 lemma mset_leD: "A \<le># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   333 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   334 apply (erule allE [where x = x])
   335 apply auto
   336 done
   337 
   338 lemma mset_less_insertD: "(A + {#x#} <# B) \<Longrightarrow> (x \<in># B \<and> A <# B)"
   339 apply (rule conjI)
   340  apply (simp add: mset_lessD)
   341 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   342 apply safe
   343  apply (erule_tac x = a in allE)
   344  apply (auto split: split_if_asm)
   345 done
   346 
   347 lemma mset_le_insertD: "(A + {#x#} \<le># B) \<Longrightarrow> (x \<in># B \<and> A \<le># B)"
   348 apply (rule conjI)
   349  apply (simp add: mset_leD)
   350 apply (force simp: subset_mset_def subseteq_mset_def split: split_if_asm)
   351 done
   352 
   353 lemma mset_less_of_empty[simp]: "A <# {#} \<longleftrightarrow> False"
   354   by (auto simp add: subseteq_mset_def subset_mset_def multiset_eq_iff)
   355 
   356 lemma empty_le[simp]: "{#} \<le># A"
   357   unfolding mset_le_exists_conv by auto
   358 
   359 lemma le_empty[simp]: "(M \<le># {#}) = (M = {#})"
   360   unfolding mset_le_exists_conv by auto
   361 
   362 lemma multi_psub_of_add_self[simp]: "A <# A + {#x#}"
   363   by (auto simp: subset_mset_def subseteq_mset_def)
   364 
   365 lemma multi_psub_self[simp]: "(A::'a multiset) <# A = False"
   366   by simp
   367 
   368 lemma mset_less_add_bothsides: "N + {#x#} <# M + {#x#} \<Longrightarrow> N <# M"
   369   by (fact subset_mset.add_less_imp_less_right)
   370 
   371 lemma mset_less_empty_nonempty: "{#} <# S \<longleftrightarrow> S \<noteq> {#}"
   372   by (auto simp: subset_mset_def subseteq_mset_def)
   373 
   374 lemma mset_less_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} <# B"
   375   by (auto simp: subset_mset_def subseteq_mset_def multiset_eq_iff)
   376 
   377 
   378 subsubsection \<open>Intersection\<close>
   379 
   380 definition inf_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   381   multiset_inter_def: "inf_subset_mset A B = A - (A - B)"
   382 
   383 interpretation subset_mset: semilattice_inf inf_subset_mset "op \<le>#" "op <#"
   384 proof -
   385   have [simp]: "m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" for m n q :: nat
   386     by arith
   387   show "class.semilattice_inf op #\<inter> op \<le># op <#"
   388     by standard (auto simp add: multiset_inter_def subseteq_mset_def)
   389 qed
   390 
   391 
   392 lemma multiset_inter_count [simp]:
   393   fixes A B :: "'a multiset"
   394   shows "count (A #\<inter> B) x = min (count A x) (count B x)"
   395   by (simp add: multiset_inter_def)
   396 
   397 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   398   by (rule multiset_eqI) auto
   399 
   400 lemma multiset_union_diff_commute:
   401   assumes "B #\<inter> C = {#}"
   402   shows "A + B - C = A - C + B"
   403 proof (rule multiset_eqI)
   404   fix x
   405   from assms have "min (count B x) (count C x) = 0"
   406     by (auto simp add: multiset_eq_iff)
   407   then have "count B x = 0 \<or> count C x = 0"
   408     by auto
   409   then show "count (A + B - C) x = count (A - C + B) x"
   410     by auto
   411 qed
   412 
   413 lemma empty_inter [simp]: "{#} #\<inter> M = {#}"
   414   by (simp add: multiset_eq_iff)
   415 
   416 lemma inter_empty [simp]: "M #\<inter> {#} = {#}"
   417   by (simp add: multiset_eq_iff)
   418 
   419 lemma inter_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   420   by (simp add: multiset_eq_iff)
   421 
   422 lemma inter_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   423   by (simp add: multiset_eq_iff)
   424 
   425 lemma inter_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   426   by (simp add: multiset_eq_iff)
   427 
   428 lemma inter_add_right2: "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   429   by (simp add: multiset_eq_iff)
   430 
   431 
   432 subsubsection \<open>Bounded union\<close>
   433 
   434 definition sup_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"(infixl "#\<union>" 70)
   435   where "sup_subset_mset A B = A + (B - A)"
   436 
   437 interpretation subset_mset: semilattice_sup sup_subset_mset "op \<le>#" "op <#"
   438 proof -
   439   have [simp]: "m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" for m n q :: nat
   440     by arith
   441   show "class.semilattice_sup op #\<union> op \<le># op <#"
   442     by standard (auto simp add: sup_subset_mset_def subseteq_mset_def)
   443 qed
   444 
   445 lemma sup_subset_mset_count [simp]: "count (A #\<union> B) x = max (count A x) (count B x)"
   446   by (simp add: sup_subset_mset_def)
   447 
   448 lemma empty_sup [simp]: "{#} #\<union> M = M"
   449   by (simp add: multiset_eq_iff)
   450 
   451 lemma sup_empty [simp]: "M #\<union> {#} = M"
   452   by (simp add: multiset_eq_iff)
   453 
   454 lemma sup_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   455   by (simp add: multiset_eq_iff)
   456 
   457 lemma sup_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   458   by (simp add: multiset_eq_iff)
   459 
   460 lemma sup_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   461   by (simp add: multiset_eq_iff)
   462 
   463 lemma sup_add_right2: "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   464   by (simp add: multiset_eq_iff)
   465 
   466 subsubsection \<open>Subset is an order\<close>
   467 interpretation subset_mset: order "op \<le>#" "op <#" by unfold_locales auto
   468 
   469 subsubsection \<open>Filter (with comprehension syntax)\<close>
   470 
   471 text \<open>Multiset comprehension\<close>
   472 
   473 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
   474 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   475 by (rule filter_preserves_multiset)
   476 
   477 lemma count_filter_mset [simp]: "count (filter_mset P M) a = (if P a then count M a else 0)"
   478   by (simp add: filter_mset.rep_eq)
   479 
   480 lemma filter_empty_mset [simp]: "filter_mset P {#} = {#}"
   481   by (rule multiset_eqI) simp
   482 
   483 lemma filter_single_mset [simp]: "filter_mset P {#x#} = (if P x then {#x#} else {#})"
   484   by (rule multiset_eqI) simp
   485 
   486 lemma filter_union_mset [simp]: "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
   487   by (rule multiset_eqI) simp
   488 
   489 lemma filter_diff_mset [simp]: "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
   490   by (rule multiset_eqI) simp
   491 
   492 lemma filter_inter_mset [simp]: "filter_mset P (M #\<inter> N) = filter_mset P M #\<inter> filter_mset P N"
   493   by (rule multiset_eqI) simp
   494 
   495 lemma multiset_filter_subset[simp]: "filter_mset f M \<le># M"
   496   by (simp add: mset_less_eqI)
   497 
   498 lemma multiset_filter_mono:
   499   assumes "A \<le># B"
   500   shows "filter_mset f A \<le># filter_mset f B"
   501 proof -
   502   from assms[unfolded mset_le_exists_conv]
   503   obtain C where B: "B = A + C" by auto
   504   show ?thesis unfolding B by auto
   505 qed
   506 
   507 syntax
   508   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   509 syntax (xsymbol)
   510   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   511 translations
   512   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
   513 
   514 
   515 subsubsection \<open>Set of elements\<close>
   516 
   517 definition set_mset :: "'a multiset \<Rightarrow> 'a set"
   518   where "set_mset M = {x. x \<in># M}"
   519 
   520 lemma set_mset_empty [simp]: "set_mset {#} = {}"
   521 by (simp add: set_mset_def)
   522 
   523 lemma set_mset_single [simp]: "set_mset {#b#} = {b}"
   524 by (simp add: set_mset_def)
   525 
   526 lemma set_mset_union [simp]: "set_mset (M + N) = set_mset M \<union> set_mset N"
   527 by (auto simp add: set_mset_def)
   528 
   529 lemma set_mset_eq_empty_iff [simp]: "(set_mset M = {}) = (M = {#})"
   530 by (auto simp add: set_mset_def multiset_eq_iff)
   531 
   532 lemma mem_set_mset_iff [simp]: "(x \<in> set_mset M) = (x \<in># M)"
   533 by (auto simp add: set_mset_def)
   534 
   535 lemma set_mset_filter [simp]: "set_mset {# x\<in>#M. P x #} = set_mset M \<inter> {x. P x}"
   536 by (auto simp add: set_mset_def)
   537 
   538 lemma finite_set_mset [iff]: "finite (set_mset M)"
   539   using count [of M] by (simp add: multiset_def set_mset_def)
   540 
   541 lemma finite_Collect_mem [iff]: "finite {x. x \<in># M}"
   542   unfolding set_mset_def[symmetric] by simp
   543 
   544 lemma set_mset_mono: "A \<le># B \<Longrightarrow> set_mset A \<subseteq> set_mset B"
   545   by (metis mset_leD subsetI mem_set_mset_iff)
   546 
   547 lemma ball_set_mset_iff: "(\<forall>x \<in> set_mset M. P x) \<longleftrightarrow> (\<forall>x. x \<in># M \<longrightarrow> P x)"
   548   by auto
   549 
   550 
   551 subsubsection \<open>Size\<close>
   552 
   553 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
   554 
   555 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
   556   by (auto simp: wcount_def add_mult_distrib)
   557 
   558 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
   559   "size_multiset f M = setsum (wcount f M) (set_mset M)"
   560 
   561 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
   562 
   563 instantiation multiset :: (type) size
   564 begin
   565 
   566 definition size_multiset where
   567   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
   568 instance ..
   569 
   570 end
   571 
   572 lemmas size_multiset_overloaded_eq =
   573   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
   574 
   575 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
   576 by (simp add: size_multiset_def)
   577 
   578 lemma size_empty [simp]: "size {#} = 0"
   579 by (simp add: size_multiset_overloaded_def)
   580 
   581 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
   582 by (simp add: size_multiset_eq)
   583 
   584 lemma size_single [simp]: "size {#b#} = 1"
   585 by (simp add: size_multiset_overloaded_def)
   586 
   587 lemma setsum_wcount_Int:
   588   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_mset N) = setsum (wcount f N) A"
   589 apply (induct rule: finite_induct)
   590  apply simp
   591 apply (simp add: Int_insert_left set_mset_def wcount_def)
   592 done
   593 
   594 lemma size_multiset_union [simp]:
   595   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
   596 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
   597 apply (subst Int_commute)
   598 apply (simp add: setsum_wcount_Int)
   599 done
   600 
   601 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   602 by (auto simp add: size_multiset_overloaded_def)
   603 
   604 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
   605 by (auto simp add: size_multiset_eq multiset_eq_iff)
   606 
   607 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   608 by (auto simp add: size_multiset_overloaded_def)
   609 
   610 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   611 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   612 
   613 lemma size_eq_Suc_imp_elem: "size M = Suc n \<Longrightarrow> \<exists>a. a \<in># M"
   614 apply (unfold size_multiset_overloaded_eq)
   615 apply (drule setsum_SucD)
   616 apply auto
   617 done
   618 
   619 lemma size_eq_Suc_imp_eq_union:
   620   assumes "size M = Suc n"
   621   shows "\<exists>a N. M = N + {#a#}"
   622 proof -
   623   from assms obtain a where "a \<in># M"
   624     by (erule size_eq_Suc_imp_elem [THEN exE])
   625   then have "M = M - {#a#} + {#a#}" by simp
   626   then show ?thesis by blast
   627 qed
   628 
   629 lemma size_mset_mono:
   630   fixes A B :: "'a multiset"
   631   assumes "A \<le># B"
   632   shows "size A \<le> size B"
   633 proof -
   634   from assms[unfolded mset_le_exists_conv]
   635   obtain C where B: "B = A + C" by auto
   636   show ?thesis unfolding B by (induct C) auto
   637 qed
   638 
   639 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
   640 by (rule size_mset_mono[OF multiset_filter_subset])
   641 
   642 lemma size_Diff_submset:
   643   "M \<le># M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
   644 by (metis add_diff_cancel_left' size_union mset_le_exists_conv)
   645 
   646 subsection \<open>Induction and case splits\<close>
   647 
   648 theorem multiset_induct [case_names empty add, induct type: multiset]:
   649   assumes empty: "P {#}"
   650   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   651   shows "P M"
   652 proof (induct n \<equiv> "size M" arbitrary: M)
   653   case 0 thus "P M" by (simp add: empty)
   654 next
   655   case (Suc k)
   656   obtain N x where "M = N + {#x#}"
   657     using \<open>Suc k = size M\<close> [symmetric]
   658     using size_eq_Suc_imp_eq_union by fast
   659   with Suc add show "P M" by simp
   660 qed
   661 
   662 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   663 by (induct M) auto
   664 
   665 lemma multiset_cases [cases type]:
   666   obtains (empty) "M = {#}"
   667     | (add) N x where "M = N + {#x#}"
   668   using assms by (induct M) simp_all
   669 
   670 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   671 by (cases "B = {#}") (auto dest: multi_member_split)
   672 
   673 lemma multiset_partition: "M = {# x\<in>#M. P x #} + {# x\<in>#M. \<not> P x #}"
   674 apply (subst multiset_eq_iff)
   675 apply auto
   676 done
   677 
   678 lemma mset_less_size: "(A::'a multiset) <# B \<Longrightarrow> size A < size B"
   679 proof (induct A arbitrary: B)
   680   case (empty M)
   681   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   682   then obtain M' x where "M = M' + {#x#}"
   683     by (blast dest: multi_nonempty_split)
   684   then show ?case by simp
   685 next
   686   case (add S x T)
   687   have IH: "\<And>B. S <# B \<Longrightarrow> size S < size B" by fact
   688   have SxsubT: "S + {#x#} <# T" by fact
   689   then have "x \<in># T" and "S <# T" by (auto dest: mset_less_insertD)
   690   then obtain T' where T: "T = T' + {#x#}"
   691     by (blast dest: multi_member_split)
   692   then have "S <# T'" using SxsubT
   693     by (blast intro: mset_less_add_bothsides)
   694   then have "size S < size T'" using IH by simp
   695   then show ?case using T by simp
   696 qed
   697 
   698 
   699 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
   700 by (cases M) auto
   701 
   702 subsubsection \<open>Strong induction and subset induction for multisets\<close>
   703 
   704 text \<open>Well-foundedness of strict subset relation\<close>
   705 
   706 lemma wf_less_mset_rel: "wf {(M, N :: 'a multiset). M <# N}"
   707 apply (rule wf_measure [THEN wf_subset, where f1=size])
   708 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   709 done
   710 
   711 lemma full_multiset_induct [case_names less]:
   712 assumes ih: "\<And>B. \<forall>(A::'a multiset). A <# B \<longrightarrow> P A \<Longrightarrow> P B"
   713 shows "P B"
   714 apply (rule wf_less_mset_rel [THEN wf_induct])
   715 apply (rule ih, auto)
   716 done
   717 
   718 lemma multi_subset_induct [consumes 2, case_names empty add]:
   719   assumes "F \<le># A"
   720     and empty: "P {#}"
   721     and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   722   shows "P F"
   723 proof -
   724   from \<open>F \<le># A\<close>
   725   show ?thesis
   726   proof (induct F)
   727     show "P {#}" by fact
   728   next
   729     fix x F
   730     assume P: "F \<le># A \<Longrightarrow> P F" and i: "F + {#x#} \<le># A"
   731     show "P (F + {#x#})"
   732     proof (rule insert)
   733       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   734       from i have "F \<le># A" by (auto dest: mset_le_insertD)
   735       with P show "P F" .
   736     qed
   737   qed
   738 qed
   739 
   740 
   741 subsection \<open>The fold combinator\<close>
   742 
   743 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   744 where
   745   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_mset M)"
   746 
   747 lemma fold_mset_empty [simp]: "fold_mset f s {#} = s"
   748   by (simp add: fold_mset_def)
   749 
   750 context comp_fun_commute
   751 begin
   752 
   753 lemma fold_mset_insert: "fold_mset f s (M + {#x#}) = f x (fold_mset f s M)"
   754 proof -
   755   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   756     by (fact comp_fun_commute_funpow)
   757   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   758     by (fact comp_fun_commute_funpow)
   759   show ?thesis
   760   proof (cases "x \<in> set_mset M")
   761     case False
   762     then have *: "count (M + {#x#}) x = 1" by simp
   763     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_mset M) =
   764       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_mset M)"
   765       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   766     with False * show ?thesis
   767       by (simp add: fold_mset_def del: count_union)
   768   next
   769     case True
   770     def N \<equiv> "set_mset M - {x}"
   771     from N_def True have *: "set_mset M = insert x N" "x \<notin> N" "finite N" by auto
   772     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   773       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   774       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   775     with * show ?thesis by (simp add: fold_mset_def del: count_union) simp
   776   qed
   777 qed
   778 
   779 corollary fold_mset_single [simp]: "fold_mset f s {#x#} = f x s"
   780 proof -
   781   have "fold_mset f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   782   then show ?thesis by simp
   783 qed
   784 
   785 lemma fold_mset_fun_left_comm: "f x (fold_mset f s M) = fold_mset f (f x s) M"
   786   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   787 
   788 lemma fold_mset_union [simp]: "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
   789 proof (induct M)
   790   case empty then show ?case by simp
   791 next
   792   case (add M x)
   793   have "M + {#x#} + N = (M + N) + {#x#}"
   794     by (simp add: ac_simps)
   795   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   796 qed
   797 
   798 lemma fold_mset_fusion:
   799   assumes "comp_fun_commute g"
   800     and *: "\<And>x y. h (g x y) = f x (h y)"
   801   shows "h (fold_mset g w A) = fold_mset f (h w) A"
   802 proof -
   803   interpret comp_fun_commute g by (fact assms)
   804   from * show ?thesis by (induct A) auto
   805 qed
   806 
   807 end
   808 
   809 text \<open>
   810   A note on code generation: When defining some function containing a
   811   subterm @{term "fold_mset F"}, code generation is not automatic. When
   812   interpreting locale @{text left_commutative} with @{text F}, the
   813   would be code thms for @{const fold_mset} become thms like
   814   @{term "fold_mset F z {#} = z"} where @{text F} is not a pattern but
   815   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   816   constant with its own code thms needs to be introduced for @{text
   817   F}. See the image operator below.
   818 \<close>
   819 
   820 
   821 subsection \<open>Image\<close>
   822 
   823 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   824   "image_mset f = fold_mset (plus \<circ> single \<circ> f) {#}"
   825 
   826 lemma comp_fun_commute_mset_image: "comp_fun_commute (plus \<circ> single \<circ> f)"
   827 proof
   828 qed (simp add: ac_simps fun_eq_iff)
   829 
   830 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   831   by (simp add: image_mset_def)
   832 
   833 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   834 proof -
   835   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   836     by (fact comp_fun_commute_mset_image)
   837   show ?thesis by (simp add: image_mset_def)
   838 qed
   839 
   840 lemma image_mset_union [simp]: "image_mset f (M + N) = image_mset f M + image_mset f N"
   841 proof -
   842   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   843     by (fact comp_fun_commute_mset_image)
   844   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
   845 qed
   846 
   847 corollary image_mset_insert: "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   848   by simp
   849 
   850 lemma set_image_mset [simp]: "set_mset (image_mset f M) = image f (set_mset M)"
   851   by (induct M) simp_all
   852 
   853 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
   854   by (induct M) simp_all
   855 
   856 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   857   by (cases M) auto
   858 
   859 syntax
   860   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   861       ("({#_/. _ :# _#})")
   862 translations
   863   "{#e. x:#M#}" == "CONST image_mset (\<lambda>x. e) M"
   864 
   865 syntax (xsymbols)
   866   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   867       ("({#_/. _ \<in># _#})")
   868 translations
   869   "{#e. x \<in># M#}" == "CONST image_mset (\<lambda>x. e) M"
   870 
   871 syntax
   872   "_comprehension3_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   873       ("({#_/ | _ :# _./ _#})")
   874 translations
   875   "{#e | x:#M. P#}" \<rightharpoonup> "{#e. x :# {# x:#M. P#}#}"
   876 
   877 syntax
   878   "_comprehension4_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   879       ("({#_/ | _ \<in># _./ _#})")
   880 translations
   881   "{#e | x\<in>#M. P#}" \<rightharpoonup> "{#e. x \<in># {# x\<in>#M. P#}#}"
   882 
   883 text \<open>
   884   This allows to write not just filters like @{term "{#x\<in>#M. x<c#}"}
   885   but also images like @{term "{#x+x. x\<in>#M #}"} and @{term [source]
   886   "{#x+x|x\<in>#M. x<c#}"}, where the latter is currently displayed as
   887   @{term "{#x+x|x\<in>#M. x<c#}"}.
   888 \<close>
   889 
   890 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_mset M"
   891 by (metis mem_set_mset_iff set_image_mset)
   892 
   893 functor image_mset: image_mset
   894 proof -
   895   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   896   proof
   897     fix A
   898     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   899       by (induct A) simp_all
   900   qed
   901   show "image_mset id = id"
   902   proof
   903     fix A
   904     show "image_mset id A = id A"
   905       by (induct A) simp_all
   906   qed
   907 qed
   908 
   909 declare
   910   image_mset.id [simp]
   911   image_mset.identity [simp]
   912 
   913 lemma image_mset_id[simp]: "image_mset id x = x"
   914   unfolding id_def by auto
   915 
   916 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
   917   by (induct M) auto
   918 
   919 lemma image_mset_cong_pair:
   920   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
   921   by (metis image_mset_cong split_cong)
   922 
   923 
   924 subsection \<open>Further conversions\<close>
   925 
   926 primrec mset :: "'a list \<Rightarrow> 'a multiset" where
   927   "mset [] = {#}" |
   928   "mset (a # x) = mset x + {# a #}"
   929 
   930 lemma in_multiset_in_set:
   931   "x \<in># mset xs \<longleftrightarrow> x \<in> set xs"
   932   by (induct xs) simp_all
   933 
   934 lemma count_mset:
   935   "count (mset xs) x = length (filter (\<lambda>y. x = y) xs)"
   936   by (induct xs) simp_all
   937 
   938 lemma mset_zero_iff[simp]: "(mset x = {#}) = (x = [])"
   939   by (induct x) auto
   940 
   941 lemma mset_zero_iff_right[simp]: "({#} = mset x) = (x = [])"
   942 by (induct x) auto
   943 
   944 lemma set_mset_mset[simp]: "set_mset (mset x) = set x"
   945 by (induct x) auto
   946 
   947 lemma mem_set_multiset_eq: "x \<in> set xs = (x \<in># mset xs)"
   948 by (induct xs) auto
   949 
   950 lemma size_mset [simp]: "size (mset xs) = length xs"
   951   by (induct xs) simp_all
   952 
   953 lemma mset_append [simp]: "mset (xs @ ys) = mset xs + mset ys"
   954   by (induct xs arbitrary: ys) (auto simp: ac_simps)
   955 
   956 lemma mset_filter: "mset (filter P xs) = {#x \<in># mset xs. P x #}"
   957   by (induct xs) simp_all
   958 
   959 lemma mset_rev [simp]:
   960   "mset (rev xs) = mset xs"
   961   by (induct xs) simp_all
   962 
   963 lemma surj_mset: "surj mset"
   964 apply (unfold surj_def)
   965 apply (rule allI)
   966 apply (rule_tac M = y in multiset_induct)
   967  apply auto
   968 apply (rule_tac x = "x # xa" in exI)
   969 apply auto
   970 done
   971 
   972 lemma set_count_greater_0: "set x = {a. count (mset x) a > 0}"
   973 by (induct x) auto
   974 
   975 lemma distinct_count_atmost_1:
   976   "distinct x = (\<forall>a. count (mset x) a = (if a \<in> set x then 1 else 0))"
   977   apply (induct x, simp, rule iffI, simp_all)
   978   subgoal for a b
   979     apply (rule conjI)
   980     apply (simp_all add: set_mset_mset [symmetric] del: set_mset_mset)
   981     apply (erule_tac x = a in allE, simp)
   982     apply clarify
   983     apply (erule_tac x = aa in allE, simp)
   984     done
   985   done
   986 
   987 lemma mset_eq_setD: "mset xs = mset ys \<Longrightarrow> set xs = set ys"
   988 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   989 
   990 lemma set_eq_iff_mset_eq_distinct:
   991   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   992     (set x = set y) = (mset x = mset y)"
   993 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   994 
   995 lemma set_eq_iff_mset_remdups_eq:
   996    "(set x = set y) = (mset (remdups x) = mset (remdups y))"
   997 apply (rule iffI)
   998 apply (simp add: set_eq_iff_mset_eq_distinct[THEN iffD1])
   999 apply (drule distinct_remdups [THEN distinct_remdups
  1000       [THEN set_eq_iff_mset_eq_distinct [THEN iffD2]]])
  1001 apply simp
  1002 done
  1003 
  1004 lemma mset_compl_union [simp]: "mset [x\<leftarrow>xs. P x] + mset [x\<leftarrow>xs. \<not>P x] = mset xs"
  1005   by (induct xs) (auto simp: ac_simps)
  1006 
  1007 lemma nth_mem_mset: "i < length ls \<Longrightarrow> (ls ! i) \<in># mset ls"
  1008 proof (induct ls arbitrary: i)
  1009   case Nil
  1010   then show ?case by simp
  1011 next
  1012   case Cons
  1013   then show ?case by (cases i) auto
  1014 qed
  1015 
  1016 lemma mset_remove1[simp]: "mset (remove1 a xs) = mset xs - {#a#}"
  1017   by (induct xs) (auto simp add: multiset_eq_iff)
  1018 
  1019 lemma mset_eq_length:
  1020   assumes "mset xs = mset ys"
  1021   shows "length xs = length ys"
  1022   using assms by (metis size_mset)
  1023 
  1024 lemma mset_eq_length_filter:
  1025   assumes "mset xs = mset ys"
  1026   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1027   using assms by (metis count_mset)
  1028 
  1029 lemma fold_multiset_equiv:
  1030   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1031     and equiv: "mset xs = mset ys"
  1032   shows "List.fold f xs = List.fold f ys"
  1033   using f equiv [symmetric]
  1034 proof (induct xs arbitrary: ys)
  1035   case Nil
  1036   then show ?case by simp
  1037 next
  1038   case (Cons x xs)
  1039   then have *: "set ys = set (x # xs)"
  1040     by (blast dest: mset_eq_setD)
  1041   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1042     by (rule Cons.prems(1)) (simp_all add: *)
  1043   moreover from * have "x \<in> set ys"
  1044     by simp
  1045   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x"
  1046     by (fact fold_remove1_split)
  1047   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)"
  1048     by (auto intro: Cons.hyps)
  1049   ultimately show ?case by simp
  1050 qed
  1051 
  1052 lemma mset_insort [simp]: "mset (insort x xs) = mset xs + {#x#}"
  1053   by (induct xs) (simp_all add: ac_simps)
  1054 
  1055 lemma mset_map: "mset (map f xs) = image_mset f (mset xs)"
  1056   by (induct xs) simp_all
  1057 
  1058 definition mset_set :: "'a set \<Rightarrow> 'a multiset"
  1059 where
  1060   "mset_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1061 
  1062 interpretation mset_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1063 where
  1064   "folding.F (\<lambda>x M. {#x#} + M) {#} = mset_set"
  1065 proof -
  1066   interpret comp_fun_commute "\<lambda>x M. {#x#} + M"
  1067     by standard (simp add: fun_eq_iff ac_simps)
  1068   show "folding (\<lambda>x M. {#x#} + M)"
  1069     by standard (fact comp_fun_commute)
  1070   from mset_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = mset_set" ..
  1071 qed
  1072 
  1073 lemma count_mset_set [simp]:
  1074   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (mset_set A) x = 1" (is "PROP ?P")
  1075   "\<not> finite A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?Q")
  1076   "x \<notin> A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?R")
  1077 proof -
  1078   have *: "count (mset_set A) x = 0" if "x \<notin> A" for A
  1079   proof (cases "finite A")
  1080     case False then show ?thesis by simp
  1081   next
  1082     case True from True \<open>x \<notin> A\<close> show ?thesis by (induct A) auto
  1083   qed
  1084   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1085   by (auto elim!: Set.set_insert)
  1086 qed -- \<open>TODO: maybe define @{const mset_set} also in terms of @{const Abs_multiset}\<close>
  1087 
  1088 lemma elem_mset_set[simp, intro]: "finite A \<Longrightarrow> x \<in># mset_set A \<longleftrightarrow> x \<in> A"
  1089   by (induct A rule: finite_induct) simp_all
  1090 
  1091 context linorder
  1092 begin
  1093 
  1094 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1095 where
  1096   "sorted_list_of_multiset M = fold_mset insort [] M"
  1097 
  1098 lemma sorted_list_of_multiset_empty [simp]:
  1099   "sorted_list_of_multiset {#} = []"
  1100   by (simp add: sorted_list_of_multiset_def)
  1101 
  1102 lemma sorted_list_of_multiset_singleton [simp]:
  1103   "sorted_list_of_multiset {#x#} = [x]"
  1104 proof -
  1105   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1106   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1107 qed
  1108 
  1109 lemma sorted_list_of_multiset_insert [simp]:
  1110   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1111 proof -
  1112   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1113   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1114 qed
  1115 
  1116 end
  1117 
  1118 lemma mset_sorted_list_of_multiset [simp]:
  1119   "mset (sorted_list_of_multiset M) = M"
  1120 by (induct M) simp_all
  1121 
  1122 lemma sorted_list_of_multiset_mset [simp]:
  1123   "sorted_list_of_multiset (mset xs) = sort xs"
  1124 by (induct xs) simp_all
  1125 
  1126 lemma finite_set_mset_mset_set[simp]:
  1127   "finite A \<Longrightarrow> set_mset (mset_set A) = A"
  1128 by (induct A rule: finite_induct) simp_all
  1129 
  1130 lemma infinite_set_mset_mset_set:
  1131   "\<not> finite A \<Longrightarrow> set_mset (mset_set A) = {}"
  1132 by simp
  1133 
  1134 lemma set_sorted_list_of_multiset [simp]:
  1135   "set (sorted_list_of_multiset M) = set_mset M"
  1136 by (induct M) (simp_all add: set_insort)
  1137 
  1138 lemma sorted_list_of_mset_set [simp]:
  1139   "sorted_list_of_multiset (mset_set A) = sorted_list_of_set A"
  1140 by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1141 
  1142 
  1143 subsection \<open>Replicate operation\<close>
  1144 
  1145 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
  1146   "replicate_mset n x = ((op + {#x#}) ^^ n) {#}"
  1147 
  1148 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
  1149   unfolding replicate_mset_def by simp
  1150 
  1151 lemma replicate_mset_Suc[simp]: "replicate_mset (Suc n) x = replicate_mset n x + {#x#}"
  1152   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
  1153 
  1154 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  1155   unfolding replicate_mset_def by (induct n) simp_all
  1156 
  1157 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
  1158   unfolding replicate_mset_def by (induct n) simp_all
  1159 
  1160 lemma set_mset_replicate_mset_subset[simp]: "set_mset (replicate_mset n x) = (if n = 0 then {} else {x})"
  1161   by (auto split: if_splits)
  1162 
  1163 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  1164   by (induct n, simp_all)
  1165 
  1166 lemma count_le_replicate_mset_le: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<le># M"
  1167   by (auto simp add: assms mset_less_eqI) (metis count_replicate_mset subseteq_mset_def)
  1168 
  1169 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  1170   by (induct D) simp_all
  1171 
  1172 
  1173 subsection \<open>Big operators\<close>
  1174 
  1175 no_notation times (infixl "*" 70)
  1176 no_notation Groups.one ("1")
  1177 
  1178 locale comm_monoid_mset = comm_monoid
  1179 begin
  1180 
  1181 definition F :: "'a multiset \<Rightarrow> 'a"
  1182   where eq_fold: "F M = fold_mset f 1 M"
  1183 
  1184 lemma empty [simp]: "F {#} = 1"
  1185   by (simp add: eq_fold)
  1186 
  1187 lemma singleton [simp]: "F {#x#} = x"
  1188 proof -
  1189   interpret comp_fun_commute
  1190     by standard (simp add: fun_eq_iff left_commute)
  1191   show ?thesis by (simp add: eq_fold)
  1192 qed
  1193 
  1194 lemma union [simp]: "F (M + N) = F M * F N"
  1195 proof -
  1196   interpret comp_fun_commute f
  1197     by standard (simp add: fun_eq_iff left_commute)
  1198   show ?thesis
  1199     by (induct N) (simp_all add: left_commute eq_fold)
  1200 qed
  1201 
  1202 end
  1203 
  1204 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + \<Colon> 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  1205   by standard (simp add: add_ac comp_def)
  1206 
  1207 declare comp_fun_commute.fold_mset_insert[OF comp_fun_commute_plus_mset, simp]
  1208 
  1209 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  1210   by (induct NN) auto
  1211 
  1212 notation times (infixl "*" 70)
  1213 notation Groups.one ("1")
  1214 
  1215 context comm_monoid_add
  1216 begin
  1217 
  1218 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1219   where "msetsum = comm_monoid_mset.F plus 0"
  1220 
  1221 sublocale msetsum!: comm_monoid_mset plus 0
  1222   where "comm_monoid_mset.F plus 0 = msetsum"
  1223 proof -
  1224   show "comm_monoid_mset plus 0" ..
  1225   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1226 qed
  1227 
  1228 lemma (in semiring_1) msetsum_replicate_mset [simp]:
  1229   "msetsum (replicate_mset n a) = of_nat n * a"
  1230   by (induct n) (simp_all add: algebra_simps)
  1231 
  1232 lemma setsum_unfold_msetsum:
  1233   "setsum f A = msetsum (image_mset f (mset_set A))"
  1234   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1235 
  1236 end
  1237 
  1238 lemma msetsum_diff:
  1239   fixes M N :: "('a \<Colon> ordered_cancel_comm_monoid_diff) multiset"
  1240   shows "N \<le># M \<Longrightarrow> msetsum (M - N) = msetsum M - msetsum N"
  1241   by (metis add_diff_cancel_right' msetsum.union subset_mset.diff_add)
  1242 
  1243 lemma size_eq_msetsum: "size M = msetsum (image_mset (\<lambda>_. 1) M)"
  1244 proof (induct M)
  1245   case empty then show ?case by simp
  1246 next
  1247   case (add M x) then show ?case
  1248     by (cases "x \<in> set_mset M")
  1249       (simp_all del: mem_set_mset_iff add: size_multiset_overloaded_eq setsum.distrib setsum.delta' insert_absorb, simp)
  1250 qed
  1251 
  1252 
  1253 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset" where
  1254   "Union_mset MM \<equiv> msetsum MM"
  1255 
  1256 notation (xsymbols) Union_mset ("\<Union>#_" [900] 900)
  1257 
  1258 lemma set_mset_Union_mset[simp]: "set_mset (\<Union># MM) = (\<Union>M \<in> set_mset MM. set_mset M)"
  1259   by (induct MM) auto
  1260 
  1261 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  1262   by (induct MM) auto
  1263 
  1264 syntax
  1265   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1266       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1267 
  1268 syntax (xsymbols)
  1269   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1270       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1271 
  1272 syntax (HTML output)
  1273   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1274       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1275 
  1276 translations
  1277   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
  1278 
  1279 context comm_monoid_mult
  1280 begin
  1281 
  1282 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1283   where "msetprod = comm_monoid_mset.F times 1"
  1284 
  1285 sublocale msetprod!: comm_monoid_mset times 1
  1286   where "comm_monoid_mset.F times 1 = msetprod"
  1287 proof -
  1288   show "comm_monoid_mset times 1" ..
  1289   show "comm_monoid_mset.F times 1 = msetprod" using msetprod_def ..
  1290 qed
  1291 
  1292 lemma msetprod_empty:
  1293   "msetprod {#} = 1"
  1294   by (fact msetprod.empty)
  1295 
  1296 lemma msetprod_singleton:
  1297   "msetprod {#x#} = x"
  1298   by (fact msetprod.singleton)
  1299 
  1300 lemma msetprod_Un:
  1301   "msetprod (A + B) = msetprod A * msetprod B"
  1302   by (fact msetprod.union)
  1303 
  1304 lemma msetprod_replicate_mset [simp]:
  1305   "msetprod (replicate_mset n a) = a ^ n"
  1306   by (induct n) (simp_all add: ac_simps)
  1307 
  1308 lemma setprod_unfold_msetprod:
  1309   "setprod f A = msetprod (image_mset f (mset_set A))"
  1310   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1311 
  1312 lemma msetprod_multiplicity:
  1313   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_mset M)"
  1314   by (simp add: fold_mset_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1315 
  1316 end
  1317 
  1318 syntax
  1319   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1320       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1321 
  1322 syntax (xsymbols)
  1323   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1324       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1325 
  1326 syntax (HTML output)
  1327   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1328       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1329 
  1330 translations
  1331   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
  1332 
  1333 lemma (in comm_semiring_1) dvd_msetprod:
  1334   assumes "x \<in># A"
  1335   shows "x dvd msetprod A"
  1336 proof -
  1337   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1338   then obtain B where "A = B + {#x#}" ..
  1339   then show ?thesis by simp
  1340 qed
  1341 
  1342 
  1343 subsection \<open>Alternative representations\<close>
  1344 
  1345 subsubsection \<open>Lists\<close>
  1346 
  1347 context linorder
  1348 begin
  1349 
  1350 lemma mset_insort [simp]:
  1351   "mset (insort_key k x xs) = {#x#} + mset xs"
  1352   by (induct xs) (simp_all add: ac_simps)
  1353 
  1354 lemma mset_sort [simp]:
  1355   "mset (sort_key k xs) = mset xs"
  1356   by (induct xs) (simp_all add: ac_simps)
  1357 
  1358 text \<open>
  1359   This lemma shows which properties suffice to show that a function
  1360   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1361 \<close>
  1362 
  1363 lemma properties_for_sort_key:
  1364   assumes "mset ys = mset xs"
  1365     and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1366     and "sorted (map f ys)"
  1367   shows "sort_key f xs = ys"
  1368   using assms
  1369 proof (induct xs arbitrary: ys)
  1370   case Nil then show ?case by simp
  1371 next
  1372   case (Cons x xs)
  1373   from Cons.prems(2) have
  1374     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1375     by (simp add: filter_remove1)
  1376   with Cons.prems have "sort_key f xs = remove1 x ys"
  1377     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1378   moreover from Cons.prems have "x \<in> set ys"
  1379     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1380   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1381 qed
  1382 
  1383 lemma properties_for_sort:
  1384   assumes multiset: "mset ys = mset xs"
  1385     and "sorted ys"
  1386   shows "sort xs = ys"
  1387 proof (rule properties_for_sort_key)
  1388   from multiset show "mset ys = mset xs" .
  1389   from \<open>sorted ys\<close> show "sorted (map (\<lambda>x. x) ys)" by simp
  1390   from multiset have "length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)" for k
  1391     by (rule mset_eq_length_filter)
  1392   then have "replicate (length (filter (\<lambda>y. k = y) ys)) k =
  1393     replicate (length (filter (\<lambda>x. k = x) xs)) k" for k
  1394     by simp
  1395   then show "k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs" for k
  1396     by (simp add: replicate_length_filter)
  1397 qed
  1398 
  1399 lemma sort_key_by_quicksort:
  1400   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1401     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1402     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1403 proof (rule properties_for_sort_key)
  1404   show "mset ?rhs = mset ?lhs"
  1405     by (rule multiset_eqI) (auto simp add: mset_filter)
  1406   show "sorted (map f ?rhs)"
  1407     by (auto simp add: sorted_append intro: sorted_map_same)
  1408 next
  1409   fix l
  1410   assume "l \<in> set ?rhs"
  1411   let ?pivot = "f (xs ! (length xs div 2))"
  1412   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1413   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1414     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1415   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1416   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1417   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1418     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1419   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1420   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1421   proof (cases "f l" ?pivot rule: linorder_cases)
  1422     case less
  1423     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1424     with less show ?thesis
  1425       by (simp add: filter_sort [symmetric] ** ***)
  1426   next
  1427     case equal then show ?thesis
  1428       by (simp add: * less_le)
  1429   next
  1430     case greater
  1431     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1432     with greater show ?thesis
  1433       by (simp add: filter_sort [symmetric] ** ***)
  1434   qed
  1435 qed
  1436 
  1437 lemma sort_by_quicksort:
  1438   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1439     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1440     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1441   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1442 
  1443 text \<open>A stable parametrized quicksort\<close>
  1444 
  1445 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1446   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1447 
  1448 lemma part_code [code]:
  1449   "part f pivot [] = ([], [], [])"
  1450   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1451      if x' < pivot then (x # lts, eqs, gts)
  1452      else if x' > pivot then (lts, eqs, x # gts)
  1453      else (lts, x # eqs, gts))"
  1454   by (auto simp add: part_def Let_def split_def)
  1455 
  1456 lemma sort_key_by_quicksort_code [code]:
  1457   "sort_key f xs =
  1458     (case xs of
  1459       [] \<Rightarrow> []
  1460     | [x] \<Rightarrow> xs
  1461     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1462     | _ \<Rightarrow>
  1463         let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1464         in sort_key f lts @ eqs @ sort_key f gts)"
  1465 proof (cases xs)
  1466   case Nil then show ?thesis by simp
  1467 next
  1468   case (Cons _ ys) note hyps = Cons show ?thesis
  1469   proof (cases ys)
  1470     case Nil with hyps show ?thesis by simp
  1471   next
  1472     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1473     proof (cases zs)
  1474       case Nil with hyps show ?thesis by auto
  1475     next
  1476       case Cons
  1477       from sort_key_by_quicksort [of f xs]
  1478       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1479         in sort_key f lts @ eqs @ sort_key f gts)"
  1480       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1481       with hyps Cons show ?thesis by (simp only: list.cases)
  1482     qed
  1483   qed
  1484 qed
  1485 
  1486 end
  1487 
  1488 hide_const (open) part
  1489 
  1490 lemma mset_remdups_le: "mset (remdups xs) \<le># mset xs"
  1491   by (induct xs) (auto intro: subset_mset.order_trans)
  1492 
  1493 lemma mset_update:
  1494   "i < length ls \<Longrightarrow> mset (ls[i := v]) = mset ls - {#ls ! i#} + {#v#}"
  1495 proof (induct ls arbitrary: i)
  1496   case Nil then show ?case by simp
  1497 next
  1498   case (Cons x xs)
  1499   show ?case
  1500   proof (cases i)
  1501     case 0 then show ?thesis by simp
  1502   next
  1503     case (Suc i')
  1504     with Cons show ?thesis
  1505       apply simp
  1506       apply (subst add.assoc)
  1507       apply (subst add.commute [of "{#v#}" "{#x#}"])
  1508       apply (subst add.assoc [symmetric])
  1509       apply simp
  1510       apply (rule mset_le_multiset_union_diff_commute)
  1511       apply (simp add: mset_le_single nth_mem_mset)
  1512       done
  1513   qed
  1514 qed
  1515 
  1516 lemma mset_swap:
  1517   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1518     mset (ls[j := ls ! i, i := ls ! j]) = mset ls"
  1519   by (cases "i = j") (simp_all add: mset_update nth_mem_mset)
  1520 
  1521 
  1522 subsection \<open>The multiset order\<close>
  1523 
  1524 subsubsection \<open>Well-foundedness\<close>
  1525 
  1526 definition mult1 :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1527   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1528       (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r)}"
  1529 
  1530 definition mult :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1531   "mult r = (mult1 r)\<^sup>+"
  1532 
  1533 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1534 by (simp add: mult1_def)
  1535 
  1536 lemma less_add:
  1537   assumes mult1: "(N, M0 + {#a#}) \<in> mult1 r"
  1538   shows
  1539     "(\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1540      (\<exists>K. (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r) \<and> N = M0 + K)"
  1541 proof -
  1542   let ?r = "\<lambda>K a. \<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r"
  1543   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1544   obtain a' M0' K where M0: "M0 + {#a#} = M0' + {#a'#}"
  1545     and N: "N = M0' + K"
  1546     and r: "?r K a'"
  1547     using mult1 unfolding mult1_def by auto
  1548   show ?thesis (is "?case1 \<or> ?case2")
  1549   proof -
  1550     from M0 consider "M0 = M0'" "a = a'"
  1551       | K' where "M0 = K' + {#a'#}" "M0' = K' + {#a#}"
  1552       by atomize_elim (simp only: add_eq_conv_ex)
  1553     then show ?thesis
  1554     proof cases
  1555       case 1
  1556       with N r have "?r K a \<and> N = M0 + K" by simp
  1557       then have ?case2 ..
  1558       then show ?thesis ..
  1559     next
  1560       case 2
  1561       from N 2(2) have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
  1562       with r 2(1) have "?R (K' + K) M0" by blast
  1563       with n have ?case1 by (simp add: mult1_def)
  1564       then show ?thesis ..
  1565     qed
  1566   qed
  1567 qed
  1568 
  1569 lemma all_accessible:
  1570   assumes "wf r"
  1571   shows "\<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1572 proof
  1573   let ?R = "mult1 r"
  1574   let ?W = "Wellfounded.acc ?R"
  1575   {
  1576     fix M M0 a
  1577     assume M0: "M0 \<in> ?W"
  1578       and wf_hyp: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1579       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W"
  1580     have "M0 + {#a#} \<in> ?W"
  1581     proof (rule accI [of "M0 + {#a#}"])
  1582       fix N
  1583       assume "(N, M0 + {#a#}) \<in> ?R"
  1584       then consider M where "(M, M0) \<in> ?R" "N = M + {#a#}"
  1585         | K where "\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r" "N = M0 + K"
  1586         by atomize_elim (rule less_add)
  1587       then show "N \<in> ?W"
  1588       proof cases
  1589         case 1
  1590         from acc_hyp have "(M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W" ..
  1591         from this and \<open>(M, M0) \<in> ?R\<close> have "M + {#a#} \<in> ?W" ..
  1592         then show "N \<in> ?W" by (simp only: \<open>N = M + {#a#}\<close>)
  1593       next
  1594         case 2
  1595         from this(1) have "M0 + K \<in> ?W"
  1596         proof (induct K)
  1597           case empty
  1598           from M0 show "M0 + {#} \<in> ?W" by simp
  1599         next
  1600           case (add K x)
  1601           from add.prems have "(x, a) \<in> r" by simp
  1602           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1603           moreover from add have "M0 + K \<in> ?W" by simp
  1604           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1605           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
  1606         qed
  1607         then show "N \<in> ?W" by (simp only: 2(2))
  1608       qed
  1609     qed
  1610   } note tedious_reasoning = this
  1611 
  1612   show "M \<in> ?W" for M
  1613   proof (induct M)
  1614     show "{#} \<in> ?W"
  1615     proof (rule accI)
  1616       fix b assume "(b, {#}) \<in> ?R"
  1617       with not_less_empty show "b \<in> ?W" by contradiction
  1618     qed
  1619 
  1620     fix M a assume "M \<in> ?W"
  1621     from \<open>wf r\<close> have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1622     proof induct
  1623       fix a
  1624       assume r: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1625       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1626       proof
  1627         fix M assume "M \<in> ?W"
  1628         then show "M + {#a#} \<in> ?W"
  1629           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1630       qed
  1631     qed
  1632     from this and \<open>M \<in> ?W\<close> show "M + {#a#} \<in> ?W" ..
  1633   qed
  1634 qed
  1635 
  1636 theorem wf_mult1: "wf r \<Longrightarrow> wf (mult1 r)"
  1637 by (rule acc_wfI) (rule all_accessible)
  1638 
  1639 theorem wf_mult: "wf r \<Longrightarrow> wf (mult r)"
  1640 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1641 
  1642 
  1643 subsubsection \<open>Closure-free presentation\<close>
  1644 
  1645 text \<open>One direction.\<close>
  1646 
  1647 lemma mult_implies_one_step:
  1648   "trans r \<Longrightarrow> (M, N) \<in> mult r \<Longrightarrow>
  1649     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1650     (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)"
  1651 apply (unfold mult_def mult1_def set_mset_def)
  1652 apply (erule converse_trancl_induct, clarify)
  1653  apply (rule_tac x = M0 in exI, simp, clarify)
  1654 apply (case_tac "a \<in># K")
  1655  apply (rule_tac x = I in exI)
  1656  apply (simp (no_asm))
  1657  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1658  apply (simp (no_asm_simp) add: add.assoc [symmetric])
  1659  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong)
  1660  apply (simp add: diff_union_single_conv)
  1661  apply (simp (no_asm_use) add: trans_def)
  1662  apply blast
  1663 apply (subgoal_tac "a \<in># I")
  1664  apply (rule_tac x = "I - {#a#}" in exI)
  1665  apply (rule_tac x = "J + {#a#}" in exI)
  1666  apply (rule_tac x = "K + Ka" in exI)
  1667  apply (rule conjI)
  1668   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1669  apply (rule conjI)
  1670   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong, simp)
  1671   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1672  apply (simp (no_asm_use) add: trans_def)
  1673  apply blast
  1674 apply (subgoal_tac "a \<in># (M0 + {#a#})")
  1675  apply simp
  1676 apply (simp (no_asm))
  1677 done
  1678 
  1679 lemma one_step_implies_mult_aux:
  1680   "\<forall>I J K. size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)
  1681     \<longrightarrow> (I + K, I + J) \<in> mult r"
  1682 apply (induct n)
  1683  apply auto
  1684 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1685 apply (rename_tac "J'", simp)
  1686 apply (erule notE, auto)
  1687 apply (case_tac "J' = {#}")
  1688  apply (simp add: mult_def)
  1689  apply (rule r_into_trancl)
  1690  apply (simp add: mult1_def set_mset_def, blast)
  1691 txt \<open>Now we know @{term "J' \<noteq> {#}"}.\<close>
  1692 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1693 apply (erule_tac P = "\<forall>k \<in> set_mset K. P k" for P in rev_mp)
  1694 apply (erule ssubst)
  1695 apply (simp add: Ball_def, auto)
  1696 apply (subgoal_tac
  1697   "((I + {# x \<in># K. (x, a) \<in> r #}) + {# x \<in># K. (x, a) \<notin> r #},
  1698     (I + {# x \<in># K. (x, a) \<in> r #}) + J') \<in> mult r")
  1699  prefer 2
  1700  apply force
  1701 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
  1702 apply (erule trancl_trans)
  1703 apply (rule r_into_trancl)
  1704 apply (simp add: mult1_def set_mset_def)
  1705 apply (rule_tac x = a in exI)
  1706 apply (rule_tac x = "I + J'" in exI)
  1707 apply (simp add: ac_simps)
  1708 done
  1709 
  1710 lemma one_step_implies_mult:
  1711   "trans r \<Longrightarrow> J \<noteq> {#} \<Longrightarrow> \<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r
  1712     \<Longrightarrow> (I + K, I + J) \<in> mult r"
  1713 using one_step_implies_mult_aux by blast
  1714 
  1715 
  1716 subsubsection \<open>Partial-order properties\<close>
  1717 
  1718 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<#" 50) where
  1719   "M' #<# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1720 
  1721 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<=#" 50) where
  1722   "M' #<=# M \<longleftrightarrow> M' #<# M \<or> M' = M"
  1723 
  1724 notation (xsymbols) less_multiset (infix "#\<subset>#" 50)
  1725 notation (xsymbols) le_multiset (infix "#\<subseteq>#" 50)
  1726 
  1727 interpretation multiset_order: order le_multiset less_multiset
  1728 proof -
  1729   have irrefl: "\<not> M #\<subset># M" for M :: "'a multiset"
  1730   proof
  1731     assume "M #\<subset># M"
  1732     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1733     have "trans {(x'::'a, x). x' < x}"
  1734       by (rule transI) simp
  1735     moreover note MM
  1736     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1737       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
  1738       by (rule mult_implies_one_step)
  1739     then obtain I J K where "M = I + J" and "M = I + K"
  1740       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
  1741     then have *: "K \<noteq> {#}" and **: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
  1742     have "finite (set_mset K)" by simp
  1743     moreover note **
  1744     ultimately have "set_mset K = {}"
  1745       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1746     with * show False by simp
  1747   qed
  1748   have trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># N" for K M N :: "'a multiset"
  1749     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1750   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1751     by standard (auto simp add: le_multiset_def irrefl dest: trans)
  1752 qed
  1753 
  1754 lemma mult_less_irrefl [elim!]:
  1755   fixes M :: "'a::order multiset"
  1756   shows "M #\<subset># M \<Longrightarrow> R"
  1757   by simp
  1758 
  1759 
  1760 subsubsection \<open>Monotonicity of multiset union\<close>
  1761 
  1762 lemma mult1_union: "(B, D) \<in> mult1 r \<Longrightarrow> (C + B, C + D) \<in> mult1 r"
  1763 apply (unfold mult1_def)
  1764 apply auto
  1765 apply (rule_tac x = a in exI)
  1766 apply (rule_tac x = "C + M0" in exI)
  1767 apply (simp add: add.assoc)
  1768 done
  1769 
  1770 lemma union_less_mono2: "B #\<subset># D \<Longrightarrow> C + B #\<subset># C + (D::'a::order multiset)"
  1771 apply (unfold less_multiset_def mult_def)
  1772 apply (erule trancl_induct)
  1773  apply (blast intro: mult1_union)
  1774 apply (blast intro: mult1_union trancl_trans)
  1775 done
  1776 
  1777 lemma union_less_mono1: "B #\<subset># D \<Longrightarrow> B + C #\<subset># D + (C::'a::order multiset)"
  1778 apply (subst add.commute [of B C])
  1779 apply (subst add.commute [of D C])
  1780 apply (erule union_less_mono2)
  1781 done
  1782 
  1783 lemma union_less_mono:
  1784   fixes A B C D :: "'a::order multiset"
  1785   shows "A #\<subset># C \<Longrightarrow> B #\<subset># D \<Longrightarrow> A + B #\<subset># C + D"
  1786   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1787 
  1788 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1789   by standard (auto simp add: le_multiset_def intro: union_less_mono2)
  1790 
  1791 
  1792 subsubsection \<open>Termination proofs with multiset orders\<close>
  1793 
  1794 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1795   and multi_member_this: "x \<in># {# x #} + XS"
  1796   and multi_member_last: "x \<in># {# x #}"
  1797   by auto
  1798 
  1799 definition "ms_strict = mult pair_less"
  1800 definition "ms_weak = ms_strict \<union> Id"
  1801 
  1802 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1803 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1804 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1805 
  1806 lemma smsI:
  1807   "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1808   unfolding ms_strict_def
  1809 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1810 
  1811 lemma wmsI:
  1812   "(set_mset A, set_mset B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1813   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1814 unfolding ms_weak_def ms_strict_def
  1815 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1816 
  1817 inductive pw_leq
  1818 where
  1819   pw_leq_empty: "pw_leq {#} {#}"
  1820 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1821 
  1822 lemma pw_leq_lstep:
  1823   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1824 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1825 
  1826 lemma pw_leq_split:
  1827   assumes "pw_leq X Y"
  1828   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1829   using assms
  1830 proof induct
  1831   case pw_leq_empty thus ?case by auto
  1832 next
  1833   case (pw_leq_step x y X Y)
  1834   then obtain A B Z where
  1835     [simp]: "X = A + Z" "Y = B + Z"
  1836       and 1[simp]: "(set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  1837     by auto
  1838   from pw_leq_step consider "x = y" | "(x, y) \<in> pair_less"
  1839     unfolding pair_leq_def by auto
  1840   thus ?case
  1841   proof cases
  1842     case [simp]: 1
  1843     have "{#x#} + X = A + ({#y#}+Z) \<and> {#y#} + Y = B + ({#y#}+Z) \<and>
  1844       ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1845       by (auto simp: ac_simps)
  1846     thus ?thesis by blast
  1847   next
  1848     case 2
  1849     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1850     have "{#x#} + X = ?A' + Z"
  1851       "{#y#} + Y = ?B' + Z"
  1852       by (auto simp add: ac_simps)
  1853     moreover have
  1854       "(set_mset ?A', set_mset ?B') \<in> max_strict"
  1855       using 1 2 unfolding max_strict_def
  1856       by (auto elim!: max_ext.cases)
  1857     ultimately show ?thesis by blast
  1858   qed
  1859 qed
  1860 
  1861 lemma
  1862   assumes pwleq: "pw_leq Z Z'"
  1863   shows ms_strictI: "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1864     and ms_weakI1:  "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1865     and ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1866 proof -
  1867   from pw_leq_split[OF pwleq]
  1868   obtain A' B' Z''
  1869     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1870     and mx_or_empty: "(set_mset A', set_mset B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1871     by blast
  1872   {
  1873     assume max: "(set_mset A, set_mset B) \<in> max_strict"
  1874     from mx_or_empty
  1875     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1876     proof
  1877       assume max': "(set_mset A', set_mset B') \<in> max_strict"
  1878       with max have "(set_mset (A + A'), set_mset (B + B')) \<in> max_strict"
  1879         by (auto simp: max_strict_def intro: max_ext_additive)
  1880       thus ?thesis by (rule smsI)
  1881     next
  1882       assume [simp]: "A' = {#} \<and> B' = {#}"
  1883       show ?thesis by (rule smsI) (auto intro: max)
  1884     qed
  1885     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add: ac_simps)
  1886     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1887   }
  1888   from mx_or_empty
  1889   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1890   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
  1891 qed
  1892 
  1893 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1894 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1895 and nonempty_single: "{# x #} \<noteq> {#}"
  1896 by auto
  1897 
  1898 setup \<open>
  1899   let
  1900     fun msetT T = Type (@{type_name multiset}, [T]);
  1901 
  1902     fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1903       | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1904       | mk_mset T (x :: xs) =
  1905             Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1906                   mk_mset T [x] $ mk_mset T xs
  1907 
  1908     fun mset_member_tac ctxt m i =
  1909       if m <= 0 then
  1910         resolve_tac ctxt @{thms multi_member_this} i ORELSE
  1911         resolve_tac ctxt @{thms multi_member_last} i
  1912       else
  1913         resolve_tac ctxt @{thms multi_member_skip} i THEN mset_member_tac ctxt (m - 1) i
  1914 
  1915     fun mset_nonempty_tac ctxt =
  1916       resolve_tac ctxt @{thms nonempty_plus} ORELSE'
  1917       resolve_tac ctxt @{thms nonempty_single}
  1918 
  1919     fun regroup_munion_conv ctxt =
  1920       Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  1921         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  1922 
  1923     fun unfold_pwleq_tac ctxt i =
  1924       (resolve_tac ctxt @{thms pw_leq_step} i THEN (fn st => unfold_pwleq_tac ctxt (i + 1) st))
  1925         ORELSE (resolve_tac ctxt @{thms pw_leq_lstep} i)
  1926         ORELSE (resolve_tac ctxt @{thms pw_leq_empty} i)
  1927 
  1928     val set_mset_simps = [@{thm set_mset_empty}, @{thm set_mset_single}, @{thm set_mset_union},
  1929                         @{thm Un_insert_left}, @{thm Un_empty_left}]
  1930   in
  1931     ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  1932     {
  1933       msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1934       mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1935       mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_mset_simps,
  1936       smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1937       reduction_pair = @{thm ms_reduction_pair}
  1938     })
  1939   end
  1940 \<close>
  1941 
  1942 
  1943 subsection \<open>Legacy theorem bindings\<close>
  1944 
  1945 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1946 
  1947 lemma union_commute: "M + N = N + (M::'a multiset)"
  1948   by (fact add.commute)
  1949 
  1950 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1951   by (fact add.assoc)
  1952 
  1953 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1954   by (fact add.left_commute)
  1955 
  1956 lemmas union_ac = union_assoc union_commute union_lcomm
  1957 
  1958 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1959   by (fact add_right_cancel)
  1960 
  1961 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1962   by (fact add_left_cancel)
  1963 
  1964 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1965   by (fact add_left_imp_eq)
  1966 
  1967 lemma mset_less_trans: "(M::'a multiset) <# K \<Longrightarrow> K <# N \<Longrightarrow> M <# N"
  1968   by (fact subset_mset.less_trans)
  1969 
  1970 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1971   by (fact subset_mset.inf.commute)
  1972 
  1973 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1974   by (fact subset_mset.inf.assoc [symmetric])
  1975 
  1976 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1977   by (fact subset_mset.inf.left_commute)
  1978 
  1979 lemmas multiset_inter_ac =
  1980   multiset_inter_commute
  1981   multiset_inter_assoc
  1982   multiset_inter_left_commute
  1983 
  1984 lemma mult_less_not_refl: "\<not> M #\<subset># (M::'a::order multiset)"
  1985   by (fact multiset_order.less_irrefl)
  1986 
  1987 lemma mult_less_trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># (N::'a::order multiset)"
  1988   by (fact multiset_order.less_trans)
  1989 
  1990 lemma mult_less_not_sym: "M #\<subset># N \<Longrightarrow> \<not> N #\<subset># (M::'a::order multiset)"
  1991   by (fact multiset_order.less_not_sym)
  1992 
  1993 lemma mult_less_asym: "M #\<subset># N \<Longrightarrow> (\<not> P \<Longrightarrow> N #\<subset># (M::'a::order multiset)) \<Longrightarrow> P"
  1994   by (fact multiset_order.less_asym)
  1995 
  1996 declaration \<open>
  1997   let
  1998     fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T])) (Const _ $ t') =
  1999           let
  2000             val (maybe_opt, ps) =
  2001               Nitpick_Model.dest_plain_fun t'
  2002               ||> op ~~
  2003               ||> map (apsnd (snd o HOLogic.dest_number))
  2004             fun elems_for t =
  2005               (case AList.lookup (op =) ps t of
  2006                 SOME n => replicate n t
  2007               | NONE => [Const (maybe_name, elem_T --> elem_T) $ t])
  2008           in
  2009             (case maps elems_for (all_values elem_T) @
  2010                  (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)] else []) of
  2011               [] => Const (@{const_name zero_class.zero}, T)
  2012             | ts =>
  2013                 foldl1 (fn (t1, t2) =>
  2014                     Const (@{const_name plus_class.plus}, T --> T --> T) $ t1 $ t2)
  2015                   (map (curry (op $) (Const (@{const_name single}, elem_T --> T))) ts))
  2016           end
  2017       | multiset_postproc _ _ _ _ t = t
  2018   in Nitpick_Model.register_term_postprocessor @{typ "'a multiset"} multiset_postproc end
  2019 \<close>
  2020 
  2021 
  2022 subsection \<open>Naive implementation using lists\<close>
  2023 
  2024 code_datatype mset
  2025 
  2026 lemma [code]: "{#} = mset []"
  2027   by simp
  2028 
  2029 lemma [code]: "{#x#} = mset [x]"
  2030   by simp
  2031 
  2032 lemma union_code [code]: "mset xs + mset ys = mset (xs @ ys)"
  2033   by simp
  2034 
  2035 lemma [code]: "image_mset f (mset xs) = mset (map f xs)"
  2036   by (simp add: mset_map)
  2037 
  2038 lemma [code]: "filter_mset f (mset xs) = mset (filter f xs)"
  2039   by (simp add: mset_filter)
  2040 
  2041 lemma [code]: "mset xs - mset ys = mset (fold remove1 ys xs)"
  2042   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2043 
  2044 lemma [code]:
  2045   "mset xs #\<inter> mset ys =
  2046     mset (snd (fold (\<lambda>x (ys, zs).
  2047       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2048 proof -
  2049   have "\<And>zs. mset (snd (fold (\<lambda>x (ys, zs).
  2050     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2051       (mset xs #\<inter> mset ys) + mset zs"
  2052     by (induct xs arbitrary: ys)
  2053       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2054   then show ?thesis by simp
  2055 qed
  2056 
  2057 lemma [code]:
  2058   "mset xs #\<union> mset ys =
  2059     mset (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2060 proof -
  2061   have "\<And>zs. mset (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2062       (mset xs #\<union> mset ys) + mset zs"
  2063     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2064   then show ?thesis by simp
  2065 qed
  2066 
  2067 declare in_multiset_in_set [code_unfold]
  2068 
  2069 lemma [code]: "count (mset xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2070 proof -
  2071   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (mset xs) x + n"
  2072     by (induct xs) simp_all
  2073   then show ?thesis by simp
  2074 qed
  2075 
  2076 declare set_mset_mset [code]
  2077 
  2078 declare sorted_list_of_multiset_mset [code]
  2079 
  2080 lemma [code]: -- \<open>not very efficient, but representation-ignorant!\<close>
  2081   "mset_set A = mset (sorted_list_of_set A)"
  2082   apply (cases "finite A")
  2083   apply simp_all
  2084   apply (induct A rule: finite_induct)
  2085   apply (simp_all add: add.commute)
  2086   done
  2087 
  2088 declare size_mset [code]
  2089 
  2090 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  2091   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2092 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  2093      None \<Rightarrow> None
  2094    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2095 
  2096 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> mset xs \<le># mset ys) \<and>
  2097   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> mset xs <# mset ys) \<and>
  2098   (ms_lesseq_impl xs ys = Some False \<longrightarrow> mset xs = mset ys)"
  2099 proof (induct xs arbitrary: ys)
  2100   case (Nil ys)
  2101   show ?case by (auto simp: mset_less_empty_nonempty)
  2102 next
  2103   case (Cons x xs ys)
  2104   show ?case
  2105   proof (cases "List.extract (op = x) ys")
  2106     case None
  2107     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2108     {
  2109       assume "mset (x # xs) \<le># mset ys"
  2110       from set_mset_mono[OF this] x have False by simp
  2111     } note nle = this
  2112     moreover
  2113     {
  2114       assume "mset (x # xs) <# mset ys"
  2115       hence "mset (x # xs) \<le># mset ys" by auto
  2116       from nle[OF this] have False .
  2117     }
  2118     ultimately show ?thesis using None by auto
  2119   next
  2120     case (Some res)
  2121     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2122     note Some = Some[unfolded res]
  2123     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2124     hence id: "mset ys = mset (ys1 @ ys2) + {#x#}"
  2125       by (auto simp: ac_simps)
  2126     show ?thesis unfolding ms_lesseq_impl.simps
  2127       unfolding Some option.simps split
  2128       unfolding id
  2129       using Cons[of "ys1 @ ys2"]
  2130       unfolding subset_mset_def subseteq_mset_def by auto
  2131   qed
  2132 qed
  2133 
  2134 lemma [code]: "mset xs \<le># mset ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2135   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2136 
  2137 lemma [code]: "mset xs <# mset ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2138   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2139 
  2140 instantiation multiset :: (equal) equal
  2141 begin
  2142 
  2143 definition
  2144   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2145 lemma [code]: "HOL.equal (mset xs) (mset ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2146   unfolding equal_multiset_def
  2147   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2148 
  2149 instance
  2150   by standard (simp add: equal_multiset_def)
  2151 
  2152 end
  2153 
  2154 lemma [code]: "msetsum (mset xs) = listsum xs"
  2155   by (induct xs) (simp_all add: add.commute)
  2156 
  2157 lemma [code]: "msetprod (mset xs) = fold times xs 1"
  2158 proof -
  2159   have "\<And>x. fold times xs x = msetprod (mset xs) * x"
  2160     by (induct xs) (simp_all add: mult.assoc)
  2161   then show ?thesis by simp
  2162 qed
  2163 
  2164 text \<open>
  2165   Exercise for the casual reader: add implementations for @{const le_multiset}
  2166   and @{const less_multiset} (multiset order).
  2167 \<close>
  2168 
  2169 text \<open>Quickcheck generators\<close>
  2170 
  2171 definition (in term_syntax)
  2172   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2173     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2174   [code_unfold]: "msetify xs = Code_Evaluation.valtermify mset {\<cdot>} xs"
  2175 
  2176 notation fcomp (infixl "\<circ>>" 60)
  2177 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2178 
  2179 instantiation multiset :: (random) random
  2180 begin
  2181 
  2182 definition
  2183   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2184 
  2185 instance ..
  2186 
  2187 end
  2188 
  2189 no_notation fcomp (infixl "\<circ>>" 60)
  2190 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2191 
  2192 instantiation multiset :: (full_exhaustive) full_exhaustive
  2193 begin
  2194 
  2195 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2196 where
  2197   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2198 
  2199 instance ..
  2200 
  2201 end
  2202 
  2203 hide_const (open) msetify
  2204 
  2205 
  2206 subsection \<open>BNF setup\<close>
  2207 
  2208 definition rel_mset where
  2209   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. mset xs = X \<and> mset ys = Y \<and> list_all2 R xs ys)"
  2210 
  2211 lemma mset_zip_take_Cons_drop_twice:
  2212   assumes "length xs = length ys" "j \<le> length xs"
  2213   shows "mset (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  2214     mset (zip xs ys) + {#(x, y)#}"
  2215   using assms
  2216 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  2217   case Nil
  2218   thus ?case
  2219     by simp
  2220 next
  2221   case (Cons x xs y ys)
  2222   thus ?case
  2223   proof (cases "j = 0")
  2224     case True
  2225     thus ?thesis
  2226       by simp
  2227   next
  2228     case False
  2229     then obtain k where k: "j = Suc k"
  2230       by (cases j) simp
  2231     hence "k \<le> length xs"
  2232       using Cons.prems by auto
  2233     hence "mset (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  2234       mset (zip xs ys) + {#(x, y)#}"
  2235       by (rule Cons.hyps(2))
  2236     thus ?thesis
  2237       unfolding k by (auto simp: add.commute union_lcomm)
  2238   qed
  2239 qed
  2240 
  2241 lemma ex_mset_zip_left:
  2242   assumes "length xs = length ys" "mset xs' = mset xs"
  2243   shows "\<exists>ys'. length ys' = length xs' \<and> mset (zip xs' ys') = mset (zip xs ys)"
  2244 using assms
  2245 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  2246   case Nil
  2247   thus ?case
  2248     by auto
  2249 next
  2250   case (Cons x xs y ys xs')
  2251   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  2252     by (metis Cons.prems in_set_conv_nth list.set_intros(1) mset_eq_setD)
  2253 
  2254   def xsa \<equiv> "take j xs' @ drop (Suc j) xs'"
  2255   have "mset xs' = {#x#} + mset xsa"
  2256     unfolding xsa_def using j_len nth_j
  2257     by (metis (no_types) ab_semigroup_add_class.add_ac(1) append_take_drop_id Cons_nth_drop_Suc
  2258       mset.simps(2) union_code add.commute)
  2259   hence ms_x: "mset xsa = mset xs"
  2260     by (metis Cons.prems add.commute add_right_imp_eq mset.simps(2))
  2261   then obtain ysa where
  2262     len_a: "length ysa = length xsa" and ms_a: "mset (zip xsa ysa) = mset (zip xs ys)"
  2263     using Cons.hyps(2) by blast
  2264 
  2265   def ys' \<equiv> "take j ysa @ y # drop j ysa"
  2266   have xs': "xs' = take j xsa @ x # drop j xsa"
  2267     using ms_x j_len nth_j Cons.prems xsa_def
  2268     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  2269       length_drop size_mset)
  2270   have j_len': "j \<le> length xsa"
  2271     using j_len xs' xsa_def
  2272     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  2273   have "length ys' = length xs'"
  2274     unfolding ys'_def using Cons.prems len_a ms_x
  2275     by (metis add_Suc_right append_take_drop_id length_Cons length_append mset_eq_length)
  2276   moreover have "mset (zip xs' ys') = mset (zip (x # xs) (y # ys))"
  2277     unfolding xs' ys'_def
  2278     by (rule trans[OF mset_zip_take_Cons_drop_twice])
  2279       (auto simp: len_a ms_a j_len' add.commute)
  2280   ultimately show ?case
  2281     by blast
  2282 qed
  2283 
  2284 lemma list_all2_reorder_left_invariance:
  2285   assumes rel: "list_all2 R xs ys" and ms_x: "mset xs' = mset xs"
  2286   shows "\<exists>ys'. list_all2 R xs' ys' \<and> mset ys' = mset ys"
  2287 proof -
  2288   have len: "length xs = length ys"
  2289     using rel list_all2_conv_all_nth by auto
  2290   obtain ys' where
  2291     len': "length xs' = length ys'" and ms_xy: "mset (zip xs' ys') = mset (zip xs ys)"
  2292     using len ms_x by (metis ex_mset_zip_left)
  2293   have "list_all2 R xs' ys'"
  2294     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: mset_eq_setD)
  2295   moreover have "mset ys' = mset ys"
  2296     using len len' ms_xy map_snd_zip mset_map by metis
  2297   ultimately show ?thesis
  2298     by blast
  2299 qed
  2300 
  2301 lemma ex_mset: "\<exists>xs. mset xs = X"
  2302   by (induct X) (simp, metis mset.simps(2))
  2303 
  2304 bnf "'a multiset"
  2305   map: image_mset
  2306   sets: set_mset
  2307   bd: natLeq
  2308   wits: "{#}"
  2309   rel: rel_mset
  2310 proof -
  2311   show "image_mset id = id"
  2312     by (rule image_mset.id)
  2313   show "image_mset (g \<circ> f) = image_mset g \<circ> image_mset f" for f g
  2314     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  2315   show "(\<And>z. z \<in> set_mset X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X" for f g X
  2316     by (induct X) (simp_all (no_asm),
  2317       metis One_nat_def Un_iff count_single mem_set_mset_iff set_mset_union zero_less_Suc)
  2318   show "set_mset \<circ> image_mset f = op ` f \<circ> set_mset" for f
  2319     by auto
  2320   show "card_order natLeq"
  2321     by (rule natLeq_card_order)
  2322   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  2323     by (rule natLeq_cinfinite)
  2324   show "ordLeq3 (card_of (set_mset X)) natLeq" for X
  2325     by transfer
  2326       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2327   show "rel_mset R OO rel_mset S \<le> rel_mset (R OO S)" for R S
  2328     unfolding rel_mset_def[abs_def] OO_def
  2329     apply clarify
  2330     subgoal for X Z Y xs ys' ys zs
  2331       apply (drule list_all2_reorder_left_invariance [where xs = ys' and ys = zs and xs' = ys])
  2332       apply (auto intro: list_all2_trans)
  2333       done
  2334     done
  2335   show "rel_mset R =
  2336     (BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset fst))\<inverse>\<inverse> OO
  2337     BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset snd)" for R
  2338     unfolding rel_mset_def[abs_def] BNF_Def.Grp_def OO_def
  2339     apply (rule ext)+
  2340     apply auto
  2341      apply (rule_tac x = "mset (zip xs ys)" in exI; auto)
  2342         apply (metis list_all2_lengthD map_fst_zip mset_map)
  2343        apply (auto simp: list_all2_iff)[1]
  2344       apply (metis list_all2_lengthD map_snd_zip mset_map)
  2345      apply (auto simp: list_all2_iff)[1]
  2346     apply (rename_tac XY)
  2347     apply (cut_tac X = XY in ex_mset)
  2348     apply (erule exE)
  2349     apply (rename_tac xys)
  2350     apply (rule_tac x = "map fst xys" in exI)
  2351     apply (auto simp: mset_map)
  2352     apply (rule_tac x = "map snd xys" in exI)
  2353     apply (auto simp: mset_map list_all2I subset_eq zip_map_fst_snd)
  2354     done
  2355   show "z \<in> set_mset {#} \<Longrightarrow> False" for z
  2356     by auto
  2357 qed
  2358 
  2359 inductive rel_mset'
  2360 where
  2361   Zero[intro]: "rel_mset' R {#} {#}"
  2362 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (M + {#a#}) (N + {#b#})"
  2363 
  2364 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  2365 unfolding rel_mset_def Grp_def by auto
  2366 
  2367 declare multiset.count[simp]
  2368 declare Abs_multiset_inverse[simp]
  2369 declare multiset.count_inverse[simp]
  2370 declare union_preserves_multiset[simp]
  2371 
  2372 lemma rel_mset_Plus:
  2373   assumes ab: "R a b"
  2374     and MN: "rel_mset R M N"
  2375   shows "rel_mset R (M + {#a#}) (N + {#b#})"
  2376 proof -
  2377   have "\<exists>ya. image_mset fst y + {#a#} = image_mset fst ya \<and>
  2378     image_mset snd y + {#b#} = image_mset snd ya \<and>
  2379     set_mset ya \<subseteq> {(x, y). R x y}"
  2380     if "R a b" and "set_mset y \<subseteq> {(x, y). R x y}" for y
  2381     using that by (intro exI[of _ "y + {#(a,b)#}"]) auto
  2382   thus ?thesis
  2383   using assms
  2384   unfolding multiset.rel_compp_Grp Grp_def by blast
  2385 qed
  2386 
  2387 lemma rel_mset'_imp_rel_mset: "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  2388   by (induct rule: rel_mset'.induct) (auto simp: rel_mset_Zero rel_mset_Plus)
  2389 
  2390 lemma rel_mset_size: "rel_mset R M N \<Longrightarrow> size M = size N"
  2391   unfolding multiset.rel_compp_Grp Grp_def by auto
  2392 
  2393 lemma multiset_induct2[case_names empty addL addR]:
  2394   assumes empty: "P {#} {#}"
  2395     and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2396     and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2397   shows "P M N"
  2398 apply(induct N rule: multiset_induct)
  2399   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2400   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2401 done
  2402 
  2403 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  2404   assumes c: "size M = size N"
  2405     and empty: "P {#} {#}"
  2406     and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2407   shows "P M N"
  2408   using c
  2409 proof (induct M arbitrary: N rule: measure_induct_rule[of size])
  2410   case (less M)
  2411   show ?case
  2412   proof(cases "M = {#}")
  2413     case True hence "N = {#}" using less.prems by auto
  2414     thus ?thesis using True empty by auto
  2415   next
  2416     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2417     have "N \<noteq> {#}" using False less.prems by auto
  2418     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2419     have "size M1 = size N1" using less.prems unfolding M N by auto
  2420     thus ?thesis using M N less.hyps add by auto
  2421   qed
  2422 qed
  2423 
  2424 lemma msed_map_invL:
  2425   assumes "image_mset f (M + {#a#}) = N"
  2426   shows "\<exists>N1. N = N1 + {#f a#} \<and> image_mset f M = N1"
  2427 proof -
  2428   have "f a \<in># N"
  2429     using assms multiset.set_map[of f "M + {#a#}"] by auto
  2430   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2431   have "image_mset f M = N1" using assms unfolding N by simp
  2432   thus ?thesis using N by blast
  2433 qed
  2434 
  2435 lemma msed_map_invR:
  2436   assumes "image_mset f M = N + {#b#}"
  2437   shows "\<exists>M1 a. M = M1 + {#a#} \<and> f a = b \<and> image_mset f M1 = N"
  2438 proof -
  2439   obtain a where a: "a \<in># M" and fa: "f a = b"
  2440     using multiset.set_map[of f M] unfolding assms
  2441     by (metis image_iff mem_set_mset_iff union_single_eq_member)
  2442   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2443   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  2444   thus ?thesis using M fa by blast
  2445 qed
  2446 
  2447 lemma msed_rel_invL:
  2448   assumes "rel_mset R (M + {#a#}) N"
  2449   shows "\<exists>N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_mset R M N1"
  2450 proof -
  2451   obtain K where KM: "image_mset fst K = M + {#a#}"
  2452     and KN: "image_mset snd K = N" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2453     using assms
  2454     unfolding multiset.rel_compp_Grp Grp_def by auto
  2455   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2456     and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  2457   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "image_mset snd K1 = N1"
  2458     using msed_map_invL[OF KN[unfolded K]] by auto
  2459   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2460   have "rel_mset R M N1" using sK K1M K1N1
  2461     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2462   thus ?thesis using N Rab by auto
  2463 qed
  2464 
  2465 lemma msed_rel_invR:
  2466   assumes "rel_mset R M (N + {#b#})"
  2467   shows "\<exists>M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_mset R M1 N"
  2468 proof -
  2469   obtain K where KN: "image_mset snd K = N + {#b#}"
  2470     and KM: "image_mset fst K = M" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2471     using assms
  2472     unfolding multiset.rel_compp_Grp Grp_def by auto
  2473   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2474     and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  2475   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "image_mset fst K1 = M1"
  2476     using msed_map_invL[OF KM[unfolded K]] by auto
  2477   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2478   have "rel_mset R M1 N" using sK K1N K1M1
  2479     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2480   thus ?thesis using M Rab by auto
  2481 qed
  2482 
  2483 lemma rel_mset_imp_rel_mset':
  2484   assumes "rel_mset R M N"
  2485   shows "rel_mset' R M N"
  2486 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  2487   case (less M)
  2488   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  2489   show ?case
  2490   proof(cases "M = {#}")
  2491     case True hence "N = {#}" using c by simp
  2492     thus ?thesis using True rel_mset'.Zero by auto
  2493   next
  2494     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2495     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_mset R M1 N1"
  2496       using msed_rel_invL[OF less.prems[unfolded M]] by auto
  2497     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  2498     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  2499   qed
  2500 qed
  2501 
  2502 lemma rel_mset_rel_mset': "rel_mset R M N = rel_mset' R M N"
  2503   using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  2504 
  2505 text \<open>The main end product for @{const rel_mset}: inductive characterization:\<close>
  2506 theorems rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  2507   rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  2508 
  2509 
  2510 subsection \<open>Size setup\<close>
  2511 
  2512 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  2513   apply (rule ext)
  2514   subgoal for x by (induct x) auto
  2515   done
  2516 
  2517 setup \<open>
  2518   BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  2519     @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  2520       size_union}
  2521     @{thms multiset_size_o_map}
  2522 \<close>
  2523 
  2524 hide_const (open) wcount
  2525 
  2526 end