src/HOL/Library/Polynomial.thy
author haftmann
Fri Mar 27 10:05:11 2009 +0100 (2009-03-27)
changeset 30738 0842e906300c
parent 30273 ecd6f0ca62ea
child 30930 11010e5f18f0
permissions -rw-r--r--
normalized imports
     1 (*  Title:      HOL/Polynomial.thy
     2     Author:     Brian Huffman
     3                 Based on an earlier development by Clemens Ballarin
     4 *)
     5 
     6 header {* Univariate Polynomials *}
     7 
     8 theory Polynomial
     9 imports Main
    10 begin
    11 
    12 subsection {* Definition of type @{text poly} *}
    13 
    14 typedef (Poly) 'a poly = "{f::nat \<Rightarrow> 'a::zero. \<exists>n. \<forall>i>n. f i = 0}"
    15   morphisms coeff Abs_poly
    16   by auto
    17 
    18 lemma expand_poly_eq: "p = q \<longleftrightarrow> (\<forall>n. coeff p n = coeff q n)"
    19 by (simp add: coeff_inject [symmetric] expand_fun_eq)
    20 
    21 lemma poly_ext: "(\<And>n. coeff p n = coeff q n) \<Longrightarrow> p = q"
    22 by (simp add: expand_poly_eq)
    23 
    24 
    25 subsection {* Degree of a polynomial *}
    26 
    27 definition
    28   degree :: "'a::zero poly \<Rightarrow> nat" where
    29   "degree p = (LEAST n. \<forall>i>n. coeff p i = 0)"
    30 
    31 lemma coeff_eq_0: "degree p < n \<Longrightarrow> coeff p n = 0"
    32 proof -
    33   have "coeff p \<in> Poly"
    34     by (rule coeff)
    35   hence "\<exists>n. \<forall>i>n. coeff p i = 0"
    36     unfolding Poly_def by simp
    37   hence "\<forall>i>degree p. coeff p i = 0"
    38     unfolding degree_def by (rule LeastI_ex)
    39   moreover assume "degree p < n"
    40   ultimately show ?thesis by simp
    41 qed
    42 
    43 lemma le_degree: "coeff p n \<noteq> 0 \<Longrightarrow> n \<le> degree p"
    44   by (erule contrapos_np, rule coeff_eq_0, simp)
    45 
    46 lemma degree_le: "\<forall>i>n. coeff p i = 0 \<Longrightarrow> degree p \<le> n"
    47   unfolding degree_def by (erule Least_le)
    48 
    49 lemma less_degree_imp: "n < degree p \<Longrightarrow> \<exists>i>n. coeff p i \<noteq> 0"
    50   unfolding degree_def by (drule not_less_Least, simp)
    51 
    52 
    53 subsection {* The zero polynomial *}
    54 
    55 instantiation poly :: (zero) zero
    56 begin
    57 
    58 definition
    59   zero_poly_def: "0 = Abs_poly (\<lambda>n. 0)"
    60 
    61 instance ..
    62 end
    63 
    64 lemma coeff_0 [simp]: "coeff 0 n = 0"
    65   unfolding zero_poly_def
    66   by (simp add: Abs_poly_inverse Poly_def)
    67 
    68 lemma degree_0 [simp]: "degree 0 = 0"
    69   by (rule order_antisym [OF degree_le le0]) simp
    70 
    71 lemma leading_coeff_neq_0:
    72   assumes "p \<noteq> 0" shows "coeff p (degree p) \<noteq> 0"
    73 proof (cases "degree p")
    74   case 0
    75   from `p \<noteq> 0` have "\<exists>n. coeff p n \<noteq> 0"
    76     by (simp add: expand_poly_eq)
    77   then obtain n where "coeff p n \<noteq> 0" ..
    78   hence "n \<le> degree p" by (rule le_degree)
    79   with `coeff p n \<noteq> 0` and `degree p = 0`
    80   show "coeff p (degree p) \<noteq> 0" by simp
    81 next
    82   case (Suc n)
    83   from `degree p = Suc n` have "n < degree p" by simp
    84   hence "\<exists>i>n. coeff p i \<noteq> 0" by (rule less_degree_imp)
    85   then obtain i where "n < i" and "coeff p i \<noteq> 0" by fast
    86   from `degree p = Suc n` and `n < i` have "degree p \<le> i" by simp
    87   also from `coeff p i \<noteq> 0` have "i \<le> degree p" by (rule le_degree)
    88   finally have "degree p = i" .
    89   with `coeff p i \<noteq> 0` show "coeff p (degree p) \<noteq> 0" by simp
    90 qed
    91 
    92 lemma leading_coeff_0_iff [simp]: "coeff p (degree p) = 0 \<longleftrightarrow> p = 0"
    93   by (cases "p = 0", simp, simp add: leading_coeff_neq_0)
    94 
    95 
    96 subsection {* List-style constructor for polynomials *}
    97 
    98 definition
    99   pCons :: "'a::zero \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   100 where
   101   [code del]: "pCons a p = Abs_poly (nat_case a (coeff p))"
   102 
   103 syntax
   104   "_poly" :: "args \<Rightarrow> 'a poly"  ("[:(_):]")
   105 
   106 translations
   107   "[:x, xs:]" == "CONST pCons x [:xs:]"
   108   "[:x:]" == "CONST pCons x 0"
   109   "[:x:]" <= "CONST pCons x (_constrain 0 t)"
   110 
   111 lemma Poly_nat_case: "f \<in> Poly \<Longrightarrow> nat_case a f \<in> Poly"
   112   unfolding Poly_def by (auto split: nat.split)
   113 
   114 lemma coeff_pCons:
   115   "coeff (pCons a p) = nat_case a (coeff p)"
   116   unfolding pCons_def
   117   by (simp add: Abs_poly_inverse Poly_nat_case coeff)
   118 
   119 lemma coeff_pCons_0 [simp]: "coeff (pCons a p) 0 = a"
   120   by (simp add: coeff_pCons)
   121 
   122 lemma coeff_pCons_Suc [simp]: "coeff (pCons a p) (Suc n) = coeff p n"
   123   by (simp add: coeff_pCons)
   124 
   125 lemma degree_pCons_le: "degree (pCons a p) \<le> Suc (degree p)"
   126 by (rule degree_le, simp add: coeff_eq_0 coeff_pCons split: nat.split)
   127 
   128 lemma degree_pCons_eq:
   129   "p \<noteq> 0 \<Longrightarrow> degree (pCons a p) = Suc (degree p)"
   130 apply (rule order_antisym [OF degree_pCons_le])
   131 apply (rule le_degree, simp)
   132 done
   133 
   134 lemma degree_pCons_0: "degree (pCons a 0) = 0"
   135 apply (rule order_antisym [OF _ le0])
   136 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   137 done
   138 
   139 lemma degree_pCons_eq_if [simp]:
   140   "degree (pCons a p) = (if p = 0 then 0 else Suc (degree p))"
   141 apply (cases "p = 0", simp_all)
   142 apply (rule order_antisym [OF _ le0])
   143 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   144 apply (rule order_antisym [OF degree_pCons_le])
   145 apply (rule le_degree, simp)
   146 done
   147 
   148 lemma pCons_0_0 [simp]: "pCons 0 0 = 0"
   149 by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   150 
   151 lemma pCons_eq_iff [simp]:
   152   "pCons a p = pCons b q \<longleftrightarrow> a = b \<and> p = q"
   153 proof (safe)
   154   assume "pCons a p = pCons b q"
   155   then have "coeff (pCons a p) 0 = coeff (pCons b q) 0" by simp
   156   then show "a = b" by simp
   157 next
   158   assume "pCons a p = pCons b q"
   159   then have "\<forall>n. coeff (pCons a p) (Suc n) =
   160                  coeff (pCons b q) (Suc n)" by simp
   161   then show "p = q" by (simp add: expand_poly_eq)
   162 qed
   163 
   164 lemma pCons_eq_0_iff [simp]: "pCons a p = 0 \<longleftrightarrow> a = 0 \<and> p = 0"
   165   using pCons_eq_iff [of a p 0 0] by simp
   166 
   167 lemma Poly_Suc: "f \<in> Poly \<Longrightarrow> (\<lambda>n. f (Suc n)) \<in> Poly"
   168   unfolding Poly_def
   169   by (clarify, rule_tac x=n in exI, simp)
   170 
   171 lemma pCons_cases [cases type: poly]:
   172   obtains (pCons) a q where "p = pCons a q"
   173 proof
   174   show "p = pCons (coeff p 0) (Abs_poly (\<lambda>n. coeff p (Suc n)))"
   175     by (rule poly_ext)
   176        (simp add: Abs_poly_inverse Poly_Suc coeff coeff_pCons
   177              split: nat.split)
   178 qed
   179 
   180 lemma pCons_induct [case_names 0 pCons, induct type: poly]:
   181   assumes zero: "P 0"
   182   assumes pCons: "\<And>a p. P p \<Longrightarrow> P (pCons a p)"
   183   shows "P p"
   184 proof (induct p rule: measure_induct_rule [where f=degree])
   185   case (less p)
   186   obtain a q where "p = pCons a q" by (rule pCons_cases)
   187   have "P q"
   188   proof (cases "q = 0")
   189     case True
   190     then show "P q" by (simp add: zero)
   191   next
   192     case False
   193     then have "degree (pCons a q) = Suc (degree q)"
   194       by (rule degree_pCons_eq)
   195     then have "degree q < degree p"
   196       using `p = pCons a q` by simp
   197     then show "P q"
   198       by (rule less.hyps)
   199   qed
   200   then have "P (pCons a q)"
   201     by (rule pCons)
   202   then show ?case
   203     using `p = pCons a q` by simp
   204 qed
   205 
   206 
   207 subsection {* Recursion combinator for polynomials *}
   208 
   209 function
   210   poly_rec :: "'b \<Rightarrow> ('a::zero \<Rightarrow> 'a poly \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a poly \<Rightarrow> 'b"
   211 where
   212   poly_rec_pCons_eq_if [simp del, code del]:
   213     "poly_rec z f (pCons a p) = f a p (if p = 0 then z else poly_rec z f p)"
   214 by (case_tac x, rename_tac q, case_tac q, auto)
   215 
   216 termination poly_rec
   217 by (relation "measure (degree \<circ> snd \<circ> snd)", simp)
   218    (simp add: degree_pCons_eq)
   219 
   220 lemma poly_rec_0:
   221   "f 0 0 z = z \<Longrightarrow> poly_rec z f 0 = z"
   222   using poly_rec_pCons_eq_if [of z f 0 0] by simp
   223 
   224 lemma poly_rec_pCons:
   225   "f 0 0 z = z \<Longrightarrow> poly_rec z f (pCons a p) = f a p (poly_rec z f p)"
   226   by (simp add: poly_rec_pCons_eq_if poly_rec_0)
   227 
   228 
   229 subsection {* Monomials *}
   230 
   231 definition
   232   monom :: "'a \<Rightarrow> nat \<Rightarrow> 'a::zero poly" where
   233   "monom a m = Abs_poly (\<lambda>n. if m = n then a else 0)"
   234 
   235 lemma coeff_monom [simp]: "coeff (monom a m) n = (if m=n then a else 0)"
   236   unfolding monom_def
   237   by (subst Abs_poly_inverse, auto simp add: Poly_def)
   238 
   239 lemma monom_0: "monom a 0 = pCons a 0"
   240   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   241 
   242 lemma monom_Suc: "monom a (Suc n) = pCons 0 (monom a n)"
   243   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   244 
   245 lemma monom_eq_0 [simp]: "monom 0 n = 0"
   246   by (rule poly_ext) simp
   247 
   248 lemma monom_eq_0_iff [simp]: "monom a n = 0 \<longleftrightarrow> a = 0"
   249   by (simp add: expand_poly_eq)
   250 
   251 lemma monom_eq_iff [simp]: "monom a n = monom b n \<longleftrightarrow> a = b"
   252   by (simp add: expand_poly_eq)
   253 
   254 lemma degree_monom_le: "degree (monom a n) \<le> n"
   255   by (rule degree_le, simp)
   256 
   257 lemma degree_monom_eq: "a \<noteq> 0 \<Longrightarrow> degree (monom a n) = n"
   258   apply (rule order_antisym [OF degree_monom_le])
   259   apply (rule le_degree, simp)
   260   done
   261 
   262 
   263 subsection {* Addition and subtraction *}
   264 
   265 instantiation poly :: (comm_monoid_add) comm_monoid_add
   266 begin
   267 
   268 definition
   269   plus_poly_def [code del]:
   270     "p + q = Abs_poly (\<lambda>n. coeff p n + coeff q n)"
   271 
   272 lemma Poly_add:
   273   fixes f g :: "nat \<Rightarrow> 'a"
   274   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n + g n) \<in> Poly"
   275   unfolding Poly_def
   276   apply (clarify, rename_tac m n)
   277   apply (rule_tac x="max m n" in exI, simp)
   278   done
   279 
   280 lemma coeff_add [simp]:
   281   "coeff (p + q) n = coeff p n + coeff q n"
   282   unfolding plus_poly_def
   283   by (simp add: Abs_poly_inverse coeff Poly_add)
   284 
   285 instance proof
   286   fix p q r :: "'a poly"
   287   show "(p + q) + r = p + (q + r)"
   288     by (simp add: expand_poly_eq add_assoc)
   289   show "p + q = q + p"
   290     by (simp add: expand_poly_eq add_commute)
   291   show "0 + p = p"
   292     by (simp add: expand_poly_eq)
   293 qed
   294 
   295 end
   296 
   297 instance poly :: (cancel_comm_monoid_add) cancel_comm_monoid_add
   298 proof
   299   fix p q r :: "'a poly"
   300   assume "p + q = p + r" thus "q = r"
   301     by (simp add: expand_poly_eq)
   302 qed
   303 
   304 instantiation poly :: (ab_group_add) ab_group_add
   305 begin
   306 
   307 definition
   308   uminus_poly_def [code del]:
   309     "- p = Abs_poly (\<lambda>n. - coeff p n)"
   310 
   311 definition
   312   minus_poly_def [code del]:
   313     "p - q = Abs_poly (\<lambda>n. coeff p n - coeff q n)"
   314 
   315 lemma Poly_minus:
   316   fixes f :: "nat \<Rightarrow> 'a"
   317   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. - f n) \<in> Poly"
   318   unfolding Poly_def by simp
   319 
   320 lemma Poly_diff:
   321   fixes f g :: "nat \<Rightarrow> 'a"
   322   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n - g n) \<in> Poly"
   323   unfolding diff_minus by (simp add: Poly_add Poly_minus)
   324 
   325 lemma coeff_minus [simp]: "coeff (- p) n = - coeff p n"
   326   unfolding uminus_poly_def
   327   by (simp add: Abs_poly_inverse coeff Poly_minus)
   328 
   329 lemma coeff_diff [simp]:
   330   "coeff (p - q) n = coeff p n - coeff q n"
   331   unfolding minus_poly_def
   332   by (simp add: Abs_poly_inverse coeff Poly_diff)
   333 
   334 instance proof
   335   fix p q :: "'a poly"
   336   show "- p + p = 0"
   337     by (simp add: expand_poly_eq)
   338   show "p - q = p + - q"
   339     by (simp add: expand_poly_eq diff_minus)
   340 qed
   341 
   342 end
   343 
   344 lemma add_pCons [simp]:
   345   "pCons a p + pCons b q = pCons (a + b) (p + q)"
   346   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   347 
   348 lemma minus_pCons [simp]:
   349   "- pCons a p = pCons (- a) (- p)"
   350   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   351 
   352 lemma diff_pCons [simp]:
   353   "pCons a p - pCons b q = pCons (a - b) (p - q)"
   354   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   355 
   356 lemma degree_add_le_max: "degree (p + q) \<le> max (degree p) (degree q)"
   357   by (rule degree_le, auto simp add: coeff_eq_0)
   358 
   359 lemma degree_add_le:
   360   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p + q) \<le> n"
   361   by (auto intro: order_trans degree_add_le_max)
   362 
   363 lemma degree_add_less:
   364   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p + q) < n"
   365   by (auto intro: le_less_trans degree_add_le_max)
   366 
   367 lemma degree_add_eq_right:
   368   "degree p < degree q \<Longrightarrow> degree (p + q) = degree q"
   369   apply (cases "q = 0", simp)
   370   apply (rule order_antisym)
   371   apply (simp add: degree_add_le)
   372   apply (rule le_degree)
   373   apply (simp add: coeff_eq_0)
   374   done
   375 
   376 lemma degree_add_eq_left:
   377   "degree q < degree p \<Longrightarrow> degree (p + q) = degree p"
   378   using degree_add_eq_right [of q p]
   379   by (simp add: add_commute)
   380 
   381 lemma degree_minus [simp]: "degree (- p) = degree p"
   382   unfolding degree_def by simp
   383 
   384 lemma degree_diff_le_max: "degree (p - q) \<le> max (degree p) (degree q)"
   385   using degree_add_le [where p=p and q="-q"]
   386   by (simp add: diff_minus)
   387 
   388 lemma degree_diff_le:
   389   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p - q) \<le> n"
   390   by (simp add: diff_minus degree_add_le)
   391 
   392 lemma degree_diff_less:
   393   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p - q) < n"
   394   by (simp add: diff_minus degree_add_less)
   395 
   396 lemma add_monom: "monom a n + monom b n = monom (a + b) n"
   397   by (rule poly_ext) simp
   398 
   399 lemma diff_monom: "monom a n - monom b n = monom (a - b) n"
   400   by (rule poly_ext) simp
   401 
   402 lemma minus_monom: "- monom a n = monom (-a) n"
   403   by (rule poly_ext) simp
   404 
   405 lemma coeff_setsum: "coeff (\<Sum>x\<in>A. p x) i = (\<Sum>x\<in>A. coeff (p x) i)"
   406   by (cases "finite A", induct set: finite, simp_all)
   407 
   408 lemma monom_setsum: "monom (\<Sum>x\<in>A. a x) n = (\<Sum>x\<in>A. monom (a x) n)"
   409   by (rule poly_ext) (simp add: coeff_setsum)
   410 
   411 
   412 subsection {* Multiplication by a constant *}
   413 
   414 definition
   415   smult :: "'a::comm_semiring_0 \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
   416   "smult a p = Abs_poly (\<lambda>n. a * coeff p n)"
   417 
   418 lemma Poly_smult:
   419   fixes f :: "nat \<Rightarrow> 'a::comm_semiring_0"
   420   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. a * f n) \<in> Poly"
   421   unfolding Poly_def
   422   by (clarify, rule_tac x=n in exI, simp)
   423 
   424 lemma coeff_smult [simp]: "coeff (smult a p) n = a * coeff p n"
   425   unfolding smult_def
   426   by (simp add: Abs_poly_inverse Poly_smult coeff)
   427 
   428 lemma degree_smult_le: "degree (smult a p) \<le> degree p"
   429   by (rule degree_le, simp add: coeff_eq_0)
   430 
   431 lemma smult_smult [simp]: "smult a (smult b p) = smult (a * b) p"
   432   by (rule poly_ext, simp add: mult_assoc)
   433 
   434 lemma smult_0_right [simp]: "smult a 0 = 0"
   435   by (rule poly_ext, simp)
   436 
   437 lemma smult_0_left [simp]: "smult 0 p = 0"
   438   by (rule poly_ext, simp)
   439 
   440 lemma smult_1_left [simp]: "smult (1::'a::comm_semiring_1) p = p"
   441   by (rule poly_ext, simp)
   442 
   443 lemma smult_add_right:
   444   "smult a (p + q) = smult a p + smult a q"
   445   by (rule poly_ext, simp add: algebra_simps)
   446 
   447 lemma smult_add_left:
   448   "smult (a + b) p = smult a p + smult b p"
   449   by (rule poly_ext, simp add: algebra_simps)
   450 
   451 lemma smult_minus_right [simp]:
   452   "smult (a::'a::comm_ring) (- p) = - smult a p"
   453   by (rule poly_ext, simp)
   454 
   455 lemma smult_minus_left [simp]:
   456   "smult (- a::'a::comm_ring) p = - smult a p"
   457   by (rule poly_ext, simp)
   458 
   459 lemma smult_diff_right:
   460   "smult (a::'a::comm_ring) (p - q) = smult a p - smult a q"
   461   by (rule poly_ext, simp add: algebra_simps)
   462 
   463 lemma smult_diff_left:
   464   "smult (a - b::'a::comm_ring) p = smult a p - smult b p"
   465   by (rule poly_ext, simp add: algebra_simps)
   466 
   467 lemmas smult_distribs =
   468   smult_add_left smult_add_right
   469   smult_diff_left smult_diff_right
   470 
   471 lemma smult_pCons [simp]:
   472   "smult a (pCons b p) = pCons (a * b) (smult a p)"
   473   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   474 
   475 lemma smult_monom: "smult a (monom b n) = monom (a * b) n"
   476   by (induct n, simp add: monom_0, simp add: monom_Suc)
   477 
   478 lemma degree_smult_eq [simp]:
   479   fixes a :: "'a::idom"
   480   shows "degree (smult a p) = (if a = 0 then 0 else degree p)"
   481   by (cases "a = 0", simp, simp add: degree_def)
   482 
   483 lemma smult_eq_0_iff [simp]:
   484   fixes a :: "'a::idom"
   485   shows "smult a p = 0 \<longleftrightarrow> a = 0 \<or> p = 0"
   486   by (simp add: expand_poly_eq)
   487 
   488 
   489 subsection {* Multiplication of polynomials *}
   490 
   491 text {* TODO: move to SetInterval.thy *}
   492 lemma setsum_atMost_Suc_shift:
   493   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
   494   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   495 proof (induct n)
   496   case 0 show ?case by simp
   497 next
   498   case (Suc n) note IH = this
   499   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
   500     by (rule setsum_atMost_Suc)
   501   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   502     by (rule IH)
   503   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
   504              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
   505     by (rule add_assoc)
   506   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
   507     by (rule setsum_atMost_Suc [symmetric])
   508   finally show ?case .
   509 qed
   510 
   511 instantiation poly :: (comm_semiring_0) comm_semiring_0
   512 begin
   513 
   514 definition
   515   times_poly_def [code del]:
   516     "p * q = poly_rec 0 (\<lambda>a p pq. smult a q + pCons 0 pq) p"
   517 
   518 lemma mult_poly_0_left: "(0::'a poly) * q = 0"
   519   unfolding times_poly_def by (simp add: poly_rec_0)
   520 
   521 lemma mult_pCons_left [simp]:
   522   "pCons a p * q = smult a q + pCons 0 (p * q)"
   523   unfolding times_poly_def by (simp add: poly_rec_pCons)
   524 
   525 lemma mult_poly_0_right: "p * (0::'a poly) = 0"
   526   by (induct p, simp add: mult_poly_0_left, simp)
   527 
   528 lemma mult_pCons_right [simp]:
   529   "p * pCons a q = smult a p + pCons 0 (p * q)"
   530   by (induct p, simp add: mult_poly_0_left, simp add: algebra_simps)
   531 
   532 lemmas mult_poly_0 = mult_poly_0_left mult_poly_0_right
   533 
   534 lemma mult_smult_left [simp]: "smult a p * q = smult a (p * q)"
   535   by (induct p, simp add: mult_poly_0, simp add: smult_add_right)
   536 
   537 lemma mult_smult_right [simp]: "p * smult a q = smult a (p * q)"
   538   by (induct q, simp add: mult_poly_0, simp add: smult_add_right)
   539 
   540 lemma mult_poly_add_left:
   541   fixes p q r :: "'a poly"
   542   shows "(p + q) * r = p * r + q * r"
   543   by (induct r, simp add: mult_poly_0,
   544                 simp add: smult_distribs algebra_simps)
   545 
   546 instance proof
   547   fix p q r :: "'a poly"
   548   show 0: "0 * p = 0"
   549     by (rule mult_poly_0_left)
   550   show "p * 0 = 0"
   551     by (rule mult_poly_0_right)
   552   show "(p + q) * r = p * r + q * r"
   553     by (rule mult_poly_add_left)
   554   show "(p * q) * r = p * (q * r)"
   555     by (induct p, simp add: mult_poly_0, simp add: mult_poly_add_left)
   556   show "p * q = q * p"
   557     by (induct p, simp add: mult_poly_0, simp)
   558 qed
   559 
   560 end
   561 
   562 instance poly :: (comm_semiring_0_cancel) comm_semiring_0_cancel ..
   563 
   564 lemma coeff_mult:
   565   "coeff (p * q) n = (\<Sum>i\<le>n. coeff p i * coeff q (n-i))"
   566 proof (induct p arbitrary: n)
   567   case 0 show ?case by simp
   568 next
   569   case (pCons a p n) thus ?case
   570     by (cases n, simp, simp add: setsum_atMost_Suc_shift
   571                             del: setsum_atMost_Suc)
   572 qed
   573 
   574 lemma degree_mult_le: "degree (p * q) \<le> degree p + degree q"
   575 apply (rule degree_le)
   576 apply (induct p)
   577 apply simp
   578 apply (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   579 done
   580 
   581 lemma mult_monom: "monom a m * monom b n = monom (a * b) (m + n)"
   582   by (induct m, simp add: monom_0 smult_monom, simp add: monom_Suc)
   583 
   584 
   585 subsection {* The unit polynomial and exponentiation *}
   586 
   587 instantiation poly :: (comm_semiring_1) comm_semiring_1
   588 begin
   589 
   590 definition
   591   one_poly_def:
   592     "1 = pCons 1 0"
   593 
   594 instance proof
   595   fix p :: "'a poly" show "1 * p = p"
   596     unfolding one_poly_def
   597     by simp
   598 next
   599   show "0 \<noteq> (1::'a poly)"
   600     unfolding one_poly_def by simp
   601 qed
   602 
   603 end
   604 
   605 instance poly :: (comm_semiring_1_cancel) comm_semiring_1_cancel ..
   606 
   607 lemma coeff_1 [simp]: "coeff 1 n = (if n = 0 then 1 else 0)"
   608   unfolding one_poly_def
   609   by (simp add: coeff_pCons split: nat.split)
   610 
   611 lemma degree_1 [simp]: "degree 1 = 0"
   612   unfolding one_poly_def
   613   by (rule degree_pCons_0)
   614 
   615 text {* Lemmas about divisibility *}
   616 
   617 lemma dvd_smult: "p dvd q \<Longrightarrow> p dvd smult a q"
   618 proof -
   619   assume "p dvd q"
   620   then obtain k where "q = p * k" ..
   621   then have "smult a q = p * smult a k" by simp
   622   then show "p dvd smult a q" ..
   623 qed
   624 
   625 lemma dvd_smult_cancel:
   626   fixes a :: "'a::field"
   627   shows "p dvd smult a q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> p dvd q"
   628   by (drule dvd_smult [where a="inverse a"]) simp
   629 
   630 lemma dvd_smult_iff:
   631   fixes a :: "'a::field"
   632   shows "a \<noteq> 0 \<Longrightarrow> p dvd smult a q \<longleftrightarrow> p dvd q"
   633   by (safe elim!: dvd_smult dvd_smult_cancel)
   634 
   635 instantiation poly :: (comm_semiring_1) recpower
   636 begin
   637 
   638 primrec power_poly where
   639   "(p::'a poly) ^ 0 = 1"
   640 | "(p::'a poly) ^ (Suc n) = p * p ^ n"
   641 
   642 instance
   643   by default simp_all
   644 
   645 declare power_poly.simps [simp del]
   646 
   647 end
   648 
   649 lemma degree_power_le: "degree (p ^ n) \<le> degree p * n"
   650 by (induct n, simp, auto intro: order_trans degree_mult_le)
   651 
   652 instance poly :: (comm_ring) comm_ring ..
   653 
   654 instance poly :: (comm_ring_1) comm_ring_1 ..
   655 
   656 instantiation poly :: (comm_ring_1) number_ring
   657 begin
   658 
   659 definition
   660   "number_of k = (of_int k :: 'a poly)"
   661 
   662 instance
   663   by default (rule number_of_poly_def)
   664 
   665 end
   666 
   667 
   668 subsection {* Polynomials form an integral domain *}
   669 
   670 lemma coeff_mult_degree_sum:
   671   "coeff (p * q) (degree p + degree q) =
   672    coeff p (degree p) * coeff q (degree q)"
   673   by (induct p, simp, simp add: coeff_eq_0)
   674 
   675 instance poly :: (idom) idom
   676 proof
   677   fix p q :: "'a poly"
   678   assume "p \<noteq> 0" and "q \<noteq> 0"
   679   have "coeff (p * q) (degree p + degree q) =
   680         coeff p (degree p) * coeff q (degree q)"
   681     by (rule coeff_mult_degree_sum)
   682   also have "coeff p (degree p) * coeff q (degree q) \<noteq> 0"
   683     using `p \<noteq> 0` and `q \<noteq> 0` by simp
   684   finally have "\<exists>n. coeff (p * q) n \<noteq> 0" ..
   685   thus "p * q \<noteq> 0" by (simp add: expand_poly_eq)
   686 qed
   687 
   688 lemma degree_mult_eq:
   689   fixes p q :: "'a::idom poly"
   690   shows "\<lbrakk>p \<noteq> 0; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree (p * q) = degree p + degree q"
   691 apply (rule order_antisym [OF degree_mult_le le_degree])
   692 apply (simp add: coeff_mult_degree_sum)
   693 done
   694 
   695 lemma dvd_imp_degree_le:
   696   fixes p q :: "'a::idom poly"
   697   shows "\<lbrakk>p dvd q; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree p \<le> degree q"
   698   by (erule dvdE, simp add: degree_mult_eq)
   699 
   700 
   701 subsection {* Polynomials form an ordered integral domain *}
   702 
   703 definition
   704   pos_poly :: "'a::ordered_idom poly \<Rightarrow> bool"
   705 where
   706   "pos_poly p \<longleftrightarrow> 0 < coeff p (degree p)"
   707 
   708 lemma pos_poly_pCons:
   709   "pos_poly (pCons a p) \<longleftrightarrow> pos_poly p \<or> (p = 0 \<and> 0 < a)"
   710   unfolding pos_poly_def by simp
   711 
   712 lemma not_pos_poly_0 [simp]: "\<not> pos_poly 0"
   713   unfolding pos_poly_def by simp
   714 
   715 lemma pos_poly_add: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p + q)"
   716   apply (induct p arbitrary: q, simp)
   717   apply (case_tac q, force simp add: pos_poly_pCons add_pos_pos)
   718   done
   719 
   720 lemma pos_poly_mult: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p * q)"
   721   unfolding pos_poly_def
   722   apply (subgoal_tac "p \<noteq> 0 \<and> q \<noteq> 0")
   723   apply (simp add: degree_mult_eq coeff_mult_degree_sum mult_pos_pos)
   724   apply auto
   725   done
   726 
   727 lemma pos_poly_total: "p = 0 \<or> pos_poly p \<or> pos_poly (- p)"
   728 by (induct p) (auto simp add: pos_poly_pCons)
   729 
   730 instantiation poly :: (ordered_idom) ordered_idom
   731 begin
   732 
   733 definition
   734   [code del]:
   735     "x < y \<longleftrightarrow> pos_poly (y - x)"
   736 
   737 definition
   738   [code del]:
   739     "x \<le> y \<longleftrightarrow> x = y \<or> pos_poly (y - x)"
   740 
   741 definition
   742   [code del]:
   743     "abs (x::'a poly) = (if x < 0 then - x else x)"
   744 
   745 definition
   746   [code del]:
   747     "sgn (x::'a poly) = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
   748 
   749 instance proof
   750   fix x y :: "'a poly"
   751   show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
   752     unfolding less_eq_poly_def less_poly_def
   753     apply safe
   754     apply simp
   755     apply (drule (1) pos_poly_add)
   756     apply simp
   757     done
   758 next
   759   fix x :: "'a poly" show "x \<le> x"
   760     unfolding less_eq_poly_def by simp
   761 next
   762   fix x y z :: "'a poly"
   763   assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
   764     unfolding less_eq_poly_def
   765     apply safe
   766     apply (drule (1) pos_poly_add)
   767     apply (simp add: algebra_simps)
   768     done
   769 next
   770   fix x y :: "'a poly"
   771   assume "x \<le> y" and "y \<le> x" thus "x = y"
   772     unfolding less_eq_poly_def
   773     apply safe
   774     apply (drule (1) pos_poly_add)
   775     apply simp
   776     done
   777 next
   778   fix x y z :: "'a poly"
   779   assume "x \<le> y" thus "z + x \<le> z + y"
   780     unfolding less_eq_poly_def
   781     apply safe
   782     apply (simp add: algebra_simps)
   783     done
   784 next
   785   fix x y :: "'a poly"
   786   show "x \<le> y \<or> y \<le> x"
   787     unfolding less_eq_poly_def
   788     using pos_poly_total [of "x - y"]
   789     by auto
   790 next
   791   fix x y z :: "'a poly"
   792   assume "x < y" and "0 < z"
   793   thus "z * x < z * y"
   794     unfolding less_poly_def
   795     by (simp add: right_diff_distrib [symmetric] pos_poly_mult)
   796 next
   797   fix x :: "'a poly"
   798   show "\<bar>x\<bar> = (if x < 0 then - x else x)"
   799     by (rule abs_poly_def)
   800 next
   801   fix x :: "'a poly"
   802   show "sgn x = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
   803     by (rule sgn_poly_def)
   804 qed
   805 
   806 end
   807 
   808 text {* TODO: Simplification rules for comparisons *}
   809 
   810 
   811 subsection {* Long division of polynomials *}
   812 
   813 definition
   814   pdivmod_rel :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> bool"
   815 where
   816   [code del]:
   817   "pdivmod_rel x y q r \<longleftrightarrow>
   818     x = q * y + r \<and> (if y = 0 then q = 0 else r = 0 \<or> degree r < degree y)"
   819 
   820 lemma pdivmod_rel_0:
   821   "pdivmod_rel 0 y 0 0"
   822   unfolding pdivmod_rel_def by simp
   823 
   824 lemma pdivmod_rel_by_0:
   825   "pdivmod_rel x 0 0 x"
   826   unfolding pdivmod_rel_def by simp
   827 
   828 lemma eq_zero_or_degree_less:
   829   assumes "degree p \<le> n" and "coeff p n = 0"
   830   shows "p = 0 \<or> degree p < n"
   831 proof (cases n)
   832   case 0
   833   with `degree p \<le> n` and `coeff p n = 0`
   834   have "coeff p (degree p) = 0" by simp
   835   then have "p = 0" by simp
   836   then show ?thesis ..
   837 next
   838   case (Suc m)
   839   have "\<forall>i>n. coeff p i = 0"
   840     using `degree p \<le> n` by (simp add: coeff_eq_0)
   841   then have "\<forall>i\<ge>n. coeff p i = 0"
   842     using `coeff p n = 0` by (simp add: le_less)
   843   then have "\<forall>i>m. coeff p i = 0"
   844     using `n = Suc m` by (simp add: less_eq_Suc_le)
   845   then have "degree p \<le> m"
   846     by (rule degree_le)
   847   then have "degree p < n"
   848     using `n = Suc m` by (simp add: less_Suc_eq_le)
   849   then show ?thesis ..
   850 qed
   851 
   852 lemma pdivmod_rel_pCons:
   853   assumes rel: "pdivmod_rel x y q r"
   854   assumes y: "y \<noteq> 0"
   855   assumes b: "b = coeff (pCons a r) (degree y) / coeff y (degree y)"
   856   shows "pdivmod_rel (pCons a x) y (pCons b q) (pCons a r - smult b y)"
   857     (is "pdivmod_rel ?x y ?q ?r")
   858 proof -
   859   have x: "x = q * y + r" and r: "r = 0 \<or> degree r < degree y"
   860     using assms unfolding pdivmod_rel_def by simp_all
   861 
   862   have 1: "?x = ?q * y + ?r"
   863     using b x by simp
   864 
   865   have 2: "?r = 0 \<or> degree ?r < degree y"
   866   proof (rule eq_zero_or_degree_less)
   867     show "degree ?r \<le> degree y"
   868     proof (rule degree_diff_le)
   869       show "degree (pCons a r) \<le> degree y"
   870         using r by auto
   871       show "degree (smult b y) \<le> degree y"
   872         by (rule degree_smult_le)
   873     qed
   874   next
   875     show "coeff ?r (degree y) = 0"
   876       using `y \<noteq> 0` unfolding b by simp
   877   qed
   878 
   879   from 1 2 show ?thesis
   880     unfolding pdivmod_rel_def
   881     using `y \<noteq> 0` by simp
   882 qed
   883 
   884 lemma pdivmod_rel_exists: "\<exists>q r. pdivmod_rel x y q r"
   885 apply (cases "y = 0")
   886 apply (fast intro!: pdivmod_rel_by_0)
   887 apply (induct x)
   888 apply (fast intro!: pdivmod_rel_0)
   889 apply (fast intro!: pdivmod_rel_pCons)
   890 done
   891 
   892 lemma pdivmod_rel_unique:
   893   assumes 1: "pdivmod_rel x y q1 r1"
   894   assumes 2: "pdivmod_rel x y q2 r2"
   895   shows "q1 = q2 \<and> r1 = r2"
   896 proof (cases "y = 0")
   897   assume "y = 0" with assms show ?thesis
   898     by (simp add: pdivmod_rel_def)
   899 next
   900   assume [simp]: "y \<noteq> 0"
   901   from 1 have q1: "x = q1 * y + r1" and r1: "r1 = 0 \<or> degree r1 < degree y"
   902     unfolding pdivmod_rel_def by simp_all
   903   from 2 have q2: "x = q2 * y + r2" and r2: "r2 = 0 \<or> degree r2 < degree y"
   904     unfolding pdivmod_rel_def by simp_all
   905   from q1 q2 have q3: "(q1 - q2) * y = r2 - r1"
   906     by (simp add: algebra_simps)
   907   from r1 r2 have r3: "(r2 - r1) = 0 \<or> degree (r2 - r1) < degree y"
   908     by (auto intro: degree_diff_less)
   909 
   910   show "q1 = q2 \<and> r1 = r2"
   911   proof (rule ccontr)
   912     assume "\<not> (q1 = q2 \<and> r1 = r2)"
   913     with q3 have "q1 \<noteq> q2" and "r1 \<noteq> r2" by auto
   914     with r3 have "degree (r2 - r1) < degree y" by simp
   915     also have "degree y \<le> degree (q1 - q2) + degree y" by simp
   916     also have "\<dots> = degree ((q1 - q2) * y)"
   917       using `q1 \<noteq> q2` by (simp add: degree_mult_eq)
   918     also have "\<dots> = degree (r2 - r1)"
   919       using q3 by simp
   920     finally have "degree (r2 - r1) < degree (r2 - r1)" .
   921     then show "False" by simp
   922   qed
   923 qed
   924 
   925 lemma pdivmod_rel_0_iff: "pdivmod_rel 0 y q r \<longleftrightarrow> q = 0 \<and> r = 0"
   926 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_0)
   927 
   928 lemma pdivmod_rel_by_0_iff: "pdivmod_rel x 0 q r \<longleftrightarrow> q = 0 \<and> r = x"
   929 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_by_0)
   930 
   931 lemmas pdivmod_rel_unique_div =
   932   pdivmod_rel_unique [THEN conjunct1, standard]
   933 
   934 lemmas pdivmod_rel_unique_mod =
   935   pdivmod_rel_unique [THEN conjunct2, standard]
   936 
   937 instantiation poly :: (field) ring_div
   938 begin
   939 
   940 definition div_poly where
   941   [code del]: "x div y = (THE q. \<exists>r. pdivmod_rel x y q r)"
   942 
   943 definition mod_poly where
   944   [code del]: "x mod y = (THE r. \<exists>q. pdivmod_rel x y q r)"
   945 
   946 lemma div_poly_eq:
   947   "pdivmod_rel x y q r \<Longrightarrow> x div y = q"
   948 unfolding div_poly_def
   949 by (fast elim: pdivmod_rel_unique_div)
   950 
   951 lemma mod_poly_eq:
   952   "pdivmod_rel x y q r \<Longrightarrow> x mod y = r"
   953 unfolding mod_poly_def
   954 by (fast elim: pdivmod_rel_unique_mod)
   955 
   956 lemma pdivmod_rel:
   957   "pdivmod_rel x y (x div y) (x mod y)"
   958 proof -
   959   from pdivmod_rel_exists
   960     obtain q r where "pdivmod_rel x y q r" by fast
   961   thus ?thesis
   962     by (simp add: div_poly_eq mod_poly_eq)
   963 qed
   964 
   965 instance proof
   966   fix x y :: "'a poly"
   967   show "x div y * y + x mod y = x"
   968     using pdivmod_rel [of x y]
   969     by (simp add: pdivmod_rel_def)
   970 next
   971   fix x :: "'a poly"
   972   have "pdivmod_rel x 0 0 x"
   973     by (rule pdivmod_rel_by_0)
   974   thus "x div 0 = 0"
   975     by (rule div_poly_eq)
   976 next
   977   fix y :: "'a poly"
   978   have "pdivmod_rel 0 y 0 0"
   979     by (rule pdivmod_rel_0)
   980   thus "0 div y = 0"
   981     by (rule div_poly_eq)
   982 next
   983   fix x y z :: "'a poly"
   984   assume "y \<noteq> 0"
   985   hence "pdivmod_rel (x + z * y) y (z + x div y) (x mod y)"
   986     using pdivmod_rel [of x y]
   987     by (simp add: pdivmod_rel_def left_distrib)
   988   thus "(x + z * y) div y = z + x div y"
   989     by (rule div_poly_eq)
   990 qed
   991 
   992 end
   993 
   994 lemma degree_mod_less:
   995   "y \<noteq> 0 \<Longrightarrow> x mod y = 0 \<or> degree (x mod y) < degree y"
   996   using pdivmod_rel [of x y]
   997   unfolding pdivmod_rel_def by simp
   998 
   999 lemma div_poly_less: "degree x < degree y \<Longrightarrow> x div y = 0"
  1000 proof -
  1001   assume "degree x < degree y"
  1002   hence "pdivmod_rel x y 0 x"
  1003     by (simp add: pdivmod_rel_def)
  1004   thus "x div y = 0" by (rule div_poly_eq)
  1005 qed
  1006 
  1007 lemma mod_poly_less: "degree x < degree y \<Longrightarrow> x mod y = x"
  1008 proof -
  1009   assume "degree x < degree y"
  1010   hence "pdivmod_rel x y 0 x"
  1011     by (simp add: pdivmod_rel_def)
  1012   thus "x mod y = x" by (rule mod_poly_eq)
  1013 qed
  1014 
  1015 lemma pdivmod_rel_smult_left:
  1016   "pdivmod_rel x y q r
  1017     \<Longrightarrow> pdivmod_rel (smult a x) y (smult a q) (smult a r)"
  1018   unfolding pdivmod_rel_def by (simp add: smult_add_right)
  1019 
  1020 lemma div_smult_left: "(smult a x) div y = smult a (x div y)"
  1021   by (rule div_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1022 
  1023 lemma mod_smult_left: "(smult a x) mod y = smult a (x mod y)"
  1024   by (rule mod_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1025 
  1026 lemma poly_div_minus_left [simp]:
  1027   fixes x y :: "'a::field poly"
  1028   shows "(- x) div y = - (x div y)"
  1029   using div_smult_left [of "- 1::'a"] by simp
  1030 
  1031 lemma poly_mod_minus_left [simp]:
  1032   fixes x y :: "'a::field poly"
  1033   shows "(- x) mod y = - (x mod y)"
  1034   using mod_smult_left [of "- 1::'a"] by simp
  1035 
  1036 lemma pdivmod_rel_smult_right:
  1037   "\<lbrakk>a \<noteq> 0; pdivmod_rel x y q r\<rbrakk>
  1038     \<Longrightarrow> pdivmod_rel x (smult a y) (smult (inverse a) q) r"
  1039   unfolding pdivmod_rel_def by simp
  1040 
  1041 lemma div_smult_right:
  1042   "a \<noteq> 0 \<Longrightarrow> x div (smult a y) = smult (inverse a) (x div y)"
  1043   by (rule div_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1044 
  1045 lemma mod_smult_right: "a \<noteq> 0 \<Longrightarrow> x mod (smult a y) = x mod y"
  1046   by (rule mod_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1047 
  1048 lemma poly_div_minus_right [simp]:
  1049   fixes x y :: "'a::field poly"
  1050   shows "x div (- y) = - (x div y)"
  1051   using div_smult_right [of "- 1::'a"]
  1052   by (simp add: nonzero_inverse_minus_eq)
  1053 
  1054 lemma poly_mod_minus_right [simp]:
  1055   fixes x y :: "'a::field poly"
  1056   shows "x mod (- y) = x mod y"
  1057   using mod_smult_right [of "- 1::'a"] by simp
  1058 
  1059 lemma pdivmod_rel_mult:
  1060   "\<lbrakk>pdivmod_rel x y q r; pdivmod_rel q z q' r'\<rbrakk>
  1061     \<Longrightarrow> pdivmod_rel x (y * z) q' (y * r' + r)"
  1062 apply (cases "z = 0", simp add: pdivmod_rel_def)
  1063 apply (cases "y = 0", simp add: pdivmod_rel_by_0_iff pdivmod_rel_0_iff)
  1064 apply (cases "r = 0")
  1065 apply (cases "r' = 0")
  1066 apply (simp add: pdivmod_rel_def)
  1067 apply (simp add: pdivmod_rel_def ring_simps degree_mult_eq)
  1068 apply (cases "r' = 0")
  1069 apply (simp add: pdivmod_rel_def degree_mult_eq)
  1070 apply (simp add: pdivmod_rel_def ring_simps)
  1071 apply (simp add: degree_mult_eq degree_add_less)
  1072 done
  1073 
  1074 lemma poly_div_mult_right:
  1075   fixes x y z :: "'a::field poly"
  1076   shows "x div (y * z) = (x div y) div z"
  1077   by (rule div_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1078 
  1079 lemma poly_mod_mult_right:
  1080   fixes x y z :: "'a::field poly"
  1081   shows "x mod (y * z) = y * (x div y mod z) + x mod y"
  1082   by (rule mod_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1083 
  1084 lemma mod_pCons:
  1085   fixes a and x
  1086   assumes y: "y \<noteq> 0"
  1087   defines b: "b \<equiv> coeff (pCons a (x mod y)) (degree y) / coeff y (degree y)"
  1088   shows "(pCons a x) mod y = (pCons a (x mod y) - smult b y)"
  1089 unfolding b
  1090 apply (rule mod_poly_eq)
  1091 apply (rule pdivmod_rel_pCons [OF pdivmod_rel y refl])
  1092 done
  1093 
  1094 
  1095 subsection {* Evaluation of polynomials *}
  1096 
  1097 definition
  1098   poly :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a" where
  1099   "poly = poly_rec (\<lambda>x. 0) (\<lambda>a p f x. a + x * f x)"
  1100 
  1101 lemma poly_0 [simp]: "poly 0 x = 0"
  1102   unfolding poly_def by (simp add: poly_rec_0)
  1103 
  1104 lemma poly_pCons [simp]: "poly (pCons a p) x = a + x * poly p x"
  1105   unfolding poly_def by (simp add: poly_rec_pCons)
  1106 
  1107 lemma poly_1 [simp]: "poly 1 x = 1"
  1108   unfolding one_poly_def by simp
  1109 
  1110 lemma poly_monom:
  1111   fixes a x :: "'a::{comm_semiring_1,recpower}"
  1112   shows "poly (monom a n) x = a * x ^ n"
  1113   by (induct n, simp add: monom_0, simp add: monom_Suc power_Suc mult_ac)
  1114 
  1115 lemma poly_add [simp]: "poly (p + q) x = poly p x + poly q x"
  1116   apply (induct p arbitrary: q, simp)
  1117   apply (case_tac q, simp, simp add: algebra_simps)
  1118   done
  1119 
  1120 lemma poly_minus [simp]:
  1121   fixes x :: "'a::comm_ring"
  1122   shows "poly (- p) x = - poly p x"
  1123   by (induct p, simp_all)
  1124 
  1125 lemma poly_diff [simp]:
  1126   fixes x :: "'a::comm_ring"
  1127   shows "poly (p - q) x = poly p x - poly q x"
  1128   by (simp add: diff_minus)
  1129 
  1130 lemma poly_setsum: "poly (\<Sum>k\<in>A. p k) x = (\<Sum>k\<in>A. poly (p k) x)"
  1131   by (cases "finite A", induct set: finite, simp_all)
  1132 
  1133 lemma poly_smult [simp]: "poly (smult a p) x = a * poly p x"
  1134   by (induct p, simp, simp add: algebra_simps)
  1135 
  1136 lemma poly_mult [simp]: "poly (p * q) x = poly p x * poly q x"
  1137   by (induct p, simp_all, simp add: algebra_simps)
  1138 
  1139 lemma poly_power [simp]:
  1140   fixes p :: "'a::{comm_semiring_1,recpower} poly"
  1141   shows "poly (p ^ n) x = poly p x ^ n"
  1142   by (induct n, simp, simp add: power_Suc)
  1143 
  1144 
  1145 subsection {* Synthetic division *}
  1146 
  1147 text {*
  1148   Synthetic division is simply division by the
  1149   linear polynomial @{term "x - c"}.
  1150 *}
  1151 
  1152 definition
  1153   synthetic_divmod :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly \<times> 'a"
  1154 where [code del]:
  1155   "synthetic_divmod p c =
  1156     poly_rec (0, 0) (\<lambda>a p (q, r). (pCons r q, a + c * r)) p"
  1157 
  1158 definition
  1159   synthetic_div :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly"
  1160 where
  1161   "synthetic_div p c = fst (synthetic_divmod p c)"
  1162 
  1163 lemma synthetic_divmod_0 [simp]:
  1164   "synthetic_divmod 0 c = (0, 0)"
  1165   unfolding synthetic_divmod_def
  1166   by (simp add: poly_rec_0)
  1167 
  1168 lemma synthetic_divmod_pCons [simp]:
  1169   "synthetic_divmod (pCons a p) c =
  1170     (\<lambda>(q, r). (pCons r q, a + c * r)) (synthetic_divmod p c)"
  1171   unfolding synthetic_divmod_def
  1172   by (simp add: poly_rec_pCons)
  1173 
  1174 lemma snd_synthetic_divmod: "snd (synthetic_divmod p c) = poly p c"
  1175   by (induct p, simp, simp add: split_def)
  1176 
  1177 lemma synthetic_div_0 [simp]: "synthetic_div 0 c = 0"
  1178   unfolding synthetic_div_def by simp
  1179 
  1180 lemma synthetic_div_pCons [simp]:
  1181   "synthetic_div (pCons a p) c = pCons (poly p c) (synthetic_div p c)"
  1182   unfolding synthetic_div_def
  1183   by (simp add: split_def snd_synthetic_divmod)
  1184 
  1185 lemma synthetic_div_eq_0_iff:
  1186   "synthetic_div p c = 0 \<longleftrightarrow> degree p = 0"
  1187   by (induct p, simp, case_tac p, simp)
  1188 
  1189 lemma degree_synthetic_div:
  1190   "degree (synthetic_div p c) = degree p - 1"
  1191   by (induct p, simp, simp add: synthetic_div_eq_0_iff)
  1192 
  1193 lemma synthetic_div_correct:
  1194   "p + smult c (synthetic_div p c) = pCons (poly p c) (synthetic_div p c)"
  1195   by (induct p) simp_all
  1196 
  1197 lemma synthetic_div_unique_lemma: "smult c p = pCons a p \<Longrightarrow> p = 0"
  1198 by (induct p arbitrary: a) simp_all
  1199 
  1200 lemma synthetic_div_unique:
  1201   "p + smult c q = pCons r q \<Longrightarrow> r = poly p c \<and> q = synthetic_div p c"
  1202 apply (induct p arbitrary: q r)
  1203 apply (simp, frule synthetic_div_unique_lemma, simp)
  1204 apply (case_tac q, force)
  1205 done
  1206 
  1207 lemma synthetic_div_correct':
  1208   fixes c :: "'a::comm_ring_1"
  1209   shows "[:-c, 1:] * synthetic_div p c + [:poly p c:] = p"
  1210   using synthetic_div_correct [of p c]
  1211   by (simp add: algebra_simps)
  1212 
  1213 lemma poly_eq_0_iff_dvd:
  1214   fixes c :: "'a::idom"
  1215   shows "poly p c = 0 \<longleftrightarrow> [:-c, 1:] dvd p"
  1216 proof
  1217   assume "poly p c = 0"
  1218   with synthetic_div_correct' [of c p]
  1219   have "p = [:-c, 1:] * synthetic_div p c" by simp
  1220   then show "[:-c, 1:] dvd p" ..
  1221 next
  1222   assume "[:-c, 1:] dvd p"
  1223   then obtain k where "p = [:-c, 1:] * k" by (rule dvdE)
  1224   then show "poly p c = 0" by simp
  1225 qed
  1226 
  1227 lemma dvd_iff_poly_eq_0:
  1228   fixes c :: "'a::idom"
  1229   shows "[:c, 1:] dvd p \<longleftrightarrow> poly p (-c) = 0"
  1230   by (simp add: poly_eq_0_iff_dvd)
  1231 
  1232 lemma poly_roots_finite:
  1233   fixes p :: "'a::idom poly"
  1234   shows "p \<noteq> 0 \<Longrightarrow> finite {x. poly p x = 0}"
  1235 proof (induct n \<equiv> "degree p" arbitrary: p)
  1236   case (0 p)
  1237   then obtain a where "a \<noteq> 0" and "p = [:a:]"
  1238     by (cases p, simp split: if_splits)
  1239   then show "finite {x. poly p x = 0}" by simp
  1240 next
  1241   case (Suc n p)
  1242   show "finite {x. poly p x = 0}"
  1243   proof (cases "\<exists>x. poly p x = 0")
  1244     case False
  1245     then show "finite {x. poly p x = 0}" by simp
  1246   next
  1247     case True
  1248     then obtain a where "poly p a = 0" ..
  1249     then have "[:-a, 1:] dvd p" by (simp only: poly_eq_0_iff_dvd)
  1250     then obtain k where k: "p = [:-a, 1:] * k" ..
  1251     with `p \<noteq> 0` have "k \<noteq> 0" by auto
  1252     with k have "degree p = Suc (degree k)"
  1253       by (simp add: degree_mult_eq del: mult_pCons_left)
  1254     with `Suc n = degree p` have "n = degree k" by simp
  1255     with `k \<noteq> 0` have "finite {x. poly k x = 0}" by (rule Suc.hyps)
  1256     then have "finite (insert a {x. poly k x = 0})" by simp
  1257     then show "finite {x. poly p x = 0}"
  1258       by (simp add: k uminus_add_conv_diff Collect_disj_eq
  1259                del: mult_pCons_left)
  1260   qed
  1261 qed
  1262 
  1263 lemma poly_zero:
  1264   fixes p :: "'a::{idom,ring_char_0} poly"
  1265   shows "poly p = poly 0 \<longleftrightarrow> p = 0"
  1266 apply (cases "p = 0", simp_all)
  1267 apply (drule poly_roots_finite)
  1268 apply (auto simp add: infinite_UNIV_char_0)
  1269 done
  1270 
  1271 lemma poly_eq_iff:
  1272   fixes p q :: "'a::{idom,ring_char_0} poly"
  1273   shows "poly p = poly q \<longleftrightarrow> p = q"
  1274   using poly_zero [of "p - q"]
  1275   by (simp add: expand_fun_eq)
  1276 
  1277 
  1278 subsection {* Composition of polynomials *}
  1279 
  1280 definition
  1281   pcompose :: "'a::comm_semiring_0 poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1282 where
  1283   "pcompose p q = poly_rec 0 (\<lambda>a _ c. [:a:] + q * c) p"
  1284 
  1285 lemma pcompose_0 [simp]: "pcompose 0 q = 0"
  1286   unfolding pcompose_def by (simp add: poly_rec_0)
  1287 
  1288 lemma pcompose_pCons:
  1289   "pcompose (pCons a p) q = [:a:] + q * pcompose p q"
  1290   unfolding pcompose_def by (simp add: poly_rec_pCons)
  1291 
  1292 lemma poly_pcompose: "poly (pcompose p q) x = poly p (poly q x)"
  1293   by (induct p) (simp_all add: pcompose_pCons)
  1294 
  1295 lemma degree_pcompose_le:
  1296   "degree (pcompose p q) \<le> degree p * degree q"
  1297 apply (induct p, simp)
  1298 apply (simp add: pcompose_pCons, clarify)
  1299 apply (rule degree_add_le, simp)
  1300 apply (rule order_trans [OF degree_mult_le], simp)
  1301 done
  1302 
  1303 
  1304 subsection {* Order of polynomial roots *}
  1305 
  1306 definition
  1307   order :: "'a::idom \<Rightarrow> 'a poly \<Rightarrow> nat"
  1308 where
  1309   [code del]:
  1310   "order a p = (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)"
  1311 
  1312 lemma coeff_linear_power:
  1313   fixes a :: "'a::comm_semiring_1"
  1314   shows "coeff ([:a, 1:] ^ n) n = 1"
  1315 apply (induct n, simp_all)
  1316 apply (subst coeff_eq_0)
  1317 apply (auto intro: le_less_trans degree_power_le)
  1318 done
  1319 
  1320 lemma degree_linear_power:
  1321   fixes a :: "'a::comm_semiring_1"
  1322   shows "degree ([:a, 1:] ^ n) = n"
  1323 apply (rule order_antisym)
  1324 apply (rule ord_le_eq_trans [OF degree_power_le], simp)
  1325 apply (rule le_degree, simp add: coeff_linear_power)
  1326 done
  1327 
  1328 lemma order_1: "[:-a, 1:] ^ order a p dvd p"
  1329 apply (cases "p = 0", simp)
  1330 apply (cases "order a p", simp)
  1331 apply (subgoal_tac "nat < (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)")
  1332 apply (drule not_less_Least, simp)
  1333 apply (fold order_def, simp)
  1334 done
  1335 
  1336 lemma order_2: "p \<noteq> 0 \<Longrightarrow> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1337 unfolding order_def
  1338 apply (rule LeastI_ex)
  1339 apply (rule_tac x="degree p" in exI)
  1340 apply (rule notI)
  1341 apply (drule (1) dvd_imp_degree_le)
  1342 apply (simp only: degree_linear_power)
  1343 done
  1344 
  1345 lemma order:
  1346   "p \<noteq> 0 \<Longrightarrow> [:-a, 1:] ^ order a p dvd p \<and> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1347 by (rule conjI [OF order_1 order_2])
  1348 
  1349 lemma order_degree:
  1350   assumes p: "p \<noteq> 0"
  1351   shows "order a p \<le> degree p"
  1352 proof -
  1353   have "order a p = degree ([:-a, 1:] ^ order a p)"
  1354     by (simp only: degree_linear_power)
  1355   also have "\<dots> \<le> degree p"
  1356     using order_1 p by (rule dvd_imp_degree_le)
  1357   finally show ?thesis .
  1358 qed
  1359 
  1360 lemma order_root: "poly p a = 0 \<longleftrightarrow> p = 0 \<or> order a p \<noteq> 0"
  1361 apply (cases "p = 0", simp_all)
  1362 apply (rule iffI)
  1363 apply (rule ccontr, simp)
  1364 apply (frule order_2 [where a=a], simp)
  1365 apply (simp add: poly_eq_0_iff_dvd)
  1366 apply (simp add: poly_eq_0_iff_dvd)
  1367 apply (simp only: order_def)
  1368 apply (drule not_less_Least, simp)
  1369 done
  1370 
  1371 
  1372 subsection {* Configuration of the code generator *}
  1373 
  1374 code_datatype "0::'a::zero poly" pCons
  1375 
  1376 declare pCons_0_0 [code post]
  1377 
  1378 instantiation poly :: ("{zero,eq}") eq
  1379 begin
  1380 
  1381 definition [code del]:
  1382   "eq_class.eq (p::'a poly) q \<longleftrightarrow> p = q"
  1383 
  1384 instance
  1385   by default (rule eq_poly_def)
  1386 
  1387 end
  1388 
  1389 lemma eq_poly_code [code]:
  1390   "eq_class.eq (0::_ poly) (0::_ poly) \<longleftrightarrow> True"
  1391   "eq_class.eq (0::_ poly) (pCons b q) \<longleftrightarrow> eq_class.eq 0 b \<and> eq_class.eq 0 q"
  1392   "eq_class.eq (pCons a p) (0::_ poly) \<longleftrightarrow> eq_class.eq a 0 \<and> eq_class.eq p 0"
  1393   "eq_class.eq (pCons a p) (pCons b q) \<longleftrightarrow> eq_class.eq a b \<and> eq_class.eq p q"
  1394 unfolding eq by simp_all
  1395 
  1396 lemmas coeff_code [code] =
  1397   coeff_0 coeff_pCons_0 coeff_pCons_Suc
  1398 
  1399 lemmas degree_code [code] =
  1400   degree_0 degree_pCons_eq_if
  1401 
  1402 lemmas monom_poly_code [code] =
  1403   monom_0 monom_Suc
  1404 
  1405 lemma add_poly_code [code]:
  1406   "0 + q = (q :: _ poly)"
  1407   "p + 0 = (p :: _ poly)"
  1408   "pCons a p + pCons b q = pCons (a + b) (p + q)"
  1409 by simp_all
  1410 
  1411 lemma minus_poly_code [code]:
  1412   "- 0 = (0 :: _ poly)"
  1413   "- pCons a p = pCons (- a) (- p)"
  1414 by simp_all
  1415 
  1416 lemma diff_poly_code [code]:
  1417   "0 - q = (- q :: _ poly)"
  1418   "p - 0 = (p :: _ poly)"
  1419   "pCons a p - pCons b q = pCons (a - b) (p - q)"
  1420 by simp_all
  1421 
  1422 lemmas smult_poly_code [code] =
  1423   smult_0_right smult_pCons
  1424 
  1425 lemma mult_poly_code [code]:
  1426   "0 * q = (0 :: _ poly)"
  1427   "pCons a p * q = smult a q + pCons 0 (p * q)"
  1428 by simp_all
  1429 
  1430 lemmas poly_code [code] =
  1431   poly_0 poly_pCons
  1432 
  1433 lemmas synthetic_divmod_code [code] =
  1434   synthetic_divmod_0 synthetic_divmod_pCons
  1435 
  1436 text {* code generator setup for div and mod *}
  1437 
  1438 definition
  1439   pdivmod :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<times> 'a poly"
  1440 where
  1441   [code del]: "pdivmod x y = (x div y, x mod y)"
  1442 
  1443 lemma div_poly_code [code]: "x div y = fst (pdivmod x y)"
  1444   unfolding pdivmod_def by simp
  1445 
  1446 lemma mod_poly_code [code]: "x mod y = snd (pdivmod x y)"
  1447   unfolding pdivmod_def by simp
  1448 
  1449 lemma pdivmod_0 [code]: "pdivmod 0 y = (0, 0)"
  1450   unfolding pdivmod_def by simp
  1451 
  1452 lemma pdivmod_pCons [code]:
  1453   "pdivmod (pCons a x) y =
  1454     (if y = 0 then (0, pCons a x) else
  1455       (let (q, r) = pdivmod x y;
  1456            b = coeff (pCons a r) (degree y) / coeff y (degree y)
  1457         in (pCons b q, pCons a r - smult b y)))"
  1458 apply (simp add: pdivmod_def Let_def, safe)
  1459 apply (rule div_poly_eq)
  1460 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1461 apply (rule mod_poly_eq)
  1462 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1463 done
  1464 
  1465 end