src/HOL/Relation.thy
author haftmann
Thu Mar 22 18:54:39 2012 +0100 (2012-03-22)
changeset 47087 08c22e8ffe70
parent 46982 144d94446378
child 47375 8e6a45f1bf8f
child 47433 07f4bf913230
permissions -rw-r--r--
fixed typo
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Datatype Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare INF1_I [intro!]
    34 declare INF2_I [intro!]
    35 declare INF1_D [elim]
    36 declare INF2_D [elim]
    37 declare INF1_E [elim]
    38 declare INF2_E [elim]
    39 declare SUP1_I [intro]
    40 declare SUP2_I [intro]
    41 declare SUP1_E [elim!]
    42 declare SUP2_E [elim!]
    43 
    44 subsection {* Fundamental *}
    45 
    46 subsubsection {* Relations as sets of pairs *}
    47 
    48 type_synonym 'a rel = "('a * 'a) set"
    49 
    50 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    51   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    52   by auto
    53 
    54 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    55   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    56     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    57   using lfp_induct_set [of "(a, b)" f "prod_case P"] by auto
    58 
    59 
    60 subsubsection {* Conversions between set and predicate relations *}
    61 
    62 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    63   by (simp add: set_eq_iff fun_eq_iff)
    64 
    65 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    66   by (simp add: set_eq_iff fun_eq_iff)
    67 
    68 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    69   by (simp add: subset_iff le_fun_def)
    70 
    71 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    72   by (simp add: subset_iff le_fun_def)
    73 
    74 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    75   by (auto simp add: fun_eq_iff)
    76 
    77 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    78   by (auto simp add: fun_eq_iff)
    79 
    80 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    81   by (auto simp add: fun_eq_iff)
    82 
    83 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    84   by (auto simp add: fun_eq_iff)
    85 
    86 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    87   by (simp add: inf_fun_def)
    88 
    89 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
    90   by (simp add: inf_fun_def)
    91 
    92 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    93   by (simp add: sup_fun_def)
    94 
    95 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    96   by (simp add: sup_fun_def)
    97 
    98 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
    99   by (simp add: fun_eq_iff)
   100 
   101 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   102   by (simp add: fun_eq_iff)
   103 
   104 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   105   by (simp add: fun_eq_iff)
   106 
   107 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   108   by (simp add: fun_eq_iff)
   109 
   110 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   111   by (simp add: fun_eq_iff)
   112 
   113 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   114   by (simp add: fun_eq_iff)
   115 
   116 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (prod_case ` S) Collect)"
   117   by (simp add: fun_eq_iff)
   118 
   119 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   120   by (simp add: fun_eq_iff)
   121 
   122 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   123   by (simp add: fun_eq_iff)
   124 
   125 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   126   by (simp add: fun_eq_iff)
   127 
   128 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (prod_case ` S) Collect)"
   129   by (simp add: fun_eq_iff)
   130 
   131 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   132   by (simp add: fun_eq_iff)
   133 
   134 
   135 subsection {* Properties of relations *}
   136 
   137 subsubsection {* Reflexivity *}
   138 
   139 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   140 where
   141   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   142 
   143 abbreviation refl :: "'a rel \<Rightarrow> bool"
   144 where -- {* reflexivity over a type *}
   145   "refl \<equiv> refl_on UNIV"
   146 
   147 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   148 where
   149   "reflp r \<longleftrightarrow> refl {(x, y). r x y}"
   150 
   151 lemma reflp_refl_eq [pred_set_conv]:
   152   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   153   by (simp add: refl_on_def reflp_def)
   154 
   155 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   156   by (unfold refl_on_def) (iprover intro!: ballI)
   157 
   158 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   159   by (unfold refl_on_def) blast
   160 
   161 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   162   by (unfold refl_on_def) blast
   163 
   164 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   165   by (unfold refl_on_def) blast
   166 
   167 lemma reflpI:
   168   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   169   by (auto intro: refl_onI simp add: reflp_def)
   170 
   171 lemma reflpE:
   172   assumes "reflp r"
   173   obtains "r x x"
   174   using assms by (auto dest: refl_onD simp add: reflp_def)
   175 
   176 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   177   by (unfold refl_on_def) blast
   178 
   179 lemma reflp_inf:
   180   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   181   by (auto intro: reflpI elim: reflpE)
   182 
   183 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   184   by (unfold refl_on_def) blast
   185 
   186 lemma reflp_sup:
   187   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   188   by (auto intro: reflpI elim: reflpE)
   189 
   190 lemma refl_on_INTER:
   191   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   192   by (unfold refl_on_def) fast
   193 
   194 lemma refl_on_UNION:
   195   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   196   by (unfold refl_on_def) blast
   197 
   198 lemma refl_on_empty [simp]: "refl_on {} {}"
   199   by (simp add:refl_on_def)
   200 
   201 lemma refl_on_def' [nitpick_unfold, code]:
   202   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   203   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   204 
   205 
   206 subsubsection {* Irreflexivity *}
   207 
   208 definition irrefl :: "'a rel \<Rightarrow> bool"
   209 where
   210   "irrefl r \<longleftrightarrow> (\<forall>x. (x, x) \<notin> r)"
   211 
   212 lemma irrefl_distinct [code]:
   213   "irrefl r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<noteq> y)"
   214   by (auto simp add: irrefl_def)
   215 
   216 
   217 subsubsection {* Symmetry *}
   218 
   219 definition sym :: "'a rel \<Rightarrow> bool"
   220 where
   221   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   222 
   223 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   224 where
   225   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   226 
   227 lemma symp_sym_eq [pred_set_conv]:
   228   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   229   by (simp add: sym_def symp_def)
   230 
   231 lemma symI:
   232   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   233   by (unfold sym_def) iprover
   234 
   235 lemma sympI:
   236   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   237   by (fact symI [to_pred])
   238 
   239 lemma symE:
   240   assumes "sym r" and "(b, a) \<in> r"
   241   obtains "(a, b) \<in> r"
   242   using assms by (simp add: sym_def)
   243 
   244 lemma sympE:
   245   assumes "symp r" and "r b a"
   246   obtains "r a b"
   247   using assms by (rule symE [to_pred])
   248 
   249 lemma symD:
   250   assumes "sym r" and "(b, a) \<in> r"
   251   shows "(a, b) \<in> r"
   252   using assms by (rule symE)
   253 
   254 lemma sympD:
   255   assumes "symp r" and "r b a"
   256   shows "r a b"
   257   using assms by (rule symD [to_pred])
   258 
   259 lemma sym_Int:
   260   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   261   by (fast intro: symI elim: symE)
   262 
   263 lemma symp_inf:
   264   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   265   by (fact sym_Int [to_pred])
   266 
   267 lemma sym_Un:
   268   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   269   by (fast intro: symI elim: symE)
   270 
   271 lemma symp_sup:
   272   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   273   by (fact sym_Un [to_pred])
   274 
   275 lemma sym_INTER:
   276   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   277   by (fast intro: symI elim: symE)
   278 
   279 lemma symp_INF:
   280   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFI S r)"
   281   by (fact sym_INTER [to_pred])
   282 
   283 lemma sym_UNION:
   284   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   285   by (fast intro: symI elim: symE)
   286 
   287 lemma symp_SUP:
   288   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPR S r)"
   289   by (fact sym_UNION [to_pred])
   290 
   291 
   292 subsubsection {* Antisymmetry *}
   293 
   294 definition antisym :: "'a rel \<Rightarrow> bool"
   295 where
   296   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   297 
   298 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   299 where
   300   "antisymP r \<equiv> antisym {(x, y). r x y}"
   301 
   302 lemma antisymI:
   303   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   304   by (unfold antisym_def) iprover
   305 
   306 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   307   by (unfold antisym_def) iprover
   308 
   309 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   310   by (unfold antisym_def) blast
   311 
   312 lemma antisym_empty [simp]: "antisym {}"
   313   by (unfold antisym_def) blast
   314 
   315 
   316 subsubsection {* Transitivity *}
   317 
   318 definition trans :: "'a rel \<Rightarrow> bool"
   319 where
   320   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   321 
   322 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   323 where
   324   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   325 
   326 lemma transp_trans_eq [pred_set_conv]:
   327   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   328   by (simp add: trans_def transp_def)
   329 
   330 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   331 where -- {* FIXME drop *}
   332   "transP r \<equiv> trans {(x, y). r x y}"
   333 
   334 lemma transI:
   335   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   336   by (unfold trans_def) iprover
   337 
   338 lemma transpI:
   339   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   340   by (fact transI [to_pred])
   341 
   342 lemma transE:
   343   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   344   obtains "(x, z) \<in> r"
   345   using assms by (unfold trans_def) iprover
   346 
   347 lemma transpE:
   348   assumes "transp r" and "r x y" and "r y z"
   349   obtains "r x z"
   350   using assms by (rule transE [to_pred])
   351 
   352 lemma transD:
   353   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   354   shows "(x, z) \<in> r"
   355   using assms by (rule transE)
   356 
   357 lemma transpD:
   358   assumes "transp r" and "r x y" and "r y z"
   359   shows "r x z"
   360   using assms by (rule transD [to_pred])
   361 
   362 lemma trans_Int:
   363   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   364   by (fast intro: transI elim: transE)
   365 
   366 lemma transp_inf:
   367   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   368   by (fact trans_Int [to_pred])
   369 
   370 lemma trans_INTER:
   371   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   372   by (fast intro: transI elim: transD)
   373 
   374 (* FIXME thm trans_INTER [to_pred] *)
   375 
   376 lemma trans_join [code]:
   377   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   378   by (auto simp add: trans_def)
   379 
   380 lemma transp_trans:
   381   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   382   by (simp add: trans_def transp_def)
   383 
   384 
   385 subsubsection {* Totality *}
   386 
   387 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   388 where
   389   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   390 
   391 abbreviation "total \<equiv> total_on UNIV"
   392 
   393 lemma total_on_empty [simp]: "total_on {} r"
   394   by (simp add: total_on_def)
   395 
   396 
   397 subsubsection {* Single valued relations *}
   398 
   399 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   400 where
   401   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   402 
   403 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   404   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   405 
   406 lemma single_valuedI:
   407   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   408   by (unfold single_valued_def)
   409 
   410 lemma single_valuedD:
   411   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   412   by (simp add: single_valued_def)
   413 
   414 lemma single_valued_subset:
   415   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   416   by (unfold single_valued_def) blast
   417 
   418 
   419 subsection {* Relation operations *}
   420 
   421 subsubsection {* The identity relation *}
   422 
   423 definition Id :: "'a rel"
   424 where
   425   "Id = {p. \<exists>x. p = (x, x)}"
   426 
   427 lemma IdI [intro]: "(a, a) : Id"
   428   by (simp add: Id_def)
   429 
   430 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   431   by (unfold Id_def) (iprover elim: CollectE)
   432 
   433 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   434   by (unfold Id_def) blast
   435 
   436 lemma refl_Id: "refl Id"
   437   by (simp add: refl_on_def)
   438 
   439 lemma antisym_Id: "antisym Id"
   440   -- {* A strange result, since @{text Id} is also symmetric. *}
   441   by (simp add: antisym_def)
   442 
   443 lemma sym_Id: "sym Id"
   444   by (simp add: sym_def)
   445 
   446 lemma trans_Id: "trans Id"
   447   by (simp add: trans_def)
   448 
   449 lemma single_valued_Id [simp]: "single_valued Id"
   450   by (unfold single_valued_def) blast
   451 
   452 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   453   by (simp add:irrefl_def)
   454 
   455 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   456   unfolding antisym_def trans_def by blast
   457 
   458 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   459   by (simp add: total_on_def)
   460 
   461 
   462 subsubsection {* Diagonal: identity over a set *}
   463 
   464 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   465 where
   466   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   467 
   468 lemma Id_on_empty [simp]: "Id_on {} = {}"
   469   by (simp add: Id_on_def) 
   470 
   471 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   472   by (simp add: Id_on_def)
   473 
   474 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   475   by (rule Id_on_eqI) (rule refl)
   476 
   477 lemma Id_onE [elim!]:
   478   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   479   -- {* The general elimination rule. *}
   480   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   481 
   482 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   483   by blast
   484 
   485 lemma Id_on_def' [nitpick_unfold]:
   486   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   487   by auto
   488 
   489 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   490   by blast
   491 
   492 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   493   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   494 
   495 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   496   by (unfold antisym_def) blast
   497 
   498 lemma sym_Id_on [simp]: "sym (Id_on A)"
   499   by (rule symI) clarify
   500 
   501 lemma trans_Id_on [simp]: "trans (Id_on A)"
   502   by (fast intro: transI elim: transD)
   503 
   504 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   505   by (unfold single_valued_def) blast
   506 
   507 
   508 subsubsection {* Composition *}
   509 
   510 inductive_set rel_comp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   511   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   512 where
   513   rel_compI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   514 
   515 abbreviation pred_comp (infixr "OO" 75) where
   516   "pred_comp \<equiv> rel_compp"
   517 
   518 lemmas pred_compI = rel_compp.intros
   519 
   520 text {*
   521   For historic reasons, the elimination rules are not wholly corresponding.
   522   Feel free to consolidate this.
   523 *}
   524 
   525 inductive_cases rel_compEpair: "(a, c) \<in> r O s"
   526 inductive_cases pred_compE [elim!]: "(r OO s) a c"
   527 
   528 lemma rel_compE [elim!]: "xz \<in> r O s \<Longrightarrow>
   529   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   530   by (cases xz) (simp, erule rel_compEpair, iprover)
   531 
   532 lemmas pred_comp_rel_comp_eq = rel_compp_rel_comp_eq
   533 
   534 lemma R_O_Id [simp]:
   535   "R O Id = R"
   536   by fast
   537 
   538 lemma Id_O_R [simp]:
   539   "Id O R = R"
   540   by fast
   541 
   542 lemma rel_comp_empty1 [simp]:
   543   "{} O R = {}"
   544   by blast
   545 
   546 lemma pred_comp_bot1 [simp]:
   547   "\<bottom> OO R = \<bottom>"
   548   by (fact rel_comp_empty1 [to_pred])
   549 
   550 lemma rel_comp_empty2 [simp]:
   551   "R O {} = {}"
   552   by blast
   553 
   554 lemma pred_comp_bot2 [simp]:
   555   "R OO \<bottom> = \<bottom>"
   556   by (fact rel_comp_empty2 [to_pred])
   557 
   558 lemma O_assoc:
   559   "(R O S) O T = R O (S O T)"
   560   by blast
   561 
   562 
   563 lemma pred_comp_assoc:
   564   "(r OO s) OO t = r OO (s OO t)"
   565   by (fact O_assoc [to_pred])
   566 
   567 lemma trans_O_subset:
   568   "trans r \<Longrightarrow> r O r \<subseteq> r"
   569   by (unfold trans_def) blast
   570 
   571 lemma transp_pred_comp_less_eq:
   572   "transp r \<Longrightarrow> r OO r \<le> r "
   573   by (fact trans_O_subset [to_pred])
   574 
   575 lemma rel_comp_mono:
   576   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   577   by blast
   578 
   579 lemma pred_comp_mono:
   580   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   581   by (fact rel_comp_mono [to_pred])
   582 
   583 lemma rel_comp_subset_Sigma:
   584   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   585   by blast
   586 
   587 lemma rel_comp_distrib [simp]:
   588   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   589   by auto
   590 
   591 lemma pred_comp_distrib [simp]:
   592   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   593   by (fact rel_comp_distrib [to_pred])
   594 
   595 lemma rel_comp_distrib2 [simp]:
   596   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   597   by auto
   598 
   599 lemma pred_comp_distrib2 [simp]:
   600   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   601   by (fact rel_comp_distrib2 [to_pred])
   602 
   603 lemma rel_comp_UNION_distrib:
   604   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   605   by auto
   606 
   607 (* FIXME thm rel_comp_UNION_distrib [to_pred] *)
   608 
   609 lemma rel_comp_UNION_distrib2:
   610   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   611   by auto
   612 
   613 (* FIXME thm rel_comp_UNION_distrib2 [to_pred] *)
   614 
   615 lemma single_valued_rel_comp:
   616   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   617   by (unfold single_valued_def) blast
   618 
   619 lemma rel_comp_unfold:
   620   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   621   by (auto simp add: set_eq_iff)
   622 
   623 
   624 subsubsection {* Converse *}
   625 
   626 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   627   for r :: "('a \<times> 'b) set"
   628 where
   629   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   630 
   631 notation (xsymbols)
   632   converse  ("(_\<inverse>)" [1000] 999)
   633 
   634 notation
   635   conversep ("(_^--1)" [1000] 1000)
   636 
   637 notation (xsymbols)
   638   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   639 
   640 lemma converseI [sym]:
   641   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   642   by (fact converse.intros)
   643 
   644 lemma conversepI (* CANDIDATE [sym] *):
   645   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   646   by (fact conversep.intros)
   647 
   648 lemma converseD [sym]:
   649   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   650   by (erule converse.cases) iprover
   651 
   652 lemma conversepD (* CANDIDATE [sym] *):
   653   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   654   by (fact converseD [to_pred])
   655 
   656 lemma converseE [elim!]:
   657   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   658   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   659   by (cases yx) (simp, erule converse.cases, iprover)
   660 
   661 lemmas conversepE [elim!] = conversep.cases
   662 
   663 lemma converse_iff [iff]:
   664   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   665   by (auto intro: converseI)
   666 
   667 lemma conversep_iff [iff]:
   668   "r\<inverse>\<inverse> a b = r b a"
   669   by (fact converse_iff [to_pred])
   670 
   671 lemma converse_converse [simp]:
   672   "(r\<inverse>)\<inverse> = r"
   673   by (simp add: set_eq_iff)
   674 
   675 lemma conversep_conversep [simp]:
   676   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   677   by (fact converse_converse [to_pred])
   678 
   679 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   680   by blast
   681 
   682 lemma converse_pred_comp: "(r OO s)^--1 = s^--1 OO r^--1"
   683   by (iprover intro: order_antisym conversepI pred_compI
   684     elim: pred_compE dest: conversepD)
   685 
   686 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   687   by blast
   688 
   689 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   690   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   691 
   692 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   693   by blast
   694 
   695 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   696   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   697 
   698 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   699   by fast
   700 
   701 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   702   by blast
   703 
   704 lemma converse_Id [simp]: "Id^-1 = Id"
   705   by blast
   706 
   707 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   708   by blast
   709 
   710 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   711   by (unfold refl_on_def) auto
   712 
   713 lemma sym_converse [simp]: "sym (converse r) = sym r"
   714   by (unfold sym_def) blast
   715 
   716 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   717   by (unfold antisym_def) blast
   718 
   719 lemma trans_converse [simp]: "trans (converse r) = trans r"
   720   by (unfold trans_def) blast
   721 
   722 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   723   by (unfold sym_def) fast
   724 
   725 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   726   by (unfold sym_def) blast
   727 
   728 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   729   by (unfold sym_def) blast
   730 
   731 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   732   by (auto simp: total_on_def)
   733 
   734 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   735   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   736    apply simp
   737    apply (rule iffI)
   738     apply (erule finite_imageD [unfolded inj_on_def])
   739     apply (simp split add: split_split)
   740    apply (erule finite_imageI)
   741   apply (simp add: set_eq_iff image_def, auto)
   742   apply (rule bexI)
   743    prefer 2 apply assumption
   744   apply simp
   745   done
   746 
   747 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   748   by (auto simp add: fun_eq_iff)
   749 
   750 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   751   by (auto simp add: fun_eq_iff)
   752 
   753 lemma converse_unfold:
   754   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   755   by (simp add: set_eq_iff)
   756 
   757 
   758 subsubsection {* Domain, range and field *}
   759 
   760 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   761   for r :: "('a \<times> 'b) set"
   762 where
   763   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   764 
   765 abbreviation (input) "DomainP \<equiv> Domainp"
   766 
   767 lemmas DomainPI = Domainp.DomainI
   768 
   769 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   770 inductive_cases DomainpE [elim!]: "Domainp r a"
   771 
   772 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   773   for r :: "('a \<times> 'b) set"
   774 where
   775   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   776 
   777 abbreviation (input) "RangeP \<equiv> Rangep"
   778 
   779 lemmas RangePI = Rangep.RangeI
   780 
   781 inductive_cases RangeE [elim!]: "b \<in> Range r"
   782 inductive_cases RangepE [elim!]: "Rangep r b"
   783 
   784 definition Field :: "'a rel \<Rightarrow> 'a set"
   785 where
   786   "Field r = Domain r \<union> Range r"
   787 
   788 lemma Domain_fst [code]:
   789   "Domain r = fst ` r"
   790   by force
   791 
   792 lemma Range_snd [code]:
   793   "Range r = snd ` r"
   794   by force
   795 
   796 lemma fst_eq_Domain: "fst ` R = Domain R"
   797   by force
   798 
   799 lemma snd_eq_Range: "snd ` R = Range R"
   800   by force
   801 
   802 lemma Domain_empty [simp]: "Domain {} = {}"
   803   by auto
   804 
   805 lemma Range_empty [simp]: "Range {} = {}"
   806   by auto
   807 
   808 lemma Field_empty [simp]: "Field {} = {}"
   809   by (simp add: Field_def)
   810 
   811 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   812   by auto
   813 
   814 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   815   by auto
   816 
   817 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   818   by blast
   819 
   820 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   821   by blast
   822 
   823 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   824   by (auto simp add: Field_def)
   825 
   826 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   827   by blast
   828 
   829 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   830   by blast
   831 
   832 lemma Domain_Id [simp]: "Domain Id = UNIV"
   833   by blast
   834 
   835 lemma Range_Id [simp]: "Range Id = UNIV"
   836   by blast
   837 
   838 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   839   by blast
   840 
   841 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   842   by blast
   843 
   844 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   845   by blast
   846 
   847 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   848   by blast
   849 
   850 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   851   by (auto simp: Field_def)
   852 
   853 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   854   by blast
   855 
   856 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   857   by blast
   858 
   859 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   860   by blast
   861 
   862 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   863   by blast
   864 
   865 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   866   by blast
   867 
   868 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   869   by blast
   870 
   871 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   872   by (auto simp: Field_def)
   873 
   874 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   875   by auto
   876 
   877 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   878   by blast
   879 
   880 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   881   by (auto simp: Field_def)
   882 
   883 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   884   by auto
   885 
   886 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   887   by auto
   888 
   889 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   890   by (induct set: finite) auto
   891 
   892 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   893   by (induct set: finite) auto
   894 
   895 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   896   by (simp add: Field_def finite_Domain finite_Range)
   897 
   898 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   899   by blast
   900 
   901 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   902   by blast
   903 
   904 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   905   by (auto simp: Field_def Domain_def Range_def)
   906 
   907 lemma Domain_unfold:
   908   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   909   by blast
   910 
   911 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   912   by auto
   913 
   914 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   915   by auto
   916 
   917 
   918 subsubsection {* Image of a set under a relation *}
   919 
   920 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixl "``" 90)
   921 where
   922   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   923 
   924 declare Image_def [no_atp]
   925 
   926 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   927   by (simp add: Image_def)
   928 
   929 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   930   by (simp add: Image_def)
   931 
   932 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   933   by (rule Image_iff [THEN trans]) simp
   934 
   935 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   936   by (unfold Image_def) blast
   937 
   938 lemma ImageE [elim!]:
   939   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   940   by (unfold Image_def) (iprover elim!: CollectE bexE)
   941 
   942 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   943   -- {* This version's more effective when we already have the required @{text a} *}
   944   by blast
   945 
   946 lemma Image_empty [simp]: "R``{} = {}"
   947   by blast
   948 
   949 lemma Image_Id [simp]: "Id `` A = A"
   950   by blast
   951 
   952 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   953   by blast
   954 
   955 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   956   by blast
   957 
   958 lemma Image_Int_eq:
   959   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   960   by (simp add: single_valued_def, blast) 
   961 
   962 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   963   by blast
   964 
   965 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   966   by blast
   967 
   968 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   969   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   970 
   971 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   972   -- {* NOT suitable for rewriting *}
   973   by blast
   974 
   975 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   976   by blast
   977 
   978 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   979   by blast
   980 
   981 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   982   by blast
   983 
   984 text{*Converse inclusion requires some assumptions*}
   985 lemma Image_INT_eq:
   986      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   987 apply (rule equalityI)
   988  apply (rule Image_INT_subset) 
   989 apply  (simp add: single_valued_def, blast)
   990 done
   991 
   992 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   993   by blast
   994 
   995 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
   996   by auto
   997 
   998 
   999 subsubsection {* Inverse image *}
  1000 
  1001 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1002 where
  1003   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1004 
  1005 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1006 where
  1007   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1008 
  1009 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1010   by (simp add: inv_image_def inv_imagep_def)
  1011 
  1012 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1013   by (unfold sym_def inv_image_def) blast
  1014 
  1015 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1016   apply (unfold trans_def inv_image_def)
  1017   apply (simp (no_asm))
  1018   apply blast
  1019   done
  1020 
  1021 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1022   by (auto simp:inv_image_def)
  1023 
  1024 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1025   unfolding inv_image_def converse_unfold by auto
  1026 
  1027 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1028   by (simp add: inv_imagep_def)
  1029 
  1030 
  1031 subsubsection {* Powerset *}
  1032 
  1033 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1034 where
  1035   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1036 
  1037 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1038   by (auto simp add: Powp_def fun_eq_iff)
  1039 
  1040 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1041 
  1042 end
  1043