src/HOL/Set.thy
author nipkow
Mon Nov 05 18:18:39 2007 +0100 (2007-11-05)
changeset 25287 094dab519ff5
parent 24730 a87d8d31abc0
child 25360 b8251517f508
permissions -rw-r--r--
added lemmas
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4 *)
     5 
     6 header {* Set theory for higher-order logic *}
     7 
     8 theory Set
     9 imports Code_Setup
    10 begin
    11 
    12 text {* A set in HOL is simply a predicate. *}
    13 
    14 
    15 subsection {* Basic syntax *}
    16 
    17 global
    18 
    19 typedecl 'a set
    20 arities set :: (type) type
    21 
    22 consts
    23   "{}"          :: "'a set"                             ("{}")
    24   UNIV          :: "'a set"
    25   insert        :: "'a => 'a set => 'a set"
    26   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    27   "op Int"      :: "'a set => 'a set => 'a set"          (infixl "Int" 70)
    28   "op Un"       :: "'a set => 'a set => 'a set"          (infixl "Un" 65)
    29   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    30   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    31   Union         :: "'a set set => 'a set"                -- "union of a set"
    32   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    33   Pow           :: "'a set => 'a set set"                -- "powerset"
    34   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    35   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    36   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    37   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    38   "op :"        :: "'a => 'a set => bool"                -- "membership"
    39 
    40 notation
    41   "op :"  ("op :") and
    42   "op :"  ("(_/ : _)" [50, 51] 50)
    43 
    44 local
    45 
    46 
    47 subsection {* Additional concrete syntax *}
    48 
    49 abbreviation
    50   range :: "('a => 'b) => 'b set" where -- "of function"
    51   "range f == f ` UNIV"
    52 
    53 abbreviation
    54   "not_mem x A == ~ (x : A)" -- "non-membership"
    55 
    56 notation
    57   not_mem  ("op ~:") and
    58   not_mem  ("(_/ ~: _)" [50, 51] 50)
    59 
    60 notation (xsymbols)
    61   "op Int"  (infixl "\<inter>" 70) and
    62   "op Un"  (infixl "\<union>" 65) and
    63   "op :"  ("op \<in>") and
    64   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    65   not_mem  ("op \<notin>") and
    66   not_mem  ("(_/ \<notin> _)" [50, 51] 50) and
    67   Union  ("\<Union>_" [90] 90) and
    68   Inter  ("\<Inter>_" [90] 90)
    69 
    70 notation (HTML output)
    71   "op Int"  (infixl "\<inter>" 70) and
    72   "op Un"  (infixl "\<union>" 65) and
    73   "op :"  ("op \<in>") and
    74   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    75   not_mem  ("op \<notin>") and
    76   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    77 
    78 syntax
    79   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    80   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    81   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    82   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
    83   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
    84   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
    85   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
    86   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
    87   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    88   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    89   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    90   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    91 
    92 syntax (HOL)
    93   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    94   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    95   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    96 
    97 translations
    98   "{x, xs}"     == "insert x {xs}"
    99   "{x}"         == "insert x {}"
   100   "{x. P}"      == "Collect (%x. P)"
   101   "{x:A. P}"    => "{x. x:A & P}"
   102   "UN x y. B"   == "UN x. UN y. B"
   103   "UN x. B"     == "UNION UNIV (%x. B)"
   104   "UN x. B"     == "UN x:UNIV. B"
   105   "INT x y. B"  == "INT x. INT y. B"
   106   "INT x. B"    == "INTER UNIV (%x. B)"
   107   "INT x. B"    == "INT x:UNIV. B"
   108   "UN x:A. B"   == "UNION A (%x. B)"
   109   "INT x:A. B"  == "INTER A (%x. B)"
   110   "ALL x:A. P"  == "Ball A (%x. P)"
   111   "EX x:A. P"   == "Bex A (%x. P)"
   112   "EX! x:A. P"  == "Bex1 A (%x. P)"
   113   "LEAST x:A. P" => "LEAST x. x:A & P"
   114 
   115 syntax (xsymbols)
   116   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   117   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   118   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   119   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   120 
   121 syntax (HTML output)
   122   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   123   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   124   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   125 
   126 syntax (xsymbols)
   127   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   128   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   129   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   130   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   131   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   132 
   133 syntax (latex output)
   134   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   135   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   136   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   137   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   138 
   139 text{*
   140   Note the difference between ordinary xsymbol syntax of indexed
   141   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   142   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   143   former does not make the index expression a subscript of the
   144   union/intersection symbol because this leads to problems with nested
   145   subscripts in Proof General. *}
   146 
   147 instance set :: (type) ord
   148   subset_def:  "A \<le> B \<equiv> \<forall>x\<in>A. x \<in> B"
   149   psubset_def: "A < B \<equiv> A \<le> B \<and> A \<noteq> B" ..
   150 lemmas [code func del] = subset_def psubset_def
   151 
   152 abbreviation
   153   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   154   "subset \<equiv> less"
   155 
   156 abbreviation
   157   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   158   "subset_eq \<equiv> less_eq"
   159 
   160 notation (output)
   161   subset  ("op <") and
   162   subset  ("(_/ < _)" [50, 51] 50) and
   163   subset_eq  ("op <=") and
   164   subset_eq  ("(_/ <= _)" [50, 51] 50)
   165 
   166 notation (xsymbols)
   167   subset  ("op \<subset>") and
   168   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   169   subset_eq  ("op \<subseteq>") and
   170   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   171 
   172 notation (HTML output)
   173   subset  ("op \<subset>") and
   174   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   175   subset_eq  ("op \<subseteq>") and
   176   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   177 
   178 abbreviation (input)
   179   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   180   "supset \<equiv> greater"
   181 
   182 abbreviation (input)
   183   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   184   "supset_eq \<equiv> greater_eq"
   185 
   186 notation (xsymbols)
   187   supset  ("op \<supset>") and
   188   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   189   supset_eq  ("op \<supseteq>") and
   190   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   191 
   192 
   193 subsubsection "Bounded quantifiers"
   194 
   195 syntax (output)
   196   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   197   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   198   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   199   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   200   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   201 
   202 syntax (xsymbols)
   203   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   204   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   205   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   206   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   207   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   208 
   209 syntax (HOL output)
   210   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   211   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   212   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   213   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   214   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   215 
   216 syntax (HTML output)
   217   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   218   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   219   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   220   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   221   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   222 
   223 translations
   224  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   225  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   226  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   227  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   228  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   229 
   230 print_translation {*
   231 let
   232   val Type (set_type, _) = @{typ "'a set"};
   233   val All_binder = Syntax.binder_name @{const_syntax "All"};
   234   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   235   val impl = @{const_syntax "op -->"};
   236   val conj = @{const_syntax "op &"};
   237   val sbset = @{const_syntax "subset"};
   238   val sbset_eq = @{const_syntax "subset_eq"};
   239 
   240   val trans =
   241    [((All_binder, impl, sbset), "_setlessAll"),
   242     ((All_binder, impl, sbset_eq), "_setleAll"),
   243     ((Ex_binder, conj, sbset), "_setlessEx"),
   244     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   245 
   246   fun mk v v' c n P =
   247     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   248     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   249 
   250   fun tr' q = (q,
   251     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   252          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   253           of NONE => raise Match
   254            | SOME l => mk v v' l n P
   255          else raise Match
   256      | _ => raise Match);
   257 in
   258   [tr' All_binder, tr' Ex_binder]
   259 end
   260 *}
   261 
   262 
   263 text {*
   264   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   265   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   266   only translated if @{text "[0..n] subset bvs(e)"}.
   267 *}
   268 
   269 parse_translation {*
   270   let
   271     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   272 
   273     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   274       | nvars _ = 1;
   275 
   276     fun setcompr_tr [e, idts, b] =
   277       let
   278         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   279         val P = Syntax.const "op &" $ eq $ b;
   280         val exP = ex_tr [idts, P];
   281       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   282 
   283   in [("@SetCompr", setcompr_tr)] end;
   284 *}
   285 
   286 (* To avoid eta-contraction of body: *)
   287 print_translation {*
   288 let
   289   fun btr' syn [A,Abs abs] =
   290     let val (x,t) = atomic_abs_tr' abs
   291     in Syntax.const syn $ x $ A $ t end
   292 in
   293 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   294  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   295 end
   296 *}
   297 
   298 print_translation {*
   299 let
   300   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   301 
   302   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   303     let
   304       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   305         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   306             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   307             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   308         | check _ = false
   309 
   310         fun tr' (_ $ abs) =
   311           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   312           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   313     in if check (P, 0) then tr' P
   314        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   315                 val M = Syntax.const "@Coll" $ x $ t
   316             in case t of
   317                  Const("op &",_)
   318                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   319                    $ P =>
   320                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   321                | _ => M
   322             end
   323     end;
   324   in [("Collect", setcompr_tr')] end;
   325 *}
   326 
   327 
   328 subsection {* Rules and definitions *}
   329 
   330 text {* Isomorphisms between predicates and sets. *}
   331 
   332 axioms
   333   mem_Collect_eq: "(a : {x. P(x)}) = P(a)"
   334   Collect_mem_eq: "{x. x:A} = A"
   335 finalconsts
   336   Collect
   337   "op :"
   338 
   339 defs
   340   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   341   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   342   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   343 
   344 instance set :: (type) minus
   345   Compl_def:    "- A            == {x. ~x:A}"
   346   set_diff_def: "A - B          == {x. x:A & ~x:B}" ..
   347 
   348 lemmas [code func del] = Compl_def set_diff_def
   349 
   350 defs
   351   Un_def:       "A Un B         == {x. x:A | x:B}"
   352   Int_def:      "A Int B        == {x. x:A & x:B}"
   353   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   354   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   355   Inter_def:    "Inter S        == (INT x:S. x)"
   356   Union_def:    "Union S        == (UN x:S. x)"
   357   Pow_def:      "Pow A          == {B. B <= A}"
   358   empty_def:    "{}             == {x. False}"
   359   UNIV_def:     "UNIV           == {x. True}"
   360   insert_def:   "insert a B     == {x. x=a} Un B"
   361   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   362 
   363 
   364 subsection {* Lemmas and proof tool setup *}
   365 
   366 subsubsection {* Relating predicates and sets *}
   367 
   368 declare mem_Collect_eq [iff]  Collect_mem_eq [simp]
   369 
   370 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   371   by simp
   372 
   373 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   374   by simp
   375 
   376 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   377   by simp
   378 
   379 lemmas CollectE = CollectD [elim_format]
   380 
   381 
   382 subsubsection {* Bounded quantifiers *}
   383 
   384 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   385   by (simp add: Ball_def)
   386 
   387 lemmas strip = impI allI ballI
   388 
   389 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   390   by (simp add: Ball_def)
   391 
   392 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   393   by (unfold Ball_def) blast
   394 
   395 ML {* bind_thm ("rev_ballE", permute_prems 1 1 @{thm ballE}) *}
   396 
   397 text {*
   398   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   399   @{prop "a:A"}; creates assumption @{prop "P a"}.
   400 *}
   401 
   402 ML {*
   403   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   404 *}
   405 
   406 text {*
   407   Gives better instantiation for bound:
   408 *}
   409 
   410 ML_setup {*
   411   change_claset (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   412 *}
   413 
   414 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   415   -- {* Normally the best argument order: @{prop "P x"} constrains the
   416     choice of @{prop "x:A"}. *}
   417   by (unfold Bex_def) blast
   418 
   419 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   420   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   421   by (unfold Bex_def) blast
   422 
   423 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   424   by (unfold Bex_def) blast
   425 
   426 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   427   by (unfold Bex_def) blast
   428 
   429 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   430   -- {* Trival rewrite rule. *}
   431   by (simp add: Ball_def)
   432 
   433 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   434   -- {* Dual form for existentials. *}
   435   by (simp add: Bex_def)
   436 
   437 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   438   by blast
   439 
   440 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   441   by blast
   442 
   443 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   444   by blast
   445 
   446 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   447   by blast
   448 
   449 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   450   by blast
   451 
   452 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   453   by blast
   454 
   455 ML_setup {*
   456   local
   457     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   458     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   459     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   460 
   461     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   462     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   463     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   464   in
   465     val defBEX_regroup = Simplifier.simproc (the_context ())
   466       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   467     val defBALL_regroup = Simplifier.simproc (the_context ())
   468       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   469   end;
   470 
   471   Addsimprocs [defBALL_regroup, defBEX_regroup];
   472 *}
   473 
   474 
   475 subsubsection {* Congruence rules *}
   476 
   477 lemma ball_cong:
   478   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   479     (ALL x:A. P x) = (ALL x:B. Q x)"
   480   by (simp add: Ball_def)
   481 
   482 lemma strong_ball_cong [cong]:
   483   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   484     (ALL x:A. P x) = (ALL x:B. Q x)"
   485   by (simp add: simp_implies_def Ball_def)
   486 
   487 lemma bex_cong:
   488   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   489     (EX x:A. P x) = (EX x:B. Q x)"
   490   by (simp add: Bex_def cong: conj_cong)
   491 
   492 lemma strong_bex_cong [cong]:
   493   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   494     (EX x:A. P x) = (EX x:B. Q x)"
   495   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   496 
   497 
   498 subsubsection {* Subsets *}
   499 
   500 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   501   by (simp add: subset_def)
   502 
   503 text {*
   504   \medskip Map the type @{text "'a set => anything"} to just @{typ
   505   'a}; for overloading constants whose first argument has type @{typ
   506   "'a set"}.
   507 *}
   508 
   509 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   510   -- {* Rule in Modus Ponens style. *}
   511   by (unfold subset_def) blast
   512 
   513 declare subsetD [intro?] -- FIXME
   514 
   515 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   516   -- {* The same, with reversed premises for use with @{text erule} --
   517       cf @{text rev_mp}. *}
   518   by (rule subsetD)
   519 
   520 declare rev_subsetD [intro?] -- FIXME
   521 
   522 text {*
   523   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   524 *}
   525 
   526 ML {*
   527   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   528 *}
   529 
   530 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   531   -- {* Classical elimination rule. *}
   532   by (unfold subset_def) blast
   533 
   534 text {*
   535   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   536   creates the assumption @{prop "c \<in> B"}.
   537 *}
   538 
   539 ML {*
   540   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   541 *}
   542 
   543 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   544   by blast
   545 
   546 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   547   by fast
   548 
   549 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   550   by blast
   551 
   552 
   553 subsubsection {* Equality *}
   554 
   555 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   556   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   557    apply (rule Collect_mem_eq)
   558   apply (rule Collect_mem_eq)
   559   done
   560 
   561 (* Due to Brian Huffman *)
   562 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   563 by(auto intro:set_ext)
   564 
   565 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   566   -- {* Anti-symmetry of the subset relation. *}
   567   by (iprover intro: set_ext subsetD)
   568 
   569 lemmas equalityI [intro!] = subset_antisym
   570 
   571 text {*
   572   \medskip Equality rules from ZF set theory -- are they appropriate
   573   here?
   574 *}
   575 
   576 lemma equalityD1: "A = B ==> A \<subseteq> B"
   577   by (simp add: subset_refl)
   578 
   579 lemma equalityD2: "A = B ==> B \<subseteq> A"
   580   by (simp add: subset_refl)
   581 
   582 text {*
   583   \medskip Be careful when adding this to the claset as @{text
   584   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   585   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   586 *}
   587 
   588 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   589   by (simp add: subset_refl)
   590 
   591 lemma equalityCE [elim]:
   592     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   593   by blast
   594 
   595 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   596   by simp
   597 
   598 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   599   by simp
   600 
   601 
   602 subsubsection {* The universal set -- UNIV *}
   603 
   604 lemma UNIV_I [simp]: "x : UNIV"
   605   by (simp add: UNIV_def)
   606 
   607 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   608 
   609 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   610   by simp
   611 
   612 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   613   by (rule subsetI) (rule UNIV_I)
   614 
   615 text {*
   616   \medskip Eta-contracting these two rules (to remove @{text P})
   617   causes them to be ignored because of their interaction with
   618   congruence rules.
   619 *}
   620 
   621 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   622   by (simp add: Ball_def)
   623 
   624 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   625   by (simp add: Bex_def)
   626 
   627 
   628 subsubsection {* The empty set *}
   629 
   630 lemma empty_iff [simp]: "(c : {}) = False"
   631   by (simp add: empty_def)
   632 
   633 lemma emptyE [elim!]: "a : {} ==> P"
   634   by simp
   635 
   636 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   637     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   638   by blast
   639 
   640 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   641   by blast
   642 
   643 lemma equals0D: "A = {} ==> a \<notin> A"
   644     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   645   by blast
   646 
   647 lemma ball_empty [simp]: "Ball {} P = True"
   648   by (simp add: Ball_def)
   649 
   650 lemma bex_empty [simp]: "Bex {} P = False"
   651   by (simp add: Bex_def)
   652 
   653 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   654   by (blast elim: equalityE)
   655 
   656 
   657 subsubsection {* The Powerset operator -- Pow *}
   658 
   659 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   660   by (simp add: Pow_def)
   661 
   662 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   663   by (simp add: Pow_def)
   664 
   665 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   666   by (simp add: Pow_def)
   667 
   668 lemma Pow_bottom: "{} \<in> Pow B"
   669   by simp
   670 
   671 lemma Pow_top: "A \<in> Pow A"
   672   by (simp add: subset_refl)
   673 
   674 
   675 subsubsection {* Set complement *}
   676 
   677 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   678   by (unfold Compl_def) blast
   679 
   680 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   681   by (unfold Compl_def) blast
   682 
   683 text {*
   684   \medskip This form, with negated conclusion, works well with the
   685   Classical prover.  Negated assumptions behave like formulae on the
   686   right side of the notional turnstile ... *}
   687 
   688 lemma ComplD [dest!]: "c : -A ==> c~:A"
   689   by (unfold Compl_def) blast
   690 
   691 lemmas ComplE = ComplD [elim_format]
   692 
   693 
   694 subsubsection {* Binary union -- Un *}
   695 
   696 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   697   by (unfold Un_def) blast
   698 
   699 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   700   by simp
   701 
   702 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   703   by simp
   704 
   705 text {*
   706   \medskip Classical introduction rule: no commitment to @{prop A} vs
   707   @{prop B}.
   708 *}
   709 
   710 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   711   by auto
   712 
   713 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   714   by (unfold Un_def) blast
   715 
   716 
   717 subsubsection {* Binary intersection -- Int *}
   718 
   719 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   720   by (unfold Int_def) blast
   721 
   722 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   723   by simp
   724 
   725 lemma IntD1: "c : A Int B ==> c:A"
   726   by simp
   727 
   728 lemma IntD2: "c : A Int B ==> c:B"
   729   by simp
   730 
   731 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   732   by simp
   733 
   734 
   735 subsubsection {* Set difference *}
   736 
   737 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   738   by (unfold set_diff_def) blast
   739 
   740 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   741   by simp
   742 
   743 lemma DiffD1: "c : A - B ==> c : A"
   744   by simp
   745 
   746 lemma DiffD2: "c : A - B ==> c : B ==> P"
   747   by simp
   748 
   749 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   750   by simp
   751 
   752 
   753 subsubsection {* Augmenting a set -- insert *}
   754 
   755 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   756   by (unfold insert_def) blast
   757 
   758 lemma insertI1: "a : insert a B"
   759   by simp
   760 
   761 lemma insertI2: "a : B ==> a : insert b B"
   762   by simp
   763 
   764 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   765   by (unfold insert_def) blast
   766 
   767 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   768   -- {* Classical introduction rule. *}
   769   by auto
   770 
   771 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   772   by auto
   773 
   774 lemma set_insert:
   775   assumes "x \<in> A"
   776   obtains B where "A = insert x B" and "x \<notin> B"
   777 proof
   778   from assms show "A = insert x (A - {x})" by blast
   779 next
   780   show "x \<notin> A - {x}" by blast
   781 qed
   782 
   783 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   784 by auto
   785 
   786 subsubsection {* Singletons, using insert *}
   787 
   788 lemma singletonI [intro!,noatp]: "a : {a}"
   789     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   790   by (rule insertI1)
   791 
   792 lemma singletonD [dest!,noatp]: "b : {a} ==> b = a"
   793   by blast
   794 
   795 lemmas singletonE = singletonD [elim_format]
   796 
   797 lemma singleton_iff: "(b : {a}) = (b = a)"
   798   by blast
   799 
   800 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   801   by blast
   802 
   803 lemma singleton_insert_inj_eq [iff,noatp]:
   804      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   805   by blast
   806 
   807 lemma singleton_insert_inj_eq' [iff,noatp]:
   808      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   809   by blast
   810 
   811 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   812   by fast
   813 
   814 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   815   by blast
   816 
   817 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   818   by blast
   819 
   820 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   821   by blast
   822 
   823 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   824   by (blast elim: equalityE)
   825 
   826 
   827 subsubsection {* Unions of families *}
   828 
   829 text {*
   830   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   831 *}
   832 
   833 declare UNION_def [noatp]
   834 
   835 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   836   by (unfold UNION_def) blast
   837 
   838 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   839   -- {* The order of the premises presupposes that @{term A} is rigid;
   840     @{term b} may be flexible. *}
   841   by auto
   842 
   843 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   844   by (unfold UNION_def) blast
   845 
   846 lemma UN_cong [cong]:
   847     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   848   by (simp add: UNION_def)
   849 
   850 
   851 subsubsection {* Intersections of families *}
   852 
   853 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   854 
   855 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   856   by (unfold INTER_def) blast
   857 
   858 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   859   by (unfold INTER_def) blast
   860 
   861 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   862   by auto
   863 
   864 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   865   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   866   by (unfold INTER_def) blast
   867 
   868 lemma INT_cong [cong]:
   869     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   870   by (simp add: INTER_def)
   871 
   872 
   873 subsubsection {* Union *}
   874 
   875 lemma Union_iff [simp,noatp]: "(A : Union C) = (EX X:C. A:X)"
   876   by (unfold Union_def) blast
   877 
   878 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   879   -- {* The order of the premises presupposes that @{term C} is rigid;
   880     @{term A} may be flexible. *}
   881   by auto
   882 
   883 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   884   by (unfold Union_def) blast
   885 
   886 
   887 subsubsection {* Inter *}
   888 
   889 lemma Inter_iff [simp,noatp]: "(A : Inter C) = (ALL X:C. A:X)"
   890   by (unfold Inter_def) blast
   891 
   892 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   893   by (simp add: Inter_def)
   894 
   895 text {*
   896   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   897   contains @{term A} as an element, but @{prop "A:X"} can hold when
   898   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   899 *}
   900 
   901 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   902   by auto
   903 
   904 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   905   -- {* ``Classical'' elimination rule -- does not require proving
   906     @{prop "X:C"}. *}
   907   by (unfold Inter_def) blast
   908 
   909 text {*
   910   \medskip Image of a set under a function.  Frequently @{term b} does
   911   not have the syntactic form of @{term "f x"}.
   912 *}
   913 
   914 declare image_def [noatp]
   915 
   916 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   917   by (unfold image_def) blast
   918 
   919 lemma imageI: "x : A ==> f x : f ` A"
   920   by (rule image_eqI) (rule refl)
   921 
   922 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   923   -- {* This version's more effective when we already have the
   924     required @{term x}. *}
   925   by (unfold image_def) blast
   926 
   927 lemma imageE [elim!]:
   928   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   929   -- {* The eta-expansion gives variable-name preservation. *}
   930   by (unfold image_def) blast
   931 
   932 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   933   by blast
   934 
   935 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   936   by blast
   937 
   938 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   939   -- {* This rewrite rule would confuse users if made default. *}
   940   by blast
   941 
   942 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   943   apply safe
   944    prefer 2 apply fast
   945   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   946   done
   947 
   948 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   949   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   950     @{text hypsubst}, but breaks too many existing proofs. *}
   951   by blast
   952 
   953 text {*
   954   \medskip Range of a function -- just a translation for image!
   955 *}
   956 
   957 lemma range_eqI: "b = f x ==> b \<in> range f"
   958   by simp
   959 
   960 lemma rangeI: "f x \<in> range f"
   961   by simp
   962 
   963 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   964   by blast
   965 
   966 
   967 subsubsection {* Set reasoning tools *}
   968 
   969 text {*
   970   Rewrite rules for boolean case-splitting: faster than @{text
   971   "split_if [split]"}.
   972 *}
   973 
   974 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   975   by (rule split_if)
   976 
   977 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   978   by (rule split_if)
   979 
   980 text {*
   981   Split ifs on either side of the membership relation.  Not for @{text
   982   "[simp]"} -- can cause goals to blow up!
   983 *}
   984 
   985 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   986   by (rule split_if)
   987 
   988 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   989   by (rule split_if)
   990 
   991 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   992 
   993 lemmas mem_simps =
   994   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   995   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   996   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   997 
   998 (*Would like to add these, but the existing code only searches for the
   999   outer-level constant, which in this case is just "op :"; we instead need
  1000   to use term-nets to associate patterns with rules.  Also, if a rule fails to
  1001   apply, then the formula should be kept.
  1002   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
  1003    ("op Int", [IntD1,IntD2]),
  1004    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
  1005  *)
  1006 
  1007 ML_setup {*
  1008   val mksimps_pairs = [("Ball", @{thms bspec})] @ mksimps_pairs;
  1009   change_simpset (fn ss => ss setmksimps (mksimps mksimps_pairs));
  1010 *}
  1011 
  1012 
  1013 subsubsection {* The ``proper subset'' relation *}
  1014 
  1015 lemma psubsetI [intro!,noatp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1016   by (unfold psubset_def) blast
  1017 
  1018 lemma psubsetE [elim!,noatp]: 
  1019     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1020   by (unfold psubset_def) blast
  1021 
  1022 lemma psubset_insert_iff:
  1023   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1024   by (auto simp add: psubset_def subset_insert_iff)
  1025 
  1026 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1027   by (simp only: psubset_def)
  1028 
  1029 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1030   by (simp add: psubset_eq)
  1031 
  1032 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1033 apply (unfold psubset_def)
  1034 apply (auto dest: subset_antisym)
  1035 done
  1036 
  1037 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1038 apply (unfold psubset_def)
  1039 apply (auto dest: subsetD)
  1040 done
  1041 
  1042 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1043   by (auto simp add: psubset_eq)
  1044 
  1045 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1046   by (auto simp add: psubset_eq)
  1047 
  1048 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1049   by (unfold psubset_def) blast
  1050 
  1051 lemma atomize_ball:
  1052     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1053   by (simp only: Ball_def atomize_all atomize_imp)
  1054 
  1055 lemmas [symmetric, rulify] = atomize_ball
  1056   and [symmetric, defn] = atomize_ball
  1057 
  1058 
  1059 subsection {* Further set-theory lemmas *}
  1060 
  1061 subsubsection {* Derived rules involving subsets. *}
  1062 
  1063 text {* @{text insert}. *}
  1064 
  1065 lemma subset_insertI: "B \<subseteq> insert a B"
  1066   by (rule subsetI) (erule insertI2)
  1067 
  1068 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1069   by blast
  1070 
  1071 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1072   by blast
  1073 
  1074 
  1075 text {* \medskip Big Union -- least upper bound of a set. *}
  1076 
  1077 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1078   by (iprover intro: subsetI UnionI)
  1079 
  1080 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1081   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1082 
  1083 
  1084 text {* \medskip General union. *}
  1085 
  1086 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1087   by blast
  1088 
  1089 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1090   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1091 
  1092 
  1093 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1094 
  1095 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1096   by blast
  1097 
  1098 lemma Inter_subset:
  1099   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1100   by blast
  1101 
  1102 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1103   by (iprover intro: InterI subsetI dest: subsetD)
  1104 
  1105 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1106   by blast
  1107 
  1108 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1109   by (iprover intro: INT_I subsetI dest: subsetD)
  1110 
  1111 
  1112 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1113 
  1114 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1115   by blast
  1116 
  1117 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1118   by blast
  1119 
  1120 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1121   by blast
  1122 
  1123 
  1124 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1125 
  1126 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1127   by blast
  1128 
  1129 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1130   by blast
  1131 
  1132 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1133   by blast
  1134 
  1135 
  1136 text {* \medskip Set difference. *}
  1137 
  1138 lemma Diff_subset: "A - B \<subseteq> A"
  1139   by blast
  1140 
  1141 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1142 by blast
  1143 
  1144 
  1145 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1146 
  1147 text {* @{text "{}"}. *}
  1148 
  1149 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1150   -- {* supersedes @{text "Collect_False_empty"} *}
  1151   by auto
  1152 
  1153 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1154   by blast
  1155 
  1156 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1157   by (unfold psubset_def) blast
  1158 
  1159 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1160 by blast
  1161 
  1162 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1163 by blast
  1164 
  1165 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1166   by blast
  1167 
  1168 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1169   by blast
  1170 
  1171 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1172   by blast
  1173 
  1174 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1175   by blast
  1176 
  1177 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1178   by blast
  1179 
  1180 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1181   by blast
  1182 
  1183 lemma Collect_ex_eq [noatp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1184   by blast
  1185 
  1186 lemma Collect_bex_eq [noatp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1187   by blast
  1188 
  1189 
  1190 text {* \medskip @{text insert}. *}
  1191 
  1192 lemma insert_is_Un: "insert a A = {a} Un A"
  1193   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1194   by blast
  1195 
  1196 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1197   by blast
  1198 
  1199 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1200 declare empty_not_insert [simp]
  1201 
  1202 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1203   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1204   -- {* with \emph{quadratic} running time *}
  1205   by blast
  1206 
  1207 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1208   by blast
  1209 
  1210 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1211   by blast
  1212 
  1213 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1214   by blast
  1215 
  1216 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1217   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1218   apply (rule_tac x = "A - {a}" in exI, blast)
  1219   done
  1220 
  1221 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1222   by auto
  1223 
  1224 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1225   by blast
  1226 
  1227 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1228   by blast
  1229 
  1230 lemma insert_disjoint [simp,noatp]:
  1231  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1232  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1233   by auto
  1234 
  1235 lemma disjoint_insert [simp,noatp]:
  1236  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1237  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1238   by auto
  1239 
  1240 text {* \medskip @{text image}. *}
  1241 
  1242 lemma image_empty [simp]: "f`{} = {}"
  1243   by blast
  1244 
  1245 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1246   by blast
  1247 
  1248 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1249   by auto
  1250 
  1251 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1252 by auto
  1253 
  1254 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1255   by blast
  1256 
  1257 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1258   by blast
  1259 
  1260 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1261   by blast
  1262 
  1263 
  1264 lemma image_Collect [noatp]: "f ` {x. P x} = {f x | x. P x}"
  1265   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1266       with its implicit quantifier and conjunction.  Also image enjoys better
  1267       equational properties than does the RHS. *}
  1268   by blast
  1269 
  1270 lemma if_image_distrib [simp]:
  1271   "(\<lambda>x. if P x then f x else g x) ` S
  1272     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1273   by (auto simp add: image_def)
  1274 
  1275 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1276   by (simp add: image_def)
  1277 
  1278 
  1279 text {* \medskip @{text range}. *}
  1280 
  1281 lemma full_SetCompr_eq [noatp]: "{u. \<exists>x. u = f x} = range f"
  1282   by auto
  1283 
  1284 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1285 by (subst image_image, simp)
  1286 
  1287 
  1288 text {* \medskip @{text Int} *}
  1289 
  1290 lemma Int_absorb [simp]: "A \<inter> A = A"
  1291   by blast
  1292 
  1293 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1294   by blast
  1295 
  1296 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1297   by blast
  1298 
  1299 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1300   by blast
  1301 
  1302 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1303   by blast
  1304 
  1305 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1306   -- {* Intersection is an AC-operator *}
  1307 
  1308 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1309   by blast
  1310 
  1311 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1312   by blast
  1313 
  1314 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1315   by blast
  1316 
  1317 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1318   by blast
  1319 
  1320 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1321   by blast
  1322 
  1323 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1324   by blast
  1325 
  1326 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1327   by blast
  1328 
  1329 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1330   by blast
  1331 
  1332 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1333   by blast
  1334 
  1335 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1336   by blast
  1337 
  1338 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1339   by blast
  1340 
  1341 lemma Int_UNIV [simp,noatp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1342   by blast
  1343 
  1344 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1345   by blast
  1346 
  1347 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1348   by blast
  1349 
  1350 
  1351 text {* \medskip @{text Un}. *}
  1352 
  1353 lemma Un_absorb [simp]: "A \<union> A = A"
  1354   by blast
  1355 
  1356 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1357   by blast
  1358 
  1359 lemma Un_commute: "A \<union> B = B \<union> A"
  1360   by blast
  1361 
  1362 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1363   by blast
  1364 
  1365 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1366   by blast
  1367 
  1368 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1369   -- {* Union is an AC-operator *}
  1370 
  1371 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1372   by blast
  1373 
  1374 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1375   by blast
  1376 
  1377 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1378   by blast
  1379 
  1380 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1381   by blast
  1382 
  1383 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1384   by blast
  1385 
  1386 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1387   by blast
  1388 
  1389 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1390   by blast
  1391 
  1392 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1393   by blast
  1394 
  1395 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1396   by blast
  1397 
  1398 lemma Int_insert_left:
  1399     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1400   by auto
  1401 
  1402 lemma Int_insert_right:
  1403     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1404   by auto
  1405 
  1406 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1407   by blast
  1408 
  1409 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1410   by blast
  1411 
  1412 lemma Un_Int_crazy:
  1413     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1414   by blast
  1415 
  1416 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1417   by blast
  1418 
  1419 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1420   by blast
  1421 
  1422 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1423   by blast
  1424 
  1425 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1426   by blast
  1427 
  1428 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1429   by blast
  1430 
  1431 
  1432 text {* \medskip Set complement *}
  1433 
  1434 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1435   by blast
  1436 
  1437 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1438   by blast
  1439 
  1440 lemma Compl_partition: "A \<union> -A = UNIV"
  1441   by blast
  1442 
  1443 lemma Compl_partition2: "-A \<union> A = UNIV"
  1444   by blast
  1445 
  1446 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1447   by blast
  1448 
  1449 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1450   by blast
  1451 
  1452 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1453   by blast
  1454 
  1455 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1456   by blast
  1457 
  1458 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1459   by blast
  1460 
  1461 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1462   by blast
  1463 
  1464 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1465   -- {* Halmos, Naive Set Theory, page 16. *}
  1466   by blast
  1467 
  1468 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1469   by blast
  1470 
  1471 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1472   by blast
  1473 
  1474 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1475   by blast
  1476 
  1477 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1478   by blast
  1479 
  1480 
  1481 text {* \medskip @{text Union}. *}
  1482 
  1483 lemma Union_empty [simp]: "Union({}) = {}"
  1484   by blast
  1485 
  1486 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1487   by blast
  1488 
  1489 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1490   by blast
  1491 
  1492 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1493   by blast
  1494 
  1495 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1496   by blast
  1497 
  1498 lemma Union_empty_conv [simp,noatp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1499   by blast
  1500 
  1501 lemma empty_Union_conv [simp,noatp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1502   by blast
  1503 
  1504 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1505   by blast
  1506 
  1507 
  1508 text {* \medskip @{text Inter}. *}
  1509 
  1510 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1511   by blast
  1512 
  1513 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1514   by blast
  1515 
  1516 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1517   by blast
  1518 
  1519 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1520   by blast
  1521 
  1522 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1523   by blast
  1524 
  1525 lemma Inter_UNIV_conv [simp,noatp]:
  1526   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1527   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1528   by blast+
  1529 
  1530 
  1531 text {*
  1532   \medskip @{text UN} and @{text INT}.
  1533 
  1534   Basic identities: *}
  1535 
  1536 lemma UN_empty [simp,noatp]: "(\<Union>x\<in>{}. B x) = {}"
  1537   by blast
  1538 
  1539 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1540   by blast
  1541 
  1542 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1543   by blast
  1544 
  1545 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1546   by auto
  1547 
  1548 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1549   by blast
  1550 
  1551 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1552   by blast
  1553 
  1554 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1555   by blast
  1556 
  1557 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1558   by blast
  1559 
  1560 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1561   by blast
  1562 
  1563 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1564   by blast
  1565 
  1566 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1567   by blast
  1568 
  1569 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1570   by blast
  1571 
  1572 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1573   by blast
  1574 
  1575 lemma INT_insert_distrib:
  1576     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1577   by blast
  1578 
  1579 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1580   by blast
  1581 
  1582 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1583   by blast
  1584 
  1585 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1586   by blast
  1587 
  1588 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1589   by auto
  1590 
  1591 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1592   by auto
  1593 
  1594 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1595   by blast
  1596 
  1597 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1598   -- {* Look: it has an \emph{existential} quantifier *}
  1599   by blast
  1600 
  1601 lemma UNION_empty_conv[simp]:
  1602   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1603   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1604 by blast+
  1605 
  1606 lemma INTER_UNIV_conv[simp]:
  1607  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1608  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1609 by blast+
  1610 
  1611 
  1612 text {* \medskip Distributive laws: *}
  1613 
  1614 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1615   by blast
  1616 
  1617 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1618   by blast
  1619 
  1620 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1621   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1622   -- {* Union of a family of unions *}
  1623   by blast
  1624 
  1625 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1626   -- {* Equivalent version *}
  1627   by blast
  1628 
  1629 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1630   by blast
  1631 
  1632 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1633   by blast
  1634 
  1635 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1636   -- {* Equivalent version *}
  1637   by blast
  1638 
  1639 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1640   -- {* Halmos, Naive Set Theory, page 35. *}
  1641   by blast
  1642 
  1643 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1644   by blast
  1645 
  1646 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1647   by blast
  1648 
  1649 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1650   by blast
  1651 
  1652 
  1653 text {* \medskip Bounded quantifiers.
  1654 
  1655   The following are not added to the default simpset because
  1656   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1657 
  1658 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1659   by blast
  1660 
  1661 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1662   by blast
  1663 
  1664 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1665   by blast
  1666 
  1667 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1668   by blast
  1669 
  1670 
  1671 text {* \medskip Set difference. *}
  1672 
  1673 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1674   by blast
  1675 
  1676 lemma Diff_eq_empty_iff [simp,noatp]: "(A - B = {}) = (A \<subseteq> B)"
  1677   by blast
  1678 
  1679 lemma Diff_cancel [simp]: "A - A = {}"
  1680   by blast
  1681 
  1682 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1683 by blast
  1684 
  1685 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1686   by (blast elim: equalityE)
  1687 
  1688 lemma empty_Diff [simp]: "{} - A = {}"
  1689   by blast
  1690 
  1691 lemma Diff_empty [simp]: "A - {} = A"
  1692   by blast
  1693 
  1694 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1695   by blast
  1696 
  1697 lemma Diff_insert0 [simp,noatp]: "x \<notin> A ==> A - insert x B = A - B"
  1698   by blast
  1699 
  1700 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1701   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1702   by blast
  1703 
  1704 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1705   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1706   by blast
  1707 
  1708 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1709   by auto
  1710 
  1711 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1712   by blast
  1713 
  1714 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1715 by blast
  1716 
  1717 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1718   by blast
  1719 
  1720 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1721   by auto
  1722 
  1723 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1724   by blast
  1725 
  1726 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1727   by blast
  1728 
  1729 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1730   by blast
  1731 
  1732 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1733   by blast
  1734 
  1735 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1736   by blast
  1737 
  1738 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1739   by blast
  1740 
  1741 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1742   by blast
  1743 
  1744 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1745   by blast
  1746 
  1747 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1748   by blast
  1749 
  1750 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1751   by blast
  1752 
  1753 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1754   by blast
  1755 
  1756 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1757   by auto
  1758 
  1759 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1760   by blast
  1761 
  1762 
  1763 text {* \medskip Quantification over type @{typ bool}. *}
  1764 
  1765 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1766   by (cases x) auto
  1767 
  1768 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1769   by (auto intro: bool_induct)
  1770 
  1771 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1772   by (cases x) auto
  1773 
  1774 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1775   by (auto intro: bool_contrapos)
  1776 
  1777 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1778   by (auto simp add: split_if_mem2)
  1779 
  1780 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1781   by (auto intro: bool_contrapos)
  1782 
  1783 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1784   by (auto intro: bool_induct)
  1785 
  1786 text {* \medskip @{text Pow} *}
  1787 
  1788 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1789   by (auto simp add: Pow_def)
  1790 
  1791 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1792   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1793 
  1794 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1795   by (blast intro: exI [where ?x = "- u", standard])
  1796 
  1797 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1798   by blast
  1799 
  1800 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1801   by blast
  1802 
  1803 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1804   by blast
  1805 
  1806 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1807   by blast
  1808 
  1809 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1810   by blast
  1811 
  1812 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1813   by blast
  1814 
  1815 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1816   by blast
  1817 
  1818 
  1819 text {* \medskip Miscellany. *}
  1820 
  1821 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1822   by blast
  1823 
  1824 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1825   by blast
  1826 
  1827 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1828   by (unfold psubset_def) blast
  1829 
  1830 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1831   by blast
  1832 
  1833 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1834   by blast
  1835 
  1836 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1837   by iprover
  1838 
  1839 
  1840 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1841            and Intersections. *}
  1842 
  1843 lemma UN_simps [simp]:
  1844   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1845   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1846   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1847   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1848   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1849   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1850   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1851   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1852   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1853   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1854   by auto
  1855 
  1856 lemma INT_simps [simp]:
  1857   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1858   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1859   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1860   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1861   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1862   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1863   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1864   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1865   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1866   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1867   by auto
  1868 
  1869 lemma ball_simps [simp,noatp]:
  1870   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1871   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1872   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1873   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1874   "!!P. (ALL x:{}. P x) = True"
  1875   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1876   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1877   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1878   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1879   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1880   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1881   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1882   by auto
  1883 
  1884 lemma bex_simps [simp,noatp]:
  1885   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1886   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1887   "!!P. (EX x:{}. P x) = False"
  1888   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1889   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1890   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1891   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1892   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1893   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1894   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1895   by auto
  1896 
  1897 lemma ball_conj_distrib:
  1898   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1899   by blast
  1900 
  1901 lemma bex_disj_distrib:
  1902   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1903   by blast
  1904 
  1905 
  1906 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1907 
  1908 lemma UN_extend_simps:
  1909   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1910   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1911   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1912   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1913   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1914   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1915   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1916   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1917   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1918   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1919   by auto
  1920 
  1921 lemma INT_extend_simps:
  1922   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1923   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1924   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1925   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1926   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1927   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1928   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1929   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1930   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1931   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1932   by auto
  1933 
  1934 
  1935 subsubsection {* Monotonicity of various operations *}
  1936 
  1937 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1938   by blast
  1939 
  1940 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1941   by blast
  1942 
  1943 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1944   by blast
  1945 
  1946 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1947   by blast
  1948 
  1949 lemma UN_mono:
  1950   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1951     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1952   by (blast dest: subsetD)
  1953 
  1954 lemma INT_anti_mono:
  1955   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1956     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1957   -- {* The last inclusion is POSITIVE! *}
  1958   by (blast dest: subsetD)
  1959 
  1960 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1961   by blast
  1962 
  1963 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1964   by blast
  1965 
  1966 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1967   by blast
  1968 
  1969 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1970   by blast
  1971 
  1972 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1973   by blast
  1974 
  1975 text {* \medskip Monotonicity of implications. *}
  1976 
  1977 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1978   apply (rule impI)
  1979   apply (erule subsetD, assumption)
  1980   done
  1981 
  1982 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1983   by iprover
  1984 
  1985 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1986   by iprover
  1987 
  1988 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1989   by iprover
  1990 
  1991 lemma imp_refl: "P --> P" ..
  1992 
  1993 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1994   by iprover
  1995 
  1996 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1997   by iprover
  1998 
  1999 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2000   by blast
  2001 
  2002 lemma Int_Collect_mono:
  2003     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2004   by blast
  2005 
  2006 lemmas basic_monos =
  2007   subset_refl imp_refl disj_mono conj_mono
  2008   ex_mono Collect_mono in_mono
  2009 
  2010 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2011   by iprover
  2012 
  2013 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2014   by iprover
  2015 
  2016 
  2017 subsection {* Inverse image of a function *}
  2018 
  2019 constdefs
  2020   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2021   "f -` B == {x. f x : B}"
  2022 
  2023 
  2024 subsubsection {* Basic rules *}
  2025 
  2026 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2027   by (unfold vimage_def) blast
  2028 
  2029 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2030   by simp
  2031 
  2032 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2033   by (unfold vimage_def) blast
  2034 
  2035 lemma vimageI2: "f a : A ==> a : f -` A"
  2036   by (unfold vimage_def) fast
  2037 
  2038 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2039   by (unfold vimage_def) blast
  2040 
  2041 lemma vimageD: "a : f -` A ==> f a : A"
  2042   by (unfold vimage_def) fast
  2043 
  2044 
  2045 subsubsection {* Equations *}
  2046 
  2047 lemma vimage_empty [simp]: "f -` {} = {}"
  2048   by blast
  2049 
  2050 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2051   by blast
  2052 
  2053 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2054   by blast
  2055 
  2056 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2057   by fast
  2058 
  2059 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2060   by blast
  2061 
  2062 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2063   by blast
  2064 
  2065 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2066   by blast
  2067 
  2068 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2069   by blast
  2070 
  2071 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2072   by blast
  2073 
  2074 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2075   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2076   by blast
  2077 
  2078 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2079   by blast
  2080 
  2081 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2082   by blast
  2083 
  2084 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2085   -- {* NOT suitable for rewriting *}
  2086   by blast
  2087 
  2088 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2089   -- {* monotonicity *}
  2090   by blast
  2091 
  2092 
  2093 subsection {* Getting the Contents of a Singleton Set *}
  2094 
  2095 definition
  2096   contents :: "'a set \<Rightarrow> 'a"
  2097 where
  2098   [code func del]: "contents X = (THE x. X = {x})"
  2099 
  2100 lemma contents_eq [simp]: "contents {x} = x"
  2101   by (simp add: contents_def)
  2102 
  2103 
  2104 subsection {* Transitivity rules for calculational reasoning *}
  2105 
  2106 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2107   by (rule subsetD)
  2108 
  2109 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2110   by (rule subsetD)
  2111 
  2112 
  2113 subsection {* Code generation for finite sets *}
  2114 
  2115 code_datatype "{}" insert
  2116 
  2117 
  2118 subsubsection {* Primitive predicates *}
  2119 
  2120 definition
  2121   is_empty :: "'a set \<Rightarrow> bool"
  2122 where
  2123   [code func del]: "is_empty A \<longleftrightarrow> A = {}"
  2124 lemmas [code inline] = is_empty_def [symmetric]
  2125 
  2126 lemma is_empty_insert [code func]:
  2127   "is_empty (insert a A) \<longleftrightarrow> False"
  2128   by (simp add: is_empty_def)
  2129 
  2130 lemma is_empty_empty [code func]:
  2131   "is_empty {} \<longleftrightarrow> True"
  2132   by (simp add: is_empty_def)
  2133 
  2134 lemma Ball_insert [code func]:
  2135   "Ball (insert a A) P \<longleftrightarrow> P a \<and> Ball A P"
  2136   by simp
  2137 
  2138 lemma Ball_empty [code func]:
  2139   "Ball {} P \<longleftrightarrow> True"
  2140   by simp
  2141 
  2142 lemma Bex_insert [code func]:
  2143   "Bex (insert a A) P \<longleftrightarrow> P a \<or> Bex A P"
  2144   by simp
  2145 
  2146 lemma Bex_empty [code func]:
  2147   "Bex {} P \<longleftrightarrow> False"
  2148   by simp
  2149 
  2150 
  2151 subsubsection {* Primitive operations *}
  2152 
  2153 lemma minus_insert [code func]:
  2154   "insert (a\<Colon>'a\<Colon>eq) A - B = (let C = A - B in if a \<in> B then C else insert a C)"
  2155   by (auto simp add: Let_def)
  2156 
  2157 lemma minus_empty1 [code func]:
  2158   "{} - A = {}"
  2159   by simp
  2160 
  2161 lemma minus_empty2 [code func]:
  2162   "A - {} = A"
  2163   by simp
  2164 
  2165 lemma inter_insert [code func]:
  2166   "insert a A \<inter> B = (let C = A \<inter> B in if a \<in> B then insert a C else C)"
  2167   by (auto simp add: Let_def)
  2168 
  2169 lemma inter_empty1 [code func]:
  2170   "{} \<inter> A = {}"
  2171   by simp
  2172 
  2173 lemma inter_empty2 [code func]:
  2174   "A \<inter> {} = {}"
  2175   by simp
  2176 
  2177 lemma union_insert [code func]:
  2178   "insert a A \<union> B = (let C = A \<union> B in if a \<in> B then C else insert a C)"
  2179   by (auto simp add: Let_def)
  2180 
  2181 lemma union_empty1 [code func]:
  2182   "{} \<union> A = A"
  2183   by simp
  2184 
  2185 lemma union_empty2 [code func]:
  2186   "A \<union> {} = A"
  2187   by simp
  2188 
  2189 lemma INTER_insert [code func]:
  2190   "INTER (insert a A) f = f a \<inter> INTER A f"
  2191   by auto
  2192 
  2193 lemma INTER_singleton [code func]:
  2194   "INTER {a} f = f a"
  2195   by auto
  2196 
  2197 lemma UNION_insert [code func]:
  2198   "UNION (insert a A) f = f a \<union> UNION A f"
  2199   by auto
  2200 
  2201 lemma UNION_empty [code func]:
  2202   "UNION {} f = {}"
  2203   by auto
  2204 
  2205 lemma contents_insert [code func]:
  2206   "contents (insert a A) = contents (insert a (A - {a}))"
  2207   by auto
  2208 declare contents_eq [code func]
  2209 
  2210 
  2211 subsubsection {* Derived predicates *}
  2212 
  2213 lemma in_code [code func]:
  2214   "a \<in> A \<longleftrightarrow> (\<exists>x\<in>A. a = x)"
  2215   by simp
  2216 
  2217 instance set :: (eq) eq ..
  2218 
  2219 lemma eq_set_code [code func]:
  2220   fixes A B :: "'a\<Colon>eq set"
  2221   shows "A = B \<longleftrightarrow> A \<subseteq> B \<and> B \<subseteq> A"
  2222   by auto
  2223 
  2224 lemma subset_eq_code [code func]:
  2225   fixes A B :: "'a\<Colon>eq set"
  2226   shows "A \<subseteq> B \<longleftrightarrow> (\<forall>x\<in>A. x \<in> B)"
  2227   by auto
  2228 
  2229 lemma subset_code [code func]:
  2230   fixes A B :: "'a\<Colon>eq set"
  2231   shows "A \<subset> B \<longleftrightarrow> A \<subseteq> B \<and> \<not> B \<subseteq> A"
  2232   by auto
  2233 
  2234 
  2235 subsubsection {* Derived operations *}
  2236 
  2237 lemma image_code [code func]:
  2238   "image f A = UNION A (\<lambda>x. {f x})" by auto
  2239 
  2240 definition
  2241   project :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'a set" where
  2242   [code func del, code post]: "project P A = {a\<in>A. P a}"
  2243 
  2244 lemmas [symmetric, code inline] = project_def
  2245 
  2246 lemma project_code [code func]:
  2247   "project P A = UNION A (\<lambda>a. if P a then {a} else {})"
  2248   by (auto simp add: project_def split: if_splits)
  2249 
  2250 lemma Inter_code [code func]:
  2251   "Inter A = INTER A (\<lambda>x. x)"
  2252   by auto
  2253 
  2254 lemma Union_code [code func]:
  2255   "Union A = UNION A (\<lambda>x. x)"
  2256   by auto
  2257 
  2258 
  2259 subsection {* Basic ML bindings *}
  2260 
  2261 ML {*
  2262 val Ball_def = @{thm Ball_def}
  2263 val Bex_def = @{thm Bex_def}
  2264 val CollectD = @{thm CollectD}
  2265 val CollectE = @{thm CollectE}
  2266 val CollectI = @{thm CollectI}
  2267 val Collect_conj_eq = @{thm Collect_conj_eq}
  2268 val Collect_mem_eq = @{thm Collect_mem_eq}
  2269 val IntD1 = @{thm IntD1}
  2270 val IntD2 = @{thm IntD2}
  2271 val IntE = @{thm IntE}
  2272 val IntI = @{thm IntI}
  2273 val Int_Collect = @{thm Int_Collect}
  2274 val UNIV_I = @{thm UNIV_I}
  2275 val UNIV_witness = @{thm UNIV_witness}
  2276 val UnE = @{thm UnE}
  2277 val UnI1 = @{thm UnI1}
  2278 val UnI2 = @{thm UnI2}
  2279 val ballE = @{thm ballE}
  2280 val ballI = @{thm ballI}
  2281 val bexCI = @{thm bexCI}
  2282 val bexE = @{thm bexE}
  2283 val bexI = @{thm bexI}
  2284 val bex_triv = @{thm bex_triv}
  2285 val bspec = @{thm bspec}
  2286 val contra_subsetD = @{thm contra_subsetD}
  2287 val distinct_lemma = @{thm distinct_lemma}
  2288 val eq_to_mono = @{thm eq_to_mono}
  2289 val eq_to_mono2 = @{thm eq_to_mono2}
  2290 val equalityCE = @{thm equalityCE}
  2291 val equalityD1 = @{thm equalityD1}
  2292 val equalityD2 = @{thm equalityD2}
  2293 val equalityE = @{thm equalityE}
  2294 val equalityI = @{thm equalityI}
  2295 val imageE = @{thm imageE}
  2296 val imageI = @{thm imageI}
  2297 val image_Un = @{thm image_Un}
  2298 val image_insert = @{thm image_insert}
  2299 val insert_commute = @{thm insert_commute}
  2300 val insert_iff = @{thm insert_iff}
  2301 val mem_Collect_eq = @{thm mem_Collect_eq}
  2302 val rangeE = @{thm rangeE}
  2303 val rangeI = @{thm rangeI}
  2304 val range_eqI = @{thm range_eqI}
  2305 val subsetCE = @{thm subsetCE}
  2306 val subsetD = @{thm subsetD}
  2307 val subsetI = @{thm subsetI}
  2308 val subset_refl = @{thm subset_refl}
  2309 val subset_trans = @{thm subset_trans}
  2310 val vimageD = @{thm vimageD}
  2311 val vimageE = @{thm vimageE}
  2312 val vimageI = @{thm vimageI}
  2313 val vimageI2 = @{thm vimageI2}
  2314 val vimage_Collect = @{thm vimage_Collect}
  2315 val vimage_Int = @{thm vimage_Int}
  2316 val vimage_Un = @{thm vimage_Un}
  2317 *}
  2318 
  2319 end