src/HOL/Rings.thy
author haftmann
Fri Jun 19 07:53:33 2015 +0200 (2015-06-19)
changeset 60516 0826b7025d07
parent 60429 d3d1e185cd63
child 60517 f16e4fb20652
permissions -rw-r--r--
generalized some theorems about integral domains and moved to HOL theories
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps) 
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196   
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   241   + zero_neq_one + comm_monoid_mult
   242 begin
   243 
   244 subclass semiring_1_cancel ..
   245 subclass comm_semiring_0_cancel ..
   246 subclass comm_semiring_1 ..
   247 
   248 end
   249 
   250 class comm_semiring_1_diff_distrib = comm_semiring_1_cancel +
   251   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   252 begin
   253 
   254 lemma left_diff_distrib' [algebra_simps]:
   255   "(b - c) * a = b * a - c * a"
   256   by (simp add: algebra_simps)
   257 
   258 lemma dvd_add_times_triv_left_iff [simp]:
   259   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   260 proof -
   261   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   262   proof
   263     assume ?Q then show ?P by simp
   264   next
   265     assume ?P
   266     then obtain d where "a * c + b = a * d" ..
   267     then have "a * c + b - a * c = a * d - a * c" by simp
   268     then have "b = a * d - a * c" by simp
   269     then have "b = a * (d - c)" by (simp add: algebra_simps) 
   270     then show ?Q ..
   271   qed
   272   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   273 qed
   274 
   275 lemma dvd_add_times_triv_right_iff [simp]:
   276   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   277   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   278 
   279 lemma dvd_add_triv_left_iff [simp]:
   280   "a dvd a + b \<longleftrightarrow> a dvd b"
   281   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   282 
   283 lemma dvd_add_triv_right_iff [simp]:
   284   "a dvd b + a \<longleftrightarrow> a dvd b"
   285   using dvd_add_times_triv_right_iff [of a b 1] by simp
   286 
   287 lemma dvd_add_right_iff:
   288   assumes "a dvd b"
   289   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   290 proof
   291   assume ?P then obtain d where "b + c = a * d" ..
   292   moreover from `a dvd b` obtain e where "b = a * e" ..
   293   ultimately have "a * e + c = a * d" by simp
   294   then have "a * e + c - a * e = a * d - a * e" by simp
   295   then have "c = a * d - a * e" by simp
   296   then have "c = a * (d - e)" by (simp add: algebra_simps)
   297   then show ?Q ..
   298 next
   299   assume ?Q with assms show ?P by simp
   300 qed
   301 
   302 lemma dvd_add_left_iff:
   303   assumes "a dvd c"
   304   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   305   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   306 
   307 end
   308 
   309 class ring = semiring + ab_group_add
   310 begin
   311 
   312 subclass semiring_0_cancel ..
   313 
   314 text {* Distribution rules *}
   315 
   316 lemma minus_mult_left: "- (a * b) = - a * b"
   317 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   318 
   319 lemma minus_mult_right: "- (a * b) = a * - b"
   320 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   321 
   322 text{*Extract signs from products*}
   323 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   324 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   325 
   326 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   327 by simp
   328 
   329 lemma minus_mult_commute: "- a * b = a * - b"
   330 by simp
   331 
   332 lemma right_diff_distrib [algebra_simps]:
   333   "a * (b - c) = a * b - a * c"
   334   using distrib_left [of a b "-c "] by simp
   335 
   336 lemma left_diff_distrib [algebra_simps]:
   337   "(a - b) * c = a * c - b * c"
   338   using distrib_right [of a "- b" c] by simp
   339 
   340 lemmas ring_distribs =
   341   distrib_left distrib_right left_diff_distrib right_diff_distrib
   342 
   343 lemma eq_add_iff1:
   344   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   345 by (simp add: algebra_simps)
   346 
   347 lemma eq_add_iff2:
   348   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   349 by (simp add: algebra_simps)
   350 
   351 end
   352 
   353 lemmas ring_distribs =
   354   distrib_left distrib_right left_diff_distrib right_diff_distrib
   355 
   356 class comm_ring = comm_semiring + ab_group_add
   357 begin
   358 
   359 subclass ring ..
   360 subclass comm_semiring_0_cancel ..
   361 
   362 lemma square_diff_square_factored:
   363   "x * x - y * y = (x + y) * (x - y)"
   364   by (simp add: algebra_simps)
   365 
   366 end
   367 
   368 class ring_1 = ring + zero_neq_one + monoid_mult
   369 begin
   370 
   371 subclass semiring_1_cancel ..
   372 
   373 lemma square_diff_one_factored:
   374   "x * x - 1 = (x + 1) * (x - 1)"
   375   by (simp add: algebra_simps)
   376 
   377 end
   378 
   379 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   380 begin
   381 
   382 subclass ring_1 ..
   383 subclass comm_semiring_1_cancel ..
   384 
   385 subclass comm_semiring_1_diff_distrib
   386   by unfold_locales (simp add: algebra_simps)
   387 
   388 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   389 proof
   390   assume "x dvd - y"
   391   then have "x dvd - 1 * - y" by (rule dvd_mult)
   392   then show "x dvd y" by simp
   393 next
   394   assume "x dvd y"
   395   then have "x dvd - 1 * y" by (rule dvd_mult)
   396   then show "x dvd - y" by simp
   397 qed
   398 
   399 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   400 proof
   401   assume "- x dvd y"
   402   then obtain k where "y = - x * k" ..
   403   then have "y = x * - k" by simp
   404   then show "x dvd y" ..
   405 next
   406   assume "x dvd y"
   407   then obtain k where "y = x * k" ..
   408   then have "y = - x * - k" by simp
   409   then show "- x dvd y" ..
   410 qed
   411 
   412 lemma dvd_diff [simp]:
   413   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   414   using dvd_add [of x y "- z"] by simp
   415 
   416 end
   417 
   418 class semiring_no_zero_divisors = semiring_0 +
   419   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   420 begin
   421 
   422 lemma divisors_zero:
   423   assumes "a * b = 0"
   424   shows "a = 0 \<or> b = 0"
   425 proof (rule classical)
   426   assume "\<not> (a = 0 \<or> b = 0)"
   427   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   428   with no_zero_divisors have "a * b \<noteq> 0" by blast
   429   with assms show ?thesis by simp
   430 qed
   431 
   432 lemma mult_eq_0_iff [simp]:
   433   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   434 proof (cases "a = 0 \<or> b = 0")
   435   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   436     then show ?thesis using no_zero_divisors by simp
   437 next
   438   case True then show ?thesis by auto
   439 qed
   440 
   441 end
   442 
   443 class semiring_no_zero_divisors_cancel = semiring_no_zero_divisors +
   444   assumes mult_cancel_right [simp]: "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   445     and mult_cancel_left [simp]: "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   446 begin
   447 
   448 lemma mult_left_cancel:
   449   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   450   by simp 
   451 
   452 lemma mult_right_cancel:
   453   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   454   by simp 
   455 
   456 end
   457 
   458 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   459 begin
   460 
   461 subclass semiring_no_zero_divisors_cancel
   462 proof
   463   fix a b c
   464   have "a * c = b * c \<longleftrightarrow> (a - b) * c = 0"
   465     by (simp add: algebra_simps)
   466   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   467     by auto
   468   finally show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b" .
   469   have "c * a = c * b \<longleftrightarrow> c * (a - b) = 0"
   470     by (simp add: algebra_simps)
   471   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   472     by auto
   473   finally show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b" .
   474 qed
   475 
   476 end
   477 
   478 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   479 begin
   480 
   481 lemma square_eq_1_iff:
   482   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   483 proof -
   484   have "(x - 1) * (x + 1) = x * x - 1"
   485     by (simp add: algebra_simps)
   486   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   487     by simp
   488   thus ?thesis
   489     by (simp add: eq_neg_iff_add_eq_0)
   490 qed
   491 
   492 lemma mult_cancel_right1 [simp]:
   493   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   494 by (insert mult_cancel_right [of 1 c b], force)
   495 
   496 lemma mult_cancel_right2 [simp]:
   497   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   498 by (insert mult_cancel_right [of a c 1], simp)
   499  
   500 lemma mult_cancel_left1 [simp]:
   501   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   502 by (insert mult_cancel_left [of c 1 b], force)
   503 
   504 lemma mult_cancel_left2 [simp]:
   505   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   506 by (insert mult_cancel_left [of c a 1], simp)
   507 
   508 end
   509 
   510 class semidom = comm_semiring_1_diff_distrib + semiring_no_zero_divisors
   511 
   512 class idom = comm_ring_1 + semiring_no_zero_divisors
   513 begin
   514 
   515 subclass semidom ..
   516 
   517 subclass ring_1_no_zero_divisors ..
   518 
   519 lemma dvd_mult_cancel_right [simp]:
   520   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   521 proof -
   522   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   523     unfolding dvd_def by (simp add: ac_simps)
   524   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   525     unfolding dvd_def by simp
   526   finally show ?thesis .
   527 qed
   528 
   529 lemma dvd_mult_cancel_left [simp]:
   530   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   531 proof -
   532   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   533     unfolding dvd_def by (simp add: ac_simps)
   534   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   535     unfolding dvd_def by simp
   536   finally show ?thesis .
   537 qed
   538 
   539 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> a = b \<or> a = - b"
   540 proof
   541   assume "a * a = b * b"
   542   then have "(a - b) * (a + b) = 0"
   543     by (simp add: algebra_simps)
   544   then show "a = b \<or> a = - b"
   545     by (simp add: eq_neg_iff_add_eq_0)
   546 next
   547   assume "a = b \<or> a = - b"
   548   then show "a * a = b * b" by auto
   549 qed
   550 
   551 end
   552 
   553 text {*
   554   The theory of partially ordered rings is taken from the books:
   555   \begin{itemize}
   556   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   557   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   558   \end{itemize}
   559   Most of the used notions can also be looked up in 
   560   \begin{itemize}
   561   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   562   \item \emph{Algebra I} by van der Waerden, Springer.
   563   \end{itemize}
   564 *}
   565 
   566 class divide =
   567   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "div" 70)
   568 
   569 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   570 
   571 context semiring
   572 begin
   573 
   574 lemma [field_simps]:
   575   shows distrib_left_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b + c) = a * b + a * c"
   576     and distrib_right_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a + b) * c = a * c + b * c"
   577   by (rule distrib_left distrib_right)+
   578 
   579 end
   580 
   581 context ring
   582 begin
   583 
   584 lemma [field_simps]:
   585   shows left_diff_distrib_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a - b) * c = a * c - b * c"
   586     and right_diff_distrib_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b - c) = a * b - a * c"
   587   by (rule left_diff_distrib right_diff_distrib)+
   588 
   589 end
   590 
   591 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a::divide \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   592 
   593 class semidom_divide = semidom + divide +
   594   assumes nonzero_mult_divide_cancel_right [simp]: "b \<noteq> 0 \<Longrightarrow> (a * b) div b = a"
   595   assumes divide_zero [simp]: "a div 0 = 0"
   596 begin
   597 
   598 lemma nonzero_mult_divide_cancel_left [simp]:
   599   "a \<noteq> 0 \<Longrightarrow> (a * b) div a = b"
   600   using nonzero_mult_divide_cancel_right [of a b] by (simp add: ac_simps)
   601 
   602 subclass semiring_no_zero_divisors_cancel
   603 proof
   604   fix a b c
   605   { fix a b c
   606     show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   607     proof (cases "c = 0")
   608       case True then show ?thesis by simp
   609     next
   610       case False
   611       { assume "a * c = b * c"
   612         then have "a * c div c = b * c div c"
   613           by simp
   614         with False have "a = b"
   615           by simp
   616       } then show ?thesis by auto
   617     qed
   618   }
   619   from this [of a c b]
   620   show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   621     by (simp add: ac_simps)
   622 qed
   623 
   624 lemma div_self [simp]:
   625   assumes "a \<noteq> 0"
   626   shows "a div a = 1"
   627   using assms nonzero_mult_divide_cancel_left [of a 1] by simp
   628 
   629 end
   630 
   631 class idom_divide = idom + semidom_divide
   632 
   633 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   634   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   635   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   636 begin
   637 
   638 lemma mult_mono:
   639   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   640 apply (erule mult_right_mono [THEN order_trans], assumption)
   641 apply (erule mult_left_mono, assumption)
   642 done
   643 
   644 lemma mult_mono':
   645   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   646 apply (rule mult_mono)
   647 apply (fast intro: order_trans)+
   648 done
   649 
   650 end
   651 
   652 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   653 begin
   654 
   655 subclass semiring_0_cancel ..
   656 
   657 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   658 using mult_left_mono [of 0 b a] by simp
   659 
   660 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   661 using mult_left_mono [of b 0 a] by simp
   662 
   663 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   664 using mult_right_mono [of a 0 b] by simp
   665 
   666 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   667 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   668 by (drule mult_right_mono [of b 0], auto)
   669 
   670 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   671 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   672 
   673 end
   674 
   675 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   676 begin
   677 
   678 subclass ordered_cancel_semiring ..
   679 
   680 subclass ordered_comm_monoid_add ..
   681 
   682 lemma mult_left_less_imp_less:
   683   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   684 by (force simp add: mult_left_mono not_le [symmetric])
   685  
   686 lemma mult_right_less_imp_less:
   687   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   688 by (force simp add: mult_right_mono not_le [symmetric])
   689 
   690 end
   691 
   692 class linordered_semiring_1 = linordered_semiring + semiring_1
   693 begin
   694 
   695 lemma convex_bound_le:
   696   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   697   shows "u * x + v * y \<le> a"
   698 proof-
   699   from assms have "u * x + v * y \<le> u * a + v * a"
   700     by (simp add: add_mono mult_left_mono)
   701   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   702 qed
   703 
   704 end
   705 
   706 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   707   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   708   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   709 begin
   710 
   711 subclass semiring_0_cancel ..
   712 
   713 subclass linordered_semiring
   714 proof
   715   fix a b c :: 'a
   716   assume A: "a \<le> b" "0 \<le> c"
   717   from A show "c * a \<le> c * b"
   718     unfolding le_less
   719     using mult_strict_left_mono by (cases "c = 0") auto
   720   from A show "a * c \<le> b * c"
   721     unfolding le_less
   722     using mult_strict_right_mono by (cases "c = 0") auto
   723 qed
   724 
   725 lemma mult_left_le_imp_le:
   726   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   727 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   728  
   729 lemma mult_right_le_imp_le:
   730   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   731 by (force simp add: mult_strict_right_mono not_less [symmetric])
   732 
   733 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   734 using mult_strict_left_mono [of 0 b a] by simp
   735 
   736 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   737 using mult_strict_left_mono [of b 0 a] by simp
   738 
   739 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   740 using mult_strict_right_mono [of a 0 b] by simp
   741 
   742 text {* Legacy - use @{text mult_neg_pos} *}
   743 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   744 by (drule mult_strict_right_mono [of b 0], auto)
   745 
   746 lemma zero_less_mult_pos:
   747   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   748 apply (cases "b\<le>0")
   749  apply (auto simp add: le_less not_less)
   750 apply (drule_tac mult_pos_neg [of a b])
   751  apply (auto dest: less_not_sym)
   752 done
   753 
   754 lemma zero_less_mult_pos2:
   755   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   756 apply (cases "b\<le>0")
   757  apply (auto simp add: le_less not_less)
   758 apply (drule_tac mult_pos_neg2 [of a b])
   759  apply (auto dest: less_not_sym)
   760 done
   761 
   762 text{*Strict monotonicity in both arguments*}
   763 lemma mult_strict_mono:
   764   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   765   shows "a * c < b * d"
   766   using assms apply (cases "c=0")
   767   apply (simp)
   768   apply (erule mult_strict_right_mono [THEN less_trans])
   769   apply (force simp add: le_less)
   770   apply (erule mult_strict_left_mono, assumption)
   771   done
   772 
   773 text{*This weaker variant has more natural premises*}
   774 lemma mult_strict_mono':
   775   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   776   shows "a * c < b * d"
   777 by (rule mult_strict_mono) (insert assms, auto)
   778 
   779 lemma mult_less_le_imp_less:
   780   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   781   shows "a * c < b * d"
   782   using assms apply (subgoal_tac "a * c < b * c")
   783   apply (erule less_le_trans)
   784   apply (erule mult_left_mono)
   785   apply simp
   786   apply (erule mult_strict_right_mono)
   787   apply assumption
   788   done
   789 
   790 lemma mult_le_less_imp_less:
   791   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   792   shows "a * c < b * d"
   793   using assms apply (subgoal_tac "a * c \<le> b * c")
   794   apply (erule le_less_trans)
   795   apply (erule mult_strict_left_mono)
   796   apply simp
   797   apply (erule mult_right_mono)
   798   apply simp
   799   done
   800 
   801 end
   802 
   803 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   804 begin
   805 
   806 subclass linordered_semiring_1 ..
   807 
   808 lemma convex_bound_lt:
   809   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   810   shows "u * x + v * y < a"
   811 proof -
   812   from assms have "u * x + v * y < u * a + v * a"
   813     by (cases "u = 0")
   814        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   815   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   816 qed
   817 
   818 end
   819 
   820 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   821   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   822 begin
   823 
   824 subclass ordered_semiring
   825 proof
   826   fix a b c :: 'a
   827   assume "a \<le> b" "0 \<le> c"
   828   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   829   thus "a * c \<le> b * c" by (simp only: mult.commute)
   830 qed
   831 
   832 end
   833 
   834 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   835 begin
   836 
   837 subclass comm_semiring_0_cancel ..
   838 subclass ordered_comm_semiring ..
   839 subclass ordered_cancel_semiring ..
   840 
   841 end
   842 
   843 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   844   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   845 begin
   846 
   847 subclass linordered_semiring_strict
   848 proof
   849   fix a b c :: 'a
   850   assume "a < b" "0 < c"
   851   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   852   thus "a * c < b * c" by (simp only: mult.commute)
   853 qed
   854 
   855 subclass ordered_cancel_comm_semiring
   856 proof
   857   fix a b c :: 'a
   858   assume "a \<le> b" "0 \<le> c"
   859   thus "c * a \<le> c * b"
   860     unfolding le_less
   861     using mult_strict_left_mono by (cases "c = 0") auto
   862 qed
   863 
   864 end
   865 
   866 class ordered_ring = ring + ordered_cancel_semiring 
   867 begin
   868 
   869 subclass ordered_ab_group_add ..
   870 
   871 lemma less_add_iff1:
   872   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   873 by (simp add: algebra_simps)
   874 
   875 lemma less_add_iff2:
   876   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   877 by (simp add: algebra_simps)
   878 
   879 lemma le_add_iff1:
   880   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   881 by (simp add: algebra_simps)
   882 
   883 lemma le_add_iff2:
   884   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   885 by (simp add: algebra_simps)
   886 
   887 lemma mult_left_mono_neg:
   888   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   889   apply (drule mult_left_mono [of _ _ "- c"])
   890   apply simp_all
   891   done
   892 
   893 lemma mult_right_mono_neg:
   894   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   895   apply (drule mult_right_mono [of _ _ "- c"])
   896   apply simp_all
   897   done
   898 
   899 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   900 using mult_right_mono_neg [of a 0 b] by simp
   901 
   902 lemma split_mult_pos_le:
   903   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   904 by (auto simp add: mult_nonpos_nonpos)
   905 
   906 end
   907 
   908 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   909 begin
   910 
   911 subclass ordered_ring ..
   912 
   913 subclass ordered_ab_group_add_abs
   914 proof
   915   fix a b
   916   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   917     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   918 qed (auto simp add: abs_if)
   919 
   920 lemma zero_le_square [simp]: "0 \<le> a * a"
   921   using linear [of 0 a]
   922   by (auto simp add: mult_nonpos_nonpos)
   923 
   924 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   925   by (simp add: not_less)
   926 
   927 end
   928 
   929 class linordered_ring_strict = ring + linordered_semiring_strict
   930   + ordered_ab_group_add + abs_if
   931 begin
   932 
   933 subclass linordered_ring ..
   934 
   935 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   936 using mult_strict_left_mono [of b a "- c"] by simp
   937 
   938 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   939 using mult_strict_right_mono [of b a "- c"] by simp
   940 
   941 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   942 using mult_strict_right_mono_neg [of a 0 b] by simp
   943 
   944 subclass ring_no_zero_divisors
   945 proof
   946   fix a b
   947   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   948   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   949   have "a * b < 0 \<or> 0 < a * b"
   950   proof (cases "a < 0")
   951     case True note A' = this
   952     show ?thesis proof (cases "b < 0")
   953       case True with A'
   954       show ?thesis by (auto dest: mult_neg_neg)
   955     next
   956       case False with B have "0 < b" by auto
   957       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   958     qed
   959   next
   960     case False with A have A': "0 < a" by auto
   961     show ?thesis proof (cases "b < 0")
   962       case True with A'
   963       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   964     next
   965       case False with B have "0 < b" by auto
   966       with A' show ?thesis by auto
   967     qed
   968   qed
   969   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   970 qed
   971 
   972 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   973   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   974      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   975 
   976 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   977   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   978 
   979 lemma mult_less_0_iff:
   980   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   981   apply (insert zero_less_mult_iff [of "-a" b])
   982   apply force
   983   done
   984 
   985 lemma mult_le_0_iff:
   986   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   987   apply (insert zero_le_mult_iff [of "-a" b]) 
   988   apply force
   989   done
   990 
   991 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   992    also with the relations @{text "\<le>"} and equality.*}
   993 
   994 text{*These ``disjunction'' versions produce two cases when the comparison is
   995  an assumption, but effectively four when the comparison is a goal.*}
   996 
   997 lemma mult_less_cancel_right_disj:
   998   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   999   apply (cases "c = 0")
  1000   apply (auto simp add: neq_iff mult_strict_right_mono 
  1001                       mult_strict_right_mono_neg)
  1002   apply (auto simp add: not_less 
  1003                       not_le [symmetric, of "a*c"]
  1004                       not_le [symmetric, of a])
  1005   apply (erule_tac [!] notE)
  1006   apply (auto simp add: less_imp_le mult_right_mono 
  1007                       mult_right_mono_neg)
  1008   done
  1009 
  1010 lemma mult_less_cancel_left_disj:
  1011   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1012   apply (cases "c = 0")
  1013   apply (auto simp add: neq_iff mult_strict_left_mono 
  1014                       mult_strict_left_mono_neg)
  1015   apply (auto simp add: not_less 
  1016                       not_le [symmetric, of "c*a"]
  1017                       not_le [symmetric, of a])
  1018   apply (erule_tac [!] notE)
  1019   apply (auto simp add: less_imp_le mult_left_mono 
  1020                       mult_left_mono_neg)
  1021   done
  1022 
  1023 text{*The ``conjunction of implication'' lemmas produce two cases when the
  1024 comparison is a goal, but give four when the comparison is an assumption.*}
  1025 
  1026 lemma mult_less_cancel_right:
  1027   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1028   using mult_less_cancel_right_disj [of a c b] by auto
  1029 
  1030 lemma mult_less_cancel_left:
  1031   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1032   using mult_less_cancel_left_disj [of c a b] by auto
  1033 
  1034 lemma mult_le_cancel_right:
  1035    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1036 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
  1037 
  1038 lemma mult_le_cancel_left:
  1039   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1040 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
  1041 
  1042 lemma mult_le_cancel_left_pos:
  1043   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
  1044 by (auto simp: mult_le_cancel_left)
  1045 
  1046 lemma mult_le_cancel_left_neg:
  1047   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
  1048 by (auto simp: mult_le_cancel_left)
  1049 
  1050 lemma mult_less_cancel_left_pos:
  1051   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
  1052 by (auto simp: mult_less_cancel_left)
  1053 
  1054 lemma mult_less_cancel_left_neg:
  1055   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
  1056 by (auto simp: mult_less_cancel_left)
  1057 
  1058 end
  1059 
  1060 lemmas mult_sign_intros =
  1061   mult_nonneg_nonneg mult_nonneg_nonpos
  1062   mult_nonpos_nonneg mult_nonpos_nonpos
  1063   mult_pos_pos mult_pos_neg
  1064   mult_neg_pos mult_neg_neg
  1065 
  1066 class ordered_comm_ring = comm_ring + ordered_comm_semiring
  1067 begin
  1068 
  1069 subclass ordered_ring ..
  1070 subclass ordered_cancel_comm_semiring ..
  1071 
  1072 end
  1073 
  1074 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1075   assumes zero_less_one [simp]: "0 < 1"
  1076 begin
  1077 
  1078 lemma pos_add_strict:
  1079   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1080   using add_strict_mono [of 0 a b c] by simp
  1081 
  1082 lemma zero_le_one [simp]: "0 \<le> 1"
  1083 by (rule zero_less_one [THEN less_imp_le]) 
  1084 
  1085 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1086 by (simp add: not_le) 
  1087 
  1088 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1089 by (simp add: not_less) 
  1090 
  1091 lemma less_1_mult:
  1092   assumes "1 < m" and "1 < n"
  1093   shows "1 < m * n"
  1094   using assms mult_strict_mono [of 1 m 1 n]
  1095     by (simp add:  less_trans [OF zero_less_one]) 
  1096 
  1097 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1098   using mult_left_mono[of c 1 a] by simp
  1099 
  1100 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1101   using mult_mono[of a 1 b 1] by simp
  1102 
  1103 end
  1104 
  1105 class linordered_idom = comm_ring_1 +
  1106   linordered_comm_semiring_strict + ordered_ab_group_add +
  1107   abs_if + sgn_if
  1108 begin
  1109 
  1110 subclass linordered_semiring_1_strict ..
  1111 subclass linordered_ring_strict ..
  1112 subclass ordered_comm_ring ..
  1113 subclass idom ..
  1114 
  1115 subclass linordered_semidom
  1116 proof
  1117   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1118   thus "0 < 1" by (simp add: le_less)
  1119 qed 
  1120 
  1121 lemma linorder_neqE_linordered_idom:
  1122   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1123   using assms by (rule neqE)
  1124 
  1125 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1126 
  1127 lemma mult_le_cancel_right1:
  1128   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1129 by (insert mult_le_cancel_right [of 1 c b], simp)
  1130 
  1131 lemma mult_le_cancel_right2:
  1132   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1133 by (insert mult_le_cancel_right [of a c 1], simp)
  1134 
  1135 lemma mult_le_cancel_left1:
  1136   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1137 by (insert mult_le_cancel_left [of c 1 b], simp)
  1138 
  1139 lemma mult_le_cancel_left2:
  1140   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1141 by (insert mult_le_cancel_left [of c a 1], simp)
  1142 
  1143 lemma mult_less_cancel_right1:
  1144   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1145 by (insert mult_less_cancel_right [of 1 c b], simp)
  1146 
  1147 lemma mult_less_cancel_right2:
  1148   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1149 by (insert mult_less_cancel_right [of a c 1], simp)
  1150 
  1151 lemma mult_less_cancel_left1:
  1152   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1153 by (insert mult_less_cancel_left [of c 1 b], simp)
  1154 
  1155 lemma mult_less_cancel_left2:
  1156   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1157 by (insert mult_less_cancel_left [of c a 1], simp)
  1158 
  1159 lemma sgn_sgn [simp]:
  1160   "sgn (sgn a) = sgn a"
  1161 unfolding sgn_if by simp
  1162 
  1163 lemma sgn_0_0:
  1164   "sgn a = 0 \<longleftrightarrow> a = 0"
  1165 unfolding sgn_if by simp
  1166 
  1167 lemma sgn_1_pos:
  1168   "sgn a = 1 \<longleftrightarrow> a > 0"
  1169 unfolding sgn_if by simp
  1170 
  1171 lemma sgn_1_neg:
  1172   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1173 unfolding sgn_if by auto
  1174 
  1175 lemma sgn_pos [simp]:
  1176   "0 < a \<Longrightarrow> sgn a = 1"
  1177 unfolding sgn_1_pos .
  1178 
  1179 lemma sgn_neg [simp]:
  1180   "a < 0 \<Longrightarrow> sgn a = - 1"
  1181 unfolding sgn_1_neg .
  1182 
  1183 lemma sgn_times:
  1184   "sgn (a * b) = sgn a * sgn b"
  1185 by (auto simp add: sgn_if zero_less_mult_iff)
  1186 
  1187 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1188 unfolding sgn_if abs_if by auto
  1189 
  1190 lemma sgn_greater [simp]:
  1191   "0 < sgn a \<longleftrightarrow> 0 < a"
  1192   unfolding sgn_if by auto
  1193 
  1194 lemma sgn_less [simp]:
  1195   "sgn a < 0 \<longleftrightarrow> a < 0"
  1196   unfolding sgn_if by auto
  1197 
  1198 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1199   by (simp add: abs_if)
  1200 
  1201 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1202   by (simp add: abs_if)
  1203 
  1204 lemma dvd_if_abs_eq:
  1205   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1206 by(subst abs_dvd_iff[symmetric]) simp
  1207 
  1208 text {* The following lemmas can be proven in more general structures, but
  1209 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1210 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1211 
  1212 lemma equation_minus_iff_1 [simp, no_atp]:
  1213   "1 = - a \<longleftrightarrow> a = - 1"
  1214   by (fact equation_minus_iff)
  1215 
  1216 lemma minus_equation_iff_1 [simp, no_atp]:
  1217   "- a = 1 \<longleftrightarrow> a = - 1"
  1218   by (subst minus_equation_iff, auto)
  1219 
  1220 lemma le_minus_iff_1 [simp, no_atp]:
  1221   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1222   by (fact le_minus_iff)
  1223 
  1224 lemma minus_le_iff_1 [simp, no_atp]:
  1225   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1226   by (fact minus_le_iff)
  1227 
  1228 lemma less_minus_iff_1 [simp, no_atp]:
  1229   "1 < - b \<longleftrightarrow> b < - 1"
  1230   by (fact less_minus_iff)
  1231 
  1232 lemma minus_less_iff_1 [simp, no_atp]:
  1233   "- a < 1 \<longleftrightarrow> - 1 < a"
  1234   by (fact minus_less_iff)
  1235 
  1236 end
  1237 
  1238 text {* Simprules for comparisons where common factors can be cancelled. *}
  1239 
  1240 lemmas mult_compare_simps =
  1241     mult_le_cancel_right mult_le_cancel_left
  1242     mult_le_cancel_right1 mult_le_cancel_right2
  1243     mult_le_cancel_left1 mult_le_cancel_left2
  1244     mult_less_cancel_right mult_less_cancel_left
  1245     mult_less_cancel_right1 mult_less_cancel_right2
  1246     mult_less_cancel_left1 mult_less_cancel_left2
  1247     mult_cancel_right mult_cancel_left
  1248     mult_cancel_right1 mult_cancel_right2
  1249     mult_cancel_left1 mult_cancel_left2
  1250 
  1251 text {* Reasoning about inequalities with division *}
  1252 
  1253 context linordered_semidom
  1254 begin
  1255 
  1256 lemma less_add_one: "a < a + 1"
  1257 proof -
  1258   have "a + 0 < a + 1"
  1259     by (blast intro: zero_less_one add_strict_left_mono)
  1260   thus ?thesis by simp
  1261 qed
  1262 
  1263 lemma zero_less_two: "0 < 1 + 1"
  1264 by (blast intro: less_trans zero_less_one less_add_one)
  1265 
  1266 end
  1267 
  1268 context linordered_idom
  1269 begin
  1270 
  1271 lemma mult_right_le_one_le:
  1272   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1273   by (rule mult_left_le)
  1274 
  1275 lemma mult_left_le_one_le:
  1276   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1277   by (auto simp add: mult_le_cancel_right2)
  1278 
  1279 end
  1280 
  1281 text {* Absolute Value *}
  1282 
  1283 context linordered_idom
  1284 begin
  1285 
  1286 lemma mult_sgn_abs:
  1287   "sgn x * \<bar>x\<bar> = x"
  1288   unfolding abs_if sgn_if by auto
  1289 
  1290 lemma abs_one [simp]:
  1291   "\<bar>1\<bar> = 1"
  1292   by (simp add: abs_if)
  1293 
  1294 end
  1295 
  1296 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1297   assumes abs_eq_mult:
  1298     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1299 
  1300 context linordered_idom
  1301 begin
  1302 
  1303 subclass ordered_ring_abs proof
  1304 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1305 
  1306 lemma abs_mult:
  1307   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1308   by (rule abs_eq_mult) auto
  1309 
  1310 lemma abs_mult_self:
  1311   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1312   by (simp add: abs_if) 
  1313 
  1314 lemma abs_mult_less:
  1315   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1316 proof -
  1317   assume ac: "\<bar>a\<bar> < c"
  1318   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1319   assume "\<bar>b\<bar> < d"
  1320   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1321 qed
  1322 
  1323 lemma abs_less_iff:
  1324   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1325   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1326 
  1327 lemma abs_mult_pos:
  1328   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1329   by (simp add: abs_mult)
  1330 
  1331 lemma abs_diff_less_iff:
  1332   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1333   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1334 
  1335 lemma abs_diff_le_iff:
  1336    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1337   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1338 
  1339 end
  1340 
  1341 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1342 
  1343 code_identifier
  1344   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1345 
  1346 end