src/HOL/Power.thy
author huffman
Thu Mar 29 14:09:10 2012 +0200 (2012-03-29)
changeset 47192 0c0501cb6da6
parent 47191 ebd8c46d156b
child 47209 4893907fe872
permissions -rw-r--r--
move many lemmas from Nat_Numeral.thy to Power.thy or Num.thy
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Exponentiation *}
     7 
     8 theory Power
     9 imports Num
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 text {* Special syntax for squares. *}
    28 
    29 abbreviation (xsymbols)
    30   power2 :: "'a \<Rightarrow> 'a"  ("(_\<twosuperior>)" [1000] 999) where
    31   "x\<twosuperior> \<equiv> x ^ 2"
    32 
    33 notation (latex output)
    34   power2  ("(_\<twosuperior>)" [1000] 999)
    35 
    36 notation (HTML output)
    37   power2  ("(_\<twosuperior>)" [1000] 999)
    38 
    39 end
    40 
    41 context monoid_mult
    42 begin
    43 
    44 subclass power .
    45 
    46 lemma power_one [simp]:
    47   "1 ^ n = 1"
    48   by (induct n) simp_all
    49 
    50 lemma power_one_right [simp]:
    51   "a ^ 1 = a"
    52   by simp
    53 
    54 lemma power_commutes:
    55   "a ^ n * a = a * a ^ n"
    56   by (induct n) (simp_all add: mult_assoc)
    57 
    58 lemma power_Suc2:
    59   "a ^ Suc n = a ^ n * a"
    60   by (simp add: power_commutes)
    61 
    62 lemma power_add:
    63   "a ^ (m + n) = a ^ m * a ^ n"
    64   by (induct m) (simp_all add: algebra_simps)
    65 
    66 lemma power_mult:
    67   "a ^ (m * n) = (a ^ m) ^ n"
    68   by (induct n) (simp_all add: power_add)
    69 
    70 lemma power2_eq_square: "a\<twosuperior> = a * a"
    71   by (simp add: numeral_2_eq_2)
    72 
    73 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    74   by (simp add: numeral_3_eq_3 mult_assoc)
    75 
    76 lemma power_even_eq:
    77   "a ^ (2*n) = (a ^ n) ^ 2"
    78   by (subst mult_commute) (simp add: power_mult)
    79 
    80 lemma power_odd_eq:
    81   "a ^ Suc (2*n) = a * (a ^ n) ^ 2"
    82   by (simp add: power_even_eq)
    83 
    84 end
    85 
    86 context comm_monoid_mult
    87 begin
    88 
    89 lemma power_mult_distrib:
    90   "(a * b) ^ n = (a ^ n) * (b ^ n)"
    91   by (induct n) (simp_all add: mult_ac)
    92 
    93 end
    94 
    95 context semiring_numeral
    96 begin
    97 
    98 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
    99   by (simp only: sqr_conv_mult numeral_mult)
   100 
   101 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   102   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   103     numeral_sqr numeral_mult power_add power_one_right)
   104 
   105 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   106   by (rule numeral_pow [symmetric])
   107 
   108 end
   109 
   110 context semiring_1
   111 begin
   112 
   113 lemma of_nat_power:
   114   "of_nat (m ^ n) = of_nat m ^ n"
   115   by (induct n) (simp_all add: of_nat_mult)
   116 
   117 lemma power_zero_numeral [simp]: "(0::'a) ^ numeral k = 0"
   118   by (cases "numeral k :: nat", simp_all)
   119 
   120 lemma zero_power2: "0\<twosuperior> = 0" (* delete? *)
   121   by (rule power_zero_numeral)
   122 
   123 lemma one_power2: "1\<twosuperior> = 1" (* delete? *)
   124   by (rule power_one)
   125 
   126 end
   127 
   128 context comm_semiring_1
   129 begin
   130 
   131 text {* The divides relation *}
   132 
   133 lemma le_imp_power_dvd:
   134   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   135 proof
   136   have "a ^ n = a ^ (m + (n - m))"
   137     using `m \<le> n` by simp
   138   also have "\<dots> = a ^ m * a ^ (n - m)"
   139     by (rule power_add)
   140   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   141 qed
   142 
   143 lemma power_le_dvd:
   144   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   145   by (rule dvd_trans [OF le_imp_power_dvd])
   146 
   147 lemma dvd_power_same:
   148   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   149   by (induct n) (auto simp add: mult_dvd_mono)
   150 
   151 lemma dvd_power_le:
   152   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   153   by (rule power_le_dvd [OF dvd_power_same])
   154 
   155 lemma dvd_power [simp]:
   156   assumes "n > (0::nat) \<or> x = 1"
   157   shows "x dvd (x ^ n)"
   158 using assms proof
   159   assume "0 < n"
   160   then have "x ^ n = x ^ Suc (n - 1)" by simp
   161   then show "x dvd (x ^ n)" by simp
   162 next
   163   assume "x = 1"
   164   then show "x dvd (x ^ n)" by simp
   165 qed
   166 
   167 end
   168 
   169 context ring_1
   170 begin
   171 
   172 lemma power_minus:
   173   "(- a) ^ n = (- 1) ^ n * a ^ n"
   174 proof (induct n)
   175   case 0 show ?case by simp
   176 next
   177   case (Suc n) then show ?case
   178     by (simp del: power_Suc add: power_Suc2 mult_assoc)
   179 qed
   180 
   181 lemma power_minus_Bit0:
   182   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   183   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   184     power_one_right mult_minus_left mult_minus_right minus_minus)
   185 
   186 lemma power_minus_Bit1:
   187   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   188   by (simp only: nat_number(4) power_Suc power_minus_Bit0 mult_minus_left)
   189 
   190 lemma power_neg_numeral_Bit0 [simp]:
   191   "neg_numeral k ^ numeral (Num.Bit0 l) = numeral (Num.pow k (Num.Bit0 l))"
   192   by (simp only: neg_numeral_def power_minus_Bit0 power_numeral)
   193 
   194 lemma power_neg_numeral_Bit1 [simp]:
   195   "neg_numeral k ^ numeral (Num.Bit1 l) = neg_numeral (Num.pow k (Num.Bit1 l))"
   196   by (simp only: neg_numeral_def power_minus_Bit1 power_numeral pow.simps)
   197 
   198 lemma power2_minus [simp]:
   199   "(- a)\<twosuperior> = a\<twosuperior>"
   200   by (rule power_minus_Bit0)
   201 
   202 lemma power_minus1_even [simp]:
   203   "-1 ^ (2*n) = 1"
   204 proof (induct n)
   205   case 0 show ?case by simp
   206 next
   207   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   208 qed
   209 
   210 lemma power_minus1_odd:
   211   "-1 ^ Suc (2*n) = -1"
   212   by simp
   213 
   214 lemma power_minus_even [simp]:
   215   "(-a) ^ (2*n) = a ^ (2*n)"
   216   by (simp add: power_minus [of a])
   217 
   218 end
   219 
   220 context ring_1_no_zero_divisors
   221 begin
   222 
   223 lemma field_power_not_zero:
   224   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   225   by (induct n) auto
   226 
   227 lemma zero_eq_power2 [simp]:
   228   "a\<twosuperior> = 0 \<longleftrightarrow> a = 0"
   229   unfolding power2_eq_square by simp
   230 
   231 lemma power2_eq_1_iff:
   232   "a\<twosuperior> = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   233   unfolding power2_eq_square by (rule square_eq_1_iff)
   234 
   235 end
   236 
   237 context idom
   238 begin
   239 
   240 lemma power2_eq_iff: "x\<twosuperior> = y\<twosuperior> \<longleftrightarrow> x = y \<or> x = - y"
   241   unfolding power2_eq_square by (rule square_eq_iff)
   242 
   243 end
   244 
   245 context division_ring
   246 begin
   247 
   248 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   249 lemma nonzero_power_inverse:
   250   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   251   by (induct n)
   252     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   253 
   254 end
   255 
   256 context field
   257 begin
   258 
   259 lemma nonzero_power_divide:
   260   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   261   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   262 
   263 end
   264 
   265 
   266 subsection {* Exponentiation on ordered types *}
   267 
   268 context linordered_ring (* TODO: move *)
   269 begin
   270 
   271 lemma sum_squares_ge_zero:
   272   "0 \<le> x * x + y * y"
   273   by (intro add_nonneg_nonneg zero_le_square)
   274 
   275 lemma not_sum_squares_lt_zero:
   276   "\<not> x * x + y * y < 0"
   277   by (simp add: not_less sum_squares_ge_zero)
   278 
   279 end
   280 
   281 context linordered_semidom
   282 begin
   283 
   284 lemma zero_less_power [simp]:
   285   "0 < a \<Longrightarrow> 0 < a ^ n"
   286   by (induct n) (simp_all add: mult_pos_pos)
   287 
   288 lemma zero_le_power [simp]:
   289   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   290   by (induct n) (simp_all add: mult_nonneg_nonneg)
   291 
   292 lemma one_le_power[simp]:
   293   "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   294   apply (induct n)
   295   apply simp_all
   296   apply (rule order_trans [OF _ mult_mono [of 1 _ 1]])
   297   apply (simp_all add: order_trans [OF zero_le_one])
   298   done
   299 
   300 lemma power_gt1_lemma:
   301   assumes gt1: "1 < a"
   302   shows "1 < a * a ^ n"
   303 proof -
   304   from gt1 have "0 \<le> a"
   305     by (fact order_trans [OF zero_le_one less_imp_le])
   306   have "1 * 1 < a * 1" using gt1 by simp
   307   also have "\<dots> \<le> a * a ^ n" using gt1
   308     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   309         zero_le_one order_refl)
   310   finally show ?thesis by simp
   311 qed
   312 
   313 lemma power_gt1:
   314   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   315   by (simp add: power_gt1_lemma)
   316 
   317 lemma one_less_power [simp]:
   318   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   319   by (cases n) (simp_all add: power_gt1_lemma)
   320 
   321 lemma power_le_imp_le_exp:
   322   assumes gt1: "1 < a"
   323   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   324 proof (induct m arbitrary: n)
   325   case 0
   326   show ?case by simp
   327 next
   328   case (Suc m)
   329   show ?case
   330   proof (cases n)
   331     case 0
   332     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   333     with gt1 show ?thesis
   334       by (force simp only: power_gt1_lemma
   335           not_less [symmetric])
   336   next
   337     case (Suc n)
   338     with Suc.prems Suc.hyps show ?thesis
   339       by (force dest: mult_left_le_imp_le
   340           simp add: less_trans [OF zero_less_one gt1])
   341   qed
   342 qed
   343 
   344 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   345 lemma power_inject_exp [simp]:
   346   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   347   by (force simp add: order_antisym power_le_imp_le_exp)
   348 
   349 text{*Can relax the first premise to @{term "0<a"} in the case of the
   350 natural numbers.*}
   351 lemma power_less_imp_less_exp:
   352   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   353   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   354     power_le_imp_le_exp)
   355 
   356 lemma power_mono:
   357   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   358   by (induct n)
   359     (auto intro: mult_mono order_trans [of 0 a b])
   360 
   361 lemma power_strict_mono [rule_format]:
   362   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   363   by (induct n)
   364    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   365 
   366 text{*Lemma for @{text power_strict_decreasing}*}
   367 lemma power_Suc_less:
   368   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   369   by (induct n)
   370     (auto simp add: mult_strict_left_mono)
   371 
   372 lemma power_strict_decreasing [rule_format]:
   373   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   374 proof (induct N)
   375   case 0 then show ?case by simp
   376 next
   377   case (Suc N) then show ?case 
   378   apply (auto simp add: power_Suc_less less_Suc_eq)
   379   apply (subgoal_tac "a * a^N < 1 * a^n")
   380   apply simp
   381   apply (rule mult_strict_mono) apply auto
   382   done
   383 qed
   384 
   385 text{*Proof resembles that of @{text power_strict_decreasing}*}
   386 lemma power_decreasing [rule_format]:
   387   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   388 proof (induct N)
   389   case 0 then show ?case by simp
   390 next
   391   case (Suc N) then show ?case 
   392   apply (auto simp add: le_Suc_eq)
   393   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   394   apply (rule mult_mono) apply auto
   395   done
   396 qed
   397 
   398 lemma power_Suc_less_one:
   399   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   400   using power_strict_decreasing [of 0 "Suc n" a] by simp
   401 
   402 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   403 lemma power_increasing [rule_format]:
   404   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   405 proof (induct N)
   406   case 0 then show ?case by simp
   407 next
   408   case (Suc N) then show ?case 
   409   apply (auto simp add: le_Suc_eq)
   410   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   411   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   412   done
   413 qed
   414 
   415 text{*Lemma for @{text power_strict_increasing}*}
   416 lemma power_less_power_Suc:
   417   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   418   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   419 
   420 lemma power_strict_increasing [rule_format]:
   421   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   422 proof (induct N)
   423   case 0 then show ?case by simp
   424 next
   425   case (Suc N) then show ?case 
   426   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   427   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   428   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   429   done
   430 qed
   431 
   432 lemma power_increasing_iff [simp]:
   433   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   434   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   435 
   436 lemma power_strict_increasing_iff [simp]:
   437   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   438 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   439 
   440 lemma power_le_imp_le_base:
   441   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   442     and ynonneg: "0 \<le> b"
   443   shows "a \<le> b"
   444 proof (rule ccontr)
   445   assume "~ a \<le> b"
   446   then have "b < a" by (simp only: linorder_not_le)
   447   then have "b ^ Suc n < a ^ Suc n"
   448     by (simp only: assms power_strict_mono)
   449   from le and this show False
   450     by (simp add: linorder_not_less [symmetric])
   451 qed
   452 
   453 lemma power_less_imp_less_base:
   454   assumes less: "a ^ n < b ^ n"
   455   assumes nonneg: "0 \<le> b"
   456   shows "a < b"
   457 proof (rule contrapos_pp [OF less])
   458   assume "~ a < b"
   459   hence "b \<le> a" by (simp only: linorder_not_less)
   460   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   461   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   462 qed
   463 
   464 lemma power_inject_base:
   465   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   466 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   467 
   468 lemma power_eq_imp_eq_base:
   469   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   470   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   471 
   472 lemma power2_le_imp_le:
   473   "x\<twosuperior> \<le> y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   474   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   475 
   476 lemma power2_less_imp_less:
   477   "x\<twosuperior> < y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   478   by (rule power_less_imp_less_base)
   479 
   480 lemma power2_eq_imp_eq:
   481   "x\<twosuperior> = y\<twosuperior> \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   482   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   483 
   484 end
   485 
   486 context linordered_ring_strict
   487 begin
   488 
   489 lemma sum_squares_eq_zero_iff:
   490   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   491   by (simp add: add_nonneg_eq_0_iff)
   492 
   493 lemma sum_squares_le_zero_iff:
   494   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   495   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   496 
   497 lemma sum_squares_gt_zero_iff:
   498   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   499   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   500 
   501 end
   502 
   503 context linordered_idom
   504 begin
   505 
   506 lemma power_abs:
   507   "abs (a ^ n) = abs a ^ n"
   508   by (induct n) (auto simp add: abs_mult)
   509 
   510 lemma abs_power_minus [simp]:
   511   "abs ((-a) ^ n) = abs (a ^ n)"
   512   by (simp add: power_abs)
   513 
   514 lemma zero_less_power_abs_iff [simp, no_atp]:
   515   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   516 proof (induct n)
   517   case 0 show ?case by simp
   518 next
   519   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   520 qed
   521 
   522 lemma zero_le_power_abs [simp]:
   523   "0 \<le> abs a ^ n"
   524   by (rule zero_le_power [OF abs_ge_zero])
   525 
   526 lemma zero_le_power2 [simp]:
   527   "0 \<le> a\<twosuperior>"
   528   by (simp add: power2_eq_square)
   529 
   530 lemma zero_less_power2 [simp]:
   531   "0 < a\<twosuperior> \<longleftrightarrow> a \<noteq> 0"
   532   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   533 
   534 lemma power2_less_0 [simp]:
   535   "\<not> a\<twosuperior> < 0"
   536   by (force simp add: power2_eq_square mult_less_0_iff)
   537 
   538 lemma abs_power2 [simp]:
   539   "abs (a\<twosuperior>) = a\<twosuperior>"
   540   by (simp add: power2_eq_square abs_mult abs_mult_self)
   541 
   542 lemma power2_abs [simp]:
   543   "(abs a)\<twosuperior> = a\<twosuperior>"
   544   by (simp add: power2_eq_square abs_mult_self)
   545 
   546 lemma odd_power_less_zero:
   547   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   548 proof (induct n)
   549   case 0
   550   then show ?case by simp
   551 next
   552   case (Suc n)
   553   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   554     by (simp add: mult_ac power_add power2_eq_square)
   555   thus ?case
   556     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   557 qed
   558 
   559 lemma odd_0_le_power_imp_0_le:
   560   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   561   using odd_power_less_zero [of a n]
   562     by (force simp add: linorder_not_less [symmetric]) 
   563 
   564 lemma zero_le_even_power'[simp]:
   565   "0 \<le> a ^ (2*n)"
   566 proof (induct n)
   567   case 0
   568     show ?case by simp
   569 next
   570   case (Suc n)
   571     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   572       by (simp add: mult_ac power_add power2_eq_square)
   573     thus ?case
   574       by (simp add: Suc zero_le_mult_iff)
   575 qed
   576 
   577 lemma sum_power2_ge_zero:
   578   "0 \<le> x\<twosuperior> + y\<twosuperior>"
   579   by (intro add_nonneg_nonneg zero_le_power2)
   580 
   581 lemma not_sum_power2_lt_zero:
   582   "\<not> x\<twosuperior> + y\<twosuperior> < 0"
   583   unfolding not_less by (rule sum_power2_ge_zero)
   584 
   585 lemma sum_power2_eq_zero_iff:
   586   "x\<twosuperior> + y\<twosuperior> = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   587   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   588 
   589 lemma sum_power2_le_zero_iff:
   590   "x\<twosuperior> + y\<twosuperior> \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   591   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   592 
   593 lemma sum_power2_gt_zero_iff:
   594   "0 < x\<twosuperior> + y\<twosuperior> \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   595   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   596 
   597 end
   598 
   599 
   600 subsection {* Miscellaneous rules *}
   601 
   602 lemma power2_sum:
   603   fixes x y :: "'a::comm_semiring_1"
   604   shows "(x + y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> + 2 * x * y"
   605   by (simp add: algebra_simps power2_eq_square mult_2_right)
   606 
   607 lemma power2_diff:
   608   fixes x y :: "'a::comm_ring_1"
   609   shows "(x - y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> - 2 * x * y"
   610   by (simp add: ring_distribs power2_eq_square mult_2) (rule mult_commute)
   611 
   612 lemma power_0_Suc [simp]:
   613   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   614   by simp
   615 
   616 text{*It looks plausible as a simprule, but its effect can be strange.*}
   617 lemma power_0_left:
   618   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   619   by (induct n) simp_all
   620 
   621 lemma power_eq_0_iff [simp]:
   622   "a ^ n = 0 \<longleftrightarrow>
   623      a = (0::'a::{mult_zero,zero_neq_one,no_zero_divisors,power}) \<and> n \<noteq> 0"
   624   by (induct n)
   625     (auto simp add: no_zero_divisors elim: contrapos_pp)
   626 
   627 lemma (in field) power_diff:
   628   assumes nz: "a \<noteq> 0"
   629   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   630   by (induct m n rule: diff_induct) (simp_all add: nz field_power_not_zero)
   631 
   632 text{*Perhaps these should be simprules.*}
   633 lemma power_inverse:
   634   fixes a :: "'a::division_ring_inverse_zero"
   635   shows "inverse (a ^ n) = inverse a ^ n"
   636 apply (cases "a = 0")
   637 apply (simp add: power_0_left)
   638 apply (simp add: nonzero_power_inverse)
   639 done (* TODO: reorient or rename to inverse_power *)
   640 
   641 lemma power_one_over:
   642   "1 / (a::'a::{field_inverse_zero, power}) ^ n =  (1 / a) ^ n"
   643   by (simp add: divide_inverse) (rule power_inverse)
   644 
   645 lemma power_divide:
   646   "(a / b) ^ n = (a::'a::field_inverse_zero) ^ n / b ^ n"
   647 apply (cases "b = 0")
   648 apply (simp add: power_0_left)
   649 apply (rule nonzero_power_divide)
   650 apply assumption
   651 done
   652 
   653 
   654 subsection {* Exponentiation for the Natural Numbers *}
   655 
   656 lemma nat_one_le_power [simp]:
   657   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   658   by (rule one_le_power [of i n, unfolded One_nat_def])
   659 
   660 lemma nat_zero_less_power_iff [simp]:
   661   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   662   by (induct n) auto
   663 
   664 lemma nat_power_eq_Suc_0_iff [simp]: 
   665   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   666   by (induct m) auto
   667 
   668 lemma power_Suc_0 [simp]:
   669   "Suc 0 ^ n = Suc 0"
   670   by simp
   671 
   672 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   673 Premises cannot be weakened: consider the case where @{term "i=0"},
   674 @{term "m=1"} and @{term "n=0"}.*}
   675 lemma nat_power_less_imp_less:
   676   assumes nonneg: "0 < (i\<Colon>nat)"
   677   assumes less: "i ^ m < i ^ n"
   678   shows "m < n"
   679 proof (cases "i = 1")
   680   case True with less power_one [where 'a = nat] show ?thesis by simp
   681 next
   682   case False with nonneg have "1 < i" by auto
   683   from power_strict_increasing_iff [OF this] less show ?thesis ..
   684 qed
   685 
   686 lemma power_dvd_imp_le:
   687   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   688   apply (rule power_le_imp_le_exp, assumption)
   689   apply (erule dvd_imp_le, simp)
   690   done
   691 
   692 
   693 subsection {* Code generator tweak *}
   694 
   695 lemma power_power_power [code]:
   696   "power = power.power (1::'a::{power}) (op *)"
   697   unfolding power_def power.power_def ..
   698 
   699 declare power.power.simps [code]
   700 
   701 code_modulename SML
   702   Power Arith
   703 
   704 code_modulename OCaml
   705   Power Arith
   706 
   707 code_modulename Haskell
   708   Power Arith
   709 
   710 end