src/HOL/Parity.thy
author huffman
Sat Mar 06 18:24:30 2010 -0800 (2010-03-06)
changeset 35631 0b8a5fd339ab
parent 35216 7641e8d831d2
child 35644 d20cf282342e
permissions -rw-r--r--
generalize some lemmas from class linordered_ring_strict to linordered_ring
     1 (*  Title:      HOL/Library/Parity.thy
     2     Author:     Jeremy Avigad, Jacques D. Fleuriot
     3 *)
     4 
     5 header {* Even and Odd for int and nat *}
     6 
     7 theory Parity
     8 imports Main
     9 begin
    10 
    11 class even_odd = 
    12   fixes even :: "'a \<Rightarrow> bool"
    13 
    14 abbreviation
    15   odd :: "'a\<Colon>even_odd \<Rightarrow> bool" where
    16   "odd x \<equiv> \<not> even x"
    17 
    18 instantiation nat and int  :: even_odd
    19 begin
    20 
    21 definition
    22   even_def [presburger]: "even x \<longleftrightarrow> (x\<Colon>int) mod 2 = 0"
    23 
    24 definition
    25   even_nat_def [presburger]: "even x \<longleftrightarrow> even (int x)"
    26 
    27 instance ..
    28 
    29 end
    30 
    31 lemma transfer_int_nat_relations:
    32   "even (int x) \<longleftrightarrow> even x"
    33   by (simp add: even_nat_def)
    34 
    35 declare TransferMorphism_int_nat[transfer add return:
    36   transfer_int_nat_relations
    37 ]
    38 
    39 lemma even_zero_int[simp]: "even (0::int)" by presburger
    40 
    41 lemma odd_one_int[simp]: "odd (1::int)" by presburger
    42 
    43 lemma even_zero_nat[simp]: "even (0::nat)" by presburger
    44 
    45 lemma odd_1_nat [simp]: "odd (1::nat)" by presburger
    46 
    47 declare even_def[of "number_of v", standard, simp]
    48 
    49 declare even_nat_def[of "number_of v", standard, simp]
    50 
    51 subsection {* Even and odd are mutually exclusive *}
    52 
    53 lemma int_pos_lt_two_imp_zero_or_one:
    54     "0 <= x ==> (x::int) < 2 ==> x = 0 | x = 1"
    55   by presburger
    56 
    57 lemma neq_one_mod_two [simp, presburger]: 
    58   "((x::int) mod 2 ~= 0) = (x mod 2 = 1)" by presburger
    59 
    60 
    61 subsection {* Behavior under integer arithmetic operations *}
    62 declare dvd_def[algebra]
    63 lemma nat_even_iff_2_dvd[algebra]: "even (x::nat) \<longleftrightarrow> 2 dvd x"
    64   by (presburger add: even_nat_def even_def)
    65 lemma int_even_iff_2_dvd[algebra]: "even (x::int) \<longleftrightarrow> 2 dvd x"
    66   by presburger
    67 
    68 lemma even_times_anything: "even (x::int) ==> even (x * y)"
    69   by algebra
    70 
    71 lemma anything_times_even: "even (y::int) ==> even (x * y)" by algebra
    72 
    73 lemma odd_times_odd: "odd (x::int) ==> odd y ==> odd (x * y)" 
    74   by (simp add: even_def zmod_zmult1_eq)
    75 
    76 lemma even_product[simp,presburger]: "even((x::int) * y) = (even x | even y)"
    77   apply (auto simp add: even_times_anything anything_times_even)
    78   apply (rule ccontr)
    79   apply (auto simp add: odd_times_odd)
    80   done
    81 
    82 lemma even_plus_even: "even (x::int) ==> even y ==> even (x + y)"
    83 by presburger
    84 
    85 lemma even_plus_odd: "even (x::int) ==> odd y ==> odd (x + y)"
    86 by presburger
    87 
    88 lemma odd_plus_even: "odd (x::int) ==> even y ==> odd (x + y)"
    89 by presburger
    90 
    91 lemma odd_plus_odd: "odd (x::int) ==> odd y ==> even (x + y)" by presburger
    92 
    93 lemma even_sum[simp,presburger]:
    94   "even ((x::int) + y) = ((even x & even y) | (odd x & odd y))"
    95 by presburger
    96 
    97 lemma even_neg[simp,presburger,algebra]: "even (-(x::int)) = even x"
    98 by presburger
    99 
   100 lemma even_difference[simp]:
   101     "even ((x::int) - y) = ((even x & even y) | (odd x & odd y))" by presburger
   102 
   103 lemma even_power[simp,presburger]: "even ((x::int)^n) = (even x & n \<noteq> 0)"
   104 by (induct n) auto
   105 
   106 lemma odd_pow: "odd x ==> odd((x::int)^n)" by simp
   107 
   108 
   109 subsection {* Equivalent definitions *}
   110 
   111 lemma two_times_even_div_two: "even (x::int) ==> 2 * (x div 2) = x" 
   112 by presburger
   113 
   114 lemma two_times_odd_div_two_plus_one:
   115   "odd (x::int) ==> 2 * (x div 2) + 1 = x"
   116 by presburger
   117 
   118 lemma even_equiv_def: "even (x::int) = (EX y. x = 2 * y)" by presburger
   119 
   120 lemma odd_equiv_def: "odd (x::int) = (EX y. x = 2 * y + 1)" by presburger
   121 
   122 subsection {* even and odd for nats *}
   123 
   124 lemma pos_int_even_equiv_nat_even: "0 \<le> x ==> even x = even (nat x)"
   125 by (simp add: even_nat_def)
   126 
   127 lemma even_product_nat[simp,presburger,algebra]:
   128   "even((x::nat) * y) = (even x | even y)"
   129 by (simp add: even_nat_def int_mult)
   130 
   131 lemma even_sum_nat[simp,presburger,algebra]:
   132   "even ((x::nat) + y) = ((even x & even y) | (odd x & odd y))"
   133 by presburger
   134 
   135 lemma even_difference_nat[simp,presburger,algebra]:
   136   "even ((x::nat) - y) = (x < y | (even x & even y) | (odd x & odd y))"
   137 by presburger
   138 
   139 lemma even_Suc[simp,presburger,algebra]: "even (Suc x) = odd x"
   140 by presburger
   141 
   142 lemma even_power_nat[simp,presburger,algebra]:
   143   "even ((x::nat)^y) = (even x & 0 < y)"
   144 by (simp add: even_nat_def int_power)
   145 
   146 
   147 subsection {* Equivalent definitions *}
   148 
   149 lemma nat_lt_two_imp_zero_or_one:
   150   "(x::nat) < Suc (Suc 0) ==> x = 0 | x = Suc 0"
   151 by presburger
   152 
   153 lemma even_nat_mod_two_eq_zero: "even (x::nat) ==> x mod (Suc (Suc 0)) = 0"
   154 by presburger
   155 
   156 lemma odd_nat_mod_two_eq_one: "odd (x::nat) ==> x mod (Suc (Suc 0)) = Suc 0"
   157 by presburger
   158 
   159 lemma even_nat_equiv_def: "even (x::nat) = (x mod Suc (Suc 0) = 0)"
   160 by presburger
   161 
   162 lemma odd_nat_equiv_def: "odd (x::nat) = (x mod Suc (Suc 0) = Suc 0)"
   163 by presburger
   164 
   165 lemma even_nat_div_two_times_two: "even (x::nat) ==>
   166     Suc (Suc 0) * (x div Suc (Suc 0)) = x" by presburger
   167 
   168 lemma odd_nat_div_two_times_two_plus_one: "odd (x::nat) ==>
   169     Suc( Suc (Suc 0) * (x div Suc (Suc 0))) = x" by presburger
   170 
   171 lemma even_nat_equiv_def2: "even (x::nat) = (EX y. x = Suc (Suc 0) * y)"
   172 by presburger
   173 
   174 lemma odd_nat_equiv_def2: "odd (x::nat) = (EX y. x = Suc(Suc (Suc 0) * y))"
   175 by presburger
   176 
   177 
   178 subsection {* Parity and powers *}
   179 
   180 lemma  minus_one_even_odd_power:
   181      "(even x --> (- 1::'a::{comm_ring_1})^x = 1) &
   182       (odd x --> (- 1::'a)^x = - 1)"
   183   apply (induct x)
   184   apply (rule conjI)
   185   apply simp
   186   apply (insert even_zero_nat, blast)
   187   apply simp
   188   done
   189 
   190 lemma minus_one_even_power [simp]:
   191     "even x ==> (- 1::'a::{comm_ring_1})^x = 1"
   192   using minus_one_even_odd_power by blast
   193 
   194 lemma minus_one_odd_power [simp]:
   195     "odd x ==> (- 1::'a::{comm_ring_1})^x = - 1"
   196   using minus_one_even_odd_power by blast
   197 
   198 lemma neg_one_even_odd_power:
   199      "(even x --> (-1::'a::{number_ring})^x = 1) &
   200       (odd x --> (-1::'a)^x = -1)"
   201   apply (induct x)
   202   apply (simp, simp)
   203   done
   204 
   205 lemma neg_one_even_power [simp]:
   206     "even x ==> (-1::'a::{number_ring})^x = 1"
   207   using neg_one_even_odd_power by blast
   208 
   209 lemma neg_one_odd_power [simp]:
   210     "odd x ==> (-1::'a::{number_ring})^x = -1"
   211   using neg_one_even_odd_power by blast
   212 
   213 lemma neg_power_if:
   214      "(-x::'a::{comm_ring_1}) ^ n =
   215       (if even n then (x ^ n) else -(x ^ n))"
   216   apply (induct n)
   217   apply simp_all
   218   done
   219 
   220 lemma zero_le_even_power: "even n ==>
   221     0 <= (x::'a::{linordered_ring,monoid_mult}) ^ n"
   222   apply (simp add: even_nat_equiv_def2)
   223   apply (erule exE)
   224   apply (erule ssubst)
   225   apply (subst power_add)
   226   apply (rule zero_le_square)
   227   done
   228 
   229 lemma zero_le_odd_power: "odd n ==>
   230     (0 <= (x::'a::{linordered_idom}) ^ n) = (0 <= x)"
   231 apply (auto simp: odd_nat_equiv_def2 power_add zero_le_mult_iff)
   232 apply (metis field_power_not_zero no_zero_divirors_neq0 order_antisym_conv zero_le_square)
   233 done
   234 
   235 lemma zero_le_power_eq[presburger]: "(0 <= (x::'a::{linordered_idom}) ^ n) =
   236     (even n | (odd n & 0 <= x))"
   237   apply auto
   238   apply (subst zero_le_odd_power [symmetric])
   239   apply assumption+
   240   apply (erule zero_le_even_power)
   241   done
   242 
   243 lemma zero_less_power_eq[presburger]: "(0 < (x::'a::{linordered_idom}) ^ n) =
   244     (n = 0 | (even n & x ~= 0) | (odd n & 0 < x))"
   245 
   246   unfolding order_less_le zero_le_power_eq by auto
   247 
   248 lemma power_less_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n < 0) =
   249     (odd n & x < 0)"
   250   apply (subst linorder_not_le [symmetric])+
   251   apply (subst zero_le_power_eq)
   252   apply auto
   253   done
   254 
   255 lemma power_le_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n <= 0) =
   256     (n ~= 0 & ((odd n & x <= 0) | (even n & x = 0)))"
   257   apply (subst linorder_not_less [symmetric])+
   258   apply (subst zero_less_power_eq)
   259   apply auto
   260   done
   261 
   262 lemma power_even_abs: "even n ==>
   263     (abs (x::'a::{linordered_idom}))^n = x^n"
   264   apply (subst power_abs [symmetric])
   265   apply (simp add: zero_le_even_power)
   266   done
   267 
   268 lemma zero_less_power_nat_eq[presburger]: "(0 < (x::nat) ^ n) = (n = 0 | 0 < x)"
   269   by (induct n) auto
   270 
   271 lemma power_minus_even [simp]: "even n ==>
   272     (- x)^n = (x^n::'a::{comm_ring_1})"
   273   apply (subst power_minus)
   274   apply simp
   275   done
   276 
   277 lemma power_minus_odd [simp]: "odd n ==>
   278     (- x)^n = - (x^n::'a::{comm_ring_1})"
   279   apply (subst power_minus)
   280   apply simp
   281   done
   282 
   283 lemma power_mono_even: fixes x y :: "'a :: {linordered_idom}"
   284   assumes "even n" and "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   285   shows "x^n \<le> y^n"
   286 proof -
   287   have "0 \<le> \<bar>x\<bar>" by auto
   288   with `\<bar>x\<bar> \<le> \<bar>y\<bar>`
   289   have "\<bar>x\<bar>^n \<le> \<bar>y\<bar>^n" by (rule power_mono)
   290   thus ?thesis unfolding power_even_abs[OF `even n`] .
   291 qed
   292 
   293 lemma odd_pos: "odd (n::nat) \<Longrightarrow> 0 < n" by presburger
   294 
   295 lemma power_mono_odd: fixes x y :: "'a :: {linordered_idom}"
   296   assumes "odd n" and "x \<le> y"
   297   shows "x^n \<le> y^n"
   298 proof (cases "y < 0")
   299   case True with `x \<le> y` have "-y \<le> -x" and "0 \<le> -y" by auto
   300   hence "(-y)^n \<le> (-x)^n" by (rule power_mono)
   301   thus ?thesis unfolding power_minus_odd[OF `odd n`] by auto
   302 next
   303   case False
   304   show ?thesis
   305   proof (cases "x < 0")
   306     case True hence "n \<noteq> 0" and "x \<le> 0" using `odd n`[THEN odd_pos] by auto
   307     hence "x^n \<le> 0" unfolding power_le_zero_eq using `odd n` by auto
   308     moreover
   309     from `\<not> y < 0` have "0 \<le> y" by auto
   310     hence "0 \<le> y^n" by auto
   311     ultimately show ?thesis by auto
   312   next
   313     case False hence "0 \<le> x" by auto
   314     with `x \<le> y` show ?thesis using power_mono by auto
   315   qed
   316 qed
   317 
   318 
   319 subsection {* More Even/Odd Results *}
   320  
   321 lemma even_mult_two_ex: "even(n) = (\<exists>m::nat. n = 2*m)" by presburger
   322 lemma odd_Suc_mult_two_ex: "odd(n) = (\<exists>m. n = Suc (2*m))" by presburger
   323 lemma even_add [simp]: "even(m + n::nat) = (even m = even n)"  by presburger
   324 
   325 lemma odd_add [simp]: "odd(m + n::nat) = (odd m \<noteq> odd n)" by presburger
   326 
   327 lemma div_Suc: "Suc a div c = a div c + Suc 0 div c +
   328     (a mod c + Suc 0 mod c) div c" 
   329   apply (subgoal_tac "Suc a = a + Suc 0")
   330   apply (erule ssubst)
   331   apply (rule div_add1_eq, simp)
   332   done
   333 
   334 lemma lemma_even_div2 [simp]: "even (n::nat) ==> (n + 1) div 2 = n div 2" by presburger
   335 
   336 lemma lemma_not_even_div2 [simp]: "~even n ==> (n + 1) div 2 = Suc (n div 2)"
   337 by presburger
   338 
   339 lemma even_num_iff: "0 < n ==> even n = (~ even(n - 1 :: nat))"  by presburger
   340 lemma even_even_mod_4_iff: "even (n::nat) = even (n mod 4)" by presburger
   341 
   342 lemma lemma_odd_mod_4_div_2: "n mod 4 = (3::nat) ==> odd((n - 1) div 2)" by presburger
   343 
   344 lemma lemma_even_mod_4_div_2: "n mod 4 = (1::nat) ==> even ((n - 1) div 2)"
   345   by presburger
   346 
   347 text {* Simplify, when the exponent is a numeral *}
   348 
   349 lemmas power_0_left_number_of = power_0_left [of "number_of w", standard]
   350 declare power_0_left_number_of [simp]
   351 
   352 lemmas zero_le_power_eq_number_of [simp] =
   353     zero_le_power_eq [of _ "number_of w", standard]
   354 
   355 lemmas zero_less_power_eq_number_of [simp] =
   356     zero_less_power_eq [of _ "number_of w", standard]
   357 
   358 lemmas power_le_zero_eq_number_of [simp] =
   359     power_le_zero_eq [of _ "number_of w", standard]
   360 
   361 lemmas power_less_zero_eq_number_of [simp] =
   362     power_less_zero_eq [of _ "number_of w", standard]
   363 
   364 lemmas zero_less_power_nat_eq_number_of [simp] =
   365     zero_less_power_nat_eq [of _ "number_of w", standard]
   366 
   367 lemmas power_eq_0_iff_number_of [simp] = power_eq_0_iff [of _ "number_of w", standard]
   368 
   369 lemmas power_even_abs_number_of [simp] = power_even_abs [of "number_of w" _, standard]
   370 
   371 
   372 subsection {* An Equivalence for @{term [source] "0 \<le> a^n"} *}
   373 
   374 lemma even_power_le_0_imp_0:
   375     "a ^ (2*k) \<le> (0::'a::{linordered_idom}) ==> a=0"
   376   by (induct k) (auto simp add: zero_le_mult_iff mult_le_0_iff)
   377 
   378 lemma zero_le_power_iff[presburger]:
   379   "(0 \<le> a^n) = (0 \<le> (a::'a::{linordered_idom}) | even n)"
   380 proof cases
   381   assume even: "even n"
   382   then obtain k where "n = 2*k"
   383     by (auto simp add: even_nat_equiv_def2 numeral_2_eq_2)
   384   thus ?thesis by (simp add: zero_le_even_power even)
   385 next
   386   assume odd: "odd n"
   387   then obtain k where "n = Suc(2*k)"
   388     by (auto simp add: odd_nat_equiv_def2 numeral_2_eq_2)
   389   thus ?thesis
   390     by (auto simp add: zero_le_mult_iff zero_le_even_power
   391              dest!: even_power_le_0_imp_0)
   392 qed
   393 
   394 
   395 subsection {* Miscellaneous *}
   396 
   397 lemma [presburger]:"(x + 1) div 2 = x div 2 \<longleftrightarrow> even (x::int)" by presburger
   398 lemma [presburger]: "(x + 1) div 2 = x div 2 + 1 \<longleftrightarrow> odd (x::int)" by presburger
   399 lemma even_plus_one_div_two: "even (x::int) ==> (x + 1) div 2 = x div 2"  by presburger
   400 lemma odd_plus_one_div_two: "odd (x::int) ==> (x + 1) div 2 = x div 2 + 1" by presburger
   401 
   402 lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
   403 lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
   404 lemma even_nat_plus_one_div_two: "even (x::nat) ==>
   405     (Suc x) div Suc (Suc 0) = x div Suc (Suc 0)" by presburger
   406 
   407 lemma odd_nat_plus_one_div_two: "odd (x::nat) ==>
   408     (Suc x) div Suc (Suc 0) = Suc (x div Suc (Suc 0))" by presburger
   409 
   410 end