src/Pure/consts.ML
author wenzelm
Thu Oct 04 20:29:42 2007 +0200 (2007-10-04)
changeset 24850 0cfd722ab579
parent 24772 2b838dfeca1e
child 24909 afae05eb1f1c
permissions -rw-r--r--
Name.uu, Name.aT;
     1 (*  Title:      Pure/consts.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Polymorphic constants: declarations, abbreviations, additional type
     6 constraints.
     7 *)
     8 
     9 signature CONSTS =
    10 sig
    11   type T
    12   val eq_consts: T * T -> bool
    13   val abbrevs_of: T -> string list -> (term * term) list
    14   val dest: T ->
    15    {constants: (typ * (term * term) option) NameSpace.table,
    16     constraints: typ NameSpace.table}
    17   val the_abbreviation: T -> string -> typ * (term * term)          (*exception TYPE*)
    18   val the_declaration: T -> string -> typ                           (*exception TYPE*)
    19   val is_monomorphic: T -> string -> bool                           (*exception TYPE*)
    20   val the_constraint: T -> string -> typ                            (*exception TYPE*)
    21   val the_tags: T -> string -> Markup.property list                 (*exception TYPE*)
    22   val space_of: T -> NameSpace.T
    23   val intern: T -> xstring -> string
    24   val extern: T -> string -> xstring
    25   val extern_early: T -> string -> xstring
    26   val syntax: T -> string * mixfix -> string * typ * mixfix
    27   val syntax_name: T -> string -> string
    28   val read_const: T -> string -> term
    29   val certify: Pretty.pp -> Type.tsig -> bool -> T -> term -> term  (*exception TYPE*)
    30   val typargs: T -> string * typ -> typ list
    31   val instance: T -> string * typ list -> typ
    32   val declare: bool -> NameSpace.naming -> Markup.property list -> (bstring * typ) -> T -> T
    33   val constrain: string * typ option -> T -> T
    34   val abbreviate: Pretty.pp -> Type.tsig -> NameSpace.naming -> string -> Markup.property list ->
    35     bstring * term -> T -> (term * term) * T
    36   val hide: bool -> string -> T -> T
    37   val empty: T
    38   val merge: T * T -> T
    39 end;
    40 
    41 structure Consts: CONSTS =
    42 struct
    43 
    44 
    45 (** consts type **)
    46 
    47 (* datatype T *)
    48 
    49 datatype kind =
    50   LogicalConst of int list list |      (*typargs positions*)
    51   Abbreviation of term * term * bool   (*rhs, normal rhs, force_expand*);
    52 
    53 type decl = {T: typ, kind: kind, tags: Markup.property list, authentic: bool};
    54 
    55 datatype T = Consts of
    56  {decls: (decl * serial) NameSpace.table,
    57   constraints: typ Symtab.table,
    58   rev_abbrevs: (term * term) list Symtab.table} * stamp;
    59 
    60 fun eq_consts (Consts (_, s1), Consts (_, s2)) = s1 = s2;
    61 
    62 fun make_consts (decls, constraints, rev_abbrevs) =
    63   Consts ({decls = decls, constraints = constraints, rev_abbrevs = rev_abbrevs}, stamp ());
    64 
    65 fun map_consts f (Consts ({decls, constraints, rev_abbrevs}, _)) =
    66   make_consts (f (decls, constraints, rev_abbrevs));
    67 
    68 fun abbrevs_of (Consts ({rev_abbrevs, ...}, _)) modes =
    69   maps (Symtab.lookup_list rev_abbrevs) modes;
    70 
    71 
    72 (* dest consts *)
    73 
    74 fun dest_kind (LogicalConst _) = NONE
    75   | dest_kind (Abbreviation (t, t', _)) = SOME (t, t');
    76 
    77 fun dest (Consts ({decls = (space, decls), constraints, ...}, _)) =
    78  {constants = (space,
    79     Symtab.fold (fn (c, ({T, kind, ...}, _)) =>
    80       Symtab.update (c, (T, dest_kind kind))) decls Symtab.empty),
    81   constraints = (space, constraints)};
    82 
    83 
    84 (* lookup consts *)
    85 
    86 fun the_const (Consts ({decls = (_, tab), ...}, _)) c =
    87   (case Symtab.lookup tab c of
    88     SOME (decl, _) => decl
    89   | NONE => raise TYPE ("Undeclared constant: " ^ quote c, [], []));
    90 
    91 fun logical_const consts c =
    92   (case the_const consts c of
    93     {T, kind = LogicalConst ps, ...} => (T, ps)
    94   | _ => raise TYPE ("Not a logical constant: " ^ quote c, [], []));
    95 
    96 fun the_abbreviation consts c =
    97   (case the_const consts c of
    98     {T, kind = Abbreviation (t, t', _), ...} => (T, (t, t'))
    99   | _ => raise TYPE ("Not an abbreviated constant: " ^ quote c, [], []));
   100 
   101 val the_declaration = #1 oo logical_const;
   102 val type_arguments = #2 oo logical_const;
   103 val is_monomorphic = null oo type_arguments;
   104 
   105 fun the_constraint (consts as Consts ({constraints, ...}, _)) c =
   106   (case Symtab.lookup constraints c of
   107     SOME T => T
   108   | NONE => #T (the_const consts c));
   109 
   110 val the_tags = #tags oo the_const;
   111 
   112 
   113 (* name space and syntax *)
   114 
   115 fun space_of (Consts ({decls = (space, _), ...}, _)) = space;
   116 
   117 val intern = NameSpace.intern o space_of;
   118 val extern = NameSpace.extern o space_of;
   119 
   120 fun extern_early consts c =
   121   (case try (the_const consts) c of
   122     SOME {authentic = true, ...} => Syntax.constN ^ c
   123   | _ => extern consts c);
   124 
   125 fun syntax consts (c, mx) =
   126   let
   127     val {T, authentic, ...} = the_const consts c handle TYPE (msg, _, _) => error msg;
   128     val c' = if authentic then Syntax.constN ^ c else NameSpace.base c;
   129   in (c', T, mx) end;
   130 
   131 fun syntax_name consts c = #1 (syntax consts (c, NoSyn));
   132 
   133 
   134 (* read_const *)
   135 
   136 fun read_const consts raw_c =
   137   let
   138     val c = intern consts raw_c;
   139     val {T, ...} = the_const consts c handle TYPE (msg, _, _) => error msg;
   140   in Const (c, T) end;
   141 
   142 
   143 (* certify *)
   144 
   145 fun certify pp tsig do_expand consts =
   146   let
   147     fun err msg (c, T) =
   148       raise TYPE (msg ^ " " ^ quote c ^ " :: " ^ Pretty.string_of_typ pp T, [], []);
   149     val certT = Type.cert_typ tsig;
   150     fun cert tm =
   151       let
   152         val (head, args) = Term.strip_comb tm;
   153         val args' = map cert args;
   154         fun comb head' = Term.list_comb (head', args');
   155       in
   156         (case head of
   157           Abs (x, T, t) => comb (Abs (x, certT T, cert t))
   158         | Const (c, T) =>
   159             let
   160               val T' = certT T;
   161               val {T = U, kind, ...} = the_const consts c;
   162             in
   163               if not (Type.raw_instance (T', U)) then
   164                 err "Illegal type for constant" (c, T)
   165               else
   166                 (case kind of
   167                   Abbreviation (_, u, force_expand) =>
   168                     if do_expand orelse force_expand then
   169                       Term.betapplys (Envir.expand_atom T' (U, u) handle TYPE _ =>
   170                         err "Illegal type for abbreviation" (c, T), args')
   171                     else comb head
   172                 | _ => comb head)
   173             end
   174         | _ => comb head)
   175       end;
   176   in cert end;
   177 
   178 
   179 (* typargs -- view actual const type as instance of declaration *)
   180 
   181 fun subscript (Type (_, Ts)) (i :: is) = subscript (nth Ts i) is
   182   | subscript T [] = T
   183   | subscript T _ = raise Subscript;
   184 
   185 fun typargs consts (c, T) = map (subscript T) (type_arguments consts c);
   186 
   187 fun instance consts (c, Ts) =
   188   let
   189     val declT = the_declaration consts c;
   190     val vars = map Term.dest_TVar (typargs consts (c, declT));
   191     val inst = vars ~~ Ts handle UnequalLengths =>
   192       raise TYPE ("Consts.instance", Ts, [Const (c, dummyT)]);
   193   in declT |> TermSubst.instantiateT inst end;
   194 
   195 
   196 
   197 (** build consts **)
   198 
   199 fun err_dup_const c =
   200   error ("Duplicate declaration of constant " ^ quote c);
   201 
   202 fun err_inconsistent_constraints c =
   203   error ("Inconsistent type constraints for constant " ^ quote c);
   204 
   205 fun extend_decls naming decl tab = NameSpace.extend_table naming [decl] tab
   206   handle Symtab.DUP c => err_dup_const c;
   207 
   208 
   209 (* name space *)
   210 
   211 fun hide fully c = map_consts (fn (decls, constraints, rev_abbrevs) =>
   212   (apfst (NameSpace.hide fully c) decls, constraints, rev_abbrevs));
   213 
   214 
   215 (* declarations *)
   216 
   217 fun declare authentic naming tags (c, declT) = map_consts (fn (decls, constraints, rev_abbrevs) =>
   218   let
   219     fun args_of (Type (_, Ts)) pos = args_of_list Ts 0 pos
   220       | args_of (TVar v) pos = insert (eq_fst op =) (v, rev pos)
   221       | args_of (TFree _) _ = I
   222     and args_of_list (T :: Ts) i is = args_of T (i :: is) #> args_of_list Ts (i + 1) is
   223       | args_of_list [] _ _ = I;
   224     val decl =
   225       {T = declT, kind = LogicalConst (map #2 (rev (args_of declT [] []))),
   226         tags = tags, authentic = authentic};
   227     val decls' = decls |> extend_decls naming (c, (decl, serial ()));
   228   in (decls', constraints, rev_abbrevs) end);
   229 
   230 
   231 (* constraints *)
   232 
   233 fun constrain (c, C) consts =
   234   consts |> map_consts (fn (decls, constraints, rev_abbrevs) =>
   235     (the_const consts c handle TYPE (msg, _, _) => error msg;
   236       (decls,
   237         constraints |> (case C of SOME T => Symtab.update (c, T) | NONE => Symtab.delete_safe c),
   238         rev_abbrevs)));
   239 
   240 
   241 (* abbreviations *)
   242 
   243 local
   244 
   245 fun strip_abss tm = ([], tm) ::
   246   (case tm of
   247     Abs (a, T, t) =>
   248       if Term.loose_bvar1 (t, 0) then
   249         strip_abss t |> map (fn (xs, b) => ((a, T) :: xs, b))
   250       else []
   251   | _ => []);
   252 
   253 fun rev_abbrev lhs rhs =
   254   let
   255     fun abbrev (xs, body) =
   256       let val vars = fold (fn (x, T) => cons (Var ((x, 0), T))) (Term.rename_wrt_term body xs) []
   257       in (Term.subst_bounds (rev vars, body), Term.list_comb (lhs, vars)) end;
   258   in map abbrev (strip_abss (Envir.beta_eta_contract rhs)) end;
   259 
   260 in
   261 
   262 fun abbreviate pp tsig naming mode tags (c, raw_rhs) consts =
   263   let
   264     val cert_term = certify pp tsig false consts;
   265     val expand_term = certify pp tsig true consts;
   266     val force_expand = mode = Syntax.internalM;
   267 
   268     val rhs = raw_rhs
   269       |> Term.map_types (Type.cert_typ tsig)
   270       |> cert_term;
   271     val T = Term.fastype_of rhs;
   272     val lhs = Const (NameSpace.full naming c, T);
   273     val rhs' = expand_term rhs;
   274 
   275     fun err msg = error (msg ^ " on rhs of abbreviation:\n" ^
   276       Pretty.string_of_term pp (Logic.mk_equals (lhs, rhs)));
   277     val _ = Term.exists_subterm Term.is_Var rhs andalso err "Illegal schematic variables"
   278     val _ = null (Term.hidden_polymorphism rhs T) orelse err "Extra type variables";
   279   in
   280     consts |> map_consts (fn (decls, constraints, rev_abbrevs) =>
   281       let
   282         val decl =
   283           {T = T, kind = Abbreviation (rhs, rhs', force_expand), tags = tags, authentic = true};
   284         val decls' = decls
   285           |> extend_decls naming (c, (decl, serial ()));
   286         val rev_abbrevs' = rev_abbrevs
   287           |> fold (curry Symtab.update_list mode) (rev_abbrev lhs rhs);
   288       in (decls', constraints, rev_abbrevs') end)
   289     |> pair (lhs, rhs)
   290   end;
   291 
   292 end;
   293 
   294 
   295 (* empty and merge *)
   296 
   297 val empty = make_consts (NameSpace.empty_table, Symtab.empty, Symtab.empty);
   298 
   299 fun merge
   300    (Consts ({decls = decls1, constraints = constraints1, rev_abbrevs = rev_abbrevs1}, _),
   301     Consts ({decls = decls2, constraints = constraints2, rev_abbrevs = rev_abbrevs2}, _)) =
   302   let
   303     val decls' = NameSpace.merge_tables (eq_snd (op =)) (decls1, decls2)
   304       handle Symtab.DUP c => err_dup_const c;
   305     val constraints' = Symtab.merge (op =) (constraints1, constraints2)
   306       handle Symtab.DUP c => err_inconsistent_constraints c;
   307     val rev_abbrevs' = (rev_abbrevs1, rev_abbrevs2) |> Symtab.join
   308       (K (Library.merge (fn ((t, u), (t', u')) => t aconv t' andalso u aconv u')));
   309   in make_consts (decls', constraints', rev_abbrevs') end;
   310 
   311 end;