src/HOL/Transitive_Closure.thy
author wenzelm
Thu Oct 04 20:29:42 2007 +0200 (2007-10-04)
changeset 24850 0cfd722ab579
parent 23743 52fbc991039f
child 25295 12985023be5e
permissions -rw-r--r--
Name.uu, Name.aT;
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Reflexive and Transitive closure of a relation *}
     8 
     9 theory Transitive_Closure
    10 imports Predicate
    11 uses "~~/src/Provers/trancl.ML"
    12 begin
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 inductive_set
    24   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    25   for r :: "('a \<times> 'a) set"
    26 where
    27     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    28   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    29 
    30 inductive_set
    31   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    32   for r :: "('a \<times> 'a) set"
    33 where
    34     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    35   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    36 
    37 notation
    38   rtranclp  ("(_^**)" [1000] 1000) and
    39   tranclp  ("(_^++)" [1000] 1000)
    40 
    41 abbreviation
    42   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    43   "r^== == sup r op ="
    44 
    45 abbreviation
    46   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    47   "r^= == r \<union> Id"
    48 
    49 notation (xsymbols)
    50   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    51   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    52   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    53   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    54   trancl  ("(_\<^sup>+)" [1000] 999) and
    55   reflcl  ("(_\<^sup>=)" [1000] 999)
    56 
    57 notation (HTML output)
    58   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    59   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    60   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    61   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    62   trancl  ("(_\<^sup>+)" [1000] 999) and
    63   reflcl  ("(_\<^sup>=)" [1000] 999)
    64 
    65 
    66 subsection {* Reflexive-transitive closure *}
    67 
    68 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r Un Id)"
    69   by (simp add: expand_fun_eq)
    70 
    71 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    72   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    73   apply (simp only: split_tupled_all)
    74   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    75   done
    76 
    77 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    78   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    79   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    80 
    81 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
    82   -- {* monotonicity of @{text rtrancl} *}
    83   apply (rule predicate2I)
    84   apply (erule rtranclp.induct)
    85    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
    86   done
    87 
    88 lemmas rtrancl_mono = rtranclp_mono [to_set]
    89 
    90 theorem rtranclp_induct [consumes 1, induct set: rtranclp]:
    91   assumes a: "r^** a b"
    92     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
    93   shows "P b"
    94 proof -
    95   from a have "a = a --> P b"
    96     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
    97   thus ?thesis by iprover
    98 qed
    99 
   100 lemmas rtrancl_induct [consumes 1, induct set: rtrancl] = rtranclp_induct [to_set]
   101 
   102 lemmas rtranclp_induct2 =
   103   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   104                  consumes 1, case_names refl step]
   105 
   106 lemmas rtrancl_induct2 =
   107   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   108                  consumes 1, case_names refl step]
   109 
   110 lemma reflexive_rtrancl: "reflexive (r^*)"
   111   by (unfold refl_def) fast
   112 
   113 lemma trans_rtrancl: "trans(r^*)"
   114   -- {* transitivity of transitive closure!! -- by induction *}
   115 proof (rule transI)
   116   fix x y z
   117   assume "(x, y) \<in> r\<^sup>*"
   118   assume "(y, z) \<in> r\<^sup>*"
   119   thus "(x, z) \<in> r\<^sup>*" by induct (iprover!)+
   120 qed
   121 
   122 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
   123 
   124 lemma rtranclp_trans:
   125   assumes xy: "r^** x y"
   126   and yz: "r^** y z"
   127   shows "r^** x z" using yz xy
   128   by induct iprover+
   129 
   130 lemma rtranclE:
   131   assumes major: "(a::'a,b) : r^*"
   132     and cases: "(a = b) ==> P"
   133       "!!y. [| (a,y) : r^*; (y,b) : r |] ==> P"
   134   shows P
   135   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   136   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   137    apply (rule_tac [2] major [THEN rtrancl_induct])
   138     prefer 2 apply blast
   139    prefer 2 apply blast
   140   apply (erule asm_rl exE disjE conjE cases)+
   141   done
   142 
   143 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; r O (r^* \<inter> s) \<subseteq> s|] ==> r^* \<subseteq> s"
   144   apply (rule subsetI)
   145   apply (rule_tac p="x" in PairE, clarify)
   146   apply (erule rtrancl_induct, auto) 
   147   done
   148 
   149 lemma converse_rtranclp_into_rtranclp:
   150   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   151   by (rule rtranclp_trans) iprover+
   152 
   153 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   154 
   155 text {*
   156   \medskip More @{term "r^*"} equations and inclusions.
   157 *}
   158 
   159 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   160   apply (auto intro!: order_antisym)
   161   apply (erule rtranclp_induct)
   162    apply (rule rtranclp.rtrancl_refl)
   163   apply (blast intro: rtranclp_trans)
   164   done
   165 
   166 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   167 
   168 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   169   apply (rule set_ext)
   170   apply (simp only: split_tupled_all)
   171   apply (blast intro: rtrancl_trans)
   172   done
   173 
   174 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   175 by (drule rtrancl_mono, simp)
   176 
   177 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   178   apply (drule rtranclp_mono)
   179   apply (drule rtranclp_mono, simp)
   180   done
   181 
   182 lemmas rtrancl_subset = rtranclp_subset [to_set]
   183 
   184 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   185   by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   186 
   187 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   188 
   189 lemma rtranclp_reflcl [simp]: "(R^==)^** = R^**"
   190   by (blast intro!: rtranclp_subset)
   191 
   192 lemmas rtrancl_reflcl [simp] = rtranclp_reflcl [to_set]
   193 
   194 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   195   apply (rule sym)
   196   apply (rule rtrancl_subset, blast, clarify)
   197   apply (rename_tac a b)
   198   apply (case_tac "a = b", blast)
   199   apply (blast intro!: r_into_rtrancl)
   200   done
   201 
   202 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   203   apply (rule sym)
   204   apply (rule rtranclp_subset)
   205   apply blast+
   206   done
   207 
   208 theorem rtranclp_converseD:
   209   assumes r: "(r^--1)^** x y"
   210   shows "r^** y x"
   211 proof -
   212   from r show ?thesis
   213     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   214 qed
   215 
   216 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   217 
   218 theorem rtranclp_converseI:
   219   assumes r: "r^** y x"
   220   shows "(r^--1)^** x y"
   221 proof -
   222   from r show ?thesis
   223     by induct (iprover intro: rtranclp_trans conversepI)+
   224 qed
   225 
   226 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   227 
   228 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   229   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   230 
   231 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   232   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   233 
   234 theorem converse_rtranclp_induct[consumes 1]:
   235   assumes major: "r^** a b"
   236     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   237   shows "P a"
   238 proof -
   239   from rtranclp_converseI [OF major]
   240   show ?thesis
   241     by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   242 qed
   243 
   244 lemmas converse_rtrancl_induct[consumes 1] = converse_rtranclp_induct [to_set]
   245 
   246 lemmas converse_rtranclp_induct2 =
   247   converse_rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   248                  consumes 1, case_names refl step]
   249 
   250 lemmas converse_rtrancl_induct2 =
   251   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   252                  consumes 1, case_names refl step]
   253 
   254 lemma converse_rtranclpE:
   255   assumes major: "r^** x z"
   256     and cases: "x=z ==> P"
   257       "!!y. [| r x y; r^** y z |] ==> P"
   258   shows P
   259   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   260    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   261     prefer 2 apply iprover
   262    prefer 2 apply iprover
   263   apply (erule asm_rl exE disjE conjE cases)+
   264   done
   265 
   266 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   267 
   268 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   269 
   270 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   271 
   272 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   273   by (blast elim: rtranclE converse_rtranclE
   274     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   275 
   276 lemma rtrancl_unfold: "r^* = Id Un r O r^*"
   277   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   278 
   279 
   280 subsection {* Transitive closure *}
   281 
   282 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   283   apply (simp add: split_tupled_all)
   284   apply (erule trancl.induct)
   285   apply (iprover dest: subsetD)+
   286   done
   287 
   288 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   289   by (simp only: split_tupled_all) (erule r_into_trancl)
   290 
   291 text {*
   292   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   293 *}
   294 
   295 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   296   by (erule tranclp.induct) iprover+
   297 
   298 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   299 
   300 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   301   shows "!!c. r b c ==> r^++ a c" using r
   302   by induct iprover+
   303 
   304 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   305 
   306 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   307   -- {* intro rule from @{text r} and @{text rtrancl} *}
   308   apply (erule rtranclp.cases, iprover)
   309   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   310    apply (simp | rule r_into_rtranclp)+
   311   done
   312 
   313 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   314 
   315 lemma tranclp_induct [consumes 1, induct set: tranclp]:
   316   assumes a: "r^++ a b"
   317   and cases: "!!y. r a y ==> P y"
   318     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   319   shows "P b"
   320   -- {* Nice induction rule for @{text trancl} *}
   321 proof -
   322   from a have "a = a --> P b"
   323     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   324   thus ?thesis by iprover
   325 qed
   326 
   327 lemmas trancl_induct [consumes 1, induct set: trancl] = tranclp_induct [to_set]
   328 
   329 lemmas tranclp_induct2 =
   330   tranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   331                  consumes 1, case_names base step]
   332 
   333 lemmas trancl_induct2 =
   334   trancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   335                  consumes 1, case_names base step]
   336 
   337 lemma tranclp_trans_induct:
   338   assumes major: "r^++ x y"
   339     and cases: "!!x y. r x y ==> P x y"
   340       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   341   shows "P x y"
   342   -- {* Another induction rule for trancl, incorporating transitivity *}
   343   by (iprover intro: major [THEN tranclp_induct] cases)
   344 
   345 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   346 
   347 inductive_cases tranclE: "(a, b) : r^+"
   348 
   349 lemma trancl_Int_subset: "[| r \<subseteq> s; r O (r^+ \<inter> s) \<subseteq> s|] ==> r^+ \<subseteq> s"
   350   apply (rule subsetI)
   351   apply (rule_tac p="x" in PairE, clarify)
   352   apply (erule trancl_induct, auto) 
   353   done
   354 
   355 lemma trancl_unfold: "r^+ = r Un r O r^+"
   356   by (auto intro: trancl_into_trancl elim: tranclE)
   357 
   358 lemma trans_trancl[simp]: "trans(r^+)"
   359   -- {* Transitivity of @{term "r^+"} *}
   360 proof (rule transI)
   361   fix x y z
   362   assume xy: "(x, y) \<in> r^+"
   363   assume "(y, z) \<in> r^+"
   364   thus "(x, z) \<in> r^+" by induct (insert xy, iprover)+
   365 qed
   366 
   367 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   368 
   369 lemma tranclp_trans:
   370   assumes xy: "r^++ x y"
   371   and yz: "r^++ y z"
   372   shows "r^++ x z" using yz xy
   373   by induct iprover+
   374 
   375 lemma trancl_id[simp]: "trans r \<Longrightarrow> r^+ = r"
   376 apply(auto)
   377 apply(erule trancl_induct)
   378 apply assumption
   379 apply(unfold trans_def)
   380 apply(blast)
   381 done
   382 
   383 lemma rtranclp_tranclp_tranclp: assumes r: "r^** x y"
   384   shows "!!z. r^++ y z ==> r^++ x z" using r
   385   by induct (iprover intro: tranclp_trans)+
   386 
   387 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   388 
   389 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   390   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   391 
   392 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   393 
   394 lemma trancl_insert:
   395   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   396   -- {* primitive recursion for @{text trancl} over finite relations *}
   397   apply (rule equalityI)
   398    apply (rule subsetI)
   399    apply (simp only: split_tupled_all)
   400    apply (erule trancl_induct, blast)
   401    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   402   apply (rule subsetI)
   403   apply (blast intro: trancl_mono rtrancl_mono
   404     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   405   done
   406 
   407 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   408   apply (drule conversepD)
   409   apply (erule tranclp_induct)
   410   apply (iprover intro: conversepI tranclp_trans)+
   411   done
   412 
   413 lemmas trancl_converseI = tranclp_converseI [to_set]
   414 
   415 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   416   apply (rule conversepI)
   417   apply (erule tranclp_induct)
   418   apply (iprover dest: conversepD intro: tranclp_trans)+
   419   done
   420 
   421 lemmas trancl_converseD = tranclp_converseD [to_set]
   422 
   423 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   424   by (fastsimp simp add: expand_fun_eq
   425     intro!: tranclp_converseI dest!: tranclp_converseD)
   426 
   427 lemmas trancl_converse = tranclp_converse [to_set]
   428 
   429 lemma sym_trancl: "sym r ==> sym (r^+)"
   430   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   431 
   432 lemma converse_tranclp_induct:
   433   assumes major: "r^++ a b"
   434     and cases: "!!y. r y b ==> P(y)"
   435       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   436   shows "P a"
   437   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   438    apply (rule cases)
   439    apply (erule conversepD)
   440   apply (blast intro: prems dest!: tranclp_converseD conversepD)
   441   done
   442 
   443 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   444 
   445 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   446   apply (erule converse_tranclp_induct, auto)
   447   apply (blast intro: rtranclp_trans)
   448   done
   449 
   450 lemmas tranclD = tranclpD [to_set]
   451 
   452 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   453   by (blast elim: tranclE dest: trancl_into_rtrancl)
   454 
   455 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   456   by (blast dest: r_into_trancl)
   457 
   458 lemma trancl_subset_Sigma_aux:
   459     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   460   by (induct rule: rtrancl_induct) auto
   461 
   462 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   463   apply (rule subsetI)
   464   apply (simp only: split_tupled_all)
   465   apply (erule tranclE)
   466   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   467   done
   468 
   469 lemma reflcl_tranclp [simp]: "(r^++)^== = r^**"
   470   apply (safe intro!: order_antisym)
   471    apply (erule tranclp_into_rtranclp)
   472   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   473   done
   474 
   475 lemmas reflcl_trancl [simp] = reflcl_tranclp [to_set]
   476 
   477 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   478   apply safe
   479    apply (drule trancl_into_rtrancl, simp)
   480   apply (erule rtranclE, safe)
   481    apply (rule r_into_trancl, simp)
   482   apply (rule rtrancl_into_trancl1)
   483    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   484   done
   485 
   486 lemma trancl_empty [simp]: "{}^+ = {}"
   487   by (auto elim: trancl_induct)
   488 
   489 lemma rtrancl_empty [simp]: "{}^* = Id"
   490   by (rule subst [OF reflcl_trancl]) simp
   491 
   492 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   493   by (force simp add: reflcl_tranclp [symmetric] simp del: reflcl_tranclp)
   494 
   495 lemmas rtranclD = rtranclpD [to_set]
   496 
   497 lemma rtrancl_eq_or_trancl:
   498   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   499   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   500 
   501 text {* @{text Domain} and @{text Range} *}
   502 
   503 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   504   by blast
   505 
   506 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   507   by blast
   508 
   509 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   510   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   511 
   512 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   513   by (blast intro: subsetD [OF rtrancl_Un_subset])
   514 
   515 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   516   by (unfold Domain_def) (blast dest: tranclD)
   517 
   518 lemma trancl_range [simp]: "Range (r^+) = Range r"
   519   by (simp add: Range_def trancl_converse [symmetric])
   520 
   521 lemma Not_Domain_rtrancl:
   522     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   523   apply auto
   524   by (erule rev_mp, erule rtrancl_induct, auto)
   525 
   526 
   527 text {* More about converse @{text rtrancl} and @{text trancl}, should
   528   be merged with main body. *}
   529 
   530 lemma single_valued_confluent:
   531   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   532   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   533 apply(erule rtrancl_induct)
   534  apply simp
   535 apply(erule disjE)
   536  apply(blast elim:converse_rtranclE dest:single_valuedD)
   537 apply(blast intro:rtrancl_trans)
   538 done
   539 
   540 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   541   by (fast intro: trancl_trans)
   542 
   543 lemma trancl_into_trancl [rule_format]:
   544     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   545   apply (erule trancl_induct)
   546    apply (fast intro: r_r_into_trancl)
   547   apply (fast intro: r_r_into_trancl trancl_trans)
   548   done
   549 
   550 lemma tranclp_rtranclp_tranclp:
   551     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   552   apply (drule tranclpD)
   553   apply (erule exE, erule conjE)
   554   apply (drule rtranclp_trans, assumption)
   555   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   556   done
   557 
   558 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   559 
   560 lemmas transitive_closure_trans [trans] =
   561   r_r_into_trancl trancl_trans rtrancl_trans
   562   trancl.trancl_into_trancl trancl_into_trancl2
   563   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   564   rtrancl_trancl_trancl trancl_rtrancl_trancl
   565 
   566 lemmas transitive_closurep_trans' [trans] =
   567   tranclp_trans rtranclp_trans
   568   tranclp.trancl_into_trancl tranclp_into_tranclp2
   569   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   570   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   571 
   572 declare trancl_into_rtrancl [elim]
   573 
   574 declare rtranclE [cases set: rtrancl]
   575 declare tranclE [cases set: trancl]
   576 
   577 
   578 
   579 
   580 
   581 subsection {* Setup of transitivity reasoner *}
   582 
   583 ML_setup {*
   584 
   585 structure Trancl_Tac = Trancl_Tac_Fun (
   586   struct
   587     val r_into_trancl = thm "trancl.r_into_trancl";
   588     val trancl_trans  = thm "trancl_trans";
   589     val rtrancl_refl = thm "rtrancl.rtrancl_refl";
   590     val r_into_rtrancl = thm "r_into_rtrancl";
   591     val trancl_into_rtrancl = thm "trancl_into_rtrancl";
   592     val rtrancl_trancl_trancl = thm "rtrancl_trancl_trancl";
   593     val trancl_rtrancl_trancl = thm "trancl_rtrancl_trancl";
   594     val rtrancl_trans = thm "rtrancl_trans";
   595 
   596   fun decomp (Trueprop $ t) =
   597     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) =
   598         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   599               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   600               | decr r = (r,"r");
   601             val (rel,r) = decr rel;
   602         in SOME (a,b,rel,r) end
   603       | dec _ =  NONE
   604     in dec t end;
   605 
   606   end);
   607 
   608 structure Tranclp_Tac = Trancl_Tac_Fun (
   609   struct
   610     val r_into_trancl = thm "tranclp.r_into_trancl";
   611     val trancl_trans  = thm "tranclp_trans";
   612     val rtrancl_refl = thm "rtranclp.rtrancl_refl";
   613     val r_into_rtrancl = thm "r_into_rtranclp";
   614     val trancl_into_rtrancl = thm "tranclp_into_rtranclp";
   615     val rtrancl_trancl_trancl = thm "rtranclp_tranclp_tranclp";
   616     val trancl_rtrancl_trancl = thm "tranclp_rtranclp_tranclp";
   617     val rtrancl_trans = thm "rtranclp_trans";
   618 
   619   fun decomp (Trueprop $ t) =
   620     let fun dec (rel $ a $ b) =
   621         let fun decr (Const ("Transitive_Closure.rtranclp", _ ) $ r) = (r,"r*")
   622               | decr (Const ("Transitive_Closure.tranclp", _ ) $ r)  = (r,"r+")
   623               | decr r = (r,"r");
   624             val (rel,r) = decr rel;
   625         in SOME (a, b, Envir.beta_eta_contract rel, r) end
   626       | dec _ =  NONE
   627     in dec t end;
   628 
   629   end);
   630 
   631 change_simpset (fn ss => ss
   632   addSolver (mk_solver "Trancl" (fn _ => Trancl_Tac.trancl_tac))
   633   addSolver (mk_solver "Rtrancl" (fn _ => Trancl_Tac.rtrancl_tac))
   634   addSolver (mk_solver "Tranclp" (fn _ => Tranclp_Tac.trancl_tac))
   635   addSolver (mk_solver "Rtranclp" (fn _ => Tranclp_Tac.rtrancl_tac)));
   636 
   637 *}
   638 
   639 (* Optional methods *)
   640 
   641 method_setup trancl =
   642   {* Method.no_args (Method.SIMPLE_METHOD' Trancl_Tac.trancl_tac) *}
   643   {* simple transitivity reasoner *}
   644 method_setup rtrancl =
   645   {* Method.no_args (Method.SIMPLE_METHOD' Trancl_Tac.rtrancl_tac) *}
   646   {* simple transitivity reasoner *}
   647 method_setup tranclp =
   648   {* Method.no_args (Method.SIMPLE_METHOD' Tranclp_Tac.trancl_tac) *}
   649   {* simple transitivity reasoner (predicate version) *}
   650 method_setup rtranclp =
   651   {* Method.no_args (Method.SIMPLE_METHOD' Tranclp_Tac.rtrancl_tac) *}
   652   {* simple transitivity reasoner (predicate version) *}
   653 
   654 end