src/Pure/variable.ML
author wenzelm
Thu Oct 04 20:29:42 2007 +0200 (2007-10-04)
changeset 24850 0cfd722ab579
parent 24848 5dbbd33c3236
child 25051 71cd45fdf332
permissions -rw-r--r--
Name.uu, Name.aT;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val maxidx_of: Proof.context -> int
    17   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    18   val is_declared: Proof.context -> string -> bool
    19   val is_fixed: Proof.context -> string -> bool
    20   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    21   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    22   val default_type: Proof.context -> string -> typ option
    23   val def_type: Proof.context -> bool -> indexname -> typ option
    24   val def_sort: Proof.context -> indexname -> sort option
    25   val declare_constraints: term -> Proof.context -> Proof.context
    26   val declare_internal: term -> Proof.context -> Proof.context
    27   val declare_term: term -> Proof.context -> Proof.context
    28   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    29   val declare_thm: thm -> Proof.context -> Proof.context
    30   val thm_context: thm -> Proof.context
    31   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    32   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    33   val expand_binds: Proof.context -> term -> term
    34   val add_fixes: string list -> Proof.context -> string list * Proof.context
    35   val add_fixes_direct: string list -> Proof.context -> Proof.context
    36   val auto_fixes: term -> Proof.context -> Proof.context
    37   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    38   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    39   val export_terms: Proof.context -> Proof.context -> term list -> term list
    40   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    41   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    42   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    43   val export: Proof.context -> Proof.context -> thm list -> thm list
    44   val export_morphism: Proof.context -> Proof.context -> morphism
    45   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    46   val import_inst: bool -> term list -> Proof.context ->
    47     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    48   val importT_terms: term list -> Proof.context -> term list * Proof.context
    49   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    50   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    51   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    52   val import_thms: bool -> thm list -> Proof.context ->
    53     ((ctyp list * cterm list) * thm list) * Proof.context
    54   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    55   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    56   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    57   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    58   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    59   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    60   val polymorphic: Proof.context -> term list -> term list
    61 end;
    62 
    63 structure Variable: VARIABLE =
    64 struct
    65 
    66 (** local context data **)
    67 
    68 datatype data = Data of
    69  {is_body: bool,                        (*inner body mode*)
    70   names: Name.context,                  (*type/term variable names*)
    71   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    72   binds: (typ * term) Vartab.table,     (*term bindings*)
    73   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    74   maxidx: int,                          (*maximum var index*)
    75   constraints:
    76     typ Vartab.table *                  (*type constraints*)
    77     sort Vartab.table};                 (*default sorts*)
    78 
    79 fun make_data (is_body, names, fixes, binds, type_occs, maxidx, constraints) =
    80   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    81     type_occs = type_occs, maxidx = maxidx, constraints = constraints};
    82 
    83 structure Data = ProofDataFun
    84 (
    85   type T = data;
    86   fun init thy =
    87     make_data (false, Name.context, [], Vartab.empty, Symtab.empty,
    88       ~1, (Vartab.empty, Vartab.empty));
    89 );
    90 
    91 fun map_data f =
    92   Data.map (fn Data {is_body, names, fixes, binds, type_occs, maxidx, constraints} =>
    93     make_data (f (is_body, names, fixes, binds, type_occs, maxidx, constraints)));
    94 
    95 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
    96   (is_body, f names, fixes, binds, type_occs, maxidx, constraints));
    97 
    98 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
    99   (is_body, names, f fixes, binds, type_occs, maxidx, constraints));
   100 
   101 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
   102   (is_body, names, fixes, f binds, type_occs, maxidx, constraints));
   103 
   104 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
   105   (is_body, names, fixes, binds, f type_occs, maxidx, constraints));
   106 
   107 fun map_maxidx f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
   108   (is_body, names, fixes, binds, type_occs, f maxidx, constraints));
   109 
   110 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, maxidx, constraints) =>
   111   (is_body, names, fixes, binds, type_occs, maxidx, f constraints));
   112 
   113 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   114 
   115 val is_body = #is_body o rep_data;
   116 
   117 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, maxidx, constraints) =>
   118   (b, names, fixes, binds, type_occs, maxidx, constraints));
   119 
   120 fun restore_body ctxt = set_body (is_body ctxt);
   121 
   122 val names_of = #names o rep_data;
   123 val fixes_of = #fixes o rep_data;
   124 val binds_of = #binds o rep_data;
   125 val type_occs_of = #type_occs o rep_data;
   126 val maxidx_of = #maxidx o rep_data;
   127 val constraints_of = #constraints o rep_data;
   128 
   129 val is_declared = Name.is_declared o names_of;
   130 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   131 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   132 
   133 fun add_fixed ctxt = Term.fold_aterms
   134   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   135 
   136 
   137 
   138 (** declarations **)
   139 
   140 (* default sorts and types *)
   141 
   142 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   143 
   144 fun def_type ctxt pattern xi =
   145   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   146     (case Vartab.lookup types xi of
   147       NONE =>
   148         if pattern then NONE
   149         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   150     | some => some)
   151   end;
   152 
   153 val def_sort = Vartab.lookup o #2 o constraints_of;
   154 
   155 
   156 (* names *)
   157 
   158 fun declare_type_names t =
   159   map_names (fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I)) t) #>
   160   map_maxidx (fold_types Term.maxidx_typ t);
   161 
   162 fun declare_names t =
   163   declare_type_names t #>
   164   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t) #>
   165   map_maxidx (Term.maxidx_term t);
   166 
   167 
   168 (* type occurrences *)
   169 
   170 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   171 
   172 val decl_type_occs = fold_term_types
   173   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   174     | _ => decl_type_occsT);
   175 
   176 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   177 val declare_type_occs = map_type_occs o decl_type_occs;
   178 
   179 
   180 (* constraints *)
   181 
   182 fun constrain_tvar (xi, S) =
   183   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   184 
   185 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   186   let
   187     val types' = fold_aterms
   188       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   189         | Var v => Vartab.update v
   190         | _ => I) t types;
   191     val sorts' = fold_types (fold_atyps
   192       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   193         | TVar v => constrain_tvar v
   194         | _ => I)) t sorts;
   195   in (types', sorts') end)
   196   #> declare_type_occsT t
   197   #> declare_type_names t;
   198 
   199 
   200 (* common declarations *)
   201 
   202 fun declare_internal t =
   203   declare_names t #>
   204   declare_type_occs t;
   205 
   206 fun declare_term t =
   207   declare_internal t #>
   208   declare_constraints t;
   209 
   210 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   211 
   212 val declare_thm = Thm.fold_terms declare_internal;
   213 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   214 
   215 
   216 (* renaming term/type frees *)
   217 
   218 fun variant_frees ctxt ts frees =
   219   let
   220     val names = names_of (fold declare_names ts ctxt);
   221     val xs = fst (Name.variants (map #1 frees) names);
   222   in xs ~~ map snd frees end;
   223 
   224 
   225 
   226 (** term bindings **)
   227 
   228 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   229   | add_bind ((x, i), SOME t) =
   230       let
   231         val T = Term.fastype_of t;
   232         val t' =
   233           if null (Term.hidden_polymorphism t T) then t
   234           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   235       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   236 
   237 val add_binds = fold add_bind;
   238 
   239 fun expand_binds ctxt =
   240   let
   241     val binds = binds_of ctxt;
   242     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   243   in Envir.beta_norm o Envir.expand_term get end;
   244 
   245 
   246 
   247 (** fixes **)
   248 
   249 local
   250 
   251 fun no_dups [] = ()
   252   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   253 
   254 fun new_fixes names' xs xs' =
   255   map_names (K names') #>
   256   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   257   fold (declare_constraints o Syntax.free) xs' #>
   258   pair xs';
   259 
   260 in
   261 
   262 fun add_fixes xs ctxt =
   263   let
   264     val _ =
   265       (case filter (can Name.dest_skolem) xs of [] => ()
   266       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   267     val _ = no_dups (duplicates (op =) xs);
   268     val (ys, zs) = split_list (fixes_of ctxt);
   269     val names = names_of ctxt;
   270     val (xs', names') =
   271       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   272       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   273         (xs, fold Name.declare xs names));
   274   in ctxt |> new_fixes names' xs xs' end;
   275 
   276 fun variant_fixes raw_xs ctxt =
   277   let
   278     val names = names_of ctxt;
   279     val xs = map Name.clean raw_xs;
   280     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   281   in ctxt |> new_fixes names' xs xs' end;
   282 
   283 end;
   284 
   285 
   286 fun add_fixes_direct xs ctxt = ctxt
   287   |> set_body false
   288   |> (snd o add_fixes xs)
   289   |> restore_body ctxt;
   290 
   291 fun fix_frees t ctxt = ctxt
   292   |> add_fixes_direct
   293       (rev (fold_aterms (fn Free (x, _) =>
   294         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   295 
   296 fun auto_fixes t ctxt =
   297   (if is_body ctxt then ctxt else fix_frees t ctxt)
   298   |> declare_term t;
   299 
   300 fun invent_types Ss ctxt =
   301   let
   302     val tfrees = Name.invents (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   303     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   304   in (tfrees, ctxt') end;
   305 
   306 
   307 
   308 (** export -- generalize type/term variables (beware of closure sizes) **)
   309 
   310 fun export_inst inner outer =
   311   let
   312     val declared_outer = is_declared outer;
   313     val fixes_inner = fixes_of inner;
   314     val fixes_outer = fixes_of outer;
   315 
   316     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   317     val still_fixed = not o member (op =) gen_fixes;
   318 
   319     val type_occs_inner = type_occs_of inner;
   320     fun gen_fixesT ts =
   321       Symtab.fold (fn (a, xs) =>
   322         if declared_outer a orelse exists still_fixed xs
   323         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   324   in (gen_fixesT, gen_fixes) end;
   325 
   326 fun exportT_inst inner outer = #1 (export_inst inner outer);
   327 
   328 fun exportT_terms inner outer =
   329   let val mk_tfrees = exportT_inst inner outer in
   330     fn ts => ts |> map
   331       (TermSubst.generalize (mk_tfrees ts, [])
   332         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   333   end;
   334 
   335 fun export_terms inner outer =
   336   let val (mk_tfrees, tfrees) = export_inst inner outer in
   337     fn ts => ts |> map
   338       (TermSubst.generalize (mk_tfrees ts, tfrees)
   339         (fold Term.maxidx_term ts ~1 + 1))
   340   end;
   341 
   342 fun export_prf inner outer prf =
   343   let
   344     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   345     val tfrees = mk_tfrees [];
   346     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   347     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   348     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   349   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   350 
   351 
   352 fun gen_export (mk_tfrees, frees) ths =
   353   let
   354     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   355     val maxidx = fold Thm.maxidx_thm ths ~1;
   356   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   357 
   358 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   359 fun export inner outer = gen_export (export_inst inner outer);
   360 
   361 fun export_morphism inner outer =
   362   let
   363     val fact = export inner outer;
   364     val term = singleton (export_terms inner outer);
   365     val typ = Logic.type_map term;
   366   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   367 
   368 
   369 
   370 (** import -- fix schematic type/term variables **)
   371 
   372 fun importT_inst ts ctxt =
   373   let
   374     val tvars = rev (fold Term.add_tvars ts []);
   375     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   376   in (tvars ~~ map TFree tfrees, ctxt') end;
   377 
   378 fun import_inst is_open ts ctxt =
   379   let
   380     val ren = if is_open then I else Name.internal;
   381     val (instT, ctxt') = importT_inst ts ctxt;
   382     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   383     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   384     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   385   in ((instT, inst), ctxt'') end;
   386 
   387 fun importT_terms ts ctxt =
   388   let val (instT, ctxt') = importT_inst ts ctxt
   389   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   390 
   391 fun import_terms is_open ts ctxt =
   392   let val (inst, ctxt') = import_inst is_open ts ctxt
   393   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   394 
   395 fun importT_thms ths ctxt =
   396   let
   397     val thy = ProofContext.theory_of ctxt;
   398     val certT = Thm.ctyp_of thy;
   399     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   400     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   401     val ths' = map (Thm.instantiate (instT', [])) ths;
   402   in ((map #2 instT', ths'), ctxt') end;
   403 
   404 fun import_prf is_open prf ctxt =
   405   let
   406     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   407     val (insts, ctxt') = import_inst is_open ts ctxt;
   408   in (Proofterm.instantiate insts prf, ctxt') end;
   409 
   410 fun import_thms is_open ths ctxt =
   411   let
   412     val thy = ProofContext.theory_of ctxt;
   413     val cert = Thm.cterm_of thy;
   414     val certT = Thm.ctyp_of thy;
   415     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   416     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   417     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   418     val ths' = map (Thm.instantiate (instT', inst')) ths;
   419   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   420 
   421 
   422 (* import/export *)
   423 
   424 fun gen_trade imp exp f ctxt ths =
   425   let val ((_, ths'), ctxt') = imp ths ctxt
   426   in exp ctxt' ctxt (f ctxt' ths') end;
   427 
   428 val tradeT = gen_trade importT_thms exportT;
   429 val trade = gen_trade (import_thms true) export;
   430 
   431 
   432 (* focus on outermost parameters *)
   433 
   434 fun forall_elim_prop t prop =
   435   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   436   |> Thm.cprop_of |> Thm.dest_arg;
   437 
   438 fun focus goal ctxt =
   439   let
   440     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   441     val t = Thm.term_of goal;
   442     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   443     val (xs, Ts) = split_list ps;
   444     val (xs', ctxt') = variant_fixes xs ctxt;
   445     val ps' = ListPair.map (cert o Free) (xs', Ts);
   446     val goal' = fold forall_elim_prop ps' goal;
   447   in ((ps', goal'), ctxt') end;
   448 
   449 fun focus_subgoal i st =
   450   let
   451     val all_vars = Thm.fold_terms Term.add_vars st [];
   452     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   453   in
   454     add_binds no_binds #>
   455     fold (declare_constraints o Var) all_vars #>
   456     focus (Thm.cprem_of st i)
   457   end;
   458 
   459 
   460 
   461 (** implicit polymorphism **)
   462 
   463 (* warn_extra_tfrees *)
   464 
   465 fun warn_extra_tfrees ctxt1 ctxt2 =
   466   let
   467     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   468     fun occs_free a x =
   469       (case def_type ctxt1 false (x, ~1) of
   470         SOME T => if occs_typ a T then I else cons (a, x)
   471       | NONE => cons (a, x));
   472 
   473     val occs1 = type_occs_of ctxt1;
   474     val occs2 = type_occs_of ctxt2;
   475     val extras = Symtab.fold (fn (a, xs) =>
   476       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   477     val tfrees = map #1 extras |> sort_distinct string_ord;
   478     val frees = map #2 extras |> sort_distinct string_ord;
   479   in
   480     if null extras then ()
   481     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   482       space_implode " or " (map quote frees))
   483   end;
   484 
   485 
   486 (* polymorphic terms *)
   487 
   488 fun polymorphic_types ctxt ts =
   489   let
   490     val ctxt' = fold declare_term ts ctxt;
   491     val occs = type_occs_of ctxt;
   492     val occs' = type_occs_of ctxt';
   493     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   494     val idx = maxidx_of ctxt' + 1;
   495     val Ts' = (fold o fold_types o fold_atyps)
   496       (fn T as TFree _ =>
   497           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   498         | _ => I) ts [];
   499     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   500   in (rev Ts', ts') end;
   501 
   502 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   503 
   504 end;