src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author wenzelm
Mon Mar 10 23:03:15 2014 +0100 (2014-03-10)
changeset 56043 0b25c3d34b77
parent 56009 dda076a32aea
child 56066 cce36efe32eb
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 header {* Implementation and verification of multivariate polynomials *}
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main Rat_Pair Polynomial_List
     9 begin
    10 
    11 subsection{* Datatype of polynomial expressions *}
    12 
    13 datatype poly = C Num | Bound nat | Add poly poly | Sub poly poly
    14   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    15 
    16 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    17 abbreviation poly_p :: "int \<Rightarrow> poly" ("'((_)')\<^sub>p") where "(i)\<^sub>p \<equiv> C (i)\<^sub>N"
    18 
    19 
    20 subsection{* Boundedness, substitution and all that *}
    21 
    22 primrec polysize:: "poly \<Rightarrow> nat"
    23 where
    24   "polysize (C c) = 1"
    25 | "polysize (Bound n) = 1"
    26 | "polysize (Neg p) = 1 + polysize p"
    27 | "polysize (Add p q) = 1 + polysize p + polysize q"
    28 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    29 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    30 | "polysize (Pw p n) = 1 + polysize p"
    31 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    32 
    33 primrec polybound0:: "poly \<Rightarrow> bool" -- {* a poly is INDEPENDENT of Bound 0 *}
    34 where
    35   "polybound0 (C c) \<longleftrightarrow> True"
    36 | "polybound0 (Bound n) \<longleftrightarrow> n > 0"
    37 | "polybound0 (Neg a) \<longleftrightarrow> polybound0 a"
    38 | "polybound0 (Add a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    39 | "polybound0 (Sub a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    40 | "polybound0 (Mul a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    41 | "polybound0 (Pw p n) \<longleftrightarrow> polybound0 p"
    42 | "polybound0 (CN c n p) \<longleftrightarrow> n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p"
    43 
    44 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" -- {* substitute a poly into a poly for Bound 0 *}
    45 where
    46   "polysubst0 t (C c) = C c"
    47 | "polysubst0 t (Bound n) = (if n = 0 then t else Bound n)"
    48 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    49 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    50 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)"
    51 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    52 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    53 | "polysubst0 t (CN c n p) =
    54     (if n = 0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    55      else CN (polysubst0 t c) n (polysubst0 t p))"
    56 
    57 fun decrpoly:: "poly \<Rightarrow> poly"
    58 where
    59   "decrpoly (Bound n) = Bound (n - 1)"
    60 | "decrpoly (Neg a) = Neg (decrpoly a)"
    61 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    62 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    63 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    64 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    65 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    66 | "decrpoly a = a"
    67 
    68 
    69 subsection{* Degrees and heads and coefficients *}
    70 
    71 fun degree:: "poly \<Rightarrow> nat"
    72 where
    73   "degree (CN c 0 p) = 1 + degree p"
    74 | "degree p = 0"
    75 
    76 fun head:: "poly \<Rightarrow> poly"
    77 where
    78   "head (CN c 0 p) = head p"
    79 | "head p = p"
    80 
    81 (* More general notions of degree and head *)
    82 fun degreen:: "poly \<Rightarrow> nat \<Rightarrow> nat"
    83 where
    84   "degreen (CN c n p) = (\<lambda>m. if n = m then 1 + degreen p n else 0)"
    85 | "degreen p = (\<lambda>m. 0)"
    86 
    87 fun headn:: "poly \<Rightarrow> nat \<Rightarrow> poly"
    88 where
    89   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    90 | "headn p = (\<lambda>m. p)"
    91 
    92 fun coefficients:: "poly \<Rightarrow> poly list"
    93 where
    94   "coefficients (CN c 0 p) = c # coefficients p"
    95 | "coefficients p = [p]"
    96 
    97 fun isconstant:: "poly \<Rightarrow> bool"
    98 where
    99   "isconstant (CN c 0 p) = False"
   100 | "isconstant p = True"
   101 
   102 fun behead:: "poly \<Rightarrow> poly"
   103 where
   104   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   105 | "behead p = 0\<^sub>p"
   106 
   107 fun headconst:: "poly \<Rightarrow> Num"
   108 where
   109   "headconst (CN c n p) = headconst p"
   110 | "headconst (C n) = n"
   111 
   112 
   113 subsection{* Operations for normalization *}
   114 
   115 declare if_cong[fundef_cong del]
   116 declare let_cong[fundef_cong del]
   117 
   118 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   119 where
   120   "polyadd (C c) (C c') = C (c +\<^sub>N c')"
   121 | "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   122 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   123 | "polyadd (CN c n p) (CN c' n' p') =
   124     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   125      else if n' < n then CN (polyadd (CN c n p) c') n' p'
   126      else
   127       let
   128         cc' = polyadd c c';
   129         pp' = polyadd p p'
   130       in if pp' = 0\<^sub>p then cc' else CN cc' n pp')"
   131 | "polyadd a b = Add a b"
   132 
   133 
   134 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   135 where
   136   "polyneg (C c) = C (~\<^sub>N c)"
   137 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   138 | "polyneg a = Neg a"
   139 
   140 definition polysub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   141   where "p -\<^sub>p q = polyadd p (polyneg q)"
   142 
   143 fun polymul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   144 where
   145   "polymul (C c) (C c') = C (c *\<^sub>N c')"
   146 | "polymul (C c) (CN c' n' p') =
   147     (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul (C c) c') n' (polymul (C c) p'))"
   148 | "polymul (CN c n p) (C c') =
   149     (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul c (C c')) n (polymul p (C c')))"
   150 | "polymul (CN c n p) (CN c' n' p') =
   151     (if n < n' then CN (polymul c (CN c' n' p')) n (polymul p (CN c' n' p'))
   152      else if n' < n then CN (polymul (CN c n p) c') n' (polymul (CN c n p) p')
   153      else polyadd (polymul (CN c n p) c') (CN 0\<^sub>p n' (polymul (CN c n p) p')))"
   154 | "polymul a b = Mul a b"
   155 
   156 declare if_cong[fundef_cong]
   157 declare let_cong[fundef_cong]
   158 
   159 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   160 where
   161   "polypow 0 = (\<lambda>p. (1)\<^sub>p)"
   162 | "polypow n =
   163     (\<lambda>p.
   164       let
   165         q = polypow (n div 2) p;
   166         d = polymul q q
   167       in if even n then d else polymul p d)"
   168 
   169 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   170   where "a ^\<^sub>p k \<equiv> polypow k a"
   171 
   172 function polynate :: "poly \<Rightarrow> poly"
   173 where
   174   "polynate (Bound n) = CN 0\<^sub>p n (1)\<^sub>p"
   175 | "polynate (Add p q) = polynate p +\<^sub>p polynate q"
   176 | "polynate (Sub p q) = polynate p -\<^sub>p polynate q"
   177 | "polynate (Mul p q) = polynate p *\<^sub>p polynate q"
   178 | "polynate (Neg p) = ~\<^sub>p (polynate p)"
   179 | "polynate (Pw p n) = polynate p ^\<^sub>p n"
   180 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   181 | "polynate (C c) = C (normNum c)"
   182 by pat_completeness auto
   183 termination by (relation "measure polysize") auto
   184 
   185 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly"
   186 where
   187   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   188 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   189 | "poly_cmul y p = C y *\<^sub>p p"
   190 
   191 definition monic :: "poly \<Rightarrow> poly \<times> bool"
   192 where
   193   "monic p =
   194     (let h = headconst p
   195      in if h = 0\<^sub>N then (p, False) else (C (Ninv h) *\<^sub>p p, 0>\<^sub>N h))"
   196 
   197 
   198 subsection {* Pseudo-division *}
   199 
   200 definition shift1 :: "poly \<Rightarrow> poly"
   201   where "shift1 p = CN 0\<^sub>p 0 p"
   202 
   203 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a"
   204   where "funpow \<equiv> compow"
   205 
   206 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   207 where
   208   "polydivide_aux a n p k s =
   209     (if s = 0\<^sub>p then (k, s)
   210      else
   211       let
   212         b = head s;
   213         m = degree s
   214       in
   215         if m < n then (k,s)
   216         else
   217           let p' = funpow (m - n) shift1 p
   218           in
   219             if a = b then polydivide_aux a n p k (s -\<^sub>p p')
   220             else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))"
   221 
   222 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   223   where "polydivide s p = polydivide_aux (head p) (degree p) p 0 s"
   224 
   225 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   226 where
   227   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   228 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   229 
   230 fun poly_deriv :: "poly \<Rightarrow> poly"
   231 where
   232   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   233 | "poly_deriv p = 0\<^sub>p"
   234 
   235 
   236 subsection{* Semantics of the polynomial representation *}
   237 
   238 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0,field_inverse_zero,power}"
   239 where
   240   "Ipoly bs (C c) = INum c"
   241 | "Ipoly bs (Bound n) = bs!n"
   242 | "Ipoly bs (Neg a) = - Ipoly bs a"
   243 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   244 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   245 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   246 | "Ipoly bs (Pw t n) = Ipoly bs t ^ n"
   247 | "Ipoly bs (CN c n p) = Ipoly bs c + (bs!n) * Ipoly bs p"
   248 
   249 abbreviation Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0,field_inverse_zero,power}"
   250     ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   251   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   252 
   253 lemma Ipoly_CInt: "Ipoly bs (C (i, 1)) = of_int i"
   254   by (simp add: INum_def)
   255 
   256 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j"
   257   by (simp  add: INum_def)
   258 
   259 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   260 
   261 
   262 subsection {* Normal form and normalization *}
   263 
   264 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   265 where
   266   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   267 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> isnpolyh c (Suc n) \<and> isnpolyh p n \<and> p \<noteq> 0\<^sub>p)"
   268 | "isnpolyh p = (\<lambda>k. False)"
   269 
   270 lemma isnpolyh_mono: "n' \<le> n \<Longrightarrow> isnpolyh p n \<Longrightarrow> isnpolyh p n'"
   271   by (induct p rule: isnpolyh.induct) auto
   272 
   273 definition isnpoly :: "poly \<Rightarrow> bool"
   274   where "isnpoly p = isnpolyh p 0"
   275 
   276 text{* polyadd preserves normal forms *}
   277 
   278 lemma polyadd_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   279 proof (induct p q arbitrary: n0 n1 rule: polyadd.induct)
   280   case (2 ab c' n' p' n0 n1)
   281   from 2 have  th1: "isnpolyh (C ab) (Suc n')"
   282     by simp
   283   from 2(3) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   284     by simp_all
   285   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   286     by simp
   287   with 2(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')"
   288     by simp
   289   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   290     by simp
   291   then show ?case using 2 th3
   292     by simp
   293 next
   294   case (3 c' n' p' ab n1 n0)
   295   from 3 have  th1: "isnpolyh (C ab) (Suc n')"
   296     by simp
   297   from 3(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   298     by simp_all
   299   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   300     by simp
   301   with 3(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')"
   302     by simp
   303   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   304     by simp
   305   then show ?case using 3 th3
   306     by simp
   307 next
   308   case (4 c n p c' n' p' n0 n1)
   309   then have nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n"
   310     by simp_all
   311   from 4 have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'"
   312     by simp_all
   313   from 4 have ngen0: "n \<ge> n0"
   314     by simp
   315   from 4 have n'gen1: "n' \<ge> n1"
   316     by simp
   317   have "n < n' \<or> n' < n \<or> n = n'"
   318     by auto
   319   moreover
   320   {
   321     assume eq: "n = n'"
   322     with "4.hyps"(3)[OF nc nc']
   323     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)"
   324       by auto
   325     then have ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   326       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1
   327       by auto
   328     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n"
   329       by simp
   330     have minle: "min n0 n1 \<le> n'"
   331       using ngen0 n'gen1 eq by simp
   332     from minle npp' ncc'n01 4 eq ngen0 n'gen1 ncc' have ?case
   333       by (simp add: Let_def)
   334   }
   335   moreover
   336   {
   337     assume lt: "n < n'"
   338     have "min n0 n1 \<le> n0"
   339       by simp
   340     with 4 lt have th1:"min n0 n1 \<le> n"
   341       by auto
   342     from 4 have th21: "isnpolyh c (Suc n)"
   343       by simp
   344     from 4 have th22: "isnpolyh (CN c' n' p') n'"
   345       by simp
   346     from lt have th23: "min (Suc n) n' = Suc n"
   347       by arith
   348     from "4.hyps"(1)[OF th21 th22] have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)"
   349       using th23 by simp
   350     with 4 lt th1 have ?case
   351       by simp
   352   }
   353   moreover
   354   {
   355     assume gt: "n' < n"
   356     then have gt': "n' < n \<and> \<not> n < n'"
   357       by simp
   358     have "min n0 n1 \<le> n1"
   359       by simp
   360     with 4 gt have th1: "min n0 n1 \<le> n'"
   361       by auto
   362     from 4 have th21: "isnpolyh c' (Suc n')"
   363       by simp_all
   364     from 4 have th22: "isnpolyh (CN c n p) n"
   365       by simp
   366     from gt have th23: "min n (Suc n') = Suc n'"
   367       by arith
   368     from "4.hyps"(2)[OF th22 th21] have "isnpolyh (polyadd (CN c n p) c') (Suc n')"
   369       using th23 by simp
   370     with 4 gt th1 have ?case
   371       by simp
   372   }
   373   ultimately show ?case by blast
   374 qed auto
   375 
   376 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   377   by (induct p q rule: polyadd.induct)
   378     (auto simp add: Let_def field_simps distrib_left[symmetric] simp del: distrib_left)
   379 
   380 lemma polyadd_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polyadd p q)"
   381   using polyadd_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   382 
   383 text{* The degree of addition and other general lemmas needed for the normal form of polymul *}
   384 
   385 lemma polyadd_different_degreen:
   386   assumes "isnpolyh p n0"
   387     and "isnpolyh q n1"
   388     and "degreen p m \<noteq> degreen q m"
   389     and "m \<le> min n0 n1"
   390   shows "degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   391   using assms
   392 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   393   case (4 c n p c' n' p' m n0 n1)
   394   have "n' = n \<or> n < n' \<or> n' < n" by arith
   395   then show ?case
   396   proof (elim disjE)
   397     assume [simp]: "n' = n"
   398     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   399     show ?thesis by (auto simp: Let_def)
   400   next
   401     assume "n < n'"
   402     with 4 show ?thesis by auto
   403   next
   404     assume "n' < n"
   405     with 4 show ?thesis by auto
   406   qed
   407 qed auto
   408 
   409 lemma headnz[simp]: "isnpolyh p n \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   410   by (induct p arbitrary: n rule: headn.induct) auto
   411 
   412 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   413   by (induct p arbitrary: n rule: degree.induct) auto
   414 
   415 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   416   by (induct p arbitrary: n rule: degreen.induct) auto
   417 
   418 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   419   by (induct p arbitrary: n rule: degree.induct) auto
   420 
   421 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   422   using degree_isnpolyh_Suc by auto
   423 
   424 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   425   using degreen_0 by auto
   426 
   427 
   428 lemma degreen_polyadd:
   429   assumes np: "isnpolyh p n0"
   430     and nq: "isnpolyh q n1"
   431     and m: "m \<le> max n0 n1"
   432   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   433   using np nq m
   434 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   435   case (2 c c' n' p' n0 n1)
   436   then show ?case
   437     by (cases n') simp_all
   438 next
   439   case (3 c n p c' n0 n1)
   440   then show ?case
   441     by (cases n) auto
   442 next
   443   case (4 c n p c' n' p' n0 n1 m)
   444   have "n' = n \<or> n < n' \<or> n' < n" by arith
   445   then show ?case
   446   proof (elim disjE)
   447     assume [simp]: "n' = n"
   448     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   449     show ?thesis by (auto simp: Let_def)
   450   qed simp_all
   451 qed auto
   452 
   453 lemma polyadd_eq_const_degreen:
   454   assumes "isnpolyh p n0"
   455     and "isnpolyh q n1"
   456     and "polyadd p q = C c"
   457   shows "degreen p m = degreen q m"
   458   using assms
   459 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   460   case (4 c n p c' n' p' m n0 n1 x)
   461   {
   462     assume nn': "n' < n"
   463     then have ?case using 4 by simp
   464   }
   465   moreover
   466   {
   467     assume nn': "\<not> n' < n"
   468     then have "n < n' \<or> n = n'" by arith
   469     moreover { assume "n < n'" with 4 have ?case by simp }
   470     moreover
   471     {
   472       assume eq: "n = n'"
   473       then have ?case using 4
   474         apply (cases "p +\<^sub>p p' = 0\<^sub>p")
   475         apply (auto simp add: Let_def)
   476         apply blast
   477         done
   478     }
   479     ultimately have ?case by blast
   480   }
   481   ultimately show ?case by blast
   482 qed simp_all
   483 
   484 lemma polymul_properties:
   485   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   486     and np: "isnpolyh p n0"
   487     and nq: "isnpolyh q n1"
   488     and m: "m \<le> min n0 n1"
   489   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)"
   490     and "p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   491     and "degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   492   using np nq m
   493 proof (induct p q arbitrary: n0 n1 m rule: polymul.induct)
   494   case (2 c c' n' p')
   495   {
   496     case (1 n0 n1)
   497     with "2.hyps"(4-6)[of n' n' n'] and "2.hyps"(1-3)[of "Suc n'" "Suc n'" n']
   498     show ?case by (auto simp add: min_def)
   499   next
   500     case (2 n0 n1)
   501     then show ?case by auto
   502   next
   503     case (3 n0 n1)
   504     then show ?case  using "2.hyps" by auto
   505   }
   506 next
   507   case (3 c n p c')
   508   {
   509     case (1 n0 n1)
   510     with "3.hyps"(4-6)[of n n n] and "3.hyps"(1-3)[of "Suc n" "Suc n" n]
   511     show ?case by (auto simp add: min_def)
   512   next
   513     case (2 n0 n1)
   514     then show ?case by auto
   515   next
   516     case (3 n0 n1)
   517     then show ?case  using "3.hyps" by auto
   518   }
   519 next
   520   case (4 c n p c' n' p')
   521   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   522   {
   523     case (1 n0 n1)
   524     then have cnp: "isnpolyh ?cnp n"
   525       and cnp': "isnpolyh ?cnp' n'"
   526       and np: "isnpolyh p n"
   527       and nc: "isnpolyh c (Suc n)"
   528       and np': "isnpolyh p' n'"
   529       and nc': "isnpolyh c' (Suc n')"
   530       and nn0: "n \<ge> n0"
   531       and nn1: "n' \<ge> n1"
   532       by simp_all
   533     {
   534       assume "n < n'"
   535       with "4.hyps"(4-5)[OF np cnp', of n] and "4.hyps"(1)[OF nc cnp', of n] nn0 cnp
   536       have ?case by (simp add: min_def)
   537     } moreover {
   538       assume "n' < n"
   539       with "4.hyps"(16-17)[OF cnp np', of "n'"] and "4.hyps"(13)[OF cnp nc', of "Suc n'"] nn1 cnp'
   540       have ?case by (cases "Suc n' = n") (simp_all add: min_def)
   541     } moreover {
   542       assume "n' = n"
   543       with "4.hyps"(16-17)[OF cnp np', of n] and "4.hyps"(13)[OF cnp nc', of n] cnp cnp' nn1 nn0
   544       have ?case
   545         apply (auto intro!: polyadd_normh)
   546         apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   547         done
   548     }
   549     ultimately show ?case by arith
   550   next
   551     fix n0 n1 m
   552     assume np: "isnpolyh ?cnp n0"
   553     assume np':"isnpolyh ?cnp' n1"
   554     assume m: "m \<le> min n0 n1"
   555     let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   556     let ?d1 = "degreen ?cnp m"
   557     let ?d2 = "degreen ?cnp' m"
   558     let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   559     have "n' < n \<or> n < n' \<or> n' = n" by auto
   560     moreover
   561     {
   562       assume "n' < n \<or> n < n'"
   563       with "4.hyps"(3,6,18) np np' m have ?eq
   564         by auto
   565     }
   566     moreover
   567     {
   568       assume nn': "n' = n"
   569       then have nn: "\<not> n' < n \<and> \<not> n < n'" by arith
   570       from "4.hyps"(16,18)[of n n' n]
   571         "4.hyps"(13,14)[of n "Suc n'" n]
   572         np np' nn'
   573       have norm:
   574         "isnpolyh ?cnp n"
   575         "isnpolyh c' (Suc n)"
   576         "isnpolyh (?cnp *\<^sub>p c') n"
   577         "isnpolyh p' n"
   578         "isnpolyh (?cnp *\<^sub>p p') n"
   579         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   580         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   581         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   582         by (auto simp add: min_def)
   583       {
   584         assume mn: "m = n"
   585         from "4.hyps"(17,18)[OF norm(1,4), of n]
   586           "4.hyps"(13,15)[OF norm(1,2), of n] norm nn' mn
   587         have degs:
   588           "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else ?d1 + degreen c' n)"
   589           "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n"
   590           by (simp_all add: min_def)
   591         from degs norm have th1: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   592           by simp
   593         then have neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   594           by simp
   595         have nmin: "n \<le> min n n"
   596           by (simp add: min_def)
   597         from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   598         have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n =
   599             degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   600           by simp
   601         from "4.hyps"(16-18)[OF norm(1,4), of n]
   602           "4.hyps"(13-15)[OF norm(1,2), of n]
   603           mn norm m nn' deg
   604         have ?eq by simp
   605       }
   606       moreover
   607       {
   608         assume mn: "m \<noteq> n"
   609         then have mn': "m < n"
   610           using m np by auto
   611         from nn' m np have max1: "m \<le> max n n"
   612           by simp
   613         then have min1: "m \<le> min n n"
   614           by simp
   615         then have min2: "m \<le> min n (Suc n)"
   616           by simp
   617         from "4.hyps"(16-18)[OF norm(1,4) min1]
   618           "4.hyps"(13-15)[OF norm(1,2) min2]
   619           degreen_polyadd[OF norm(3,6) max1]
   620         have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m \<le>
   621             max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   622           using mn nn' np np' by simp
   623         with "4.hyps"(16-18)[OF norm(1,4) min1]
   624           "4.hyps"(13-15)[OF norm(1,2) min2]
   625           degreen_0[OF norm(3) mn']
   626         have ?eq using nn' mn np np' by clarsimp
   627       }
   628       ultimately have ?eq by blast
   629     }
   630     ultimately show ?eq by blast
   631   }
   632   {
   633     case (2 n0 n1)
   634     then have np: "isnpolyh ?cnp n0"
   635       and np': "isnpolyh ?cnp' n1"
   636       and m: "m \<le> min n0 n1"
   637       by simp_all
   638     then have mn: "m \<le> n" by simp
   639     let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   640     {
   641       assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   642       then have nn: "\<not> n' < n \<and> \<not> n < n'"
   643         by simp
   644       from "4.hyps"(16-18) [of n n n]
   645         "4.hyps"(13-15)[of n "Suc n" n]
   646         np np' C(2) mn
   647       have norm:
   648         "isnpolyh ?cnp n"
   649         "isnpolyh c' (Suc n)"
   650         "isnpolyh (?cnp *\<^sub>p c') n"
   651         "isnpolyh p' n"
   652         "isnpolyh (?cnp *\<^sub>p p') n"
   653         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   654         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   655         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   656         "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   657         "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   658         by (simp_all add: min_def)
   659       from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   660         by simp
   661       have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   662         using norm by simp
   663       from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"] degneq
   664       have False by simp
   665     }
   666     then show ?case using "4.hyps" by clarsimp
   667   }
   668 qed auto
   669 
   670 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = Ipoly bs p * Ipoly bs q"
   671   by (induct p q rule: polymul.induct) (auto simp add: field_simps)
   672 
   673 lemma polymul_normh:
   674   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   675   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   676   using polymul_properties(1) by blast
   677 
   678 lemma polymul_eq0_iff:
   679   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   680   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   681   using polymul_properties(2) by blast
   682 
   683 lemma polymul_degreen:  (* FIXME duplicate? *)
   684   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   685   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> m \<le> min n0 n1 \<Longrightarrow>
   686     degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   687   using polymul_properties(3) by blast
   688 
   689 lemma polymul_norm:
   690   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   691   shows "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polymul p q)"
   692   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   693 
   694 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   695   by (induct p arbitrary: n0 rule: headconst.induct) auto
   696 
   697 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   698   by (induct p arbitrary: n0) auto
   699 
   700 lemma monic_eqI:
   701   assumes np: "isnpolyh p n0"
   702   shows "INum (headconst p) * Ipoly bs (fst (monic p)) =
   703     (Ipoly bs p ::'a::{field_char_0,field_inverse_zero, power})"
   704   unfolding monic_def Let_def
   705 proof (cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   706   let ?h = "headconst p"
   707   assume pz: "p \<noteq> 0\<^sub>p"
   708   {
   709     assume hz: "INum ?h = (0::'a)"
   710     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N"
   711       by simp_all
   712     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N"
   713       by simp
   714     with headconst_zero[OF np] have "p = 0\<^sub>p"
   715       by blast
   716     with pz have False
   717       by blast
   718   }
   719   then show "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
   720     by blast
   721 qed
   722 
   723 
   724 text{* polyneg is a negation and preserves normal forms *}
   725 
   726 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   727   by (induct p rule: polyneg.induct) auto
   728 
   729 lemma polyneg0: "isnpolyh p n \<Longrightarrow> (~\<^sub>p p) = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   730   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: Nneg_def)
   731 
   732 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   733   by (induct p arbitrary: n0 rule: polyneg.induct) auto
   734 
   735 lemma polyneg_normh: "isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n"
   736   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: polyneg0)
   737 
   738 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   739   using isnpoly_def polyneg_normh by simp
   740 
   741 
   742 text{* polysub is a substraction and preserves normal forms *}
   743 
   744 lemma polysub[simp]: "Ipoly bs (polysub p q) = Ipoly bs p - Ipoly bs q"
   745   by (simp add: polysub_def)
   746 
   747 lemma polysub_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polysub p q) (min n0 n1)"
   748   by (simp add: polysub_def polyneg_normh polyadd_normh)
   749 
   750 lemma polysub_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polysub p q)"
   751   using polyadd_norm polyneg_norm by (simp add: polysub_def)
   752 
   753 lemma polysub_same_0[simp]:
   754   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   755   shows "isnpolyh p n0 \<Longrightarrow> polysub p p = 0\<^sub>p"
   756   unfolding polysub_def split_def fst_conv snd_conv
   757   by (induct p arbitrary: n0) (auto simp add: Let_def Nsub0[simplified Nsub_def])
   758 
   759 lemma polysub_0:
   760   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   761   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p -\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = q"
   762   unfolding polysub_def split_def fst_conv snd_conv
   763   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   764     (auto simp: Nsub0[simplified Nsub_def] Let_def)
   765 
   766 text{* polypow is a power function and preserves normal forms *}
   767 
   768 lemma polypow[simp]:
   769   "Ipoly bs (polypow n p) = (Ipoly bs p :: 'a::{field_char_0,field_inverse_zero}) ^ n"
   770 proof (induct n rule: polypow.induct)
   771   case 1
   772   then show ?case
   773     by simp
   774 next
   775   case (2 n)
   776   let ?q = "polypow ((Suc n) div 2) p"
   777   let ?d = "polymul ?q ?q"
   778   have "odd (Suc n) \<or> even (Suc n)"
   779     by simp
   780   moreover
   781   {
   782     assume odd: "odd (Suc n)"
   783     have th: "(Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0)))) = Suc n div 2 + Suc n div 2 + 1"
   784       by arith
   785     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul p ?d)"
   786       by (simp add: Let_def)
   787     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2) * (Ipoly bs p)^(Suc n div 2)"
   788       using "2.hyps" by simp
   789     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   790       by (simp only: power_add power_one_right) simp
   791     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0))))"
   792       by (simp only: th)
   793     finally have ?case
   794     using odd_nat_div_two_times_two_plus_one[OF odd, symmetric] by simp
   795   }
   796   moreover
   797   {
   798     assume even: "even (Suc n)"
   799     have th: "(Suc (Suc 0)) * (Suc n div Suc (Suc 0)) = Suc n div 2 + Suc n div 2"
   800       by arith
   801     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d"
   802       by (simp add: Let_def)
   803     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2)"
   804       using "2.hyps" by (simp only: power_add) simp
   805     finally have ?case using even_nat_div_two_times_two[OF even]
   806       by (simp only: th)
   807   }
   808   ultimately show ?case by blast
   809 qed
   810 
   811 lemma polypow_normh:
   812   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   813   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   814 proof (induct k arbitrary: n rule: polypow.induct)
   815   case 1
   816   then show ?case by auto
   817 next
   818   case (2 k n)
   819   let ?q = "polypow (Suc k div 2) p"
   820   let ?d = "polymul ?q ?q"
   821   from 2 have th1: "isnpolyh ?q n" and th2: "isnpolyh p n"
   822     by blast+
   823   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n"
   824     by simp
   825   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul p ?d) n"
   826     by simp
   827   from dn on show ?case
   828     by (simp add: Let_def)
   829 qed
   830 
   831 lemma polypow_norm:
   832   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   833   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   834   by (simp add: polypow_normh isnpoly_def)
   835 
   836 text{* Finally the whole normalization *}
   837 
   838 lemma polynate [simp]:
   839   "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0,field_inverse_zero})"
   840   by (induct p rule:polynate.induct) auto
   841 
   842 lemma polynate_norm[simp]:
   843   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   844   shows "isnpoly (polynate p)"
   845   by (induct p rule: polynate.induct)
   846      (simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm,
   847       simp_all add: isnpoly_def)
   848 
   849 text{* shift1 *}
   850 
   851 
   852 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   853   by (simp add: shift1_def)
   854 
   855 lemma shift1_isnpoly:
   856   assumes pn: "isnpoly p"
   857     and pnz: "p \<noteq> 0\<^sub>p"
   858   shows "isnpoly (shift1 p) "
   859   using pn pnz by (simp add: shift1_def isnpoly_def)
   860 
   861 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   862   by (simp add: shift1_def)
   863 
   864 lemma funpow_shift1_isnpoly: "isnpoly p \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpoly (funpow n shift1 p)"
   865   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   866 
   867 lemma funpow_isnpolyh:
   868   assumes f: "\<And>p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n"
   869     and np: "isnpolyh p n"
   870   shows "isnpolyh (funpow k f p) n"
   871   using f np by (induct k arbitrary: p) auto
   872 
   873 lemma funpow_shift1:
   874   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   875     Ipoly bs (Mul (Pw (Bound 0) n) p)"
   876   by (induct n arbitrary: p) (simp_all add: shift1_isnpoly shift1)
   877 
   878 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   879   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   880 
   881 lemma funpow_shift1_1:
   882   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   883     Ipoly bs (funpow n shift1 (1)\<^sub>p *\<^sub>p p)"
   884   by (simp add: funpow_shift1)
   885 
   886 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   887   by (induct p rule: poly_cmul.induct) (auto simp add: field_simps)
   888 
   889 lemma behead:
   890   assumes np: "isnpolyh p n"
   891   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) =
   892     (Ipoly bs p :: 'a :: {field_char_0,field_inverse_zero})"
   893   using np
   894 proof (induct p arbitrary: n rule: behead.induct)
   895   case (1 c p n)
   896   then have pn: "isnpolyh p n" by simp
   897   from 1(1)[OF pn]
   898   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" .
   899   then show ?case using "1.hyps"
   900     apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   901     apply (simp_all add: th[symmetric] field_simps)
   902     done
   903 qed (auto simp add: Let_def)
   904 
   905 lemma behead_isnpolyh:
   906   assumes np: "isnpolyh p n"
   907   shows "isnpolyh (behead p) n"
   908   using np by (induct p rule: behead.induct) (auto simp add: Let_def isnpolyh_mono)
   909 
   910 
   911 subsection{* Miscellaneous lemmas about indexes, decrementation, substitution  etc ... *}
   912 
   913 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   914 proof (induct p arbitrary: n rule: poly.induct, auto)
   915   case (goal1 c n p n')
   916   then have "n = Suc (n - 1)"
   917     by simp
   918   then have "isnpolyh p (Suc (n - 1))"
   919     using `isnpolyh p n` by simp
   920   with goal1(2) show ?case
   921     by simp
   922 qed
   923 
   924 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   925   by (induct p arbitrary: n0 rule: isconstant.induct) (auto simp add: isnpolyh_polybound0)
   926 
   927 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   928   by (induct p) auto
   929 
   930 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   931   apply (induct p arbitrary: n0)
   932   apply auto
   933   apply atomize
   934   apply (erule_tac x = "Suc nat" in allE)
   935   apply auto
   936   done
   937 
   938 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   939   by (induct p  arbitrary: n0 rule: head.induct) (auto intro: isnpolyh_polybound0)
   940 
   941 lemma polybound0_I:
   942   assumes nb: "polybound0 a"
   943   shows "Ipoly (b # bs) a = Ipoly (b' # bs) a"
   944   using nb
   945   by (induct a rule: poly.induct) auto
   946 
   947 lemma polysubst0_I: "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b # bs) a) # bs) t"
   948   by (induct t) simp_all
   949 
   950 lemma polysubst0_I':
   951   assumes nb: "polybound0 a"
   952   shows "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b' # bs) a) # bs) t"
   953   by (induct t) (simp_all add: polybound0_I[OF nb, where b="b" and b'="b'"])
   954 
   955 lemma decrpoly:
   956   assumes nb: "polybound0 t"
   957   shows "Ipoly (x # bs) t = Ipoly bs (decrpoly t)"
   958   using nb by (induct t rule: decrpoly.induct) simp_all
   959 
   960 lemma polysubst0_polybound0:
   961   assumes nb: "polybound0 t"
   962   shows "polybound0 (polysubst0 t a)"
   963   using nb by (induct a rule: poly.induct) auto
   964 
   965 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   966   by (induct p arbitrary: n rule: degree.induct) (auto simp add: isnpolyh_polybound0)
   967 
   968 primrec maxindex :: "poly \<Rightarrow> nat"
   969 where
   970   "maxindex (Bound n) = n + 1"
   971 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   972 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   973 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   974 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   975 | "maxindex (Neg p) = maxindex p"
   976 | "maxindex (Pw p n) = maxindex p"
   977 | "maxindex (C x) = 0"
   978 
   979 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool"
   980   where "wf_bs bs p \<longleftrightarrow> length bs \<ge> maxindex p"
   981 
   982 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall>c \<in> set (coefficients p). wf_bs bs c"
   983 proof (induct p rule: coefficients.induct)
   984   case (1 c p)
   985   show ?case
   986   proof
   987     fix x
   988     assume xc: "x \<in> set (coefficients (CN c 0 p))"
   989     then have "x = c \<or> x \<in> set (coefficients p)"
   990       by simp
   991     moreover
   992     {
   993       assume "x = c"
   994       then have "wf_bs bs x"
   995         using "1.prems" unfolding wf_bs_def by simp
   996     }
   997     moreover
   998     {
   999       assume H: "x \<in> set (coefficients p)"
  1000       from "1.prems" have "wf_bs bs p"
  1001         unfolding wf_bs_def by simp
  1002       with "1.hyps" H have "wf_bs bs x"
  1003         by blast
  1004     }
  1005     ultimately  show "wf_bs bs x"
  1006       by blast
  1007   qed
  1008 qed simp_all
  1009 
  1010 lemma maxindex_coefficients: "\<forall>c \<in> set (coefficients p). maxindex c \<le> maxindex p"
  1011   by (induct p rule: coefficients.induct) auto
  1012 
  1013 lemma wf_bs_I: "wf_bs bs p \<Longrightarrow> Ipoly (bs @ bs') p = Ipoly bs p"
  1014   unfolding wf_bs_def by (induct p) (auto simp add: nth_append)
  1015 
  1016 lemma take_maxindex_wf:
  1017   assumes wf: "wf_bs bs p"
  1018   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
  1019 proof -
  1020   let ?ip = "maxindex p"
  1021   let ?tbs = "take ?ip bs"
  1022   from wf have "length ?tbs = ?ip"
  1023     unfolding wf_bs_def by simp
  1024   then have wf': "wf_bs ?tbs p"
  1025     unfolding wf_bs_def by  simp
  1026   have eq: "bs = ?tbs @ drop ?ip bs"
  1027     by simp
  1028   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis
  1029     using eq by simp
  1030 qed
  1031 
  1032 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
  1033   by (induct p) auto
  1034 
  1035 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
  1036   unfolding wf_bs_def by simp
  1037 
  1038 lemma wf_bs_insensitive': "wf_bs (x#bs) p = wf_bs (y#bs) p"
  1039   unfolding wf_bs_def by simp
  1040 
  1041 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x#bs) p"
  1042   by (induct p rule: coefficients.induct) (auto simp add: wf_bs_def)
  1043 
  1044 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
  1045   by (induct p rule: coefficients.induct) simp_all
  1046 
  1047 lemma coefficients_head: "last (coefficients p) = head p"
  1048   by (induct p rule: coefficients.induct) auto
  1049 
  1050 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x#bs) p"
  1051   unfolding wf_bs_def by (induct p rule: decrpoly.induct) auto
  1052 
  1053 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists>ys. length (xs @ ys) = n"
  1054   apply (rule exI[where x="replicate (n - length xs) z"])
  1055   apply simp
  1056   done
  1057 
  1058 lemma isnpolyh_Suc_const: "isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
  1059   apply (cases p)
  1060   apply auto
  1061   apply (case_tac "nat")
  1062   apply simp_all
  1063   done
  1064 
  1065 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
  1066   unfolding wf_bs_def
  1067   apply (induct p q rule: polyadd.induct)
  1068   apply (auto simp add: Let_def)
  1069   done
  1070 
  1071 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
  1072   unfolding wf_bs_def
  1073   apply (induct p q arbitrary: bs rule: polymul.induct)
  1074   apply (simp_all add: wf_bs_polyadd)
  1075   apply clarsimp
  1076   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
  1077   apply auto
  1078   done
  1079 
  1080 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
  1081   unfolding wf_bs_def by (induct p rule: polyneg.induct) auto
  1082 
  1083 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
  1084   unfolding polysub_def split_def fst_conv snd_conv
  1085   using wf_bs_polyadd wf_bs_polyneg by blast
  1086 
  1087 
  1088 subsection {* Canonicity of polynomial representation, see lemma isnpolyh_unique *}
  1089 
  1090 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
  1091 definition "polypoly' bs p = map (Ipoly bs \<circ> decrpoly) (coefficients p)"
  1092 definition "poly_nate bs p = map (Ipoly bs \<circ> decrpoly) (coefficients (polynate p))"
  1093 
  1094 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall>q \<in> set (coefficients p). isnpolyh q n0"
  1095 proof (induct p arbitrary: n0 rule: coefficients.induct)
  1096   case (1 c p n0)
  1097   have cp: "isnpolyh (CN c 0 p) n0"
  1098     by fact
  1099   then have norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
  1100     by (auto simp add: isnpolyh_mono[where n'=0])
  1101   from "1.hyps"[OF norm(2)] norm(1) norm(4) show ?case
  1102     by simp
  1103 qed auto
  1104 
  1105 lemma coefficients_isconst: "isnpolyh p n \<Longrightarrow> \<forall>q \<in> set (coefficients p). isconstant q"
  1106   by (induct p arbitrary: n rule: coefficients.induct) (auto simp add: isnpolyh_Suc_const)
  1107 
  1108 lemma polypoly_polypoly':
  1109   assumes np: "isnpolyh p n0"
  1110   shows "polypoly (x # bs) p = polypoly' bs p"
  1111 proof -
  1112   let ?cf = "set (coefficients p)"
  1113   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
  1114   {
  1115     fix q
  1116     assume q: "q \<in> ?cf"
  1117     from q cn_norm have th: "isnpolyh q n0"
  1118       by blast
  1119     from coefficients_isconst[OF np] q have "isconstant q"
  1120       by blast
  1121     with isconstant_polybound0[OF th] have "polybound0 q"
  1122       by blast
  1123   }
  1124   then have "\<forall>q \<in> ?cf. polybound0 q" ..
  1125   then have "\<forall>q \<in> ?cf. Ipoly (x # bs) q = Ipoly bs (decrpoly q)"
  1126     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
  1127     by auto
  1128   then show ?thesis
  1129     unfolding polypoly_def polypoly'_def by simp
  1130 qed
  1131 
  1132 lemma polypoly_poly:
  1133   assumes "isnpolyh p n0"
  1134   shows "Ipoly (x # bs) p = poly (polypoly (x # bs) p) x"
  1135   using assms
  1136   by (induct p arbitrary: n0 bs rule: coefficients.induct) (auto simp add: polypoly_def)
  1137 
  1138 lemma polypoly'_poly:
  1139   assumes "isnpolyh p n0"
  1140   shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
  1141   using polypoly_poly[OF assms, simplified polypoly_polypoly'[OF assms]] .
  1142 
  1143 
  1144 lemma polypoly_poly_polybound0:
  1145   assumes "isnpolyh p n0"
  1146     and "polybound0 p"
  1147   shows "polypoly bs p = [Ipoly bs p]"
  1148   using assms
  1149   unfolding polypoly_def
  1150   apply (cases p)
  1151   apply auto
  1152   apply (case_tac nat)
  1153   apply auto
  1154   done
  1155 
  1156 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0"
  1157   by (induct p rule: head.induct) auto
  1158 
  1159 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> headn p m = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1160   by (cases p) auto
  1161 
  1162 lemma head_eq_headn0: "head p = headn p 0"
  1163   by (induct p rule: head.induct) simp_all
  1164 
  1165 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> head p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1166   by (simp add: head_eq_headn0)
  1167 
  1168 lemma isnpolyh_zero_iff:
  1169   assumes nq: "isnpolyh p n0"
  1170     and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0,field_inverse_zero, power})"
  1171   shows "p = 0\<^sub>p"
  1172   using nq eq
  1173 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
  1174   case less
  1175   note np = `isnpolyh p n0` and zp = `\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)`
  1176   {
  1177     assume nz: "maxindex p = 0"
  1178     then obtain c where "p = C c"
  1179       using np by (cases p) auto
  1180     with zp np have "p = 0\<^sub>p"
  1181       unfolding wf_bs_def by simp
  1182   }
  1183   moreover
  1184   {
  1185     assume nz: "maxindex p \<noteq> 0"
  1186     let ?h = "head p"
  1187     let ?hd = "decrpoly ?h"
  1188     let ?ihd = "maxindex ?hd"
  1189     from head_isnpolyh[OF np] head_polybound0[OF np]
  1190     have h: "isnpolyh ?h n0" "polybound0 ?h"
  1191       by simp_all
  1192     then have nhd: "isnpolyh ?hd (n0 - 1)"
  1193       using decrpoly_normh by blast
  1194 
  1195     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
  1196     have mihn: "maxindex ?h \<le> maxindex p"
  1197       by auto
  1198     with decr_maxindex[OF h(2)] nz have ihd_lt_n: "?ihd < maxindex p"
  1199       by auto
  1200     {
  1201       fix bs :: "'a list"
  1202       assume bs: "wf_bs bs ?hd"
  1203       let ?ts = "take ?ihd bs"
  1204       let ?rs = "drop ?ihd bs"
  1205       have ts: "wf_bs ?ts ?hd"
  1206         using bs unfolding wf_bs_def by simp
  1207       have bs_ts_eq: "?ts @ ?rs = bs"
  1208         by simp
  1209       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x # ?ts) ?h"
  1210         by simp
  1211       from ihd_lt_n have "\<forall>x. length (x # ?ts) \<le> maxindex p"
  1212         by simp
  1213       with length_le_list_ex obtain xs where xs: "length ((x # ?ts) @ xs) = maxindex p"
  1214         by blast
  1215       then have "\<forall>x. wf_bs ((x # ?ts) @ xs) p"
  1216         unfolding wf_bs_def by simp
  1217       with zp have "\<forall>x. Ipoly ((x # ?ts) @ xs) p = 0"
  1218         by blast
  1219       then have "\<forall>x. Ipoly (x # (?ts @ xs)) p = 0"
  1220         by simp
  1221       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
  1222       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"
  1223         by simp
  1224       then have "poly (polypoly' (?ts @ xs) p) = poly []"
  1225         by auto
  1226       then have "\<forall>c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
  1227         using poly_zero[where ?'a='a] by (simp add: polypoly'_def list_all_iff)
  1228       with coefficients_head[of p, symmetric]
  1229       have th0: "Ipoly (?ts @ xs) ?hd = 0"
  1230         by simp
  1231       from bs have wf'': "wf_bs ?ts ?hd"
  1232         unfolding wf_bs_def by simp
  1233       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0"
  1234         by simp
  1235       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
  1236         by simp
  1237     }
  1238     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1239       by blast
  1240     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p"
  1241       by blast
  1242     then have "?h = 0\<^sub>p" by simp
  1243     with head_nz[OF np] have "p = 0\<^sub>p" by simp
  1244   }
  1245   ultimately show "p = 0\<^sub>p"
  1246     by blast
  1247 qed
  1248 
  1249 lemma isnpolyh_unique:
  1250   assumes np: "isnpolyh p n0"
  1251     and nq: "isnpolyh q n1"
  1252   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0,field_inverse_zero,power})) \<longleftrightarrow> p = q"
  1253 proof auto
  1254   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a) = \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
  1255   then have "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)"
  1256     by simp
  1257   then have "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1258     using wf_bs_polysub[where p=p and q=q] by auto
  1259   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq] show "p = q"
  1260     by blast
  1261 qed
  1262 
  1263 
  1264 text{* consequences of unicity on the algorithms for polynomial normalization *}
  1265 
  1266 lemma polyadd_commute:
  1267   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1268     and np: "isnpolyh p n0"
  1269     and nq: "isnpolyh q n1"
  1270   shows "p +\<^sub>p q = q +\<^sub>p p"
  1271   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]]
  1272   by simp
  1273 
  1274 lemma zero_normh: "isnpolyh 0\<^sub>p n"
  1275   by simp
  1276 
  1277 lemma one_normh: "isnpolyh (1)\<^sub>p n"
  1278   by simp
  1279 
  1280 lemma polyadd_0[simp]:
  1281   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1282     and np: "isnpolyh p n0"
  1283   shows "p +\<^sub>p 0\<^sub>p = p"
  1284     and "0\<^sub>p +\<^sub>p p = p"
  1285   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np]
  1286     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1287 
  1288 lemma polymul_1[simp]:
  1289   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1290     and np: "isnpolyh p n0"
  1291   shows "p *\<^sub>p (1)\<^sub>p = p"
  1292     and "(1)\<^sub>p *\<^sub>p p = p"
  1293   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np]
  1294     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1295 
  1296 lemma polymul_0[simp]:
  1297   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1298     and np: "isnpolyh p n0"
  1299   shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p"
  1300     and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1301   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh]
  1302     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1303 
  1304 lemma polymul_commute:
  1305   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1306     and np: "isnpolyh p n0"
  1307     and nq: "isnpolyh q n1"
  1308   shows "p *\<^sub>p q = q *\<^sub>p p"
  1309   using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np],
  1310     where ?'a = "'a::{field_char_0,field_inverse_zero, power}"]
  1311   by simp
  1312 
  1313 declare polyneg_polyneg [simp]
  1314 
  1315 lemma isnpolyh_polynate_id [simp]:
  1316   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1317     and np: "isnpolyh p n0"
  1318   shows "polynate p = p"
  1319   using isnpolyh_unique[where ?'a= "'a::{field_char_0,field_inverse_zero}",
  1320       OF polynate_norm[of p, unfolded isnpoly_def] np]
  1321     polynate[where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1322   by simp
  1323 
  1324 lemma polynate_idempotent[simp]:
  1325   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1326   shows "polynate (polynate p) = polynate p"
  1327   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1328 
  1329 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1330   unfolding poly_nate_def polypoly'_def ..
  1331 
  1332 lemma poly_nate_poly:
  1333   "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0,field_inverse_zero}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1334   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1335   unfolding poly_nate_polypoly' by auto
  1336 
  1337 
  1338 subsection{* heads, degrees and all that *}
  1339 
  1340 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1341   by (induct p rule: degree.induct) simp_all
  1342 
  1343 lemma degree_polyneg:
  1344   assumes "isnpolyh p n"
  1345   shows "degree (polyneg p) = degree p"
  1346   apply (induct p rule: polyneg.induct)
  1347   using assms
  1348   apply simp_all
  1349   apply (case_tac na)
  1350   apply auto
  1351   done
  1352 
  1353 lemma degree_polyadd:
  1354   assumes np: "isnpolyh p n0"
  1355     and nq: "isnpolyh q n1"
  1356   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1357   using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1358 
  1359 
  1360 lemma degree_polysub:
  1361   assumes np: "isnpolyh p n0"
  1362     and nq: "isnpolyh q n1"
  1363   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1364 proof-
  1365   from nq have nq': "isnpolyh (~\<^sub>p q) n1"
  1366     using polyneg_normh by simp
  1367   from degree_polyadd[OF np nq'] show ?thesis
  1368     by (simp add: polysub_def degree_polyneg[OF nq])
  1369 qed
  1370 
  1371 lemma degree_polysub_samehead:
  1372   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1373     and np: "isnpolyh p n0"
  1374     and nq: "isnpolyh q n1"
  1375     and h: "head p = head q"
  1376     and d: "degree p = degree q"
  1377   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1378   unfolding polysub_def split_def fst_conv snd_conv
  1379   using np nq h d
  1380 proof (induct p q rule: polyadd.induct)
  1381   case (1 c c')
  1382   then show ?case
  1383     by (simp add: Nsub_def Nsub0[simplified Nsub_def])
  1384 next
  1385   case (2 c c' n' p')
  1386   from 2 have "degree (C c) = degree (CN c' n' p')"
  1387     by simp
  1388   then have nz: "n' > 0"
  1389     by (cases n') auto
  1390   then have "head (CN c' n' p') = CN c' n' p'"
  1391     by (cases n') auto
  1392   with 2 show ?case
  1393     by simp
  1394 next
  1395   case (3 c n p c')
  1396   then have "degree (C c') = degree (CN c n p)"
  1397     by simp
  1398   then have nz: "n > 0"
  1399     by (cases n) auto
  1400   then have "head (CN c n p) = CN c n p"
  1401     by (cases n) auto
  1402   with 3 show ?case by simp
  1403 next
  1404   case (4 c n p c' n' p')
  1405   then have H:
  1406     "isnpolyh (CN c n p) n0"
  1407     "isnpolyh (CN c' n' p') n1"
  1408     "head (CN c n p) = head (CN c' n' p')"
  1409     "degree (CN c n p) = degree (CN c' n' p')"
  1410     by simp_all
  1411   then have degc: "degree c = 0" and degc': "degree c' = 0"
  1412     by simp_all
  1413   then have degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0"
  1414     using H(1-2) degree_polyneg by auto
  1415   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"
  1416     by simp_all
  1417   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc'
  1418   have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"
  1419     by simp
  1420   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'"
  1421     by auto
  1422   have "n = n' \<or> n < n' \<or> n > n'"
  1423     by arith
  1424   moreover
  1425   {
  1426     assume nn': "n = n'"
  1427     have "n = 0 \<or> n > 0" by arith
  1428     moreover {
  1429       assume nz: "n = 0"
  1430       then have ?case using 4 nn'
  1431         by (auto simp add: Let_def degcmc')
  1432     }
  1433     moreover {
  1434       assume nz: "n > 0"
  1435       with nn' H(3) have  cc': "c = c'" and pp': "p = p'"
  1436         by (cases n, auto)+
  1437       then have ?case
  1438         using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv]
  1439         using polysub_same_0[OF c'nh, simplified polysub_def]
  1440         using nn' 4 by (simp add: Let_def)
  1441     }
  1442     ultimately have ?case by blast
  1443   }
  1444   moreover
  1445   {
  1446     assume nn': "n < n'"
  1447     then have n'p: "n' > 0"
  1448       by simp
  1449     then have headcnp':"head (CN c' n' p') = CN c' n' p'"
  1450       by (cases n') simp_all
  1451     have degcnp': "degree (CN c' n' p') = 0"
  1452       and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')"
  1453       using 4 nn' by (cases n', simp_all)
  1454     then have "n > 0"
  1455       by (cases n) simp_all
  1456     then have headcnp: "head (CN c n p) = CN c n p"
  1457       by (cases n) auto
  1458     from H(3) headcnp headcnp' nn' have ?case
  1459       by auto
  1460   }
  1461   moreover
  1462   {
  1463     assume nn': "n > n'"
  1464     then have np: "n > 0" by simp
  1465     then have headcnp:"head (CN c n p) = CN c n p"
  1466       by (cases n) simp_all
  1467     from 4 have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)"
  1468       by simp
  1469     from np have degcnp: "degree (CN c n p) = 0"
  1470       by (cases n) simp_all
  1471     with degcnpeq have "n' > 0"
  1472       by (cases n') simp_all
  1473     then have headcnp': "head (CN c' n' p') = CN c' n' p'"
  1474       by (cases n') auto
  1475     from H(3) headcnp headcnp' nn' have ?case by auto
  1476   }
  1477   ultimately show ?case by blast
  1478 qed auto
  1479 
  1480 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1481   by (induct p arbitrary: n0 rule: head.induct) (simp_all add: shift1_def)
  1482 
  1483 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1484 proof (induct k arbitrary: n0 p)
  1485   case 0
  1486   then show ?case by auto
  1487 next
  1488   case (Suc k n0 p)
  1489   then have "isnpolyh (shift1 p) 0" by (simp add: shift1_isnpolyh)
  1490   with Suc have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1491     and "head (shift1 p) = head p" by (simp_all add: shift1_head)
  1492   then show ?case by (simp add: funpow_swap1)
  1493 qed
  1494 
  1495 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1496   by (simp add: shift1_def)
  1497 
  1498 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1499   by (induct k arbitrary: p) (auto simp add: shift1_degree)
  1500 
  1501 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1502   by (induct n arbitrary: p) simp_all
  1503 
  1504 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1505   by (induct p arbitrary: n rule: degree.induct) auto
  1506 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1507   by (induct p arbitrary: n rule: degreen.induct) auto
  1508 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1509   by (induct p arbitrary: n rule: degree.induct) auto
  1510 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1511   by (induct p rule: head.induct) auto
  1512 
  1513 lemma polyadd_eq_const_degree:
  1514   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> polyadd p q = C c \<Longrightarrow> degree p = degree q"
  1515   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1516 
  1517 lemma polyadd_head:
  1518   assumes np: "isnpolyh p n0"
  1519     and nq: "isnpolyh q n1"
  1520     and deg: "degree p \<noteq> degree q"
  1521   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1522   using np nq deg
  1523   apply (induct p q arbitrary: n0 n1 rule: polyadd.induct)
  1524   using np
  1525   apply simp_all
  1526   apply (case_tac n', simp, simp)
  1527   apply (case_tac n, simp, simp)
  1528   apply (case_tac n, case_tac n', simp add: Let_def)
  1529   apply (auto simp add: polyadd_eq_const_degree)[2]
  1530   apply (metis head_nz)
  1531   apply (metis head_nz)
  1532   apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1533   done
  1534 
  1535 lemma polymul_head_polyeq:
  1536   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1537   shows "\<lbrakk>isnpolyh p n0; isnpolyh q n1 ; p \<noteq> 0\<^sub>p ; q \<noteq> 0\<^sub>p \<rbrakk> \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1538 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1539   case (2 c c' n' p' n0 n1)
  1540   then have "isnpolyh (head (CN c' n' p')) n1" "isnormNum c"
  1541     by (simp_all add: head_isnpolyh)
  1542   then show ?case
  1543     using 2 by (cases n') auto
  1544 next
  1545   case (3 c n p c' n0 n1)
  1546   then have "isnpolyh (head (CN c n p)) n0" "isnormNum c'"
  1547     by (simp_all add: head_isnpolyh)
  1548   then show ?case using 3
  1549     by (cases n) auto
  1550 next
  1551   case (4 c n p c' n' p' n0 n1)
  1552   hence norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1553     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1554     by simp_all
  1555   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1556   moreover
  1557   {
  1558     assume nn': "n < n'"
  1559     then have ?case
  1560       using norm "4.hyps"(2)[OF norm(1,6)] "4.hyps"(1)[OF norm(2,6)]
  1561       apply simp
  1562       apply (cases n)
  1563       apply simp
  1564       apply (cases n')
  1565       apply simp_all
  1566       done
  1567   }
  1568   moreover {
  1569     assume nn': "n'< n"
  1570     then have ?case
  1571       using norm "4.hyps"(6) [OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)]
  1572       apply simp
  1573       apply (cases n')
  1574       apply simp
  1575       apply (cases n)
  1576       apply auto
  1577       done
  1578   }
  1579   moreover {
  1580     assume nn': "n' = n"
  1581     from nn' polymul_normh[OF norm(5,4)]
  1582     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1583     from nn' polymul_normh[OF norm(5,3)] norm
  1584     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1585     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1586     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
  1587     from polyadd_normh[OF ncnpc' ncnpp0']
  1588     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n"
  1589       by (simp add: min_def)
  1590     {
  1591       assume np: "n > 0"
  1592       with nn' head_isnpolyh_Suc'[OF np nth]
  1593         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1594       have ?case by simp
  1595     }
  1596     moreover
  1597     {
  1598       assume nz: "n = 0"
  1599       from polymul_degreen[OF norm(5,4), where m="0"]
  1600         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1601       norm(5,6) degree_npolyhCN[OF norm(6)]
  1602     have dth:"degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1603     hence dth':"degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1604     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1605     have ?case   using norm "4.hyps"(6)[OF norm(5,3)]
  1606         "4.hyps"(5)[OF norm(5,4)] nn' nz by simp
  1607     }
  1608     ultimately have ?case by (cases n) auto
  1609   }
  1610   ultimately show ?case by blast
  1611 qed simp_all
  1612 
  1613 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1614   by (induct p rule: degree.induct) auto
  1615 
  1616 lemma degree_head[simp]: "degree (head p) = 0"
  1617   by (induct p rule: head.induct) auto
  1618 
  1619 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1620   by (cases n) simp_all
  1621 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1622   by (cases n) simp_all
  1623 
  1624 lemma polyadd_different_degree:
  1625   "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degree p \<noteq> degree q\<rbrakk> \<Longrightarrow>
  1626     degree (polyadd p q) = max (degree p) (degree q)"
  1627   using polyadd_different_degreen degree_eq_degreen0 by simp
  1628 
  1629 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1630   by (induct p arbitrary: n0 rule: polyneg.induct) auto
  1631 
  1632 lemma degree_polymul:
  1633   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1634     and np: "isnpolyh p n0"
  1635     and nq: "isnpolyh q n1"
  1636   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1637   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1638 
  1639 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1640   by (induct p arbitrary: n rule: degree.induct) auto
  1641 
  1642 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head(polyneg p) = polyneg (head p)"
  1643   by (induct p arbitrary: n rule: degree.induct) auto
  1644 
  1645 
  1646 subsection {* Correctness of polynomial pseudo division *}
  1647 
  1648 lemma polydivide_aux_properties:
  1649   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1650     and np: "isnpolyh p n0"
  1651     and ns: "isnpolyh s n1"
  1652     and ap: "head p = a"
  1653     and ndp: "degree p = n" and pnz: "p \<noteq> 0\<^sub>p"
  1654   shows "(polydivide_aux a n p k s = (k',r) \<longrightarrow> (k' \<ge> k) \<and> (degree r = 0 \<or> degree r < degree p)
  1655           \<and> (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> ((polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)))"
  1656   using ns
  1657 proof (induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1658   case less
  1659   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1660   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p)
  1661     \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1662   let ?b = "head s"
  1663   let ?p' = "funpow (degree s - n) shift1 p"
  1664   let ?xdn = "funpow (degree s - n) shift1 (1)\<^sub>p"
  1665   let ?akk' = "a ^\<^sub>p (k' - k)"
  1666   note ns = `isnpolyh s n1`
  1667   from np have np0: "isnpolyh p 0"
  1668     using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by simp
  1669   have np': "isnpolyh ?p' 0"
  1670     using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def
  1671     by simp
  1672   have headp': "head ?p' = head p"
  1673     using funpow_shift1_head[OF np pnz] by simp
  1674   from funpow_shift1_isnpoly[where p="(1)\<^sub>p"] have nxdn: "isnpolyh ?xdn 0"
  1675     by (simp add: isnpoly_def)
  1676   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap
  1677   have nakk':"isnpolyh ?akk' 0" by blast
  1678   { assume sz: "s = 0\<^sub>p"
  1679     hence ?ths using np polydivide_aux.simps
  1680       apply clarsimp
  1681       apply (rule exI[where x="0\<^sub>p"])
  1682       apply simp
  1683       done }
  1684   moreover
  1685   { assume sz: "s \<noteq> 0\<^sub>p"
  1686     { assume dn: "degree s < n"
  1687       hence "?ths" using ns ndp np polydivide_aux.simps
  1688         apply auto
  1689         apply (rule exI[where x="0\<^sub>p"])
  1690         apply simp
  1691         done }
  1692     moreover
  1693     { assume dn': "\<not> degree s < n" hence dn: "degree s \<ge> n" by arith
  1694       have degsp': "degree s = degree ?p'"
  1695         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"] by simp
  1696       { assume ba: "?b = a"
  1697         hence headsp': "head s = head ?p'"
  1698           using ap headp' by simp
  1699         have nr: "isnpolyh (s -\<^sub>p ?p') 0"
  1700           using polysub_normh[OF ns np'] by simp
  1701         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1702         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p" by simp
  1703         moreover
  1704         { assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1705           from polydivide_aux.simps sz dn' ba
  1706           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1707             by (simp add: Let_def)
  1708           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1709             from less(1)[OF deglt nr, of k k' r] trans[OF eq[symmetric] h1]
  1710             have kk': "k \<le> k'"
  1711               and nr:"\<exists>nr. isnpolyh r nr"
  1712               and dr: "degree r = 0 \<or> degree r < degree p"
  1713               and q1: "\<exists>q nq. isnpolyh q nq \<and> (a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r)"
  1714               by auto
  1715             from q1 obtain q n1 where nq: "isnpolyh q n1"
  1716               and asp:"a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r" by blast
  1717             from nr obtain nr where nr': "isnpolyh r nr" by blast
  1718             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0"
  1719               by simp
  1720             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1721             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1722             from polyadd_normh[OF polymul_normh[OF np
  1723               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1724             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0"
  1725               by simp
  1726             from asp have "\<forall> (bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) =
  1727               Ipoly bs (p *\<^sub>p q +\<^sub>p r)" by simp
  1728             hence " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) =
  1729               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1730               by (simp add: field_simps)
  1731             hence " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1732               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p *\<^sub>p p) +
  1733               Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1734               by (auto simp only: funpow_shift1_1)
  1735             hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1736               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p) +
  1737               Ipoly bs q) + Ipoly bs r"
  1738               by (simp add: field_simps)
  1739             hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1740               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r)"
  1741               by simp
  1742             with isnpolyh_unique[OF nakks' nqr']
  1743             have "a ^\<^sub>p (k' - k) *\<^sub>p s =
  1744               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r"
  1745               by blast
  1746             hence ?qths using nq'
  1747               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q" in exI)
  1748               apply (rule_tac x="0" in exI)
  1749               apply simp
  1750               done
  1751             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1752               by blast
  1753           }
  1754           hence ?ths by blast
  1755         }
  1756         moreover
  1757         { assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1758           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1759           have " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs s = Ipoly bs ?p'"
  1760             by simp
  1761           hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)"
  1762             using np nxdn
  1763             apply simp
  1764             apply (simp only: funpow_shift1_1)
  1765             apply simp
  1766             done
  1767           hence sp': "s = ?xdn *\<^sub>p p" using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]]
  1768             by blast
  1769           { assume h1: "polydivide_aux a n p k s = (k',r)"
  1770             from polydivide_aux.simps sz dn' ba
  1771             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1772               by (simp add: Let_def)
  1773             also have "\<dots> = (k,0\<^sub>p)"
  1774               using polydivide_aux.simps spz by simp
  1775             finally have "(k',r) = (k,0\<^sub>p)" using h1 by simp
  1776             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1777               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1778               apply auto
  1779               apply (rule exI[where x="?xdn"])
  1780               apply (auto simp add: polymul_commute[of p])
  1781               done
  1782           }
  1783         }
  1784         ultimately have ?ths by blast
  1785       }
  1786       moreover
  1787       { assume ba: "?b \<noteq> a"
  1788         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns]
  1789           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1790         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1791           by (simp add: min_def)
  1792         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1793           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns]
  1794             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1795             funpow_shift1_nz[OF pnz]
  1796           by simp_all
  1797         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1798           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1799         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')"
  1800           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1801             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1802           by (simp add: ap)
  1803         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1804           head_nz[OF np] pnz sz ap[symmetric]
  1805           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1806           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"] head_nz[OF ns]
  1807           ndp dn
  1808         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p')"
  1809           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1810         { assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1811           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1812             polymul_normh[OF head_isnpolyh[OF ns]np']] ap
  1813           have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1814             by simp
  1815           { assume h1:"polydivide_aux a n p k s = (k', r)"
  1816             from h1 polydivide_aux.simps sz dn' ba
  1817             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1818               by (simp add: Let_def)
  1819             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1820             obtain q nq nr where kk': "Suc k \<le> k'"
  1821               and nr: "isnpolyh r nr"
  1822               and nq: "isnpolyh q nq"
  1823               and dr: "degree r = 0 \<or> degree r < degree p"
  1824               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r"
  1825               by auto
  1826             from kk' have kk'':"Suc (k' - Suc k) = k' - k" by arith
  1827             {
  1828               fix bs:: "'a::{field_char_0,field_inverse_zero} list"
  1829               from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1830               have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1831                 by simp
  1832               hence "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s =
  1833                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1834                 by (simp add: field_simps)
  1835               hence "Ipoly bs a ^ (k' - k)  * Ipoly bs s =
  1836                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1837                 by (simp add: kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1838               hence "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1839                 Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1840                 by (simp add: field_simps)
  1841             }
  1842             hence ieq:"\<forall>(bs :: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1843               Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)"
  1844               by auto
  1845             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1846             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap ] nxdn]]
  1847             have nqw: "isnpolyh ?q 0"
  1848               by simp
  1849             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1850             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r"
  1851               by blast
  1852             from dr kk' nr h1 asth nqw have ?ths
  1853               apply simp
  1854               apply (rule conjI)
  1855               apply (rule exI[where x="nr"], simp)
  1856               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1857               apply (rule exI[where x="0"], simp)
  1858               done
  1859           }
  1860           hence ?ths by blast
  1861         }
  1862         moreover
  1863         { assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1864           {
  1865             fix bs :: "'a::{field_char_0,field_inverse_zero} list"
  1866             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1867             have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'"
  1868               by simp
  1869             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p"
  1870               by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1871             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))"
  1872               by simp
  1873           }
  1874           hence hth: "\<forall> (bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a*\<^sub>p s) =
  1875             Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1876           from hth have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)"
  1877             using isnpolyh_unique[where ?'a = "'a::{field_char_0,field_inverse_zero}", OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1878                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1879               simplified ap] by simp
  1880           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1881             from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1882             have "(k',r) = (Suc k, 0\<^sub>p)" by (simp add: Let_def)
  1883             with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1884               polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1885             have ?ths
  1886               apply (clarsimp simp add: Let_def)
  1887               apply (rule exI[where x="?b *\<^sub>p ?xdn"])
  1888               apply simp
  1889               apply (rule exI[where x="0"], simp)
  1890               done
  1891           }
  1892           hence ?ths by blast
  1893         }
  1894         ultimately have ?ths
  1895           using  degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1896             head_nz[OF np] pnz sz ap[symmetric]
  1897           by (simp add: degree_eq_degreen0[symmetric]) blast
  1898       }
  1899       ultimately have ?ths by blast
  1900     }
  1901     ultimately have ?ths by blast
  1902   }
  1903   ultimately show ?ths by blast
  1904 qed
  1905 
  1906 lemma polydivide_properties:
  1907   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1908     and np: "isnpolyh p n0" and ns: "isnpolyh s n1" and pnz: "p \<noteq> 0\<^sub>p"
  1909   shows "\<exists>k r. polydivide s p = (k,r) \<and>
  1910     (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1911     (\<exists>q n1. isnpolyh q n1 \<and> ((polypow k (head p)) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r))"
  1912 proof -
  1913   have trv: "head p = head p" "degree p = degree p"
  1914     by simp_all
  1915   from polydivide_def[where s="s" and p="p"] have ex: "\<exists> k r. polydivide s p = (k,r)"
  1916     by auto
  1917   then obtain k r where kr: "polydivide s p = (k,r)"
  1918     by blast
  1919   from trans[OF polydivide_def[where s="s"and p="p", symmetric] kr]
  1920     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1921   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1922     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1923     by blast
  1924   with kr show ?thesis
  1925     apply -
  1926     apply (rule exI[where x="k"])
  1927     apply (rule exI[where x="r"])
  1928     apply simp
  1929     done
  1930 qed
  1931 
  1932 
  1933 subsection{* More about polypoly and pnormal etc *}
  1934 
  1935 definition "isnonconstant p \<longleftrightarrow> \<not> isconstant p"
  1936 
  1937 lemma isnonconstant_pnormal_iff:
  1938   assumes nc: "isnonconstant p"
  1939   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1940 proof
  1941   let ?p = "polypoly bs p"
  1942   assume H: "pnormal ?p"
  1943   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1944 
  1945   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1946     pnormal_last_nonzero[OF H]
  1947   show "Ipoly bs (head p) \<noteq> 0" by (simp add: polypoly_def)
  1948 next
  1949   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1950   let ?p = "polypoly bs p"
  1951   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1952   hence pz: "?p \<noteq> []" by (simp add: polypoly_def)
  1953   hence lg: "length ?p > 0" by simp
  1954   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1955   have lz: "last ?p \<noteq> 0" by (simp add: polypoly_def)
  1956   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  1957 qed
  1958 
  1959 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  1960   unfolding isnonconstant_def
  1961   apply (cases p)
  1962   apply simp_all
  1963   apply (case_tac nat)
  1964   apply auto
  1965   done
  1966 
  1967 lemma isnonconstant_nonconstant:
  1968   assumes inc: "isnonconstant p"
  1969   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1970 proof
  1971   let ?p = "polypoly bs p"
  1972   assume nc: "nonconstant ?p"
  1973   from isnonconstant_pnormal_iff[OF inc, of bs] nc
  1974   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" unfolding nonconstant_def by blast
  1975 next
  1976   let ?p = "polypoly bs p"
  1977   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1978   from isnonconstant_pnormal_iff[OF inc, of bs] h
  1979   have pn: "pnormal ?p" by blast
  1980   {
  1981     fix x
  1982     assume H: "?p = [x]"
  1983     from H have "length (coefficients p) = 1"
  1984       unfolding polypoly_def by auto
  1985     with isnonconstant_coefficients_length[OF inc]
  1986       have False by arith
  1987   }
  1988   then show "nonconstant ?p"
  1989     using pn unfolding nonconstant_def by blast
  1990 qed
  1991 
  1992 lemma pnormal_length: "p\<noteq>[] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  1993   apply (induct p)
  1994   apply (simp_all add: pnormal_def)
  1995   apply (case_tac "p = []")
  1996   apply simp_all
  1997   done
  1998 
  1999 lemma degree_degree:
  2000   assumes inc: "isnonconstant p"
  2001   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2002 proof
  2003   let ?p = "polypoly bs p"
  2004   assume H: "degree p = Polynomial_List.degree ?p"
  2005   from isnonconstant_coefficients_length[OF inc] have pz: "?p \<noteq> []"
  2006     unfolding polypoly_def by auto
  2007   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  2008   have lg:"length (pnormalize ?p) = length ?p"
  2009     unfolding Polynomial_List.degree_def polypoly_def by simp
  2010   hence "pnormal ?p" using pnormal_length[OF pz] by blast
  2011   with isnonconstant_pnormal_iff[OF inc]
  2012   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" by blast
  2013 next
  2014   let  ?p = "polypoly bs p"
  2015   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2016   with isnonconstant_pnormal_iff[OF inc] have "pnormal ?p" by blast
  2017   with degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  2018   show "degree p = Polynomial_List.degree ?p"
  2019     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  2020 qed
  2021 
  2022 
  2023 section {* Swaps ; Division by a certain variable *}
  2024 
  2025 primrec swap :: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly" where
  2026   "swap n m (C x) = C x"
  2027 | "swap n m (Bound k) = Bound (if k = n then m else if k=m then n else k)"
  2028 | "swap n m (Neg t) = Neg (swap n m t)"
  2029 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  2030 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  2031 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  2032 | "swap n m (Pw t k) = Pw (swap n m t) k"
  2033 | "swap n m (CN c k p) =
  2034     CN (swap n m c) (if k = n then m else if k=m then n else k) (swap n m p)"
  2035 
  2036 lemma swap:
  2037   assumes nbs: "n < length bs"
  2038     and mbs: "m < length bs"
  2039   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2040 proof (induct t)
  2041   case (Bound k)
  2042   then show ?case using nbs mbs by simp
  2043 next
  2044   case (CN c k p)
  2045   then show ?case using nbs mbs by simp
  2046 qed simp_all
  2047 
  2048 lemma swap_swap_id [simp]: "swap n m (swap m n t) = t"
  2049   by (induct t) simp_all
  2050 
  2051 lemma swap_commute: "swap n m p = swap m n p"
  2052   by (induct p) simp_all
  2053 
  2054 lemma swap_same_id[simp]: "swap n n t = t"
  2055   by (induct t) simp_all
  2056 
  2057 definition "swapnorm n m t = polynate (swap n m t)"
  2058 
  2059 lemma swapnorm:
  2060   assumes nbs: "n < length bs"
  2061     and mbs: "m < length bs"
  2062   shows "((Ipoly bs (swapnorm n m t) :: 'a::{field_char_0,field_inverse_zero})) =
  2063     Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2064   using swap[OF assms] swapnorm_def by simp
  2065 
  2066 lemma swapnorm_isnpoly [simp]:
  2067   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  2068   shows "isnpoly (swapnorm n m p)"
  2069   unfolding swapnorm_def by simp
  2070 
  2071 definition "polydivideby n s p =
  2072   (let
  2073     ss = swapnorm 0 n s;
  2074     sp = swapnorm 0 n p;
  2075     h = head sp;
  2076     (k, r) = polydivide ss sp
  2077    in (k, swapnorm 0 n h, swapnorm 0 n r))"
  2078 
  2079 lemma swap_nz [simp]: "swap n m p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  2080   by (induct p) simp_all
  2081 
  2082 fun isweaknpoly :: "poly \<Rightarrow> bool"
  2083 where
  2084   "isweaknpoly (C c) = True"
  2085 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  2086 | "isweaknpoly p = False"
  2087 
  2088 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p"
  2089   by (induct p arbitrary: n0) auto
  2090 
  2091 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)"
  2092   by (induct p) auto
  2093 
  2094 end