src/Pure/sign.ML
author wenzelm
Wed Sep 26 20:50:34 2007 +0200 (2007-09-26)
changeset 24732 08c2dd5378c7
parent 24707 dfeb98f84e93
child 24761 d762ab297a07
permissions -rw-r--r--
added minimize_sort, complete_sort;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> output * int)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> output * int)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    57     theory -> theory
    58   val restore_naming: theory -> theory -> theory
    59 end
    60 
    61 signature SIGN =
    62 sig
    63   val rep_sg: theory ->
    64    {naming: NameSpace.naming,
    65     syn: Syntax.syntax,
    66     tsig: Type.tsig,
    67     consts: Consts.T}
    68   val naming_of: theory -> NameSpace.naming
    69   val base_name: string -> bstring
    70   val full_name: theory -> bstring -> string
    71   val full_name_path: theory -> string -> bstring -> string
    72   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    73   val syn_of: theory -> Syntax.syntax
    74   val tsig_of: theory -> Type.tsig
    75   val classes_of: theory -> Sorts.algebra
    76   val all_classes: theory -> class list
    77   val super_classes: theory -> class -> class list
    78   val minimize_sort: theory -> sort -> sort
    79   val complete_sort: theory -> sort -> sort
    80   val defaultS: theory -> sort
    81   val subsort: theory -> sort * sort -> bool
    82   val of_sort: theory -> typ * sort -> bool
    83   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    84   val universal_witness: theory -> (typ * sort) option
    85   val all_sorts_nonempty: theory -> bool
    86   val is_logtype: theory -> string -> bool
    87   val typ_instance: theory -> typ * typ -> bool
    88   val typ_equiv: theory -> typ * typ -> bool
    89   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    90   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    91   val consts_of: theory -> Consts.T
    92   val const_constraint: theory -> string -> typ option
    93   val the_const_constraint: theory -> string -> typ
    94   val const_type: theory -> string -> typ option
    95   val the_const_type: theory -> string -> typ
    96   val declared_tyname: theory -> string -> bool
    97   val declared_const: theory -> string -> bool
    98   val const_monomorphic: theory -> string -> bool
    99   val const_syntax_name: theory -> string -> string
   100   val const_typargs: theory -> string * typ -> typ list
   101   val const_instance: theory -> string * typ list -> typ
   102   val class_space: theory -> NameSpace.T
   103   val type_space: theory -> NameSpace.T
   104   val const_space: theory -> NameSpace.T
   105   val intern_class: theory -> xstring -> string
   106   val extern_class: theory -> string -> xstring
   107   val intern_type: theory -> xstring -> string
   108   val extern_type: theory -> string -> xstring
   109   val intern_const: theory -> xstring -> string
   110   val extern_const: theory -> string -> xstring
   111   val intern_sort: theory -> sort -> sort
   112   val extern_sort: theory -> sort -> sort
   113   val intern_typ: theory -> typ -> typ
   114   val extern_typ: theory -> typ -> typ
   115   val intern_term: theory -> term -> term
   116   val extern_term: (string -> xstring) -> theory -> term -> term
   117   val intern_tycons: theory -> typ -> typ
   118   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   119   val pretty_term: theory -> term -> Pretty.T
   120   val pretty_typ: theory -> typ -> Pretty.T
   121   val pretty_sort: theory -> sort -> Pretty.T
   122   val pretty_classrel: theory -> class list -> Pretty.T
   123   val pretty_arity: theory -> arity -> Pretty.T
   124   val string_of_term: theory -> term -> string
   125   val string_of_typ: theory -> typ -> string
   126   val string_of_sort: theory -> sort -> string
   127   val string_of_classrel: theory -> class list -> string
   128   val string_of_arity: theory -> arity -> string
   129   val pp: theory -> Pretty.pp
   130   val arity_number: theory -> string -> int
   131   val arity_sorts: theory -> string -> sort -> sort list
   132   val certify_class: theory -> class -> class
   133   val certify_sort: theory -> sort -> sort
   134   val certify_typ: theory -> typ -> typ
   135   val certify_typ_mode: Type.mode -> theory -> typ -> typ
   136   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
   137   val certify_term: theory -> term -> term * typ * int
   138   val certify_prop: theory -> term -> term * typ * int
   139   val cert_term: theory -> term -> term
   140   val cert_prop: theory -> term -> term
   141   val no_frees: Pretty.pp -> term -> term
   142   val no_vars: Pretty.pp -> term -> term
   143   val cert_def: Pretty.pp -> term -> (string * typ) * term
   144   val read_class: theory -> xstring -> class
   145   val read_arity: theory -> xstring * string list * string -> arity
   146   val cert_arity: theory -> arity -> arity
   147   val get_sort: theory ->
   148     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   149   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   150   val read_typ: theory -> string -> typ
   151   val read_typ_syntax: theory -> string -> typ
   152   val read_typ_abbrev: theory -> string -> typ
   153   val read_tyname: theory -> string -> typ
   154   val read_const: theory -> string -> term
   155   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   156     (string -> string option) -> Proof.context ->
   157     (indexname -> typ option) * (indexname -> sort option) ->
   158     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   159   val read_def_terms:
   160     theory * (indexname -> typ option) * (indexname -> sort option) ->
   161     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   162   val simple_read_term: theory -> typ -> string -> term
   163   val read_term: theory -> string -> term
   164   val read_prop: theory -> string -> term
   165   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   166   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   167   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   168   include SIGN_THEORY
   169   val add_const_constraint: xstring * string option -> theory -> theory
   170   val add_const_constraint_i: string * typ option -> theory -> theory
   171   val primitive_class: string * class list -> theory -> theory
   172   val primitive_classrel: class * class -> theory -> theory
   173   val primitive_arity: arity -> theory -> theory
   174   val hide_classes: bool -> xstring list -> theory -> theory
   175   val hide_classes_i: bool -> string list -> theory -> theory
   176   val hide_types: bool -> xstring list -> theory -> theory
   177   val hide_types_i: bool -> string list -> theory -> theory
   178   val hide_consts: bool -> xstring list -> theory -> theory
   179   val hide_consts_i: bool -> string list -> theory -> theory
   180   val hide_names: bool -> string * xstring list -> theory -> theory
   181   val hide_names_i: bool -> string * string list -> theory -> theory
   182 end
   183 
   184 structure Sign: SIGN =
   185 struct
   186 
   187 (** datatype sign **)
   188 
   189 datatype sign = Sign of
   190  {naming: NameSpace.naming,     (*common naming conventions*)
   191   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   192   tsig: Type.tsig,              (*order-sorted signature of types*)
   193   consts: Consts.T};            (*polymorphic constants*)
   194 
   195 fun make_sign (naming, syn, tsig, consts) =
   196   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   197 
   198 structure SignData = TheoryDataFun
   199 (
   200   type T = sign;
   201   val copy = I;
   202   fun extend (Sign {syn, tsig, consts, ...}) =
   203     make_sign (NameSpace.default_naming, syn, tsig, consts);
   204 
   205   val empty =
   206     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   207 
   208   fun merge pp (sign1, sign2) =
   209     let
   210       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   211       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   212 
   213       val naming = NameSpace.default_naming;
   214       val syn = Syntax.merge_syntaxes syn1 syn2;
   215       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   216       val consts = Consts.merge (consts1, consts2);
   217     in make_sign (naming, syn, tsig, consts) end;
   218 );
   219 
   220 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   221 
   222 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   223   make_sign (f (naming, syn, tsig, consts)));
   224 
   225 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   226 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   227 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   228 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   229 
   230 
   231 (* naming *)
   232 
   233 val naming_of = #naming o rep_sg;
   234 val base_name = NameSpace.base;
   235 val full_name = NameSpace.full o naming_of;
   236 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   237 val declare_name = NameSpace.declare o naming_of;
   238 
   239 
   240 (* syntax *)
   241 
   242 val syn_of = #syn o rep_sg;
   243 
   244 
   245 (* type signature *)
   246 
   247 val tsig_of = #tsig o rep_sg;
   248 
   249 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   250 val all_classes = Sorts.all_classes o classes_of;
   251 val minimal_classes = Sorts.minimal_classes o classes_of;
   252 val super_classes = Sorts.super_classes o classes_of;
   253 val minimize_sort = Sorts.minimize_sort o classes_of;
   254 val complete_sort = Sorts.complete_sort o classes_of;
   255 
   256 val defaultS = Type.defaultS o tsig_of;
   257 val subsort = Type.subsort o tsig_of;
   258 val of_sort = Type.of_sort o tsig_of;
   259 val witness_sorts = Type.witness_sorts o tsig_of;
   260 val universal_witness = Type.universal_witness o tsig_of;
   261 val all_sorts_nonempty = is_some o universal_witness;
   262 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   263 
   264 val typ_instance = Type.typ_instance o tsig_of;
   265 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   266 val typ_match = Type.typ_match o tsig_of;
   267 val typ_unify = Type.unify o tsig_of;
   268 
   269 
   270 (* polymorphic constants *)
   271 
   272 val consts_of = #consts o rep_sg;
   273 val the_const_constraint = Consts.the_constraint o consts_of;
   274 val const_constraint = try o the_const_constraint;
   275 val the_const_type = Consts.the_declaration o consts_of;
   276 val const_type = try o the_const_type;
   277 val const_monomorphic = Consts.is_monomorphic o consts_of;
   278 val const_syntax_name = Consts.syntax_name o consts_of;
   279 val const_typargs = Consts.typargs o consts_of;
   280 val const_instance = Consts.instance o consts_of;
   281 
   282 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   283 val declared_const = is_some oo const_constraint;
   284 
   285 
   286 
   287 (** intern / extern names **)
   288 
   289 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   290 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   291 val const_space = Consts.space_of o consts_of;
   292 
   293 val intern_class = NameSpace.intern o class_space;
   294 val extern_class = NameSpace.extern o class_space;
   295 val intern_type = NameSpace.intern o type_space;
   296 val extern_type = NameSpace.extern o type_space;
   297 val intern_const = NameSpace.intern o const_space;
   298 val extern_const = NameSpace.extern o const_space;
   299 
   300 val intern_sort = map o intern_class;
   301 val extern_sort = map o extern_class;
   302 
   303 local
   304 
   305 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   306   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   307   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   308 
   309 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   310   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   311   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   312   | map_term _ _ _ (t as Bound _) = t
   313   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   314   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   315 
   316 val add_classesT = Term.fold_atyps
   317   (fn TFree (_, S) => fold (insert (op =)) S
   318     | TVar (_, S) => fold (insert (op =)) S
   319     | _ => I);
   320 
   321 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   322   | add_tyconsT _ = I;
   323 
   324 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   325 
   326 fun mapping add_names f t =
   327   let
   328     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   329     val tab = map_filter f' (add_names t []);
   330     fun get x = the_default x (AList.lookup (op =) tab x);
   331   in get end;
   332 
   333 fun typ_mapping f g thy T =
   334   T |> map_typ
   335     (mapping add_classesT (f thy) T)
   336     (mapping add_tyconsT (g thy) T);
   337 
   338 fun term_mapping f g h thy t =
   339   t |> map_term
   340     (mapping (Term.fold_types add_classesT) (f thy) t)
   341     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   342     (mapping add_consts (h thy) t);
   343 
   344 in
   345 
   346 val intern_typ = typ_mapping intern_class intern_type;
   347 val extern_typ = typ_mapping extern_class extern_type;
   348 val intern_term = term_mapping intern_class intern_type intern_const;
   349 fun extern_term h = term_mapping extern_class extern_type (K h);
   350 val intern_tycons = typ_mapping (K I) intern_type;
   351 
   352 end;
   353 
   354 
   355 
   356 (** pretty printing of terms, types etc. **)
   357 
   358 fun pretty_term' ctxt syn ext t =
   359   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   360   in Syntax.pretty_term ext ctxt syn curried t end;
   361 
   362 fun pretty_term thy t =
   363   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   364     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   365 
   366 fun pretty_typ thy T =
   367   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   368 
   369 fun pretty_sort thy S =
   370   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   371 
   372 fun pretty_classrel thy cs = Pretty.block (flat
   373   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   374 
   375 fun pretty_arity thy (a, Ss, S) =
   376   let
   377     val a' = extern_type thy a;
   378     val dom =
   379       if null Ss then []
   380       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   381   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   382 
   383 val string_of_term = Pretty.string_of oo pretty_term;
   384 val string_of_typ = Pretty.string_of oo pretty_typ;
   385 val string_of_sort = Pretty.string_of oo pretty_sort;
   386 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   387 val string_of_arity = Pretty.string_of oo pretty_arity;
   388 
   389 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   390   pretty_classrel thy, pretty_arity thy);
   391 
   392 
   393 
   394 (** certify entities **)    (*exception TYPE*)
   395 
   396 (* certify wrt. type signature *)
   397 
   398 val arity_number = Type.arity_number o tsig_of;
   399 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   400 
   401 val certify_class         = Type.cert_class o tsig_of;
   402 val certify_sort          = Type.cert_sort o tsig_of;
   403 val certify_typ           = Type.cert_typ o tsig_of;
   404 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   405 
   406 
   407 (* certify term/prop *)
   408 
   409 local
   410 
   411 fun type_check pp tm =
   412   let
   413     fun err_appl why bs t T u U =
   414       let
   415         val xs = map Free bs;           (*we do not rename here*)
   416         val t' = subst_bounds (xs, t);
   417         val u' = subst_bounds (xs, u);
   418         val msg = cat_lines
   419           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   420       in raise TYPE (msg, [T, U], [t', u']) end;
   421 
   422     fun typ_of (_, Const (_, T)) = T
   423       | typ_of (_, Free  (_, T)) = T
   424       | typ_of (_, Var (_, T)) = T
   425       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   426           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   427       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   428       | typ_of (bs, t $ u) =
   429           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   430             (case T of
   431               Type ("fun", [T1, T2]) =>
   432                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   433             | _ => err_appl "Operator not of function type" bs t T u U)
   434           end;
   435   in typ_of ([], tm) end;
   436 
   437 fun err msg = raise TYPE (msg, [], []);
   438 
   439 fun check_vars (t $ u) = (check_vars t; check_vars u)
   440   | check_vars (Abs (_, _, t)) = check_vars t
   441   | check_vars (Var (xi as (_, i), _)) =
   442       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   443   | check_vars _ = ();
   444 
   445 in
   446 
   447 fun certify' prop pp do_expand consts thy tm =
   448   let
   449     val _ = check_vars tm;
   450     val tm' = Term.map_types (certify_typ thy) tm;
   451     val T = type_check pp tm';
   452     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   453     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   454   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   455 
   456 fun certify_term thy = certify' false (pp thy) true (consts_of thy) thy;
   457 fun certify_prop thy = certify' true (pp thy) true (consts_of thy) thy;
   458 
   459 fun cert_term_abbrev thy = #1 o certify' false (pp thy) false (consts_of thy) thy;
   460 val cert_term = #1 oo certify_term;
   461 val cert_prop = #1 oo certify_prop;
   462 
   463 end;
   464 
   465 
   466 (* specifications *)
   467 
   468 fun no_variables kind add addT mk mkT pp tm =
   469   (case (add tm [], addT tm []) of
   470     ([], []) => tm
   471   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   472       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   473        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   474 
   475 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   476 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   477 
   478 fun cert_def pp tm =
   479   let val ((lhs, rhs), _) = tm
   480     |> no_vars pp
   481     |> Logic.strip_imp_concl
   482     |> PrimitiveDefs.dest_def pp Term.is_Const (K false) (K false)
   483   in (Term.dest_Const (Term.head_of lhs), rhs) end
   484   handle TERM (msg, _) => error msg;
   485 
   486 
   487 
   488 (** read and certify entities **)    (*exception ERROR*)
   489 
   490 (* classes *)
   491 
   492 fun read_class thy c = certify_class thy (intern_class thy c)
   493   handle TYPE (msg, _, _) => error msg;
   494 
   495 
   496 (* type arities *)
   497 
   498 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   499   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   500   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   501 
   502 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   503 val cert_arity = prep_arity (K I) certify_sort;
   504 
   505 
   506 (* types *)
   507 
   508 fun get_sort thy def_sort raw_env =
   509   let
   510     val tsig = tsig_of thy;
   511 
   512     fun eq ((xi, S), (xi', S')) =
   513       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   514     val env = distinct eq raw_env;
   515     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   516       | dups => error ("Inconsistent sort constraints for type variable(s) "
   517           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   518 
   519     fun get xi =
   520       (case (AList.lookup (op =) env xi, def_sort xi) of
   521         (NONE, NONE) => Type.defaultS tsig
   522       | (NONE, SOME S) => S
   523       | (SOME S, NONE) => S
   524       | (SOME S, SOME S') =>
   525           if Type.eq_sort tsig (S, S') then S'
   526           else error ("Sort constraint inconsistent with default for type variable " ^
   527             quote (Term.string_of_vname' xi)));
   528   in get end;
   529 
   530 local
   531 
   532 fun gen_read_typ mode (thy, def_sort) str =
   533   let
   534     val ctxt = ProofContext.init thy;
   535     val syn = syn_of thy;
   536     val T = intern_tycons thy
   537       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   538   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   539   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   540 
   541 in
   542 
   543 fun no_def_sort thy = (thy: theory, K NONE);
   544 
   545 val read_def_typ     = gen_read_typ Type.mode_default;
   546 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   547 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   548 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   549 
   550 end;
   551 
   552 
   553 (* type and constant names *)
   554 
   555 fun read_tyname thy raw_c =
   556   let val c = intern_type thy raw_c
   557   in Type (c, replicate (arity_number thy c) dummyT) end;
   558 
   559 val read_const = Consts.read_const o consts_of;
   560 
   561 
   562 
   563 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   564 
   565 (*
   566   def_type: partial map from indexnames to types (constrains Frees and Vars)
   567   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   568   used: context of already used type variables
   569   freeze: if true then generated parameters are turned into TFrees, else TVars
   570 *)
   571 
   572 fun read_def_terms'
   573     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   574   let
   575     val thy = ProofContext.theory_of ctxt;
   576     fun check_typs Ts = map (certify_typ thy) Ts
   577       handle TYPE (msg, _, _) => error msg;
   578 
   579     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   580         (try (Consts.the_constraint consts)) def_type used freeze args |>> map fst
   581       handle TYPE (msg, _, _) => error msg;
   582 
   583     fun check T t = Exn.Result (singleton (fst o infer) (t, T))
   584       handle ERROR msg => Exn.Exn (ERROR msg);
   585     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   586     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   587         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   588   in
   589     raw_args
   590     |> map (fn (s, raw_T) =>
   591       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   592       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   593     |> infer
   594   end;
   595 
   596 fun read_def_terms (thy, types, sorts) used freeze sTs =
   597   let
   598     val pp = pp thy;
   599     val consts = consts_of thy;
   600     val cert_consts = Consts.certify pp (tsig_of thy) true consts;
   601     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   602     val (ts, inst) =
   603       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   604         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   605   in (map cert_consts ts, inst) end;
   606 
   607 fun simple_read_term thy T s =
   608   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   609   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   610 
   611 fun read_term thy = simple_read_term thy dummyT;
   612 fun read_prop thy = simple_read_term thy propT;
   613 
   614 
   615 
   616 (** signature extension functions **)  (*exception ERROR/TYPE*)
   617 
   618 (* add default sort *)
   619 
   620 fun gen_add_defsort prep_sort s thy =
   621   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   622 
   623 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   624 val add_defsort_i = gen_add_defsort certify_sort;
   625 
   626 
   627 (* add type constructors *)
   628 
   629 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   630   let
   631     val syn' = Syntax.extend_type_gram types syn;
   632     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   633     val tsig' = Type.add_types naming decls tsig;
   634   in (naming, syn', tsig', consts) end);
   635 
   636 fun add_typedecls decls thy =
   637   let
   638     fun type_of (a, vs: string list, mx) =
   639       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   640       else error ("Duplicate parameters in type declaration: " ^ quote a);
   641   in add_types (map type_of decls) thy end;
   642 
   643 
   644 (* add nonterminals *)
   645 
   646 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   647   let
   648     val syn' = Syntax.extend_consts ns syn;
   649     val tsig' = Type.add_nonterminals naming ns tsig;
   650   in (naming, syn', tsig', consts) end);
   651 
   652 
   653 (* add type abbreviations *)
   654 
   655 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   656   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   657     let
   658       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   659       val a' = Syntax.type_name a mx;
   660       val abbr = (a', vs,
   661           certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) rhs))
   662         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   663       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   664     in (naming, syn', tsig', consts) end);
   665 
   666 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   667 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   668 
   669 
   670 (* modify syntax *)
   671 
   672 fun gen_syntax change_gram prep_typ mode args thy =
   673   let
   674     fun prep (c, T, mx) = (c,
   675         certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) T), mx)
   676       handle ERROR msg =>
   677         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   678   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   679 
   680 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   681 
   682 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   683 val add_modesyntax_i = gen_add_syntax (K I);
   684 val add_syntax = add_modesyntax Syntax.default_mode;
   685 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   686 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   687 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   688 
   689 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   690   | const_syntax _ _ = NONE;
   691 
   692 fun add_notation mode args thy =
   693   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   694 
   695 
   696 (* add constants *)
   697 
   698 local
   699 
   700 fun gen_add_consts prep_typ authentic raw_args thy =
   701   let
   702     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   703     fun prep (raw_c, raw_T, raw_mx) =
   704       let
   705         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   706         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   707         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   708           cat_error msg ("in declaration of constant " ^ quote c);
   709       in (((c, T), authentic), (c', T, mx)) end;
   710     val args = map prep raw_args;
   711   in
   712     thy
   713     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   714     |> add_syntax_i (map #2 args)
   715   end;
   716 
   717 in
   718 
   719 val add_consts = gen_add_consts read_typ false;
   720 val add_consts_i = gen_add_consts certify_typ false;
   721 val add_consts_authentic = gen_add_consts certify_typ true;
   722 
   723 end;
   724 
   725 
   726 (* add abbreviations *)
   727 
   728 fun add_abbrev mode (c, raw_t) thy =
   729   let
   730     val pp = pp thy;
   731     val prep_tm = Compress.term thy o no_frees pp o
   732       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   733       Term.no_dummy_patterns o cert_term_abbrev thy;
   734     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   735       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   736     val (res, consts') = consts_of thy
   737       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   738   in (res, thy |> map_consts (K consts')) end;
   739 
   740 
   741 (* add constraints *)
   742 
   743 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   744   let
   745     val c = int_const thy raw_c;
   746     fun prepT raw_T =
   747       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   748       in cert_term thy (Const (c, T)); T end
   749       handle TYPE (msg, _, _) => error msg;
   750   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   751 
   752 val add_const_constraint = gen_add_constraint intern_const read_typ;
   753 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   754 
   755 
   756 (* primitive classes and arities *)
   757 
   758 fun primitive_class (bclass, classes) thy =
   759   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   760     let
   761       val syn' = Syntax.extend_consts [bclass] syn;
   762       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   763     in (naming, syn', tsig', consts) end)
   764   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   765 
   766 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   767 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   768 
   769 
   770 (* add translation functions *)
   771 
   772 local
   773 
   774 fun mk trs = map Syntax.mk_trfun trs;
   775 
   776 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   777   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   778 
   779 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   780 
   781 in
   782 
   783 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   784 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   785 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   786 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   787 
   788 end;
   789 
   790 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   791 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   792 
   793 
   794 (* translation rules *)
   795 
   796 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   797   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   798   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   799 
   800 val add_trrules = gen_trrules Syntax.extend_trrules;
   801 val del_trrules = gen_trrules Syntax.remove_trrules;
   802 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   803 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   804 
   805 
   806 (* modify naming *)
   807 
   808 val add_path        = map_naming o NameSpace.add_path;
   809 val no_base_names   = map_naming NameSpace.no_base_names;
   810 val qualified_names = map_naming NameSpace.qualified_names;
   811 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   812 val set_policy      = map_naming o NameSpace.set_policy;
   813 val restore_naming  = map_naming o K o naming_of;
   814 
   815 val parent_path   = add_path "..";
   816 val root_path     = add_path "/";
   817 val absolute_path = add_path "//";
   818 
   819 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   820 
   821 
   822 (* hide names *)
   823 
   824 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   825 val hide_classes_i = map_tsig oo Type.hide_classes;
   826 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   827 val hide_types_i = map_tsig oo Type.hide_types;
   828 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   829 val hide_consts_i = map_consts oo (fold o Consts.hide);
   830 
   831 local
   832 
   833 val kinds =
   834  [("class", (intern_class, can o certify_class, hide_classes_i)),
   835   ("type", (intern_type, declared_tyname, hide_types_i)),
   836   ("const", (intern_const, declared_const, hide_consts_i))];
   837 
   838 fun gen_hide int b (kind, xnames) thy =
   839   (case AList.lookup (op =) kinds kind of
   840     SOME (intern, check, hide) =>
   841       let
   842         val names = if int then map (intern thy) xnames else xnames;
   843         val bads = filter_out (check thy) names;
   844       in
   845         if null bads then hide b names thy
   846         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   847       end
   848   | NONE => error ("Bad name space specification: " ^ quote kind));
   849 
   850 in
   851 
   852 val hide_names = gen_hide true;
   853 val hide_names_i = gen_hide false;
   854 
   855 end;
   856 
   857 end;