src/HOL/Number_Theory/Residues.thy
author paulson <lp15@cam.ac.uk>
Thu Jun 14 15:20:10 2018 +0100 (12 months ago)
changeset 68447 0beb927eed89
parent 67341 df79ef3b3a41
child 68458 023b353911c5
permissions -rw-r--r--
Adjusting Number_Theory for new Algebra
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports
    12   Cong
    13   "HOL-Algebra.Multiplicative_Group"
    14   Totient
    15 begin
    16 
    17 definition QuadRes :: "int \<Rightarrow> int \<Rightarrow> bool"
    18   where "QuadRes p a = (\<exists>y. ([y^2 = a] (mod p)))"
    19 
    20 definition Legendre :: "int \<Rightarrow> int \<Rightarrow> int"
    21   where "Legendre a p =
    22     (if ([a = 0] (mod p)) then 0
    23      else if QuadRes p a then 1
    24      else -1)"
    25 
    26 
    27 subsection \<open>A locale for residue rings\<close>
    28 
    29 definition residue_ring :: "int \<Rightarrow> int ring"
    30   where
    31     "residue_ring m =
    32       \<lparr>carrier = {0..m - 1},
    33        monoid.mult = \<lambda>x y. (x * y) mod m,
    34        one = 1,
    35        zero = 0,
    36        add = \<lambda>x y. (x + y) mod m\<rparr>"
    37 
    38 locale residues =
    39   fixes m :: int and R (structure)
    40   assumes m_gt_one: "m > 1"
    41   defines "R \<equiv> residue_ring m"
    42 begin
    43 
    44 lemma abelian_group: "abelian_group R"
    45 proof -
    46   have "\<exists>y\<in>{0..m - 1}. (x + y) mod m = 0" if "0 \<le> x" "x < m" for x
    47   proof (cases "x = 0")
    48     case True
    49     with m_gt_one show ?thesis by simp
    50   next
    51     case False
    52     then have "(x + (m - x)) mod m = 0"
    53       by simp
    54     with m_gt_one that show ?thesis
    55       by (metis False atLeastAtMost_iff diff_ge_0_iff_ge diff_left_mono int_one_le_iff_zero_less less_le)
    56   qed
    57   with m_gt_one show ?thesis
    58     by (fastforce simp add: R_def residue_ring_def mod_add_right_eq ac_simps  intro!: abelian_groupI)
    59 qed
    60 
    61 lemma comm_monoid: "comm_monoid R"
    62   unfolding R_def residue_ring_def
    63   apply (rule comm_monoidI)
    64     using m_gt_one  apply auto
    65   apply (metis mod_mult_right_eq mult.assoc mult.commute)
    66   apply (metis mult.commute)
    67   done
    68 
    69 lemma cring: "cring R"
    70   apply (intro cringI abelian_group comm_monoid)
    71   unfolding R_def residue_ring_def
    72   apply (auto simp add: comm_semiring_class.distrib mod_add_eq mod_mult_left_eq)
    73   done
    74 
    75 end
    76 
    77 sublocale residues < cring
    78   by (rule cring)
    79 
    80 
    81 context residues
    82 begin
    83 
    84 text \<open>
    85   These lemmas translate back and forth between internal and
    86   external concepts.
    87 \<close>
    88 
    89 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    90   by (auto simp: R_def residue_ring_def)
    91 
    92 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    93   by (auto simp: R_def residue_ring_def)
    94 
    95 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    96   by (auto simp: R_def residue_ring_def)
    97 
    98 lemma res_zero_eq: "\<zero> = 0"
    99   by (auto simp: R_def residue_ring_def)
   100 
   101 lemma res_one_eq: "\<one> = 1"
   102   by (auto simp: R_def residue_ring_def units_of_def)
   103 
   104 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
   105   using m_gt_one
   106   apply (auto simp add: Units_def R_def residue_ring_def ac_simps invertible_coprime intro: ccontr)
   107   apply (subst (asm) coprime_iff_invertible'_int)
   108    apply (auto simp add: cong_def)
   109   done
   110 
   111 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   112   using m_gt_one unfolding R_def a_inv_def m_inv_def residue_ring_def
   113   apply simp
   114   apply (rule the_equality)
   115    apply (simp add: mod_add_right_eq)
   116    apply (simp add: add.commute mod_add_right_eq)
   117   apply (metis add.right_neutral minus_add_cancel mod_add_right_eq mod_pos_pos_trivial)
   118   done
   119 
   120 lemma finite [iff]: "finite (carrier R)"
   121   by (simp add: res_carrier_eq)
   122 
   123 lemma finite_Units [iff]: "finite (Units R)"
   124   by (simp add: finite_ring_finite_units)
   125 
   126 text \<open>
   127   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   128   residue classes. The following lemmas show that this mapping
   129   respects addition and multiplication on the integers.
   130 \<close>
   131 
   132 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   133   unfolding res_carrier_eq
   134   using insert m_gt_one by auto
   135 
   136 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   137   by (auto simp: R_def residue_ring_def mod_simps)
   138 
   139 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   140   by (auto simp: R_def residue_ring_def mod_simps)
   141 
   142 lemma zero_cong: "\<zero> = 0"
   143   by (auto simp: R_def residue_ring_def)
   144 
   145 lemma one_cong: "\<one> = 1 mod m"
   146   using m_gt_one by (auto simp: R_def residue_ring_def)
   147 
   148 (* FIXME revise algebra library to use 1? *)
   149 lemma pow_cong: "(x mod m) [^] n = x^n mod m"
   150   using m_gt_one
   151   apply (induct n)
   152   apply (auto simp add: nat_pow_def one_cong)
   153   apply (metis mult.commute mult_cong)
   154   done
   155 
   156 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   157   by (metis mod_minus_eq res_neg_eq)
   158 
   159 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   160   by (induct set: finite) (auto simp: one_cong mult_cong)
   161 
   162 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   163   by (induct set: finite) (auto simp: zero_cong add_cong)
   164 
   165 lemma mod_in_res_units [simp]:
   166   assumes "1 < m" and "coprime a m"
   167   shows "a mod m \<in> Units R"
   168 proof (cases "a mod m = 0")
   169   case True
   170   with assms show ?thesis
   171     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   172 next
   173   case False
   174   from assms have "0 < m" by simp
   175   then have "0 \<le> a mod m" by (rule pos_mod_sign [of m a])
   176   with False have "0 < a mod m" by simp
   177   with assms show ?thesis
   178     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   179 qed
   180 
   181 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   182   by (auto simp: cong_def)
   183 
   184 
   185 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   186 lemmas res_to_cong_simps =
   187   add_cong mult_cong pow_cong one_cong
   188   prod_cong sum_cong neg_cong res_eq_to_cong
   189 
   190 text \<open>Other useful facts about the residue ring.\<close>
   191 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   192   apply (simp add: res_one_eq res_neg_eq)
   193   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   194     zero_neq_one zmod_zminus1_eq_if)
   195   done
   196 
   197 end
   198 
   199 
   200 subsection \<open>Prime residues\<close>
   201 
   202 locale residues_prime =
   203   fixes p :: nat and R (structure)
   204   assumes p_prime [intro]: "prime p"
   205   defines "R \<equiv> residue_ring (int p)"
   206 
   207 sublocale residues_prime < residues p
   208   unfolding R_def residues_def
   209   using p_prime apply auto
   210   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   211   done
   212 
   213 context residues_prime
   214 begin
   215 
   216 lemma p_coprime_left:
   217   "coprime p a \<longleftrightarrow> \<not> p dvd a"
   218   using p_prime by (auto intro: prime_imp_coprime dest: coprime_common_divisor)
   219 
   220 lemma p_coprime_right:
   221   "coprime a p  \<longleftrightarrow> \<not> p dvd a"
   222   using p_coprime_left [of a] by (simp add: ac_simps)
   223 
   224 lemma p_coprime_left_int:
   225   "coprime (int p) a \<longleftrightarrow> \<not> int p dvd a"
   226   using p_prime by (auto intro: prime_imp_coprime dest: coprime_common_divisor)
   227 
   228 lemma p_coprime_right_int:
   229   "coprime a (int p) \<longleftrightarrow> \<not> int p dvd a"
   230   using p_coprime_left_int [of a] by (simp add: ac_simps)
   231 
   232 lemma is_field: "field R"
   233 proof -
   234   have "0 < x \<Longrightarrow> x < int p \<Longrightarrow> coprime (int p) x" for x
   235     by (rule prime_imp_coprime) (auto simp add: zdvd_not_zless)
   236   then show ?thesis
   237     by (intro cring.field_intro2 cring)
   238       (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq ac_simps)
   239 qed
   240 
   241 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   242   apply (subst res_units_eq)
   243   apply (auto simp add: p_coprime_right_int zdvd_not_zless)
   244   done
   245 
   246 end
   247 
   248 sublocale residues_prime < field
   249   by (rule is_field)
   250 
   251 
   252 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   253 
   254 subsection \<open>Euler's theorem\<close>
   255 
   256 lemma (in residues) totatives_eq:
   257   "totatives (nat m) = nat ` Units R"
   258 proof -
   259   from m_gt_one have "\<bar>m\<bar> > 1"
   260     by simp
   261   then have "totatives (nat \<bar>m\<bar>) = nat ` abs ` Units R"
   262     by (auto simp add: totatives_def res_units_eq image_iff le_less)
   263       (use m_gt_one zless_nat_eq_int_zless in force)
   264   moreover have "\<bar>m\<bar> = m" "abs ` Units R = Units R"
   265     using m_gt_one by (auto simp add: res_units_eq image_iff)
   266   ultimately show ?thesis
   267     by simp
   268 qed
   269 
   270 lemma (in residues) totient_eq:
   271   "totient (nat m) = card (Units R)"
   272 proof  -
   273   have *: "inj_on nat (Units R)"
   274     by (rule inj_onI) (auto simp add: res_units_eq)
   275   then show ?thesis
   276     by (simp add: totient_def totatives_eq card_image)
   277 qed
   278 
   279 lemma (in residues_prime) totient_eq: "totient p = p - 1"
   280   using totient_eq by (simp add: res_prime_units_eq)
   281 
   282 lemma (in residues) euler_theorem:
   283   assumes "coprime a m"
   284   shows "[a ^ totient (nat m) = 1] (mod m)"
   285 proof -
   286   have "a ^ totient (nat m) mod m = 1 mod m"
   287     by (metis assms finite_Units m_gt_one mod_in_res_units one_cong totient_eq pow_cong units_power_order_eq_one)
   288   then show ?thesis
   289     using res_eq_to_cong by blast
   290 qed
   291 
   292 lemma euler_theorem:
   293   fixes a m :: nat
   294   assumes "coprime a m"
   295   shows "[a ^ totient m = 1] (mod m)"
   296 proof (cases "m = 0 \<or> m = 1")
   297   case True
   298   then show ?thesis by auto
   299 next
   300   case False
   301   with assms show ?thesis
   302     using residues.euler_theorem [of "int m" "int a"] cong_int_iff
   303     by (auto simp add: residues_def gcd_int_def) fastforce
   304 qed
   305 
   306 lemma fermat_theorem:
   307   fixes p a :: nat
   308   assumes "prime p" and "\<not> p dvd a"
   309   shows "[a ^ (p - 1) = 1] (mod p)"
   310 proof -
   311   from assms prime_imp_coprime [of p a] have "coprime a p"
   312     by (auto simp add: ac_simps)
   313   then have "[a ^ totient p = 1] (mod p)"
   314      by (rule euler_theorem)
   315   also have "totient p = p - 1"
   316     by (rule totient_prime) (rule assms)
   317   finally show ?thesis .
   318 qed
   319 
   320 
   321 subsection \<open>Wilson's theorem\<close>
   322 
   323 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   324     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   325   apply auto
   326   apply (metis Units_inv_inv)+
   327   done
   328 
   329 lemma (in residues_prime) wilson_theorem1:
   330   assumes a: "p > 2"
   331   shows "[fact (p - 1) = (-1::int)] (mod p)"
   332 proof -
   333   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   334   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   335     by auto
   336   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   337     apply (subst UR)
   338     apply (subst finprod_Un_disjoint)
   339          apply (auto intro: funcsetI)
   340     using inv_one apply auto[1]
   341     using inv_eq_neg_one_eq apply auto
   342     done
   343   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   344     apply (subst finprod_insert)
   345         apply auto
   346     apply (frule one_eq_neg_one)
   347     using a apply force
   348     done
   349   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   350     apply (subst finprod_Union_disjoint)
   351        apply auto
   352      apply (metis Units_inv_inv)+
   353     done
   354   also have "\<dots> = \<one>"
   355     apply (rule finprod_one_eqI)
   356      apply auto
   357     apply (subst finprod_insert)
   358         apply auto
   359     apply (metis inv_eq_self)
   360     done
   361   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   362     by simp
   363   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   364     by (rule finprod_cong') (auto simp: res_units_eq)
   365   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   366     by (rule prod_cong) auto
   367   also have "\<dots> = fact (p - 1) mod p"
   368     apply (simp add: fact_prod)
   369     using assms
   370     apply (subst res_prime_units_eq)
   371     apply (simp add: int_prod zmod_int prod_int_eq)
   372     done
   373   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   374   then show ?thesis
   375     by (simp add: cong_def res_neg_eq res_one_eq zmod_int)
   376 qed
   377 
   378 lemma wilson_theorem:
   379   assumes "prime p"
   380   shows "[fact (p - 1) = - 1] (mod p)"
   381 proof (cases "p = 2")
   382   case True
   383   then show ?thesis
   384     by (simp add: cong_def fact_prod)
   385 next
   386   case False
   387   then show ?thesis
   388     using assms prime_ge_2_nat
   389     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   390 qed
   391 
   392 text \<open>
   393   This result can be transferred to the multiplicative group of
   394   \<open>\<int>/p\<int>\<close> for \<open>p\<close> prime.\<close>
   395 
   396 lemma mod_nat_int_pow_eq:
   397   fixes n :: nat and p a :: int
   398   shows "a \<ge> 0 \<Longrightarrow> p \<ge> 0 \<Longrightarrow> (nat a ^ n) mod (nat p) = nat ((a ^ n) mod p)"
   399   by (simp add: int_one_le_iff_zero_less nat_mod_distrib order_less_imp_le nat_power_eq[symmetric])
   400 
   401 theorem residue_prime_mult_group_has_gen :
   402  fixes p :: nat
   403  assumes prime_p : "prime p"
   404  shows "\<exists>a \<in> {1 .. p - 1}. {1 .. p - 1} = {a^i mod p|i . i \<in> UNIV}"
   405 proof -
   406   have "p \<ge> 2"
   407     using prime_gt_1_nat[OF prime_p] by simp
   408   interpret R: residues_prime p "residue_ring p"
   409     by (simp add: residues_prime_def prime_p)
   410   have car: "carrier (residue_ring (int p)) - {\<zero>\<^bsub>residue_ring (int p)\<^esub>} = {1 .. int p - 1}"
   411     by (auto simp add: R.zero_cong R.res_carrier_eq)
   412 
   413   have "x [^]\<^bsub>residue_ring (int p)\<^esub> i = x ^ i mod (int p)"
   414     if "x \<in> {1 .. int p - 1}" for x and i :: nat
   415     using that R.pow_cong[of x i] by auto
   416   moreover
   417   obtain a where a: "a \<in> {1 .. int p - 1}"
   418     and a_gen: "{1 .. int p - 1} = {a[^]\<^bsub>residue_ring (int p)\<^esub>i|i::nat . i \<in> UNIV}"
   419     using field.finite_field_mult_group_has_gen[OF R.is_field]
   420     by (auto simp add: car[symmetric] carrier_mult_of)
   421   moreover
   422   have "nat ` {1 .. int p - 1} = {1 .. p - 1}" (is "?L = ?R")
   423   proof
   424     have "n \<in> ?R" if "n \<in> ?L" for n
   425       using that \<open>p\<ge>2\<close> by force
   426     then show "?L \<subseteq> ?R" by blast
   427     have "n \<in> ?L" if "n \<in> ?R" for n
   428       using that \<open>p\<ge>2\<close> by (auto intro: rev_image_eqI [of "int n"])
   429     then show "?R \<subseteq> ?L" by blast
   430   qed
   431   moreover
   432   have "nat ` {a^i mod (int p) | i::nat. i \<in> UNIV} = {nat a^i mod p | i . i \<in> UNIV}" (is "?L = ?R")
   433   proof
   434     have "x \<in> ?R" if "x \<in> ?L" for x
   435     proof -
   436       from that obtain i where i: "x = nat (a^i mod (int p))"
   437         by blast
   438       then have "x = nat a ^ i mod p"
   439         using mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> by auto
   440       with i show ?thesis by blast
   441     qed
   442     then show "?L \<subseteq> ?R" by blast
   443     have "x \<in> ?L" if "x \<in> ?R" for x
   444     proof -
   445       from that obtain i where i: "x = nat a^i mod p"
   446         by blast
   447       with mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> show ?thesis
   448         by auto
   449     qed
   450     then show "?R \<subseteq> ?L" by blast
   451   qed
   452   ultimately have "{1 .. p - 1} = {nat a^i mod p | i. i \<in> UNIV}"
   453     by presburger
   454   moreover from a have "nat a \<in> {1 .. p - 1}" by force
   455   ultimately show ?thesis ..
   456 qed
   457 
   458 end