src/Pure/Thy/thy_output.ML
author wenzelm
Sun Mar 22 20:49:47 2009 +0100 (2009-03-22)
changeset 30642 0c9f9c49d5df
parent 30635 a7d175c48228
child 30683 e8ac1f9d9469
permissions -rw-r--r--
simplified Antiquote.read (again);
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display: bool ref
    10   val quotes: bool ref
    11   val indent: int ref
    12   val source: bool ref
    13   val break: bool ref
    14   val add_commands: (string * (Args.src -> Toplevel.state -> string)) list -> unit
    15   val add_options: (string * (string -> (unit -> string) -> unit -> string)) list -> unit
    16   val defined_command: string -> bool
    17   val defined_option: string -> bool
    18   val print_antiquotations: unit -> unit
    19   val boolean: string -> bool
    20   val integer: string -> int
    21   val antiquotation: string -> 'a context_parser ->
    22     ({state: Toplevel.state, source: Args.src, context: Proof.context} -> 'a -> string) -> unit
    23   datatype markup = Markup | MarkupEnv | Verbatim
    24   val modes: string list ref
    25   val eval_antiquote: Scan.lexicon -> Toplevel.state -> Symbol_Pos.text * Position.T -> string
    26   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    27     (Toplevel.transition * Toplevel.state) list -> (OuterLex.token, 'a) Source.source -> Buffer.T
    28   val pretty_text: string -> Pretty.T
    29   val pretty_term: Proof.context -> term -> Pretty.T
    30   val pretty_thm: Proof.context -> thm -> Pretty.T
    31   val str_of_source: Args.src -> string
    32   val maybe_pretty_source: ('a -> Pretty.T) -> Args.src -> 'a list -> Pretty.T list
    33   val output: Pretty.T list -> string
    34 end;
    35 
    36 structure ThyOutput: THY_OUTPUT =
    37 struct
    38 
    39 structure T = OuterLex;
    40 structure P = OuterParse;
    41 
    42 
    43 (** global options **)
    44 
    45 val display = ref false;
    46 val quotes = ref false;
    47 val indent = ref 0;
    48 val source = ref false;
    49 val break = ref false;
    50 
    51 
    52 
    53 (** maintain global antiquotations **)
    54 
    55 local
    56 
    57 val global_commands =
    58   ref (Symtab.empty: (Args.src -> Toplevel.state -> string) Symtab.table);
    59 
    60 val global_options =
    61   ref (Symtab.empty: (string -> (unit -> string) -> unit -> string) Symtab.table);
    62 
    63 fun add_item kind (name, x) tab =
    64  (if not (Symtab.defined tab name) then ()
    65   else warning ("Redefined document antiquotation " ^ kind ^ ": " ^ quote name);
    66   Symtab.update (name, x) tab);
    67 
    68 in
    69 
    70 fun add_commands xs = CRITICAL (fn () => change global_commands (fold (add_item "command") xs));
    71 fun add_options xs = CRITICAL (fn () => change global_options (fold (add_item "option") xs));
    72 
    73 fun defined_command name = Symtab.defined (! global_commands) name;
    74 fun defined_option name = Symtab.defined (! global_options) name;
    75 
    76 fun command src =
    77   let val ((name, _), pos) = Args.dest_src src in
    78     (case Symtab.lookup (! global_commands) name of
    79       NONE => error ("Unknown document antiquotation: " ^ quote name ^ Position.str_of pos)
    80     | SOME f =>
    81        (Position.report (Markup.doc_antiq name) pos;
    82         (fn state => f src state handle ERROR msg =>
    83           cat_error msg ("The error(s) above occurred in document antiquotation: " ^
    84             quote name ^ Position.str_of pos))))
    85   end;
    86 
    87 fun option (name, s) f () =
    88   (case Symtab.lookup (! global_options) name of
    89     NONE => error ("Unknown document antiquotation option: " ^ quote name)
    90   | SOME opt => opt s f ());
    91 
    92 fun options [] f = f
    93   | options (opt :: opts) f = option opt (options opts f);
    94 
    95 
    96 fun print_antiquotations () =
    97  [Pretty.big_list "document antiquotation commands:"
    98     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
    99   Pretty.big_list "document antiquotation options:"
   100     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
   101  |> Pretty.chunks |> Pretty.writeln;
   102 
   103 end;
   104 
   105 fun antiquotation name scan out = add_commands [(name, fn src => fn state =>
   106   let val (x, ctxt) = Args.context_syntax "document antiquotation"
   107     scan src (Toplevel.presentation_context_of state)
   108   in out {source = src, state = state, context = ctxt} x end)];
   109 
   110 
   111 
   112 (** syntax of antiquotations **)
   113 
   114 (* option values *)
   115 
   116 fun boolean "" = true
   117   | boolean "true" = true
   118   | boolean "false" = false
   119   | boolean s = error ("Bad boolean value: " ^ quote s);
   120 
   121 fun integer s =
   122   let
   123     fun int ss =
   124       (case Library.read_int ss of (i, []) => i
   125       | _ => error ("Bad integer value: " ^ quote s));
   126   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   127 
   128 
   129 (* outer syntax *)
   130 
   131 local
   132 
   133 val property = P.xname -- Scan.optional (P.$$$ "=" |-- P.!!! P.xname) "";
   134 val properties = Scan.optional (P.$$$ "[" |-- P.!!! (P.enum "," property --| P.$$$ "]")) [];
   135 
   136 in
   137 
   138 val antiq = P.!!! (P.position P.xname -- properties -- Args.parse --| Scan.ahead P.eof)
   139   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   140 
   141 end;
   142 
   143 
   144 (* eval_antiquote *)
   145 
   146 val modes = ref ([]: string list);
   147 
   148 fun eval_antiquote lex state (txt, pos) =
   149   let
   150     fun expand (Antiquote.Text ss) = Symbol_Pos.content ss
   151       | expand (Antiquote.Antiq x) =
   152           let val (opts, src) = T.read_antiq lex antiq x in
   153             options opts (fn () => command src state) ();  (*preview errors!*)
   154             PrintMode.with_modes (! modes @ Latex.modes)
   155               (Output.no_warnings (options opts (fn () => command src state))) ()
   156           end
   157       | expand (Antiquote.Open _) = ""
   158       | expand (Antiquote.Close _) = "";
   159     val ants = Antiquote.read (Symbol_Pos.explode (txt, pos), pos);
   160   in
   161     if Toplevel.is_toplevel state andalso not (forall Antiquote.is_text ants) then
   162       error ("Unknown context -- cannot expand document antiquotations" ^ Position.str_of pos)
   163     else implode (map expand ants)
   164   end;
   165 
   166 
   167 
   168 (** present theory source **)
   169 
   170 (*NB: arranging white space around command spans is a black art.*)
   171 
   172 (* presentation tokens *)
   173 
   174 datatype token =
   175     NoToken
   176   | BasicToken of T.token
   177   | MarkupToken of string * (string * Position.T)
   178   | MarkupEnvToken of string * (string * Position.T)
   179   | VerbatimToken of string * Position.T;
   180 
   181 fun output_token lex state =
   182   let val eval = eval_antiquote lex state in
   183     fn NoToken => ""
   184      | BasicToken tok => Latex.output_basic tok
   185      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   186      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   187      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   188   end;
   189 
   190 fun basic_token pred (BasicToken tok) = pred tok
   191   | basic_token _ _ = false;
   192 
   193 val improper_token = basic_token (not o T.is_proper);
   194 val comment_token = basic_token T.is_comment;
   195 val blank_token = basic_token T.is_blank;
   196 val newline_token = basic_token T.is_newline;
   197 
   198 
   199 (* command spans *)
   200 
   201 type command = string * Position.T * string list;   (*name, position, tags*)
   202 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   203 
   204 datatype span = Span of command * (source * source * source * source) * bool;
   205 
   206 fun make_span cmd src =
   207   let
   208     fun take_newline (tok :: toks) =
   209           if newline_token (fst tok) then ([tok], toks, true)
   210           else ([], tok :: toks, false)
   211       | take_newline [] = ([], [], false);
   212     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   213       src
   214       |> take_prefix (improper_token o fst)
   215       ||>> take_suffix (improper_token o fst)
   216       ||>> take_prefix (comment_token o fst)
   217       ||> take_newline;
   218   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   219 
   220 
   221 (* present spans *)
   222 
   223 local
   224 
   225 fun err_bad_nesting pos =
   226   error ("Bad nesting of commands in presentation" ^ pos);
   227 
   228 fun edge which f (x: string option, y) =
   229   if x = y then I
   230   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   231 
   232 val begin_tag = edge #2 Latex.begin_tag;
   233 val end_tag = edge #1 Latex.end_tag;
   234 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   235 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   236 
   237 in
   238 
   239 fun present_span lex default_tags span state state'
   240     (tag_stack, active_tag, newline, buffer, present_cont) =
   241   let
   242     val present = fold (fn (tok, (flag, 0)) =>
   243         Buffer.add (output_token lex state' tok)
   244         #> Buffer.add flag
   245       | _ => I);
   246 
   247     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   248 
   249     val (tag, tags) = tag_stack;
   250     val tag' = try hd (fold OuterKeyword.update_tags cmd_tags (the_list tag));
   251 
   252     val active_tag' =
   253       if is_some tag' then tag'
   254       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   255       else try hd (default_tags cmd_name);
   256     val edge = (active_tag, active_tag');
   257 
   258     val newline' =
   259       if is_none active_tag' then span_newline else newline;
   260 
   261     val nesting = Toplevel.level state' - Toplevel.level state;
   262     val tag_stack' =
   263       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   264       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   265       else
   266         (case Library.drop (~ nesting - 1, tags) of
   267           tgs :: tgss => (tgs, tgss)
   268         | [] => err_bad_nesting (Position.str_of cmd_pos));
   269 
   270     val buffer' =
   271       buffer
   272       |> end_tag edge
   273       |> close_delim (fst present_cont) edge
   274       |> snd present_cont
   275       |> open_delim (present (#1 srcs)) edge
   276       |> begin_tag edge
   277       |> present (#2 srcs);
   278     val present_cont' =
   279       if newline then (present (#3 srcs), present (#4 srcs))
   280       else (I, present (#3 srcs) #> present (#4 srcs));
   281   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   282 
   283 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   284   if not (null tags) then err_bad_nesting " at end of theory"
   285   else
   286     buffer
   287     |> end_tag (active_tag, NONE)
   288     |> close_delim (fst present_cont) (active_tag, NONE)
   289     |> snd present_cont;
   290 
   291 end;
   292 
   293 
   294 (* present_thy *)
   295 
   296 datatype markup = Markup | MarkupEnv | Verbatim;
   297 
   298 local
   299 
   300 val space_proper =
   301   Scan.one T.is_blank -- Scan.many T.is_comment -- Scan.one T.is_proper;
   302 
   303 val is_improper = not o (T.is_proper orf T.is_begin_ignore orf T.is_end_ignore);
   304 val improper = Scan.many is_improper;
   305 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   306 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one T.is_blank));
   307 
   308 val opt_newline = Scan.option (Scan.one T.is_newline);
   309 
   310 val ignore =
   311   Scan.depend (fn d => opt_newline |-- Scan.one T.is_begin_ignore
   312     >> pair (d + 1)) ||
   313   Scan.depend (fn d => Scan.one T.is_end_ignore --|
   314     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   315     >> pair (d - 1));
   316 
   317 val tag = (improper -- P.$$$ "%" -- improper) |-- P.!!! (P.tag_name --| blank_end);
   318 
   319 val locale =
   320   Scan.option ((P.$$$ "(" -- improper -- P.$$$ "in") |--
   321     P.!!! (improper |-- P.xname --| (improper -- P.$$$ ")")));
   322 
   323 in
   324 
   325 fun present_thy lex default_tags is_markup command_results src =
   326   let
   327     (* tokens *)
   328 
   329     val ignored = Scan.state --| ignore
   330       >> (fn d => (NONE, (NoToken, ("", d))));
   331 
   332     fun markup mark mk flag = Scan.peek (fn d =>
   333       improper |-- P.position (Scan.one (T.is_kind T.Command andf is_markup mark o T.content_of)) --
   334       Scan.repeat tag --
   335       P.!!!! ((improper -- locale -- improper) |-- P.doc_source --| improper_end)
   336       >> (fn (((tok, pos), tags), txt) =>
   337         let val name = T.content_of tok
   338         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   339 
   340     val command = Scan.peek (fn d =>
   341       P.position (Scan.one (T.is_kind T.Command)) --
   342       Scan.repeat tag
   343       >> (fn ((tok, pos), tags) =>
   344         let val name = T.content_of tok
   345         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   346 
   347     val cmt = Scan.peek (fn d =>
   348       P.$$$ "--" |-- P.!!!! (improper |-- P.doc_source)
   349       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   350 
   351     val other = Scan.peek (fn d =>
   352        P.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   353 
   354     val token =
   355       ignored ||
   356       markup Markup MarkupToken Latex.markup_true ||
   357       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   358       markup Verbatim (VerbatimToken o #2) "" ||
   359       command || cmt || other;
   360 
   361 
   362     (* spans *)
   363 
   364     val is_eof = fn (_, (BasicToken x, _)) => T.is_eof x | _ => false;
   365     val stopper = Scan.stopper (K (NONE, (BasicToken T.eof, ("", 0)))) is_eof;
   366 
   367     val cmd = Scan.one (is_some o fst);
   368     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   369 
   370     val comments = Scan.many (comment_token o fst o snd);
   371     val blank = Scan.one (blank_token o fst o snd);
   372     val newline = Scan.one (newline_token o fst o snd);
   373     val before_cmd =
   374       Scan.option (newline -- comments) --
   375       Scan.option (newline -- comments) --
   376       Scan.option (blank -- comments) -- cmd;
   377 
   378     val span =
   379       Scan.repeat non_cmd -- cmd --
   380         Scan.repeat (Scan.unless before_cmd non_cmd) --
   381         Scan.option (newline >> (single o snd))
   382       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   383           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   384 
   385     val spans =
   386       src
   387       |> Source.filter (not o T.is_semicolon)
   388       |> Source.source' 0 T.stopper (Scan.error (Scan.bulk token)) NONE
   389       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   390       |> Source.exhaust;
   391 
   392 
   393     (* present commands *)
   394 
   395     fun present_command tr span st st' =
   396       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   397 
   398     fun present _ [] = I
   399       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   400   in
   401     if length command_results = length spans then
   402       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   403       |> present Toplevel.toplevel (command_results ~~ spans)
   404       |> present_trailer
   405     else error "Messed-up outer syntax for presentation"
   406   end;
   407 
   408 end;
   409 
   410 
   411 
   412 (** setup default output **)
   413 
   414 (* options *)
   415 
   416 val _ = add_options
   417  [("show_types", Library.setmp Syntax.show_types o boolean),
   418   ("show_sorts", Library.setmp Syntax.show_sorts o boolean),
   419   ("show_structs", Library.setmp show_structs o boolean),
   420   ("show_question_marks", Library.setmp show_question_marks o boolean),
   421   ("long_names", Library.setmp NameSpace.long_names o boolean),
   422   ("short_names", Library.setmp NameSpace.short_names o boolean),
   423   ("unique_names", Library.setmp NameSpace.unique_names o boolean),
   424   ("eta_contract", Library.setmp Syntax.eta_contract o boolean),
   425   ("display", Library.setmp display o boolean),
   426   ("break", Library.setmp break o boolean),
   427   ("quotes", Library.setmp quotes o boolean),
   428   ("mode", fn s => fn f => PrintMode.with_modes [s] f),
   429   ("margin", Pretty.setmp_margin o integer),
   430   ("indent", Library.setmp indent o integer),
   431   ("source", Library.setmp source o boolean),
   432   ("goals_limit", Library.setmp goals_limit o integer)];
   433 
   434 
   435 (* basic pretty printing *)
   436 
   437 fun tweak_line s =
   438   if ! display then s else Symbol.strip_blanks s;
   439 
   440 val pretty_text = Pretty.chunks o map Pretty.str o map tweak_line o Library.split_lines;
   441 
   442 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   443 
   444 fun pretty_term_abbrev ctxt t = ProofContext.pretty_term_abbrev (Variable.auto_fixes t ctxt) t;
   445 
   446 fun pretty_term_typ ctxt t =
   447   Syntax.pretty_term ctxt (TypeInfer.constrain (Term.fastype_of t) t);
   448 
   449 fun pretty_term_typeof ctxt = Syntax.pretty_typ ctxt o Term.fastype_of;
   450 
   451 fun pretty_const ctxt c =
   452   let
   453     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   454       handle TYPE (msg, _, _) => error msg;
   455     val ([t'], _) = Variable.import_terms true [t] ctxt;
   456   in pretty_term ctxt t' end;
   457 
   458 fun pretty_abbrev ctxt s =
   459   let
   460     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   461     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   462     val (head, args) = Term.strip_comb t;
   463     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   464     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   465       handle TYPE _ => err ();
   466     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   467   in pretty_term_abbrev ctxt (Logic.mk_equals (t, t')) end;
   468 
   469 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   470 
   471 fun pretty_term_style ctxt (name, t) =
   472   pretty_term ctxt (TermStyle.the_style (ProofContext.theory_of ctxt) name ctxt t);
   473 
   474 fun pretty_thm_style ctxt (name, th) =
   475   pretty_term_style ctxt (name, Thm.full_prop_of th);
   476 
   477 fun pretty_prf full ctxt = ProofSyntax.pretty_proof_of ctxt full;
   478 
   479 fun pretty_theory ctxt name =
   480   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   481 
   482 
   483 (* default output *)
   484 
   485 val str_of_source = space_implode " " o map T.unparse o #2 o #1 o Args.dest_src;
   486 
   487 fun maybe_pretty_source pretty src xs =
   488   map pretty xs  (*always pretty in order to exhibit errors!*)
   489   |> (if ! source then K [pretty_text (str_of_source src)] else I);
   490 
   491 fun output prts =
   492   prts
   493   |> (if ! quotes then map Pretty.quote else I)
   494   |> (if ! display then
   495     map (Output.output o Pretty.string_of o Pretty.indent (! indent))
   496     #> space_implode "\\isasep\\isanewline%\n"
   497     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   498   else
   499     map (Output.output o (if ! break then Pretty.string_of else Pretty.str_of))
   500     #> space_implode "\\isasep\\isanewline%\n"
   501     #> enclose "\\isa{" "}");
   502 
   503 
   504 
   505 (** concrete antiquotations **)
   506 
   507 (* basic entities *)
   508 
   509 local
   510 
   511 fun basic_entities name scan pretty = antiquotation name scan
   512   (fn {source, context, ...} => output o maybe_pretty_source (pretty context) source);
   513 
   514 fun basic_entity name scan = basic_entities name (scan >> single);
   515 
   516 in
   517 
   518 val _ = basic_entities "thm" Attrib.thms pretty_thm;
   519 val _ = basic_entity "thm_style" (Scan.lift Args.liberal_name -- Attrib.thm) pretty_thm_style;
   520 val _ = basic_entity "prop" Args.prop pretty_term;
   521 val _ = basic_entity "term" Args.term pretty_term;
   522 val _ = basic_entity "term_style" (Scan.lift Args.liberal_name -- Args.term) pretty_term_style;
   523 val _ = basic_entity "term_type" Args.term pretty_term_typ;
   524 val _ = basic_entity "typeof" Args.term pretty_term_typeof;
   525 val _ = basic_entity "const" Args.const_proper pretty_const;
   526 val _ = basic_entity "abbrev" (Scan.lift Args.name_source) pretty_abbrev;
   527 val _ = basic_entity "typ" Args.typ_abbrev Syntax.pretty_typ;
   528 val _ = basic_entity "text" (Scan.lift Args.name) (K pretty_text);
   529 val _ = basic_entities "prf" Attrib.thms (pretty_prf false);
   530 val _ = basic_entities "full_prf" Attrib.thms (pretty_prf true);
   531 val _ = basic_entity "theory" (Scan.lift Args.name) pretty_theory;
   532 
   533 end;
   534 
   535 
   536 (* goal state *)
   537 
   538 local
   539 
   540 fun proof_state state =
   541   (case try Toplevel.proof_of state of
   542     SOME prf => prf
   543   | _ => error "No proof state");
   544 
   545 fun goal_state name main_goal = antiquotation name (Scan.succeed ())
   546   (fn {state, ...} => fn () => output
   547     [Pretty.chunks (Proof.pretty_goals main_goal (proof_state state))]);
   548 
   549 in
   550 
   551 val _ = goal_state "goals" true;
   552 val _ = goal_state "subgoals" false;
   553 
   554 end;
   555 
   556 
   557 (* embedded lemma *)
   558 
   559 val _ = OuterKeyword.keyword "by";
   560 
   561 val _ = antiquotation "lemma"
   562   (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   563   (fn {source, context, ...} => fn (prop, methods) =>
   564     let
   565       val prop_src =
   566         (case Args.dest_src source of ((a, arg :: _), pos) => Args.src ((a, [arg]), pos));
   567       val _ = context
   568         |> Proof.theorem_i NONE (K I) [[(prop, [])]]
   569         |> Proof.global_terminal_proof methods;
   570     in output (maybe_pretty_source (pretty_term context) prop_src [prop]) end);
   571 
   572 
   573 (* ML text *)
   574 
   575 local
   576 
   577 fun ml_text name ml = antiquotation name (Scan.lift Args.name_source_position)
   578   (fn {context, ...} => fn (txt, pos) =>
   579    (ML_Context.eval_in (SOME context) false pos (ml txt);
   580     Symbol_Pos.content (Symbol_Pos.explode (txt, pos))
   581     |> (if ! quotes then quote else I)
   582     |> (if ! display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   583     else
   584       split_lines
   585       #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   586       #> space_implode "\\isasep\\isanewline%\n")));
   587 
   588 in
   589 
   590 val _ = ml_text "ML" (fn txt => "fn _ => (" ^ txt ^ ");");
   591 val _ = ml_text "ML_type" (fn txt => "val _ = NONE : (" ^ txt ^ ") option;");
   592 val _ = ml_text "ML_struct" (fn txt => "functor XXX() = struct structure XX = " ^ txt ^ " end;");
   593 val _ = ml_text "ML_functor" (K "");  (*no check!*)
   594 val _ = ml_text "ML_text" (K "");
   595 
   596 end;
   597 
   598 end;