src/Pure/drule.ML
author wenzelm
Thu Oct 04 20:29:42 2007 +0200 (2007-10-04)
changeset 24850 0cfd722ab579
parent 24848 5dbbd33c3236
child 24947 b7e990e1706a
permissions -rw-r--r--
Name.uu, Name.aT;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val strip_imp_prems: cterm -> cterm list
    16   val strip_imp_concl: cterm -> cterm
    17   val cprems_of: thm -> cterm list
    18   val cterm_fun: (term -> term) -> (cterm -> cterm)
    19   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    20   val read_insts: theory -> (indexname -> typ option) * (indexname -> sort option) ->
    21     (indexname -> typ option) * (indexname -> sort option) -> string list ->
    22     (indexname * string) list -> (ctyp * ctyp) list * (cterm * cterm) list
    23   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    24   val forall_intr_list: cterm list -> thm -> thm
    25   val forall_intr_frees: thm -> thm
    26   val forall_intr_vars: thm -> thm
    27   val forall_elim_list: cterm list -> thm -> thm
    28   val forall_elim_var: int -> thm -> thm
    29   val forall_elim_vars: int -> thm -> thm
    30   val gen_all: thm -> thm
    31   val lift_all: cterm -> thm -> thm
    32   val freeze_thaw: thm -> thm * (thm -> thm)
    33   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    34   val implies_elim_list: thm -> thm list -> thm
    35   val implies_intr_list: cterm list -> thm -> thm
    36   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    37   val zero_var_indexes_list: thm list -> thm list
    38   val zero_var_indexes: thm -> thm
    39   val implies_intr_hyps: thm -> thm
    40   val standard: thm -> thm
    41   val standard': thm -> thm
    42   val rotate_prems: int -> thm -> thm
    43   val rearrange_prems: int list -> thm -> thm
    44   val RSN: thm * (int * thm) -> thm
    45   val RS: thm * thm -> thm
    46   val RLN: thm list * (int * thm list) -> thm list
    47   val RL: thm list * thm list -> thm list
    48   val MRS: thm list * thm -> thm
    49   val MRL: thm list list * thm list -> thm list
    50   val OF: thm * thm list -> thm
    51   val compose: thm * int * thm -> thm list
    52   val COMP: thm * thm -> thm
    53   val INCR_COMP: thm * thm -> thm
    54   val COMP_INCR: thm * thm -> thm
    55   val read_instantiate_sg: theory -> (string*string)list -> thm -> thm
    56   val read_instantiate: (string*string)list -> thm -> thm
    57   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    58   val size_of_thm: thm -> int
    59   val reflexive_thm: thm
    60   val symmetric_thm: thm
    61   val transitive_thm: thm
    62   val symmetric_fun: thm -> thm
    63   val extensional: thm -> thm
    64   val equals_cong: thm
    65   val imp_cong: thm
    66   val swap_prems_eq: thm
    67   val asm_rl: thm
    68   val cut_rl: thm
    69   val revcut_rl: thm
    70   val thin_rl: thm
    71   val triv_forall_equality: thm
    72   val distinct_prems_rl: thm
    73   val swap_prems_rl: thm
    74   val equal_intr_rule: thm
    75   val equal_elim_rule1: thm
    76   val equal_elim_rule2: thm
    77   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    78 end;
    79 
    80 signature DRULE =
    81 sig
    82   include BASIC_DRULE
    83   val generalize: string list * string list -> thm -> thm
    84   val list_comb: cterm * cterm list -> cterm
    85   val strip_comb: cterm -> cterm * cterm list
    86   val strip_type: ctyp -> ctyp list * ctyp
    87   val beta_conv: cterm -> cterm -> cterm
    88   val add_used: thm -> string list -> string list
    89   val flexflex_unique: thm -> thm
    90   val close_derivation: thm -> thm
    91   val store_thm: bstring -> thm -> thm
    92   val store_standard_thm: bstring -> thm -> thm
    93   val store_thm_open: bstring -> thm -> thm
    94   val store_standard_thm_open: bstring -> thm -> thm
    95   val compose_single: thm * int * thm -> thm
    96   val imp_cong_rule: thm -> thm -> thm
    97   val arg_cong_rule: cterm -> thm -> thm
    98   val binop_cong_rule: cterm -> thm -> thm -> thm
    99   val fun_cong_rule: thm -> cterm -> thm
   100   val beta_eta_conversion: cterm -> thm
   101   val eta_long_conversion: cterm -> thm
   102   val eta_contraction_rule: thm -> thm
   103   val norm_hhf_eq: thm
   104   val is_norm_hhf: term -> bool
   105   val norm_hhf: theory -> term -> term
   106   val norm_hhf_cterm: cterm -> cterm
   107   val unvarify: thm -> thm
   108   val protect: cterm -> cterm
   109   val protectI: thm
   110   val protectD: thm
   111   val protect_cong: thm
   112   val implies_intr_protected: cterm list -> thm -> thm
   113   val termI: thm
   114   val mk_term: cterm -> thm
   115   val dest_term: thm -> cterm
   116   val cterm_rule: (thm -> thm) -> cterm -> cterm
   117   val term_rule: theory -> (thm -> thm) -> term -> term
   118   val dummy_thm: thm
   119   val sort_triv: theory -> typ * sort -> thm list
   120   val unconstrainTs: thm -> thm
   121   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   122   val rename_bvars: (string * string) list -> thm -> thm
   123   val rename_bvars': string option list -> thm -> thm
   124   val incr_type_indexes: int -> thm -> thm
   125   val incr_indexes: thm -> thm -> thm
   126   val incr_indexes2: thm -> thm -> thm -> thm
   127   val remdups_rl: thm
   128   val multi_resolve: thm list -> thm -> thm Seq.seq
   129   val multi_resolves: thm list -> thm list -> thm Seq.seq
   130   val abs_def: thm -> thm
   131   val read_instantiate_sg': theory -> (indexname * string) list -> thm -> thm
   132   val read_instantiate': (indexname * string) list -> thm -> thm
   133 end;
   134 
   135 structure Drule: DRULE =
   136 struct
   137 
   138 
   139 (** some cterm->cterm operations: faster than calling cterm_of! **)
   140 
   141 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   142 fun strip_imp_prems ct =
   143   let val (cA, cB) = Thm.dest_implies ct
   144   in cA :: strip_imp_prems cB end
   145   handle TERM _ => [];
   146 
   147 (* A1==>...An==>B  goes to B, where B is not an implication *)
   148 fun strip_imp_concl ct =
   149   (case Thm.term_of ct of
   150     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   151   | _ => ct);
   152 
   153 (*The premises of a theorem, as a cterm list*)
   154 val cprems_of = strip_imp_prems o cprop_of;
   155 
   156 fun cterm_fun f ct =
   157   let val {t, thy, ...} = Thm.rep_cterm ct
   158   in Thm.cterm_of thy (f t) end;
   159 
   160 fun ctyp_fun f cT =
   161   let val {T, thy, ...} = Thm.rep_ctyp cT
   162   in Thm.ctyp_of thy (f T) end;
   163 
   164 val cert = cterm_of ProtoPure.thy;
   165 
   166 val implies = cert Term.implies;
   167 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   168 
   169 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   170 fun list_implies([], B) = B
   171   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   172 
   173 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   174 fun list_comb (f, []) = f
   175   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   176 
   177 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   178 fun strip_comb ct =
   179   let
   180     fun stripc (p as (ct, cts)) =
   181       let val (ct1, ct2) = Thm.dest_comb ct
   182       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   183   in stripc (ct, []) end;
   184 
   185 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   186 fun strip_type cT = (case Thm.typ_of cT of
   187     Type ("fun", _) =>
   188       let
   189         val [cT1, cT2] = Thm.dest_ctyp cT;
   190         val (cTs, cT') = strip_type cT2
   191       in (cT1 :: cTs, cT') end
   192   | _ => ([], cT));
   193 
   194 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   195   of the meta-equality returned by the beta_conversion rule.*)
   196 fun beta_conv x y =
   197   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   198 
   199 
   200 
   201 (** reading of instantiations **)
   202 
   203 fun absent ixn =
   204   error("No such variable in term: " ^ Term.string_of_vname ixn);
   205 
   206 fun inst_failure ixn =
   207   error("Instantiation of " ^ Term.string_of_vname ixn ^ " fails");
   208 
   209 fun read_insts thy (rtypes,rsorts) (types,sorts) used insts =
   210 let
   211     fun is_tv ((a, _), _) =
   212       (case Symbol.explode a of "'" :: _ => true | _ => false);
   213     val (tvs, vs) = List.partition is_tv insts;
   214     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   215     fun readT (ixn, st) =
   216         let val S = sort_of ixn;
   217             val T = Sign.read_def_typ (thy,sorts) st;
   218         in if Sign.typ_instance thy (T, TVar(ixn,S)) then (ixn,T)
   219            else inst_failure ixn
   220         end
   221     val tye = map readT tvs;
   222     fun mkty(ixn,st) = (case rtypes ixn of
   223                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   224                         | NONE => absent ixn);
   225     val ixnsTs = map mkty vs;
   226     val ixns = map fst ixnsTs
   227     and sTs  = map snd ixnsTs
   228     val (cts,tye2) = Thm.read_def_cterms(thy,types,sorts) used false sTs;
   229     fun mkcVar(ixn,T) =
   230         let val U = typ_subst_TVars tye2 T
   231         in cterm_of thy (Var(ixn,U)) end
   232     val ixnTs = ListPair.zip(ixns, map snd sTs)
   233 in (map (fn (ixn, T) => (ctyp_of thy (TVar (ixn, sort_of ixn)),
   234       ctyp_of thy T)) (tye2 @ tye),
   235     ListPair.zip(map mkcVar ixnTs,cts))
   236 end;
   237 
   238 
   239 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   240      Used for establishing default types (of variables) and sorts (of
   241      type variables) when reading another term.
   242      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   243 ***)
   244 
   245 fun types_sorts thm =
   246   let
   247     val vars = Thm.fold_terms Term.add_vars thm [];
   248     val frees = Thm.fold_terms Term.add_frees thm [];
   249     val tvars = Thm.fold_terms Term.add_tvars thm [];
   250     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   251     fun types (a, i) =
   252       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   253     fun sorts (a, i) =
   254       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   255   in (types, sorts) end;
   256 
   257 val add_used =
   258   (Thm.fold_terms o fold_types o fold_atyps)
   259     (fn TFree (a, _) => insert (op =) a
   260       | TVar ((a, _), _) => insert (op =) a
   261       | _ => I);
   262 
   263 
   264 
   265 (** Standardization of rules **)
   266 
   267 (* type classes and sorts *)
   268 
   269 fun sort_triv thy (T, S) =
   270   let
   271     val certT = Thm.ctyp_of thy;
   272     val cT = certT T;
   273     fun class_triv c =
   274       Thm.class_triv thy c
   275       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   276   in map class_triv S end;
   277 
   278 fun unconstrainTs th =
   279   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   280     (Thm.fold_terms Term.add_tvars th []) th;
   281 
   282 (*Generalization over a list of variables*)
   283 val forall_intr_list = fold_rev forall_intr;
   284 
   285 (*Generalization over all suitable Free variables*)
   286 fun forall_intr_frees th =
   287     let
   288       val {prop, hyps, tpairs, thy,...} = rep_thm th;
   289       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   290       val frees = Term.fold_aterms (fn Free v =>
   291         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   292     in fold (forall_intr o cterm_of thy o Free) frees th end;
   293 
   294 (*Generalization over Vars -- canonical order*)
   295 fun forall_intr_vars th =
   296   fold forall_intr
   297     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   298 
   299 val forall_elim_var = PureThy.forall_elim_var;
   300 val forall_elim_vars = PureThy.forall_elim_vars;
   301 
   302 fun outer_params t =
   303   let val vs = Term.strip_all_vars t
   304   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   305 
   306 (*generalize outermost parameters*)
   307 fun gen_all th =
   308   let
   309     val {thy, prop, maxidx, ...} = Thm.rep_thm th;
   310     val cert = Thm.cterm_of thy;
   311     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   312   in fold elim (outer_params prop) th end;
   313 
   314 (*lift vars wrt. outermost goal parameters
   315   -- reverses the effect of gen_all modulo higher-order unification*)
   316 fun lift_all goal th =
   317   let
   318     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   319     val cert = Thm.cterm_of thy;
   320     val maxidx = Thm.maxidx_of th;
   321     val ps = outer_params (Thm.term_of goal)
   322       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   323     val Ts = map Term.fastype_of ps;
   324     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   325       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   326   in
   327     th |> Thm.instantiate ([], inst)
   328     |> fold_rev (Thm.forall_intr o cert) ps
   329   end;
   330 
   331 (*direct generalization*)
   332 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   333 
   334 (*specialization over a list of cterms*)
   335 val forall_elim_list = fold forall_elim;
   336 
   337 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   338 val implies_intr_list = fold_rev implies_intr;
   339 
   340 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   341 fun implies_elim_list impth ths = Library.foldl (uncurry implies_elim) (impth,ths);
   342 
   343 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   344 fun zero_var_indexes_list [] = []
   345   | zero_var_indexes_list ths =
   346       let
   347         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   348         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   349         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   350         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   351         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   352       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   353 
   354 val zero_var_indexes = singleton zero_var_indexes_list;
   355 
   356 
   357 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   358     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   359 
   360 (*Discharge all hypotheses.*)
   361 fun implies_intr_hyps th =
   362   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   363 
   364 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   365   This step can lose information.*)
   366 fun flexflex_unique th =
   367   if null (tpairs_of th) then th else
   368     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   369       [th] => th
   370     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   371     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   372 
   373 fun close_derivation thm =
   374   if Thm.get_name thm = "" then Thm.put_name "" thm
   375   else thm;
   376 
   377 
   378 (* legacy standard operations *)
   379 
   380 val standard' =
   381   implies_intr_hyps
   382   #> forall_intr_frees
   383   #> `Thm.maxidx_of
   384   #-> (fn maxidx =>
   385     forall_elim_vars (maxidx + 1)
   386     #> Thm.strip_shyps
   387     #> zero_var_indexes
   388     #> Thm.varifyT
   389     #> Thm.compress);
   390 
   391 val standard =
   392   flexflex_unique
   393   #> standard'
   394   #> close_derivation;
   395 
   396 
   397 (*Convert all Vars in a theorem to Frees.  Also return a function for
   398   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   399   Similar code in type/freeze_thaw*)
   400 
   401 fun freeze_thaw_robust th =
   402  let val fth = Thm.freezeT th
   403      val {prop, tpairs, thy, ...} = rep_thm fth
   404  in
   405    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   406        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   407      | vars =>
   408          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   409              val alist = map newName vars
   410              fun mk_inst (Var(v,T)) =
   411                  (cterm_of thy (Var(v,T)),
   412                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   413              val insts = map mk_inst vars
   414              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   415                  th' |> forall_intr_list (map #2 insts)
   416                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   417          in  (Thm.instantiate ([],insts) fth, thaw)  end
   418  end;
   419 
   420 (*Basic version of the function above. No option to rename Vars apart in thaw.
   421   The Frees created from Vars have nice names. FIXME: does not check for
   422   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   423 fun freeze_thaw th =
   424  let val fth = Thm.freezeT th
   425      val {prop, tpairs, thy, ...} = rep_thm fth
   426  in
   427    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   428        [] => (fth, fn x => x)
   429      | vars =>
   430          let fun newName (Var(ix,_), (pairs,used)) =
   431                    let val v = Name.variant used (string_of_indexname ix)
   432                    in  ((ix,v)::pairs, v::used)  end;
   433              val (alist, _) = List.foldr newName ([], Library.foldr add_term_names
   434                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   435              fun mk_inst (Var(v,T)) =
   436                  (cterm_of thy (Var(v,T)),
   437                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   438              val insts = map mk_inst vars
   439              fun thaw th' =
   440                  th' |> forall_intr_list (map #2 insts)
   441                      |> forall_elim_list (map #1 insts)
   442          in  (Thm.instantiate ([],insts) fth, thaw)  end
   443  end;
   444 
   445 (*Rotates a rule's premises to the left by k*)
   446 fun rotate_prems 0 = I
   447   | rotate_prems k = permute_prems 0 k;
   448 
   449 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   450 
   451 (* permute prems, where the i-th position in the argument list (counting from 0)
   452    gives the position within the original thm to be transferred to position i.
   453    Any remaining trailing positions are left unchanged. *)
   454 val rearrange_prems = let
   455   fun rearr new []      thm = thm
   456   |   rearr new (p::ps) thm = rearr (new+1)
   457      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   458      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   459   in rearr 0 end;
   460 
   461 (*Resolution: exactly one resolvent must be produced.*)
   462 fun tha RSN (i,thb) =
   463   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   464       ([th],_) => th
   465     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   466     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   467 
   468 (*resolution: P==>Q, Q==>R gives P==>R. *)
   469 fun tha RS thb = tha RSN (1,thb);
   470 
   471 (*For joining lists of rules*)
   472 fun thas RLN (i,thbs) =
   473   let val resolve = biresolution false (map (pair false) thas) i
   474       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   475   in maps resb thbs end;
   476 
   477 fun thas RL thbs = thas RLN (1,thbs);
   478 
   479 (*Resolve a list of rules against bottom_rl from right to left;
   480   makes proof trees*)
   481 fun rls MRS bottom_rl =
   482   let fun rs_aux i [] = bottom_rl
   483         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   484   in  rs_aux 1 rls  end;
   485 
   486 (*As above, but for rule lists*)
   487 fun rlss MRL bottom_rls =
   488   let fun rs_aux i [] = bottom_rls
   489         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   490   in  rs_aux 1 rlss  end;
   491 
   492 (*A version of MRS with more appropriate argument order*)
   493 fun bottom_rl OF rls = rls MRS bottom_rl;
   494 
   495 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   496   with no lifting or renaming!  Q may contain ==> or meta-quants
   497   ALWAYS deletes premise i *)
   498 fun compose(tha,i,thb) =
   499     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   500 
   501 fun compose_single (tha,i,thb) =
   502   case compose (tha,i,thb) of
   503     [th] => th
   504   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   505 
   506 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   507 fun tha COMP thb =
   508     case compose(tha,1,thb) of
   509         [th] => th
   510       | _ =>   raise THM("COMP", 1, [tha,thb]);
   511 
   512 
   513 (** theorem equality **)
   514 
   515 (*Useful "distance" function for BEST_FIRST*)
   516 val size_of_thm = size_of_term o Thm.full_prop_of;
   517 
   518 
   519 
   520 (*** Meta-Rewriting Rules ***)
   521 
   522 val read_prop = Thm.cterm_of ProtoPure.thy o SimpleSyntax.read_prop;
   523 
   524 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   525 fun store_standard_thm name thm = store_thm name (standard thm);
   526 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   527 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   528 
   529 val reflexive_thm =
   530   let val cx = cert (Var(("x",0),TVar(("'a",0),[])))
   531   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   532 
   533 val symmetric_thm =
   534   let val xy = read_prop "x::'a == y::'a"
   535   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   536 
   537 val transitive_thm =
   538   let val xy = read_prop "x::'a == y::'a"
   539       val yz = read_prop "y::'a == z::'a"
   540       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   541   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   542 
   543 fun symmetric_fun thm = thm RS symmetric_thm;
   544 
   545 fun extensional eq =
   546   let val eq' =
   547     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   548   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   549 
   550 val equals_cong =
   551   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   552 
   553 val imp_cong =
   554   let
   555     val ABC = read_prop "A ==> B::prop == C::prop"
   556     val AB = read_prop "A ==> B"
   557     val AC = read_prop "A ==> C"
   558     val A = read_prop "A"
   559   in
   560     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   561       (implies_intr AB (implies_intr A
   562         (equal_elim (implies_elim (assume ABC) (assume A))
   563           (implies_elim (assume AB) (assume A)))))
   564       (implies_intr AC (implies_intr A
   565         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   566           (implies_elim (assume AC) (assume A)))))))
   567   end;
   568 
   569 val swap_prems_eq =
   570   let
   571     val ABC = read_prop "A ==> B ==> C"
   572     val BAC = read_prop "B ==> A ==> C"
   573     val A = read_prop "A"
   574     val B = read_prop "B"
   575   in
   576     store_standard_thm_open "swap_prems_eq" (equal_intr
   577       (implies_intr ABC (implies_intr B (implies_intr A
   578         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   579       (implies_intr BAC (implies_intr A (implies_intr B
   580         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   581   end;
   582 
   583 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   584 
   585 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   586 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   587 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   588 
   589 local
   590   val dest_eq = Thm.dest_equals o cprop_of
   591   val rhs_of = snd o dest_eq
   592 in
   593 fun beta_eta_conversion t =
   594   let val thm = beta_conversion true t
   595   in transitive thm (eta_conversion (rhs_of thm)) end
   596 end;
   597 
   598 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   599   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   600 
   601 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   602 fun eta_contraction_rule th =
   603   equal_elim (eta_conversion (cprop_of th)) th;
   604 
   605 val abs_def =
   606   let
   607     fun contract_lhs th =
   608       Thm.transitive (Thm.symmetric (beta_eta_conversion
   609         (fst (Thm.dest_equals (cprop_of th))))) th;
   610     fun abstract cx th = Thm.abstract_rule
   611         (case Thm.term_of cx of Var ((x, _), _) => x | Free (x, _) => x | _ => "x") cx th
   612       handle THM _ => raise THM ("Malformed definitional equation", 0, [th]);
   613   in
   614     contract_lhs
   615     #> `(snd o strip_comb o fst o Thm.dest_equals o cprop_of)
   616     #-> fold_rev abstract
   617     #> contract_lhs
   618   end;
   619 
   620 
   621 (*** Some useful meta-theorems ***)
   622 
   623 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   624 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   625 val _ = store_thm "_" asm_rl;
   626 
   627 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   628 val cut_rl =
   629   store_standard_thm_open "cut_rl"
   630     (Thm.trivial (read_prop "?psi ==> ?theta"));
   631 
   632 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   633      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   634 val revcut_rl =
   635   let val V = read_prop "V"
   636       and VW = read_prop "V ==> W";
   637   in
   638     store_standard_thm_open "revcut_rl"
   639       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   640   end;
   641 
   642 (*for deleting an unwanted assumption*)
   643 val thin_rl =
   644   let val V = read_prop "V"
   645       and W = read_prop "W";
   646   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   647 
   648 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   649 val triv_forall_equality =
   650   let val V  = read_prop "V"
   651       and QV = read_prop "!!x::'a. V"
   652       and x  = cert (Free ("x", Term.aT []));
   653   in
   654     store_standard_thm_open "triv_forall_equality"
   655       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   656         (implies_intr V  (forall_intr x (assume V))))
   657   end;
   658 
   659 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   660    (PROP ?Phi ==> PROP ?Psi)
   661 *)
   662 val distinct_prems_rl =
   663   let
   664     val AAB = read_prop "Phi ==> Phi ==> Psi"
   665     val A = read_prop "Phi";
   666   in
   667     store_standard_thm_open "distinct_prems_rl"
   668       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   669   end;
   670 
   671 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   672    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   673    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   674 *)
   675 val swap_prems_rl =
   676   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   677       val major = assume cmajor;
   678       val cminor1 = read_prop "PhiA";
   679       val minor1 = assume cminor1;
   680       val cminor2 = read_prop "PhiB";
   681       val minor2 = assume cminor2;
   682   in store_standard_thm_open "swap_prems_rl"
   683        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   684          (implies_elim (implies_elim major minor1) minor2))))
   685   end;
   686 
   687 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   688    ==> PROP ?phi == PROP ?psi
   689    Introduction rule for == as a meta-theorem.
   690 *)
   691 val equal_intr_rule =
   692   let val PQ = read_prop "phi ==> psi"
   693       and QP = read_prop "psi ==> phi"
   694   in
   695     store_standard_thm_open "equal_intr_rule"
   696       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   697   end;
   698 
   699 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   700 val equal_elim_rule1 =
   701   let val eq = read_prop "phi::prop == psi::prop"
   702       and P = read_prop "phi"
   703   in store_standard_thm_open "equal_elim_rule1"
   704     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   705   end;
   706 
   707 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   708 val equal_elim_rule2 =
   709   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   710 
   711 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   712 val remdups_rl =
   713   let val P = read_prop "phi" and Q = read_prop "psi";
   714   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   715 
   716 
   717 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   718   Rewrite rule for HHF normalization.*)
   719 
   720 val norm_hhf_eq =
   721   let
   722     val aT = TFree ("'a", []);
   723     val all = Term.all aT;
   724     val x = Free ("x", aT);
   725     val phi = Free ("phi", propT);
   726     val psi = Free ("psi", aT --> propT);
   727 
   728     val cx = cert x;
   729     val cphi = cert phi;
   730     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   731     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   732   in
   733     Thm.equal_intr
   734       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   735         |> Thm.forall_elim cx
   736         |> Thm.implies_intr cphi
   737         |> Thm.forall_intr cx
   738         |> Thm.implies_intr lhs)
   739       (Thm.implies_elim
   740           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   741         |> Thm.forall_intr cx
   742         |> Thm.implies_intr cphi
   743         |> Thm.implies_intr rhs)
   744     |> store_standard_thm_open "norm_hhf_eq"
   745   end;
   746 
   747 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   748 
   749 fun is_norm_hhf tm =
   750   let
   751     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   752       | is_norm (t $ u) = is_norm t andalso is_norm u
   753       | is_norm (Abs (_, _, t)) = is_norm t
   754       | is_norm _ = true;
   755   in is_norm (Envir.beta_eta_contract tm) end;
   756 
   757 fun norm_hhf thy t =
   758   if is_norm_hhf t then t
   759   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   760 
   761 fun norm_hhf_cterm ct =
   762   if is_norm_hhf (Thm.term_of ct) then ct
   763   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   764 
   765 
   766 (* var indexes *)
   767 
   768 (*Increment the indexes of only the type variables*)
   769 fun incr_type_indexes inc th =
   770   let val tvs = term_tvars (prop_of th)
   771       and thy = theory_of_thm th
   772       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   773   in Thm.instantiate (map inc_tvar tvs, []) th end;
   774 
   775 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   776 
   777 fun incr_indexes2 th1 th2 =
   778   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   779 
   780 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   781 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   782 
   783 
   784 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   785 
   786 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   787 fun instantiate instpair th =
   788   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   789 
   790 fun read_instantiate_sg' thy sinsts th =
   791     let val ts = types_sorts th;
   792         val used = add_used th [];
   793     in  instantiate (read_insts thy ts ts used sinsts) th  end;
   794 
   795 fun read_instantiate_sg thy sinsts th =
   796   read_instantiate_sg' thy (map (apfst Syntax.read_indexname) sinsts) th;
   797 
   798 (*Instantiate theorem th, reading instantiations under theory of th*)
   799 fun read_instantiate sinsts th =
   800     read_instantiate_sg (Thm.theory_of_thm th) sinsts th;
   801 
   802 fun read_instantiate' sinsts th =
   803     read_instantiate_sg' (Thm.theory_of_thm th) sinsts th;
   804 
   805 
   806 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   807   Instantiates distinct Vars by terms, inferring type instantiations. *)
   808 local
   809   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   810     let val {thy=thyt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   811         and {thy=thyu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   812         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   813         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   814         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   815           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   816     in  (thy', tye', maxi')  end;
   817 in
   818 fun cterm_instantiate [] th = th
   819   | cterm_instantiate ctpairs0 th =
   820   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   821       fun instT(ct,cu) =
   822         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   823         in (inst ct, inst cu) end
   824       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   825   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   826   handle TERM _ =>
   827            raise THM("cterm_instantiate: incompatible theories",0,[th])
   828        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   829 end;
   830 
   831 
   832 (* global schematic variables *)
   833 
   834 fun unvarify th =
   835   let
   836     val thy = Thm.theory_of_thm th;
   837     val cert = Thm.cterm_of thy;
   838     val certT = Thm.ctyp_of thy;
   839 
   840     val prop = Thm.full_prop_of th;
   841     val _ = map Logic.unvarify (prop :: Thm.hyps_of th)
   842       handle TERM (msg, _) => raise THM (msg, 0, [th]);
   843 
   844     val instT0 = rev (Term.add_tvars prop []) |> map (fn v as ((a, _), S) => (v, TFree (a, S)));
   845     val instT = map (fn (v, T) => (certT (TVar v), certT T)) instT0;
   846     val inst = rev (Term.add_vars prop []) |> map (fn ((a, i), T) =>
   847       let val T' = TermSubst.instantiateT instT0 T
   848       in (cert (Var ((a, i), T')), cert (Free ((a, T')))) end);
   849   in Thm.instantiate (instT, inst) th end;
   850 
   851 
   852 (** protected propositions and embedded terms **)
   853 
   854 local
   855   val A = cert (Free ("A", propT));
   856   val prop_def = unvarify ProtoPure.prop_def;
   857   val term_def = unvarify ProtoPure.term_def;
   858 in
   859   val protect = Thm.capply (cert Logic.protectC);
   860   val protectI = store_thm "protectI" (PureThy.kind_rule Thm.internalK (standard
   861       (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   862   val protectD = store_thm "protectD" (PureThy.kind_rule Thm.internalK (standard
   863       (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   864   val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   865 
   866   val termI = store_thm "termI" (PureThy.kind_rule Thm.internalK (standard
   867       (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   868 end;
   869 
   870 fun implies_intr_protected asms th =
   871   let val asms' = map protect asms in
   872     implies_elim_list
   873       (implies_intr_list asms th)
   874       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   875     |> implies_intr_list asms'
   876   end;
   877 
   878 fun mk_term ct =
   879   let
   880     val {thy, T, ...} = Thm.rep_cterm ct;
   881     val cert = Thm.cterm_of thy;
   882     val certT = Thm.ctyp_of thy;
   883     val a = certT (TVar (("'a", 0), []));
   884     val x = cert (Var (("x", 0), T));
   885   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   886 
   887 fun dest_term th =
   888   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   889     if can Logic.dest_term (Thm.term_of cprop) then
   890       Thm.dest_arg cprop
   891     else raise THM ("dest_term", 0, [th])
   892   end;
   893 
   894 fun cterm_rule f = dest_term o f o mk_term;
   895 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   896 
   897 val dummy_thm = mk_term (Thm.cterm_of ProtoPure.thy (Term.dummy_pattern propT));
   898 
   899 
   900 
   901 (** variations on instantiate **)
   902 
   903 (* instantiate by left-to-right occurrence of variables *)
   904 
   905 fun instantiate' cTs cts thm =
   906   let
   907     fun err msg =
   908       raise TYPE ("instantiate': " ^ msg,
   909         map_filter (Option.map Thm.typ_of) cTs,
   910         map_filter (Option.map Thm.term_of) cts);
   911 
   912     fun inst_of (v, ct) =
   913       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   914         handle TYPE (msg, _, _) => err msg;
   915 
   916     fun tyinst_of (v, cT) =
   917       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   918         handle TYPE (msg, _, _) => err msg;
   919 
   920     fun zip_vars xs ys =
   921       zip_options xs ys handle Library.UnequalLengths =>
   922         err "more instantiations than variables in thm";
   923 
   924     (*instantiate types first!*)
   925     val thm' =
   926       if forall is_none cTs then thm
   927       else Thm.instantiate
   928         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   929     val thm'' =
   930       if forall is_none cts then thm'
   931       else Thm.instantiate
   932         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   933     in thm'' end;
   934 
   935 
   936 
   937 (** renaming of bound variables **)
   938 
   939 (* replace bound variables x_i in thm by y_i *)
   940 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   941 
   942 fun rename_bvars [] thm = thm
   943   | rename_bvars vs thm =
   944     let
   945       val {thy, prop, ...} = rep_thm thm;
   946       fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   947         | ren (t $ u) = ren t $ ren u
   948         | ren t = t;
   949     in equal_elim (reflexive (cterm_of thy (ren prop))) thm end;
   950 
   951 
   952 (* renaming in left-to-right order *)
   953 
   954 fun rename_bvars' xs thm =
   955   let
   956     val {thy, prop, ...} = rep_thm thm;
   957     fun rename [] t = ([], t)
   958       | rename (x' :: xs) (Abs (x, T, t)) =
   959           let val (xs', t') = rename xs t
   960           in (xs', Abs (the_default x x', T, t')) end
   961       | rename xs (t $ u) =
   962           let
   963             val (xs', t') = rename xs t;
   964             val (xs'', u') = rename xs' u
   965           in (xs'', t' $ u') end
   966       | rename xs t = (xs, t);
   967   in case rename xs prop of
   968       ([], prop') => equal_elim (reflexive (cterm_of thy prop')) thm
   969     | _ => error "More names than abstractions in theorem"
   970   end;
   971 
   972 
   973 
   974 (** multi_resolve **)
   975 
   976 local
   977 
   978 fun res th i rule =
   979   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   980 
   981 fun multi_res _ [] rule = Seq.single rule
   982   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   983 
   984 in
   985 
   986 val multi_resolve = multi_res 1;
   987 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   988 
   989 end;
   990 
   991 end;
   992 
   993 structure BasicDrule: BASIC_DRULE = Drule;
   994 open BasicDrule;