src/HOL/Parity.thy
author haftmann
Fri Mar 27 10:05:11 2009 +0100 (2009-03-27)
changeset 30738 0842e906300c
parent 30056 0a35bee25c20
child 31017 2c227493ea56
permissions -rw-r--r--
normalized imports
     1 (*  Title:      HOL/Library/Parity.thy
     2     Author:     Jeremy Avigad, Jacques D. Fleuriot
     3 *)
     4 
     5 header {* Even and Odd for int and nat *}
     6 
     7 theory Parity
     8 imports Main
     9 begin
    10 
    11 class even_odd = 
    12   fixes even :: "'a \<Rightarrow> bool"
    13 
    14 abbreviation
    15   odd :: "'a\<Colon>even_odd \<Rightarrow> bool" where
    16   "odd x \<equiv> \<not> even x"
    17 
    18 instantiation nat and int  :: even_odd
    19 begin
    20 
    21 definition
    22   even_def [presburger]: "even x \<longleftrightarrow> (x\<Colon>int) mod 2 = 0"
    23 
    24 definition
    25   even_nat_def [presburger]: "even x \<longleftrightarrow> even (int x)"
    26 
    27 instance ..
    28 
    29 end
    30 
    31 
    32 subsection {* Even and odd are mutually exclusive *}
    33 
    34 lemma int_pos_lt_two_imp_zero_or_one:
    35     "0 <= x ==> (x::int) < 2 ==> x = 0 | x = 1"
    36   by presburger
    37 
    38 lemma neq_one_mod_two [simp, presburger]: 
    39   "((x::int) mod 2 ~= 0) = (x mod 2 = 1)" by presburger
    40 
    41 
    42 subsection {* Behavior under integer arithmetic operations *}
    43 declare dvd_def[algebra]
    44 lemma nat_even_iff_2_dvd[algebra]: "even (x::nat) \<longleftrightarrow> 2 dvd x"
    45   by (presburger add: even_nat_def even_def)
    46 lemma int_even_iff_2_dvd[algebra]: "even (x::int) \<longleftrightarrow> 2 dvd x"
    47   by presburger
    48 
    49 lemma even_times_anything: "even (x::int) ==> even (x * y)"
    50   by algebra
    51 
    52 lemma anything_times_even: "even (y::int) ==> even (x * y)" by algebra
    53 
    54 lemma odd_times_odd: "odd (x::int) ==> odd y ==> odd (x * y)" 
    55   by (simp add: even_def zmod_zmult1_eq)
    56 
    57 lemma even_product[presburger]: "even((x::int) * y) = (even x | even y)"
    58   apply (auto simp add: even_times_anything anything_times_even)
    59   apply (rule ccontr)
    60   apply (auto simp add: odd_times_odd)
    61   done
    62 
    63 lemma even_plus_even: "even (x::int) ==> even y ==> even (x + y)"
    64   by presburger
    65 
    66 lemma even_plus_odd: "even (x::int) ==> odd y ==> odd (x + y)"
    67   by presburger
    68 
    69 lemma odd_plus_even: "odd (x::int) ==> even y ==> odd (x + y)"
    70   by presburger
    71 
    72 lemma odd_plus_odd: "odd (x::int) ==> odd y ==> even (x + y)" by presburger
    73 
    74 lemma even_sum[presburger]: "even ((x::int) + y) = ((even x & even y) | (odd x & odd y))"
    75   by presburger
    76 
    77 lemma even_neg[presburger, algebra]: "even (-(x::int)) = even x" by presburger
    78 
    79 lemma even_difference:
    80     "even ((x::int) - y) = ((even x & even y) | (odd x & odd y))" by presburger
    81 
    82 lemma even_pow_gt_zero:
    83     "even (x::int) ==> 0 < n ==> even (x^n)"
    84   by (induct n) (auto simp add: even_product)
    85 
    86 lemma odd_pow_iff[presburger, algebra]: 
    87   "odd ((x::int) ^ n) \<longleftrightarrow> (n = 0 \<or> odd x)"
    88   apply (induct n, simp_all)
    89   apply presburger
    90   apply (case_tac n, auto)
    91   apply (simp_all add: even_product)
    92   done
    93 
    94 lemma odd_pow: "odd x ==> odd((x::int)^n)" by (simp add: odd_pow_iff)
    95 
    96 lemma even_power[presburger]: "even ((x::int)^n) = (even x & 0 < n)"
    97   apply (auto simp add: even_pow_gt_zero)
    98   apply (erule contrapos_pp, erule odd_pow)
    99   apply (erule contrapos_pp, simp add: even_def)
   100   done
   101 
   102 lemma even_zero[presburger]: "even (0::int)" by presburger
   103 
   104 lemma odd_one[presburger]: "odd (1::int)" by presburger
   105 
   106 lemmas even_odd_simps [simp] = even_def[of "number_of v",standard] even_zero
   107   odd_one even_product even_sum even_neg even_difference even_power
   108 
   109 
   110 subsection {* Equivalent definitions *}
   111 
   112 lemma two_times_even_div_two: "even (x::int) ==> 2 * (x div 2) = x" 
   113   by presburger
   114 
   115 lemma two_times_odd_div_two_plus_one: "odd (x::int) ==>
   116     2 * (x div 2) + 1 = x" by presburger
   117 
   118 lemma even_equiv_def: "even (x::int) = (EX y. x = 2 * y)" by presburger
   119 
   120 lemma odd_equiv_def: "odd (x::int) = (EX y. x = 2 * y + 1)" by presburger
   121 
   122 subsection {* even and odd for nats *}
   123 
   124 lemma pos_int_even_equiv_nat_even: "0 \<le> x ==> even x = even (nat x)"
   125   by (simp add: even_nat_def)
   126 
   127 lemma even_nat_product[presburger, algebra]: "even((x::nat) * y) = (even x | even y)"
   128   by (simp add: even_nat_def int_mult)
   129 
   130 lemma even_nat_sum[presburger, algebra]: "even ((x::nat) + y) =
   131     ((even x & even y) | (odd x & odd y))" by presburger
   132 
   133 lemma even_nat_difference[presburger, algebra]:
   134     "even ((x::nat) - y) = (x < y | (even x & even y) | (odd x & odd y))"
   135 by presburger
   136 
   137 lemma even_nat_Suc[presburger, algebra]: "even (Suc x) = odd x" by presburger
   138 
   139 lemma even_nat_power[presburger, algebra]: "even ((x::nat)^y) = (even x & 0 < y)"
   140   by (simp add: even_nat_def int_power)
   141 
   142 lemma even_nat_zero[presburger]: "even (0::nat)" by presburger
   143 
   144 lemmas even_odd_nat_simps [simp] = even_nat_def[of "number_of v",standard]
   145   even_nat_zero even_nat_Suc even_nat_product even_nat_sum even_nat_power
   146 
   147 
   148 subsection {* Equivalent definitions *}
   149 
   150 lemma nat_lt_two_imp_zero_or_one: "(x::nat) < Suc (Suc 0) ==>
   151     x = 0 | x = Suc 0" by presburger
   152 
   153 lemma even_nat_mod_two_eq_zero: "even (x::nat) ==> x mod (Suc (Suc 0)) = 0"
   154   by presburger
   155 
   156 lemma odd_nat_mod_two_eq_one: "odd (x::nat) ==> x mod (Suc (Suc 0)) = Suc 0"
   157 by presburger
   158 
   159 lemma even_nat_equiv_def: "even (x::nat) = (x mod Suc (Suc 0) = 0)"
   160   by presburger
   161 
   162 lemma odd_nat_equiv_def: "odd (x::nat) = (x mod Suc (Suc 0) = Suc 0)"
   163   by presburger
   164 
   165 lemma even_nat_div_two_times_two: "even (x::nat) ==>
   166     Suc (Suc 0) * (x div Suc (Suc 0)) = x" by presburger
   167 
   168 lemma odd_nat_div_two_times_two_plus_one: "odd (x::nat) ==>
   169     Suc( Suc (Suc 0) * (x div Suc (Suc 0))) = x" by presburger
   170 
   171 lemma even_nat_equiv_def2: "even (x::nat) = (EX y. x = Suc (Suc 0) * y)"
   172   by presburger
   173 
   174 lemma odd_nat_equiv_def2: "odd (x::nat) = (EX y. x = Suc(Suc (Suc 0) * y))"
   175   by presburger
   176 
   177 
   178 subsection {* Parity and powers *}
   179 
   180 lemma  minus_one_even_odd_power:
   181      "(even x --> (- 1::'a::{comm_ring_1,recpower})^x = 1) &
   182       (odd x --> (- 1::'a)^x = - 1)"
   183   apply (induct x)
   184   apply (rule conjI)
   185   apply simp
   186   apply (insert even_nat_zero, blast)
   187   apply (simp add: power_Suc)
   188   done
   189 
   190 lemma minus_one_even_power [simp]:
   191     "even x ==> (- 1::'a::{comm_ring_1,recpower})^x = 1"
   192   using minus_one_even_odd_power by blast
   193 
   194 lemma minus_one_odd_power [simp]:
   195     "odd x ==> (- 1::'a::{comm_ring_1,recpower})^x = - 1"
   196   using minus_one_even_odd_power by blast
   197 
   198 lemma neg_one_even_odd_power:
   199      "(even x --> (-1::'a::{number_ring,recpower})^x = 1) &
   200       (odd x --> (-1::'a)^x = -1)"
   201   apply (induct x)
   202   apply (simp, simp add: power_Suc)
   203   done
   204 
   205 lemma neg_one_even_power [simp]:
   206     "even x ==> (-1::'a::{number_ring,recpower})^x = 1"
   207   using neg_one_even_odd_power by blast
   208 
   209 lemma neg_one_odd_power [simp]:
   210     "odd x ==> (-1::'a::{number_ring,recpower})^x = -1"
   211   using neg_one_even_odd_power by blast
   212 
   213 lemma neg_power_if:
   214      "(-x::'a::{comm_ring_1,recpower}) ^ n =
   215       (if even n then (x ^ n) else -(x ^ n))"
   216   apply (induct n)
   217   apply (simp_all split: split_if_asm add: power_Suc)
   218   done
   219 
   220 lemma zero_le_even_power: "even n ==>
   221     0 <= (x::'a::{recpower,ordered_ring_strict}) ^ n"
   222   apply (simp add: even_nat_equiv_def2)
   223   apply (erule exE)
   224   apply (erule ssubst)
   225   apply (subst power_add)
   226   apply (rule zero_le_square)
   227   done
   228 
   229 lemma zero_le_odd_power: "odd n ==>
   230     (0 <= (x::'a::{recpower,ordered_idom}) ^ n) = (0 <= x)"
   231 apply (auto simp: odd_nat_equiv_def2 power_Suc power_add zero_le_mult_iff)
   232 apply (metis field_power_not_zero no_zero_divirors_neq0 order_antisym_conv zero_le_square)
   233 done
   234 
   235 lemma zero_le_power_eq[presburger]: "(0 <= (x::'a::{recpower,ordered_idom}) ^ n) =
   236     (even n | (odd n & 0 <= x))"
   237   apply auto
   238   apply (subst zero_le_odd_power [symmetric])
   239   apply assumption+
   240   apply (erule zero_le_even_power)
   241   done
   242 
   243 lemma zero_less_power_eq[presburger]: "(0 < (x::'a::{recpower,ordered_idom}) ^ n) =
   244     (n = 0 | (even n & x ~= 0) | (odd n & 0 < x))"
   245 
   246   unfolding order_less_le zero_le_power_eq by auto
   247 
   248 lemma power_less_zero_eq[presburger]: "((x::'a::{recpower,ordered_idom}) ^ n < 0) =
   249     (odd n & x < 0)"
   250   apply (subst linorder_not_le [symmetric])+
   251   apply (subst zero_le_power_eq)
   252   apply auto
   253   done
   254 
   255 lemma power_le_zero_eq[presburger]: "((x::'a::{recpower,ordered_idom}) ^ n <= 0) =
   256     (n ~= 0 & ((odd n & x <= 0) | (even n & x = 0)))"
   257   apply (subst linorder_not_less [symmetric])+
   258   apply (subst zero_less_power_eq)
   259   apply auto
   260   done
   261 
   262 lemma power_even_abs: "even n ==>
   263     (abs (x::'a::{recpower,ordered_idom}))^n = x^n"
   264   apply (subst power_abs [symmetric])
   265   apply (simp add: zero_le_even_power)
   266   done
   267 
   268 lemma zero_less_power_nat_eq[presburger]: "(0 < (x::nat) ^ n) = (n = 0 | 0 < x)"
   269   by (induct n) auto
   270 
   271 lemma power_minus_even [simp]: "even n ==>
   272     (- x)^n = (x^n::'a::{recpower,comm_ring_1})"
   273   apply (subst power_minus)
   274   apply simp
   275   done
   276 
   277 lemma power_minus_odd [simp]: "odd n ==>
   278     (- x)^n = - (x^n::'a::{recpower,comm_ring_1})"
   279   apply (subst power_minus)
   280   apply simp
   281   done
   282 
   283 lemma power_mono_even: fixes x y :: "'a :: {recpower, ordered_idom}"
   284   assumes "even n" and "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   285   shows "x^n \<le> y^n"
   286 proof -
   287   have "0 \<le> \<bar>x\<bar>" by auto
   288   with `\<bar>x\<bar> \<le> \<bar>y\<bar>`
   289   have "\<bar>x\<bar>^n \<le> \<bar>y\<bar>^n" by (rule power_mono)
   290   thus ?thesis unfolding power_even_abs[OF `even n`] .
   291 qed
   292 
   293 lemma odd_pos: "odd (n::nat) \<Longrightarrow> 0 < n" by presburger
   294 
   295 lemma power_mono_odd: fixes x y :: "'a :: {recpower, ordered_idom}"
   296   assumes "odd n" and "x \<le> y"
   297   shows "x^n \<le> y^n"
   298 proof (cases "y < 0")
   299   case True with `x \<le> y` have "-y \<le> -x" and "0 \<le> -y" by auto
   300   hence "(-y)^n \<le> (-x)^n" by (rule power_mono)
   301   thus ?thesis unfolding power_minus_odd[OF `odd n`] by auto
   302 next
   303   case False
   304   show ?thesis
   305   proof (cases "x < 0")
   306     case True hence "n \<noteq> 0" and "x \<le> 0" using `odd n`[THEN odd_pos] by auto
   307     hence "x^n \<le> 0" unfolding power_le_zero_eq using `odd n` by auto
   308     moreover
   309     from `\<not> y < 0` have "0 \<le> y" by auto
   310     hence "0 \<le> y^n" by auto
   311     ultimately show ?thesis by auto
   312   next
   313     case False hence "0 \<le> x" by auto
   314     with `x \<le> y` show ?thesis using power_mono by auto
   315   qed
   316 qed
   317 
   318 subsection {* General Lemmas About Division *}
   319 
   320 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
   321 apply (induct "m")
   322 apply (simp_all add: mod_Suc)
   323 done
   324 
   325 declare Suc_times_mod_eq [of "number_of w", standard, simp]
   326 
   327 lemma [simp]: "n div k \<le> (Suc n) div k"
   328 by (simp add: div_le_mono) 
   329 
   330 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
   331 by arith
   332 
   333 lemma div_2_gt_zero [simp]: "(1::nat) < n ==> 0 < n div 2" 
   334 by arith
   335 
   336   (* Potential use of algebra : Equality modulo n*)
   337 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
   338 by (simp add: mult_ac add_ac)
   339 
   340 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
   341 proof -
   342   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
   343   also have "... = Suc m mod n" by (rule mod_mult_self3) 
   344   finally show ?thesis .
   345 qed
   346 
   347 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
   348 apply (subst mod_Suc [of m]) 
   349 apply (subst mod_Suc [of "m mod n"], simp) 
   350 done
   351 
   352 
   353 subsection {* More Even/Odd Results *}
   354  
   355 lemma even_mult_two_ex: "even(n) = (\<exists>m::nat. n = 2*m)" by presburger
   356 lemma odd_Suc_mult_two_ex: "odd(n) = (\<exists>m. n = Suc (2*m))" by presburger
   357 lemma even_add [simp]: "even(m + n::nat) = (even m = even n)"  by presburger
   358 
   359 lemma odd_add [simp]: "odd(m + n::nat) = (odd m \<noteq> odd n)" by presburger
   360 
   361 lemma div_Suc: "Suc a div c = a div c + Suc 0 div c +
   362     (a mod c + Suc 0 mod c) div c" 
   363   apply (subgoal_tac "Suc a = a + Suc 0")
   364   apply (erule ssubst)
   365   apply (rule div_add1_eq, simp)
   366   done
   367 
   368 lemma lemma_even_div2 [simp]: "even (n::nat) ==> (n + 1) div 2 = n div 2" by presburger
   369 
   370 lemma lemma_not_even_div2 [simp]: "~even n ==> (n + 1) div 2 = Suc (n div 2)"
   371 by presburger
   372 
   373 lemma even_num_iff: "0 < n ==> even n = (~ even(n - 1 :: nat))"  by presburger
   374 lemma even_even_mod_4_iff: "even (n::nat) = even (n mod 4)" by presburger
   375 
   376 lemma lemma_odd_mod_4_div_2: "n mod 4 = (3::nat) ==> odd((n - 1) div 2)" by presburger
   377 
   378 lemma lemma_even_mod_4_div_2: "n mod 4 = (1::nat) ==> even ((n - 1) div 2)"
   379   by presburger
   380 
   381 text {* Simplify, when the exponent is a numeral *}
   382 
   383 lemmas power_0_left_number_of = power_0_left [of "number_of w", standard]
   384 declare power_0_left_number_of [simp]
   385 
   386 lemmas zero_le_power_eq_number_of [simp] =
   387     zero_le_power_eq [of _ "number_of w", standard]
   388 
   389 lemmas zero_less_power_eq_number_of [simp] =
   390     zero_less_power_eq [of _ "number_of w", standard]
   391 
   392 lemmas power_le_zero_eq_number_of [simp] =
   393     power_le_zero_eq [of _ "number_of w", standard]
   394 
   395 lemmas power_less_zero_eq_number_of [simp] =
   396     power_less_zero_eq [of _ "number_of w", standard]
   397 
   398 lemmas zero_less_power_nat_eq_number_of [simp] =
   399     zero_less_power_nat_eq [of _ "number_of w", standard]
   400 
   401 lemmas power_eq_0_iff_number_of [simp] = power_eq_0_iff [of _ "number_of w", standard]
   402 
   403 lemmas power_even_abs_number_of [simp] = power_even_abs [of "number_of w" _, standard]
   404 
   405 
   406 subsection {* An Equivalence for @{term [source] "0 \<le> a^n"} *}
   407 
   408 lemma even_power_le_0_imp_0:
   409     "a ^ (2*k) \<le> (0::'a::{ordered_idom,recpower}) ==> a=0"
   410   by (induct k) (auto simp add: zero_le_mult_iff mult_le_0_iff power_Suc)
   411 
   412 lemma zero_le_power_iff[presburger]:
   413   "(0 \<le> a^n) = (0 \<le> (a::'a::{ordered_idom,recpower}) | even n)"
   414 proof cases
   415   assume even: "even n"
   416   then obtain k where "n = 2*k"
   417     by (auto simp add: even_nat_equiv_def2 numeral_2_eq_2)
   418   thus ?thesis by (simp add: zero_le_even_power even)
   419 next
   420   assume odd: "odd n"
   421   then obtain k where "n = Suc(2*k)"
   422     by (auto simp add: odd_nat_equiv_def2 numeral_2_eq_2)
   423   thus ?thesis
   424     by (auto simp add: power_Suc zero_le_mult_iff zero_le_even_power
   425              dest!: even_power_le_0_imp_0)
   426 qed
   427 
   428 
   429 subsection {* Miscellaneous *}
   430 
   431 lemma [presburger]:"(x + 1) div 2 = x div 2 \<longleftrightarrow> even (x::int)" by presburger
   432 lemma [presburger]: "(x + 1) div 2 = x div 2 + 1 \<longleftrightarrow> odd (x::int)" by presburger
   433 lemma even_plus_one_div_two: "even (x::int) ==> (x + 1) div 2 = x div 2"  by presburger
   434 lemma odd_plus_one_div_two: "odd (x::int) ==> (x + 1) div 2 = x div 2 + 1" by presburger
   435 
   436 lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
   437 lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
   438 lemma even_nat_plus_one_div_two: "even (x::nat) ==>
   439     (Suc x) div Suc (Suc 0) = x div Suc (Suc 0)" by presburger
   440 
   441 lemma odd_nat_plus_one_div_two: "odd (x::nat) ==>
   442     (Suc x) div Suc (Suc 0) = Suc (x div Suc (Suc 0))" by presburger
   443 
   444 end