src/HOLCF/Tools/fixrec_package.ML
author wenzelm
Thu Mar 20 00:20:44 2008 +0100 (2008-03-20)
changeset 26343 0dd2eab7b296
parent 26336 a0e2b706ce73
child 26939 1035c89b4c02
permissions -rw-r--r--
simplified get_thm(s): back to plain name argument;
     1 (*  Title:      HOLCF/Tools/fixrec_package.ML
     2     ID:         $Id$
     3     Author:     Amber Telfer and Brian Huffman
     4 
     5 Recursive function definition package for HOLCF.
     6 *)
     7 
     8 signature FIXREC_PACKAGE =
     9 sig
    10   val legacy_infer_term: theory -> term -> term
    11   val legacy_infer_prop: theory -> term -> term
    12   val add_fixrec: bool -> ((string * Attrib.src list) * string) list list -> theory -> theory
    13   val add_fixrec_i: bool -> ((string * attribute list) * term) list list -> theory -> theory
    14   val add_fixpat: (string * Attrib.src list) * string list -> theory -> theory
    15   val add_fixpat_i: (string * attribute list) * term list -> theory -> theory
    16 end;
    17 
    18 structure FixrecPackage: FIXREC_PACKAGE =
    19 struct
    20 
    21 (* legacy type inference *)
    22 
    23 fun legacy_infer_term thy t =
    24   singleton (Syntax.check_terms (ProofContext.init thy)) (Sign.intern_term thy t);
    25 
    26 fun legacy_infer_prop thy t = legacy_infer_term thy (TypeInfer.constrain propT t);
    27 
    28 
    29 val fix_eq2 = @{thm fix_eq2};
    30 val def_fix_ind = @{thm def_fix_ind};
    31 
    32 
    33 fun fixrec_err s = error ("fixrec definition error:\n" ^ s);
    34 fun fixrec_eq_err thy s eq =
    35   fixrec_err (s ^ "\nin\n" ^ quote (Sign.string_of_term thy eq));
    36 
    37 (* ->> is taken from holcf_logic.ML *)
    38 (* TODO: fix dependencies so we can import HOLCFLogic here *)
    39 infixr 6 ->>;
    40 fun S ->> T = Type (@{type_name "->"},[S,T]);
    41 
    42 (* extern_name is taken from domain/library.ML *)
    43 fun extern_name con = case Symbol.explode con of 
    44 		   ("o"::"p"::" "::rest) => implode rest
    45 		   | _ => con;
    46 
    47 val mk_trp = HOLogic.mk_Trueprop;
    48 
    49 (* splits a cterm into the right and lefthand sides of equality *)
    50 fun dest_eqs t = HOLogic.dest_eq (HOLogic.dest_Trueprop t);
    51 
    52 (* similar to Thm.head_of, but for continuous application *)
    53 fun chead_of (Const(@{const_name Rep_CFun},_)$f$t) = chead_of f
    54   | chead_of u = u;
    55 
    56 (* these are helpful functions copied from HOLCF/domain/library.ML *)
    57 fun %: s = Free(s,dummyT);
    58 fun %%: s = Const(s,dummyT);
    59 infix 0 ==;  fun S ==  T = %%:"==" $ S $ T;
    60 infix 1 ===; fun S === T = %%:"op =" $ S $ T;
    61 infix 9 `  ; fun f ` x = %%:@{const_name Rep_CFun} $ f $ x;
    62 
    63 (* builds the expression (LAM v. rhs) *)
    64 fun big_lambda v rhs = %%:@{const_name Abs_CFun}$(Term.lambda v rhs);
    65 
    66 (* builds the expression (LAM v1 v2 .. vn. rhs) *)
    67 fun big_lambdas [] rhs = rhs
    68   | big_lambdas (v::vs) rhs = big_lambda v (big_lambdas vs rhs);
    69 
    70 (* builds the expression (LAM <v1,v2,..,vn>. rhs) *)
    71 fun lambda_ctuple [] rhs = big_lambda (%:"unit") rhs
    72   | lambda_ctuple (v::[]) rhs = big_lambda v rhs
    73   | lambda_ctuple (v::vs) rhs =
    74       %%:@{const_name csplit}`(big_lambda v (lambda_ctuple vs rhs));
    75 
    76 (* builds the expression <v1,v2,..,vn> *)
    77 fun mk_ctuple [] = %%:"UU"
    78 |   mk_ctuple (t::[]) = t
    79 |   mk_ctuple (t::ts) = %%:@{const_name cpair}`t`(mk_ctuple ts);
    80 
    81 (*************************************************************************)
    82 (************* fixed-point definitions and unfolding theorems ************)
    83 (*************************************************************************)
    84 
    85 fun add_fixdefs eqs thy =
    86   let
    87     val (lhss,rhss) = ListPair.unzip (map dest_eqs eqs);
    88     val fixpoint = %%:@{const_name fix}`lambda_ctuple lhss (mk_ctuple rhss);
    89     
    90     fun one_def (l as Const(n,T)) r =
    91           let val b = Sign.base_name n in (b, (b^"_def", l == r)) end
    92       | one_def _ _ = fixrec_err "fixdefs: lhs not of correct form";
    93     fun defs [] _ = []
    94       | defs (l::[]) r = [one_def l r]
    95       | defs (l::ls) r = one_def l (%%:@{const_name cfst}`r) :: defs ls (%%:@{const_name csnd}`r);
    96     val (names, pre_fixdefs) = ListPair.unzip (defs lhss fixpoint);
    97     
    98     val fixdefs = map (apsnd (legacy_infer_prop thy)) pre_fixdefs;
    99     val (fixdef_thms, thy') =
   100       PureThy.add_defs_i false (map Thm.no_attributes fixdefs) thy;
   101     val ctuple_fixdef_thm = foldr1 (fn (x,y) => @{thm cpair_equalI} OF [x,y]) fixdef_thms;
   102     
   103     val ctuple_unfold = legacy_infer_term thy' (mk_trp (mk_ctuple lhss === mk_ctuple rhss));
   104     val ctuple_unfold_thm = Goal.prove_global thy' [] [] ctuple_unfold
   105           (fn _ => EVERY [rtac (ctuple_fixdef_thm RS fix_eq2 RS trans) 1,
   106                     simp_tac (simpset_of thy') 1]);
   107     val ctuple_induct_thm =
   108           (space_implode "_" names ^ "_induct", ctuple_fixdef_thm RS def_fix_ind);
   109     
   110     fun unfolds [] thm = []
   111       | unfolds (n::[]) thm = [(n^"_unfold", thm)]
   112       | unfolds (n::ns) thm = let
   113           val thmL = thm RS @{thm cpair_eqD1};
   114           val thmR = thm RS @{thm cpair_eqD2};
   115         in (n^"_unfold", thmL) :: unfolds ns thmR end;
   116     val unfold_thms = unfolds names ctuple_unfold_thm;
   117     val thms = ctuple_induct_thm :: unfold_thms;
   118     val (_, thy'') = PureThy.add_thms (map Thm.no_attributes thms) thy';
   119   in
   120     (thy'', names, fixdef_thms, map snd unfold_thms)
   121   end;
   122 
   123 (*************************************************************************)
   124 (*********** monadic notation and pattern matching compilation ***********)
   125 (*************************************************************************)
   126 
   127 fun add_names (Const(a,_), bs) = insert (op =) (Sign.base_name a) bs
   128   | add_names (Free(a,_) , bs) = insert (op =) a bs
   129   | add_names (f $ u     , bs) = add_names (f, add_names(u, bs))
   130   | add_names (Abs(a,_,t), bs) = add_names (t, insert (op =) a bs)
   131   | add_names (_         , bs) = bs;
   132 
   133 fun add_terms ts xs = foldr add_names xs ts;
   134 
   135 (* builds a monadic term for matching a constructor pattern *)
   136 fun pre_build pat rhs vs taken =
   137   case pat of
   138     Const(@{const_name Rep_CFun},_)$f$(v as Free(n,T)) =>
   139       pre_build f rhs (v::vs) taken
   140   | Const(@{const_name Rep_CFun},_)$f$x =>
   141       let val (rhs', v, taken') = pre_build x rhs [] taken;
   142       in pre_build f rhs' (v::vs) taken' end
   143   | Const(c,T) =>
   144       let
   145         val n = Name.variant taken "v";
   146         fun result_type (Type(@{type_name "->"},[_,T])) (x::xs) = result_type T xs
   147           | result_type T _ = T;
   148         val v = Free(n, result_type T vs);
   149         val m = "match_"^(extern_name(Sign.base_name c));
   150         val k = lambda_ctuple vs rhs;
   151       in
   152         (%%:@{const_name Fixrec.bind}`(%%:m`v)`k, v, n::taken)
   153       end
   154   | Free(n,_) => fixrec_err ("expected constructor, found free variable " ^ quote n)
   155   | _ => fixrec_err "pre_build: invalid pattern";
   156 
   157 (* builds a monadic term for matching a function definition pattern *)
   158 (* returns (name, arity, matcher) *)
   159 fun building pat rhs vs taken =
   160   case pat of
   161     Const(@{const_name Rep_CFun}, _)$f$(v as Free(n,T)) =>
   162       building f rhs (v::vs) taken
   163   | Const(@{const_name Rep_CFun}, _)$f$x =>
   164       let val (rhs', v, taken') = pre_build x rhs [] taken;
   165       in building f rhs' (v::vs) taken' end
   166   | Const(name,_) => (name, length vs, big_lambdas vs rhs)
   167   | _ => fixrec_err "function is not declared as constant in theory";
   168 
   169 fun match_eq eq = 
   170   let val (lhs,rhs) = dest_eqs eq;
   171   in building lhs (%%:@{const_name Fixrec.return}`rhs) [] (add_terms [eq] []) end;
   172 
   173 (* returns the sum (using +++) of the terms in ms *)
   174 (* also applies "run" to the result! *)
   175 fun fatbar arity ms =
   176   let
   177     fun unLAM 0 t = t
   178       | unLAM n (_$Abs(_,_,t)) = unLAM (n-1) t
   179       | unLAM _ _ = fixrec_err "fatbar: internal error, not enough LAMs";
   180     fun reLAM 0 t = t
   181       | reLAM n t = reLAM (n-1) (%%:@{const_name Abs_CFun} $ Abs("",dummyT,t));
   182     fun mplus (x,y) = %%:@{const_name Fixrec.mplus}`x`y;
   183     val msum = foldr1 mplus (map (unLAM arity) ms);
   184   in
   185     reLAM arity (%%:@{const_name Fixrec.run}`msum)
   186   end;
   187 
   188 fun unzip3 [] = ([],[],[])
   189   | unzip3 ((x,y,z)::ts) =
   190       let val (xs,ys,zs) = unzip3 ts
   191       in (x::xs, y::ys, z::zs) end;
   192 
   193 (* this is the pattern-matching compiler function *)
   194 fun compile_pats eqs = 
   195   let
   196     val ((n::names),(a::arities),mats) = unzip3 (map match_eq eqs);
   197     val cname = if forall (fn x => n=x) names then n
   198           else fixrec_err "all equations in block must define the same function";
   199     val arity = if forall (fn x => a=x) arities then a
   200           else fixrec_err "all equations in block must have the same arity";
   201     val rhs = fatbar arity mats;
   202   in
   203     mk_trp (%%:cname === rhs)
   204   end;
   205 
   206 (*************************************************************************)
   207 (********************** Proving associated theorems **********************)
   208 (*************************************************************************)
   209 
   210 (* proves a block of pattern matching equations as theorems, using unfold *)
   211 fun make_simps thy (unfold_thm, eqns) =
   212   let
   213     val tacs = [rtac (unfold_thm RS @{thm ssubst_lhs}) 1, asm_simp_tac (simpset_of thy) 1];
   214     fun prove_term t = Goal.prove_global thy [] [] t (K (EVERY tacs));
   215     fun prove_eqn ((name, eqn_t), atts) = ((name, prove_term eqn_t), atts);
   216   in
   217     map prove_eqn eqns
   218   end;
   219 
   220 (*************************************************************************)
   221 (************************* Main fixrec function **************************)
   222 (*************************************************************************)
   223 
   224 fun gen_add_fixrec prep_prop prep_attrib strict blocks thy =
   225   let
   226     val eqns = List.concat blocks;
   227     val lengths = map length blocks;
   228     
   229     val ((names, srcss), strings) = apfst split_list (split_list eqns);
   230     val atts = map (map (prep_attrib thy)) srcss;
   231     val eqn_ts = map (prep_prop thy) strings;
   232     val rec_ts = map (fn eq => chead_of (fst (dest_eqs (Logic.strip_imp_concl eq)))
   233       handle TERM _ => fixrec_eq_err thy "not a proper equation" eq) eqn_ts;
   234     val (_, eqn_ts') = OldPrimrecPackage.unify_consts thy rec_ts eqn_ts;
   235     
   236     fun unconcat [] _ = []
   237       | unconcat (n::ns) xs = List.take (xs,n) :: unconcat ns (List.drop (xs,n));
   238     val pattern_blocks = unconcat lengths (map Logic.strip_imp_concl eqn_ts');
   239     val compiled_ts = map (legacy_infer_term thy o compile_pats) pattern_blocks;
   240     val (thy', cnames, fixdef_thms, unfold_thms) = add_fixdefs compiled_ts thy;
   241   in
   242     if strict then let (* only prove simp rules if strict = true *)
   243       val eqn_blocks = unconcat lengths ((names ~~ eqn_ts') ~~ atts);
   244       val simps = List.concat (map (make_simps thy') (unfold_thms ~~ eqn_blocks));
   245       val (simp_thms, thy'') = PureThy.add_thms simps thy';
   246       
   247       val simp_names = map (fn name => name^"_simps") cnames;
   248       val simp_attribute = rpair [Simplifier.simp_add];
   249       val simps' = map simp_attribute (simp_names ~~ unconcat lengths simp_thms);
   250     in
   251       (snd o PureThy.add_thmss simps') thy''
   252     end
   253     else thy'
   254   end;
   255 
   256 val add_fixrec = gen_add_fixrec Syntax.read_prop_global Attrib.attribute;
   257 val add_fixrec_i = gen_add_fixrec Sign.cert_prop (K I);
   258 
   259 
   260 (*************************************************************************)
   261 (******************************** Fixpat *********************************)
   262 (*************************************************************************)
   263 
   264 fun fix_pat thy t = 
   265   let
   266     val T = fastype_of t;
   267     val eq = mk_trp (HOLogic.eq_const T $ t $ Var (("x",0),T));
   268     val cname = case chead_of t of Const(c,_) => c | _ =>
   269               fixrec_err "function is not declared as constant in theory";
   270     val unfold_thm = PureThy.get_thm thy (cname^"_unfold");
   271     val simp = Goal.prove_global thy [] [] eq
   272           (fn _ => EVERY [stac unfold_thm 1, simp_tac (simpset_of thy) 1]);
   273   in simp end;
   274 
   275 fun gen_add_fixpat prep_term prep_attrib ((name, srcs), strings) thy =
   276   let
   277     val atts = map (prep_attrib thy) srcs;
   278     val ts = map (prep_term thy) strings;
   279     val simps = map (fix_pat thy) ts;
   280   in
   281     (snd o PureThy.add_thmss [((name, simps), atts)]) thy
   282   end;
   283 
   284 val add_fixpat = gen_add_fixpat Syntax.read_term_global Attrib.attribute;
   285 val add_fixpat_i = gen_add_fixpat Sign.cert_term (K I);
   286 
   287 
   288 (*************************************************************************)
   289 (******************************** Parsers ********************************)
   290 (*************************************************************************)
   291 
   292 local structure P = OuterParse and K = OuterKeyword in
   293 
   294 val fixrec_eqn = SpecParse.opt_thm_name ":" -- P.prop;
   295 
   296 val fixrec_strict = P.opt_keyword "permissive" >> not;
   297 
   298 val fixrec_decl = fixrec_strict -- P.and_list1 (Scan.repeat1 fixrec_eqn);
   299 
   300 (* this builds a parser for a new keyword, fixrec, whose functionality 
   301 is defined by add_fixrec *)
   302 val _ =
   303   OuterSyntax.command "fixrec" "define recursive functions (HOLCF)" K.thy_decl
   304     (fixrec_decl >> (Toplevel.theory o uncurry add_fixrec));
   305 
   306 (* fixpat parser *)
   307 val fixpat_decl = SpecParse.opt_thm_name ":" -- Scan.repeat1 P.prop;
   308 
   309 val _ =
   310   OuterSyntax.command "fixpat" "define rewrites for fixrec functions" K.thy_decl
   311     (fixpat_decl >> (Toplevel.theory o add_fixpat));
   312 
   313 end; (* local structure *)
   314 
   315 end;