src/HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
author blanchet
Fri Apr 16 15:49:13 2010 +0200 (2010-04-16)
changeset 36170 0cdb76723c88
parent 36169 27b1cc58715e
child 36218 0e4a01f3e7d3
permissions -rw-r--r--
added original constant names to Sledgehammer internal terms + output short names if "debug" is set (for increased readability)
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory
     3 
     4 Storing/printing FOL clauses and arity clauses.  Typed equality is
     5 treated differently.
     6 
     7 FIXME: combine with res_hol_clause!
     8 *)
     9 
    10 signature SLEDGEHAMMER_FOL_CLAUSE =
    11 sig
    12   val schematic_var_prefix: string
    13   val fixed_var_prefix: string
    14   val tvar_prefix: string
    15   val tfree_prefix: string
    16   val clause_prefix: string
    17   val const_prefix: string
    18   val tconst_prefix: string
    19   val class_prefix: string
    20   val union_all: ''a list list -> ''a list
    21   val const_trans_table: string Symtab.table
    22   val type_const_trans_table: string Symtab.table
    23   val ascii_of: string -> string
    24   val undo_ascii_of: string -> string
    25   val paren_pack : string list -> string
    26   val make_schematic_var : string * int -> string
    27   val make_fixed_var : string -> string
    28   val make_schematic_type_var : string * int -> string
    29   val make_fixed_type_var : string -> string
    30   val make_fixed_const : bool -> string -> string
    31   val make_fixed_type_const : bool -> string -> string
    32   val make_type_class : string -> string
    33   type name = string * string
    34   type name_pool = string Symtab.table * string Symtab.table
    35   val empty_name_pool : bool -> name_pool option
    36   val pool_map : ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    37   val nice_name : name -> name_pool option -> string * name_pool option
    38   datatype kind = Axiom | Conjecture
    39   type axiom_name = string
    40   datatype fol_type =
    41     TyVar of name |
    42     TyFree of name |
    43     TyConstr of name * fol_type list
    44   val string_of_fol_type :
    45     fol_type -> name_pool option -> string * name_pool option
    46   datatype type_literal = LTVar of string * string | LTFree of string * string
    47   exception CLAUSE of string * term
    48   val add_typs : typ list -> type_literal list
    49   val get_tvar_strs: typ list -> string list
    50   datatype arLit =
    51       TConsLit of class * string * string list
    52     | TVarLit of class * string
    53   datatype arity_clause = ArityClause of
    54    {axiom_name: axiom_name, conclLit: arLit, premLits: arLit list}
    55   datatype classrel_clause = ClassrelClause of
    56    {axiom_name: axiom_name, subclass: class, superclass: class}
    57   val make_classrel_clauses: theory -> class list -> class list -> classrel_clause list
    58   val make_arity_clauses_dfg: bool -> theory -> string list -> class list -> class list * arity_clause list
    59   val make_arity_clauses: theory -> string list -> class list -> class list * arity_clause list
    60   val add_type_sort_preds: typ * int Symtab.table -> int Symtab.table
    61   val add_classrel_clause_preds : classrel_clause * int Symtab.table -> int Symtab.table
    62   val class_of_arityLit: arLit -> class
    63   val add_arity_clause_preds: arity_clause * int Symtab.table -> int Symtab.table
    64   val add_foltype_funcs: fol_type * int Symtab.table -> int Symtab.table
    65   val add_arity_clause_funcs: arity_clause * int Symtab.table -> int Symtab.table
    66   val init_functab: int Symtab.table
    67   val dfg_sign: bool -> string -> string
    68   val dfg_of_typeLit: bool -> type_literal -> string
    69   val gen_dfg_cls: int * string * kind * string list * string list * string list -> string
    70   val string_of_preds: (string * Int.int) list -> string
    71   val string_of_funcs: (string * int) list -> string
    72   val string_of_symbols: string -> string -> string
    73   val string_of_start: string -> string
    74   val string_of_descrip : string -> string
    75   val dfg_tfree_clause : string -> string
    76   val dfg_classrel_clause: classrel_clause -> string
    77   val dfg_arity_clause: arity_clause -> string
    78   val tptp_sign: bool -> string -> string
    79   val tptp_of_typeLit : bool -> type_literal -> string
    80   val gen_tptp_cls : int * string * kind * string list * string list -> string
    81   val tptp_tfree_clause : string -> string
    82   val tptp_arity_clause : arity_clause -> string
    83   val tptp_classrel_clause : classrel_clause -> string
    84 end
    85 
    86 structure Sledgehammer_FOL_Clause : SLEDGEHAMMER_FOL_CLAUSE =
    87 struct
    88 
    89 open Sledgehammer_Util
    90 
    91 val schematic_var_prefix = "V_";
    92 val fixed_var_prefix = "v_";
    93 
    94 val tvar_prefix = "T_";
    95 val tfree_prefix = "t_";
    96 
    97 val clause_prefix = "cls_";
    98 val arclause_prefix = "clsarity_"
    99 val clrelclause_prefix = "clsrel_";
   100 
   101 val const_prefix = "c_";
   102 val tconst_prefix = "tc_";
   103 val class_prefix = "class_";
   104 
   105 fun union_all xss = List.foldl (uncurry (union (op =))) [] xss;
   106 
   107 (* Provide readable names for the more common symbolic functions *)
   108 val const_trans_table =
   109   Symtab.make [(@{const_name "op ="}, "equal"),
   110                (@{const_name Orderings.less_eq}, "lessequals"),
   111                (@{const_name "op &"}, "and"),
   112                (@{const_name "op |"}, "or"),
   113                (@{const_name "op -->"}, "implies"),
   114                (@{const_name "op :"}, "in"),
   115                (@{const_name fequal}, "fequal"),
   116                (@{const_name COMBI}, "COMBI"),
   117                (@{const_name COMBK}, "COMBK"),
   118                (@{const_name COMBB}, "COMBB"),
   119                (@{const_name COMBC}, "COMBC"),
   120                (@{const_name COMBS}, "COMBS")];
   121 
   122 val type_const_trans_table =
   123   Symtab.make [("*", "prod"), ("+", "sum"), ("~=>", "map")];
   124 
   125 (*Escaping of special characters.
   126   Alphanumeric characters are left unchanged.
   127   The character _ goes to __
   128   Characters in the range ASCII space to / go to _A to _P, respectively.
   129   Other printing characters go to _nnn where nnn is the decimal ASCII code.*)
   130 val A_minus_space = Char.ord #"A" - Char.ord #" ";
   131 
   132 fun stringN_of_int 0 _ = ""
   133   | stringN_of_int k n = stringN_of_int (k-1) (n div 10) ^ Int.toString (n mod 10);
   134 
   135 fun ascii_of_c c =
   136   if Char.isAlphaNum c then String.str c
   137   else if c = #"_" then "__"
   138   else if #" " <= c andalso c <= #"/"
   139        then "_" ^ String.str (Char.chr (Char.ord c + A_minus_space))
   140   else if Char.isPrint c
   141        then ("_" ^ stringN_of_int 3 (Char.ord c))  (*fixed width, in case more digits follow*)
   142   else ""
   143 
   144 val ascii_of = String.translate ascii_of_c;
   145 
   146 (** Remove ASCII armouring from names in proof files **)
   147 
   148 (*We don't raise error exceptions because this code can run inside the watcher.
   149   Also, the errors are "impossible" (hah!)*)
   150 fun undo_ascii_aux rcs [] = String.implode(rev rcs)
   151   | undo_ascii_aux rcs [#"_"] = undo_ascii_aux (#"_"::rcs) []  (*ERROR*)
   152       (*Three types of _ escapes: __, _A to _P, _nnn*)
   153   | undo_ascii_aux rcs (#"_" :: #"_" :: cs) = undo_ascii_aux (#"_"::rcs) cs
   154   | undo_ascii_aux rcs (#"_" :: c :: cs) =
   155       if #"A" <= c andalso c<= #"P"  (*translation of #" " to #"/"*)
   156       then undo_ascii_aux (Char.chr(Char.ord c - A_minus_space) :: rcs) cs
   157       else
   158         let val digits = List.take (c::cs, 3) handle Subscript => []
   159         in
   160             case Int.fromString (String.implode digits) of
   161                 NONE => undo_ascii_aux (c:: #"_"::rcs) cs  (*ERROR*)
   162               | SOME n => undo_ascii_aux (Char.chr n :: rcs) (List.drop (cs, 2))
   163         end
   164   | undo_ascii_aux rcs (c::cs) = undo_ascii_aux (c::rcs) cs;
   165 
   166 val undo_ascii_of = undo_ascii_aux [] o String.explode;
   167 
   168 (* convert a list of strings into one single string; surrounded by brackets *)
   169 fun paren_pack [] = ""   (*empty argument list*)
   170   | paren_pack strings = "(" ^ commas strings ^ ")";
   171 
   172 (*TSTP format uses (...) rather than the old [...]*)
   173 fun tptp_pack strings = "(" ^ space_implode " | " strings ^ ")";
   174 
   175 
   176 (*Remove the initial ' character from a type variable, if it is present*)
   177 fun trim_type_var s =
   178   if s <> "" andalso String.sub(s,0) = #"'" then String.extract(s,1,NONE)
   179   else error ("trim_type: Malformed type variable encountered: " ^ s);
   180 
   181 fun ascii_of_indexname (v,0) = ascii_of v
   182   | ascii_of_indexname (v,i) = ascii_of v ^ "_" ^ Int.toString i;
   183 
   184 fun make_schematic_var v = schematic_var_prefix ^ (ascii_of_indexname v);
   185 fun make_fixed_var x = fixed_var_prefix ^ (ascii_of x);
   186 
   187 fun make_schematic_type_var (x,i) =
   188       tvar_prefix ^ (ascii_of_indexname (trim_type_var x,i));
   189 fun make_fixed_type_var x = tfree_prefix ^ (ascii_of (trim_type_var x));
   190 
   191 (* HACK because SPASS 3.0 truncates identifiers to 63 characters. (This is
   192    solved in 3.7 and perhaps in earlier versions too.) *)
   193 (* 32-bit hash, so we expect no collisions. *)
   194 fun controlled_length dfg s =
   195   if dfg andalso size s > 60 then Word.toString (hashw_string (s, 0w0)) else s;
   196 
   197 fun lookup_const dfg c =
   198     case Symtab.lookup const_trans_table c of
   199         SOME c' => c'
   200       | NONE => controlled_length dfg (ascii_of c);
   201 
   202 fun lookup_type_const dfg c =
   203     case Symtab.lookup type_const_trans_table c of
   204         SOME c' => c'
   205       | NONE => controlled_length dfg (ascii_of c);
   206 
   207 (* "op =" MUST BE "equal" because it's built into ATPs. *)
   208 fun make_fixed_const _ (@{const_name "op ="}) = "equal"
   209   | make_fixed_const dfg c = const_prefix ^ lookup_const dfg c;
   210 
   211 fun make_fixed_type_const dfg c = tconst_prefix ^ lookup_type_const dfg c;
   212 
   213 fun make_type_class clas = class_prefix ^ ascii_of clas;
   214 
   215 
   216 (**** name pool ****)
   217  
   218 type name = string * string
   219 type name_pool = string Symtab.table * string Symtab.table
   220 
   221 fun empty_name_pool debug = if debug then SOME (`I Symtab.empty) else NONE
   222 
   223 fun pool_map f xs =
   224   fold_rev (fn x => fn (ys, pool) => f x pool |>> (fn y => y :: ys)) xs
   225   o pair []
   226 
   227 fun add_nice_name full_name nice_prefix j the_pool =
   228   let
   229     val nice_name = nice_prefix ^ (if j = 0 then "" else "_" ^ Int.toString j)
   230   in
   231     case Symtab.lookup (snd the_pool) nice_name of
   232       SOME full_name' =>
   233       if full_name = full_name' then (nice_name, the_pool)
   234       else add_nice_name full_name nice_prefix (j + 1) the_pool
   235     | NONE =>
   236       (nice_name, (Symtab.update_new (full_name, nice_name) (fst the_pool),
   237                    Symtab.update_new (nice_name, full_name) (snd the_pool)))
   238   end
   239 
   240 fun translate_first_char f s =
   241   String.str (f (String.sub (s, 0))) ^ String.extract (s, 1, NONE)
   242 
   243 fun clean_short_name full_name s =
   244   let
   245     val s = s |> Long_Name.base_name
   246               |> fold remove_all ["\<^sub>", "\<^bsub>", "\<^esub>", "\<^isub>"]
   247     val s' = s |> explode |> rev |> dropwhile (curry (op =) "'")
   248     val s' =
   249       (s' |> rev
   250           |> implode
   251           |> String.translate
   252                  (fn c => if Char.isAlphaNum c then String.str c else ""))
   253       ^ replicate_string (String.size s - length s') "_"
   254     val s' =
   255       if s' = "" orelse not (Char.isAlpha (String.sub (s', 0))) then "X" ^ s'
   256       else s'
   257     val s' = if s' = "op" then full_name else s'
   258   in
   259     case (Char.isLower (String.sub (full_name, 0)),
   260           Char.isLower (String.sub (s', 0))) of
   261       (true, false) => translate_first_char Char.toLower s'
   262     | (false, true) => translate_first_char Char.toUpper s'
   263     | _ => s'
   264   end
   265 
   266 fun nice_name (full_name, _) NONE = (full_name, NONE)
   267   | nice_name (full_name, desired_name) (SOME the_pool) =
   268     case Symtab.lookup (fst the_pool) full_name of
   269       SOME nice_name => (nice_name, SOME the_pool)
   270     | NONE => add_nice_name full_name (clean_short_name full_name desired_name)
   271                             0 the_pool
   272               |> apsnd SOME
   273 
   274 (**** Definitions and functions for FOL clauses, for conversion to TPTP or DFG
   275       format ****)
   276 
   277 datatype kind = Axiom | Conjecture;
   278 
   279 type axiom_name = string;
   280 
   281 (**** Isabelle FOL clauses ****)
   282 
   283 datatype fol_type =
   284   TyVar of name |
   285   TyFree of name |
   286   TyConstr of name * fol_type list
   287 
   288 fun string_of_fol_type (TyVar sp) pool = nice_name sp pool
   289   | string_of_fol_type (TyFree sp) pool = nice_name sp pool
   290   | string_of_fol_type (TyConstr (sp, tys)) pool =
   291     let
   292       val (s, pool) = nice_name sp pool
   293       val (ss, pool) = pool_map string_of_fol_type tys pool
   294     in (s ^ paren_pack ss, pool) end
   295 
   296 (*First string is the type class; the second is a TVar or TFfree*)
   297 datatype type_literal = LTVar of string * string | LTFree of string * string;
   298 
   299 exception CLAUSE of string * term;
   300 
   301 (*Make literals for sorted type variables*)
   302 fun sorts_on_typs_aux (_, [])   = []
   303   | sorts_on_typs_aux ((x,i),  s::ss) =
   304       let val sorts = sorts_on_typs_aux ((x,i), ss)
   305       in
   306           if s = "HOL.type" then sorts
   307           else if i = ~1 then LTFree(make_type_class s, make_fixed_type_var x) :: sorts
   308           else LTVar(make_type_class s, make_schematic_type_var (x,i)) :: sorts
   309       end;
   310 
   311 fun sorts_on_typs (TFree (a,s)) = sorts_on_typs_aux ((a,~1),s)
   312   | sorts_on_typs (TVar (v,s))  = sorts_on_typs_aux (v,s);
   313 
   314 fun pred_of_sort (LTVar (s,ty)) = (s,1)
   315   | pred_of_sort (LTFree (s,ty)) = (s,1)
   316 
   317 (*Given a list of sorted type variables, return a list of type literals.*)
   318 fun add_typs Ts = List.foldl (uncurry (union (op =))) [] (map sorts_on_typs Ts);
   319 
   320 (*The correct treatment of TFrees like 'a in lemmas (axiom clauses) is not clear.
   321   * Ignoring them leads to unsound proofs, since we do nothing to ensure that 'a
   322     in a lemma has the same sort as 'a in the conjecture.
   323   * Deleting such clauses will lead to problems with locales in other use of local results
   324     where 'a is fixed. Probably we should delete clauses unless the sorts agree.
   325   * Currently we include a class constraint in the clause, exactly as with TVars.
   326 *)
   327 
   328 (** make axiom and conjecture clauses. **)
   329 
   330 fun get_tvar_strs [] = []
   331   | get_tvar_strs ((TVar (indx,s))::Ts) =
   332       insert (op =) (make_schematic_type_var indx) (get_tvar_strs Ts)
   333   | get_tvar_strs((TFree _)::Ts) = get_tvar_strs Ts
   334 
   335 
   336 
   337 (**** Isabelle arities ****)
   338 
   339 datatype arLit = TConsLit of class * string * string list
   340                | TVarLit of class * string;
   341 
   342 datatype arity_clause =
   343          ArityClause of {axiom_name: axiom_name,
   344                          conclLit: arLit,
   345                          premLits: arLit list};
   346 
   347 
   348 fun gen_TVars 0 = []
   349   | gen_TVars n = ("T_" ^ Int.toString n) :: gen_TVars (n-1);
   350 
   351 fun pack_sort(_,[])  = []
   352   | pack_sort(tvar, "HOL.type"::srt) = pack_sort(tvar, srt)   (*IGNORE sort "type"*)
   353   | pack_sort(tvar, cls::srt) =  (cls, tvar) :: pack_sort(tvar, srt);
   354 
   355 (*Arity of type constructor tcon :: (arg1,...,argN)res*)
   356 fun make_axiom_arity_clause dfg (tcons, axiom_name, (cls,args)) =
   357    let val tvars = gen_TVars (length args)
   358        val tvars_srts = ListPair.zip (tvars,args)
   359    in
   360       ArityClause {axiom_name = axiom_name, 
   361                    conclLit = TConsLit (cls, make_fixed_type_const dfg tcons, tvars),
   362                    premLits = map TVarLit (union_all(map pack_sort tvars_srts))}
   363    end;
   364 
   365 
   366 (**** Isabelle class relations ****)
   367 
   368 datatype classrel_clause =
   369          ClassrelClause of {axiom_name: axiom_name,
   370                             subclass: class,
   371                             superclass: class};
   372 
   373 (*Generate all pairs (sub,super) such that sub is a proper subclass of super in theory thy.*)
   374 fun class_pairs thy [] supers = []
   375   | class_pairs thy subs supers =
   376       let val class_less = Sorts.class_less(Sign.classes_of thy)
   377           fun add_super sub (super,pairs) =
   378                 if class_less (sub,super) then (sub,super)::pairs else pairs
   379           fun add_supers (sub,pairs) = List.foldl (add_super sub) pairs supers
   380       in  List.foldl add_supers [] subs  end;
   381 
   382 fun make_classrel_clause (sub,super) =
   383   ClassrelClause {axiom_name = clrelclause_prefix ^ ascii_of sub ^ "_" ^ ascii_of super,
   384                   subclass = make_type_class sub,
   385                   superclass = make_type_class super};
   386 
   387 fun make_classrel_clauses thy subs supers =
   388   map make_classrel_clause (class_pairs thy subs supers);
   389 
   390 
   391 (** Isabelle arities **)
   392 
   393 fun arity_clause dfg _ _ (tcons, []) = []
   394   | arity_clause dfg seen n (tcons, ("HOL.type",_)::ars) =  (*ignore*)
   395       arity_clause dfg seen n (tcons,ars)
   396   | arity_clause dfg seen n (tcons, (ar as (class,_)) :: ars) =
   397       if class mem_string seen then (*multiple arities for the same tycon, class pair*)
   398           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class ^ "_" ^ Int.toString n, ar) ::
   399           arity_clause dfg seen (n+1) (tcons,ars)
   400       else
   401           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class, ar) ::
   402           arity_clause dfg (class::seen) n (tcons,ars)
   403 
   404 fun multi_arity_clause dfg [] = []
   405   | multi_arity_clause dfg ((tcons,ars) :: tc_arlists) =
   406       arity_clause dfg [] 1 (tcons, ars)  @  multi_arity_clause dfg tc_arlists
   407 
   408 (*Generate all pairs (tycon,class,sorts) such that tycon belongs to class in theory thy
   409   provided its arguments have the corresponding sorts.*)
   410 fun type_class_pairs thy tycons classes =
   411   let val alg = Sign.classes_of thy
   412       fun domain_sorts (tycon,class) = Sorts.mg_domain alg tycon [class]
   413       fun add_class tycon (class,pairs) =
   414             (class, domain_sorts(tycon,class))::pairs
   415             handle Sorts.CLASS_ERROR _ => pairs
   416       fun try_classes tycon = (tycon, List.foldl (add_class tycon) [] classes)
   417   in  map try_classes tycons  end;
   418 
   419 (*Proving one (tycon, class) membership may require proving others, so iterate.*)
   420 fun iter_type_class_pairs thy tycons [] = ([], [])
   421   | iter_type_class_pairs thy tycons classes =
   422       let val cpairs = type_class_pairs thy tycons classes
   423           val newclasses = union_all (union_all (union_all (map (map #2 o #2) cpairs)))
   424             |> subtract (op =) classes |> subtract (op =) HOLogic.typeS
   425           val (classes', cpairs') = iter_type_class_pairs thy tycons newclasses
   426       in (union (op =) classes' classes, union (op =) cpairs' cpairs) end;
   427 
   428 fun make_arity_clauses_dfg dfg thy tycons classes =
   429   let val (classes', cpairs) = iter_type_class_pairs thy tycons classes
   430   in  (classes', multi_arity_clause dfg cpairs)  end;
   431 val make_arity_clauses = make_arity_clauses_dfg false;
   432 
   433 (**** Find occurrences of predicates in clauses ****)
   434 
   435 (*FIXME: multiple-arity checking doesn't work, as update_new is the wrong
   436   function (it flags repeated declarations of a function, even with the same arity)*)
   437 
   438 fun update_many (tab, keypairs) = List.foldl (uncurry Symtab.update) tab keypairs;
   439 
   440 fun add_type_sort_preds (T, preds) =
   441       update_many (preds, map pred_of_sort (sorts_on_typs T));
   442 
   443 fun add_classrel_clause_preds (ClassrelClause {subclass,superclass,...}, preds) =
   444   Symtab.update (subclass,1) (Symtab.update (superclass,1) preds);
   445 
   446 fun class_of_arityLit (TConsLit (tclass, _, _)) = tclass
   447   | class_of_arityLit (TVarLit (tclass, _)) = tclass;
   448 
   449 fun add_arity_clause_preds (ArityClause {conclLit,premLits,...}, preds) =
   450   let val classes = map (make_type_class o class_of_arityLit) (conclLit::premLits)
   451       fun upd (class,preds) = Symtab.update (class,1) preds
   452   in  List.foldl upd preds classes  end;
   453 
   454 (*** Find occurrences of functions in clauses ***)
   455 
   456 fun add_foltype_funcs (TyVar _, funcs) = funcs
   457   | add_foltype_funcs (TyFree (s, _), funcs) = Symtab.update (s, 0) funcs
   458   | add_foltype_funcs (TyConstr ((s, _), tys), funcs) =
   459       List.foldl add_foltype_funcs (Symtab.update (s, length tys) funcs) tys;
   460 
   461 (*TFrees are recorded as constants*)
   462 fun add_type_sort_funcs (TVar _, funcs) = funcs
   463   | add_type_sort_funcs (TFree (a, _), funcs) =
   464       Symtab.update (make_fixed_type_var a, 0) funcs
   465 
   466 fun add_arity_clause_funcs (ArityClause {conclLit,...}, funcs) =
   467   let val TConsLit (_, tcons, tvars) = conclLit
   468   in  Symtab.update (tcons, length tvars) funcs  end;
   469 
   470 (*This type can be overlooked because it is built-in...*)
   471 val init_functab = Symtab.update ("tc_itself", 1) Symtab.empty;
   472 
   473 
   474 (**** String-oriented operations ****)
   475 
   476 fun string_of_clausename (cls_id,ax_name) =
   477     clause_prefix ^ ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   478 
   479 fun string_of_type_clsname (cls_id,ax_name,idx) =
   480     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   481 
   482 
   483 (**** Producing DFG files ****)
   484 
   485 (*Attach sign in DFG syntax: false means negate.*)
   486 fun dfg_sign true s = s
   487   | dfg_sign false s = "not(" ^ s ^ ")"
   488 
   489 fun dfg_of_typeLit pos (LTVar (s,ty))  = dfg_sign pos (s ^ "(" ^ ty ^ ")")
   490   | dfg_of_typeLit pos (LTFree (s,ty)) = dfg_sign pos (s ^ "(" ^ ty ^ ")");
   491 
   492 (*Enclose the clause body by quantifiers, if necessary*)
   493 fun dfg_forall [] body = body
   494   | dfg_forall vars body = "forall([" ^ commas vars ^ "],\n" ^ body ^ ")"
   495 
   496 fun gen_dfg_cls (cls_id, ax_name, Axiom, lits, tylits, vars) =
   497       "clause( %(axiom)\n" ^
   498       dfg_forall vars ("or(" ^ commas (tylits@lits) ^ ")") ^ ",\n" ^
   499       string_of_clausename (cls_id,ax_name) ^  ").\n\n"
   500   | gen_dfg_cls (cls_id, ax_name, Conjecture, lits, _, vars) =
   501       "clause( %(negated_conjecture)\n" ^
   502       dfg_forall vars ("or(" ^ commas lits ^ ")") ^ ",\n" ^
   503       string_of_clausename (cls_id,ax_name) ^  ").\n\n";
   504 
   505 fun string_of_arity (name, num) =  "(" ^ name ^ "," ^ Int.toString num ^ ")"
   506 
   507 fun string_of_preds [] = ""
   508   | string_of_preds preds = "predicates[" ^ commas(map string_of_arity preds) ^ "].\n";
   509 
   510 fun string_of_funcs [] = ""
   511   | string_of_funcs funcs = "functions[" ^ commas(map string_of_arity funcs) ^ "].\n" ;
   512 
   513 fun string_of_symbols predstr funcstr =
   514   "list_of_symbols.\n" ^ predstr  ^ funcstr  ^ "end_of_list.\n\n";
   515 
   516 fun string_of_start name = "begin_problem(" ^ name ^ ").\n\n";
   517 
   518 fun string_of_descrip name =
   519   "list_of_descriptions.\nname({*" ^ name ^
   520   "*}).\nauthor({*Isabelle*}).\nstatus(unknown).\ndescription({*auto-generated*}).\nend_of_list.\n\n"
   521 
   522 fun dfg_tfree_clause tfree_lit =
   523   "clause( %(negated_conjecture)\n" ^ "or( " ^ tfree_lit ^ "),\n" ^ "tfree_tcs" ^ ").\n\n"
   524 
   525 fun dfg_of_arLit (TConsLit (c,t,args)) =
   526       dfg_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   527   | dfg_of_arLit (TVarLit (c,str)) =
   528       dfg_sign false (make_type_class c ^ "(" ^ str ^ ")")
   529 
   530 fun dfg_classrelLits sub sup =  "not(" ^ sub ^ "(T)), " ^ sup ^ "(T)";
   531 
   532 fun dfg_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   533   "clause(forall([T],\nor( " ^ dfg_classrelLits subclass superclass ^ ")),\n" ^
   534   axiom_name ^ ").\n\n";
   535 
   536 fun string_of_ar axiom_name = arclause_prefix ^ ascii_of axiom_name;
   537 
   538 fun dfg_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   539   let val TConsLit (_,_,tvars) = conclLit
   540       val lits = map dfg_of_arLit (conclLit :: premLits)
   541   in
   542       "clause( %(axiom)\n" ^
   543       dfg_forall tvars ("or( " ^ commas lits ^ ")") ^ ",\n" ^
   544       string_of_ar axiom_name ^ ").\n\n"
   545   end;
   546 
   547 
   548 (**** Produce TPTP files ****)
   549 
   550 fun tptp_sign true s = s
   551   | tptp_sign false s = "~ " ^ s
   552 
   553 fun tptp_of_typeLit pos (LTVar (s, ty))  = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   554   | tptp_of_typeLit pos (LTFree (s, ty)) = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   555 
   556 fun tptp_cnf name kind formula =
   557   "cnf(" ^ name ^ ", " ^ kind ^ ",\n    " ^ formula ^ ").\n"
   558 
   559 fun gen_tptp_cls (cls_id, ax_name, Axiom, lits, tylits) =
   560       tptp_cnf (string_of_clausename (cls_id, ax_name)) "axiom"
   561                (tptp_pack (tylits @ lits))
   562   | gen_tptp_cls (cls_id, ax_name, Conjecture, lits, _) =
   563       tptp_cnf (string_of_clausename (cls_id, ax_name)) "negated_conjecture"
   564                (tptp_pack lits)
   565 
   566 fun tptp_tfree_clause tfree_lit =
   567     tptp_cnf "tfree_tcs" "negated_conjecture" (tptp_pack [tfree_lit])
   568 
   569 fun tptp_of_arLit (TConsLit (c,t,args)) =
   570       tptp_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   571   | tptp_of_arLit (TVarLit (c,str)) =
   572       tptp_sign false (make_type_class c ^ "(" ^ str ^ ")")
   573 
   574 fun tptp_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   575   tptp_cnf (string_of_ar axiom_name) "axiom"
   576            (tptp_pack (map tptp_of_arLit (conclLit :: premLits)))
   577 
   578 fun tptp_classrelLits sub sup =
   579   let val tvar = "(T)"
   580   in  tptp_pack [tptp_sign false (sub^tvar), tptp_sign true (sup^tvar)]  end;
   581 
   582 fun tptp_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   583   tptp_cnf axiom_name "axiom" (tptp_classrelLits subclass superclass)
   584 
   585 end;