src/Pure/drule.ML
author wenzelm
Thu Oct 23 15:28:01 2008 +0200 (2008-10-23)
changeset 28674 08a77c495dc1
parent 28618 fa09f7b8ffca
child 28713 135317cd34d6
permissions -rw-r--r--
renamed Thm.get_axiom_i to Thm.axiom;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val strip_imp_prems: cterm -> cterm list
    16   val strip_imp_concl: cterm -> cterm
    17   val cprems_of: thm -> cterm list
    18   val cterm_fun: (term -> term) -> (cterm -> cterm)
    19   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    20   val forall_intr_list: cterm list -> thm -> thm
    21   val forall_intr_frees: thm -> thm
    22   val forall_intr_vars: thm -> thm
    23   val forall_elim_list: cterm list -> thm -> thm
    24   val gen_all: thm -> thm
    25   val lift_all: cterm -> thm -> thm
    26   val freeze_thaw: thm -> thm * (thm -> thm)
    27   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    28   val implies_elim_list: thm -> thm list -> thm
    29   val implies_intr_list: cterm list -> thm -> thm
    30   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    31   val zero_var_indexes_list: thm list -> thm list
    32   val zero_var_indexes: thm -> thm
    33   val implies_intr_hyps: thm -> thm
    34   val standard: thm -> thm
    35   val standard': thm -> thm
    36   val rotate_prems: int -> thm -> thm
    37   val rearrange_prems: int list -> thm -> thm
    38   val RSN: thm * (int * thm) -> thm
    39   val RS: thm * thm -> thm
    40   val RLN: thm list * (int * thm list) -> thm list
    41   val RL: thm list * thm list -> thm list
    42   val MRS: thm list * thm -> thm
    43   val MRL: thm list list * thm list -> thm list
    44   val OF: thm * thm list -> thm
    45   val compose: thm * int * thm -> thm list
    46   val COMP: thm * thm -> thm
    47   val INCR_COMP: thm * thm -> thm
    48   val COMP_INCR: thm * thm -> thm
    49   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    50   val size_of_thm: thm -> int
    51   val reflexive_thm: thm
    52   val symmetric_thm: thm
    53   val transitive_thm: thm
    54   val symmetric_fun: thm -> thm
    55   val extensional: thm -> thm
    56   val equals_cong: thm
    57   val imp_cong: thm
    58   val swap_prems_eq: thm
    59   val asm_rl: thm
    60   val cut_rl: thm
    61   val revcut_rl: thm
    62   val thin_rl: thm
    63   val triv_forall_equality: thm
    64   val distinct_prems_rl: thm
    65   val swap_prems_rl: thm
    66   val equal_intr_rule: thm
    67   val equal_elim_rule1: thm
    68   val equal_elim_rule2: thm
    69   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    70 end;
    71 
    72 signature DRULE =
    73 sig
    74   include BASIC_DRULE
    75   val generalize: string list * string list -> thm -> thm
    76   val list_comb: cterm * cterm list -> cterm
    77   val strip_comb: cterm -> cterm * cterm list
    78   val strip_type: ctyp -> ctyp list * ctyp
    79   val beta_conv: cterm -> cterm -> cterm
    80   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    81   val flexflex_unique: thm -> thm
    82   val store_thm: bstring -> thm -> thm
    83   val store_standard_thm: bstring -> thm -> thm
    84   val store_thm_open: bstring -> thm -> thm
    85   val store_standard_thm_open: bstring -> thm -> thm
    86   val compose_single: thm * int * thm -> thm
    87   val imp_cong_rule: thm -> thm -> thm
    88   val arg_cong_rule: cterm -> thm -> thm
    89   val binop_cong_rule: cterm -> thm -> thm -> thm
    90   val fun_cong_rule: thm -> cterm -> thm
    91   val beta_eta_conversion: cterm -> thm
    92   val eta_long_conversion: cterm -> thm
    93   val eta_contraction_rule: thm -> thm
    94   val norm_hhf_eq: thm
    95   val norm_hhf_eqs: thm list
    96   val is_norm_hhf: term -> bool
    97   val norm_hhf: theory -> term -> term
    98   val norm_hhf_cterm: cterm -> cterm
    99   val protect: cterm -> cterm
   100   val protectI: thm
   101   val protectD: thm
   102   val protect_cong: thm
   103   val implies_intr_protected: cterm list -> thm -> thm
   104   val termI: thm
   105   val mk_term: cterm -> thm
   106   val dest_term: thm -> cterm
   107   val cterm_rule: (thm -> thm) -> cterm -> cterm
   108   val term_rule: theory -> (thm -> thm) -> term -> term
   109   val dummy_thm: thm
   110   val sort_constraintI: thm
   111   val sort_constraint_eq: thm
   112   val sort_triv: theory -> typ * sort -> thm list
   113   val unconstrainTs: thm -> thm
   114   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   115   val rename_bvars: (string * string) list -> thm -> thm
   116   val rename_bvars': string option list -> thm -> thm
   117   val incr_type_indexes: int -> thm -> thm
   118   val incr_indexes: thm -> thm -> thm
   119   val incr_indexes2: thm -> thm -> thm -> thm
   120   val remdups_rl: thm
   121   val multi_resolve: thm list -> thm -> thm Seq.seq
   122   val multi_resolves: thm list -> thm list -> thm Seq.seq
   123   val abs_def: thm -> thm
   124 end;
   125 
   126 structure Drule: DRULE =
   127 struct
   128 
   129 
   130 (** some cterm->cterm operations: faster than calling cterm_of! **)
   131 
   132 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   133 fun strip_imp_prems ct =
   134   let val (cA, cB) = Thm.dest_implies ct
   135   in cA :: strip_imp_prems cB end
   136   handle TERM _ => [];
   137 
   138 (* A1==>...An==>B  goes to B, where B is not an implication *)
   139 fun strip_imp_concl ct =
   140   (case Thm.term_of ct of
   141     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   142   | _ => ct);
   143 
   144 (*The premises of a theorem, as a cterm list*)
   145 val cprems_of = strip_imp_prems o cprop_of;
   146 
   147 fun cterm_fun f ct = Thm.cterm_of (Thm.theory_of_cterm ct) (f (Thm.term_of ct));
   148 fun ctyp_fun f cT = Thm.ctyp_of (Thm.theory_of_ctyp cT) (f (Thm.typ_of cT));
   149 
   150 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
   151 
   152 val implies = certify Logic.implies;
   153 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   154 
   155 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   156 fun list_implies([], B) = B
   157   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   158 
   159 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   160 fun list_comb (f, []) = f
   161   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   162 
   163 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   164 fun strip_comb ct =
   165   let
   166     fun stripc (p as (ct, cts)) =
   167       let val (ct1, ct2) = Thm.dest_comb ct
   168       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   169   in stripc (ct, []) end;
   170 
   171 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   172 fun strip_type cT = (case Thm.typ_of cT of
   173     Type ("fun", _) =>
   174       let
   175         val [cT1, cT2] = Thm.dest_ctyp cT;
   176         val (cTs, cT') = strip_type cT2
   177       in (cT1 :: cTs, cT') end
   178   | _ => ([], cT));
   179 
   180 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   181   of the meta-equality returned by the beta_conversion rule.*)
   182 fun beta_conv x y =
   183   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   184 
   185 
   186 
   187 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   188      Used for establishing default types (of variables) and sorts (of
   189      type variables) when reading another term.
   190      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   191 ***)
   192 
   193 fun types_sorts thm =
   194   let
   195     val vars = Thm.fold_terms Term.add_vars thm [];
   196     val frees = Thm.fold_terms Term.add_frees thm [];
   197     val tvars = Thm.fold_terms Term.add_tvars thm [];
   198     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   199     fun types (a, i) =
   200       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   201     fun sorts (a, i) =
   202       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   203   in (types, sorts) end;
   204 
   205 
   206 
   207 
   208 (** Standardization of rules **)
   209 
   210 (* type classes and sorts *)
   211 
   212 fun sort_triv thy (T, S) =
   213   let
   214     val certT = Thm.ctyp_of thy;
   215     val cT = certT T;
   216     fun class_triv c =
   217       Thm.class_triv thy c
   218       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   219   in map class_triv S end;
   220 
   221 fun unconstrainTs th =
   222   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   223     (Thm.fold_terms Term.add_tvars th []) th;
   224 
   225 (*Generalization over a list of variables*)
   226 val forall_intr_list = fold_rev forall_intr;
   227 
   228 (*Generalization over all suitable Free variables*)
   229 fun forall_intr_frees th =
   230     let
   231       val thy = Thm.theory_of_thm th;
   232       val {prop, hyps, tpairs, ...} = rep_thm th;
   233       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   234       val frees = Term.fold_aterms (fn Free v =>
   235         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   236     in fold (forall_intr o cterm_of thy o Free) frees th end;
   237 
   238 (*Generalization over Vars -- canonical order*)
   239 fun forall_intr_vars th =
   240   fold forall_intr
   241     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   242 
   243 fun outer_params t =
   244   let val vs = Term.strip_all_vars t
   245   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   246 
   247 (*generalize outermost parameters*)
   248 fun gen_all th =
   249   let
   250     val thy = Thm.theory_of_thm th;
   251     val {prop, maxidx, ...} = Thm.rep_thm th;
   252     val cert = Thm.cterm_of thy;
   253     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   254   in fold elim (outer_params prop) th end;
   255 
   256 (*lift vars wrt. outermost goal parameters
   257   -- reverses the effect of gen_all modulo higher-order unification*)
   258 fun lift_all goal th =
   259   let
   260     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   261     val cert = Thm.cterm_of thy;
   262     val maxidx = Thm.maxidx_of th;
   263     val ps = outer_params (Thm.term_of goal)
   264       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   265     val Ts = map Term.fastype_of ps;
   266     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   267       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   268   in
   269     th |> Thm.instantiate ([], inst)
   270     |> fold_rev (Thm.forall_intr o cert) ps
   271   end;
   272 
   273 (*direct generalization*)
   274 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   275 
   276 (*specialization over a list of cterms*)
   277 val forall_elim_list = fold forall_elim;
   278 
   279 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   280 val implies_intr_list = fold_rev implies_intr;
   281 
   282 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   283 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   284 
   285 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   286 fun zero_var_indexes_list [] = []
   287   | zero_var_indexes_list ths =
   288       let
   289         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   290         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   291         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   292         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   293         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   294       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   295 
   296 val zero_var_indexes = singleton zero_var_indexes_list;
   297 
   298 
   299 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   300     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   301 
   302 (*Discharge all hypotheses.*)
   303 fun implies_intr_hyps th =
   304   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   305 
   306 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   307   This step can lose information.*)
   308 fun flexflex_unique th =
   309   if null (tpairs_of th) then th else
   310     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   311       [th] => th
   312     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   313     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   314 
   315 
   316 (* legacy standard operations *)
   317 
   318 val standard' =
   319   implies_intr_hyps
   320   #> forall_intr_frees
   321   #> `Thm.maxidx_of
   322   #-> (fn maxidx =>
   323     Thm.forall_elim_vars (maxidx + 1)
   324     #> Thm.strip_shyps
   325     #> zero_var_indexes
   326     #> Thm.varifyT);
   327 
   328 val standard =
   329   flexflex_unique
   330   #> standard'
   331   #> Thm.close_derivation;
   332 
   333 
   334 (*Convert all Vars in a theorem to Frees.  Also return a function for
   335   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   336   Similar code in type/freeze_thaw*)
   337 
   338 fun freeze_thaw_robust th =
   339  let val fth = Thm.freezeT th
   340      val thy = Thm.theory_of_thm fth
   341      val {prop, tpairs, ...} = rep_thm fth
   342  in
   343    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   344        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   345      | vars =>
   346          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   347              val alist = map newName vars
   348              fun mk_inst (Var(v,T)) =
   349                  (cterm_of thy (Var(v,T)),
   350                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   351              val insts = map mk_inst vars
   352              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   353                  th' |> forall_intr_list (map #2 insts)
   354                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   355          in  (Thm.instantiate ([],insts) fth, thaw)  end
   356  end;
   357 
   358 (*Basic version of the function above. No option to rename Vars apart in thaw.
   359   The Frees created from Vars have nice names. FIXME: does not check for
   360   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   361 fun freeze_thaw th =
   362  let val fth = Thm.freezeT th
   363      val thy = Thm.theory_of_thm fth
   364      val {prop, tpairs, ...} = rep_thm fth
   365  in
   366    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   367        [] => (fth, fn x => x)
   368      | vars =>
   369          let fun newName (Var(ix,_), (pairs,used)) =
   370                    let val v = Name.variant used (string_of_indexname ix)
   371                    in  ((ix,v)::pairs, v::used)  end;
   372              val (alist, _) = List.foldr newName ([], Library.foldr add_term_names
   373                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   374              fun mk_inst (Var(v,T)) =
   375                  (cterm_of thy (Var(v,T)),
   376                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   377              val insts = map mk_inst vars
   378              fun thaw th' =
   379                  th' |> forall_intr_list (map #2 insts)
   380                      |> forall_elim_list (map #1 insts)
   381          in  (Thm.instantiate ([],insts) fth, thaw)  end
   382  end;
   383 
   384 (*Rotates a rule's premises to the left by k*)
   385 fun rotate_prems 0 = I
   386   | rotate_prems k = permute_prems 0 k;
   387 
   388 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   389 
   390 (* permute prems, where the i-th position in the argument list (counting from 0)
   391    gives the position within the original thm to be transferred to position i.
   392    Any remaining trailing positions are left unchanged. *)
   393 val rearrange_prems = let
   394   fun rearr new []      thm = thm
   395   |   rearr new (p::ps) thm = rearr (new+1)
   396      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   397      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   398   in rearr 0 end;
   399 
   400 (*Resolution: exactly one resolvent must be produced.*)
   401 fun tha RSN (i,thb) =
   402   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   403       ([th],_) => th
   404     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   405     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   406 
   407 (*resolution: P==>Q, Q==>R gives P==>R. *)
   408 fun tha RS thb = tha RSN (1,thb);
   409 
   410 (*For joining lists of rules*)
   411 fun thas RLN (i,thbs) =
   412   let val resolve = biresolution false (map (pair false) thas) i
   413       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   414   in maps resb thbs end;
   415 
   416 fun thas RL thbs = thas RLN (1,thbs);
   417 
   418 (*Resolve a list of rules against bottom_rl from right to left;
   419   makes proof trees*)
   420 fun rls MRS bottom_rl =
   421   let fun rs_aux i [] = bottom_rl
   422         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   423   in  rs_aux 1 rls  end;
   424 
   425 (*As above, but for rule lists*)
   426 fun rlss MRL bottom_rls =
   427   let fun rs_aux i [] = bottom_rls
   428         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   429   in  rs_aux 1 rlss  end;
   430 
   431 (*A version of MRS with more appropriate argument order*)
   432 fun bottom_rl OF rls = rls MRS bottom_rl;
   433 
   434 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   435   with no lifting or renaming!  Q may contain ==> or meta-quants
   436   ALWAYS deletes premise i *)
   437 fun compose(tha,i,thb) =
   438     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   439 
   440 fun compose_single (tha,i,thb) =
   441   case compose (tha,i,thb) of
   442     [th] => th
   443   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   444 
   445 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   446 fun tha COMP thb =
   447     case compose(tha,1,thb) of
   448         [th] => th
   449       | _ =>   raise THM("COMP", 1, [tha,thb]);
   450 
   451 
   452 (** theorem equality **)
   453 
   454 (*Useful "distance" function for BEST_FIRST*)
   455 val size_of_thm = size_of_term o Thm.full_prop_of;
   456 
   457 
   458 
   459 (*** Meta-Rewriting Rules ***)
   460 
   461 val read_prop = certify o SimpleSyntax.read_prop;
   462 
   463 fun store_thm name th =
   464   Context.>>> (Context.map_theory_result (PureThy.store_thm (name, th)));
   465 
   466 fun store_thm_open name th =
   467   Context.>>> (Context.map_theory_result (PureThy.store_thm_open (name, th)));
   468 
   469 fun store_standard_thm name th = store_thm name (standard th);
   470 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   471 
   472 val reflexive_thm =
   473   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   474   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   475 
   476 val symmetric_thm =
   477   let val xy = read_prop "x::'a == y::'a"
   478   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   479 
   480 val transitive_thm =
   481   let val xy = read_prop "x::'a == y::'a"
   482       val yz = read_prop "y::'a == z::'a"
   483       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   484   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   485 
   486 fun symmetric_fun thm = thm RS symmetric_thm;
   487 
   488 fun extensional eq =
   489   let val eq' =
   490     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   491   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   492 
   493 val equals_cong =
   494   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   495 
   496 val imp_cong =
   497   let
   498     val ABC = read_prop "A ==> B::prop == C::prop"
   499     val AB = read_prop "A ==> B"
   500     val AC = read_prop "A ==> C"
   501     val A = read_prop "A"
   502   in
   503     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   504       (implies_intr AB (implies_intr A
   505         (equal_elim (implies_elim (assume ABC) (assume A))
   506           (implies_elim (assume AB) (assume A)))))
   507       (implies_intr AC (implies_intr A
   508         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   509           (implies_elim (assume AC) (assume A)))))))
   510   end;
   511 
   512 val swap_prems_eq =
   513   let
   514     val ABC = read_prop "A ==> B ==> C"
   515     val BAC = read_prop "B ==> A ==> C"
   516     val A = read_prop "A"
   517     val B = read_prop "B"
   518   in
   519     store_standard_thm_open "swap_prems_eq" (equal_intr
   520       (implies_intr ABC (implies_intr B (implies_intr A
   521         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   522       (implies_intr BAC (implies_intr A (implies_intr B
   523         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   524   end;
   525 
   526 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   527 
   528 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   529 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   530 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   531 
   532 local
   533   val dest_eq = Thm.dest_equals o cprop_of
   534   val rhs_of = snd o dest_eq
   535 in
   536 fun beta_eta_conversion t =
   537   let val thm = beta_conversion true t
   538   in transitive thm (eta_conversion (rhs_of thm)) end
   539 end;
   540 
   541 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   542   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   543 
   544 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   545 fun eta_contraction_rule th =
   546   equal_elim (eta_conversion (cprop_of th)) th;
   547 
   548 
   549 (* abs_def *)
   550 
   551 (*
   552    f ?x1 ... ?xn == u
   553   --------------------
   554    f == %x1 ... xn. u
   555 *)
   556 
   557 local
   558 
   559 fun contract_lhs th =
   560   Thm.transitive (Thm.symmetric (beta_eta_conversion
   561     (fst (Thm.dest_equals (cprop_of th))))) th;
   562 
   563 fun var_args ct =
   564   (case try Thm.dest_comb ct of
   565     SOME (f, arg) =>
   566       (case Thm.term_of arg of
   567         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   568       | _ => [])
   569   | NONE => []);
   570 
   571 in
   572 
   573 fun abs_def th =
   574   let
   575     val th' = contract_lhs th;
   576     val args = var_args (Thm.lhs_of th');
   577   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   578 
   579 end;
   580 
   581 
   582 
   583 (*** Some useful meta-theorems ***)
   584 
   585 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   586 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   587 val _ = store_thm "_" asm_rl;
   588 
   589 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   590 val cut_rl =
   591   store_standard_thm_open "cut_rl"
   592     (Thm.trivial (read_prop "?psi ==> ?theta"));
   593 
   594 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   595      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   596 val revcut_rl =
   597   let val V = read_prop "V"
   598       and VW = read_prop "V ==> W";
   599   in
   600     store_standard_thm_open "revcut_rl"
   601       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   602   end;
   603 
   604 (*for deleting an unwanted assumption*)
   605 val thin_rl =
   606   let val V = read_prop "V"
   607       and W = read_prop "W";
   608   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   609 
   610 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   611 val triv_forall_equality =
   612   let val V  = read_prop "V"
   613       and QV = read_prop "!!x::'a. V"
   614       and x  = certify (Free ("x", Term.aT []));
   615   in
   616     store_standard_thm_open "triv_forall_equality"
   617       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   618         (implies_intr V  (forall_intr x (assume V))))
   619   end;
   620 
   621 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   622    (PROP ?Phi ==> PROP ?Psi)
   623 *)
   624 val distinct_prems_rl =
   625   let
   626     val AAB = read_prop "Phi ==> Phi ==> Psi"
   627     val A = read_prop "Phi";
   628   in
   629     store_standard_thm_open "distinct_prems_rl"
   630       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   631   end;
   632 
   633 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   634    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   635    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   636 *)
   637 val swap_prems_rl =
   638   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   639       val major = assume cmajor;
   640       val cminor1 = read_prop "PhiA";
   641       val minor1 = assume cminor1;
   642       val cminor2 = read_prop "PhiB";
   643       val minor2 = assume cminor2;
   644   in store_standard_thm_open "swap_prems_rl"
   645        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   646          (implies_elim (implies_elim major minor1) minor2))))
   647   end;
   648 
   649 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   650    ==> PROP ?phi == PROP ?psi
   651    Introduction rule for == as a meta-theorem.
   652 *)
   653 val equal_intr_rule =
   654   let val PQ = read_prop "phi ==> psi"
   655       and QP = read_prop "psi ==> phi"
   656   in
   657     store_standard_thm_open "equal_intr_rule"
   658       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   659   end;
   660 
   661 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   662 val equal_elim_rule1 =
   663   let val eq = read_prop "phi::prop == psi::prop"
   664       and P = read_prop "phi"
   665   in store_standard_thm_open "equal_elim_rule1"
   666     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   667   end;
   668 
   669 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   670 val equal_elim_rule2 =
   671   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   672 
   673 (* PROP ?phi ==> PROP ?phi ==> PROP ?psi ==> PROP ?psi *)
   674 val remdups_rl =
   675   let val P = read_prop "phi" and Q = read_prop "psi";
   676   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   677 
   678 
   679 
   680 (** embedded terms and types **)
   681 
   682 local
   683   val A = certify (Free ("A", propT));
   684   val axiom = Thm.unvarify o Thm.axiom (Context.the_theory (Context.the_thread_data ()));
   685   val prop_def = axiom "Pure.prop_def";
   686   val term_def = axiom "Pure.term_def";
   687   val sort_constraint_def = axiom "Pure.sort_constraint_def";
   688   val C = Thm.lhs_of sort_constraint_def;
   689   val T = Thm.dest_arg C;
   690   val CA = mk_implies (C, A);
   691 in
   692 
   693 (* protect *)
   694 
   695 val protect = Thm.capply (certify Logic.protectC);
   696 
   697 val protectI = store_thm "protectI" (Thm.kind_rule Thm.internalK (standard
   698     (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   699 
   700 val protectD = store_thm "protectD" (Thm.kind_rule Thm.internalK (standard
   701     (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   702 
   703 val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   704 
   705 fun implies_intr_protected asms th =
   706   let val asms' = map protect asms in
   707     implies_elim_list
   708       (implies_intr_list asms th)
   709       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   710     |> implies_intr_list asms'
   711   end;
   712 
   713 
   714 (* term *)
   715 
   716 val termI = store_thm "termI" (Thm.kind_rule Thm.internalK (standard
   717     (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   718 
   719 fun mk_term ct =
   720   let
   721     val thy = Thm.theory_of_cterm ct;
   722     val cert = Thm.cterm_of thy;
   723     val certT = Thm.ctyp_of thy;
   724     val T = Thm.typ_of (Thm.ctyp_of_term ct);
   725     val a = certT (TVar (("'a", 0), []));
   726     val x = cert (Var (("x", 0), T));
   727   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   728 
   729 fun dest_term th =
   730   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   731     if can Logic.dest_term (Thm.term_of cprop) then
   732       Thm.dest_arg cprop
   733     else raise THM ("dest_term", 0, [th])
   734   end;
   735 
   736 fun cterm_rule f = dest_term o f o mk_term;
   737 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   738 
   739 val dummy_thm = mk_term (certify (Term.dummy_pattern propT));
   740 
   741 
   742 (* sort_constraint *)
   743 
   744 val sort_constraintI = store_thm "sort_constraintI" (Thm.kind_rule Thm.internalK (standard
   745   (Thm.equal_elim (Thm.symmetric sort_constraint_def) (mk_term T))));
   746 
   747 val sort_constraint_eq = store_thm "sort_constraint_eq" (Thm.kind_rule Thm.internalK (standard
   748   (Thm.equal_intr
   749     (Thm.implies_intr CA (Thm.implies_elim (Thm.assume CA) (Thm.unvarify sort_constraintI)))
   750     (implies_intr_list [A, C] (Thm.assume A)))));
   751 
   752 end;
   753 
   754 
   755 (* HHF normalization *)
   756 
   757 (* (PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x)) *)
   758 val norm_hhf_eq =
   759   let
   760     val aT = TFree ("'a", []);
   761     val all = Term.all aT;
   762     val x = Free ("x", aT);
   763     val phi = Free ("phi", propT);
   764     val psi = Free ("psi", aT --> propT);
   765 
   766     val cx = certify x;
   767     val cphi = certify phi;
   768     val lhs = certify (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   769     val rhs = certify (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   770   in
   771     Thm.equal_intr
   772       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   773         |> Thm.forall_elim cx
   774         |> Thm.implies_intr cphi
   775         |> Thm.forall_intr cx
   776         |> Thm.implies_intr lhs)
   777       (Thm.implies_elim
   778           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   779         |> Thm.forall_intr cx
   780         |> Thm.implies_intr cphi
   781         |> Thm.implies_intr rhs)
   782     |> store_standard_thm_open "norm_hhf_eq"
   783   end;
   784 
   785 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   786 val norm_hhf_eqs = [norm_hhf_eq, sort_constraint_eq];
   787 
   788 fun is_norm_hhf tm =
   789   let
   790     fun is_norm (Const ("Pure.sort_constraint", _)) = false
   791       | is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   792       | is_norm (t $ u) = is_norm t andalso is_norm u
   793       | is_norm (Abs (_, _, t)) = is_norm t
   794       | is_norm _ = true;
   795   in is_norm (Envir.beta_eta_contract tm) end;
   796 
   797 fun norm_hhf thy t =
   798   if is_norm_hhf t then t
   799   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   800 
   801 fun norm_hhf_cterm ct =
   802   if is_norm_hhf (Thm.term_of ct) then ct
   803   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   804 
   805 
   806 (* var indexes *)
   807 
   808 (*Increment the indexes of only the type variables*)
   809 fun incr_type_indexes inc th =
   810   let val tvs = term_tvars (prop_of th)
   811       and thy = theory_of_thm th
   812       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   813   in Thm.instantiate (map inc_tvar tvs, []) th end;
   814 
   815 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   816 
   817 fun incr_indexes2 th1 th2 =
   818   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   819 
   820 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   821 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   822 
   823 
   824 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   825 
   826 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   827 fun instantiate instpair th =
   828   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   829 
   830 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   831   Instantiates distinct Vars by terms, inferring type instantiations. *)
   832 local
   833   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   834     let
   835         val thyt = Thm.theory_of_cterm ct;
   836         val thyu = Thm.theory_of_cterm cu;
   837         val {t, T, maxidx = maxt, ...} = Thm.rep_cterm ct;
   838         val {t = u, T = U, maxidx = maxu, ...} = Thm.rep_cterm cu;
   839         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   840         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   841         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   842           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   843             Syntax.string_of_typ_global thy' (Envir.norm_type tye T) ^
   844             "\nof variable " ^
   845             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) t) ^
   846             "\ncannot be unified with type\n" ^
   847             Syntax.string_of_typ_global thy' (Envir.norm_type tye U) ^ "\nof term " ^
   848             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) u),
   849             [T, U], [t, u])
   850     in  (thy', tye', maxi')  end;
   851 in
   852 fun cterm_instantiate [] th = th
   853   | cterm_instantiate ctpairs0 th =
   854   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   855       fun instT(ct,cu) =
   856         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   857         in (inst ct, inst cu) end
   858       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   859   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   860   handle TERM _ =>
   861            raise THM("cterm_instantiate: incompatible theories",0,[th])
   862        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   863 end;
   864 
   865 
   866 
   867 (** variations on instantiate **)
   868 
   869 (* instantiate by left-to-right occurrence of variables *)
   870 
   871 fun instantiate' cTs cts thm =
   872   let
   873     fun err msg =
   874       raise TYPE ("instantiate': " ^ msg,
   875         map_filter (Option.map Thm.typ_of) cTs,
   876         map_filter (Option.map Thm.term_of) cts);
   877 
   878     fun inst_of (v, ct) =
   879       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   880         handle TYPE (msg, _, _) => err msg;
   881 
   882     fun tyinst_of (v, cT) =
   883       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   884         handle TYPE (msg, _, _) => err msg;
   885 
   886     fun zip_vars xs ys =
   887       zip_options xs ys handle Library.UnequalLengths =>
   888         err "more instantiations than variables in thm";
   889 
   890     (*instantiate types first!*)
   891     val thm' =
   892       if forall is_none cTs then thm
   893       else Thm.instantiate
   894         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   895     val thm'' =
   896       if forall is_none cts then thm'
   897       else Thm.instantiate
   898         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   899     in thm'' end;
   900 
   901 
   902 
   903 (** renaming of bound variables **)
   904 
   905 (* replace bound variables x_i in thm by y_i *)
   906 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   907 
   908 fun rename_bvars [] thm = thm
   909   | rename_bvars vs thm =
   910       let
   911         val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   912         fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   913           | ren (t $ u) = ren t $ ren u
   914           | ren t = t;
   915       in equal_elim (reflexive (cert (ren (Thm.prop_of thm)))) thm end;
   916 
   917 
   918 (* renaming in left-to-right order *)
   919 
   920 fun rename_bvars' xs thm =
   921   let
   922     val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   923     val prop = Thm.prop_of thm;
   924     fun rename [] t = ([], t)
   925       | rename (x' :: xs) (Abs (x, T, t)) =
   926           let val (xs', t') = rename xs t
   927           in (xs', Abs (the_default x x', T, t')) end
   928       | rename xs (t $ u) =
   929           let
   930             val (xs', t') = rename xs t;
   931             val (xs'', u') = rename xs' u
   932           in (xs'', t' $ u') end
   933       | rename xs t = (xs, t);
   934   in case rename xs prop of
   935       ([], prop') => equal_elim (reflexive (cert prop')) thm
   936     | _ => error "More names than abstractions in theorem"
   937   end;
   938 
   939 
   940 
   941 (** multi_resolve **)
   942 
   943 local
   944 
   945 fun res th i rule =
   946   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   947 
   948 fun multi_res _ [] rule = Seq.single rule
   949   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   950 
   951 in
   952 
   953 val multi_resolve = multi_res 1;
   954 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   955 
   956 end;
   957 
   958 end;
   959 
   960 structure BasicDrule: BASIC_DRULE = Drule;
   961 open BasicDrule;