src/HOL/Complete_Lattice.thy
author haftmann
Wed Jul 13 07:26:31 2011 +0200 (2011-07-13)
changeset 43801 097732301fc0
parent 43756 15ea1a07a8cf
child 43814 58791b75cf1f
permissions -rw-r--r--
more generalization towards complete lattices
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_empty Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_empty Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
    93   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
    97   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
    98   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   103   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   107   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   108   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   109 qed
   110 
   111 lemma top_le:
   112   "\<top> \<sqsubseteq> x \<Longrightarrow> x = \<top>"
   113   by (rule antisym) auto
   114 
   115 lemma le_bot:
   116   "x \<sqsubseteq> \<bottom> \<Longrightarrow> x = \<bottom>"
   117   by (rule antisym) auto
   118 
   119 lemma not_less_bot[simp]: "\<not> (x \<sqsubset> \<bottom>)"
   120   using bot_least[of x] by (auto simp: le_less)
   121 
   122 lemma not_top_less[simp]: "\<not> (\<top> \<sqsubset> x)"
   123   using top_greatest[of x] by (auto simp: le_less)
   124 
   125 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   126   using Sup_upper[of u A] by auto
   127 
   128 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   129   using Inf_lower[of u A] by auto
   130 
   131 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   132   "INFI A f = \<Sqinter> (f ` A)"
   133 
   134 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   135   "SUPR A f = \<Squnion> (f ` A)"
   136 
   137 end
   138 
   139 syntax
   140   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   141   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   142   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   143   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   144 
   145 syntax (xsymbols)
   146   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   147   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   148   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   149   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   150 
   151 translations
   152   "INF x y. B"   == "INF x. INF y. B"
   153   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   154   "INF x. B"     == "INF x:CONST UNIV. B"
   155   "INF x:A. B"   == "CONST INFI A (%x. B)"
   156   "SUP x y. B"   == "SUP x. SUP y. B"
   157   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   158   "SUP x. B"     == "SUP x:CONST UNIV. B"
   159   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   160 
   161 print_translation {*
   162   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   163     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   164 *} -- {* to avoid eta-contraction of body *}
   165 
   166 context complete_lattice
   167 begin
   168 
   169 lemma SUP_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> SUPR A f = SUPR A g"
   170   by (simp add: SUPR_def cong: image_cong)
   171 
   172 lemma INF_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> INFI A f = INFI A g"
   173   by (simp add: INFI_def cong: image_cong)
   174 
   175 lemma le_SUPI: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   176   by (auto simp add: SUPR_def intro: Sup_upper)
   177 
   178 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> M i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   179   using le_SUPI[of i A M] by auto
   180 
   181 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. M i) \<sqsubseteq> u"
   182   by (auto simp add: SUPR_def intro: Sup_least)
   183 
   184 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> M i"
   185   by (auto simp add: INFI_def intro: Inf_lower)
   186 
   187 lemma INF_leI2: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> u"
   188   using INF_leI[of i A M] by auto
   189 
   190 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. M i)"
   191   by (auto simp add: INFI_def intro: Inf_greatest)
   192 
   193 lemma SUP_le_iff: "(\<Squnion>i\<in>A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   194   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   195 
   196 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   197   unfolding INFI_def by (auto simp add: le_Inf_iff)
   198 
   199 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. M) = M"
   200   by (auto intro: antisym INF_leI le_INFI)
   201 
   202 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. M) = M"
   203   by (auto intro: antisym SUP_leI le_SUPI)
   204 
   205 lemma INF_mono:
   206   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   207   by (force intro!: Inf_mono simp: INFI_def)
   208 
   209 lemma SUP_mono:
   210   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   211   by (force intro!: Sup_mono simp: SUPR_def)
   212 
   213 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<sqsubseteq> INFI A f"
   214   by (intro INF_mono) auto
   215 
   216 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<sqsubseteq> SUPR B f"
   217   by (intro SUP_mono) auto
   218 
   219 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   220   by (iprover intro: INF_leI le_INFI order_trans antisym)
   221 
   222 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   223   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   224 
   225 end
   226 
   227 lemma Inf_less_iff:
   228   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   229   shows "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   230   unfolding not_le [symmetric] le_Inf_iff by auto
   231 
   232 lemma less_Sup_iff:
   233   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   234   shows "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   235   unfolding not_le [symmetric] Sup_le_iff by auto
   236 
   237 lemma INF_less_iff:
   238   fixes a :: "'a::{complete_lattice,linorder}"
   239   shows "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   240   unfolding INFI_def Inf_less_iff by auto
   241 
   242 lemma less_SUP_iff:
   243   fixes a :: "'a::{complete_lattice,linorder}"
   244   shows "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   245   unfolding SUPR_def less_Sup_iff by auto
   246 
   247 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   248 
   249 instantiation bool :: complete_lattice
   250 begin
   251 
   252 definition
   253   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   254 
   255 definition
   256   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   257 
   258 instance proof
   259 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   260 
   261 end
   262 
   263 lemma INFI_bool_eq [simp]:
   264   "INFI = Ball"
   265 proof (rule ext)+
   266   fix A :: "'a set"
   267   fix P :: "'a \<Rightarrow> bool"
   268   show "(\<Sqinter>x\<in>A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
   269     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   270 qed
   271 
   272 lemma SUPR_bool_eq [simp]:
   273   "SUPR = Bex"
   274 proof (rule ext)+
   275   fix A :: "'a set"
   276   fix P :: "'a \<Rightarrow> bool"
   277   show "(\<Squnion>x\<in>A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P x)"
   278     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   279 qed
   280 
   281 instantiation "fun" :: (type, complete_lattice) complete_lattice
   282 begin
   283 
   284 definition
   285   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   286 
   287 lemma Inf_apply:
   288   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   289   by (simp add: Inf_fun_def)
   290 
   291 definition
   292   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   293 
   294 lemma Sup_apply:
   295   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   296   by (simp add: Sup_fun_def)
   297 
   298 instance proof
   299 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   300   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   301 
   302 end
   303 
   304 lemma INFI_apply:
   305   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   306   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   307 
   308 lemma SUPR_apply:
   309   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   310   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   311 
   312 
   313 subsection {* Inter *}
   314 
   315 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   316   "Inter S \<equiv> \<Sqinter>S"
   317   
   318 notation (xsymbols)
   319   Inter  ("\<Inter>_" [90] 90)
   320 
   321 lemma Inter_eq:
   322   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   323 proof (rule set_eqI)
   324   fix x
   325   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   326     by auto
   327   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   328     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   329 qed
   330 
   331 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   332   by (unfold Inter_eq) blast
   333 
   334 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   335   by (simp add: Inter_eq)
   336 
   337 text {*
   338   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   339   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   340   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   341 *}
   342 
   343 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   344   by auto
   345 
   346 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   347   -- {* ``Classical'' elimination rule -- does not require proving
   348     @{prop "X \<in> C"}. *}
   349   by (unfold Inter_eq) blast
   350 
   351 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   352   by (fact Inf_lower)
   353 
   354 lemma (in complete_lattice) Inf_less_eq:
   355   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   356     and "A \<noteq> {}"
   357   shows "\<Sqinter>A \<sqsubseteq> u"
   358 proof -
   359   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   360   moreover with assms have "v \<sqsubseteq> u" by blast
   361   ultimately show ?thesis by (rule Inf_lower2)
   362 qed
   363 
   364 lemma Inter_subset:
   365   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   366   by (fact Inf_less_eq)
   367 
   368 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   369   by (fact Inf_greatest)
   370 
   371 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   372   by (fact Inf_binary [symmetric])
   373 
   374 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   375   by (fact Inf_empty)
   376 
   377 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   378   by (fact Inf_UNIV)
   379 
   380 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   381   by (fact Inf_insert)
   382 
   383 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   384   by (auto intro: Inf_greatest Inf_lower)
   385 
   386 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   387   by (fact Inf_inter_less)
   388 
   389 lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   390   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   391 
   392 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   393   by (fact Inf_union_distrib)
   394 
   395 lemma (in bounded_lattice_bot) bot_less:
   396   -- {* FIXME: tighten classes bot, top to partial orders (uniqueness!), move lemmas there *}
   397   "a \<noteq> bot \<longleftrightarrow> bot < a"
   398   by (auto simp add: less_le_not_le intro!: antisym)
   399 
   400 lemma (in bounded_lattice_top) less_top:
   401   "a \<noteq> top \<longleftrightarrow> a < top"
   402   by (auto simp add: less_le_not_le intro!: antisym)
   403 
   404 lemma (in complete_lattice) Inf_top_conv [no_atp]:
   405   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   406   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   407 proof -
   408   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   409   proof
   410     assume "\<forall>x\<in>A. x = \<top>"
   411     then have "A = {} \<or> A = {\<top>}" by auto
   412     then show "\<Sqinter>A = \<top>" by auto
   413   next
   414     assume "\<Sqinter>A = \<top>"
   415     show "\<forall>x\<in>A. x = \<top>"
   416     proof (rule ccontr)
   417       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   418       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   419       then obtain B where "A = insert x B" by blast
   420       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by (simp add: Inf_insert)
   421     qed
   422   qed
   423   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   424 qed
   425 
   426 lemma Inter_UNIV_conv [simp,no_atp]:
   427   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   428   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   429   by (fact Inf_top_conv)+
   430 
   431 lemma (in complete_lattice) Inf_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   432   by (auto intro: Inf_greatest Inf_lower)
   433 
   434 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   435   by (fact Inf_anti_mono)
   436 
   437 
   438 subsection {* Intersections of families *}
   439 
   440 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   441   "INTER \<equiv> INFI"
   442 
   443 syntax
   444   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   445   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   446 
   447 syntax (xsymbols)
   448   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   449   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   450 
   451 syntax (latex output)
   452   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   453   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   454 
   455 translations
   456   "INT x y. B"  == "INT x. INT y. B"
   457   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   458   "INT x. B"    == "INT x:CONST UNIV. B"
   459   "INT x:A. B"  == "CONST INTER A (%x. B)"
   460 
   461 print_translation {*
   462   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   463 *} -- {* to avoid eta-contraction of body *}
   464 
   465 lemma INTER_eq_Inter_image:
   466   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   467   by (fact INFI_def)
   468   
   469 lemma Inter_def:
   470   "\<Inter>S = (\<Inter>x\<in>S. x)"
   471   by (simp add: INTER_eq_Inter_image image_def)
   472 
   473 lemma INTER_def:
   474   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   475   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   476 
   477 lemma Inter_image_eq [simp]:
   478   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   479   by (rule sym) (fact INFI_def)
   480 
   481 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   482   by (unfold INTER_def) blast
   483 
   484 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   485   by (unfold INTER_def) blast
   486 
   487 lemma INT_D [elim, Pure.elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   488   by auto
   489 
   490 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   491   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   492   by (unfold INTER_def) blast
   493 
   494 lemma INT_cong [cong]:
   495     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   496   by (simp add: INTER_def)
   497 
   498 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   499   by blast
   500 
   501 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   502   by blast
   503 
   504 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   505   by (fact INF_leI)
   506 
   507 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   508   by (fact le_INFI)
   509 
   510 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   511   by blast
   512 
   513 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   514   by blast
   515 
   516 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   517   by (fact le_INF_iff)
   518 
   519 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   520   by blast
   521 
   522 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   523   by blast
   524 
   525 lemma INT_insert_distrib:
   526     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   527   by blast
   528 
   529 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   530   by auto
   531 
   532 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   533   -- {* Look: it has an \emph{existential} quantifier *}
   534   by blast
   535 
   536 lemma INTER_UNIV_conv[simp]:
   537  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   538  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   539 by blast+
   540 
   541 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
   542   by (auto intro: bool_induct)
   543 
   544 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   545   by blast
   546 
   547 lemma INT_anti_mono:
   548   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   549     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   550   -- {* The last inclusion is POSITIVE! *}
   551   by (blast dest: subsetD)
   552 
   553 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
   554   by blast
   555 
   556 
   557 subsection {* Union *}
   558 
   559 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   560   "Union S \<equiv> \<Squnion>S"
   561 
   562 notation (xsymbols)
   563   Union  ("\<Union>_" [90] 90)
   564 
   565 lemma Union_eq:
   566   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   567 proof (rule set_eqI)
   568   fix x
   569   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   570     by auto
   571   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   572     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   573 qed
   574 
   575 lemma Union_iff [simp, no_atp]:
   576   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   577   by (unfold Union_eq) blast
   578 
   579 lemma UnionI [intro]:
   580   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   581   -- {* The order of the premises presupposes that @{term C} is rigid;
   582     @{term A} may be flexible. *}
   583   by auto
   584 
   585 lemma UnionE [elim!]:
   586   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A\<in>X \<Longrightarrow> X\<in>C \<Longrightarrow> R) \<Longrightarrow> R"
   587   by auto
   588 
   589 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   590   by (iprover intro: subsetI UnionI)
   591 
   592 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   593   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   594 
   595 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   596   by blast
   597 
   598 lemma Union_empty [simp]: "Union({}) = {}"
   599   by blast
   600 
   601 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
   602   by blast
   603 
   604 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
   605   by blast
   606 
   607 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
   608   by blast
   609 
   610 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   611   by blast
   612 
   613 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
   614   by blast
   615 
   616 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
   617   by blast
   618 
   619 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
   620   by blast
   621 
   622 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   623   by blast
   624 
   625 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   626   by blast
   627 
   628 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
   629   by blast
   630 
   631 
   632 subsection {* Unions of families *}
   633 
   634 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   635   "UNION \<equiv> SUPR"
   636 
   637 syntax
   638   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   639   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   640 
   641 syntax (xsymbols)
   642   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   643   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   644 
   645 syntax (latex output)
   646   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   647   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   648 
   649 translations
   650   "UN x y. B"   == "UN x. UN y. B"
   651   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   652   "UN x. B"     == "UN x:CONST UNIV. B"
   653   "UN x:A. B"   == "CONST UNION A (%x. B)"
   654 
   655 text {*
   656   Note the difference between ordinary xsymbol syntax of indexed
   657   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   658   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   659   former does not make the index expression a subscript of the
   660   union/intersection symbol because this leads to problems with nested
   661   subscripts in Proof General.
   662 *}
   663 
   664 print_translation {*
   665   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   666 *} -- {* to avoid eta-contraction of body *}
   667 
   668 lemma UNION_eq_Union_image:
   669   "(\<Union>x\<in>A. B x) = \<Union>(B`A)"
   670   by (fact SUPR_def)
   671 
   672 lemma Union_def:
   673   "\<Union>S = (\<Union>x\<in>S. x)"
   674   by (simp add: UNION_eq_Union_image image_def)
   675 
   676 lemma UNION_def [no_atp]:
   677   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   678   by (auto simp add: UNION_eq_Union_image Union_eq)
   679   
   680 lemma Union_image_eq [simp]:
   681   "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
   682   by (rule sym) (fact UNION_eq_Union_image)
   683   
   684 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   685   by (unfold UNION_def) blast
   686 
   687 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   688   -- {* The order of the premises presupposes that @{term A} is rigid;
   689     @{term b} may be flexible. *}
   690   by auto
   691 
   692 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   693   by (unfold UNION_def) blast
   694 
   695 lemma UN_cong [cong]:
   696     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   697   by (simp add: UNION_def)
   698 
   699 lemma strong_UN_cong:
   700     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   701   by (simp add: UNION_def simp_implies_def)
   702 
   703 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
   704   by blast
   705 
   706 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   707   by (fact le_SUPI)
   708 
   709 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   710   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   711 
   712 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   713   by blast
   714 
   715 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   716   by blast
   717 
   718 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   719   by blast
   720 
   721 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   722   by blast
   723 
   724 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   725   by blast
   726 
   727 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   728   by auto
   729 
   730 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   731   by blast
   732 
   733 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   734   by blast
   735 
   736 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   737   by blast
   738 
   739 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   740   by (fact SUP_le_iff)
   741 
   742 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   743   by blast
   744 
   745 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   746   by auto
   747 
   748 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   749   by blast
   750 
   751 lemma UNION_empty_conv[simp]:
   752   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
   753   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
   754 by blast+
   755 
   756 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   757   by blast
   758 
   759 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   760   by blast
   761 
   762 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   763   by blast
   764 
   765 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   766   by (auto simp add: split_if_mem2)
   767 
   768 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
   769   by (auto intro: bool_contrapos)
   770 
   771 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   772   by blast
   773 
   774 lemma UN_mono:
   775   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   776     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   777   by (blast dest: subsetD)
   778 
   779 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
   780   by blast
   781 
   782 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
   783   by blast
   784 
   785 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
   786   -- {* NOT suitable for rewriting *}
   787   by blast
   788 
   789 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
   790 by blast
   791 
   792 
   793 subsection {* Distributive laws *}
   794 
   795 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   796   by blast
   797 
   798 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   799   by blast
   800 
   801 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
   802   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   803   -- {* Union of a family of unions *}
   804   by blast
   805 
   806 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   807   -- {* Equivalent version *}
   808   by blast
   809 
   810 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   811   by blast
   812 
   813 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
   814   by blast
   815 
   816 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   817   -- {* Equivalent version *}
   818   by blast
   819 
   820 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   821   -- {* Halmos, Naive Set Theory, page 35. *}
   822   by blast
   823 
   824 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   825   by blast
   826 
   827 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   828   by blast
   829 
   830 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   831   by blast
   832 
   833 
   834 subsection {* Complement *}
   835 
   836 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   837   by blast
   838 
   839 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   840   by blast
   841 
   842 
   843 subsection {* Miniscoping and maxiscoping *}
   844 
   845 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   846            and Intersections. *}
   847 
   848 lemma UN_simps [simp]:
   849   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
   850   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
   851   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
   852   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
   853   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
   854   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
   855   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
   856   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
   857   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   858   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   859   by auto
   860 
   861 lemma INT_simps [simp]:
   862   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
   863   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
   864   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
   865   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
   866   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
   867   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
   868   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
   869   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
   870   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
   871   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   872   by auto
   873 
   874 lemma ball_simps [simp,no_atp]:
   875   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
   876   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
   877   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
   878   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
   879   "!!P. (ALL x:{}. P x) = True"
   880   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
   881   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   882   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
   883   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   884   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   885   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
   886   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
   887   by auto
   888 
   889 lemma bex_simps [simp,no_atp]:
   890   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
   891   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
   892   "!!P. (EX x:{}. P x) = False"
   893   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
   894   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   895   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
   896   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   897   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   898   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
   899   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
   900   by auto
   901 
   902 lemma ball_conj_distrib:
   903   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
   904   by blast
   905 
   906 lemma bex_disj_distrib:
   907   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
   908   by blast
   909 
   910 
   911 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   912 
   913 lemma UN_extend_simps:
   914   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
   915   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
   916   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
   917   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
   918   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
   919   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
   920   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
   921   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
   922   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   923   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   924   by auto
   925 
   926 lemma INT_extend_simps:
   927   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
   928   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
   929   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
   930   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
   931   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
   932   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
   933   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
   934   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
   935   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   936   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   937   by auto
   938 
   939 
   940 no_notation
   941   less_eq  (infix "\<sqsubseteq>" 50) and
   942   less (infix "\<sqsubset>" 50) and
   943   bot ("\<bottom>") and
   944   top ("\<top>") and
   945   inf  (infixl "\<sqinter>" 70) and
   946   sup  (infixl "\<squnion>" 65) and
   947   Inf  ("\<Sqinter>_" [900] 900) and
   948   Sup  ("\<Squnion>_" [900] 900)
   949 
   950 no_syntax (xsymbols)
   951   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   952   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   953   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   954   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   955 
   956 lemmas mem_simps =
   957   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   958   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   959   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   960 
   961 end