src/HOL/Limits.thy
author haftmann
Fri Sep 13 07:59:50 2013 +0200 (2013-09-13)
changeset 53602 0ae3db699a3e
parent 53381 355a4cac5440
child 54230 b1d955791529
permissions -rw-r--r--
tuned proofs
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 subsection {* Filter going to infinity norm *}
    16 
    17 definition at_infinity :: "'a::real_normed_vector filter" where
    18   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    19 
    20 lemma eventually_at_infinity:
    21   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    22 unfolding at_infinity_def
    23 proof (rule eventually_Abs_filter, rule is_filter.intro)
    24   fix P Q :: "'a \<Rightarrow> bool"
    25   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    26   then obtain r s where
    27     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    28   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    29   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    30 qed auto
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    34   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    35 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    36   fix P :: "real \<Rightarrow> bool"
    37   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    38   then obtain r where "\<forall>x. r \<le> norm x \<longrightarrow> P x" ..
    39   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    40   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    41 next
    42   fix P :: "real \<Rightarrow> bool"
    43   assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    44   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    45   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    46     by (intro exI[of _ "max p (-q)"]) (auto simp: abs_real_def)
    47 qed
    48 
    49 lemma at_top_le_at_infinity:
    50   "at_top \<le> (at_infinity :: real filter)"
    51   unfolding at_infinity_eq_at_top_bot by simp
    52 
    53 lemma at_bot_le_at_infinity:
    54   "at_bot \<le> (at_infinity :: real filter)"
    55   unfolding at_infinity_eq_at_top_bot by simp
    56 
    57 subsubsection {* Boundedness *}
    58 
    59 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    60   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    61 
    62 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    63   "Bseq X \<equiv> Bfun X sequentially"
    64 
    65 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    66 
    67 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    68   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    69 
    70 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    71   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    72 
    73 lemma Bfun_def:
    74   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    75   unfolding Bfun_metric_def norm_conv_dist
    76 proof safe
    77   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    78   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    79     by (intro always_eventually) (metis dist_commute dist_triangle)
    80   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    81     by eventually_elim auto
    82   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    83     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    84 qed auto
    85 
    86 lemma BfunI:
    87   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    88 unfolding Bfun_def
    89 proof (intro exI conjI allI)
    90   show "0 < max K 1" by simp
    91 next
    92   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    93     using K by (rule eventually_elim1, simp)
    94 qed
    95 
    96 lemma BfunE:
    97   assumes "Bfun f F"
    98   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    99 using assms unfolding Bfun_def by fast
   100 
   101 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   102   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   103   apply (erule_tac x=1 in allE)
   104   apply simp
   105   apply safe
   106   apply (rule_tac x="X M" in exI)
   107   apply (rule_tac x=1 in exI)
   108   apply (erule_tac x=M in allE)
   109   apply simp
   110   apply (rule_tac x=M in exI)
   111   apply (auto simp: dist_commute)
   112   done
   113 
   114 
   115 subsubsection {* Bounded Sequences *}
   116 
   117 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   118   by (intro BfunI) (auto simp: eventually_sequentially)
   119 
   120 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   121   by (intro BfunI) (auto simp: eventually_sequentially)
   122 
   123 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   124   unfolding Bfun_def eventually_sequentially
   125 proof safe
   126   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   127   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   128     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] min_max.less_supI2)
   129        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   130 qed auto
   131 
   132 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   133 unfolding Bseq_def by auto
   134 
   135 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   136 by (simp add: Bseq_def)
   137 
   138 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   139 by (auto simp add: Bseq_def)
   140 
   141 lemma lemma_NBseq_def:
   142   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   143 proof safe
   144   fix K :: real
   145   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   146   then have "K \<le> real (Suc n)" by auto
   147   moreover assume "\<forall>m. norm (X m) \<le> K"
   148   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   149     by (blast intro: order_trans)
   150   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   151 qed (force simp add: real_of_nat_Suc)
   152 
   153 text{* alternative definition for Bseq *}
   154 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   155 apply (simp add: Bseq_def)
   156 apply (simp (no_asm) add: lemma_NBseq_def)
   157 done
   158 
   159 lemma lemma_NBseq_def2:
   160      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   161 apply (subst lemma_NBseq_def, auto)
   162 apply (rule_tac x = "Suc N" in exI)
   163 apply (rule_tac [2] x = N in exI)
   164 apply (auto simp add: real_of_nat_Suc)
   165  prefer 2 apply (blast intro: order_less_imp_le)
   166 apply (drule_tac x = n in spec, simp)
   167 done
   168 
   169 (* yet another definition for Bseq *)
   170 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   171 by (simp add: Bseq_def lemma_NBseq_def2)
   172 
   173 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   174 
   175 text{*alternative formulation for boundedness*}
   176 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   177 apply (unfold Bseq_def, safe)
   178 apply (rule_tac [2] x = "k + norm x" in exI)
   179 apply (rule_tac x = K in exI, simp)
   180 apply (rule exI [where x = 0], auto)
   181 apply (erule order_less_le_trans, simp)
   182 apply (drule_tac x=n in spec, fold diff_minus)
   183 apply (drule order_trans [OF norm_triangle_ineq2])
   184 apply simp
   185 done
   186 
   187 text{*alternative formulation for boundedness*}
   188 lemma Bseq_iff3:
   189   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   190 proof
   191   assume ?P
   192   then obtain K
   193     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   194   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   195   moreover from ** have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   196     by (auto intro: order_trans norm_triangle_ineq)
   197   ultimately show ?Q by blast
   198 next
   199   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   200 qed
   201 
   202 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   203 apply (simp add: Bseq_def)
   204 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   205 apply (drule_tac x = n in spec, arith)
   206 done
   207 
   208 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   209 
   210 lemma Bseq_isUb:
   211   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   212 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   213 
   214 text{* Use completeness of reals (supremum property)
   215    to show that any bounded sequence has a least upper bound*}
   216 
   217 lemma Bseq_isLub:
   218   "!!(X::nat=>real). Bseq X ==>
   219    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   220 by (blast intro: reals_complete Bseq_isUb)
   221 
   222 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   223   by (simp add: Bseq_def)
   224 
   225 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   226   apply (simp add: subset_eq)
   227   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   228   apply (erule_tac x=n in allE)
   229   apply auto
   230   done
   231 
   232 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   233   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   234 
   235 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   236   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   237 
   238 subsection {* Bounded Monotonic Sequences *}
   239 
   240 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   241 
   242 (* TODO: delete *)
   243 (* FIXME: one use in NSA/HSEQ.thy *)
   244 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   245   apply (rule_tac x="X m" in exI)
   246   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   247   unfolding eventually_sequentially
   248   apply blast
   249   done
   250 
   251 subsection {* Convergence to Zero *}
   252 
   253 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   254   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   255 
   256 lemma ZfunI:
   257   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   258   unfolding Zfun_def by simp
   259 
   260 lemma ZfunD:
   261   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   262   unfolding Zfun_def by simp
   263 
   264 lemma Zfun_ssubst:
   265   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   266   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   267 
   268 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   269   unfolding Zfun_def by simp
   270 
   271 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   272   unfolding Zfun_def by simp
   273 
   274 lemma Zfun_imp_Zfun:
   275   assumes f: "Zfun f F"
   276   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   277   shows "Zfun (\<lambda>x. g x) F"
   278 proof (cases)
   279   assume K: "0 < K"
   280   show ?thesis
   281   proof (rule ZfunI)
   282     fix r::real assume "0 < r"
   283     hence "0 < r / K"
   284       using K by (rule divide_pos_pos)
   285     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   286       using ZfunD [OF f] by fast
   287     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   288     proof eventually_elim
   289       case (elim x)
   290       hence "norm (f x) * K < r"
   291         by (simp add: pos_less_divide_eq K)
   292       thus ?case
   293         by (simp add: order_le_less_trans [OF elim(1)])
   294     qed
   295   qed
   296 next
   297   assume "\<not> 0 < K"
   298   hence K: "K \<le> 0" by (simp only: not_less)
   299   show ?thesis
   300   proof (rule ZfunI)
   301     fix r :: real
   302     assume "0 < r"
   303     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   304     proof eventually_elim
   305       case (elim x)
   306       also have "norm (f x) * K \<le> norm (f x) * 0"
   307         using K norm_ge_zero by (rule mult_left_mono)
   308       finally show ?case
   309         using `0 < r` by simp
   310     qed
   311   qed
   312 qed
   313 
   314 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   315   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   316 
   317 lemma Zfun_add:
   318   assumes f: "Zfun f F" and g: "Zfun g F"
   319   shows "Zfun (\<lambda>x. f x + g x) F"
   320 proof (rule ZfunI)
   321   fix r::real assume "0 < r"
   322   hence r: "0 < r / 2" by simp
   323   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   324     using f r by (rule ZfunD)
   325   moreover
   326   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   327     using g r by (rule ZfunD)
   328   ultimately
   329   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   330   proof eventually_elim
   331     case (elim x)
   332     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   333       by (rule norm_triangle_ineq)
   334     also have "\<dots> < r/2 + r/2"
   335       using elim by (rule add_strict_mono)
   336     finally show ?case
   337       by simp
   338   qed
   339 qed
   340 
   341 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   342   unfolding Zfun_def by simp
   343 
   344 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   345   by (simp only: diff_minus Zfun_add Zfun_minus)
   346 
   347 lemma (in bounded_linear) Zfun:
   348   assumes g: "Zfun g F"
   349   shows "Zfun (\<lambda>x. f (g x)) F"
   350 proof -
   351   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   352     using bounded by fast
   353   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   354     by simp
   355   with g show ?thesis
   356     by (rule Zfun_imp_Zfun)
   357 qed
   358 
   359 lemma (in bounded_bilinear) Zfun:
   360   assumes f: "Zfun f F"
   361   assumes g: "Zfun g F"
   362   shows "Zfun (\<lambda>x. f x ** g x) F"
   363 proof (rule ZfunI)
   364   fix r::real assume r: "0 < r"
   365   obtain K where K: "0 < K"
   366     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   367     using pos_bounded by fast
   368   from K have K': "0 < inverse K"
   369     by (rule positive_imp_inverse_positive)
   370   have "eventually (\<lambda>x. norm (f x) < r) F"
   371     using f r by (rule ZfunD)
   372   moreover
   373   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   374     using g K' by (rule ZfunD)
   375   ultimately
   376   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   377   proof eventually_elim
   378     case (elim x)
   379     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   380       by (rule norm_le)
   381     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   382       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   383     also from K have "r * inverse K * K = r"
   384       by simp
   385     finally show ?case .
   386   qed
   387 qed
   388 
   389 lemma (in bounded_bilinear) Zfun_left:
   390   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   391   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   392 
   393 lemma (in bounded_bilinear) Zfun_right:
   394   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   395   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   396 
   397 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   398 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   399 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   400 
   401 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   402   by (simp only: tendsto_iff Zfun_def dist_norm)
   403 
   404 subsubsection {* Distance and norms *}
   405 
   406 lemma tendsto_dist [tendsto_intros]:
   407   fixes l m :: "'a :: metric_space"
   408   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   409   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   410 proof (rule tendstoI)
   411   fix e :: real assume "0 < e"
   412   hence e2: "0 < e/2" by simp
   413   from tendstoD [OF f e2] tendstoD [OF g e2]
   414   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   415   proof (eventually_elim)
   416     case (elim x)
   417     then show "dist (dist (f x) (g x)) (dist l m) < e"
   418       unfolding dist_real_def
   419       using dist_triangle2 [of "f x" "g x" "l"]
   420       using dist_triangle2 [of "g x" "l" "m"]
   421       using dist_triangle3 [of "l" "m" "f x"]
   422       using dist_triangle [of "f x" "m" "g x"]
   423       by arith
   424   qed
   425 qed
   426 
   427 lemma continuous_dist[continuous_intros]:
   428   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   429   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   430   unfolding continuous_def by (rule tendsto_dist)
   431 
   432 lemma continuous_on_dist[continuous_on_intros]:
   433   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   434   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   435   unfolding continuous_on_def by (auto intro: tendsto_dist)
   436 
   437 lemma tendsto_norm [tendsto_intros]:
   438   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   439   unfolding norm_conv_dist by (intro tendsto_intros)
   440 
   441 lemma continuous_norm [continuous_intros]:
   442   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   443   unfolding continuous_def by (rule tendsto_norm)
   444 
   445 lemma continuous_on_norm [continuous_on_intros]:
   446   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   447   unfolding continuous_on_def by (auto intro: tendsto_norm)
   448 
   449 lemma tendsto_norm_zero:
   450   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   451   by (drule tendsto_norm, simp)
   452 
   453 lemma tendsto_norm_zero_cancel:
   454   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   455   unfolding tendsto_iff dist_norm by simp
   456 
   457 lemma tendsto_norm_zero_iff:
   458   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   459   unfolding tendsto_iff dist_norm by simp
   460 
   461 lemma tendsto_rabs [tendsto_intros]:
   462   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   463   by (fold real_norm_def, rule tendsto_norm)
   464 
   465 lemma continuous_rabs [continuous_intros]:
   466   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   467   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   468 
   469 lemma continuous_on_rabs [continuous_on_intros]:
   470   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   471   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   472 
   473 lemma tendsto_rabs_zero:
   474   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   475   by (fold real_norm_def, rule tendsto_norm_zero)
   476 
   477 lemma tendsto_rabs_zero_cancel:
   478   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   479   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   480 
   481 lemma tendsto_rabs_zero_iff:
   482   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   483   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   484 
   485 subsubsection {* Addition and subtraction *}
   486 
   487 lemma tendsto_add [tendsto_intros]:
   488   fixes a b :: "'a::real_normed_vector"
   489   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   490   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   491 
   492 lemma continuous_add [continuous_intros]:
   493   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   494   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   495   unfolding continuous_def by (rule tendsto_add)
   496 
   497 lemma continuous_on_add [continuous_on_intros]:
   498   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   499   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   500   unfolding continuous_on_def by (auto intro: tendsto_add)
   501 
   502 lemma tendsto_add_zero:
   503   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   504   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   505   by (drule (1) tendsto_add, simp)
   506 
   507 lemma tendsto_minus [tendsto_intros]:
   508   fixes a :: "'a::real_normed_vector"
   509   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   510   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   511 
   512 lemma continuous_minus [continuous_intros]:
   513   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   514   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   515   unfolding continuous_def by (rule tendsto_minus)
   516 
   517 lemma continuous_on_minus [continuous_on_intros]:
   518   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   519   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   520   unfolding continuous_on_def by (auto intro: tendsto_minus)
   521 
   522 lemma tendsto_minus_cancel:
   523   fixes a :: "'a::real_normed_vector"
   524   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   525   by (drule tendsto_minus, simp)
   526 
   527 lemma tendsto_minus_cancel_left:
   528     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   529   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   530   by auto
   531 
   532 lemma tendsto_diff [tendsto_intros]:
   533   fixes a b :: "'a::real_normed_vector"
   534   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   535   by (simp add: diff_minus tendsto_add tendsto_minus)
   536 
   537 lemma continuous_diff [continuous_intros]:
   538   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   539   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   540   unfolding continuous_def by (rule tendsto_diff)
   541 
   542 lemma continuous_on_diff [continuous_on_intros]:
   543   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   544   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   545   unfolding continuous_on_def by (auto intro: tendsto_diff)
   546 
   547 lemma tendsto_setsum [tendsto_intros]:
   548   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   549   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   550   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   551 proof (cases "finite S")
   552   assume "finite S" thus ?thesis using assms
   553     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   554 next
   555   assume "\<not> finite S" thus ?thesis
   556     by (simp add: tendsto_const)
   557 qed
   558 
   559 lemma continuous_setsum [continuous_intros]:
   560   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   561   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   562   unfolding continuous_def by (rule tendsto_setsum)
   563 
   564 lemma continuous_on_setsum [continuous_intros]:
   565   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   566   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   567   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   568 
   569 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   570 
   571 subsubsection {* Linear operators and multiplication *}
   572 
   573 lemma (in bounded_linear) tendsto:
   574   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   575   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   576 
   577 lemma (in bounded_linear) continuous:
   578   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   579   using tendsto[of g _ F] by (auto simp: continuous_def)
   580 
   581 lemma (in bounded_linear) continuous_on:
   582   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   583   using tendsto[of g] by (auto simp: continuous_on_def)
   584 
   585 lemma (in bounded_linear) tendsto_zero:
   586   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   587   by (drule tendsto, simp only: zero)
   588 
   589 lemma (in bounded_bilinear) tendsto:
   590   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   591   by (simp only: tendsto_Zfun_iff prod_diff_prod
   592                  Zfun_add Zfun Zfun_left Zfun_right)
   593 
   594 lemma (in bounded_bilinear) continuous:
   595   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   596   using tendsto[of f _ F g] by (auto simp: continuous_def)
   597 
   598 lemma (in bounded_bilinear) continuous_on:
   599   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   600   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   601 
   602 lemma (in bounded_bilinear) tendsto_zero:
   603   assumes f: "(f ---> 0) F"
   604   assumes g: "(g ---> 0) F"
   605   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   606   using tendsto [OF f g] by (simp add: zero_left)
   607 
   608 lemma (in bounded_bilinear) tendsto_left_zero:
   609   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   610   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   611 
   612 lemma (in bounded_bilinear) tendsto_right_zero:
   613   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   614   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   615 
   616 lemmas tendsto_of_real [tendsto_intros] =
   617   bounded_linear.tendsto [OF bounded_linear_of_real]
   618 
   619 lemmas tendsto_scaleR [tendsto_intros] =
   620   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   621 
   622 lemmas tendsto_mult [tendsto_intros] =
   623   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   624 
   625 lemmas continuous_of_real [continuous_intros] =
   626   bounded_linear.continuous [OF bounded_linear_of_real]
   627 
   628 lemmas continuous_scaleR [continuous_intros] =
   629   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   630 
   631 lemmas continuous_mult [continuous_intros] =
   632   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   633 
   634 lemmas continuous_on_of_real [continuous_on_intros] =
   635   bounded_linear.continuous_on [OF bounded_linear_of_real]
   636 
   637 lemmas continuous_on_scaleR [continuous_on_intros] =
   638   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   639 
   640 lemmas continuous_on_mult [continuous_on_intros] =
   641   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   642 
   643 lemmas tendsto_mult_zero =
   644   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   645 
   646 lemmas tendsto_mult_left_zero =
   647   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   648 
   649 lemmas tendsto_mult_right_zero =
   650   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   651 
   652 lemma tendsto_power [tendsto_intros]:
   653   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   654   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   655   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   656 
   657 lemma continuous_power [continuous_intros]:
   658   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   659   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   660   unfolding continuous_def by (rule tendsto_power)
   661 
   662 lemma continuous_on_power [continuous_on_intros]:
   663   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   664   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   665   unfolding continuous_on_def by (auto intro: tendsto_power)
   666 
   667 lemma tendsto_setprod [tendsto_intros]:
   668   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   669   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   670   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   671 proof (cases "finite S")
   672   assume "finite S" thus ?thesis using assms
   673     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   674 next
   675   assume "\<not> finite S" thus ?thesis
   676     by (simp add: tendsto_const)
   677 qed
   678 
   679 lemma continuous_setprod [continuous_intros]:
   680   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   681   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   682   unfolding continuous_def by (rule tendsto_setprod)
   683 
   684 lemma continuous_on_setprod [continuous_intros]:
   685   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   686   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   687   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   688 
   689 subsubsection {* Inverse and division *}
   690 
   691 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   692   assumes f: "Zfun f F"
   693   assumes g: "Bfun g F"
   694   shows "Zfun (\<lambda>x. f x ** g x) F"
   695 proof -
   696   obtain K where K: "0 \<le> K"
   697     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   698     using nonneg_bounded by fast
   699   obtain B where B: "0 < B"
   700     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   701     using g by (rule BfunE)
   702   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   703   using norm_g proof eventually_elim
   704     case (elim x)
   705     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   706       by (rule norm_le)
   707     also have "\<dots> \<le> norm (f x) * B * K"
   708       by (intro mult_mono' order_refl norm_g norm_ge_zero
   709                 mult_nonneg_nonneg K elim)
   710     also have "\<dots> = norm (f x) * (B * K)"
   711       by (rule mult_assoc)
   712     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   713   qed
   714   with f show ?thesis
   715     by (rule Zfun_imp_Zfun)
   716 qed
   717 
   718 lemma (in bounded_bilinear) flip:
   719   "bounded_bilinear (\<lambda>x y. y ** x)"
   720   apply default
   721   apply (rule add_right)
   722   apply (rule add_left)
   723   apply (rule scaleR_right)
   724   apply (rule scaleR_left)
   725   apply (subst mult_commute)
   726   using bounded by fast
   727 
   728 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   729   assumes f: "Bfun f F"
   730   assumes g: "Zfun g F"
   731   shows "Zfun (\<lambda>x. f x ** g x) F"
   732   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   733 
   734 lemma Bfun_inverse_lemma:
   735   fixes x :: "'a::real_normed_div_algebra"
   736   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   737   apply (subst nonzero_norm_inverse, clarsimp)
   738   apply (erule (1) le_imp_inverse_le)
   739   done
   740 
   741 lemma Bfun_inverse:
   742   fixes a :: "'a::real_normed_div_algebra"
   743   assumes f: "(f ---> a) F"
   744   assumes a: "a \<noteq> 0"
   745   shows "Bfun (\<lambda>x. inverse (f x)) F"
   746 proof -
   747   from a have "0 < norm a" by simp
   748   hence "\<exists>r>0. r < norm a" by (rule dense)
   749   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   750   have "eventually (\<lambda>x. dist (f x) a < r) F"
   751     using tendstoD [OF f r1] by fast
   752   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   753   proof eventually_elim
   754     case (elim x)
   755     hence 1: "norm (f x - a) < r"
   756       by (simp add: dist_norm)
   757     hence 2: "f x \<noteq> 0" using r2 by auto
   758     hence "norm (inverse (f x)) = inverse (norm (f x))"
   759       by (rule nonzero_norm_inverse)
   760     also have "\<dots> \<le> inverse (norm a - r)"
   761     proof (rule le_imp_inverse_le)
   762       show "0 < norm a - r" using r2 by simp
   763     next
   764       have "norm a - norm (f x) \<le> norm (a - f x)"
   765         by (rule norm_triangle_ineq2)
   766       also have "\<dots> = norm (f x - a)"
   767         by (rule norm_minus_commute)
   768       also have "\<dots> < r" using 1 .
   769       finally show "norm a - r \<le> norm (f x)" by simp
   770     qed
   771     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   772   qed
   773   thus ?thesis by (rule BfunI)
   774 qed
   775 
   776 lemma tendsto_inverse [tendsto_intros]:
   777   fixes a :: "'a::real_normed_div_algebra"
   778   assumes f: "(f ---> a) F"
   779   assumes a: "a \<noteq> 0"
   780   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   781 proof -
   782   from a have "0 < norm a" by simp
   783   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   784     by (rule tendstoD)
   785   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   786     unfolding dist_norm by (auto elim!: eventually_elim1)
   787   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   788     - (inverse (f x) * (f x - a) * inverse a)) F"
   789     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   790   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   791     by (intro Zfun_minus Zfun_mult_left
   792       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   793       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   794   ultimately show ?thesis
   795     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   796 qed
   797 
   798 lemma continuous_inverse:
   799   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   800   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   801   shows "continuous F (\<lambda>x. inverse (f x))"
   802   using assms unfolding continuous_def by (rule tendsto_inverse)
   803 
   804 lemma continuous_at_within_inverse[continuous_intros]:
   805   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   806   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   807   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   808   using assms unfolding continuous_within by (rule tendsto_inverse)
   809 
   810 lemma isCont_inverse[continuous_intros, simp]:
   811   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   812   assumes "isCont f a" and "f a \<noteq> 0"
   813   shows "isCont (\<lambda>x. inverse (f x)) a"
   814   using assms unfolding continuous_at by (rule tendsto_inverse)
   815 
   816 lemma continuous_on_inverse[continuous_on_intros]:
   817   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   818   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   819   shows "continuous_on s (\<lambda>x. inverse (f x))"
   820   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   821 
   822 lemma tendsto_divide [tendsto_intros]:
   823   fixes a b :: "'a::real_normed_field"
   824   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   825     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   826   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   827 
   828 lemma continuous_divide:
   829   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   830   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   831   shows "continuous F (\<lambda>x. (f x) / (g x))"
   832   using assms unfolding continuous_def by (rule tendsto_divide)
   833 
   834 lemma continuous_at_within_divide[continuous_intros]:
   835   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   836   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   837   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   838   using assms unfolding continuous_within by (rule tendsto_divide)
   839 
   840 lemma isCont_divide[continuous_intros, simp]:
   841   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   842   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   843   shows "isCont (\<lambda>x. (f x) / g x) a"
   844   using assms unfolding continuous_at by (rule tendsto_divide)
   845 
   846 lemma continuous_on_divide[continuous_on_intros]:
   847   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   848   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   849   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   850   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   851 
   852 lemma tendsto_sgn [tendsto_intros]:
   853   fixes l :: "'a::real_normed_vector"
   854   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   855   unfolding sgn_div_norm by (simp add: tendsto_intros)
   856 
   857 lemma continuous_sgn:
   858   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   859   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   860   shows "continuous F (\<lambda>x. sgn (f x))"
   861   using assms unfolding continuous_def by (rule tendsto_sgn)
   862 
   863 lemma continuous_at_within_sgn[continuous_intros]:
   864   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   865   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   866   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   867   using assms unfolding continuous_within by (rule tendsto_sgn)
   868 
   869 lemma isCont_sgn[continuous_intros]:
   870   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   871   assumes "isCont f a" and "f a \<noteq> 0"
   872   shows "isCont (\<lambda>x. sgn (f x)) a"
   873   using assms unfolding continuous_at by (rule tendsto_sgn)
   874 
   875 lemma continuous_on_sgn[continuous_on_intros]:
   876   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   877   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   878   shows "continuous_on s (\<lambda>x. sgn (f x))"
   879   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   880 
   881 lemma filterlim_at_infinity:
   882   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   883   assumes "0 \<le> c"
   884   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   885   unfolding filterlim_iff eventually_at_infinity
   886 proof safe
   887   fix P :: "'a \<Rightarrow> bool" and b
   888   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   889     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   890   have "max b (c + 1) > c" by auto
   891   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   892     by auto
   893   then show "eventually (\<lambda>x. P (f x)) F"
   894   proof eventually_elim
   895     fix x assume "max b (c + 1) \<le> norm (f x)"
   896     with P show "P (f x)" by auto
   897   qed
   898 qed force
   899 
   900 
   901 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   902 
   903 text {*
   904 
   905 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   906 @{term "at_right x"} and also @{term "at_right 0"}.
   907 
   908 *}
   909 
   910 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   911 
   912 lemma filtermap_homeomorph:
   913   assumes f: "continuous (at a) f"
   914   assumes g: "continuous (at (f a)) g"
   915   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   916   shows "filtermap f (nhds a) = nhds (f a)"
   917   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   918 proof safe
   919   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   920   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   921   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   922 next
   923   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   924   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   925   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   926     by (metis UNIV_I)
   927   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   928     by (force intro!: exI[of _ A])
   929 qed
   930 
   931 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   932   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   933 
   934 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   935   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   936 
   937 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   938   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   939 
   940 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   941   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   942 
   943 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   944   using filtermap_at_right_shift[of "-a" 0] by simp
   945 
   946 lemma filterlim_at_right_to_0:
   947   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   948   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   949 
   950 lemma eventually_at_right_to_0:
   951   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   952   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   953 
   954 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   955   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   956 
   957 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   958   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   959 
   960 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   961   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   962 
   963 lemma filterlim_at_left_to_right:
   964   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   965   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   966 
   967 lemma eventually_at_left_to_right:
   968   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   969   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   970 
   971 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   972   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   973   by (metis le_minus_iff minus_minus)
   974 
   975 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   976   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   977 
   978 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   979   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   980 
   981 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   982   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   983 
   984 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   985   unfolding filterlim_at_top eventually_at_bot_dense
   986   by (metis leI minus_less_iff order_less_asym)
   987 
   988 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   989   unfolding filterlim_at_bot eventually_at_top_dense
   990   by (metis leI less_minus_iff order_less_asym)
   991 
   992 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   993   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   994   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   995   by auto
   996 
   997 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   998   unfolding filterlim_uminus_at_top by simp
   999 
  1000 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1001   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1002 proof safe
  1003   fix Z :: real assume [arith]: "0 < Z"
  1004   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1005     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1006   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1007     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1008 qed
  1009 
  1010 lemma filterlim_inverse_at_top:
  1011   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1012   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1013      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1014 
  1015 lemma filterlim_inverse_at_bot_neg:
  1016   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1017   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1018 
  1019 lemma filterlim_inverse_at_bot:
  1020   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1021   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1022   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1023 
  1024 lemma tendsto_inverse_0:
  1025   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1026   shows "(inverse ---> (0::'a)) at_infinity"
  1027   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1028 proof safe
  1029   fix r :: real assume "0 < r"
  1030   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1031   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1032     fix x :: 'a
  1033     from `0 < r` have "0 < inverse (r / 2)" by simp
  1034     also assume *: "inverse (r / 2) \<le> norm x"
  1035     finally show "norm (inverse x) < r"
  1036       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1037   qed
  1038 qed
  1039 
  1040 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1041 proof (rule antisym)
  1042   have "(inverse ---> (0::real)) at_top"
  1043     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1044   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1045     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1046 next
  1047   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1048     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1049   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1050     by (simp add: filtermap_ident filtermap_filtermap)
  1051 qed
  1052 
  1053 lemma eventually_at_right_to_top:
  1054   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1055   unfolding at_right_to_top eventually_filtermap ..
  1056 
  1057 lemma filterlim_at_right_to_top:
  1058   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1059   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1060 
  1061 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1062   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1063 
  1064 lemma eventually_at_top_to_right:
  1065   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1066   unfolding at_top_to_right eventually_filtermap ..
  1067 
  1068 lemma filterlim_at_top_to_right:
  1069   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1070   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1071 
  1072 lemma filterlim_inverse_at_infinity:
  1073   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1074   shows "filterlim inverse at_infinity (at (0::'a))"
  1075   unfolding filterlim_at_infinity[OF order_refl]
  1076 proof safe
  1077   fix r :: real assume "0 < r"
  1078   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1079     unfolding eventually_at norm_inverse
  1080     by (intro exI[of _ "inverse r"])
  1081        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1082 qed
  1083 
  1084 lemma filterlim_inverse_at_iff:
  1085   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1086   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1087   unfolding filterlim_def filtermap_filtermap[symmetric]
  1088 proof
  1089   assume "filtermap g F \<le> at_infinity"
  1090   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1091     by (rule filtermap_mono)
  1092   also have "\<dots> \<le> at 0"
  1093     using tendsto_inverse_0[where 'a='b]
  1094     by (auto intro!: exI[of _ 1]
  1095              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1096   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1097 next
  1098   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1099   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1100     by (rule filtermap_mono)
  1101   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1102     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1103 qed
  1104 
  1105 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1106  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1107 
  1108 text {*
  1109 
  1110 We only show rules for multiplication and addition when the functions are either against a real
  1111 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1112 
  1113 *}
  1114 
  1115 lemma filterlim_tendsto_pos_mult_at_top: 
  1116   assumes f: "(f ---> c) F" and c: "0 < c"
  1117   assumes g: "LIM x F. g x :> at_top"
  1118   shows "LIM x F. (f x * g x :: real) :> at_top"
  1119   unfolding filterlim_at_top_gt[where c=0]
  1120 proof safe
  1121   fix Z :: real assume "0 < Z"
  1122   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1123     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1124              simp: dist_real_def abs_real_def split: split_if_asm)
  1125   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1126     unfolding filterlim_at_top by auto
  1127   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1128   proof eventually_elim
  1129     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1130     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1131       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1132     with `0 < c` show "Z \<le> f x * g x"
  1133        by simp
  1134   qed
  1135 qed
  1136 
  1137 lemma filterlim_at_top_mult_at_top: 
  1138   assumes f: "LIM x F. f x :> at_top"
  1139   assumes g: "LIM x F. g x :> at_top"
  1140   shows "LIM x F. (f x * g x :: real) :> at_top"
  1141   unfolding filterlim_at_top_gt[where c=0]
  1142 proof safe
  1143   fix Z :: real assume "0 < Z"
  1144   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1145     unfolding filterlim_at_top by auto
  1146   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1147     unfolding filterlim_at_top by auto
  1148   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1149   proof eventually_elim
  1150     fix x assume "1 \<le> f x" "Z \<le> g x"
  1151     with `0 < Z` have "1 * Z \<le> f x * g x"
  1152       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1153     then show "Z \<le> f x * g x"
  1154        by simp
  1155   qed
  1156 qed
  1157 
  1158 lemma filterlim_tendsto_pos_mult_at_bot:
  1159   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1160   shows "LIM x F. f x * g x :> at_bot"
  1161   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1162   unfolding filterlim_uminus_at_bot by simp
  1163 
  1164 lemma filterlim_tendsto_add_at_top: 
  1165   assumes f: "(f ---> c) F"
  1166   assumes g: "LIM x F. g x :> at_top"
  1167   shows "LIM x F. (f x + g x :: real) :> at_top"
  1168   unfolding filterlim_at_top_gt[where c=0]
  1169 proof safe
  1170   fix Z :: real assume "0 < Z"
  1171   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1172     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1173   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1174     unfolding filterlim_at_top by auto
  1175   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1176     by eventually_elim simp
  1177 qed
  1178 
  1179 lemma LIM_at_top_divide:
  1180   fixes f g :: "'a \<Rightarrow> real"
  1181   assumes f: "(f ---> a) F" "0 < a"
  1182   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1183   shows "LIM x F. f x / g x :> at_top"
  1184   unfolding divide_inverse
  1185   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1186 
  1187 lemma filterlim_at_top_add_at_top: 
  1188   assumes f: "LIM x F. f x :> at_top"
  1189   assumes g: "LIM x F. g x :> at_top"
  1190   shows "LIM x F. (f x + g x :: real) :> at_top"
  1191   unfolding filterlim_at_top_gt[where c=0]
  1192 proof safe
  1193   fix Z :: real assume "0 < Z"
  1194   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1195     unfolding filterlim_at_top by auto
  1196   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1197     unfolding filterlim_at_top by auto
  1198   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1199     by eventually_elim simp
  1200 qed
  1201 
  1202 lemma tendsto_divide_0:
  1203   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1204   assumes f: "(f ---> c) F"
  1205   assumes g: "LIM x F. g x :> at_infinity"
  1206   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1207   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1208 
  1209 lemma linear_plus_1_le_power:
  1210   fixes x :: real
  1211   assumes x: "0 \<le> x"
  1212   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1213 proof (induct n)
  1214   case (Suc n)
  1215   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1216     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1217   also have "\<dots> \<le> (x + 1)^Suc n"
  1218     using Suc x by (simp add: mult_left_mono)
  1219   finally show ?case .
  1220 qed simp
  1221 
  1222 lemma filterlim_realpow_sequentially_gt1:
  1223   fixes x :: "'a :: real_normed_div_algebra"
  1224   assumes x[arith]: "1 < norm x"
  1225   shows "LIM n sequentially. x ^ n :> at_infinity"
  1226 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1227   fix y :: real assume "0 < y"
  1228   have "0 < norm x - 1" by simp
  1229   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1230   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1231   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1232   also have "\<dots> = norm x ^ N" by simp
  1233   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1234     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1235   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1236     unfolding eventually_sequentially
  1237     by (auto simp: norm_power)
  1238 qed simp
  1239 
  1240 
  1241 subsection {* Limits of Sequences *}
  1242 
  1243 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1244   by simp
  1245 
  1246 lemma LIMSEQ_iff:
  1247   fixes L :: "'a::real_normed_vector"
  1248   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1249 unfolding LIMSEQ_def dist_norm ..
  1250 
  1251 lemma LIMSEQ_I:
  1252   fixes L :: "'a::real_normed_vector"
  1253   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1254 by (simp add: LIMSEQ_iff)
  1255 
  1256 lemma LIMSEQ_D:
  1257   fixes L :: "'a::real_normed_vector"
  1258   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1259 by (simp add: LIMSEQ_iff)
  1260 
  1261 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1262   unfolding tendsto_def eventually_sequentially
  1263   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1264 
  1265 lemma Bseq_inverse_lemma:
  1266   fixes x :: "'a::real_normed_div_algebra"
  1267   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1268 apply (subst nonzero_norm_inverse, clarsimp)
  1269 apply (erule (1) le_imp_inverse_le)
  1270 done
  1271 
  1272 lemma Bseq_inverse:
  1273   fixes a :: "'a::real_normed_div_algebra"
  1274   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1275   by (rule Bfun_inverse)
  1276 
  1277 lemma LIMSEQ_diff_approach_zero:
  1278   fixes L :: "'a::real_normed_vector"
  1279   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1280   by (drule (1) tendsto_add, simp)
  1281 
  1282 lemma LIMSEQ_diff_approach_zero2:
  1283   fixes L :: "'a::real_normed_vector"
  1284   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1285   by (drule (1) tendsto_diff, simp)
  1286 
  1287 text{*An unbounded sequence's inverse tends to 0*}
  1288 
  1289 lemma LIMSEQ_inverse_zero:
  1290   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1291   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1292   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1293   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1294   done
  1295 
  1296 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1297 
  1298 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1299   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1300             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1301 
  1302 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1303 infinity is now easily proved*}
  1304 
  1305 lemma LIMSEQ_inverse_real_of_nat_add:
  1306      "(%n. r + inverse(real(Suc n))) ----> r"
  1307   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1308 
  1309 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1310      "(%n. r + -inverse(real(Suc n))) ----> r"
  1311   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1312   by auto
  1313 
  1314 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1315      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1316   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1317   by auto
  1318 
  1319 subsection {* Convergence on sequences *}
  1320 
  1321 lemma convergent_add:
  1322   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1323   assumes "convergent (\<lambda>n. X n)"
  1324   assumes "convergent (\<lambda>n. Y n)"
  1325   shows "convergent (\<lambda>n. X n + Y n)"
  1326   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1327 
  1328 lemma convergent_setsum:
  1329   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1330   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1331   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1332 proof (cases "finite A")
  1333   case True from this and assms show ?thesis
  1334     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1335 qed (simp add: convergent_const)
  1336 
  1337 lemma (in bounded_linear) convergent:
  1338   assumes "convergent (\<lambda>n. X n)"
  1339   shows "convergent (\<lambda>n. f (X n))"
  1340   using assms unfolding convergent_def by (fast intro: tendsto)
  1341 
  1342 lemma (in bounded_bilinear) convergent:
  1343   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1344   shows "convergent (\<lambda>n. X n ** Y n)"
  1345   using assms unfolding convergent_def by (fast intro: tendsto)
  1346 
  1347 lemma convergent_minus_iff:
  1348   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1349   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1350 apply (simp add: convergent_def)
  1351 apply (auto dest: tendsto_minus)
  1352 apply (drule tendsto_minus, auto)
  1353 done
  1354 
  1355 
  1356 text {* A monotone sequence converges to its least upper bound. *}
  1357 
  1358 lemma isLub_mono_imp_LIMSEQ:
  1359   fixes X :: "nat \<Rightarrow> real"
  1360   assumes u: "isLub UNIV {x. \<exists>n. X n = x} u" (* FIXME: use 'range X' *)
  1361   assumes X: "\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n"
  1362   shows "X ----> u"
  1363 proof (rule LIMSEQ_I)
  1364   have 1: "\<forall>n. X n \<le> u"
  1365     using isLubD2 [OF u] by auto
  1366   have "\<forall>y. (\<forall>n. X n \<le> y) \<longrightarrow> u \<le> y"
  1367     using isLub_le_isUb [OF u] by (auto simp add: isUb_def setle_def)
  1368   hence 2: "\<forall>y<u. \<exists>n. y < X n"
  1369     by (metis not_le)
  1370   fix r :: real assume "0 < r"
  1371   hence "u - r < u" by simp
  1372   hence "\<exists>m. u - r < X m" using 2 by simp
  1373   then obtain m where "u - r < X m" ..
  1374   with X have "\<forall>n\<ge>m. u - r < X n"
  1375     by (fast intro: less_le_trans)
  1376   hence "\<exists>m. \<forall>n\<ge>m. u - r < X n" ..
  1377   thus "\<exists>m. \<forall>n\<ge>m. norm (X n - u) < r"
  1378     using 1 by (simp add: diff_less_eq add_commute)
  1379 qed
  1380 
  1381 text{*A standard proof of the theorem for monotone increasing sequence*}
  1382 
  1383 lemma Bseq_mono_convergent:
  1384    "Bseq X \<Longrightarrow> \<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> convergent (X::nat=>real)"
  1385   by (metis Bseq_isLub isLub_mono_imp_LIMSEQ convergentI)
  1386 
  1387 text{*Main monotonicity theorem*}
  1388 
  1389 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1390   by (metis monoseq_iff incseq_def decseq_eq_incseq convergent_minus_iff Bseq_minus_iff
  1391             Bseq_mono_convergent)
  1392 
  1393 lemma Cauchy_iff:
  1394   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1395   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1396   unfolding Cauchy_def dist_norm ..
  1397 
  1398 lemma CauchyI:
  1399   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1400   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1401 by (simp add: Cauchy_iff)
  1402 
  1403 lemma CauchyD:
  1404   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1405   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1406 by (simp add: Cauchy_iff)
  1407 
  1408 lemma incseq_convergent:
  1409   fixes X :: "nat \<Rightarrow> real"
  1410   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1411   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1412 proof atomize_elim
  1413   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1414   obtain L where "X ----> L"
  1415     by (auto simp: convergent_def monoseq_def incseq_def)
  1416   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1417     by (auto intro!: exI[of _ L] incseq_le)
  1418 qed
  1419 
  1420 lemma decseq_convergent:
  1421   fixes X :: "nat \<Rightarrow> real"
  1422   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1423   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1424 proof atomize_elim
  1425   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1426   obtain L where "X ----> L"
  1427     by (auto simp: convergent_def monoseq_def decseq_def)
  1428   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1429     by (auto intro!: exI[of _ L] decseq_le)
  1430 qed
  1431 
  1432 subsubsection {* Cauchy Sequences are Bounded *}
  1433 
  1434 text{*A Cauchy sequence is bounded -- this is the standard
  1435   proof mechanization rather than the nonstandard proof*}
  1436 
  1437 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1438           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1439 apply (clarify, drule spec, drule (1) mp)
  1440 apply (simp only: norm_minus_commute)
  1441 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1442 apply simp
  1443 done
  1444 
  1445 subsection {* Power Sequences *}
  1446 
  1447 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1448 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1449   also fact that bounded and monotonic sequence converges.*}
  1450 
  1451 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1452 apply (simp add: Bseq_def)
  1453 apply (rule_tac x = 1 in exI)
  1454 apply (simp add: power_abs)
  1455 apply (auto dest: power_mono)
  1456 done
  1457 
  1458 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1459 apply (clarify intro!: mono_SucI2)
  1460 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1461 done
  1462 
  1463 lemma convergent_realpow:
  1464   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1465 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1466 
  1467 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1468   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1469 
  1470 lemma LIMSEQ_realpow_zero:
  1471   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1472 proof cases
  1473   assume "0 \<le> x" and "x \<noteq> 0"
  1474   hence x0: "0 < x" by simp
  1475   assume x1: "x < 1"
  1476   from x0 x1 have "1 < inverse x"
  1477     by (rule one_less_inverse)
  1478   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1479     by (rule LIMSEQ_inverse_realpow_zero)
  1480   thus ?thesis by (simp add: power_inverse)
  1481 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1482 
  1483 lemma LIMSEQ_power_zero:
  1484   fixes x :: "'a::{real_normed_algebra_1}"
  1485   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1486 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1487 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1488 apply (simp add: power_abs norm_power_ineq)
  1489 done
  1490 
  1491 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1492   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1493 
  1494 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1495 
  1496 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1497   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1498 
  1499 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1500   by (rule LIMSEQ_power_zero) simp
  1501 
  1502 
  1503 subsection {* Limits of Functions *}
  1504 
  1505 lemma LIM_eq:
  1506   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1507   shows "f -- a --> L =
  1508      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1509 by (simp add: LIM_def dist_norm)
  1510 
  1511 lemma LIM_I:
  1512   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1513   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1514       ==> f -- a --> L"
  1515 by (simp add: LIM_eq)
  1516 
  1517 lemma LIM_D:
  1518   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1519   shows "[| f -- a --> L; 0<r |]
  1520       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1521 by (simp add: LIM_eq)
  1522 
  1523 lemma LIM_offset:
  1524   fixes a :: "'a::real_normed_vector"
  1525   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1526   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1527 
  1528 lemma LIM_offset_zero:
  1529   fixes a :: "'a::real_normed_vector"
  1530   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1531 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1532 
  1533 lemma LIM_offset_zero_cancel:
  1534   fixes a :: "'a::real_normed_vector"
  1535   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1536 by (drule_tac k="- a" in LIM_offset, simp)
  1537 
  1538 lemma LIM_offset_zero_iff:
  1539   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1540   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1541   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1542 
  1543 lemma LIM_zero:
  1544   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1545   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1546 unfolding tendsto_iff dist_norm by simp
  1547 
  1548 lemma LIM_zero_cancel:
  1549   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1550   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1551 unfolding tendsto_iff dist_norm by simp
  1552 
  1553 lemma LIM_zero_iff:
  1554   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1555   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1556 unfolding tendsto_iff dist_norm by simp
  1557 
  1558 lemma LIM_imp_LIM:
  1559   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1560   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1561   assumes f: "f -- a --> l"
  1562   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1563   shows "g -- a --> m"
  1564   by (rule metric_LIM_imp_LIM [OF f],
  1565     simp add: dist_norm le)
  1566 
  1567 lemma LIM_equal2:
  1568   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1569   assumes 1: "0 < R"
  1570   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1571   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1572 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1573 
  1574 lemma LIM_compose2:
  1575   fixes a :: "'a::real_normed_vector"
  1576   assumes f: "f -- a --> b"
  1577   assumes g: "g -- b --> c"
  1578   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1579   shows "(\<lambda>x. g (f x)) -- a --> c"
  1580 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1581 
  1582 lemma real_LIM_sandwich_zero:
  1583   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1584   assumes f: "f -- a --> 0"
  1585   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1586   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1587   shows "g -- a --> 0"
  1588 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1589   fix x assume x: "x \<noteq> a"
  1590   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1591   also have "g x \<le> f x" by (rule 2 [OF x])
  1592   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1593   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1594   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1595 qed
  1596 
  1597 
  1598 subsection {* Continuity *}
  1599 
  1600 lemma LIM_isCont_iff:
  1601   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1602   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1603 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1604 
  1605 lemma isCont_iff:
  1606   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1607   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1608 by (simp add: isCont_def LIM_isCont_iff)
  1609 
  1610 lemma isCont_LIM_compose2:
  1611   fixes a :: "'a::real_normed_vector"
  1612   assumes f [unfolded isCont_def]: "isCont f a"
  1613   assumes g: "g -- f a --> l"
  1614   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1615   shows "(\<lambda>x. g (f x)) -- a --> l"
  1616 by (rule LIM_compose2 [OF f g inj])
  1617 
  1618 
  1619 lemma isCont_norm [simp]:
  1620   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1621   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1622   by (fact continuous_norm)
  1623 
  1624 lemma isCont_rabs [simp]:
  1625   fixes f :: "'a::t2_space \<Rightarrow> real"
  1626   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1627   by (fact continuous_rabs)
  1628 
  1629 lemma isCont_add [simp]:
  1630   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1631   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1632   by (fact continuous_add)
  1633 
  1634 lemma isCont_minus [simp]:
  1635   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1636   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1637   by (fact continuous_minus)
  1638 
  1639 lemma isCont_diff [simp]:
  1640   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1641   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1642   by (fact continuous_diff)
  1643 
  1644 lemma isCont_mult [simp]:
  1645   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1646   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1647   by (fact continuous_mult)
  1648 
  1649 lemma (in bounded_linear) isCont:
  1650   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1651   by (fact continuous)
  1652 
  1653 lemma (in bounded_bilinear) isCont:
  1654   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1655   by (fact continuous)
  1656 
  1657 lemmas isCont_scaleR [simp] = 
  1658   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1659 
  1660 lemmas isCont_of_real [simp] =
  1661   bounded_linear.isCont [OF bounded_linear_of_real]
  1662 
  1663 lemma isCont_power [simp]:
  1664   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1665   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1666   by (fact continuous_power)
  1667 
  1668 lemma isCont_setsum [simp]:
  1669   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1670   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1671   by (auto intro: continuous_setsum)
  1672 
  1673 lemmas isCont_intros =
  1674   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
  1675   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
  1676   isCont_of_real isCont_power isCont_sgn isCont_setsum
  1677 
  1678 subsection {* Uniform Continuity *}
  1679 
  1680 definition
  1681   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1682   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1683 
  1684 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1685 by (simp add: isUCont_def isCont_def LIM_def, force)
  1686 
  1687 lemma isUCont_Cauchy:
  1688   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1689 unfolding isUCont_def
  1690 apply (rule metric_CauchyI)
  1691 apply (drule_tac x=e in spec, safe)
  1692 apply (drule_tac e=s in metric_CauchyD, safe)
  1693 apply (rule_tac x=M in exI, simp)
  1694 done
  1695 
  1696 lemma (in bounded_linear) isUCont: "isUCont f"
  1697 unfolding isUCont_def dist_norm
  1698 proof (intro allI impI)
  1699   fix r::real assume r: "0 < r"
  1700   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1701     using pos_bounded by fast
  1702   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1703   proof (rule exI, safe)
  1704     from r K show "0 < r / K" by (rule divide_pos_pos)
  1705   next
  1706     fix x y :: 'a
  1707     assume xy: "norm (x - y) < r / K"
  1708     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1709     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1710     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1711     finally show "norm (f x - f y) < r" .
  1712   qed
  1713 qed
  1714 
  1715 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1716 by (rule isUCont [THEN isUCont_Cauchy])
  1717 
  1718 lemma LIM_less_bound: 
  1719   fixes f :: "real \<Rightarrow> real"
  1720   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1721   shows "0 \<le> f x"
  1722 proof (rule tendsto_le_const)
  1723   show "(f ---> f x) (at_left x)"
  1724     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1725   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1726     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1727 qed simp
  1728 
  1729 
  1730 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1731 
  1732 lemma nested_sequence_unique:
  1733   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1734   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1735 proof -
  1736   have "incseq f" unfolding incseq_Suc_iff by fact
  1737   have "decseq g" unfolding decseq_Suc_iff by fact
  1738 
  1739   { fix n
  1740     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1741     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1742   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1743     using incseq_convergent[OF `incseq f`] by auto
  1744   moreover
  1745   { fix n
  1746     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1747     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1748   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1749     using decseq_convergent[OF `decseq g`] by auto
  1750   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1751   ultimately show ?thesis by auto
  1752 qed
  1753 
  1754 lemma Bolzano[consumes 1, case_names trans local]:
  1755   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1756   assumes [arith]: "a \<le> b"
  1757   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1758   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1759   shows "P a b"
  1760 proof -
  1761   def bisect \<equiv> "nat_rec (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1762   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1763   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1764     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1765     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1766 
  1767   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1768 
  1769   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1770   proof (safe intro!: nested_sequence_unique)
  1771     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1772   next
  1773     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1774     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1775   qed fact
  1776   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1777   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1778     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1779 
  1780   show "P a b"
  1781   proof (rule ccontr)
  1782     assume "\<not> P a b" 
  1783     { fix n have "\<not> P (l n) (u n)"
  1784       proof (induct n)
  1785         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1786       qed (simp add: `\<not> P a b`) }
  1787     moreover
  1788     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1789         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1790       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1791         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1792       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1793       proof eventually_elim
  1794         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1795         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1796         with x show "P (l n) (u n)" by (rule d)
  1797       qed }
  1798     ultimately show False by simp
  1799   qed
  1800 qed
  1801 
  1802 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1803 proof (cases "a \<le> b", rule compactI)
  1804   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1805   def T == "{a .. b}"
  1806   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1807   proof (induct rule: Bolzano)
  1808     case (trans a b c)
  1809     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1810     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1811       by (auto simp: *)
  1812     with trans show ?case
  1813       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1814   next
  1815     case (local x)
  1816     then have "x \<in> \<Union>C" using C by auto
  1817     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1818     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1819       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1820     with `c \<in> C` show ?case
  1821       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1822   qed
  1823 qed simp
  1824 
  1825 
  1826 subsection {* Boundedness of continuous functions *}
  1827 
  1828 text{*By bisection, function continuous on closed interval is bounded above*}
  1829 
  1830 lemma isCont_eq_Ub:
  1831   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1832   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1833     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1834   using continuous_attains_sup[of "{a .. b}" f]
  1835   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1836 
  1837 lemma isCont_eq_Lb:
  1838   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1839   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1840     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1841   using continuous_attains_inf[of "{a .. b}" f]
  1842   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1843 
  1844 lemma isCont_bounded:
  1845   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1846   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1847   using isCont_eq_Ub[of a b f] by auto
  1848 
  1849 lemma isCont_has_Ub:
  1850   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1851   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1852     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1853   using isCont_eq_Ub[of a b f] by auto
  1854 
  1855 (*HOL style here: object-level formulations*)
  1856 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1857       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1858       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1859   by (blast intro: IVT)
  1860 
  1861 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1862       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1863       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1864   by (blast intro: IVT2)
  1865 
  1866 lemma isCont_Lb_Ub:
  1867   fixes f :: "real \<Rightarrow> real"
  1868   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1869   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1870                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1871 proof -
  1872   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1873     using isCont_eq_Ub[OF assms] by auto
  1874   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1875     using isCont_eq_Lb[OF assms] by auto
  1876   show ?thesis
  1877     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1878     apply (rule_tac x="f L" in exI)
  1879     apply (rule_tac x="f M" in exI)
  1880     apply (cases "L \<le> M")
  1881     apply (simp, metis order_trans)
  1882     apply (simp, metis order_trans)
  1883     done
  1884 qed
  1885 
  1886 
  1887 text{*Continuity of inverse function*}
  1888 
  1889 lemma isCont_inverse_function:
  1890   fixes f g :: "real \<Rightarrow> real"
  1891   assumes d: "0 < d"
  1892       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1893       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1894   shows "isCont g (f x)"
  1895 proof -
  1896   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1897 
  1898   have f: "continuous_on ?D f"
  1899     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1900   then have g: "continuous_on (f`?D) g"
  1901     using inj by (intro continuous_on_inv) auto
  1902 
  1903   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1904     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1905   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1906     by (rule continuous_on_subset)
  1907   moreover
  1908   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1909     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1910   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1911     by auto
  1912   ultimately
  1913   show ?thesis
  1914     by (simp add: continuous_on_eq_continuous_at)
  1915 qed
  1916 
  1917 lemma isCont_inverse_function2:
  1918   fixes f g :: "real \<Rightarrow> real" shows
  1919   "\<lbrakk>a < x; x < b;
  1920     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1921     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1922    \<Longrightarrow> isCont g (f x)"
  1923 apply (rule isCont_inverse_function
  1924        [where f=f and d="min (x - a) (b - x)"])
  1925 apply (simp_all add: abs_le_iff)
  1926 done
  1927 
  1928 (* need to rename second isCont_inverse *)
  1929 
  1930 lemma isCont_inv_fun:
  1931   fixes f g :: "real \<Rightarrow> real"
  1932   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1933          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1934       ==> isCont g (f x)"
  1935 by (rule isCont_inverse_function)
  1936 
  1937 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1938 lemma LIM_fun_gt_zero:
  1939   fixes f :: "real \<Rightarrow> real"
  1940   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1941 apply (drule (1) LIM_D, clarify)
  1942 apply (rule_tac x = s in exI)
  1943 apply (simp add: abs_less_iff)
  1944 done
  1945 
  1946 lemma LIM_fun_less_zero:
  1947   fixes f :: "real \<Rightarrow> real"
  1948   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1949 apply (drule LIM_D [where r="-l"], simp, clarify)
  1950 apply (rule_tac x = s in exI)
  1951 apply (simp add: abs_less_iff)
  1952 done
  1953 
  1954 lemma LIM_fun_not_zero:
  1955   fixes f :: "real \<Rightarrow> real"
  1956   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1957   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1958 
  1959 end
  1960