src/HOL/Library/Cardinality.thy
author Andreas Lochbihler
Thu Feb 14 16:01:28 2013 +0100 (2013-02-14)
changeset 51116 0dac0158b8d4
parent 49948 744934b818c7
child 51139 c8e3cf3520b3
permissions -rw-r--r--
implement code generation for finite, card, op = and op <= for sets always via finite_UNIV and card_UNIV, as fragile rewrites based on sorts are hard to find and debug
     1 (*  Title:      HOL/Library/Cardinality.thy
     2     Author:     Brian Huffman, Andreas Lochbihler
     3 *)
     4 
     5 header {* Cardinality of types *}
     6 
     7 theory Cardinality
     8 imports Phantom_Type
     9 begin
    10 
    11 subsection {* Preliminary lemmas *}
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 lemma finite_range_Some: "finite (range (Some :: 'a \<Rightarrow> 'a option)) = finite (UNIV :: 'a set)"
    31 by(auto dest: finite_imageD intro: inj_Some)
    32 
    33 lemma infinite_literal: "\<not> finite (UNIV :: String.literal set)"
    34 proof -
    35   have "inj STR" by(auto intro: injI)
    36   thus ?thesis
    37     by(auto simp add: type_definition.univ[OF type_definition_literal] infinite_UNIV_listI dest: finite_imageD)
    38 qed
    39 
    40 subsection {* Cardinalities of types *}
    41 
    42 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    43 
    44 translations "CARD('t)" => "CONST card (CONST UNIV \<Colon> 't set)"
    45 
    46 typed_print_translation (advanced) {*
    47   let
    48     fun card_univ_tr' ctxt _ [Const (@{const_syntax UNIV}, Type (_, [T]))] =
    49       Syntax.const @{syntax_const "_type_card"} $ Syntax_Phases.term_of_typ ctxt T
    50   in [(@{const_syntax card}, card_univ_tr')] end
    51 *}
    52 
    53 lemma card_prod [simp]: "CARD('a \<times> 'b) = CARD('a) * CARD('b)"
    54   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    55 
    56 lemma card_UNIV_sum: "CARD('a + 'b) = (if CARD('a) \<noteq> 0 \<and> CARD('b) \<noteq> 0 then CARD('a) + CARD('b) else 0)"
    57 unfolding UNIV_Plus_UNIV[symmetric]
    58 by(auto simp add: card_eq_0_iff card_Plus simp del: UNIV_Plus_UNIV)
    59 
    60 lemma card_sum [simp]: "CARD('a + 'b) = CARD('a::finite) + CARD('b::finite)"
    61 by(simp add: card_UNIV_sum)
    62 
    63 lemma card_UNIV_option: "CARD('a option) = (if CARD('a) = 0 then 0 else CARD('a) + 1)"
    64 proof -
    65   have "(None :: 'a option) \<notin> range Some" by clarsimp
    66   thus ?thesis
    67     by(simp add: UNIV_option_conv card_eq_0_iff finite_range_Some card_insert_disjoint card_image)
    68 qed
    69 
    70 lemma card_option [simp]: "CARD('a option) = Suc CARD('a::finite)"
    71 by(simp add: card_UNIV_option)
    72 
    73 lemma card_UNIV_set: "CARD('a set) = (if CARD('a) = 0 then 0 else 2 ^ CARD('a))"
    74 by(simp add: Pow_UNIV[symmetric] card_eq_0_iff card_Pow del: Pow_UNIV)
    75 
    76 lemma card_set [simp]: "CARD('a set) = 2 ^ CARD('a::finite)"
    77 by(simp add: card_UNIV_set)
    78 
    79 lemma card_nat [simp]: "CARD(nat) = 0"
    80   by (simp add: card_eq_0_iff)
    81 
    82 lemma card_fun: "CARD('a \<Rightarrow> 'b) = (if CARD('a) \<noteq> 0 \<and> CARD('b) \<noteq> 0 \<or> CARD('b) = 1 then CARD('b) ^ CARD('a) else 0)"
    83 proof -
    84   {  assume "0 < CARD('a)" and "0 < CARD('b)"
    85     hence fina: "finite (UNIV :: 'a set)" and finb: "finite (UNIV :: 'b set)"
    86       by(simp_all only: card_ge_0_finite)
    87     from finite_distinct_list[OF finb] obtain bs 
    88       where bs: "set bs = (UNIV :: 'b set)" and distb: "distinct bs" by blast
    89     from finite_distinct_list[OF fina] obtain as
    90       where as: "set as = (UNIV :: 'a set)" and dista: "distinct as" by blast
    91     have cb: "CARD('b) = length bs"
    92       unfolding bs[symmetric] distinct_card[OF distb] ..
    93     have ca: "CARD('a) = length as"
    94       unfolding as[symmetric] distinct_card[OF dista] ..
    95     let ?xs = "map (\<lambda>ys. the o map_of (zip as ys)) (List.n_lists (length as) bs)"
    96     have "UNIV = set ?xs"
    97     proof(rule UNIV_eq_I)
    98       fix f :: "'a \<Rightarrow> 'b"
    99       from as have "f = the \<circ> map_of (zip as (map f as))"
   100         by(auto simp add: map_of_zip_map)
   101       thus "f \<in> set ?xs" using bs by(auto simp add: set_n_lists)
   102     qed
   103     moreover have "distinct ?xs" unfolding distinct_map
   104     proof(intro conjI distinct_n_lists distb inj_onI)
   105       fix xs ys :: "'b list"
   106       assume xs: "xs \<in> set (List.n_lists (length as) bs)"
   107         and ys: "ys \<in> set (List.n_lists (length as) bs)"
   108         and eq: "the \<circ> map_of (zip as xs) = the \<circ> map_of (zip as ys)"
   109       from xs ys have [simp]: "length xs = length as" "length ys = length as"
   110         by(simp_all add: length_n_lists_elem)
   111       have "map_of (zip as xs) = map_of (zip as ys)"
   112       proof
   113         fix x
   114         from as bs have "\<exists>y. map_of (zip as xs) x = Some y" "\<exists>y. map_of (zip as ys) x = Some y"
   115           by(simp_all add: map_of_zip_is_Some[symmetric])
   116         with eq show "map_of (zip as xs) x = map_of (zip as ys) x"
   117           by(auto dest: fun_cong[where x=x])
   118       qed
   119       with dista show "xs = ys" by(simp add: map_of_zip_inject)
   120     qed
   121     hence "card (set ?xs) = length ?xs" by(simp only: distinct_card)
   122     moreover have "length ?xs = length bs ^ length as" by(simp add: length_n_lists)
   123     ultimately have "CARD('a \<Rightarrow> 'b) = CARD('b) ^ CARD('a)" using cb ca by simp }
   124   moreover {
   125     assume cb: "CARD('b) = 1"
   126     then obtain b where b: "UNIV = {b :: 'b}" by(auto simp add: card_Suc_eq)
   127     have eq: "UNIV = {\<lambda>x :: 'a. b ::'b}"
   128     proof(rule UNIV_eq_I)
   129       fix x :: "'a \<Rightarrow> 'b"
   130       { fix y
   131         have "x y \<in> UNIV" ..
   132         hence "x y = b" unfolding b by simp }
   133       thus "x \<in> {\<lambda>x. b}" by(auto)
   134     qed
   135     have "CARD('a \<Rightarrow> 'b) = 1" unfolding eq by simp }
   136   ultimately show ?thesis
   137     by(auto simp del: One_nat_def)(auto simp add: card_eq_0_iff dest: finite_fun_UNIVD2 finite_fun_UNIVD1)
   138 qed
   139 
   140 corollary finite_UNIV_fun:
   141   "finite (UNIV :: ('a \<Rightarrow> 'b) set) \<longleftrightarrow>
   142    finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set) \<or> CARD('b) = 1"
   143   (is "?lhs \<longleftrightarrow> ?rhs")
   144 proof -
   145   have "?lhs \<longleftrightarrow> CARD('a \<Rightarrow> 'b) > 0" by(simp add: card_gt_0_iff)
   146   also have "\<dots> \<longleftrightarrow> CARD('a) > 0 \<and> CARD('b) > 0 \<or> CARD('b) = 1"
   147     by(simp add: card_fun)
   148   also have "\<dots> = ?rhs" by(simp add: card_gt_0_iff)
   149   finally show ?thesis .
   150 qed
   151 
   152 lemma card_nibble: "CARD(nibble) = 16"
   153 unfolding UNIV_nibble by simp
   154 
   155 lemma card_UNIV_char: "CARD(char) = 256"
   156 proof -
   157   have "inj (\<lambda>(x, y). Char x y)" by(auto intro: injI)
   158   thus ?thesis unfolding UNIV_char by(simp add: card_image card_nibble)
   159 qed
   160 
   161 lemma card_literal: "CARD(String.literal) = 0"
   162 by(simp add: card_eq_0_iff infinite_literal)
   163 
   164 subsection {* Classes with at least 1 and 2  *}
   165 
   166 text {* Class finite already captures "at least 1" *}
   167 
   168 lemma zero_less_card_finite [simp]: "0 < CARD('a::finite)"
   169   unfolding neq0_conv [symmetric] by simp
   170 
   171 lemma one_le_card_finite [simp]: "Suc 0 \<le> CARD('a::finite)"
   172   by (simp add: less_Suc_eq_le [symmetric])
   173 
   174 text {* Class for cardinality "at least 2" *}
   175 
   176 class card2 = finite + 
   177   assumes two_le_card: "2 \<le> CARD('a)"
   178 
   179 lemma one_less_card: "Suc 0 < CARD('a::card2)"
   180   using two_le_card [where 'a='a] by simp
   181 
   182 lemma one_less_int_card: "1 < int CARD('a::card2)"
   183   using one_less_card [where 'a='a] by simp
   184 
   185 
   186 subsection {* A type class for deciding finiteness of types *}
   187 
   188 type_synonym 'a finite_UNIV = "('a, bool) phantom"
   189 
   190 class finite_UNIV = 
   191   fixes finite_UNIV :: "('a, bool) phantom"
   192   assumes finite_UNIV: "finite_UNIV = Phantom('a) (finite (UNIV :: 'a set))"
   193 
   194 lemma finite_UNIV_code [code_unfold]:
   195   "finite (UNIV :: 'a :: finite_UNIV set)
   196   \<longleftrightarrow> of_phantom (finite_UNIV :: 'a finite_UNIV)"
   197 by(simp add: finite_UNIV)
   198 
   199 subsection {* A type class for computing the cardinality of types *}
   200 
   201 definition is_list_UNIV :: "'a list \<Rightarrow> bool"
   202 where "is_list_UNIV xs = (let c = CARD('a) in if c = 0 then False else size (remdups xs) = c)"
   203 
   204 lemma is_list_UNIV_iff: "is_list_UNIV xs \<longleftrightarrow> set xs = UNIV"
   205 by(auto simp add: is_list_UNIV_def Let_def card_eq_0_iff List.card_set[symmetric] 
   206    dest: subst[where P="finite", OF _ finite_set] card_eq_UNIV_imp_eq_UNIV)
   207 
   208 type_synonym 'a card_UNIV = "('a, nat) phantom"
   209 
   210 class card_UNIV = finite_UNIV +
   211   fixes card_UNIV :: "'a card_UNIV"
   212   assumes card_UNIV: "card_UNIV = Phantom('a) CARD('a)"
   213 
   214 subsection {* Instantiations for @{text "card_UNIV"} *}
   215 
   216 instantiation nat :: card_UNIV begin
   217 definition "finite_UNIV = Phantom(nat) False"
   218 definition "card_UNIV = Phantom(nat) 0"
   219 instance by intro_classes (simp_all add: finite_UNIV_nat_def card_UNIV_nat_def)
   220 end
   221 
   222 instantiation int :: card_UNIV begin
   223 definition "finite_UNIV = Phantom(int) False"
   224 definition "card_UNIV = Phantom(int) 0"
   225 instance by intro_classes (simp_all add: card_UNIV_int_def finite_UNIV_int_def infinite_UNIV_int)
   226 end
   227 
   228 instantiation code_numeral :: card_UNIV begin
   229 definition "finite_UNIV = Phantom(code_numeral) False"
   230 definition "card_UNIV = Phantom(code_numeral) 0"
   231 instance
   232   by(intro_classes)(auto simp add: card_UNIV_code_numeral_def finite_UNIV_code_numeral_def type_definition.univ[OF type_definition_code_numeral] card_eq_0_iff dest!: finite_imageD intro: inj_onI)
   233 end
   234 
   235 instantiation list :: (type) card_UNIV begin
   236 definition "finite_UNIV = Phantom('a list) False"
   237 definition "card_UNIV = Phantom('a list) 0"
   238 instance by intro_classes (simp_all add: card_UNIV_list_def finite_UNIV_list_def infinite_UNIV_listI)
   239 end
   240 
   241 instantiation unit :: card_UNIV begin
   242 definition "finite_UNIV = Phantom(unit) True"
   243 definition "card_UNIV = Phantom(unit) 1"
   244 instance by intro_classes (simp_all add: card_UNIV_unit_def finite_UNIV_unit_def)
   245 end
   246 
   247 instantiation bool :: card_UNIV begin
   248 definition "finite_UNIV = Phantom(bool) True"
   249 definition "card_UNIV = Phantom(bool) 2"
   250 instance by(intro_classes)(simp_all add: card_UNIV_bool_def finite_UNIV_bool_def)
   251 end
   252 
   253 instantiation nibble :: card_UNIV begin
   254 definition "finite_UNIV = Phantom(nibble) True"
   255 definition "card_UNIV = Phantom(nibble) 16"
   256 instance by(intro_classes)(simp_all add: card_UNIV_nibble_def card_nibble finite_UNIV_nibble_def)
   257 end
   258 
   259 instantiation char :: card_UNIV begin
   260 definition "finite_UNIV = Phantom(char) True"
   261 definition "card_UNIV = Phantom(char) 256"
   262 instance by intro_classes (simp_all add: card_UNIV_char_def card_UNIV_char finite_UNIV_char_def)
   263 end
   264 
   265 instantiation prod :: (finite_UNIV, finite_UNIV) finite_UNIV begin
   266 definition "finite_UNIV = Phantom('a \<times> 'b) 
   267   (of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> of_phantom (finite_UNIV :: 'b finite_UNIV))"
   268 instance by intro_classes (simp add: finite_UNIV_prod_def finite_UNIV finite_prod)
   269 end
   270 
   271 instantiation prod :: (card_UNIV, card_UNIV) card_UNIV begin
   272 definition "card_UNIV = Phantom('a \<times> 'b) 
   273   (of_phantom (card_UNIV :: 'a card_UNIV) * of_phantom (card_UNIV :: 'b card_UNIV))"
   274 instance by intro_classes (simp add: card_UNIV_prod_def card_UNIV)
   275 end
   276 
   277 instantiation sum :: (finite_UNIV, finite_UNIV) finite_UNIV begin
   278 definition "finite_UNIV = Phantom('a + 'b)
   279   (of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> of_phantom (finite_UNIV :: 'b finite_UNIV))"
   280 instance
   281   by intro_classes (simp add: UNIV_Plus_UNIV[symmetric] finite_UNIV_sum_def finite_UNIV del: UNIV_Plus_UNIV)
   282 end
   283 
   284 instantiation sum :: (card_UNIV, card_UNIV) card_UNIV begin
   285 definition "card_UNIV = Phantom('a + 'b)
   286   (let ca = of_phantom (card_UNIV :: 'a card_UNIV); 
   287        cb = of_phantom (card_UNIV :: 'b card_UNIV)
   288    in if ca \<noteq> 0 \<and> cb \<noteq> 0 then ca + cb else 0)"
   289 instance by intro_classes (auto simp add: card_UNIV_sum_def card_UNIV card_UNIV_sum)
   290 end
   291 
   292 instantiation "fun" :: (finite_UNIV, card_UNIV) finite_UNIV begin
   293 definition "finite_UNIV = Phantom('a \<Rightarrow> 'b)
   294   (let cb = of_phantom (card_UNIV :: 'b card_UNIV)
   295    in cb = 1 \<or> of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> cb \<noteq> 0)"
   296 instance
   297   by intro_classes (auto simp add: finite_UNIV_fun_def Let_def card_UNIV finite_UNIV finite_UNIV_fun card_gt_0_iff)
   298 end
   299 
   300 instantiation "fun" :: (card_UNIV, card_UNIV) card_UNIV begin
   301 definition "card_UNIV = Phantom('a \<Rightarrow> 'b)
   302   (let ca = of_phantom (card_UNIV :: 'a card_UNIV);
   303        cb = of_phantom (card_UNIV :: 'b card_UNIV)
   304    in if ca \<noteq> 0 \<and> cb \<noteq> 0 \<or> cb = 1 then cb ^ ca else 0)"
   305 instance by intro_classes (simp add: card_UNIV_fun_def card_UNIV Let_def card_fun)
   306 end
   307 
   308 instantiation option :: (finite_UNIV) finite_UNIV begin
   309 definition "finite_UNIV = Phantom('a option) (of_phantom (finite_UNIV :: 'a finite_UNIV))"
   310 instance by intro_classes (simp add: finite_UNIV_option_def finite_UNIV)
   311 end
   312 
   313 instantiation option :: (card_UNIV) card_UNIV begin
   314 definition "card_UNIV = Phantom('a option)
   315   (let c = of_phantom (card_UNIV :: 'a card_UNIV) in if c \<noteq> 0 then Suc c else 0)"
   316 instance by intro_classes (simp add: card_UNIV_option_def card_UNIV card_UNIV_option)
   317 end
   318 
   319 instantiation String.literal :: card_UNIV begin
   320 definition "finite_UNIV = Phantom(String.literal) False"
   321 definition "card_UNIV = Phantom(String.literal) 0"
   322 instance
   323   by intro_classes (simp_all add: card_UNIV_literal_def finite_UNIV_literal_def infinite_literal card_literal)
   324 end
   325 
   326 instantiation set :: (finite_UNIV) finite_UNIV begin
   327 definition "finite_UNIV = Phantom('a set) (of_phantom (finite_UNIV :: 'a finite_UNIV))"
   328 instance by intro_classes (simp add: finite_UNIV_set_def finite_UNIV Finite_Set.finite_set)
   329 end
   330 
   331 instantiation set :: (card_UNIV) card_UNIV begin
   332 definition "card_UNIV = Phantom('a set)
   333   (let c = of_phantom (card_UNIV :: 'a card_UNIV) in if c = 0 then 0 else 2 ^ c)"
   334 instance by intro_classes (simp add: card_UNIV_set_def card_UNIV_set card_UNIV)
   335 end
   336 
   337 lemma UNIV_finite_1: "UNIV = set [finite_1.a\<^isub>1]"
   338 by(auto intro: finite_1.exhaust)
   339 
   340 lemma UNIV_finite_2: "UNIV = set [finite_2.a\<^isub>1, finite_2.a\<^isub>2]"
   341 by(auto intro: finite_2.exhaust)
   342 
   343 lemma UNIV_finite_3: "UNIV = set [finite_3.a\<^isub>1, finite_3.a\<^isub>2, finite_3.a\<^isub>3]"
   344 by(auto intro: finite_3.exhaust)
   345 
   346 lemma UNIV_finite_4: "UNIV = set [finite_4.a\<^isub>1, finite_4.a\<^isub>2, finite_4.a\<^isub>3, finite_4.a\<^isub>4]"
   347 by(auto intro: finite_4.exhaust)
   348 
   349 lemma UNIV_finite_5:
   350   "UNIV = set [finite_5.a\<^isub>1, finite_5.a\<^isub>2, finite_5.a\<^isub>3, finite_5.a\<^isub>4, finite_5.a\<^isub>5]"
   351 by(auto intro: finite_5.exhaust)
   352 
   353 instantiation Enum.finite_1 :: card_UNIV begin
   354 definition "finite_UNIV = Phantom(Enum.finite_1) True"
   355 definition "card_UNIV = Phantom(Enum.finite_1) 1"
   356 instance
   357   by intro_classes (simp_all add: UNIV_finite_1 card_UNIV_finite_1_def finite_UNIV_finite_1_def)
   358 end
   359 
   360 instantiation Enum.finite_2 :: card_UNIV begin
   361 definition "finite_UNIV = Phantom(Enum.finite_2) True"
   362 definition "card_UNIV = Phantom(Enum.finite_2) 2"
   363 instance
   364   by intro_classes (simp_all add: UNIV_finite_2 card_UNIV_finite_2_def finite_UNIV_finite_2_def)
   365 end
   366 
   367 instantiation Enum.finite_3 :: card_UNIV begin
   368 definition "finite_UNIV = Phantom(Enum.finite_3) True"
   369 definition "card_UNIV = Phantom(Enum.finite_3) 3"
   370 instance
   371   by intro_classes (simp_all add: UNIV_finite_3 card_UNIV_finite_3_def finite_UNIV_finite_3_def)
   372 end
   373 
   374 instantiation Enum.finite_4 :: card_UNIV begin
   375 definition "finite_UNIV = Phantom(Enum.finite_4) True"
   376 definition "card_UNIV = Phantom(Enum.finite_4) 4"
   377 instance
   378   by intro_classes (simp_all add: UNIV_finite_4 card_UNIV_finite_4_def finite_UNIV_finite_4_def)
   379 end
   380 
   381 instantiation Enum.finite_5 :: card_UNIV begin
   382 definition "finite_UNIV = Phantom(Enum.finite_5) True"
   383 definition "card_UNIV = Phantom(Enum.finite_5) 5"
   384 instance
   385   by intro_classes (simp_all add: UNIV_finite_5 card_UNIV_finite_5_def finite_UNIV_finite_5_def)
   386 end
   387 
   388 subsection {* Code setup for sets *}
   389 
   390 text {*
   391   Implement operations @{term "finite"}, @{term "card"}, @{term "op \<subseteq>"}, and @{term "op ="} 
   392   for sets using @{term "finite_UNIV"} and @{term "card_UNIV"}.
   393 *}
   394 
   395 lemma card_Compl:
   396   "finite A \<Longrightarrow> card (- A) = card (UNIV :: 'a set) - card (A :: 'a set)"
   397 by (metis Compl_eq_Diff_UNIV card_Diff_subset top_greatest)
   398 
   399 lemma card_coset_code [code]:
   400   fixes xs :: "'a :: card_UNIV list" 
   401   shows "card (List.coset xs) = of_phantom (card_UNIV :: 'a card_UNIV) - length (remdups xs)"
   402 by(simp add: List.card_set card_Compl card_UNIV)
   403 
   404 lemma [code, code del]: "finite = finite" ..
   405 
   406 lemma [code]:
   407   fixes xs :: "'a :: card_UNIV list" 
   408   shows finite_set_code:
   409   "finite (set xs) = True" 
   410   and finite_coset_code:
   411   "finite (List.coset xs) \<longleftrightarrow> of_phantom (finite_UNIV :: 'a finite_UNIV)"
   412 by(simp_all add: card_gt_0_iff finite_UNIV)
   413 
   414 lemma coset_subset_code [code]:
   415   fixes xs :: "'a list" shows
   416   "List.coset xs \<subseteq> set ys \<longleftrightarrow> (let n = CARD('a) in n > 0 \<and> card (set (xs @ ys)) = n)"
   417 by(auto simp add: Let_def card_gt_0_iff dest: card_eq_UNIV_imp_eq_UNIV intro: arg_cong[where f=card])
   418   (metis finite_compl finite_set rev_finite_subset)
   419 
   420 lemma equal_set_code [code]:
   421   fixes xs ys :: "'a :: equal list"
   422   defines "rhs \<equiv> 
   423   let n = CARD('a)
   424   in if n = 0 then False else 
   425         let xs' = remdups xs; ys' = remdups ys 
   426         in length xs' + length ys' = n \<and> (\<forall>x \<in> set xs'. x \<notin> set ys') \<and> (\<forall>y \<in> set ys'. y \<notin> set xs')"
   427   shows "equal_class.equal (List.coset xs) (set ys) \<longleftrightarrow> rhs" (is ?thesis1)
   428   and "equal_class.equal (set ys) (List.coset xs) \<longleftrightarrow> rhs" (is ?thesis2)
   429   and "equal_class.equal (set xs) (set ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)" (is ?thesis3)
   430   and "equal_class.equal (List.coset xs) (List.coset ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)" (is ?thesis4)
   431 proof -
   432   show ?thesis1 (is "?lhs \<longleftrightarrow> ?rhs")
   433   proof
   434     assume ?lhs thus ?rhs
   435       by(auto simp add: equal_eq rhs_def Let_def List.card_set[symmetric] card_Un_Int[where A="set xs" and B="- set xs"] card_UNIV Compl_partition card_gt_0_iff dest: sym)(metis finite_compl finite_set)
   436   next
   437     assume ?rhs
   438     moreover have "\<lbrakk> \<forall>y\<in>set xs. y \<notin> set ys; \<forall>x\<in>set ys. x \<notin> set xs \<rbrakk> \<Longrightarrow> set xs \<inter> set ys = {}" by blast
   439     ultimately show ?lhs
   440       by(auto simp add: equal_eq rhs_def Let_def List.card_set[symmetric] card_UNIV card_gt_0_iff card_Un_Int[where A="set xs" and B="set ys"] dest: card_eq_UNIV_imp_eq_UNIV split: split_if_asm)
   441   qed
   442   thus ?thesis2 unfolding equal_eq by blast
   443   show ?thesis3 ?thesis4 unfolding equal_eq List.coset_def by blast+
   444 qed
   445 
   446 notepad begin (* test code setup *)
   447 have "List.coset [True] = set [False] \<and> List.coset [] \<subseteq> List.set [True, False] \<and> finite (List.coset [True])"
   448   by eval
   449 end
   450 
   451 end
   452