src/HOL/HOL.thy
author berghofe
Mon Sep 22 23:00:15 2008 +0200 (2008-09-22)
changeset 28325 0b6b83ec8458
parent 28227 77221ee0f7b9
child 28346 b8390cd56b8f
permissions -rw-r--r--
Added setup for coherent logic prover.
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports Pure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/coherent.ML"
    23   "~~/src/Provers/eqsubst.ML"
    24   "~~/src/Provers/quantifier1.ML"
    25   ("simpdata.ML")
    26   "~~/src/Tools/random_word.ML"
    27   "~~/src/Tools/atomize_elim.ML"
    28   "~~/src/Tools/induct.ML"
    29   ("~~/src/Tools/induct_tacs.ML")
    30   "~~/src/Tools/code/code_name.ML"
    31   "~~/src/Tools/code/code_funcgr.ML"
    32   "~~/src/Tools/code/code_thingol.ML"
    33   "~~/src/Tools/code/code_printer.ML"
    34   "~~/src/Tools/code/code_target.ML"
    35   "~~/src/Tools/code/code_ml.ML"
    36   "~~/src/Tools/code/code_haskell.ML"
    37   "~~/src/Tools/nbe.ML"
    38 begin
    39 
    40 subsection {* Primitive logic *}
    41 
    42 subsubsection {* Core syntax *}
    43 
    44 classes type
    45 defaultsort type
    46 setup {* ObjectLogic.add_base_sort @{sort type} *}
    47 
    48 arities
    49   "fun" :: (type, type) type
    50   itself :: (type) type
    51 
    52 global
    53 
    54 typedecl bool
    55 
    56 judgment
    57   Trueprop      :: "bool => prop"                   ("(_)" 5)
    58 
    59 consts
    60   Not           :: "bool => bool"                   ("~ _" [40] 40)
    61   True          :: bool
    62   False         :: bool
    63   arbitrary     :: 'a
    64 
    65   The           :: "('a => bool) => 'a"
    66   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    67   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    68   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    69   Let           :: "['a, 'a => 'b] => 'b"
    70 
    71   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    72   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    73   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    74   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    75 
    76 local
    77 
    78 consts
    79   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    80 
    81 
    82 subsubsection {* Additional concrete syntax *}
    83 
    84 notation (output)
    85   "op ="  (infix "=" 50)
    86 
    87 abbreviation
    88   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    89   "x ~= y == ~ (x = y)"
    90 
    91 notation (output)
    92   not_equal  (infix "~=" 50)
    93 
    94 notation (xsymbols)
    95   Not  ("\<not> _" [40] 40) and
    96   "op &"  (infixr "\<and>" 35) and
    97   "op |"  (infixr "\<or>" 30) and
    98   "op -->"  (infixr "\<longrightarrow>" 25) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 notation (HTML output)
   102   Not  ("\<not> _" [40] 40) and
   103   "op &"  (infixr "\<and>" 35) and
   104   "op |"  (infixr "\<or>" 30) and
   105   not_equal  (infix "\<noteq>" 50)
   106 
   107 abbreviation (iff)
   108   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   109   "A <-> B == A = B"
   110 
   111 notation (xsymbols)
   112   iff  (infixr "\<longleftrightarrow>" 25)
   113 
   114 
   115 nonterminals
   116   letbinds  letbind
   117   case_syn  cases_syn
   118 
   119 syntax
   120   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   121 
   122   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   123   ""            :: "letbind => letbinds"                 ("_")
   124   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   125   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   126 
   127   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   128   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   129   ""            :: "case_syn => cases_syn"               ("_")
   130   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   131 
   132 translations
   133   "THE x. P"              == "The (%x. P)"
   134   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   135   "let x = a in e"        == "Let a (%x. e)"
   136 
   137 print_translation {*
   138 (* To avoid eta-contraction of body: *)
   139 [("The", fn [Abs abs] =>
   140      let val (x,t) = atomic_abs_tr' abs
   141      in Syntax.const "_The" $ x $ t end)]
   142 *}
   143 
   144 syntax (xsymbols)
   145   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   146 
   147 notation (xsymbols)
   148   All  (binder "\<forall>" 10) and
   149   Ex  (binder "\<exists>" 10) and
   150   Ex1  (binder "\<exists>!" 10)
   151 
   152 notation (HTML output)
   153   All  (binder "\<forall>" 10) and
   154   Ex  (binder "\<exists>" 10) and
   155   Ex1  (binder "\<exists>!" 10)
   156 
   157 notation (HOL)
   158   All  (binder "! " 10) and
   159   Ex  (binder "? " 10) and
   160   Ex1  (binder "?! " 10)
   161 
   162 
   163 subsubsection {* Axioms and basic definitions *}
   164 
   165 axioms
   166   eq_reflection:  "(x=y) ==> (x==y)"
   167 
   168   refl:           "t = (t::'a)"
   169 
   170   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   171     -- {*Extensionality is built into the meta-logic, and this rule expresses
   172          a related property.  It is an eta-expanded version of the traditional
   173          rule, and similar to the ABS rule of HOL*}
   174 
   175   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   176 
   177   impI:           "(P ==> Q) ==> P-->Q"
   178   mp:             "[| P-->Q;  P |] ==> Q"
   179 
   180 
   181 defs
   182   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   183   All_def:      "All(P)    == (P = (%x. True))"
   184   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   185   False_def:    "False     == (!P. P)"
   186   not_def:      "~ P       == P-->False"
   187   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   188   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   189   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   190 
   191 axioms
   192   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   193   True_or_False:  "(P=True) | (P=False)"
   194 
   195 defs
   196   Let_def:      "Let s f == f(s)"
   197   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   198 
   199 finalconsts
   200   "op ="
   201   "op -->"
   202   The
   203   arbitrary
   204 
   205 axiomatization
   206   undefined :: 'a
   207 
   208 axiomatization where
   209   undefined_fun: "undefined x = undefined"
   210 
   211 
   212 subsubsection {* Generic classes and algebraic operations *}
   213 
   214 class default = type +
   215   fixes default :: 'a
   216 
   217 class zero = type + 
   218   fixes zero :: 'a  ("0")
   219 
   220 class one = type +
   221   fixes one  :: 'a  ("1")
   222 
   223 hide (open) const zero one
   224 
   225 class plus = type +
   226   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   227 
   228 class minus = type +
   229   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   230 
   231 class uminus = type +
   232   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   233 
   234 class times = type +
   235   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   236 
   237 class inverse = type +
   238   fixes inverse :: "'a \<Rightarrow> 'a"
   239     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   240 
   241 class abs = type +
   242   fixes abs :: "'a \<Rightarrow> 'a"
   243 begin
   244 
   245 notation (xsymbols)
   246   abs  ("\<bar>_\<bar>")
   247 
   248 notation (HTML output)
   249   abs  ("\<bar>_\<bar>")
   250 
   251 end
   252 
   253 class sgn = type +
   254   fixes sgn :: "'a \<Rightarrow> 'a"
   255 
   256 class ord = type +
   257   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   258     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   259 begin
   260 
   261 notation
   262   less_eq  ("op <=") and
   263   less_eq  ("(_/ <= _)" [51, 51] 50) and
   264   less  ("op <") and
   265   less  ("(_/ < _)"  [51, 51] 50)
   266   
   267 notation (xsymbols)
   268   less_eq  ("op \<le>") and
   269   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   270 
   271 notation (HTML output)
   272   less_eq  ("op \<le>") and
   273   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   274 
   275 abbreviation (input)
   276   greater_eq  (infix ">=" 50) where
   277   "x >= y \<equiv> y <= x"
   278 
   279 notation (input)
   280   greater_eq  (infix "\<ge>" 50)
   281 
   282 abbreviation (input)
   283   greater  (infix ">" 50) where
   284   "x > y \<equiv> y < x"
   285 
   286 end
   287 
   288 syntax
   289   "_index1"  :: index    ("\<^sub>1")
   290 translations
   291   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   292 
   293 typed_print_translation {*
   294 let
   295   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   296     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   297     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   298 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   299 *} -- {* show types that are presumably too general *}
   300 
   301 
   302 subsection {* Fundamental rules *}
   303 
   304 subsubsection {* Equality *}
   305 
   306 text {* Thanks to Stephan Merz *}
   307 lemma subst:
   308   assumes eq: "s = t" and p: "P s"
   309   shows "P t"
   310 proof -
   311   from eq have meta: "s \<equiv> t"
   312     by (rule eq_reflection)
   313   from p show ?thesis
   314     by (unfold meta)
   315 qed
   316 
   317 lemma sym: "s = t ==> t = s"
   318   by (erule subst) (rule refl)
   319 
   320 lemma ssubst: "t = s ==> P s ==> P t"
   321   by (drule sym) (erule subst)
   322 
   323 lemma trans: "[| r=s; s=t |] ==> r=t"
   324   by (erule subst)
   325 
   326 lemma meta_eq_to_obj_eq: 
   327   assumes meq: "A == B"
   328   shows "A = B"
   329   by (unfold meq) (rule refl)
   330 
   331 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   332      (* a = b
   333         |   |
   334         c = d   *)
   335 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   336 apply (rule trans)
   337 apply (rule trans)
   338 apply (rule sym)
   339 apply assumption+
   340 done
   341 
   342 text {* For calculational reasoning: *}
   343 
   344 lemma forw_subst: "a = b ==> P b ==> P a"
   345   by (rule ssubst)
   346 
   347 lemma back_subst: "P a ==> a = b ==> P b"
   348   by (rule subst)
   349 
   350 
   351 subsubsection {*Congruence rules for application*}
   352 
   353 (*similar to AP_THM in Gordon's HOL*)
   354 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   355 apply (erule subst)
   356 apply (rule refl)
   357 done
   358 
   359 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   360 lemma arg_cong: "x=y ==> f(x)=f(y)"
   361 apply (erule subst)
   362 apply (rule refl)
   363 done
   364 
   365 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   366 apply (erule ssubst)+
   367 apply (rule refl)
   368 done
   369 
   370 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   371 apply (erule subst)+
   372 apply (rule refl)
   373 done
   374 
   375 
   376 subsubsection {*Equality of booleans -- iff*}
   377 
   378 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   379   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   380 
   381 lemma iffD2: "[| P=Q; Q |] ==> P"
   382   by (erule ssubst)
   383 
   384 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   385   by (erule iffD2)
   386 
   387 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   388   by (drule sym) (rule iffD2)
   389 
   390 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   391   by (drule sym) (rule rev_iffD2)
   392 
   393 lemma iffE:
   394   assumes major: "P=Q"
   395     and minor: "[| P --> Q; Q --> P |] ==> R"
   396   shows R
   397   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   398 
   399 
   400 subsubsection {*True*}
   401 
   402 lemma TrueI: "True"
   403   unfolding True_def by (rule refl)
   404 
   405 lemma eqTrueI: "P ==> P = True"
   406   by (iprover intro: iffI TrueI)
   407 
   408 lemma eqTrueE: "P = True ==> P"
   409   by (erule iffD2) (rule TrueI)
   410 
   411 
   412 subsubsection {*Universal quantifier*}
   413 
   414 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   415   unfolding All_def by (iprover intro: ext eqTrueI assms)
   416 
   417 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   418 apply (unfold All_def)
   419 apply (rule eqTrueE)
   420 apply (erule fun_cong)
   421 done
   422 
   423 lemma allE:
   424   assumes major: "ALL x. P(x)"
   425     and minor: "P(x) ==> R"
   426   shows R
   427   by (iprover intro: minor major [THEN spec])
   428 
   429 lemma all_dupE:
   430   assumes major: "ALL x. P(x)"
   431     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   432   shows R
   433   by (iprover intro: minor major major [THEN spec])
   434 
   435 
   436 subsubsection {* False *}
   437 
   438 text {*
   439   Depends upon @{text spec}; it is impossible to do propositional
   440   logic before quantifiers!
   441 *}
   442 
   443 lemma FalseE: "False ==> P"
   444   apply (unfold False_def)
   445   apply (erule spec)
   446   done
   447 
   448 lemma False_neq_True: "False = True ==> P"
   449   by (erule eqTrueE [THEN FalseE])
   450 
   451 
   452 subsubsection {* Negation *}
   453 
   454 lemma notI:
   455   assumes "P ==> False"
   456   shows "~P"
   457   apply (unfold not_def)
   458   apply (iprover intro: impI assms)
   459   done
   460 
   461 lemma False_not_True: "False ~= True"
   462   apply (rule notI)
   463   apply (erule False_neq_True)
   464   done
   465 
   466 lemma True_not_False: "True ~= False"
   467   apply (rule notI)
   468   apply (drule sym)
   469   apply (erule False_neq_True)
   470   done
   471 
   472 lemma notE: "[| ~P;  P |] ==> R"
   473   apply (unfold not_def)
   474   apply (erule mp [THEN FalseE])
   475   apply assumption
   476   done
   477 
   478 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   479   by (erule notE [THEN notI]) (erule meta_mp)
   480 
   481 
   482 subsubsection {*Implication*}
   483 
   484 lemma impE:
   485   assumes "P-->Q" "P" "Q ==> R"
   486   shows "R"
   487 by (iprover intro: assms mp)
   488 
   489 (* Reduces Q to P-->Q, allowing substitution in P. *)
   490 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   491 by (iprover intro: mp)
   492 
   493 lemma contrapos_nn:
   494   assumes major: "~Q"
   495       and minor: "P==>Q"
   496   shows "~P"
   497 by (iprover intro: notI minor major [THEN notE])
   498 
   499 (*not used at all, but we already have the other 3 combinations *)
   500 lemma contrapos_pn:
   501   assumes major: "Q"
   502       and minor: "P ==> ~Q"
   503   shows "~P"
   504 by (iprover intro: notI minor major notE)
   505 
   506 lemma not_sym: "t ~= s ==> s ~= t"
   507   by (erule contrapos_nn) (erule sym)
   508 
   509 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   510   by (erule subst, erule ssubst, assumption)
   511 
   512 (*still used in HOLCF*)
   513 lemma rev_contrapos:
   514   assumes pq: "P ==> Q"
   515       and nq: "~Q"
   516   shows "~P"
   517 apply (rule nq [THEN contrapos_nn])
   518 apply (erule pq)
   519 done
   520 
   521 subsubsection {*Existential quantifier*}
   522 
   523 lemma exI: "P x ==> EX x::'a. P x"
   524 apply (unfold Ex_def)
   525 apply (iprover intro: allI allE impI mp)
   526 done
   527 
   528 lemma exE:
   529   assumes major: "EX x::'a. P(x)"
   530       and minor: "!!x. P(x) ==> Q"
   531   shows "Q"
   532 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   533 apply (iprover intro: impI [THEN allI] minor)
   534 done
   535 
   536 
   537 subsubsection {*Conjunction*}
   538 
   539 lemma conjI: "[| P; Q |] ==> P&Q"
   540 apply (unfold and_def)
   541 apply (iprover intro: impI [THEN allI] mp)
   542 done
   543 
   544 lemma conjunct1: "[| P & Q |] ==> P"
   545 apply (unfold and_def)
   546 apply (iprover intro: impI dest: spec mp)
   547 done
   548 
   549 lemma conjunct2: "[| P & Q |] ==> Q"
   550 apply (unfold and_def)
   551 apply (iprover intro: impI dest: spec mp)
   552 done
   553 
   554 lemma conjE:
   555   assumes major: "P&Q"
   556       and minor: "[| P; Q |] ==> R"
   557   shows "R"
   558 apply (rule minor)
   559 apply (rule major [THEN conjunct1])
   560 apply (rule major [THEN conjunct2])
   561 done
   562 
   563 lemma context_conjI:
   564   assumes "P" "P ==> Q" shows "P & Q"
   565 by (iprover intro: conjI assms)
   566 
   567 
   568 subsubsection {*Disjunction*}
   569 
   570 lemma disjI1: "P ==> P|Q"
   571 apply (unfold or_def)
   572 apply (iprover intro: allI impI mp)
   573 done
   574 
   575 lemma disjI2: "Q ==> P|Q"
   576 apply (unfold or_def)
   577 apply (iprover intro: allI impI mp)
   578 done
   579 
   580 lemma disjE:
   581   assumes major: "P|Q"
   582       and minorP: "P ==> R"
   583       and minorQ: "Q ==> R"
   584   shows "R"
   585 by (iprover intro: minorP minorQ impI
   586                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   587 
   588 
   589 subsubsection {*Classical logic*}
   590 
   591 lemma classical:
   592   assumes prem: "~P ==> P"
   593   shows "P"
   594 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   595 apply assumption
   596 apply (rule notI [THEN prem, THEN eqTrueI])
   597 apply (erule subst)
   598 apply assumption
   599 done
   600 
   601 lemmas ccontr = FalseE [THEN classical, standard]
   602 
   603 (*notE with premises exchanged; it discharges ~R so that it can be used to
   604   make elimination rules*)
   605 lemma rev_notE:
   606   assumes premp: "P"
   607       and premnot: "~R ==> ~P"
   608   shows "R"
   609 apply (rule ccontr)
   610 apply (erule notE [OF premnot premp])
   611 done
   612 
   613 (*Double negation law*)
   614 lemma notnotD: "~~P ==> P"
   615 apply (rule classical)
   616 apply (erule notE)
   617 apply assumption
   618 done
   619 
   620 lemma contrapos_pp:
   621   assumes p1: "Q"
   622       and p2: "~P ==> ~Q"
   623   shows "P"
   624 by (iprover intro: classical p1 p2 notE)
   625 
   626 
   627 subsubsection {*Unique existence*}
   628 
   629 lemma ex1I:
   630   assumes "P a" "!!x. P(x) ==> x=a"
   631   shows "EX! x. P(x)"
   632 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   633 
   634 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   635 lemma ex_ex1I:
   636   assumes ex_prem: "EX x. P(x)"
   637       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   638   shows "EX! x. P(x)"
   639 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   640 
   641 lemma ex1E:
   642   assumes major: "EX! x. P(x)"
   643       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   644   shows "R"
   645 apply (rule major [unfolded Ex1_def, THEN exE])
   646 apply (erule conjE)
   647 apply (iprover intro: minor)
   648 done
   649 
   650 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   651 apply (erule ex1E)
   652 apply (rule exI)
   653 apply assumption
   654 done
   655 
   656 
   657 subsubsection {*THE: definite description operator*}
   658 
   659 lemma the_equality:
   660   assumes prema: "P a"
   661       and premx: "!!x. P x ==> x=a"
   662   shows "(THE x. P x) = a"
   663 apply (rule trans [OF _ the_eq_trivial])
   664 apply (rule_tac f = "The" in arg_cong)
   665 apply (rule ext)
   666 apply (rule iffI)
   667  apply (erule premx)
   668 apply (erule ssubst, rule prema)
   669 done
   670 
   671 lemma theI:
   672   assumes "P a" and "!!x. P x ==> x=a"
   673   shows "P (THE x. P x)"
   674 by (iprover intro: assms the_equality [THEN ssubst])
   675 
   676 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   677 apply (erule ex1E)
   678 apply (erule theI)
   679 apply (erule allE)
   680 apply (erule mp)
   681 apply assumption
   682 done
   683 
   684 (*Easier to apply than theI: only one occurrence of P*)
   685 lemma theI2:
   686   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   687   shows "Q (THE x. P x)"
   688 by (iprover intro: assms theI)
   689 
   690 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   691 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   692            elim:allE impE)
   693 
   694 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   695 apply (rule the_equality)
   696 apply  assumption
   697 apply (erule ex1E)
   698 apply (erule all_dupE)
   699 apply (drule mp)
   700 apply  assumption
   701 apply (erule ssubst)
   702 apply (erule allE)
   703 apply (erule mp)
   704 apply assumption
   705 done
   706 
   707 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   708 apply (rule the_equality)
   709 apply (rule refl)
   710 apply (erule sym)
   711 done
   712 
   713 
   714 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   715 
   716 lemma disjCI:
   717   assumes "~Q ==> P" shows "P|Q"
   718 apply (rule classical)
   719 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   720 done
   721 
   722 lemma excluded_middle: "~P | P"
   723 by (iprover intro: disjCI)
   724 
   725 text {*
   726   case distinction as a natural deduction rule.
   727   Note that @{term "~P"} is the second case, not the first
   728 *}
   729 lemma case_split [case_names True False]:
   730   assumes prem1: "P ==> Q"
   731       and prem2: "~P ==> Q"
   732   shows "Q"
   733 apply (rule excluded_middle [THEN disjE])
   734 apply (erule prem2)
   735 apply (erule prem1)
   736 done
   737 
   738 (*Classical implies (-->) elimination. *)
   739 lemma impCE:
   740   assumes major: "P-->Q"
   741       and minor: "~P ==> R" "Q ==> R"
   742   shows "R"
   743 apply (rule excluded_middle [of P, THEN disjE])
   744 apply (iprover intro: minor major [THEN mp])+
   745 done
   746 
   747 (*This version of --> elimination works on Q before P.  It works best for
   748   those cases in which P holds "almost everywhere".  Can't install as
   749   default: would break old proofs.*)
   750 lemma impCE':
   751   assumes major: "P-->Q"
   752       and minor: "Q ==> R" "~P ==> R"
   753   shows "R"
   754 apply (rule excluded_middle [of P, THEN disjE])
   755 apply (iprover intro: minor major [THEN mp])+
   756 done
   757 
   758 (*Classical <-> elimination. *)
   759 lemma iffCE:
   760   assumes major: "P=Q"
   761       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   762   shows "R"
   763 apply (rule major [THEN iffE])
   764 apply (iprover intro: minor elim: impCE notE)
   765 done
   766 
   767 lemma exCI:
   768   assumes "ALL x. ~P(x) ==> P(a)"
   769   shows "EX x. P(x)"
   770 apply (rule ccontr)
   771 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   772 done
   773 
   774 
   775 subsubsection {* Intuitionistic Reasoning *}
   776 
   777 lemma impE':
   778   assumes 1: "P --> Q"
   779     and 2: "Q ==> R"
   780     and 3: "P --> Q ==> P"
   781   shows R
   782 proof -
   783   from 3 and 1 have P .
   784   with 1 have Q by (rule impE)
   785   with 2 show R .
   786 qed
   787 
   788 lemma allE':
   789   assumes 1: "ALL x. P x"
   790     and 2: "P x ==> ALL x. P x ==> Q"
   791   shows Q
   792 proof -
   793   from 1 have "P x" by (rule spec)
   794   from this and 1 show Q by (rule 2)
   795 qed
   796 
   797 lemma notE':
   798   assumes 1: "~ P"
   799     and 2: "~ P ==> P"
   800   shows R
   801 proof -
   802   from 2 and 1 have P .
   803   with 1 show R by (rule notE)
   804 qed
   805 
   806 lemma TrueE: "True ==> P ==> P" .
   807 lemma notFalseE: "~ False ==> P ==> P" .
   808 
   809 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   810   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   811   and [Pure.elim 2] = allE notE' impE'
   812   and [Pure.intro] = exI disjI2 disjI1
   813 
   814 lemmas [trans] = trans
   815   and [sym] = sym not_sym
   816   and [Pure.elim?] = iffD1 iffD2 impE
   817 
   818 use "hologic.ML"
   819 
   820 
   821 subsubsection {* Atomizing meta-level connectives *}
   822 
   823 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   824 proof
   825   assume "!!x. P x"
   826   then show "ALL x. P x" ..
   827 next
   828   assume "ALL x. P x"
   829   then show "!!x. P x" by (rule allE)
   830 qed
   831 
   832 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   833 proof
   834   assume r: "A ==> B"
   835   show "A --> B" by (rule impI) (rule r)
   836 next
   837   assume "A --> B" and A
   838   then show B by (rule mp)
   839 qed
   840 
   841 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   842 proof
   843   assume r: "A ==> False"
   844   show "~A" by (rule notI) (rule r)
   845 next
   846   assume "~A" and A
   847   then show False by (rule notE)
   848 qed
   849 
   850 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   851 proof
   852   assume "x == y"
   853   show "x = y" by (unfold `x == y`) (rule refl)
   854 next
   855   assume "x = y"
   856   then show "x == y" by (rule eq_reflection)
   857 qed
   858 
   859 lemma atomize_conj [atomize]:
   860   includes meta_conjunction_syntax
   861   shows "(A && B) == Trueprop (A & B)"
   862 proof
   863   assume conj: "A && B"
   864   show "A & B"
   865   proof (rule conjI)
   866     from conj show A by (rule conjunctionD1)
   867     from conj show B by (rule conjunctionD2)
   868   qed
   869 next
   870   assume conj: "A & B"
   871   show "A && B"
   872   proof -
   873     from conj show A ..
   874     from conj show B ..
   875   qed
   876 qed
   877 
   878 lemmas [symmetric, rulify] = atomize_all atomize_imp
   879   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   880 
   881 
   882 subsubsection {* Atomizing elimination rules *}
   883 
   884 setup AtomizeElim.setup
   885 
   886 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   887   by rule iprover+
   888 
   889 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   890   by rule iprover+
   891 
   892 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   893   by rule iprover+
   894 
   895 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   896 
   897 
   898 subsection {* Package setup *}
   899 
   900 subsubsection {* Classical Reasoner setup *}
   901 
   902 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   903   by (rule classical) iprover
   904 
   905 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   906   by (rule classical) iprover
   907 
   908 lemma thin_refl:
   909   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   910 
   911 ML {*
   912 structure Hypsubst = HypsubstFun(
   913 struct
   914   structure Simplifier = Simplifier
   915   val dest_eq = HOLogic.dest_eq
   916   val dest_Trueprop = HOLogic.dest_Trueprop
   917   val dest_imp = HOLogic.dest_imp
   918   val eq_reflection = @{thm eq_reflection}
   919   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   920   val imp_intr = @{thm impI}
   921   val rev_mp = @{thm rev_mp}
   922   val subst = @{thm subst}
   923   val sym = @{thm sym}
   924   val thin_refl = @{thm thin_refl};
   925   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   926                      by (unfold prop_def) (drule eq_reflection, unfold)}
   927 end);
   928 open Hypsubst;
   929 
   930 structure Classical = ClassicalFun(
   931 struct
   932   val imp_elim = @{thm imp_elim}
   933   val not_elim = @{thm notE}
   934   val swap = @{thm swap}
   935   val classical = @{thm classical}
   936   val sizef = Drule.size_of_thm
   937   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   938 end);
   939 
   940 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   941 open BasicClassical;
   942 
   943 ML_Antiquote.value "claset"
   944   (Scan.succeed "Classical.local_claset_of (ML_Context.the_local_context ())");
   945 
   946 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   947 
   948 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   949 *}
   950 
   951 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   952   These theorems typically produce clauses that are prolific (match too many equality or
   953   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   954 
   955 setup {*
   956 let
   957   (*prevent substitution on bool*)
   958   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   959     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   960       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   961 in
   962   Hypsubst.hypsubst_setup
   963   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   964   #> Classical.setup
   965   #> ResAtpset.setup
   966   #> ResBlacklist.setup
   967 end
   968 *}
   969 
   970 declare iffI [intro!]
   971   and notI [intro!]
   972   and impI [intro!]
   973   and disjCI [intro!]
   974   and conjI [intro!]
   975   and TrueI [intro!]
   976   and refl [intro!]
   977 
   978 declare iffCE [elim!]
   979   and FalseE [elim!]
   980   and impCE [elim!]
   981   and disjE [elim!]
   982   and conjE [elim!]
   983   and conjE [elim!]
   984 
   985 declare ex_ex1I [intro!]
   986   and allI [intro!]
   987   and the_equality [intro]
   988   and exI [intro]
   989 
   990 declare exE [elim!]
   991   allE [elim]
   992 
   993 ML {* val HOL_cs = @{claset} *}
   994 
   995 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   996   apply (erule swap)
   997   apply (erule (1) meta_mp)
   998   done
   999 
  1000 declare ex_ex1I [rule del, intro! 2]
  1001   and ex1I [intro]
  1002 
  1003 lemmas [intro?] = ext
  1004   and [elim?] = ex1_implies_ex
  1005 
  1006 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1007 lemma alt_ex1E [elim!]:
  1008   assumes major: "\<exists>!x. P x"
  1009       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1010   shows R
  1011 apply (rule ex1E [OF major])
  1012 apply (rule prem)
  1013 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1014 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1015 apply iprover
  1016 done
  1017 
  1018 ML {*
  1019 structure Blast = BlastFun
  1020 (
  1021   type claset = Classical.claset
  1022   val equality_name = @{const_name "op ="}
  1023   val not_name = @{const_name Not}
  1024   val notE = @{thm notE}
  1025   val ccontr = @{thm ccontr}
  1026   val contr_tac = Classical.contr_tac
  1027   val dup_intr = Classical.dup_intr
  1028   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1029   val claset = Classical.claset
  1030   val rep_cs = Classical.rep_cs
  1031   val cla_modifiers = Classical.cla_modifiers
  1032   val cla_meth' = Classical.cla_meth'
  1033 );
  1034 val Blast_tac = Blast.Blast_tac;
  1035 val blast_tac = Blast.blast_tac;
  1036 *}
  1037 
  1038 setup Blast.setup
  1039 
  1040 
  1041 subsubsection {* Simplifier *}
  1042 
  1043 lemma eta_contract_eq: "(%s. f s) = f" ..
  1044 
  1045 lemma simp_thms:
  1046   shows not_not: "(~ ~ P) = P"
  1047   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1048   and
  1049     "(P ~= Q) = (P = (~Q))"
  1050     "(P | ~P) = True"    "(~P | P) = True"
  1051     "(x = x) = True"
  1052   and not_True_eq_False: "(\<not> True) = False"
  1053   and not_False_eq_True: "(\<not> False) = True"
  1054   and
  1055     "(~P) ~= P"  "P ~= (~P)"
  1056     "(True=P) = P"
  1057   and eq_True: "(P = True) = P"
  1058   and "(False=P) = (~P)"
  1059   and eq_False: "(P = False) = (\<not> P)"
  1060   and
  1061     "(True --> P) = P"  "(False --> P) = True"
  1062     "(P --> True) = True"  "(P --> P) = True"
  1063     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1064     "(P & True) = P"  "(True & P) = P"
  1065     "(P & False) = False"  "(False & P) = False"
  1066     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1067     "(P & ~P) = False"    "(~P & P) = False"
  1068     "(P | True) = True"  "(True | P) = True"
  1069     "(P | False) = P"  "(False | P) = P"
  1070     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1071     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1072     -- {* needed for the one-point-rule quantifier simplification procs *}
  1073     -- {* essential for termination!! *} and
  1074     "!!P. (EX x. x=t & P(x)) = P(t)"
  1075     "!!P. (EX x. t=x & P(x)) = P(t)"
  1076     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1077     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1078   by (blast, blast, blast, blast, blast, iprover+)
  1079 
  1080 lemma disj_absorb: "(A | A) = A"
  1081   by blast
  1082 
  1083 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1084   by blast
  1085 
  1086 lemma conj_absorb: "(A & A) = A"
  1087   by blast
  1088 
  1089 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1090   by blast
  1091 
  1092 lemma eq_ac:
  1093   shows eq_commute: "(a=b) = (b=a)"
  1094     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1095     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1096 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1097 
  1098 lemma conj_comms:
  1099   shows conj_commute: "(P&Q) = (Q&P)"
  1100     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1101 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1102 
  1103 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1104 
  1105 lemma disj_comms:
  1106   shows disj_commute: "(P|Q) = (Q|P)"
  1107     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1108 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1109 
  1110 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1111 
  1112 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1113 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1114 
  1115 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1116 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1117 
  1118 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1119 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1120 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1121 
  1122 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1123 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1124 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1125 
  1126 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1127 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1128 
  1129 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1130   by iprover
  1131 
  1132 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1133 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1134 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1135 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1136 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1137 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1138   by blast
  1139 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1140 
  1141 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1142 
  1143 
  1144 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1145   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1146   -- {* cases boil down to the same thing. *}
  1147   by blast
  1148 
  1149 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1150 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1151 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1152 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1153 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1154 
  1155 declare All_def [noatp]
  1156 
  1157 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1158 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1159 
  1160 text {*
  1161   \medskip The @{text "&"} congruence rule: not included by default!
  1162   May slow rewrite proofs down by as much as 50\% *}
  1163 
  1164 lemma conj_cong:
  1165     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1166   by iprover
  1167 
  1168 lemma rev_conj_cong:
  1169     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1170   by iprover
  1171 
  1172 text {* The @{text "|"} congruence rule: not included by default! *}
  1173 
  1174 lemma disj_cong:
  1175     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1176   by blast
  1177 
  1178 
  1179 text {* \medskip if-then-else rules *}
  1180 
  1181 lemma if_True: "(if True then x else y) = x"
  1182   by (unfold if_def) blast
  1183 
  1184 lemma if_False: "(if False then x else y) = y"
  1185   by (unfold if_def) blast
  1186 
  1187 lemma if_P: "P ==> (if P then x else y) = x"
  1188   by (unfold if_def) blast
  1189 
  1190 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1191   by (unfold if_def) blast
  1192 
  1193 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1194   apply (rule case_split [of Q])
  1195    apply (simplesubst if_P)
  1196     prefer 3 apply (simplesubst if_not_P, blast+)
  1197   done
  1198 
  1199 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1200 by (simplesubst split_if, blast)
  1201 
  1202 lemmas if_splits [noatp] = split_if split_if_asm
  1203 
  1204 lemma if_cancel: "(if c then x else x) = x"
  1205 by (simplesubst split_if, blast)
  1206 
  1207 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1208 by (simplesubst split_if, blast)
  1209 
  1210 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1211   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1212   by (rule split_if)
  1213 
  1214 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1215   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1216   apply (simplesubst split_if, blast)
  1217   done
  1218 
  1219 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1220 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1221 
  1222 text {* \medskip let rules for simproc *}
  1223 
  1224 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1225   by (unfold Let_def)
  1226 
  1227 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1228   by (unfold Let_def)
  1229 
  1230 text {*
  1231   The following copy of the implication operator is useful for
  1232   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1233   its premise.
  1234 *}
  1235 
  1236 constdefs
  1237   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1238   [code func del]: "simp_implies \<equiv> op ==>"
  1239 
  1240 lemma simp_impliesI:
  1241   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1242   shows "PROP P =simp=> PROP Q"
  1243   apply (unfold simp_implies_def)
  1244   apply (rule PQ)
  1245   apply assumption
  1246   done
  1247 
  1248 lemma simp_impliesE:
  1249   assumes PQ: "PROP P =simp=> PROP Q"
  1250   and P: "PROP P"
  1251   and QR: "PROP Q \<Longrightarrow> PROP R"
  1252   shows "PROP R"
  1253   apply (rule QR)
  1254   apply (rule PQ [unfolded simp_implies_def])
  1255   apply (rule P)
  1256   done
  1257 
  1258 lemma simp_implies_cong:
  1259   assumes PP' :"PROP P == PROP P'"
  1260   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1261   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1262 proof (unfold simp_implies_def, rule equal_intr_rule)
  1263   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1264   and P': "PROP P'"
  1265   from PP' [symmetric] and P' have "PROP P"
  1266     by (rule equal_elim_rule1)
  1267   then have "PROP Q" by (rule PQ)
  1268   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1269 next
  1270   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1271   and P: "PROP P"
  1272   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1273   then have "PROP Q'" by (rule P'Q')
  1274   with P'QQ' [OF P', symmetric] show "PROP Q"
  1275     by (rule equal_elim_rule1)
  1276 qed
  1277 
  1278 lemma uncurry:
  1279   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1280   shows "P \<and> Q \<longrightarrow> R"
  1281   using assms by blast
  1282 
  1283 lemma iff_allI:
  1284   assumes "\<And>x. P x = Q x"
  1285   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1286   using assms by blast
  1287 
  1288 lemma iff_exI:
  1289   assumes "\<And>x. P x = Q x"
  1290   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1291   using assms by blast
  1292 
  1293 lemma all_comm:
  1294   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1295   by blast
  1296 
  1297 lemma ex_comm:
  1298   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1299   by blast
  1300 
  1301 use "simpdata.ML"
  1302 ML {* open Simpdata *}
  1303 
  1304 setup {*
  1305   Simplifier.method_setup Splitter.split_modifiers
  1306   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1307   #> Splitter.setup
  1308   #> clasimp_setup
  1309   #> EqSubst.setup
  1310 *}
  1311 
  1312 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1313 
  1314 simproc_setup neq ("x = y") = {* fn _ =>
  1315 let
  1316   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1317   fun is_neq eq lhs rhs thm =
  1318     (case Thm.prop_of thm of
  1319       _ $ (Not $ (eq' $ l' $ r')) =>
  1320         Not = HOLogic.Not andalso eq' = eq andalso
  1321         r' aconv lhs andalso l' aconv rhs
  1322     | _ => false);
  1323   fun proc ss ct =
  1324     (case Thm.term_of ct of
  1325       eq $ lhs $ rhs =>
  1326         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1327           SOME thm => SOME (thm RS neq_to_EQ_False)
  1328         | NONE => NONE)
  1329      | _ => NONE);
  1330 in proc end;
  1331 *}
  1332 
  1333 simproc_setup let_simp ("Let x f") = {*
  1334 let
  1335   val (f_Let_unfold, x_Let_unfold) =
  1336     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1337     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1338   val (f_Let_folded, x_Let_folded) =
  1339     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1340     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1341   val g_Let_folded =
  1342     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1343 
  1344   fun proc _ ss ct =
  1345     let
  1346       val ctxt = Simplifier.the_context ss;
  1347       val thy = ProofContext.theory_of ctxt;
  1348       val t = Thm.term_of ct;
  1349       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1350     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1351       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1352         if is_Free x orelse is_Bound x orelse is_Const x
  1353         then SOME @{thm Let_def}
  1354         else
  1355           let
  1356             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1357             val cx = cterm_of thy x;
  1358             val {T=xT,...} = rep_cterm cx;
  1359             val cf = cterm_of thy f;
  1360             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1361             val (_$_$g) = prop_of fx_g;
  1362             val g' = abstract_over (x,g);
  1363           in (if (g aconv g')
  1364                then
  1365                   let
  1366                     val rl =
  1367                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1368                   in SOME (rl OF [fx_g]) end
  1369                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1370                else let
  1371                      val abs_g'= Abs (n,xT,g');
  1372                      val g'x = abs_g'$x;
  1373                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1374                      val rl = cterm_instantiate
  1375                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1376                                 (g_Let_folded,cterm_of thy abs_g')]
  1377                                @{thm Let_folded};
  1378                    in SOME (rl OF [transitive fx_g g_g'x])
  1379                    end)
  1380           end
  1381       | _ => NONE)
  1382     end
  1383 in proc end *}
  1384 
  1385 
  1386 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1387 proof
  1388   assume "True \<Longrightarrow> PROP P"
  1389   from this [OF TrueI] show "PROP P" .
  1390 next
  1391   assume "PROP P"
  1392   then show "PROP P" .
  1393 qed
  1394 
  1395 lemma ex_simps:
  1396   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1397   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1398   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1399   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1400   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1401   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1402   -- {* Miniscoping: pushing in existential quantifiers. *}
  1403   by (iprover | blast)+
  1404 
  1405 lemma all_simps:
  1406   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1407   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1408   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1409   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1410   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1411   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1412   -- {* Miniscoping: pushing in universal quantifiers. *}
  1413   by (iprover | blast)+
  1414 
  1415 lemmas [simp] =
  1416   triv_forall_equality (*prunes params*)
  1417   True_implies_equals  (*prune asms `True'*)
  1418   if_True
  1419   if_False
  1420   if_cancel
  1421   if_eq_cancel
  1422   imp_disjL
  1423   (*In general it seems wrong to add distributive laws by default: they
  1424     might cause exponential blow-up.  But imp_disjL has been in for a while
  1425     and cannot be removed without affecting existing proofs.  Moreover,
  1426     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1427     grounds that it allows simplification of R in the two cases.*)
  1428   conj_assoc
  1429   disj_assoc
  1430   de_Morgan_conj
  1431   de_Morgan_disj
  1432   imp_disj1
  1433   imp_disj2
  1434   not_imp
  1435   disj_not1
  1436   not_all
  1437   not_ex
  1438   cases_simp
  1439   the_eq_trivial
  1440   the_sym_eq_trivial
  1441   ex_simps
  1442   all_simps
  1443   simp_thms
  1444 
  1445 lemmas [cong] = imp_cong simp_implies_cong
  1446 lemmas [split] = split_if
  1447 
  1448 ML {* val HOL_ss = @{simpset} *}
  1449 
  1450 text {* Simplifies x assuming c and y assuming ~c *}
  1451 lemma if_cong:
  1452   assumes "b = c"
  1453       and "c \<Longrightarrow> x = u"
  1454       and "\<not> c \<Longrightarrow> y = v"
  1455   shows "(if b then x else y) = (if c then u else v)"
  1456   unfolding if_def using assms by simp
  1457 
  1458 text {* Prevents simplification of x and y:
  1459   faster and allows the execution of functional programs. *}
  1460 lemma if_weak_cong [cong]:
  1461   assumes "b = c"
  1462   shows "(if b then x else y) = (if c then x else y)"
  1463   using assms by (rule arg_cong)
  1464 
  1465 text {* Prevents simplification of t: much faster *}
  1466 lemma let_weak_cong:
  1467   assumes "a = b"
  1468   shows "(let x = a in t x) = (let x = b in t x)"
  1469   using assms by (rule arg_cong)
  1470 
  1471 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1472 lemma eq_cong2:
  1473   assumes "u = u'"
  1474   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1475   using assms by simp
  1476 
  1477 lemma if_distrib:
  1478   "f (if c then x else y) = (if c then f x else f y)"
  1479   by simp
  1480 
  1481 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1482   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1483 lemma restrict_to_left:
  1484   assumes "x = y"
  1485   shows "(x = z) = (y = z)"
  1486   using assms by simp
  1487 
  1488 
  1489 subsubsection {* Generic cases and induction *}
  1490 
  1491 text {* Rule projections: *}
  1492 
  1493 ML {*
  1494 structure ProjectRule = ProjectRuleFun
  1495 (
  1496   val conjunct1 = @{thm conjunct1}
  1497   val conjunct2 = @{thm conjunct2}
  1498   val mp = @{thm mp}
  1499 )
  1500 *}
  1501 
  1502 constdefs
  1503   induct_forall where "induct_forall P == \<forall>x. P x"
  1504   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1505   induct_equal where "induct_equal x y == x = y"
  1506   induct_conj where "induct_conj A B == A \<and> B"
  1507 
  1508 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1509   by (unfold atomize_all induct_forall_def)
  1510 
  1511 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1512   by (unfold atomize_imp induct_implies_def)
  1513 
  1514 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1515   by (unfold atomize_eq induct_equal_def)
  1516 
  1517 lemma induct_conj_eq:
  1518   includes meta_conjunction_syntax
  1519   shows "(A && B) == Trueprop (induct_conj A B)"
  1520   by (unfold atomize_conj induct_conj_def)
  1521 
  1522 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1523 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1524 lemmas induct_rulify_fallback =
  1525   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1526 
  1527 
  1528 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1529     induct_conj (induct_forall A) (induct_forall B)"
  1530   by (unfold induct_forall_def induct_conj_def) iprover
  1531 
  1532 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1533     induct_conj (induct_implies C A) (induct_implies C B)"
  1534   by (unfold induct_implies_def induct_conj_def) iprover
  1535 
  1536 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1537 proof
  1538   assume r: "induct_conj A B ==> PROP C" and A B
  1539   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1540 next
  1541   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1542   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1543 qed
  1544 
  1545 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1546 
  1547 hide const induct_forall induct_implies induct_equal induct_conj
  1548 
  1549 text {* Method setup. *}
  1550 
  1551 ML {*
  1552 structure Induct = InductFun
  1553 (
  1554   val cases_default = @{thm case_split}
  1555   val atomize = @{thms induct_atomize}
  1556   val rulify = @{thms induct_rulify}
  1557   val rulify_fallback = @{thms induct_rulify_fallback}
  1558 )
  1559 *}
  1560 
  1561 setup Induct.setup
  1562 
  1563 use "~~/src/Tools/induct_tacs.ML"
  1564 setup InductTacs.setup
  1565 
  1566 
  1567 subsubsection {* Coherent logic *}
  1568 
  1569 ML {*
  1570 structure Coherent = CoherentFun
  1571 (
  1572   val atomize_elimL = @{thm atomize_elimL}
  1573   val atomize_exL = @{thm atomize_exL}
  1574   val atomize_conjL = @{thm atomize_conjL}
  1575   val atomize_disjL = @{thm atomize_disjL}
  1576   val operator_names =
  1577     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1578 );
  1579 *}
  1580 
  1581 setup Coherent.setup
  1582 
  1583 
  1584 subsection {* Other simple lemmas and lemma duplicates *}
  1585 
  1586 lemma Let_0 [simp]: "Let 0 f = f 0"
  1587   unfolding Let_def ..
  1588 
  1589 lemma Let_1 [simp]: "Let 1 f = f 1"
  1590   unfolding Let_def ..
  1591 
  1592 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1593   by blast+
  1594 
  1595 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1596   apply (rule iffI)
  1597   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1598   apply (fast dest!: theI')
  1599   apply (fast intro: ext the1_equality [symmetric])
  1600   apply (erule ex1E)
  1601   apply (rule allI)
  1602   apply (rule ex1I)
  1603   apply (erule spec)
  1604   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1605   apply (erule impE)
  1606   apply (rule allI)
  1607   apply (case_tac "xa = x")
  1608   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1609   done
  1610 
  1611 lemma mk_left_commute:
  1612   fixes f (infix "\<otimes>" 60)
  1613   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1614           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1615   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1616   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1617 
  1618 lemmas eq_sym_conv = eq_commute
  1619 
  1620 lemma nnf_simps:
  1621   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1622   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1623   "(\<not> \<not>(P)) = P"
  1624 by blast+
  1625 
  1626 
  1627 subsection {* Basic ML bindings *}
  1628 
  1629 ML {*
  1630 val FalseE = @{thm FalseE}
  1631 val Let_def = @{thm Let_def}
  1632 val TrueI = @{thm TrueI}
  1633 val allE = @{thm allE}
  1634 val allI = @{thm allI}
  1635 val all_dupE = @{thm all_dupE}
  1636 val arg_cong = @{thm arg_cong}
  1637 val box_equals = @{thm box_equals}
  1638 val ccontr = @{thm ccontr}
  1639 val classical = @{thm classical}
  1640 val conjE = @{thm conjE}
  1641 val conjI = @{thm conjI}
  1642 val conjunct1 = @{thm conjunct1}
  1643 val conjunct2 = @{thm conjunct2}
  1644 val disjCI = @{thm disjCI}
  1645 val disjE = @{thm disjE}
  1646 val disjI1 = @{thm disjI1}
  1647 val disjI2 = @{thm disjI2}
  1648 val eq_reflection = @{thm eq_reflection}
  1649 val ex1E = @{thm ex1E}
  1650 val ex1I = @{thm ex1I}
  1651 val ex1_implies_ex = @{thm ex1_implies_ex}
  1652 val exE = @{thm exE}
  1653 val exI = @{thm exI}
  1654 val excluded_middle = @{thm excluded_middle}
  1655 val ext = @{thm ext}
  1656 val fun_cong = @{thm fun_cong}
  1657 val iffD1 = @{thm iffD1}
  1658 val iffD2 = @{thm iffD2}
  1659 val iffI = @{thm iffI}
  1660 val impE = @{thm impE}
  1661 val impI = @{thm impI}
  1662 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1663 val mp = @{thm mp}
  1664 val notE = @{thm notE}
  1665 val notI = @{thm notI}
  1666 val not_all = @{thm not_all}
  1667 val not_ex = @{thm not_ex}
  1668 val not_iff = @{thm not_iff}
  1669 val not_not = @{thm not_not}
  1670 val not_sym = @{thm not_sym}
  1671 val refl = @{thm refl}
  1672 val rev_mp = @{thm rev_mp}
  1673 val spec = @{thm spec}
  1674 val ssubst = @{thm ssubst}
  1675 val subst = @{thm subst}
  1676 val sym = @{thm sym}
  1677 val trans = @{thm trans}
  1678 *}
  1679 
  1680 
  1681 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1682 
  1683 setup {*
  1684   Code.map_pre (K HOL_basic_ss)
  1685   #> Code.map_post (K HOL_basic_ss)
  1686 *}
  1687 
  1688 code_datatype True False
  1689 
  1690 code_datatype "TYPE('a\<Colon>{})"
  1691 
  1692 code_datatype Trueprop "prop"
  1693 
  1694 lemma Let_case_cert:
  1695   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1696   shows "CASE x \<equiv> f x"
  1697   using assms by simp_all
  1698 
  1699 lemma If_case_cert:
  1700   includes meta_conjunction_syntax
  1701   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1702   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1703   using assms by simp_all
  1704 
  1705 setup {*
  1706   Code.add_case @{thm Let_case_cert}
  1707   #> Code.add_case @{thm If_case_cert}
  1708   #> Code.add_undefined @{const_name undefined}
  1709 *}
  1710 
  1711 class eq = type +
  1712   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1713   assumes eq: "eq x y \<longleftrightarrow> x = y "
  1714 begin
  1715 
  1716 lemma equals_eq [code inline, code func]: "op = \<equiv> eq"
  1717   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq)
  1718 
  1719 declare equals_eq [symmetric, code post]
  1720 
  1721 end
  1722 
  1723 hide (open) const eq
  1724 hide const eq
  1725 
  1726 setup {*
  1727   Code_Unit.add_const_alias @{thm equals_eq}
  1728   #> Code_Name.setup
  1729   #> Code_ML.setup
  1730   #> Code_Haskell.setup
  1731   #> Nbe.setup
  1732   #> Codegen.setup
  1733 *}
  1734 
  1735 lemma [code func]:
  1736   shows "False \<and> x \<longleftrightarrow> False"
  1737     and "True \<and> x \<longleftrightarrow> x"
  1738     and "x \<and> False \<longleftrightarrow> False"
  1739     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1740 
  1741 lemma [code func]:
  1742   shows "False \<or> x \<longleftrightarrow> x"
  1743     and "True \<or> x \<longleftrightarrow> True"
  1744     and "x \<or> False \<longleftrightarrow> x"
  1745     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1746 
  1747 lemma [code func]:
  1748   shows "\<not> True \<longleftrightarrow> False"
  1749     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1750 
  1751 lemmas [code func] = Let_def if_True if_False
  1752 
  1753 lemmas [code func, code unfold, symmetric, code post] = imp_conv_disj
  1754 
  1755 
  1756 subsection {* Legacy tactics and ML bindings *}
  1757 
  1758 ML {*
  1759 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1760 
  1761 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1762 local
  1763   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1764     | wrong_prem (Bound _) = true
  1765     | wrong_prem _ = false;
  1766   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1767 in
  1768   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1769   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1770 end;
  1771 
  1772 val all_conj_distrib = thm "all_conj_distrib";
  1773 val all_simps = thms "all_simps";
  1774 val atomize_not = thm "atomize_not";
  1775 val case_split = thm "case_split";
  1776 val cases_simp = thm "cases_simp";
  1777 val choice_eq = thm "choice_eq"
  1778 val cong = thm "cong"
  1779 val conj_comms = thms "conj_comms";
  1780 val conj_cong = thm "conj_cong";
  1781 val de_Morgan_conj = thm "de_Morgan_conj";
  1782 val de_Morgan_disj = thm "de_Morgan_disj";
  1783 val disj_assoc = thm "disj_assoc";
  1784 val disj_comms = thms "disj_comms";
  1785 val disj_cong = thm "disj_cong";
  1786 val eq_ac = thms "eq_ac";
  1787 val eq_cong2 = thm "eq_cong2"
  1788 val Eq_FalseI = thm "Eq_FalseI";
  1789 val Eq_TrueI = thm "Eq_TrueI";
  1790 val Ex1_def = thm "Ex1_def"
  1791 val ex_disj_distrib = thm "ex_disj_distrib";
  1792 val ex_simps = thms "ex_simps";
  1793 val if_cancel = thm "if_cancel";
  1794 val if_eq_cancel = thm "if_eq_cancel";
  1795 val if_False = thm "if_False";
  1796 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1797 val iff = thm "iff"
  1798 val if_splits = thms "if_splits";
  1799 val if_True = thm "if_True";
  1800 val if_weak_cong = thm "if_weak_cong"
  1801 val imp_all = thm "imp_all";
  1802 val imp_cong = thm "imp_cong";
  1803 val imp_conjL = thm "imp_conjL";
  1804 val imp_conjR = thm "imp_conjR";
  1805 val imp_conv_disj = thm "imp_conv_disj";
  1806 val simp_implies_def = thm "simp_implies_def";
  1807 val simp_thms = thms "simp_thms";
  1808 val split_if = thm "split_if";
  1809 val the1_equality = thm "the1_equality"
  1810 val theI = thm "theI"
  1811 val theI' = thm "theI'"
  1812 val True_implies_equals = thm "True_implies_equals";
  1813 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1814 
  1815 *}
  1816 
  1817 end