src/Pure/Isar/outer_syntax.ML
author skalberg
Sun Feb 13 17:15:14 2005 +0100 (2005-02-13)
changeset 15531 08c8dad8e399
parent 15224 1bd35fd87963
child 15570 8d8c70b41bab
permissions -rw-r--r--
Deleted Library.option type.
     1 (*  Title:      Pure/Isar/outer_syntax.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The global Isabelle/Isar outer syntax.
     6 *)
     7 
     8 signature BASIC_OUTER_SYNTAX =
     9 sig
    10   val main: unit -> unit
    11   val loop: unit -> unit
    12   val sync_main: unit -> unit
    13   val sync_loop: unit -> unit
    14 end;
    15 
    16 signature OUTER_SYNTAX =
    17 sig
    18   include BASIC_OUTER_SYNTAX
    19   structure Keyword:
    20     sig
    21       val control: string
    22       val diag: string
    23       val thy_begin: string
    24       val thy_switch: string
    25       val thy_end: string
    26       val thy_heading: string
    27       val thy_decl: string
    28       val thy_script: string
    29       val thy_goal: string
    30       val qed: string
    31       val qed_block: string
    32       val qed_global: string
    33       val prf_heading: string
    34       val prf_goal: string
    35       val prf_block: string
    36       val prf_open: string
    37       val prf_close: string
    38       val prf_chain: string
    39       val prf_decl: string
    40       val prf_asm: string
    41       val prf_asm_goal: string
    42       val prf_script: string
    43       val kinds: string list
    44     end
    45   type token
    46   type parser
    47   val command: string -> string -> string ->
    48     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    49   val markup_command: IsarOutput.markup -> string -> string -> string ->
    50     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    51   val improper_command: string -> string -> string ->
    52     (token list -> (Toplevel.transition -> Toplevel.transition) * token list) -> parser
    53   val is_keyword: string -> bool
    54   val dest_keywords: unit -> string list
    55   val dest_parsers: unit -> (string * string * string * bool) list
    56   val print_outer_syntax: unit -> unit
    57   val print_commands: Toplevel.transition -> Toplevel.transition
    58   val add_keywords: string list -> unit
    59   val add_parsers: parser list -> unit
    60   val check_text: string * Position.T -> bool -> Toplevel.state -> unit
    61   val deps_thy: string -> bool -> Path.T -> string list * Path.T list
    62   val load_thy: string -> bool -> bool -> Path.T -> unit
    63   val isar: bool -> bool -> unit Toplevel.isar
    64   val scan: string -> OuterLex.token list  
    65   val read: OuterLex.token list -> 
    66 		(string * OuterLex.token list * Toplevel.transition) list
    67 end;
    68 
    69 structure OuterSyntax : OUTER_SYNTAX  =
    70 struct
    71 
    72 structure T = OuterLex;
    73 structure P = OuterParse;
    74 
    75 
    76 (** outer syntax **)
    77 
    78 (* command keyword classification *)
    79 
    80 structure Keyword =
    81 struct
    82   val control = "control";
    83   val diag = "diag";
    84   val thy_begin = "theory-begin";
    85   val thy_switch = "theory-switch";
    86   val thy_end = "theory-end";
    87   val thy_heading = "theory-heading";
    88   val thy_decl = "theory-decl";
    89   val thy_script = "theory-script";
    90   val thy_goal = "theory-goal";
    91   val qed = "qed";
    92   val qed_block = "qed-block";
    93   val qed_global = "qed-global";
    94   val prf_heading = "proof-heading";
    95   val prf_goal = "proof-goal";
    96   val prf_block = "proof-block";
    97   val prf_open = "proof-open";
    98   val prf_close = "proof-close";
    99   val prf_chain = "proof-chain";
   100   val prf_decl = "proof-decl";
   101   val prf_asm = "proof-asm";
   102   val prf_asm_goal = "proof-asm-goal";
   103   val prf_script = "proof-script";
   104 
   105   val kinds = [control, diag, thy_begin, thy_switch, thy_end, thy_heading, thy_decl, thy_script,
   106     thy_goal, qed, qed_block, qed_global, prf_heading, prf_goal, prf_block, prf_open, prf_close,
   107     prf_chain, prf_decl, prf_asm, prf_asm_goal, prf_script];
   108 end;
   109 
   110 
   111 (* parsers *)
   112 
   113 type token = T.token;
   114 type parser_fn = token list -> (Toplevel.transition -> Toplevel.transition) * token list;
   115 
   116 datatype parser =
   117   Parser of string * (string * string * IsarOutput.markup option) * bool * parser_fn;
   118 
   119 fun parser int_only markup name comment kind parse =
   120   Parser (name, (comment, kind, markup), int_only, parse);
   121 
   122 
   123 (* parse command *)
   124 
   125 local
   126 
   127 fun terminate false = Scan.succeed ()
   128   | terminate true = P.group "end of input" (Scan.option P.sync -- P.semicolon >> K ());
   129 
   130 fun trace false parse = parse
   131   | trace true parse = Scan.trace parse >> (fn (f, toks) => f o Toplevel.source toks);
   132 
   133 fun body cmd trc (name, _) =
   134   (case cmd name of
   135     SOME (int_only, parse) =>
   136       P.!!! (Scan.prompt (name ^ "# ") (trace trc parse >> pair int_only))
   137   | NONE => sys_error ("no parser for outer syntax command " ^ quote name));
   138 
   139 in
   140 
   141 fun command do_terminate do_trace cmd =
   142   P.semicolon >> K NONE ||
   143   P.sync >> K NONE ||
   144   (P.position P.command :-- body cmd do_trace) --| terminate do_terminate
   145     >> (fn ((name, pos), (int_only, f)) =>
   146       SOME (Toplevel.empty |> Toplevel.name name |> Toplevel.position pos |>
   147         Toplevel.interactive int_only |> f));
   148 
   149 end;
   150 
   151 
   152 
   153 (** global outer syntax **)
   154 
   155 local
   156 
   157 val global_lexicons = ref (Scan.empty_lexicon, Scan.empty_lexicon);
   158 val global_parsers =
   159   ref (Symtab.empty: (((string * string) * (bool * parser_fn)) * IsarOutput.markup option)
   160     Symtab.table);
   161 val global_markups = ref ([]: (string * IsarOutput.markup) list);
   162 
   163 fun change_lexicons f =
   164   let val lexs = f (! global_lexicons) in
   165     (case (op inter_string) (pairself Scan.dest_lexicon lexs) of
   166       [] => global_lexicons := lexs
   167     | bads => error ("Clash of outer syntax commands and keywords: " ^ commas_quote bads))
   168   end;
   169 
   170 fun get_markup (ms, (name, (_, SOME m))) = (name, m) :: ms
   171   | get_markup (ms, _) = ms;
   172 
   173 fun make_markups () = global_markups := Symtab.foldl get_markup ([], ! global_parsers);
   174 fun change_parsers f = (Library.change global_parsers f; make_markups ());
   175 
   176 in
   177 
   178 
   179 (* access current syntax *)
   180 
   181 (*Note: the syntax for files is statically determined at the very
   182   beginning; for interactive processing it may change dynamically.*)
   183 
   184 fun get_lexicons () = ! global_lexicons;
   185 fun get_parsers () = ! global_parsers;
   186 fun get_parser () = apsome (#2 o #1) o curry Symtab.lookup (! global_parsers);
   187 
   188 fun is_markup kind name =
   189   (case assoc (! global_markups, name) of SOME k => k = kind | NONE => false);
   190 fun markup kind = Scan.one (T.is_kind T.Command andf is_markup kind o T.val_of);
   191 
   192 
   193 (* augment syntax *)
   194 
   195 fun add_keywords keywords = change_lexicons (apfst (fn lex =>
   196   (Scan.extend_lexicon lex (map Symbol.explode keywords))));
   197 
   198 fun add_parser (tab, Parser (name, (comment, kind, markup), int_only, parse)) =
   199  (if is_none (Symtab.lookup (tab, name)) then ()
   200   else warning ("Redefined outer syntax command " ^ quote name);
   201   Symtab.update ((name, (((comment, kind), (int_only, parse)), markup)), tab));
   202 
   203 fun add_parsers parsers =
   204   (change_parsers (fn tab => foldl add_parser (tab, parsers));
   205     change_lexicons (apsnd (fn lex => Scan.extend_lexicon lex
   206       (map (fn Parser (name, _, _, _) => Symbol.explode name) parsers))));
   207 
   208 end;
   209 
   210 
   211 (* print syntax *)
   212 
   213 fun is_keyword s = Scan.is_literal (#1 (get_lexicons ())) (Symbol.explode s);
   214 fun dest_keywords () = Scan.dest_lexicon (#1 (get_lexicons ()));
   215 
   216 fun dest_parsers () =
   217   map (fn (name, (((cmt, kind), (int_only, _)), _)) => (name, cmt, kind, int_only))
   218     (Symtab.dest (get_parsers ()));
   219 
   220 fun print_outer_syntax () =
   221   let
   222     fun pretty_cmd (name, comment, _, _) =
   223       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
   224     val (int_cmds, cmds) = partition #4 (dest_parsers ());
   225   in
   226     [Pretty.strs ("syntax keywords:" :: map quote (dest_keywords ())),
   227       Pretty.big_list "proper commands:" (map pretty_cmd cmds),
   228       Pretty.big_list "improper commands (interactive-only):" (map pretty_cmd int_cmds)]
   229     |> Pretty.chunks |> Pretty.writeln
   230   end;
   231 
   232 val print_commands = Toplevel.imperative print_outer_syntax;
   233 
   234 
   235 
   236 (** toplevel parsing **)
   237 
   238 (* basic sources *)
   239 
   240 fun toplevel_source term trc do_recover cmd src =
   241   let
   242     val no_terminator =
   243       Scan.unless P.semicolon (Scan.one (T.not_sync andf T.not_eof));
   244     fun recover x = (Scan.prompt "recover# " (Scan.repeat no_terminator) >> K [NONE]) x;
   245   in
   246     src
   247     |> T.source_proper
   248     |> Source.source T.stopper
   249       (Scan.bulk (P.$$$ "--" -- P.!!! P.text >> K NONE || P.not_eof >> SOME))
   250       (if do_recover then SOME recover else NONE)
   251     |> Source.mapfilter I
   252     |> Source.source T.stopper (Scan.bulk (fn xs => P.!!! (command term trc (cmd ())) xs))
   253       (if do_recover then SOME recover else NONE)
   254     |> Source.mapfilter I
   255   end;
   256 
   257 
   258 (* interactive source of toplevel transformers *)
   259 
   260 fun isar term no_pos =
   261   Source.tty
   262   |> Symbol.source true
   263   |> T.source true get_lexicons
   264     (if no_pos then Position.none else Position.line_name 1 "stdin")
   265   |> toplevel_source term false true get_parser;
   266 
   267 
   268 (* scan text,  read tokens with trace (for Proof General) *)
   269 
   270 fun scan str =
   271  Source.of_string str
   272  |> Symbol.source false
   273  |> T.source true get_lexicons Position.none
   274  |> Source.exhaust
   275 
   276 fun read toks =
   277   Source.of_list toks
   278   |> toplevel_source false true true get_parser
   279   |> Source.exhaust
   280   |> map (fn tr => (Toplevel.name_of tr, the (Toplevel.source_of tr), tr));
   281 
   282 
   283 (** read theory **)
   284 
   285 (* check_text *)
   286 
   287 fun check_text s true state = (IsarOutput.eval_antiquote (#1 (get_lexicons ())) state s; ())
   288   | check_text _ false _ = ();
   289 
   290 
   291 (* deps_thy *)
   292 
   293 fun deps_thy name ml path =
   294   let
   295     val src = Source.of_string (File.read path);
   296     val pos = Path.position path;
   297     val (name', parents, files) = ThyHeader.scan (src, pos);
   298     val ml_path = ThyLoad.ml_path name;
   299     val ml_file = if ml andalso is_some (ThyLoad.check_file NONE ml_path) then [ml_path] else [];
   300   in
   301     if name <> name' then
   302       error ("Filename " ^ quote (Path.pack path) ^
   303         " does not agree with theory name " ^ quote name')
   304     else (parents, map (Path.unpack o #1) files @ ml_file)
   305   end;
   306 
   307 
   308 (* load_thy *)
   309 
   310 local
   311 
   312 fun try_ml_file name time =
   313   let
   314     val path = ThyLoad.ml_path name;
   315     val tr = Toplevel.imperative (fn () => ThyInfo.load_file time path);
   316     val tr_name = if time then "time_use" else "use";
   317   in
   318     if is_none (ThyLoad.check_file NONE path) then ()
   319     else Toplevel.excursion [Toplevel.empty |> Toplevel.name tr_name |> tr]
   320   end;
   321 
   322 fun parse_thy src =
   323   src
   324   |> toplevel_source false false false (K (get_parser ()))
   325   |> Source.exhaust;
   326 
   327 fun run_thy name path =
   328   let
   329     val pos = Path.position path;
   330     val text = Library.untabify (explode (File.read path));
   331     val text_src = Source.of_list text;
   332     fun present_text () = Source.exhaust (Symbol.source false text_src);
   333   in
   334     Present.init_theory name;
   335     Present.verbatim_source name present_text;
   336     if ThyHeader.is_old (text_src, pos) then (ThySyn.load_thy name text;
   337       Present.old_symbol_source name present_text)   (*note: text presented twice*)
   338     else
   339       let
   340         val tok_src = text_src
   341           |> Symbol.source false
   342           |> T.source false (K (get_lexicons ())) pos
   343           |> Source.exhausted;
   344         val out = Toplevel.excursion_result
   345           (IsarOutput.parse_thy markup (#1 (get_lexicons ()))
   346             (parse_thy tok_src) tok_src);
   347       in Present.theory_output name (Buffer.content out) end
   348   end;
   349 
   350 in
   351 
   352 fun load_thy name ml time path =
   353  (if time then
   354     timeit (fn () =>
   355      (writeln ("\n**** Starting theory " ^ quote name ^ " ****");
   356       run_thy name path;
   357       writeln ("**** Finished theory " ^ quote name ^ " ****\n")))
   358   else run_thy name path;
   359   Context.context (ThyInfo.get_theory name);
   360   if ml then try_ml_file name time else ());
   361 
   362 end;
   363 
   364 
   365 
   366 (** the read-eval-print loop **)
   367 
   368 (* main loop *)
   369 
   370 fun gen_loop term no_pos =
   371  (Context.reset_context ();
   372   Toplevel.loop (isar term no_pos));
   373 
   374 fun gen_main term no_pos =
   375  (Toplevel.set_state Toplevel.toplevel;
   376   writeln (Session.welcome ());
   377   gen_loop term no_pos);
   378 
   379 fun main () = gen_main false false;
   380 fun loop () = gen_loop false false;
   381 fun sync_main () = gen_main true true;
   382 fun sync_loop () = gen_loop true true;
   383 
   384 
   385 (*final declarations of this structure!*)
   386 val command = parser false NONE;
   387 val markup_command = parser false o SOME;
   388 val improper_command = parser true NONE;
   389 
   390 
   391 end;
   392 
   393 (*setup theory syntax dependent operations*)
   394 ThyLoad.deps_thy_fn := OuterSyntax.deps_thy;
   395 ThyLoad.load_thy_fn := OuterSyntax.load_thy;
   396 structure ThyLoad: THY_LOAD = ThyLoad;
   397 
   398 structure BasicOuterSyntax: BASIC_OUTER_SYNTAX = OuterSyntax;
   399 open BasicOuterSyntax;