src/HOL/Set.ML
author paulson
Mon May 22 12:29:02 2000 +0200 (2000-05-22)
changeset 8913 0bc13d5e60b8
parent 8839 31da5b9790c0
child 9041 3730ae0f513a
permissions -rw-r--r--
psubsetI is a safe rule
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 bind_thm ("CollectE", make_elim CollectD);
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 bind_thms ("strip", [impI, allI, ballI]);
    48 
    49 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    50 by (Blast_tac 1);
    51 qed "bspec";
    52 
    53 val major::prems = Goalw [Ball_def]
    54     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    55 by (rtac (major RS spec RS impCE) 1);
    56 by (REPEAT (eresolve_tac prems 1));
    57 qed "ballE";
    58 
    59 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    60 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    61 
    62 AddSIs [ballI];
    63 AddEs  [ballE];
    64 AddXDs [bspec];
    65 (* gives better instantiation for bound: *)
    66 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    67 			 (dtac bspec THEN' atac) APPEND' tac2);
    68 
    69 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    70 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    71 by (Blast_tac 1);
    72 qed "bexI";
    73 
    74 (*The best argument order when there is only one x:A*)
    75 Goalw [Bex_def] "[| x:A;  P(x) |] ==> ? x:A. P(x)";
    76 by (Blast_tac 1);
    77 qed "rev_bexI";
    78 
    79 val prems = Goal 
    80    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)";
    81 by (rtac classical 1);
    82 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    83 qed "bexCI";
    84 
    85 val major::prems = Goalw [Bex_def]
    86     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    87 by (rtac (major RS exE) 1);
    88 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    89 qed "bexE";
    90 
    91 AddIs  [bexI];
    92 AddSEs [bexE];
    93 
    94 (*Trival rewrite rule*)
    95 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    96 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    97 qed "ball_triv";
    98 
    99 (*Dual form for existentials*)
   100 Goal "(? x:A. P) = ((? x. x:A) & P)";
   101 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   102 qed "bex_triv";
   103 
   104 Addsimps [ball_triv, bex_triv];
   105 
   106 (** Congruence rules **)
   107 
   108 val prems = Goalw [Ball_def]
   109     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   110 \    (! x:A. P(x)) = (! x:B. Q(x))";
   111 by (asm_simp_tac (simpset() addsimps prems) 1);
   112 qed "ball_cong";
   113 
   114 val prems = Goalw [Bex_def]
   115     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   116 \    (? x:A. P(x)) = (? x:B. Q(x))";
   117 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   118 qed "bex_cong";
   119 
   120 Addcongs [ball_cong,bex_cong];
   121 
   122 section "Subsets";
   123 
   124 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   125 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   126 qed "subsetI";
   127 
   128 (*Map the type ('a set => anything) to just 'a.
   129   For overloading constants whose first argument has type "'a set" *)
   130 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   131 
   132 (*While (:) is not, its type must be kept
   133   for overloading of = to work.*)
   134 Blast.overloaded ("op :", domain_type);
   135 
   136 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   137 overload_1st_set "Bex";
   138 
   139 (*Image: retain the type of the set being expressed*)
   140 Blast.overloaded ("image", domain_type);
   141 
   142 (*Rule in Modus Ponens style*)
   143 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   144 by (Blast_tac 1);
   145 qed "subsetD";
   146 AddXIs [subsetD];
   147 
   148 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   149 Goal "[| c:A;  A <= B |] ==> c:B";
   150 by (REPEAT (ares_tac [subsetD] 1)) ;
   151 qed "rev_subsetD";
   152 AddXIs [rev_subsetD];
   153 
   154 (*Converts A<=B to x:A ==> x:B*)
   155 fun impOfSubs th = th RSN (2, rev_subsetD);
   156 
   157 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   158 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   159 qed "contra_subsetD";
   160 
   161 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   162 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   163 qed "rev_contra_subsetD";
   164 
   165 (*Classical elimination rule*)
   166 val major::prems = Goalw [subset_def] 
   167     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   168 by (rtac (major RS ballE) 1);
   169 by (REPEAT (eresolve_tac prems 1));
   170 qed "subsetCE";
   171 
   172 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   173 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   174 
   175 AddSIs [subsetI];
   176 AddEs  [subsetD, subsetCE];
   177 
   178 Goal "A <= (A::'a set)";
   179 by (Fast_tac 1);
   180 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   181 
   182 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   183 by (Blast_tac 1);
   184 qed "subset_trans";
   185 
   186 
   187 section "Equality";
   188 
   189 (*Anti-symmetry of the subset relation*)
   190 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   191 by (rtac set_ext 1);
   192 by (blast_tac (claset() addIs [subsetD]) 1);
   193 qed "subset_antisym";
   194 val equalityI = subset_antisym;
   195 
   196 AddSIs [equalityI];
   197 
   198 (* Equality rules from ZF set theory -- are they appropriate here? *)
   199 Goal "A = B ==> A<=(B::'a set)";
   200 by (etac ssubst 1);
   201 by (rtac subset_refl 1);
   202 qed "equalityD1";
   203 
   204 Goal "A = B ==> B<=(A::'a set)";
   205 by (etac ssubst 1);
   206 by (rtac subset_refl 1);
   207 qed "equalityD2";
   208 
   209 val prems = Goal
   210     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   211 by (resolve_tac prems 1);
   212 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   213 qed "equalityE";
   214 
   215 val major::prems = Goal
   216     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   217 by (rtac (major RS equalityE) 1);
   218 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   219 qed "equalityCE";
   220 
   221 (*Lemma for creating induction formulae -- for "pattern matching" on p
   222   To make the induction hypotheses usable, apply "spec" or "bspec" to
   223   put universal quantifiers over the free variables in p. *)
   224 val prems = Goal 
   225     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   226 by (rtac mp 1);
   227 by (REPEAT (resolve_tac (refl::prems) 1));
   228 qed "setup_induction";
   229 
   230 Goal "A = B ==> (x : A) = (x : B)";
   231 by (Asm_simp_tac 1);
   232 qed "eqset_imp_iff";
   233 
   234 
   235 section "The universal set -- UNIV";
   236 
   237 Goalw [UNIV_def] "x : UNIV";
   238 by (rtac CollectI 1);
   239 by (rtac TrueI 1);
   240 qed "UNIV_I";
   241 
   242 Addsimps [UNIV_I];
   243 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   244 
   245 Goal "A <= UNIV";
   246 by (rtac subsetI 1);
   247 by (rtac UNIV_I 1);
   248 qed "subset_UNIV";
   249 
   250 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   251     because of their interaction with congruence rules. **)
   252 
   253 Goalw [Ball_def] "Ball UNIV P = All P";
   254 by (Simp_tac 1);
   255 qed "ball_UNIV";
   256 
   257 Goalw [Bex_def] "Bex UNIV P = Ex P";
   258 by (Simp_tac 1);
   259 qed "bex_UNIV";
   260 Addsimps [ball_UNIV, bex_UNIV];
   261 
   262 
   263 section "The empty set -- {}";
   264 
   265 Goalw [empty_def] "(c : {}) = False";
   266 by (Blast_tac 1) ;
   267 qed "empty_iff";
   268 
   269 Addsimps [empty_iff];
   270 
   271 Goal "a:{} ==> P";
   272 by (Full_simp_tac 1);
   273 qed "emptyE";
   274 
   275 AddSEs [emptyE];
   276 
   277 Goal "{} <= A";
   278 by (Blast_tac 1) ;
   279 qed "empty_subsetI";
   280 
   281 (*One effect is to delete the ASSUMPTION {} <= A*)
   282 AddIffs [empty_subsetI];
   283 
   284 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   285 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   286 qed "equals0I";
   287 
   288 (*Use for reasoning about disjointness: A Int B = {} *)
   289 Goal "A={} ==> a ~: A";
   290 by (Blast_tac 1) ;
   291 qed "equals0D";
   292 
   293 AddDs [equals0D, sym RS equals0D];
   294 
   295 Goalw [Ball_def] "Ball {} P = True";
   296 by (Simp_tac 1);
   297 qed "ball_empty";
   298 
   299 Goalw [Bex_def] "Bex {} P = False";
   300 by (Simp_tac 1);
   301 qed "bex_empty";
   302 Addsimps [ball_empty, bex_empty];
   303 
   304 Goal "UNIV ~= {}";
   305 by (blast_tac (claset() addEs [equalityE]) 1);
   306 qed "UNIV_not_empty";
   307 AddIffs [UNIV_not_empty];
   308 
   309 
   310 
   311 section "The Powerset operator -- Pow";
   312 
   313 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   314 by (Asm_simp_tac 1);
   315 qed "Pow_iff";
   316 
   317 AddIffs [Pow_iff]; 
   318 
   319 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   320 by (etac CollectI 1);
   321 qed "PowI";
   322 
   323 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   324 by (etac CollectD 1);
   325 qed "PowD";
   326 
   327 
   328 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   329 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   330 
   331 
   332 section "Set complement";
   333 
   334 Goalw [Compl_def] "(c : -A) = (c~:A)";
   335 by (Blast_tac 1);
   336 qed "Compl_iff";
   337 
   338 Addsimps [Compl_iff];
   339 
   340 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   341 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   342 qed "ComplI";
   343 
   344 (*This form, with negated conclusion, works well with the Classical prover.
   345   Negated assumptions behave like formulae on the right side of the notional
   346   turnstile...*)
   347 Goalw [Compl_def] "c : -A ==> c~:A";
   348 by (etac CollectD 1);
   349 qed "ComplD";
   350 
   351 val ComplE = make_elim ComplD;
   352 
   353 AddSIs [ComplI];
   354 AddSEs [ComplE];
   355 
   356 
   357 section "Binary union -- Un";
   358 
   359 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   360 by (Blast_tac 1);
   361 qed "Un_iff";
   362 Addsimps [Un_iff];
   363 
   364 Goal "c:A ==> c : A Un B";
   365 by (Asm_simp_tac 1);
   366 qed "UnI1";
   367 
   368 Goal "c:B ==> c : A Un B";
   369 by (Asm_simp_tac 1);
   370 qed "UnI2";
   371 
   372 (*Classical introduction rule: no commitment to A vs B*)
   373 
   374 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   375 by (Simp_tac 1);
   376 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   377 qed "UnCI";
   378 
   379 val major::prems = Goalw [Un_def]
   380     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   381 by (rtac (major RS CollectD RS disjE) 1);
   382 by (REPEAT (eresolve_tac prems 1));
   383 qed "UnE";
   384 
   385 AddSIs [UnCI];
   386 AddSEs [UnE];
   387 
   388 
   389 section "Binary intersection -- Int";
   390 
   391 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   392 by (Blast_tac 1);
   393 qed "Int_iff";
   394 Addsimps [Int_iff];
   395 
   396 Goal "[| c:A;  c:B |] ==> c : A Int B";
   397 by (Asm_simp_tac 1);
   398 qed "IntI";
   399 
   400 Goal "c : A Int B ==> c:A";
   401 by (Asm_full_simp_tac 1);
   402 qed "IntD1";
   403 
   404 Goal "c : A Int B ==> c:B";
   405 by (Asm_full_simp_tac 1);
   406 qed "IntD2";
   407 
   408 val [major,minor] = Goal
   409     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   410 by (rtac minor 1);
   411 by (rtac (major RS IntD1) 1);
   412 by (rtac (major RS IntD2) 1);
   413 qed "IntE";
   414 
   415 AddSIs [IntI];
   416 AddSEs [IntE];
   417 
   418 section "Set difference";
   419 
   420 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   421 by (Blast_tac 1);
   422 qed "Diff_iff";
   423 Addsimps [Diff_iff];
   424 
   425 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   426 by (Asm_simp_tac 1) ;
   427 qed "DiffI";
   428 
   429 Goal "c : A - B ==> c : A";
   430 by (Asm_full_simp_tac 1) ;
   431 qed "DiffD1";
   432 
   433 Goal "[| c : A - B;  c : B |] ==> P";
   434 by (Asm_full_simp_tac 1) ;
   435 qed "DiffD2";
   436 
   437 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   438 by (resolve_tac prems 1);
   439 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   440 qed "DiffE";
   441 
   442 AddSIs [DiffI];
   443 AddSEs [DiffE];
   444 
   445 
   446 section "Augmenting a set -- insert";
   447 
   448 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   449 by (Blast_tac 1);
   450 qed "insert_iff";
   451 Addsimps [insert_iff];
   452 
   453 Goal "a : insert a B";
   454 by (Simp_tac 1);
   455 qed "insertI1";
   456 
   457 Goal "!!a. a : B ==> a : insert b B";
   458 by (Asm_simp_tac 1);
   459 qed "insertI2";
   460 
   461 val major::prems = Goalw [insert_def]
   462     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   463 by (rtac (major RS UnE) 1);
   464 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   465 qed "insertE";
   466 
   467 (*Classical introduction rule*)
   468 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   469 by (Simp_tac 1);
   470 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   471 qed "insertCI";
   472 
   473 AddSIs [insertCI]; 
   474 AddSEs [insertE];
   475 
   476 Goal "A <= insert x B ==> A <= B & x ~: A | (? B'. A = insert x B' & B' <= B)";
   477 by (case_tac "x:A" 1);
   478 by  (Fast_tac 2);
   479 by (rtac disjI2 1);
   480 by (res_inst_tac [("x","A-{x}")] exI 1);
   481 by (Fast_tac 1);
   482 qed "subset_insertD";
   483 
   484 section "Singletons, using insert";
   485 
   486 Goal "a : {a}";
   487 by (rtac insertI1 1) ;
   488 qed "singletonI";
   489 
   490 Goal "b : {a} ==> b=a";
   491 by (Blast_tac 1);
   492 qed "singletonD";
   493 
   494 bind_thm ("singletonE", make_elim singletonD);
   495 
   496 Goal "(b : {a}) = (b=a)";
   497 by (Blast_tac 1);
   498 qed "singleton_iff";
   499 
   500 Goal "{a}={b} ==> a=b";
   501 by (blast_tac (claset() addEs [equalityE]) 1);
   502 qed "singleton_inject";
   503 
   504 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   505 AddSIs [singletonI];   
   506 AddSDs [singleton_inject];
   507 AddSEs [singletonE];
   508 
   509 Goal "{b} = insert a A = (a = b & A <= {b})";
   510 by (blast_tac (claset() addSEs [equalityE]) 1);
   511 qed "singleton_insert_inj_eq";
   512 
   513 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   514 by (blast_tac (claset() addSEs [equalityE]) 1);
   515 qed "singleton_insert_inj_eq'";
   516 
   517 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   518 
   519 Goal "A <= {x} ==> A={} | A = {x}";
   520 by (Fast_tac 1);
   521 qed "subset_singletonD";
   522 
   523 Goal "{x. x=a} = {a}";
   524 by (Blast_tac 1);
   525 qed "singleton_conv";
   526 Addsimps [singleton_conv];
   527 
   528 Goal "{x. a=x} = {a}";
   529 by (Blast_tac 1);
   530 qed "singleton_conv2";
   531 Addsimps [singleton_conv2];
   532 
   533 
   534 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   535 
   536 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   537 by (Blast_tac 1);
   538 qed "UN_iff";
   539 
   540 Addsimps [UN_iff];
   541 
   542 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   543 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   544 by Auto_tac;
   545 qed "UN_I";
   546 
   547 val major::prems = Goalw [UNION_def]
   548     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   549 by (rtac (major RS CollectD RS bexE) 1);
   550 by (REPEAT (ares_tac prems 1));
   551 qed "UN_E";
   552 
   553 AddIs  [UN_I];
   554 AddSEs [UN_E];
   555 
   556 val prems = Goalw [UNION_def]
   557     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   558 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   559 by (asm_simp_tac (simpset() addsimps prems) 1);
   560 qed "UN_cong";
   561 
   562 
   563 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   564 
   565 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   566 by Auto_tac;
   567 qed "INT_iff";
   568 
   569 Addsimps [INT_iff];
   570 
   571 val prems = Goalw [INTER_def]
   572     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   573 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   574 qed "INT_I";
   575 
   576 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   577 by Auto_tac;
   578 qed "INT_D";
   579 
   580 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   581 val major::prems = Goalw [INTER_def]
   582     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   583 by (rtac (major RS CollectD RS ballE) 1);
   584 by (REPEAT (eresolve_tac prems 1));
   585 qed "INT_E";
   586 
   587 AddSIs [INT_I];
   588 AddEs  [INT_D, INT_E];
   589 
   590 val prems = Goalw [INTER_def]
   591     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   592 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   593 by (asm_simp_tac (simpset() addsimps prems) 1);
   594 qed "INT_cong";
   595 
   596 
   597 section "Union";
   598 
   599 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   600 by (Blast_tac 1);
   601 qed "Union_iff";
   602 
   603 Addsimps [Union_iff];
   604 
   605 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   606 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   607 by Auto_tac;
   608 qed "UnionI";
   609 
   610 val major::prems = Goalw [Union_def]
   611     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   612 by (rtac (major RS UN_E) 1);
   613 by (REPEAT (ares_tac prems 1));
   614 qed "UnionE";
   615 
   616 AddIs  [UnionI];
   617 AddSEs [UnionE];
   618 
   619 
   620 section "Inter";
   621 
   622 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   623 by (Blast_tac 1);
   624 qed "Inter_iff";
   625 
   626 Addsimps [Inter_iff];
   627 
   628 val prems = Goalw [Inter_def]
   629     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   630 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   631 qed "InterI";
   632 
   633 (*A "destruct" rule -- every X in C contains A as an element, but
   634   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   635 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   636 by Auto_tac;
   637 qed "InterD";
   638 
   639 (*"Classical" elimination rule -- does not require proving X:C *)
   640 val major::prems = Goalw [Inter_def]
   641     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   642 by (rtac (major RS INT_E) 1);
   643 by (REPEAT (eresolve_tac prems 1));
   644 qed "InterE";
   645 
   646 AddSIs [InterI];
   647 AddEs  [InterD, InterE];
   648 
   649 
   650 (*** Image of a set under a function ***)
   651 
   652 (*Frequently b does not have the syntactic form of f(x).*)
   653 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   654 by (Blast_tac 1);
   655 qed "image_eqI";
   656 Addsimps [image_eqI];
   657 
   658 bind_thm ("imageI", refl RS image_eqI);
   659 
   660 (*This version's more effective when we already have the required x*)
   661 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   662 by (Blast_tac 1);
   663 qed "rev_image_eqI";
   664 
   665 (*The eta-expansion gives variable-name preservation.*)
   666 val major::prems = Goalw [image_def]
   667     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   668 by (rtac (major RS CollectD RS bexE) 1);
   669 by (REPEAT (ares_tac prems 1));
   670 qed "imageE";
   671 
   672 AddIs  [image_eqI];
   673 AddSEs [imageE]; 
   674 
   675 Goal "f``(A Un B) = f``A Un f``B";
   676 by (Blast_tac 1);
   677 qed "image_Un";
   678 
   679 Goal "(z : f``A) = (EX x:A. z = f x)";
   680 by (Blast_tac 1);
   681 qed "image_iff";
   682 
   683 (*This rewrite rule would confuse users if made default.*)
   684 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   685 by (Blast_tac 1);
   686 qed "image_subset_iff";
   687 
   688 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   689   many existing proofs.*)
   690 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   691 by (blast_tac (claset() addIs prems) 1);
   692 qed "image_subsetI";
   693 
   694 
   695 (*** Range of a function -- just a translation for image! ***)
   696 
   697 Goal "b=f(x) ==> b : range(f)";
   698 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   699 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   700 
   701 bind_thm ("rangeI", UNIV_I RS imageI);
   702 
   703 val [major,minor] = Goal 
   704     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   705 by (rtac (major RS imageE) 1);
   706 by (etac minor 1);
   707 qed "rangeE";
   708 
   709 
   710 (*** Set reasoning tools ***)
   711 
   712 
   713 (** Rewrite rules for boolean case-splitting: faster than 
   714 	addsplits[split_if]
   715 **)
   716 
   717 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   718 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   719 
   720 (*Split ifs on either side of the membership relation.
   721 	Not for Addsimps -- can cause goals to blow up!*)
   722 bind_thm ("split_if_mem1", 
   723     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   724 bind_thm ("split_if_mem2", 
   725     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   726 
   727 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   728 		  split_if_mem1, split_if_mem2];
   729 
   730 
   731 (*Each of these has ALREADY been added to simpset() above.*)
   732 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   733                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   734 
   735 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   736 
   737 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   738 
   739 Addsimps[subset_UNIV, subset_refl];
   740 
   741 
   742 (*** The 'proper subset' relation (<) ***)
   743 
   744 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   745 by (Blast_tac 1);
   746 qed "psubsetI";
   747 AddSIs [psubsetI];
   748 
   749 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   750 by Auto_tac;
   751 qed "psubset_insertD";
   752 
   753 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   754 
   755 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   756 
   757 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   758 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   759 qed "psubset_subset_trans";
   760 
   761 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   762 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   763 qed "subset_psubset_trans";
   764 
   765 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   766 by (Blast_tac 1);
   767 qed "psubset_imp_ex_mem";
   768 
   769 
   770 (* attributes *)
   771 
   772 local
   773 
   774 fun gen_rulify_prems x =
   775   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   776     rule_by_tactic (REPEAT (ALLGOALS (resolve_tac [allI, ballI, impI])))))) x;
   777 
   778 in
   779 
   780 val rulify_prems_attrib_setup =
   781  [Attrib.add_attributes
   782   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   783 
   784 end;