src/Pure/search.ML
author wenzelm
Sun Jul 23 12:04:56 2000 +0200 (2000-07-23)
changeset 9411 0d5a171db2f0
parent 9094 530e7a33b3dd
child 12262 11ff5f47df6e
permissions -rw-r--r--
tuned ThmHeap;
     1 (*  Title: 	search
     2     ID:         $Id$
     3     Author: 	Lawrence C Paulson and Norbert Voelker
     4 
     5 Search tacticals
     6 *)
     7 
     8 infix 1 THEN_MAYBE THEN_MAYBE';
     9 
    10 signature SEARCH =
    11   sig
    12   val DEEPEN  	        : int*int -> (int->int->tactic) -> int -> int -> tactic
    13 
    14   val THEN_MAYBE	: tactic * tactic -> tactic
    15   val THEN_MAYBE'	: ('a -> tactic) * ('a -> tactic) -> ('a -> tactic)
    16 
    17   val trace_DEPTH_FIRST	: bool ref
    18   val DEPTH_FIRST	: (thm -> bool) -> tactic -> tactic
    19   val DEPTH_SOLVE	: tactic -> tactic
    20   val DEPTH_SOLVE_1	: tactic -> tactic
    21   val ITER_DEEPEN	: (thm->bool) -> (int->tactic) -> tactic
    22   val THEN_ITER_DEEPEN	: tactic -> (thm->bool) -> (int->tactic) -> tactic
    23 
    24   val has_fewer_prems	: int -> thm -> bool   
    25   val IF_UNSOLVED	: tactic -> tactic
    26   val SOLVE		: tactic -> tactic
    27   val DETERM_UNTIL_SOLVED: tactic -> tactic
    28   val trace_BEST_FIRST	: bool ref
    29   val BEST_FIRST	: (thm -> bool) * (thm -> int) -> tactic -> tactic
    30   val THEN_BEST_FIRST	: tactic -> (thm->bool) * (thm->int) -> tactic
    31 			  -> tactic
    32   val trace_ASTAR	: bool ref
    33   val ASTAR	        : (thm -> bool) * (int->thm->int) -> tactic -> tactic
    34   val THEN_ASTAR	: tactic -> (thm->bool) * (int->thm->int) -> tactic
    35 			  -> tactic
    36   val BREADTH_FIRST	: (thm -> bool) -> tactic -> tactic
    37   val QUIET_BREADTH_FIRST	: (thm -> bool) -> tactic -> tactic
    38   end;
    39 
    40 
    41 (** Instantiation of heaps for best-first search **)
    42 
    43 (*total ordering on theorems, allowing duplicates to be found*)
    44 structure ThmHeap =
    45   HeapFun (type elem = int * thm
    46     val ord = Library.prod_ord Library.int_ord
    47       (Term.term_ord o Library.pairself (#prop o Thm.rep_thm)));
    48 
    49 
    50 structure Search : SEARCH = 
    51 struct
    52 
    53 (**** Depth-first search ****)
    54 
    55 val trace_DEPTH_FIRST = ref false;
    56 
    57 (*Searches until "satp" reports proof tree as satisfied.
    58   Suppresses duplicate solutions to minimize search space.*)
    59 fun DEPTH_FIRST satp tac = 
    60  let val tac = tracify trace_DEPTH_FIRST tac
    61      fun depth used [] = None
    62        | depth used (q::qs) =
    63 	  case Seq.pull q of
    64 	      None         => depth used qs
    65 	    | Some(st,stq) => 
    66 		if satp st andalso not (gen_mem eq_thm (st, used))
    67 		then Some(st, Seq.make
    68 			         (fn()=> depth (st::used) (stq::qs)))
    69 		else depth used (tac st :: stq :: qs)
    70   in  traced_tac (fn st => depth [] ([Seq.single st]))  end;
    71 
    72 
    73 
    74 (*Predicate: Does the rule have fewer than n premises?*)
    75 fun has_fewer_prems n rule = (nprems_of rule < n);
    76 
    77 (*Apply a tactic if subgoals remain, else do nothing.*)
    78 val IF_UNSOLVED = COND (has_fewer_prems 1) all_tac;
    79 
    80 (*Force a tactic to solve its goal completely, otherwise fail *)
    81 fun SOLVE tac = tac THEN COND (has_fewer_prems 1) all_tac no_tac;
    82 
    83 (*Force repeated application of tactic until goal is solved completely *)
    84 val DETERM_UNTIL_SOLVED = DETERM_UNTIL (has_fewer_prems 1);
    85 
    86 (*Execute tac1, but only execute tac2 if there are at least as many subgoals
    87   as before.  This ensures that tac2 is only applied to an outcome of tac1.*)
    88 fun (tac1 THEN_MAYBE tac2) st = 
    89     (tac1  THEN  COND (has_fewer_prems (nprems_of st)) all_tac tac2)  st;
    90 
    91 fun (tac1 THEN_MAYBE' tac2) x = tac1 x THEN_MAYBE tac2 x;
    92 
    93 (*Tactical to reduce the number of premises by 1.
    94   If no subgoals then it must fail! *)
    95 fun DEPTH_SOLVE_1 tac st = st |>
    96     (case nprems_of st of
    97 	0 => no_tac
    98       | n => DEPTH_FIRST (has_fewer_prems n) tac);
    99 
   100 (*Uses depth-first search to solve ALL subgoals*)
   101 val DEPTH_SOLVE = DEPTH_FIRST (has_fewer_prems 1);
   102 
   103 
   104 
   105 (**** Iterative deepening with pruning ****)
   106 
   107 fun has_vars (Var _) = true
   108   | has_vars (Abs (_,_,t)) = has_vars t
   109   | has_vars (f$t) = has_vars f orelse has_vars t
   110   | has_vars _ = false;
   111 
   112 (*Counting of primitive inferences is APPROXIMATE, as the step tactic
   113   may perform >1 inference*)
   114 
   115 (*Pruning of rigid ancestor to prevent backtracking*)
   116 fun prune (new as (k', np':int, rgd', stq), qs) = 
   117     let fun prune_aux (qs, []) = new::qs
   118           | prune_aux (qs, (k,np,rgd,q)::rqs) =
   119 	      if np'+1 = np andalso rgd then
   120 		  (if !trace_DEPTH_FIRST then
   121 		       writeln ("Pruning " ^ 
   122 				string_of_int (1+length rqs) ^ " levels")
   123 		   else ();
   124 		   (*Use OLD k: zero-cost solution; see Stickel, p 365*)
   125 		   (k, np', rgd', stq) :: qs)
   126 	      else prune_aux ((k,np,rgd,q)::qs, rqs)
   127         fun take ([], rqs) = ([], rqs)
   128 	  | take (arg as ((k,np,rgd,stq)::qs, rqs)) = 
   129 	        if np' < np then take (qs, (k,np,rgd,stq)::rqs)
   130 		            else arg
   131     in  prune_aux (take (qs, []))  end;
   132 
   133 
   134 (*Depth-first iterative deepening search for a state that satisfies satp
   135   tactic tac0 sets up the initial goal queue, while tac1 searches it.
   136   The solution sequence is redundant: the cutoff heuristic makes it impossible
   137   to suppress solutions arising from earlier searches, as the accumulated cost
   138   (k) can be wrong.*)
   139 fun THEN_ITER_DEEPEN tac0 satp tac1 = traced_tac (fn st => 
   140  let val countr = ref 0
   141      and tf = tracify trace_DEPTH_FIRST (tac1 1)
   142      and qs0 = tac0 st
   143      (*bnd = depth bound; inc = estimate of increment required next*)
   144      fun depth (bnd,inc) [] = 
   145 	     (writeln (string_of_int (!countr) ^ 
   146 		       " inferences so far.  Searching to depth " ^ 
   147 		       string_of_int bnd);
   148 	      (*larger increments make it run slower for the hard problems*)
   149 	      depth (bnd+inc, 10)) [(0, 1, false, qs0)]
   150        | depth (bnd,inc) ((k,np,rgd,q)::qs) =
   151 	  if k>=bnd then depth (bnd,inc) qs
   152           else
   153 	  case (countr := !countr+1;
   154 		if !trace_DEPTH_FIRST then
   155 		    writeln (string_of_int np ^ 
   156 			     implode (map (fn _ => "*") qs))
   157 		else ();
   158 		Seq.pull q) of
   159 	     None         => depth (bnd,inc) qs
   160 	   | Some(st,stq) => 
   161 	       if satp st	(*solution!*)
   162 	       then Some(st, Seq.make
   163 			 (fn()=> depth (bnd,inc) ((k,np,rgd,stq)::qs)))
   164 
   165 	       else 
   166                let val np' = nprems_of st
   167 		     (*rgd' calculation assumes tactic operates on subgoal 1*)
   168                    val rgd' = not (has_vars (hd (prems_of st)))
   169                    val k' = k+np'-np+1  (*difference in # of subgoals, +1*)
   170                in  if k'+np' >= bnd 
   171 		   then depth (bnd, Int.min(inc, k'+np'+1-bnd)) qs
   172 		   else if np' < np (*solved a subgoal; prune rigid ancestors*)
   173                    then depth (bnd,inc) 
   174 		         (prune ((k', np', rgd', tf st), (k,np,rgd,stq) :: qs))
   175 	           else depth (bnd,inc) ((k', np', rgd', tf st) :: 
   176 					 (k,np,rgd,stq) :: qs)
   177 	       end
   178   in depth (0,5) [] end);
   179 
   180 val ITER_DEEPEN = THEN_ITER_DEEPEN all_tac;
   181 
   182 
   183 (*Simple iterative deepening tactical.  It merely "deepens" any search tactic
   184   using increment "inc" up to limit "lim". *)
   185 fun DEEPEN (inc,lim) tacf m i = 
   186   let fun dpn m st = st |> (if has_fewer_prems i st then no_tac
   187 			    else if m>lim then 
   188 				(writeln "Giving up..."; no_tac)
   189 				 else (writeln ("Depth = " ^ string_of_int m);
   190 				       tacf m i  ORELSE  dpn (m+inc)))
   191   in  dpn m  end;
   192 
   193 (*** Best-first search ***)
   194 
   195 val trace_BEST_FIRST = ref false;
   196 
   197 (*For creating output sequence*)
   198 fun some_of_list []     = None
   199   | some_of_list (x::l) = Some (x, Seq.make (fn () => some_of_list l));
   200 
   201 (*Check for and delete duplicate proof states*)
   202 fun deleteAllMin prf heap = 
   203       if ThmHeap.is_empty heap then heap
   204       else if eq_thm (prf, #2 (ThmHeap.min heap))
   205       then deleteAllMin prf (ThmHeap.delete_min heap)
   206       else heap;
   207 
   208 (*Best-first search for a state that satisfies satp (incl initial state)
   209   Function sizef estimates size of problem remaining (smaller means better).
   210   tactic tac0 sets up the initial priority queue, while tac1 searches it. *)
   211 fun THEN_BEST_FIRST tac0 (satp, sizef) tac1 = 
   212   let val tac = tracify trace_BEST_FIRST tac1
   213       fun pairsize th = (sizef th, th);
   214       fun bfs (news,nprf_heap) =
   215 	   (case  partition satp news  of
   216 		([],nonsats) => next(foldr ThmHeap.insert
   217 					(map pairsize nonsats, nprf_heap)) 
   218 	      | (sats,_)  => some_of_list sats)
   219       and next nprf_heap =
   220             if ThmHeap.is_empty nprf_heap then None
   221 	    else 
   222 	    let val (n,prf) = ThmHeap.min nprf_heap
   223 	    in if !trace_BEST_FIRST 
   224 	       then writeln("state size = " ^ string_of_int n)  
   225                else ();
   226 	       bfs (Seq.list_of (tac prf), 
   227 		    deleteAllMin prf (ThmHeap.delete_min nprf_heap))
   228             end
   229       fun btac st = bfs (Seq.list_of (tac0 st), ThmHeap.empty)
   230   in traced_tac btac end;
   231 
   232 (*Ordinary best-first search, with no initial tactic*)
   233 val BEST_FIRST = THEN_BEST_FIRST all_tac;
   234 
   235 (*Breadth-first search to satisfy satpred (including initial state) 
   236   SLOW -- SHOULD NOT USE APPEND!*)
   237 fun gen_BREADTH_FIRST message satpred (tac:tactic) = 
   238   let val tacf = Seq.list_of o tac;
   239       fun bfs prfs =
   240 	 (case  partition satpred prfs  of
   241 	      ([],[]) => []
   242 	    | ([],nonsats) => 
   243 		  (message("breadth=" ^ string_of_int(length nonsats));
   244 		   bfs (List.concat (map tacf nonsats)))
   245 	    | (sats,_)  => sats)
   246   in (fn st => Seq.of_list (bfs [st])) end;
   247 
   248 val BREADTH_FIRST = gen_BREADTH_FIRST writeln;
   249 val QUIET_BREADTH_FIRST = gen_BREADTH_FIRST (K ());
   250 
   251 
   252 (*  Author: 	Norbert Voelker, FernUniversitaet Hagen
   253     Remarks:    Implementation of A*-like proof procedure by modification
   254 		of the existing code for BEST_FIRST and best_tac so that the 
   255 		current level of search is taken into account.
   256 *)		
   257 
   258 (*Insertion into priority queue of states, marked with level *)
   259 fun insert_with_level (lnth: int*int*thm, []) = [lnth]
   260   | insert_with_level ((l,m,th), (l',n,th')::nths) = 
   261       if  n<m then (l',n,th') :: insert_with_level ((l,m,th), nths)
   262       else if  n=m andalso eq_thm(th,th')
   263               then (l',n,th')::nths
   264               else (l,m,th)::(l',n,th')::nths;
   265 
   266 (*For creating output sequence*)
   267 fun some_of_list []     = None
   268   | some_of_list (x::l) = Some (x, Seq.make (fn () => some_of_list l));
   269 
   270 val trace_ASTAR = ref false; 
   271 
   272 fun THEN_ASTAR tac0 (satp, costf) tac1 = 
   273   let val tf = tracify trace_ASTAR tac1;   
   274       fun bfs (news,nprfs,level) =
   275       let fun cost thm = (level, costf level thm, thm)
   276       in (case  partition satp news  of
   277             ([],nonsats) 
   278 		 => next (foldr insert_with_level (map cost nonsats, nprfs))
   279           | (sats,_)  => some_of_list sats)
   280       end and    
   281       next []  = None
   282         | next ((level,n,prf)::nprfs)  =
   283             (if !trace_ASTAR 
   284                then writeln("level = " ^ string_of_int level ^
   285 			 "  cost = " ^ string_of_int n ^ 
   286                          "  queue length =" ^ string_of_int (length nprfs))  
   287                else ();
   288              bfs (Seq.list_of (tf prf), nprfs,level+1))
   289       fun tf st = bfs (Seq.list_of (tac0 st), [], 0)
   290   in traced_tac tf end;
   291 
   292 (*Ordinary ASTAR, with no initial tactic*)
   293 val ASTAR = THEN_ASTAR all_tac;
   294 
   295 end;
   296 
   297 open Search;