src/HOL/Set.thy
author paulson
Mon Mar 17 17:37:20 2003 +0100 (2003-03-17)
changeset 13865 0a6bf71955b0
parent 13860 b681a3cb0beb
child 14098 54f130df1136
permissions -rw-r--r--
moved one proof, added another
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      == "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "UN x. B"     == "UN x:UNIV. B"
    81   "INT x y. B"  == "INT x. INT y. B"
    82   "INT x. B"    == "INTER UNIV (%x. B)"
    83   "INT x. B"    == "INT x:UNIV. B"
    84   "UN x:A. B"   == "UNION A (%x. B)"
    85   "INT x:A. B"  == "INTER A (%x. B)"
    86   "ALL x:A. P"  == "Ball A (%x. P)"
    87   "EX x:A. P"   == "Bex A (%x. P)"
    88 
    89 syntax (output)
    90   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    91   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    92   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    93   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    94 
    95 syntax (xsymbols)
    96   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    97   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    98   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    99   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
   100   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
   101   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   102   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   103   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   104   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   105   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   106   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   107   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   108   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   109   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   110   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   111   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   112   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   113   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   114 
   115 translations
   116   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   117   "op \<subset>" => "op <  :: _ set => _ set => bool"
   118 
   119 
   120 typed_print_translation {*
   121   let
   122     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   123           list_comb (Syntax.const "_setle", ts)
   124       | le_tr' _ _ _ = raise Match;
   125 
   126     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   127           list_comb (Syntax.const "_setless", ts)
   128       | less_tr' _ _ _ = raise Match;
   129   in [("op <=", le_tr'), ("op <", less_tr')] end
   130 *}
   131 
   132 text {*
   133   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   134   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   135   only translated if @{text "[0..n] subset bvs(e)"}.
   136 *}
   137 
   138 parse_translation {*
   139   let
   140     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   141 
   142     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   143       | nvars _ = 1;
   144 
   145     fun setcompr_tr [e, idts, b] =
   146       let
   147         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   148         val P = Syntax.const "op &" $ eq $ b;
   149         val exP = ex_tr [idts, P];
   150       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   151 
   152   in [("@SetCompr", setcompr_tr)] end;
   153 *}
   154 
   155 (* To avoid eta-contraction of body: *)
   156 print_translation {*
   157 let
   158   fun btr' syn [A,Abs abs] =
   159     let val (x,t) = atomic_abs_tr' abs
   160     in Syntax.const syn $ x $ A $ t end
   161 in
   162 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   163  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   164 end
   165 *}
   166 
   167 print_translation {*
   168 let
   169   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   170 
   171   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   172     let
   173       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   174         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   175             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   176             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   177         | check _ = false
   178 
   179         fun tr' (_ $ abs) =
   180           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   181           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   182     in if check (P, 0) then tr' P
   183        else let val (x,t) = atomic_abs_tr' abs
   184             in Syntax.const "@Coll" $ x $ t end
   185     end;
   186   in [("Collect", setcompr_tr')] end;
   187 *}
   188 
   189 
   190 subsection {* Rules and definitions *}
   191 
   192 text {* Isomorphisms between predicates and sets. *}
   193 
   194 axioms
   195   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   196   Collect_mem_eq [simp]: "{x. x:A} = A"
   197 
   198 defs
   199   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   200   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   201 
   202 defs (overloaded)
   203   subset_def:   "A <= B         == ALL x:A. x:B"
   204   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   205   Compl_def:    "- A            == {x. ~x:A}"
   206   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   207 
   208 defs
   209   Un_def:       "A Un B         == {x. x:A | x:B}"
   210   Int_def:      "A Int B        == {x. x:A & x:B}"
   211   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   212   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   213   Inter_def:    "Inter S        == (INT x:S. x)"
   214   Union_def:    "Union S        == (UN x:S. x)"
   215   Pow_def:      "Pow A          == {B. B <= A}"
   216   empty_def:    "{}             == {x. False}"
   217   UNIV_def:     "UNIV           == {x. True}"
   218   insert_def:   "insert a B     == {x. x=a} Un B"
   219   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   220 
   221 
   222 subsection {* Lemmas and proof tool setup *}
   223 
   224 subsubsection {* Relating predicates and sets *}
   225 
   226 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   227   by simp
   228 
   229 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   230   by simp
   231 
   232 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   233   by simp
   234 
   235 lemmas CollectE = CollectD [elim_format]
   236 
   237 
   238 subsubsection {* Bounded quantifiers *}
   239 
   240 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   241   by (simp add: Ball_def)
   242 
   243 lemmas strip = impI allI ballI
   244 
   245 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   246   by (simp add: Ball_def)
   247 
   248 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   249   by (unfold Ball_def) blast
   250 
   251 text {*
   252   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   253   @{prop "a:A"}; creates assumption @{prop "P a"}.
   254 *}
   255 
   256 ML {*
   257   local val ballE = thm "ballE"
   258   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   259 *}
   260 
   261 text {*
   262   Gives better instantiation for bound:
   263 *}
   264 
   265 ML_setup {*
   266   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   267 *}
   268 
   269 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   270   -- {* Normally the best argument order: @{prop "P x"} constrains the
   271     choice of @{prop "x:A"}. *}
   272   by (unfold Bex_def) blast
   273 
   274 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   275   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   276   by (unfold Bex_def) blast
   277 
   278 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   279   by (unfold Bex_def) blast
   280 
   281 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   282   by (unfold Bex_def) blast
   283 
   284 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   285   -- {* Trival rewrite rule. *}
   286   by (simp add: Ball_def)
   287 
   288 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   289   -- {* Dual form for existentials. *}
   290   by (simp add: Bex_def)
   291 
   292 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   293   by blast
   294 
   295 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   296   by blast
   297 
   298 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   299   by blast
   300 
   301 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   302   by blast
   303 
   304 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   305   by blast
   306 
   307 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   308   by blast
   309 
   310 ML_setup {*
   311   local
   312     val Ball_def = thm "Ball_def";
   313     val Bex_def = thm "Bex_def";
   314 
   315     val prove_bex_tac =
   316       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   317     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   318 
   319     val prove_ball_tac =
   320       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   321     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   322   in
   323     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   324       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   325     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   326       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   327   end;
   328 
   329   Addsimprocs [defBALL_regroup, defBEX_regroup];
   330 *}
   331 
   332 
   333 subsubsection {* Congruence rules *}
   334 
   335 lemma ball_cong [cong]:
   336   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   337     (ALL x:A. P x) = (ALL x:B. Q x)"
   338   by (simp add: Ball_def)
   339 
   340 lemma bex_cong [cong]:
   341   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   342     (EX x:A. P x) = (EX x:B. Q x)"
   343   by (simp add: Bex_def cong: conj_cong)
   344 
   345 
   346 subsubsection {* Subsets *}
   347 
   348 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   349   by (simp add: subset_def)
   350 
   351 text {*
   352   \medskip Map the type @{text "'a set => anything"} to just @{typ
   353   'a}; for overloading constants whose first argument has type @{typ
   354   "'a set"}.
   355 *}
   356 
   357 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   358   -- {* Rule in Modus Ponens style. *}
   359   by (unfold subset_def) blast
   360 
   361 declare subsetD [intro?] -- FIXME
   362 
   363 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   364   -- {* The same, with reversed premises for use with @{text erule} --
   365       cf @{text rev_mp}. *}
   366   by (rule subsetD)
   367 
   368 declare rev_subsetD [intro?] -- FIXME
   369 
   370 text {*
   371   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   372 *}
   373 
   374 ML {*
   375   local val rev_subsetD = thm "rev_subsetD"
   376   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   377 *}
   378 
   379 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   380   -- {* Classical elimination rule. *}
   381   by (unfold subset_def) blast
   382 
   383 text {*
   384   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   385   creates the assumption @{prop "c \<in> B"}.
   386 *}
   387 
   388 ML {*
   389   local val subsetCE = thm "subsetCE"
   390   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   391 *}
   392 
   393 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   394   by blast
   395 
   396 lemma subset_refl: "A \<subseteq> A"
   397   by fast
   398 
   399 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   400   by blast
   401 
   402 
   403 subsubsection {* Equality *}
   404 
   405 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   406   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   407    apply (rule Collect_mem_eq)
   408   apply (rule Collect_mem_eq)
   409   done
   410 
   411 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   412   -- {* Anti-symmetry of the subset relation. *}
   413   by (rules intro: set_ext subsetD)
   414 
   415 lemmas equalityI [intro!] = subset_antisym
   416 
   417 text {*
   418   \medskip Equality rules from ZF set theory -- are they appropriate
   419   here?
   420 *}
   421 
   422 lemma equalityD1: "A = B ==> A \<subseteq> B"
   423   by (simp add: subset_refl)
   424 
   425 lemma equalityD2: "A = B ==> B \<subseteq> A"
   426   by (simp add: subset_refl)
   427 
   428 text {*
   429   \medskip Be careful when adding this to the claset as @{text
   430   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   431   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   432 *}
   433 
   434 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   435   by (simp add: subset_refl)
   436 
   437 lemma equalityCE [elim]:
   438     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   439   by blast
   440 
   441 text {*
   442   \medskip Lemma for creating induction formulae -- for "pattern
   443   matching" on @{text p}.  To make the induction hypotheses usable,
   444   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   445   variables in @{text p}.
   446 *}
   447 
   448 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   449   by simp
   450 
   451 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   452   by simp
   453 
   454 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   455   by simp
   456 
   457 
   458 subsubsection {* The universal set -- UNIV *}
   459 
   460 lemma UNIV_I [simp]: "x : UNIV"
   461   by (simp add: UNIV_def)
   462 
   463 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   464 
   465 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   466   by simp
   467 
   468 lemma subset_UNIV: "A \<subseteq> UNIV"
   469   by (rule subsetI) (rule UNIV_I)
   470 
   471 text {*
   472   \medskip Eta-contracting these two rules (to remove @{text P})
   473   causes them to be ignored because of their interaction with
   474   congruence rules.
   475 *}
   476 
   477 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   478   by (simp add: Ball_def)
   479 
   480 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   481   by (simp add: Bex_def)
   482 
   483 
   484 subsubsection {* The empty set *}
   485 
   486 lemma empty_iff [simp]: "(c : {}) = False"
   487   by (simp add: empty_def)
   488 
   489 lemma emptyE [elim!]: "a : {} ==> P"
   490   by simp
   491 
   492 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   493     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   494   by blast
   495 
   496 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   497   by blast
   498 
   499 lemma equals0D: "A = {} ==> a \<notin> A"
   500     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   501   by blast
   502 
   503 lemma ball_empty [simp]: "Ball {} P = True"
   504   by (simp add: Ball_def)
   505 
   506 lemma bex_empty [simp]: "Bex {} P = False"
   507   by (simp add: Bex_def)
   508 
   509 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   510   by (blast elim: equalityE)
   511 
   512 
   513 subsubsection {* The Powerset operator -- Pow *}
   514 
   515 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   516   by (simp add: Pow_def)
   517 
   518 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   519   by (simp add: Pow_def)
   520 
   521 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   522   by (simp add: Pow_def)
   523 
   524 lemma Pow_bottom: "{} \<in> Pow B"
   525   by simp
   526 
   527 lemma Pow_top: "A \<in> Pow A"
   528   by (simp add: subset_refl)
   529 
   530 
   531 subsubsection {* Set complement *}
   532 
   533 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   534   by (unfold Compl_def) blast
   535 
   536 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   537   by (unfold Compl_def) blast
   538 
   539 text {*
   540   \medskip This form, with negated conclusion, works well with the
   541   Classical prover.  Negated assumptions behave like formulae on the
   542   right side of the notional turnstile ... *}
   543 
   544 lemma ComplD: "c : -A ==> c~:A"
   545   by (unfold Compl_def) blast
   546 
   547 lemmas ComplE [elim!] = ComplD [elim_format]
   548 
   549 
   550 subsubsection {* Binary union -- Un *}
   551 
   552 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   553   by (unfold Un_def) blast
   554 
   555 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   556   by simp
   557 
   558 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   559   by simp
   560 
   561 text {*
   562   \medskip Classical introduction rule: no commitment to @{prop A} vs
   563   @{prop B}.
   564 *}
   565 
   566 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   567   by auto
   568 
   569 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   570   by (unfold Un_def) blast
   571 
   572 
   573 subsubsection {* Binary intersection -- Int *}
   574 
   575 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   576   by (unfold Int_def) blast
   577 
   578 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   579   by simp
   580 
   581 lemma IntD1: "c : A Int B ==> c:A"
   582   by simp
   583 
   584 lemma IntD2: "c : A Int B ==> c:B"
   585   by simp
   586 
   587 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   588   by simp
   589 
   590 
   591 subsubsection {* Set difference *}
   592 
   593 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   594   by (unfold set_diff_def) blast
   595 
   596 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   597   by simp
   598 
   599 lemma DiffD1: "c : A - B ==> c : A"
   600   by simp
   601 
   602 lemma DiffD2: "c : A - B ==> c : B ==> P"
   603   by simp
   604 
   605 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   606   by simp
   607 
   608 
   609 subsubsection {* Augmenting a set -- insert *}
   610 
   611 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   612   by (unfold insert_def) blast
   613 
   614 lemma insertI1: "a : insert a B"
   615   by simp
   616 
   617 lemma insertI2: "a : B ==> a : insert b B"
   618   by simp
   619 
   620 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   621   by (unfold insert_def) blast
   622 
   623 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   624   -- {* Classical introduction rule. *}
   625   by auto
   626 
   627 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   628   by auto
   629 
   630 
   631 subsubsection {* Singletons, using insert *}
   632 
   633 lemma singletonI [intro!]: "a : {a}"
   634     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   635   by (rule insertI1)
   636 
   637 lemma singletonD: "b : {a} ==> b = a"
   638   by blast
   639 
   640 lemmas singletonE [elim!] = singletonD [elim_format]
   641 
   642 lemma singleton_iff: "(b : {a}) = (b = a)"
   643   by blast
   644 
   645 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   646   by blast
   647 
   648 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   649   by blast
   650 
   651 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   652   by blast
   653 
   654 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   655   by fast
   656 
   657 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   658   by blast
   659 
   660 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   661   by blast
   662 
   663 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   664   by blast
   665 
   666 
   667 subsubsection {* Unions of families *}
   668 
   669 text {*
   670   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   671 *}
   672 
   673 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   674   by (unfold UNION_def) blast
   675 
   676 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   677   -- {* The order of the premises presupposes that @{term A} is rigid;
   678     @{term b} may be flexible. *}
   679   by auto
   680 
   681 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   682   by (unfold UNION_def) blast
   683 
   684 lemma UN_cong [cong]:
   685     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   686   by (simp add: UNION_def)
   687 
   688 
   689 subsubsection {* Intersections of families *}
   690 
   691 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   692 
   693 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   694   by (unfold INTER_def) blast
   695 
   696 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   697   by (unfold INTER_def) blast
   698 
   699 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   700   by auto
   701 
   702 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   703   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   704   by (unfold INTER_def) blast
   705 
   706 lemma INT_cong [cong]:
   707     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   708   by (simp add: INTER_def)
   709 
   710 
   711 subsubsection {* Union *}
   712 
   713 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   714   by (unfold Union_def) blast
   715 
   716 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   717   -- {* The order of the premises presupposes that @{term C} is rigid;
   718     @{term A} may be flexible. *}
   719   by auto
   720 
   721 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   722   by (unfold Union_def) blast
   723 
   724 
   725 subsubsection {* Inter *}
   726 
   727 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   728   by (unfold Inter_def) blast
   729 
   730 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   731   by (simp add: Inter_def)
   732 
   733 text {*
   734   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   735   contains @{term A} as an element, but @{prop "A:X"} can hold when
   736   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   737 *}
   738 
   739 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   740   by auto
   741 
   742 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   743   -- {* ``Classical'' elimination rule -- does not require proving
   744     @{prop "X:C"}. *}
   745   by (unfold Inter_def) blast
   746 
   747 text {*
   748   \medskip Image of a set under a function.  Frequently @{term b} does
   749   not have the syntactic form of @{term "f x"}.
   750 *}
   751 
   752 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   753   by (unfold image_def) blast
   754 
   755 lemma imageI: "x : A ==> f x : f ` A"
   756   by (rule image_eqI) (rule refl)
   757 
   758 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   759   -- {* This version's more effective when we already have the
   760     required @{term x}. *}
   761   by (unfold image_def) blast
   762 
   763 lemma imageE [elim!]:
   764   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   765   -- {* The eta-expansion gives variable-name preservation. *}
   766   by (unfold image_def) blast
   767 
   768 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   769   by blast
   770 
   771 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   772   by blast
   773 
   774 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   775   -- {* This rewrite rule would confuse users if made default. *}
   776   by blast
   777 
   778 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   779   apply safe
   780    prefer 2 apply fast
   781   apply (rule_tac x = "{a. a : A & f a : B}" in exI)
   782   apply fast
   783   done
   784 
   785 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   786   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   787     @{text hypsubst}, but breaks too many existing proofs. *}
   788   by blast
   789 
   790 text {*
   791   \medskip Range of a function -- just a translation for image!
   792 *}
   793 
   794 lemma range_eqI: "b = f x ==> b \<in> range f"
   795   by simp
   796 
   797 lemma rangeI: "f x \<in> range f"
   798   by simp
   799 
   800 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   801   by blast
   802 
   803 
   804 subsubsection {* Set reasoning tools *}
   805 
   806 text {*
   807   Rewrite rules for boolean case-splitting: faster than @{text
   808   "split_if [split]"}.
   809 *}
   810 
   811 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   812   by (rule split_if)
   813 
   814 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   815   by (rule split_if)
   816 
   817 text {*
   818   Split ifs on either side of the membership relation.  Not for @{text
   819   "[simp]"} -- can cause goals to blow up!
   820 *}
   821 
   822 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   823   by (rule split_if)
   824 
   825 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   826   by (rule split_if)
   827 
   828 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   829 
   830 lemmas mem_simps =
   831   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   832   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   833   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   834 
   835 (*Would like to add these, but the existing code only searches for the
   836   outer-level constant, which in this case is just "op :"; we instead need
   837   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   838   apply, then the formula should be kept.
   839   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   840    ("op Int", [IntD1,IntD2]),
   841    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   842  *)
   843 
   844 ML_setup {*
   845   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   846   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   847 *}
   848 
   849 declare subset_UNIV [simp] subset_refl [simp]
   850 
   851 
   852 subsubsection {* The ``proper subset'' relation *}
   853 
   854 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   855   by (unfold psubset_def) blast
   856 
   857 lemma psubsetE [elim!]: 
   858     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   859   by (unfold psubset_def) blast
   860 
   861 lemma psubset_insert_iff:
   862   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   863   by (auto simp add: psubset_def subset_insert_iff)
   864 
   865 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   866   by (simp only: psubset_def)
   867 
   868 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   869   by (simp add: psubset_eq)
   870 
   871 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   872   by (auto simp add: psubset_eq)
   873 
   874 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   875   by (auto simp add: psubset_eq)
   876 
   877 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   878   by (unfold psubset_def) blast
   879 
   880 lemma atomize_ball:
   881     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   882   by (simp only: Ball_def atomize_all atomize_imp)
   883 
   884 declare atomize_ball [symmetric, rulify]
   885 
   886 
   887 subsection {* Further set-theory lemmas *}
   888 
   889 subsubsection {* Derived rules involving subsets. *}
   890 
   891 text {* @{text insert}. *}
   892 
   893 lemma subset_insertI: "B \<subseteq> insert a B"
   894   apply (rule subsetI)
   895   apply (erule insertI2)
   896   done
   897 
   898 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   899   by blast
   900 
   901 
   902 text {* \medskip Big Union -- least upper bound of a set. *}
   903 
   904 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   905   by (rules intro: subsetI UnionI)
   906 
   907 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   908   by (rules intro: subsetI elim: UnionE dest: subsetD)
   909 
   910 
   911 text {* \medskip General union. *}
   912 
   913 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   914   by blast
   915 
   916 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   917   by (rules intro: subsetI elim: UN_E dest: subsetD)
   918 
   919 
   920 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   921 
   922 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   923   by blast
   924 
   925 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   926   by (rules intro: InterI subsetI dest: subsetD)
   927 
   928 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   929   by blast
   930 
   931 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   932   by (rules intro: INT_I subsetI dest: subsetD)
   933 
   934 
   935 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   936 
   937 lemma Un_upper1: "A \<subseteq> A \<union> B"
   938   by blast
   939 
   940 lemma Un_upper2: "B \<subseteq> A \<union> B"
   941   by blast
   942 
   943 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   944   by blast
   945 
   946 
   947 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   948 
   949 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   950   by blast
   951 
   952 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   953   by blast
   954 
   955 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   956   by blast
   957 
   958 
   959 text {* \medskip Set difference. *}
   960 
   961 lemma Diff_subset: "A - B \<subseteq> A"
   962   by blast
   963 
   964 
   965 text {* \medskip Monotonicity. *}
   966 
   967 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   968   apply (rule Un_least)
   969    apply (rule Un_upper1 [THEN mono])
   970   apply (rule Un_upper2 [THEN mono])
   971   done
   972 
   973 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   974   apply (rule Int_greatest)
   975    apply (rule Int_lower1 [THEN mono])
   976   apply (rule Int_lower2 [THEN mono])
   977   done
   978 
   979 
   980 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
   981 
   982 text {* @{text "{}"}. *}
   983 
   984 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
   985   -- {* supersedes @{text "Collect_False_empty"} *}
   986   by auto
   987 
   988 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
   989   by blast
   990 
   991 lemma not_psubset_empty [iff]: "\<not> (A < {})"
   992   by (unfold psubset_def) blast
   993 
   994 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
   995   by auto
   996 
   997 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
   998   by blast
   999 
  1000 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1001   by blast
  1002 
  1003 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1004   by blast
  1005 
  1006 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1007   by blast
  1008 
  1009 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1010   by blast
  1011 
  1012 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1013   by blast
  1014 
  1015 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1016   by blast
  1017 
  1018 
  1019 text {* \medskip @{text insert}. *}
  1020 
  1021 lemma insert_is_Un: "insert a A = {a} Un A"
  1022   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1023   by blast
  1024 
  1025 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1026   by blast
  1027 
  1028 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1029 
  1030 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1031   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1032   -- {* with \emph{quadratic} running time *}
  1033   by blast
  1034 
  1035 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1036   by blast
  1037 
  1038 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1039   by blast
  1040 
  1041 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1042   by blast
  1043 
  1044 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1045   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1046   apply (rule_tac x = "A - {a}" in exI)
  1047   apply blast
  1048   done
  1049 
  1050 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1051   by auto
  1052 
  1053 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1054   by blast
  1055 
  1056 lemma insert_disjoint[simp]:
  1057  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1058 by blast
  1059 
  1060 lemma disjoint_insert[simp]:
  1061  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1062 by blast
  1063 
  1064 text {* \medskip @{text image}. *}
  1065 
  1066 lemma image_empty [simp]: "f`{} = {}"
  1067   by blast
  1068 
  1069 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1070   by blast
  1071 
  1072 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1073   by blast
  1074 
  1075 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1076   by blast
  1077 
  1078 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1079   by blast
  1080 
  1081 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1082   by blast
  1083 
  1084 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1085   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1086   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1087   -- {* equational properties than does the RHS. *}
  1088   by blast
  1089 
  1090 lemma if_image_distrib [simp]:
  1091   "(\<lambda>x. if P x then f x else g x) ` S
  1092     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1093   by (auto simp add: image_def)
  1094 
  1095 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1096   by (simp add: image_def)
  1097 
  1098 
  1099 text {* \medskip @{text range}. *}
  1100 
  1101 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1102   by auto
  1103 
  1104 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1105   apply (subst image_image)
  1106   apply simp
  1107   done
  1108 
  1109 
  1110 text {* \medskip @{text Int} *}
  1111 
  1112 lemma Int_absorb [simp]: "A \<inter> A = A"
  1113   by blast
  1114 
  1115 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1116   by blast
  1117 
  1118 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1119   by blast
  1120 
  1121 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1122   by blast
  1123 
  1124 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1125   by blast
  1126 
  1127 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1128   -- {* Intersection is an AC-operator *}
  1129 
  1130 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1131   by blast
  1132 
  1133 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1134   by blast
  1135 
  1136 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1137   by blast
  1138 
  1139 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1140   by blast
  1141 
  1142 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1143   by blast
  1144 
  1145 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1146   by blast
  1147 
  1148 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1149   by blast
  1150 
  1151 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1152   by blast
  1153 
  1154 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1155   by blast
  1156 
  1157 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1158   by blast
  1159 
  1160 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1161   by blast
  1162 
  1163 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1164   by blast
  1165 
  1166 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1167   by blast
  1168 
  1169 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1170   by blast
  1171 
  1172 
  1173 text {* \medskip @{text Un}. *}
  1174 
  1175 lemma Un_absorb [simp]: "A \<union> A = A"
  1176   by blast
  1177 
  1178 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1179   by blast
  1180 
  1181 lemma Un_commute: "A \<union> B = B \<union> A"
  1182   by blast
  1183 
  1184 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1185   by blast
  1186 
  1187 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1188   by blast
  1189 
  1190 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1191   -- {* Union is an AC-operator *}
  1192 
  1193 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1194   by blast
  1195 
  1196 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1197   by blast
  1198 
  1199 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1200   by blast
  1201 
  1202 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1203   by blast
  1204 
  1205 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1206   by blast
  1207 
  1208 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1209   by blast
  1210 
  1211 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1212   by blast
  1213 
  1214 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1215   by blast
  1216 
  1217 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1218   by blast
  1219 
  1220 lemma Int_insert_left:
  1221     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1222   by auto
  1223 
  1224 lemma Int_insert_right:
  1225     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1226   by auto
  1227 
  1228 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1229   by blast
  1230 
  1231 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1232   by blast
  1233 
  1234 lemma Un_Int_crazy:
  1235     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1236   by blast
  1237 
  1238 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1239   by blast
  1240 
  1241 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1242   by blast
  1243 
  1244 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1245   by blast
  1246 
  1247 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1248   by blast
  1249 
  1250 
  1251 text {* \medskip Set complement *}
  1252 
  1253 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1254   by blast
  1255 
  1256 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1257   by blast
  1258 
  1259 lemma Compl_partition: "A \<union> -A = UNIV"
  1260   by blast
  1261 
  1262 lemma Compl_partition2: "-A \<union> A = UNIV"
  1263   by blast
  1264 
  1265 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1266   by blast
  1267 
  1268 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1269   by blast
  1270 
  1271 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1272   by blast
  1273 
  1274 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1275   by blast
  1276 
  1277 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1278   by blast
  1279 
  1280 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1281   by blast
  1282 
  1283 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1284   -- {* Halmos, Naive Set Theory, page 16. *}
  1285   by blast
  1286 
  1287 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1288   by blast
  1289 
  1290 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1291   by blast
  1292 
  1293 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1294   by blast
  1295 
  1296 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1297   by blast
  1298 
  1299 
  1300 text {* \medskip @{text Union}. *}
  1301 
  1302 lemma Union_empty [simp]: "Union({}) = {}"
  1303   by blast
  1304 
  1305 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1306   by blast
  1307 
  1308 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1309   by blast
  1310 
  1311 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1312   by blast
  1313 
  1314 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1315   by blast
  1316 
  1317 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1318   by blast
  1319 
  1320 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1321   by blast
  1322 
  1323 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1324   by blast
  1325 
  1326 
  1327 text {* \medskip @{text Inter}. *}
  1328 
  1329 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1330   by blast
  1331 
  1332 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1333   by blast
  1334 
  1335 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1336   by blast
  1337 
  1338 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1339   by blast
  1340 
  1341 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1342   by blast
  1343 
  1344 lemma Inter_UNIV_conv [iff]:
  1345   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1346   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1347   by(blast)+
  1348 
  1349 
  1350 text {*
  1351   \medskip @{text UN} and @{text INT}.
  1352 
  1353   Basic identities: *}
  1354 
  1355 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1356   by blast
  1357 
  1358 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1359   by blast
  1360 
  1361 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1362   by blast
  1363 
  1364 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1365   by blast
  1366 
  1367 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1368   by blast
  1369 
  1370 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1371   by blast
  1372 
  1373 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1374   by blast
  1375 
  1376 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1377   by blast
  1378 
  1379 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1380   by blast
  1381 
  1382 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1383   by blast
  1384 
  1385 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1386   by blast
  1387 
  1388 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1389   by blast
  1390 
  1391 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1392   by blast
  1393 
  1394 lemma INT_insert_distrib:
  1395     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1396   by blast
  1397 
  1398 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1399   by blast
  1400 
  1401 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1402   by blast
  1403 
  1404 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1405   by blast
  1406 
  1407 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1408   by auto
  1409 
  1410 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1411   by auto
  1412 
  1413 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1414   by blast
  1415 
  1416 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1417   -- {* Look: it has an \emph{existential} quantifier *}
  1418   by blast
  1419 
  1420 lemma UNION_empty_conv[iff]:
  1421   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1422   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1423 by blast+
  1424 
  1425 lemma INTER_UNIV_conv[iff]:
  1426  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1427  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1428 by blast+
  1429 
  1430 
  1431 text {* \medskip Distributive laws: *}
  1432 
  1433 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1434   by blast
  1435 
  1436 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1437   by blast
  1438 
  1439 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1440   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1441   -- {* Union of a family of unions *}
  1442   by blast
  1443 
  1444 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1445   -- {* Equivalent version *}
  1446   by blast
  1447 
  1448 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1449   by blast
  1450 
  1451 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1452   by blast
  1453 
  1454 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1455   -- {* Equivalent version *}
  1456   by blast
  1457 
  1458 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1459   -- {* Halmos, Naive Set Theory, page 35. *}
  1460   by blast
  1461 
  1462 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1463   by blast
  1464 
  1465 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1466   by blast
  1467 
  1468 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1469   by blast
  1470 
  1471 
  1472 text {* \medskip Bounded quantifiers.
  1473 
  1474   The following are not added to the default simpset because
  1475   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1476 
  1477 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1478   by blast
  1479 
  1480 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1481   by blast
  1482 
  1483 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1484   by blast
  1485 
  1486 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1487   by blast
  1488 
  1489 
  1490 text {* \medskip Set difference. *}
  1491 
  1492 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1493   by blast
  1494 
  1495 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1496   by blast
  1497 
  1498 lemma Diff_cancel [simp]: "A - A = {}"
  1499   by blast
  1500 
  1501 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1502   by (blast elim: equalityE)
  1503 
  1504 lemma empty_Diff [simp]: "{} - A = {}"
  1505   by blast
  1506 
  1507 lemma Diff_empty [simp]: "A - {} = A"
  1508   by blast
  1509 
  1510 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1511   by blast
  1512 
  1513 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1514   by blast
  1515 
  1516 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1517   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1518   by blast
  1519 
  1520 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1521   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1522   by blast
  1523 
  1524 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1525   by auto
  1526 
  1527 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1528   by blast
  1529 
  1530 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1531   by blast
  1532 
  1533 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1534   by auto
  1535 
  1536 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1537   by blast
  1538 
  1539 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1540   by blast
  1541 
  1542 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1543   by blast
  1544 
  1545 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1546   by blast
  1547 
  1548 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1549   by blast
  1550 
  1551 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1552   by blast
  1553 
  1554 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1555   by blast
  1556 
  1557 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1558   by blast
  1559 
  1560 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1561   by blast
  1562 
  1563 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1564   by blast
  1565 
  1566 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1567   by blast
  1568 
  1569 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1570   by auto
  1571 
  1572 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1573   by blast
  1574 
  1575 
  1576 text {* \medskip Quantification over type @{typ bool}. *}
  1577 
  1578 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1579   apply auto
  1580   apply (tactic {* case_tac "b" 1 *})
  1581    apply auto
  1582   done
  1583 
  1584 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1585   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1586 
  1587 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1588   apply auto
  1589   apply (tactic {* case_tac "b" 1 *})
  1590    apply auto
  1591   done
  1592 
  1593 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1594   by (auto simp add: split_if_mem2)
  1595 
  1596 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1597   apply auto
  1598   apply (tactic {* case_tac "b" 1 *})
  1599    apply auto
  1600   done
  1601 
  1602 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1603   apply auto
  1604   apply (tactic {* case_tac "b" 1 *})
  1605   apply auto
  1606   done
  1607 
  1608 
  1609 text {* \medskip @{text Pow} *}
  1610 
  1611 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1612   by (auto simp add: Pow_def)
  1613 
  1614 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1615   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1616 
  1617 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1618   by (blast intro: exI [where ?x = "- u", standard])
  1619 
  1620 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1621   by blast
  1622 
  1623 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1624   by blast
  1625 
  1626 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1627   by blast
  1628 
  1629 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1630   by blast
  1631 
  1632 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1633   by blast
  1634 
  1635 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1636   by blast
  1637 
  1638 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1639   by blast
  1640 
  1641 
  1642 text {* \medskip Miscellany. *}
  1643 
  1644 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1645   by blast
  1646 
  1647 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1648   by blast
  1649 
  1650 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1651   by (unfold psubset_def) blast
  1652 
  1653 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1654   by blast
  1655 
  1656 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1657   by blast
  1658 
  1659 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1660   by rules
  1661 
  1662 
  1663 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1664            and Intersections. *}
  1665 
  1666 lemma UN_simps [simp]:
  1667   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1668   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1669   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1670   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1671   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1672   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1673   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1674   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1675   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1676   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1677   by auto
  1678 
  1679 lemma INT_simps [simp]:
  1680   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1681   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1682   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1683   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1684   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1685   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1686   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1687   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1688   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1689   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1690   by auto
  1691 
  1692 lemma ball_simps [simp]:
  1693   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1694   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1695   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1696   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1697   "!!P. (ALL x:{}. P x) = True"
  1698   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1699   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1700   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1701   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1702   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1703   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1704   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1705   by auto
  1706 
  1707 lemma bex_simps [simp]:
  1708   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1709   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1710   "!!P. (EX x:{}. P x) = False"
  1711   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1712   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1713   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1714   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1715   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1716   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1717   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1718   by auto
  1719 
  1720 lemma ball_conj_distrib:
  1721   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1722   by blast
  1723 
  1724 lemma bex_disj_distrib:
  1725   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1726   by blast
  1727 
  1728 
  1729 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1730 
  1731 lemma UN_extend_simps:
  1732   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1733   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1734   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1735   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1736   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1737   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1738   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1739   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1740   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1741   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1742   by auto
  1743 
  1744 lemma INT_extend_simps:
  1745   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1746   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1747   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1748   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1749   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1750   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1751   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1752   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1753   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1754   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1755   by auto
  1756 
  1757 
  1758 subsubsection {* Monotonicity of various operations *}
  1759 
  1760 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1761   by blast
  1762 
  1763 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1764   by blast
  1765 
  1766 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1767   by blast
  1768 
  1769 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1770   by blast
  1771 
  1772 lemma UN_mono:
  1773   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1774     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1775   by (blast dest: subsetD)
  1776 
  1777 lemma INT_anti_mono:
  1778   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1779     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1780   -- {* The last inclusion is POSITIVE! *}
  1781   by (blast dest: subsetD)
  1782 
  1783 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1784   by blast
  1785 
  1786 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1787   by blast
  1788 
  1789 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1790   by blast
  1791 
  1792 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1793   by blast
  1794 
  1795 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1796   by blast
  1797 
  1798 text {* \medskip Monotonicity of implications. *}
  1799 
  1800 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1801   apply (rule impI)
  1802   apply (erule subsetD)
  1803   apply assumption
  1804   done
  1805 
  1806 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1807   by rules
  1808 
  1809 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1810   by rules
  1811 
  1812 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1813   by rules
  1814 
  1815 lemma imp_refl: "P --> P" ..
  1816 
  1817 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1818   by rules
  1819 
  1820 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1821   by rules
  1822 
  1823 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1824   by blast
  1825 
  1826 lemma Int_Collect_mono:
  1827     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1828   by blast
  1829 
  1830 lemmas basic_monos =
  1831   subset_refl imp_refl disj_mono conj_mono
  1832   ex_mono Collect_mono in_mono
  1833 
  1834 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1835   by rules
  1836 
  1837 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1838   by rules
  1839 
  1840 lemma Least_mono:
  1841   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1842     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1843     -- {* Courtesy of Stephan Merz *}
  1844   apply clarify
  1845   apply (erule_tac P = "%x. x : S" in LeastI2)
  1846    apply fast
  1847   apply (rule LeastI2)
  1848   apply (auto elim: monoD intro!: order_antisym)
  1849   done
  1850 
  1851 
  1852 subsection {* Inverse image of a function *}
  1853 
  1854 constdefs
  1855   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1856   "f -` B == {x. f x : B}"
  1857 
  1858 
  1859 subsubsection {* Basic rules *}
  1860 
  1861 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1862   by (unfold vimage_def) blast
  1863 
  1864 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1865   by simp
  1866 
  1867 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1868   by (unfold vimage_def) blast
  1869 
  1870 lemma vimageI2: "f a : A ==> a : f -` A"
  1871   by (unfold vimage_def) fast
  1872 
  1873 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1874   by (unfold vimage_def) blast
  1875 
  1876 lemma vimageD: "a : f -` A ==> f a : A"
  1877   by (unfold vimage_def) fast
  1878 
  1879 
  1880 subsubsection {* Equations *}
  1881 
  1882 lemma vimage_empty [simp]: "f -` {} = {}"
  1883   by blast
  1884 
  1885 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1886   by blast
  1887 
  1888 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1889   by blast
  1890 
  1891 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1892   by fast
  1893 
  1894 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1895   by blast
  1896 
  1897 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1898   by blast
  1899 
  1900 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1901   by blast
  1902 
  1903 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1904   by blast
  1905 
  1906 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1907   by blast
  1908 
  1909 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1910   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1911   by blast
  1912 
  1913 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1914   by blast
  1915 
  1916 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1917   by blast
  1918 
  1919 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1920   -- {* NOT suitable for rewriting *}
  1921   by blast
  1922 
  1923 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1924   -- {* monotonicity *}
  1925   by blast
  1926 
  1927 
  1928 subsection {* Transitivity rules for calculational reasoning *}
  1929 
  1930 lemma forw_subst: "a = b ==> P b ==> P a"
  1931   by (rule ssubst)
  1932 
  1933 lemma back_subst: "P a ==> a = b ==> P b"
  1934   by (rule subst)
  1935 
  1936 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1937   by (rule subsetD)
  1938 
  1939 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1940   by (rule subsetD)
  1941 
  1942 lemma order_neq_le_trans: "a ~= b ==> (a::'a::order) <= b ==> a < b"
  1943   by (simp add: order_less_le)
  1944 
  1945 lemma order_le_neq_trans: "(a::'a::order) <= b ==> a ~= b ==> a < b"
  1946   by (simp add: order_less_le)
  1947 
  1948 lemma order_less_asym': "(a::'a::order) < b ==> b < a ==> P"
  1949   by (rule order_less_asym)
  1950 
  1951 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1952   by (rule subst)
  1953 
  1954 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1955   by (rule ssubst)
  1956 
  1957 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1958   by (rule subst)
  1959 
  1960 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1961   by (rule ssubst)
  1962 
  1963 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1964   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1965 proof -
  1966   assume r: "!!x y. x < y ==> f x < f y"
  1967   assume "a < b" hence "f a < f b" by (rule r)
  1968   also assume "f b < c"
  1969   finally (order_less_trans) show ?thesis .
  1970 qed
  1971 
  1972 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1973   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1974 proof -
  1975   assume r: "!!x y. x < y ==> f x < f y"
  1976   assume "a < f b"
  1977   also assume "b < c" hence "f b < f c" by (rule r)
  1978   finally (order_less_trans) show ?thesis .
  1979 qed
  1980 
  1981 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1982   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1983 proof -
  1984   assume r: "!!x y. x <= y ==> f x <= f y"
  1985   assume "a <= b" hence "f a <= f b" by (rule r)
  1986   also assume "f b < c"
  1987   finally (order_le_less_trans) show ?thesis .
  1988 qed
  1989 
  1990 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  1991   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1992 proof -
  1993   assume r: "!!x y. x < y ==> f x < f y"
  1994   assume "a <= f b"
  1995   also assume "b < c" hence "f b < f c" by (rule r)
  1996   finally (order_le_less_trans) show ?thesis .
  1997 qed
  1998 
  1999 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  2000   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2001 proof -
  2002   assume r: "!!x y. x < y ==> f x < f y"
  2003   assume "a < b" hence "f a < f b" by (rule r)
  2004   also assume "f b <= c"
  2005   finally (order_less_le_trans) show ?thesis .
  2006 qed
  2007 
  2008 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  2009   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  2010 proof -
  2011   assume r: "!!x y. x <= y ==> f x <= f y"
  2012   assume "a < f b"
  2013   also assume "b <= c" hence "f b <= f c" by (rule r)
  2014   finally (order_less_le_trans) show ?thesis .
  2015 qed
  2016 
  2017 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  2018   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2019 proof -
  2020   assume r: "!!x y. x <= y ==> f x <= f y"
  2021   assume "a <= f b"
  2022   also assume "b <= c" hence "f b <= f c" by (rule r)
  2023   finally (order_trans) show ?thesis .
  2024 qed
  2025 
  2026 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  2027   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2028 proof -
  2029   assume r: "!!x y. x <= y ==> f x <= f y"
  2030   assume "a <= b" hence "f a <= f b" by (rule r)
  2031   also assume "f b <= c"
  2032   finally (order_trans) show ?thesis .
  2033 qed
  2034 
  2035 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  2036   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2037 proof -
  2038   assume r: "!!x y. x <= y ==> f x <= f y"
  2039   assume "a <= b" hence "f a <= f b" by (rule r)
  2040   also assume "f b = c"
  2041   finally (ord_le_eq_trans) show ?thesis .
  2042 qed
  2043 
  2044 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2045   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2046 proof -
  2047   assume r: "!!x y. x <= y ==> f x <= f y"
  2048   assume "a = f b"
  2049   also assume "b <= c" hence "f b <= f c" by (rule r)
  2050   finally (ord_eq_le_trans) show ?thesis .
  2051 qed
  2052 
  2053 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2054   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2055 proof -
  2056   assume r: "!!x y. x < y ==> f x < f y"
  2057   assume "a < b" hence "f a < f b" by (rule r)
  2058   also assume "f b = c"
  2059   finally (ord_less_eq_trans) show ?thesis .
  2060 qed
  2061 
  2062 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2063   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2064 proof -
  2065   assume r: "!!x y. x < y ==> f x < f y"
  2066   assume "a = f b"
  2067   also assume "b < c" hence "f b < f c" by (rule r)
  2068   finally (ord_eq_less_trans) show ?thesis .
  2069 qed
  2070 
  2071 text {*
  2072   Note that this list of rules is in reverse order of priorities.
  2073 *}
  2074 
  2075 lemmas basic_trans_rules [trans] =
  2076   order_less_subst2
  2077   order_less_subst1
  2078   order_le_less_subst2
  2079   order_le_less_subst1
  2080   order_less_le_subst2
  2081   order_less_le_subst1
  2082   order_subst2
  2083   order_subst1
  2084   ord_le_eq_subst
  2085   ord_eq_le_subst
  2086   ord_less_eq_subst
  2087   ord_eq_less_subst
  2088   forw_subst
  2089   back_subst
  2090   rev_mp
  2091   mp
  2092   set_rev_mp
  2093   set_mp
  2094   order_neq_le_trans
  2095   order_le_neq_trans
  2096   order_less_trans
  2097   order_less_asym'
  2098   order_le_less_trans
  2099   order_less_le_trans
  2100   order_trans
  2101   order_antisym
  2102   ord_le_eq_trans
  2103   ord_eq_le_trans
  2104   ord_less_eq_trans
  2105   ord_eq_less_trans
  2106   trans
  2107 
  2108 end