src/HOL/Limits.thy
author hoelzl
Wed Jun 18 07:31:12 2014 +0200 (2014-06-18)
changeset 57275 0ddb5b755cdc
parent 56541 0e3abadbef39
child 57276 49c51eeaa623
permissions -rw-r--r--
moved lemmas from the proof of the Central Limit Theorem by Jeremy Avigad and Luke Serafin
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 subsection {* Filter going to infinity norm *}
    16 
    17 definition at_infinity :: "'a::real_normed_vector filter" where
    18   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    19 
    20 lemma eventually_at_infinity:
    21   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    22 unfolding at_infinity_def
    23 proof (rule eventually_Abs_filter, rule is_filter.intro)
    24   fix P Q :: "'a \<Rightarrow> bool"
    25   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    26   then obtain r s where
    27     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    28   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    29   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    30 qed auto
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    34   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    35 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    36   fix P :: "real \<Rightarrow> bool"
    37   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    38   then obtain r where "\<forall>x. r \<le> norm x \<longrightarrow> P x" ..
    39   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    40   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    41 next
    42   fix P :: "real \<Rightarrow> bool"
    43   assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    44   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    45   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    46     by (intro exI[of _ "max p (-q)"]) (auto simp: abs_real_def)
    47 qed
    48 
    49 lemma at_top_le_at_infinity:
    50   "at_top \<le> (at_infinity :: real filter)"
    51   unfolding at_infinity_eq_at_top_bot by simp
    52 
    53 lemma at_bot_le_at_infinity:
    54   "at_bot \<le> (at_infinity :: real filter)"
    55   unfolding at_infinity_eq_at_top_bot by simp
    56 
    57 lemma filterlim_at_top_imp_at_infinity:
    58   fixes f :: "_ \<Rightarrow> real"
    59   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    60   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    61 
    62 subsubsection {* Boundedness *}
    63 
    64 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    65   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    66 
    67 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    68   "Bseq X \<equiv> Bfun X sequentially"
    69 
    70 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    71 
    72 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    73   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    74 
    75 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    76   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    77 
    78 lemma Bfun_def:
    79   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    80   unfolding Bfun_metric_def norm_conv_dist
    81 proof safe
    82   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    83   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    84     by (intro always_eventually) (metis dist_commute dist_triangle)
    85   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    86     by eventually_elim auto
    87   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    88     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    89 qed auto
    90 
    91 lemma BfunI:
    92   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    93 unfolding Bfun_def
    94 proof (intro exI conjI allI)
    95   show "0 < max K 1" by simp
    96 next
    97   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    98     using K by (rule eventually_elim1, simp)
    99 qed
   100 
   101 lemma BfunE:
   102   assumes "Bfun f F"
   103   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   104 using assms unfolding Bfun_def by fast
   105 
   106 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   107   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   108   apply (erule_tac x=1 in allE)
   109   apply simp
   110   apply safe
   111   apply (rule_tac x="X M" in exI)
   112   apply (rule_tac x=1 in exI)
   113   apply (erule_tac x=M in allE)
   114   apply simp
   115   apply (rule_tac x=M in exI)
   116   apply (auto simp: dist_commute)
   117   done
   118 
   119 
   120 subsubsection {* Bounded Sequences *}
   121 
   122 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   123   by (intro BfunI) (auto simp: eventually_sequentially)
   124 
   125 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   126   by (intro BfunI) (auto simp: eventually_sequentially)
   127 
   128 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   129   unfolding Bfun_def eventually_sequentially
   130 proof safe
   131   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   132   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   133     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   134        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   135 qed auto
   136 
   137 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   138 unfolding Bseq_def by auto
   139 
   140 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   141 by (simp add: Bseq_def)
   142 
   143 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   144 by (auto simp add: Bseq_def)
   145 
   146 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   147 proof (elim BseqE, intro bdd_aboveI2)
   148   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   149     by (auto elim!: allE[of _ n])
   150 qed
   151 
   152 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   153 proof (elim BseqE, intro bdd_belowI2)
   154   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   155     by (auto elim!: allE[of _ n])
   156 qed
   157 
   158 lemma lemma_NBseq_def:
   159   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   160 proof safe
   161   fix K :: real
   162   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   163   then have "K \<le> real (Suc n)" by auto
   164   moreover assume "\<forall>m. norm (X m) \<le> K"
   165   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   166     by (blast intro: order_trans)
   167   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   168 qed (force simp add: real_of_nat_Suc)
   169 
   170 text{* alternative definition for Bseq *}
   171 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   172 apply (simp add: Bseq_def)
   173 apply (simp (no_asm) add: lemma_NBseq_def)
   174 done
   175 
   176 lemma lemma_NBseq_def2:
   177      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   178 apply (subst lemma_NBseq_def, auto)
   179 apply (rule_tac x = "Suc N" in exI)
   180 apply (rule_tac [2] x = N in exI)
   181 apply (auto simp add: real_of_nat_Suc)
   182  prefer 2 apply (blast intro: order_less_imp_le)
   183 apply (drule_tac x = n in spec, simp)
   184 done
   185 
   186 (* yet another definition for Bseq *)
   187 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   188 by (simp add: Bseq_def lemma_NBseq_def2)
   189 
   190 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   191 
   192 text{*alternative formulation for boundedness*}
   193 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   194 apply (unfold Bseq_def, safe)
   195 apply (rule_tac [2] x = "k + norm x" in exI)
   196 apply (rule_tac x = K in exI, simp)
   197 apply (rule exI [where x = 0], auto)
   198 apply (erule order_less_le_trans, simp)
   199 apply (drule_tac x=n in spec)
   200 apply (drule order_trans [OF norm_triangle_ineq2])
   201 apply simp
   202 done
   203 
   204 text{*alternative formulation for boundedness*}
   205 lemma Bseq_iff3:
   206   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   207 proof
   208   assume ?P
   209   then obtain K
   210     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   211   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   212   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   213     by (auto intro: order_trans norm_triangle_ineq4)
   214   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   215     by simp
   216   with `0 < K + norm (X 0)` show ?Q by blast
   217 next
   218   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   219 qed
   220 
   221 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   222 apply (simp add: Bseq_def)
   223 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   224 apply (drule_tac x = n in spec, arith)
   225 done
   226 
   227 
   228 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   229 
   230 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   231   by (simp add: Bseq_def)
   232 
   233 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   234   apply (simp add: subset_eq)
   235   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   236   apply (erule_tac x=n in allE)
   237   apply auto
   238   done
   239 
   240 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   241   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   242 
   243 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   244   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   245 
   246 subsection {* Bounded Monotonic Sequences *}
   247 
   248 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   249 
   250 (* TODO: delete *)
   251 (* FIXME: one use in NSA/HSEQ.thy *)
   252 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   253   apply (rule_tac x="X m" in exI)
   254   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   255   unfolding eventually_sequentially
   256   apply blast
   257   done
   258 
   259 subsection {* Convergence to Zero *}
   260 
   261 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   262   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   263 
   264 lemma ZfunI:
   265   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   266   unfolding Zfun_def by simp
   267 
   268 lemma ZfunD:
   269   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   270   unfolding Zfun_def by simp
   271 
   272 lemma Zfun_ssubst:
   273   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   274   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   275 
   276 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   277   unfolding Zfun_def by simp
   278 
   279 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   280   unfolding Zfun_def by simp
   281 
   282 lemma Zfun_imp_Zfun:
   283   assumes f: "Zfun f F"
   284   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   285   shows "Zfun (\<lambda>x. g x) F"
   286 proof (cases)
   287   assume K: "0 < K"
   288   show ?thesis
   289   proof (rule ZfunI)
   290     fix r::real assume "0 < r"
   291     hence "0 < r / K" using K by simp
   292     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   293       using ZfunD [OF f] by fast
   294     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   295     proof eventually_elim
   296       case (elim x)
   297       hence "norm (f x) * K < r"
   298         by (simp add: pos_less_divide_eq K)
   299       thus ?case
   300         by (simp add: order_le_less_trans [OF elim(1)])
   301     qed
   302   qed
   303 next
   304   assume "\<not> 0 < K"
   305   hence K: "K \<le> 0" by (simp only: not_less)
   306   show ?thesis
   307   proof (rule ZfunI)
   308     fix r :: real
   309     assume "0 < r"
   310     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   311     proof eventually_elim
   312       case (elim x)
   313       also have "norm (f x) * K \<le> norm (f x) * 0"
   314         using K norm_ge_zero by (rule mult_left_mono)
   315       finally show ?case
   316         using `0 < r` by simp
   317     qed
   318   qed
   319 qed
   320 
   321 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   322   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   323 
   324 lemma Zfun_add:
   325   assumes f: "Zfun f F" and g: "Zfun g F"
   326   shows "Zfun (\<lambda>x. f x + g x) F"
   327 proof (rule ZfunI)
   328   fix r::real assume "0 < r"
   329   hence r: "0 < r / 2" by simp
   330   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   331     using f r by (rule ZfunD)
   332   moreover
   333   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   334     using g r by (rule ZfunD)
   335   ultimately
   336   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   337   proof eventually_elim
   338     case (elim x)
   339     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   340       by (rule norm_triangle_ineq)
   341     also have "\<dots> < r/2 + r/2"
   342       using elim by (rule add_strict_mono)
   343     finally show ?case
   344       by simp
   345   qed
   346 qed
   347 
   348 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   349   unfolding Zfun_def by simp
   350 
   351 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   352   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   353 
   354 lemma (in bounded_linear) Zfun:
   355   assumes g: "Zfun g F"
   356   shows "Zfun (\<lambda>x. f (g x)) F"
   357 proof -
   358   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   359     using bounded by fast
   360   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   361     by simp
   362   with g show ?thesis
   363     by (rule Zfun_imp_Zfun)
   364 qed
   365 
   366 lemma (in bounded_bilinear) Zfun:
   367   assumes f: "Zfun f F"
   368   assumes g: "Zfun g F"
   369   shows "Zfun (\<lambda>x. f x ** g x) F"
   370 proof (rule ZfunI)
   371   fix r::real assume r: "0 < r"
   372   obtain K where K: "0 < K"
   373     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   374     using pos_bounded by fast
   375   from K have K': "0 < inverse K"
   376     by (rule positive_imp_inverse_positive)
   377   have "eventually (\<lambda>x. norm (f x) < r) F"
   378     using f r by (rule ZfunD)
   379   moreover
   380   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   381     using g K' by (rule ZfunD)
   382   ultimately
   383   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   384   proof eventually_elim
   385     case (elim x)
   386     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   387       by (rule norm_le)
   388     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   389       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   390     also from K have "r * inverse K * K = r"
   391       by simp
   392     finally show ?case .
   393   qed
   394 qed
   395 
   396 lemma (in bounded_bilinear) Zfun_left:
   397   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   398   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   399 
   400 lemma (in bounded_bilinear) Zfun_right:
   401   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   402   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   403 
   404 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   405 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   406 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   407 
   408 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   409   by (simp only: tendsto_iff Zfun_def dist_norm)
   410 
   411 lemma tendsto_0_le: "\<lbrakk>(f ---> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk> 
   412                      \<Longrightarrow> (g ---> 0) F"
   413   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   414 
   415 subsubsection {* Distance and norms *}
   416 
   417 lemma tendsto_dist [tendsto_intros]:
   418   fixes l m :: "'a :: metric_space"
   419   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   420   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   421 proof (rule tendstoI)
   422   fix e :: real assume "0 < e"
   423   hence e2: "0 < e/2" by simp
   424   from tendstoD [OF f e2] tendstoD [OF g e2]
   425   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   426   proof (eventually_elim)
   427     case (elim x)
   428     then show "dist (dist (f x) (g x)) (dist l m) < e"
   429       unfolding dist_real_def
   430       using dist_triangle2 [of "f x" "g x" "l"]
   431       using dist_triangle2 [of "g x" "l" "m"]
   432       using dist_triangle3 [of "l" "m" "f x"]
   433       using dist_triangle [of "f x" "m" "g x"]
   434       by arith
   435   qed
   436 qed
   437 
   438 lemma continuous_dist[continuous_intros]:
   439   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   440   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   441   unfolding continuous_def by (rule tendsto_dist)
   442 
   443 lemma continuous_on_dist[continuous_intros]:
   444   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   445   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   446   unfolding continuous_on_def by (auto intro: tendsto_dist)
   447 
   448 lemma tendsto_norm [tendsto_intros]:
   449   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   450   unfolding norm_conv_dist by (intro tendsto_intros)
   451 
   452 lemma continuous_norm [continuous_intros]:
   453   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   454   unfolding continuous_def by (rule tendsto_norm)
   455 
   456 lemma continuous_on_norm [continuous_intros]:
   457   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   458   unfolding continuous_on_def by (auto intro: tendsto_norm)
   459 
   460 lemma tendsto_norm_zero:
   461   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   462   by (drule tendsto_norm, simp)
   463 
   464 lemma tendsto_norm_zero_cancel:
   465   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   466   unfolding tendsto_iff dist_norm by simp
   467 
   468 lemma tendsto_norm_zero_iff:
   469   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   470   unfolding tendsto_iff dist_norm by simp
   471 
   472 lemma tendsto_rabs [tendsto_intros]:
   473   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   474   by (fold real_norm_def, rule tendsto_norm)
   475 
   476 lemma continuous_rabs [continuous_intros]:
   477   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   478   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   479 
   480 lemma continuous_on_rabs [continuous_intros]:
   481   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   482   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   483 
   484 lemma tendsto_rabs_zero:
   485   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   486   by (fold real_norm_def, rule tendsto_norm_zero)
   487 
   488 lemma tendsto_rabs_zero_cancel:
   489   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   490   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   491 
   492 lemma tendsto_rabs_zero_iff:
   493   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   494   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   495 
   496 subsubsection {* Addition and subtraction *}
   497 
   498 lemma tendsto_add [tendsto_intros]:
   499   fixes a b :: "'a::real_normed_vector"
   500   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   501   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   502 
   503 lemma continuous_add [continuous_intros]:
   504   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   505   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   506   unfolding continuous_def by (rule tendsto_add)
   507 
   508 lemma continuous_on_add [continuous_intros]:
   509   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   510   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   511   unfolding continuous_on_def by (auto intro: tendsto_add)
   512 
   513 lemma tendsto_add_zero:
   514   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   515   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   516   by (drule (1) tendsto_add, simp)
   517 
   518 lemma tendsto_minus [tendsto_intros]:
   519   fixes a :: "'a::real_normed_vector"
   520   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   521   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   522 
   523 lemma continuous_minus [continuous_intros]:
   524   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   525   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   526   unfolding continuous_def by (rule tendsto_minus)
   527 
   528 lemma continuous_on_minus [continuous_intros]:
   529   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   530   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   531   unfolding continuous_on_def by (auto intro: tendsto_minus)
   532 
   533 lemma tendsto_minus_cancel:
   534   fixes a :: "'a::real_normed_vector"
   535   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   536   by (drule tendsto_minus, simp)
   537 
   538 lemma tendsto_minus_cancel_left:
   539     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   540   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   541   by auto
   542 
   543 lemma tendsto_diff [tendsto_intros]:
   544   fixes a b :: "'a::real_normed_vector"
   545   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   546   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   547 
   548 lemma continuous_diff [continuous_intros]:
   549   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   550   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   551   unfolding continuous_def by (rule tendsto_diff)
   552 
   553 lemma continuous_on_diff [continuous_intros]:
   554   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   555   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   556   unfolding continuous_on_def by (auto intro: tendsto_diff)
   557 
   558 lemma tendsto_setsum [tendsto_intros]:
   559   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   560   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   561   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   562 proof (cases "finite S")
   563   assume "finite S" thus ?thesis using assms
   564     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   565 next
   566   assume "\<not> finite S" thus ?thesis
   567     by (simp add: tendsto_const)
   568 qed
   569 
   570 lemma continuous_setsum [continuous_intros]:
   571   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   572   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   573   unfolding continuous_def by (rule tendsto_setsum)
   574 
   575 lemma continuous_on_setsum [continuous_intros]:
   576   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   577   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   578   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   579 
   580 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   581 
   582 subsubsection {* Linear operators and multiplication *}
   583 
   584 lemma (in bounded_linear) tendsto:
   585   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   586   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   587 
   588 lemma (in bounded_linear) continuous:
   589   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   590   using tendsto[of g _ F] by (auto simp: continuous_def)
   591 
   592 lemma (in bounded_linear) continuous_on:
   593   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   594   using tendsto[of g] by (auto simp: continuous_on_def)
   595 
   596 lemma (in bounded_linear) tendsto_zero:
   597   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   598   by (drule tendsto, simp only: zero)
   599 
   600 lemma (in bounded_bilinear) tendsto:
   601   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   602   by (simp only: tendsto_Zfun_iff prod_diff_prod
   603                  Zfun_add Zfun Zfun_left Zfun_right)
   604 
   605 lemma (in bounded_bilinear) continuous:
   606   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   607   using tendsto[of f _ F g] by (auto simp: continuous_def)
   608 
   609 lemma (in bounded_bilinear) continuous_on:
   610   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   611   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   612 
   613 lemma (in bounded_bilinear) tendsto_zero:
   614   assumes f: "(f ---> 0) F"
   615   assumes g: "(g ---> 0) F"
   616   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   617   using tendsto [OF f g] by (simp add: zero_left)
   618 
   619 lemma (in bounded_bilinear) tendsto_left_zero:
   620   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   621   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   622 
   623 lemma (in bounded_bilinear) tendsto_right_zero:
   624   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   625   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   626 
   627 lemmas tendsto_of_real [tendsto_intros] =
   628   bounded_linear.tendsto [OF bounded_linear_of_real]
   629 
   630 lemmas tendsto_scaleR [tendsto_intros] =
   631   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   632 
   633 lemmas tendsto_mult [tendsto_intros] =
   634   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   635 
   636 lemmas continuous_of_real [continuous_intros] =
   637   bounded_linear.continuous [OF bounded_linear_of_real]
   638 
   639 lemmas continuous_scaleR [continuous_intros] =
   640   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   641 
   642 lemmas continuous_mult [continuous_intros] =
   643   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   644 
   645 lemmas continuous_on_of_real [continuous_intros] =
   646   bounded_linear.continuous_on [OF bounded_linear_of_real]
   647 
   648 lemmas continuous_on_scaleR [continuous_intros] =
   649   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   650 
   651 lemmas continuous_on_mult [continuous_intros] =
   652   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   653 
   654 lemmas tendsto_mult_zero =
   655   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   656 
   657 lemmas tendsto_mult_left_zero =
   658   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   659 
   660 lemmas tendsto_mult_right_zero =
   661   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   662 
   663 lemma tendsto_power [tendsto_intros]:
   664   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   665   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   666   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   667 
   668 lemma continuous_power [continuous_intros]:
   669   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   670   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   671   unfolding continuous_def by (rule tendsto_power)
   672 
   673 lemma continuous_on_power [continuous_intros]:
   674   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   675   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   676   unfolding continuous_on_def by (auto intro: tendsto_power)
   677 
   678 lemma tendsto_setprod [tendsto_intros]:
   679   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   680   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   681   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   682 proof (cases "finite S")
   683   assume "finite S" thus ?thesis using assms
   684     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   685 next
   686   assume "\<not> finite S" thus ?thesis
   687     by (simp add: tendsto_const)
   688 qed
   689 
   690 lemma continuous_setprod [continuous_intros]:
   691   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   692   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   693   unfolding continuous_def by (rule tendsto_setprod)
   694 
   695 lemma continuous_on_setprod [continuous_intros]:
   696   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   697   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   698   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   699 
   700 subsubsection {* Inverse and division *}
   701 
   702 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   703   assumes f: "Zfun f F"
   704   assumes g: "Bfun g F"
   705   shows "Zfun (\<lambda>x. f x ** g x) F"
   706 proof -
   707   obtain K where K: "0 \<le> K"
   708     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   709     using nonneg_bounded by fast
   710   obtain B where B: "0 < B"
   711     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   712     using g by (rule BfunE)
   713   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   714   using norm_g proof eventually_elim
   715     case (elim x)
   716     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   717       by (rule norm_le)
   718     also have "\<dots> \<le> norm (f x) * B * K"
   719       by (intro mult_mono' order_refl norm_g norm_ge_zero
   720                 mult_nonneg_nonneg K elim)
   721     also have "\<dots> = norm (f x) * (B * K)"
   722       by (rule mult_assoc)
   723     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   724   qed
   725   with f show ?thesis
   726     by (rule Zfun_imp_Zfun)
   727 qed
   728 
   729 lemma (in bounded_bilinear) flip:
   730   "bounded_bilinear (\<lambda>x y. y ** x)"
   731   apply default
   732   apply (rule add_right)
   733   apply (rule add_left)
   734   apply (rule scaleR_right)
   735   apply (rule scaleR_left)
   736   apply (subst mult_commute)
   737   using bounded by fast
   738 
   739 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   740   assumes f: "Bfun f F"
   741   assumes g: "Zfun g F"
   742   shows "Zfun (\<lambda>x. f x ** g x) F"
   743   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   744 
   745 lemma Bfun_inverse_lemma:
   746   fixes x :: "'a::real_normed_div_algebra"
   747   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   748   apply (subst nonzero_norm_inverse, clarsimp)
   749   apply (erule (1) le_imp_inverse_le)
   750   done
   751 
   752 lemma Bfun_inverse:
   753   fixes a :: "'a::real_normed_div_algebra"
   754   assumes f: "(f ---> a) F"
   755   assumes a: "a \<noteq> 0"
   756   shows "Bfun (\<lambda>x. inverse (f x)) F"
   757 proof -
   758   from a have "0 < norm a" by simp
   759   hence "\<exists>r>0. r < norm a" by (rule dense)
   760   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   761   have "eventually (\<lambda>x. dist (f x) a < r) F"
   762     using tendstoD [OF f r1] by fast
   763   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   764   proof eventually_elim
   765     case (elim x)
   766     hence 1: "norm (f x - a) < r"
   767       by (simp add: dist_norm)
   768     hence 2: "f x \<noteq> 0" using r2 by auto
   769     hence "norm (inverse (f x)) = inverse (norm (f x))"
   770       by (rule nonzero_norm_inverse)
   771     also have "\<dots> \<le> inverse (norm a - r)"
   772     proof (rule le_imp_inverse_le)
   773       show "0 < norm a - r" using r2 by simp
   774     next
   775       have "norm a - norm (f x) \<le> norm (a - f x)"
   776         by (rule norm_triangle_ineq2)
   777       also have "\<dots> = norm (f x - a)"
   778         by (rule norm_minus_commute)
   779       also have "\<dots> < r" using 1 .
   780       finally show "norm a - r \<le> norm (f x)" by simp
   781     qed
   782     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   783   qed
   784   thus ?thesis by (rule BfunI)
   785 qed
   786 
   787 lemma tendsto_inverse [tendsto_intros]:
   788   fixes a :: "'a::real_normed_div_algebra"
   789   assumes f: "(f ---> a) F"
   790   assumes a: "a \<noteq> 0"
   791   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   792 proof -
   793   from a have "0 < norm a" by simp
   794   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   795     by (rule tendstoD)
   796   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   797     unfolding dist_norm by (auto elim!: eventually_elim1)
   798   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   799     - (inverse (f x) * (f x - a) * inverse a)) F"
   800     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   801   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   802     by (intro Zfun_minus Zfun_mult_left
   803       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   804       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   805   ultimately show ?thesis
   806     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   807 qed
   808 
   809 lemma continuous_inverse:
   810   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   811   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   812   shows "continuous F (\<lambda>x. inverse (f x))"
   813   using assms unfolding continuous_def by (rule tendsto_inverse)
   814 
   815 lemma continuous_at_within_inverse[continuous_intros]:
   816   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   817   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   818   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   819   using assms unfolding continuous_within by (rule tendsto_inverse)
   820 
   821 lemma isCont_inverse[continuous_intros, simp]:
   822   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   823   assumes "isCont f a" and "f a \<noteq> 0"
   824   shows "isCont (\<lambda>x. inverse (f x)) a"
   825   using assms unfolding continuous_at by (rule tendsto_inverse)
   826 
   827 lemma continuous_on_inverse[continuous_intros]:
   828   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   829   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   830   shows "continuous_on s (\<lambda>x. inverse (f x))"
   831   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   832 
   833 lemma tendsto_divide [tendsto_intros]:
   834   fixes a b :: "'a::real_normed_field"
   835   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   836     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   837   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   838 
   839 lemma continuous_divide:
   840   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   841   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   842   shows "continuous F (\<lambda>x. (f x) / (g x))"
   843   using assms unfolding continuous_def by (rule tendsto_divide)
   844 
   845 lemma continuous_at_within_divide[continuous_intros]:
   846   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   847   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   848   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   849   using assms unfolding continuous_within by (rule tendsto_divide)
   850 
   851 lemma isCont_divide[continuous_intros, simp]:
   852   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   853   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   854   shows "isCont (\<lambda>x. (f x) / g x) a"
   855   using assms unfolding continuous_at by (rule tendsto_divide)
   856 
   857 lemma continuous_on_divide[continuous_intros]:
   858   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   859   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   860   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   861   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   862 
   863 lemma tendsto_sgn [tendsto_intros]:
   864   fixes l :: "'a::real_normed_vector"
   865   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   866   unfolding sgn_div_norm by (simp add: tendsto_intros)
   867 
   868 lemma continuous_sgn:
   869   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   870   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   871   shows "continuous F (\<lambda>x. sgn (f x))"
   872   using assms unfolding continuous_def by (rule tendsto_sgn)
   873 
   874 lemma continuous_at_within_sgn[continuous_intros]:
   875   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   876   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   877   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   878   using assms unfolding continuous_within by (rule tendsto_sgn)
   879 
   880 lemma isCont_sgn[continuous_intros]:
   881   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   882   assumes "isCont f a" and "f a \<noteq> 0"
   883   shows "isCont (\<lambda>x. sgn (f x)) a"
   884   using assms unfolding continuous_at by (rule tendsto_sgn)
   885 
   886 lemma continuous_on_sgn[continuous_intros]:
   887   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   888   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   889   shows "continuous_on s (\<lambda>x. sgn (f x))"
   890   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   891 
   892 lemma filterlim_at_infinity:
   893   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   894   assumes "0 \<le> c"
   895   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   896   unfolding filterlim_iff eventually_at_infinity
   897 proof safe
   898   fix P :: "'a \<Rightarrow> bool" and b
   899   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   900     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   901   have "max b (c + 1) > c" by auto
   902   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   903     by auto
   904   then show "eventually (\<lambda>x. P (f x)) F"
   905   proof eventually_elim
   906     fix x assume "max b (c + 1) \<le> norm (f x)"
   907     with P show "P (f x)" by auto
   908   qed
   909 qed force
   910 
   911 
   912 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   913 
   914 text {*
   915 
   916 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   917 @{term "at_right x"} and also @{term "at_right 0"}.
   918 
   919 *}
   920 
   921 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   922 
   923 lemma filtermap_homeomorph:
   924   assumes f: "continuous (at a) f"
   925   assumes g: "continuous (at (f a)) g"
   926   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   927   shows "filtermap f (nhds a) = nhds (f a)"
   928   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   929 proof safe
   930   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   931   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   932   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   933 next
   934   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   935   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   936   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   937     by (metis UNIV_I)
   938   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   939     by (force intro!: exI[of _ A])
   940 qed
   941 
   942 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   943   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   944 
   945 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   946   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   947 
   948 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   949   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   950 
   951 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   952   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   953 
   954 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   955   using filtermap_at_right_shift[of "-a" 0] by simp
   956 
   957 lemma filterlim_at_right_to_0:
   958   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   959   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   960 
   961 lemma eventually_at_right_to_0:
   962   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   963   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   964 
   965 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   966   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   967 
   968 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   969   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   970 
   971 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   972   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   973 
   974 lemma filterlim_at_left_to_right:
   975   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   976   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   977 
   978 lemma eventually_at_left_to_right:
   979   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   980   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   981 
   982 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   983   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   984   by (metis le_minus_iff minus_minus)
   985 
   986 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   987   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   988 
   989 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   990   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   991 
   992 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   993   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   994 
   995 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   996   unfolding filterlim_at_top eventually_at_bot_dense
   997   by (metis leI minus_less_iff order_less_asym)
   998 
   999 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1000   unfolding filterlim_at_bot eventually_at_top_dense
  1001   by (metis leI less_minus_iff order_less_asym)
  1002 
  1003 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1004   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1005   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1006   by auto
  1007 
  1008 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1009   unfolding filterlim_uminus_at_top by simp
  1010 
  1011 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1012   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1013 proof safe
  1014   fix Z :: real assume [arith]: "0 < Z"
  1015   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1016     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1017   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1018     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1019 qed
  1020 
  1021 lemma filterlim_inverse_at_top:
  1022   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1023   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1024      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1025 
  1026 lemma filterlim_inverse_at_bot_neg:
  1027   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1028   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1029 
  1030 lemma filterlim_inverse_at_bot:
  1031   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1032   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1033   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1034 
  1035 lemma tendsto_inverse_0:
  1036   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1037   shows "(inverse ---> (0::'a)) at_infinity"
  1038   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1039 proof safe
  1040   fix r :: real assume "0 < r"
  1041   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1042   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1043     fix x :: 'a
  1044     from `0 < r` have "0 < inverse (r / 2)" by simp
  1045     also assume *: "inverse (r / 2) \<le> norm x"
  1046     finally show "norm (inverse x) < r"
  1047       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1048   qed
  1049 qed
  1050 
  1051 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1052 proof (rule antisym)
  1053   have "(inverse ---> (0::real)) at_top"
  1054     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1055   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1056     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1057 next
  1058   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1059     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1060   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1061     by (simp add: filtermap_ident filtermap_filtermap)
  1062 qed
  1063 
  1064 lemma eventually_at_right_to_top:
  1065   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1066   unfolding at_right_to_top eventually_filtermap ..
  1067 
  1068 lemma filterlim_at_right_to_top:
  1069   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1070   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1071 
  1072 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1073   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1074 
  1075 lemma eventually_at_top_to_right:
  1076   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1077   unfolding at_top_to_right eventually_filtermap ..
  1078 
  1079 lemma filterlim_at_top_to_right:
  1080   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1081   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1082 
  1083 lemma filterlim_inverse_at_infinity:
  1084   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1085   shows "filterlim inverse at_infinity (at (0::'a))"
  1086   unfolding filterlim_at_infinity[OF order_refl]
  1087 proof safe
  1088   fix r :: real assume "0 < r"
  1089   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1090     unfolding eventually_at norm_inverse
  1091     by (intro exI[of _ "inverse r"])
  1092        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1093 qed
  1094 
  1095 lemma filterlim_inverse_at_iff:
  1096   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1097   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1098   unfolding filterlim_def filtermap_filtermap[symmetric]
  1099 proof
  1100   assume "filtermap g F \<le> at_infinity"
  1101   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1102     by (rule filtermap_mono)
  1103   also have "\<dots> \<le> at 0"
  1104     using tendsto_inverse_0[where 'a='b]
  1105     by (auto intro!: exI[of _ 1]
  1106              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1107   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1108 next
  1109   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1110   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1111     by (rule filtermap_mono)
  1112   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1113     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1114 qed
  1115 
  1116 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1117  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1118 
  1119 text {*
  1120 
  1121 We only show rules for multiplication and addition when the functions are either against a real
  1122 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1123 
  1124 *}
  1125 
  1126 lemma filterlim_tendsto_pos_mult_at_top: 
  1127   assumes f: "(f ---> c) F" and c: "0 < c"
  1128   assumes g: "LIM x F. g x :> at_top"
  1129   shows "LIM x F. (f x * g x :: real) :> at_top"
  1130   unfolding filterlim_at_top_gt[where c=0]
  1131 proof safe
  1132   fix Z :: real assume "0 < Z"
  1133   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1134     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1135              simp: dist_real_def abs_real_def split: split_if_asm)
  1136   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1137     unfolding filterlim_at_top by auto
  1138   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1139   proof eventually_elim
  1140     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1141     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1142       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1143     with `0 < c` show "Z \<le> f x * g x"
  1144        by simp
  1145   qed
  1146 qed
  1147 
  1148 lemma filterlim_at_top_mult_at_top: 
  1149   assumes f: "LIM x F. f x :> at_top"
  1150   assumes g: "LIM x F. g x :> at_top"
  1151   shows "LIM x F. (f x * g x :: real) :> at_top"
  1152   unfolding filterlim_at_top_gt[where c=0]
  1153 proof safe
  1154   fix Z :: real assume "0 < Z"
  1155   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1156     unfolding filterlim_at_top by auto
  1157   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1158     unfolding filterlim_at_top by auto
  1159   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1160   proof eventually_elim
  1161     fix x assume "1 \<le> f x" "Z \<le> g x"
  1162     with `0 < Z` have "1 * Z \<le> f x * g x"
  1163       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1164     then show "Z \<le> f x * g x"
  1165        by simp
  1166   qed
  1167 qed
  1168 
  1169 lemma filterlim_tendsto_pos_mult_at_bot:
  1170   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1171   shows "LIM x F. f x * g x :> at_bot"
  1172   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1173   unfolding filterlim_uminus_at_bot by simp
  1174 
  1175 lemma filterlim_pow_at_top:
  1176   fixes f :: "real \<Rightarrow> real"
  1177   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1178   shows "LIM x F. (f x)^n :: real :> at_top"
  1179 using `0 < n` proof (induct n)
  1180   case (Suc n) with f show ?case
  1181     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1182 qed simp
  1183 
  1184 lemma filterlim_pow_at_bot_even:
  1185   fixes f :: "real \<Rightarrow> real"
  1186   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1187   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1188 
  1189 lemma filterlim_pow_at_bot_odd:
  1190   fixes f :: "real \<Rightarrow> real"
  1191   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1192   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1193 
  1194 lemma filterlim_tendsto_add_at_top: 
  1195   assumes f: "(f ---> c) F"
  1196   assumes g: "LIM x F. g x :> at_top"
  1197   shows "LIM x F. (f x + g x :: real) :> at_top"
  1198   unfolding filterlim_at_top_gt[where c=0]
  1199 proof safe
  1200   fix Z :: real assume "0 < Z"
  1201   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1202     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1203   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1204     unfolding filterlim_at_top by auto
  1205   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1206     by eventually_elim simp
  1207 qed
  1208 
  1209 lemma LIM_at_top_divide:
  1210   fixes f g :: "'a \<Rightarrow> real"
  1211   assumes f: "(f ---> a) F" "0 < a"
  1212   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1213   shows "LIM x F. f x / g x :> at_top"
  1214   unfolding divide_inverse
  1215   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1216 
  1217 lemma filterlim_at_top_add_at_top: 
  1218   assumes f: "LIM x F. f x :> at_top"
  1219   assumes g: "LIM x F. g x :> at_top"
  1220   shows "LIM x F. (f x + g x :: real) :> at_top"
  1221   unfolding filterlim_at_top_gt[where c=0]
  1222 proof safe
  1223   fix Z :: real assume "0 < Z"
  1224   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1225     unfolding filterlim_at_top by auto
  1226   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1227     unfolding filterlim_at_top by auto
  1228   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1229     by eventually_elim simp
  1230 qed
  1231 
  1232 lemma tendsto_divide_0:
  1233   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1234   assumes f: "(f ---> c) F"
  1235   assumes g: "LIM x F. g x :> at_infinity"
  1236   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1237   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1238 
  1239 lemma linear_plus_1_le_power:
  1240   fixes x :: real
  1241   assumes x: "0 \<le> x"
  1242   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1243 proof (induct n)
  1244   case (Suc n)
  1245   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1246     by (simp add: field_simps real_of_nat_Suc x)
  1247   also have "\<dots> \<le> (x + 1)^Suc n"
  1248     using Suc x by (simp add: mult_left_mono)
  1249   finally show ?case .
  1250 qed simp
  1251 
  1252 lemma filterlim_realpow_sequentially_gt1:
  1253   fixes x :: "'a :: real_normed_div_algebra"
  1254   assumes x[arith]: "1 < norm x"
  1255   shows "LIM n sequentially. x ^ n :> at_infinity"
  1256 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1257   fix y :: real assume "0 < y"
  1258   have "0 < norm x - 1" by simp
  1259   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1260   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1261   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1262   also have "\<dots> = norm x ^ N" by simp
  1263   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1264     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1265   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1266     unfolding eventually_sequentially
  1267     by (auto simp: norm_power)
  1268 qed simp
  1269 
  1270 
  1271 subsection {* Limits of Sequences *}
  1272 
  1273 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1274   by simp
  1275 
  1276 lemma LIMSEQ_iff:
  1277   fixes L :: "'a::real_normed_vector"
  1278   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1279 unfolding LIMSEQ_def dist_norm ..
  1280 
  1281 lemma LIMSEQ_I:
  1282   fixes L :: "'a::real_normed_vector"
  1283   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1284 by (simp add: LIMSEQ_iff)
  1285 
  1286 lemma LIMSEQ_D:
  1287   fixes L :: "'a::real_normed_vector"
  1288   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1289 by (simp add: LIMSEQ_iff)
  1290 
  1291 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1292   unfolding tendsto_def eventually_sequentially
  1293   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1294 
  1295 lemma Bseq_inverse_lemma:
  1296   fixes x :: "'a::real_normed_div_algebra"
  1297   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1298 apply (subst nonzero_norm_inverse, clarsimp)
  1299 apply (erule (1) le_imp_inverse_le)
  1300 done
  1301 
  1302 lemma Bseq_inverse:
  1303   fixes a :: "'a::real_normed_div_algebra"
  1304   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1305   by (rule Bfun_inverse)
  1306 
  1307 lemma LIMSEQ_diff_approach_zero:
  1308   fixes L :: "'a::real_normed_vector"
  1309   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1310   by (drule (1) tendsto_add, simp)
  1311 
  1312 lemma LIMSEQ_diff_approach_zero2:
  1313   fixes L :: "'a::real_normed_vector"
  1314   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1315   by (drule (1) tendsto_diff, simp)
  1316 
  1317 text{*An unbounded sequence's inverse tends to 0*}
  1318 
  1319 lemma LIMSEQ_inverse_zero:
  1320   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1321   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1322   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1323   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1324   done
  1325 
  1326 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1327 
  1328 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1329   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1330             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1331 
  1332 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1333 infinity is now easily proved*}
  1334 
  1335 lemma LIMSEQ_inverse_real_of_nat_add:
  1336      "(%n. r + inverse(real(Suc n))) ----> r"
  1337   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1338 
  1339 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1340      "(%n. r + -inverse(real(Suc n))) ----> r"
  1341   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1342   by auto
  1343 
  1344 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1345      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1346   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1347   by auto
  1348 
  1349 subsection {* Convergence on sequences *}
  1350 
  1351 lemma convergent_add:
  1352   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1353   assumes "convergent (\<lambda>n. X n)"
  1354   assumes "convergent (\<lambda>n. Y n)"
  1355   shows "convergent (\<lambda>n. X n + Y n)"
  1356   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1357 
  1358 lemma convergent_setsum:
  1359   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1360   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1361   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1362 proof (cases "finite A")
  1363   case True from this and assms show ?thesis
  1364     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1365 qed (simp add: convergent_const)
  1366 
  1367 lemma (in bounded_linear) convergent:
  1368   assumes "convergent (\<lambda>n. X n)"
  1369   shows "convergent (\<lambda>n. f (X n))"
  1370   using assms unfolding convergent_def by (fast intro: tendsto)
  1371 
  1372 lemma (in bounded_bilinear) convergent:
  1373   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1374   shows "convergent (\<lambda>n. X n ** Y n)"
  1375   using assms unfolding convergent_def by (fast intro: tendsto)
  1376 
  1377 lemma convergent_minus_iff:
  1378   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1379   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1380 apply (simp add: convergent_def)
  1381 apply (auto dest: tendsto_minus)
  1382 apply (drule tendsto_minus, auto)
  1383 done
  1384 
  1385 
  1386 text {* A monotone sequence converges to its least upper bound. *}
  1387 
  1388 lemma LIMSEQ_incseq_SUP:
  1389   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1390   assumes u: "bdd_above (range X)"
  1391   assumes X: "incseq X"
  1392   shows "X ----> (SUP i. X i)"
  1393   by (rule order_tendstoI)
  1394      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1395 
  1396 lemma LIMSEQ_decseq_INF:
  1397   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1398   assumes u: "bdd_below (range X)"
  1399   assumes X: "decseq X"
  1400   shows "X ----> (INF i. X i)"
  1401   by (rule order_tendstoI)
  1402      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1403 
  1404 text{*Main monotonicity theorem*}
  1405 
  1406 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1407   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1408 
  1409 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1410   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1411 
  1412 lemma Cauchy_iff:
  1413   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1414   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1415   unfolding Cauchy_def dist_norm ..
  1416 
  1417 lemma CauchyI:
  1418   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1419   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1420 by (simp add: Cauchy_iff)
  1421 
  1422 lemma CauchyD:
  1423   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1424   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1425 by (simp add: Cauchy_iff)
  1426 
  1427 lemma incseq_convergent:
  1428   fixes X :: "nat \<Rightarrow> real"
  1429   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1430   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1431 proof atomize_elim
  1432   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1433   obtain L where "X ----> L"
  1434     by (auto simp: convergent_def monoseq_def incseq_def)
  1435   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1436     by (auto intro!: exI[of _ L] incseq_le)
  1437 qed
  1438 
  1439 lemma decseq_convergent:
  1440   fixes X :: "nat \<Rightarrow> real"
  1441   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1442   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1443 proof atomize_elim
  1444   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1445   obtain L where "X ----> L"
  1446     by (auto simp: convergent_def monoseq_def decseq_def)
  1447   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1448     by (auto intro!: exI[of _ L] decseq_le)
  1449 qed
  1450 
  1451 subsubsection {* Cauchy Sequences are Bounded *}
  1452 
  1453 text{*A Cauchy sequence is bounded -- this is the standard
  1454   proof mechanization rather than the nonstandard proof*}
  1455 
  1456 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1457           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1458 apply (clarify, drule spec, drule (1) mp)
  1459 apply (simp only: norm_minus_commute)
  1460 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1461 apply simp
  1462 done
  1463 
  1464 subsection {* Power Sequences *}
  1465 
  1466 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1467 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1468   also fact that bounded and monotonic sequence converges.*}
  1469 
  1470 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1471 apply (simp add: Bseq_def)
  1472 apply (rule_tac x = 1 in exI)
  1473 apply (simp add: power_abs)
  1474 apply (auto dest: power_mono)
  1475 done
  1476 
  1477 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1478 apply (clarify intro!: mono_SucI2)
  1479 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1480 done
  1481 
  1482 lemma convergent_realpow:
  1483   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1484 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1485 
  1486 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1487   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1488 
  1489 lemma LIMSEQ_realpow_zero:
  1490   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1491 proof cases
  1492   assume "0 \<le> x" and "x \<noteq> 0"
  1493   hence x0: "0 < x" by simp
  1494   assume x1: "x < 1"
  1495   from x0 x1 have "1 < inverse x"
  1496     by (rule one_less_inverse)
  1497   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1498     by (rule LIMSEQ_inverse_realpow_zero)
  1499   thus ?thesis by (simp add: power_inverse)
  1500 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1501 
  1502 lemma LIMSEQ_power_zero:
  1503   fixes x :: "'a::{real_normed_algebra_1}"
  1504   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1505 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1506 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1507 apply (simp add: power_abs norm_power_ineq)
  1508 done
  1509 
  1510 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1511   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1512 
  1513 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1514 
  1515 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1516   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1517 
  1518 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1519   by (rule LIMSEQ_power_zero) simp
  1520 
  1521 
  1522 subsection {* Limits of Functions *}
  1523 
  1524 lemma LIM_eq:
  1525   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1526   shows "f -- a --> L =
  1527      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1528 by (simp add: LIM_def dist_norm)
  1529 
  1530 lemma LIM_I:
  1531   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1532   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1533       ==> f -- a --> L"
  1534 by (simp add: LIM_eq)
  1535 
  1536 lemma LIM_D:
  1537   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1538   shows "[| f -- a --> L; 0<r |]
  1539       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1540 by (simp add: LIM_eq)
  1541 
  1542 lemma LIM_offset:
  1543   fixes a :: "'a::real_normed_vector"
  1544   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1545   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1546 
  1547 lemma LIM_offset_zero:
  1548   fixes a :: "'a::real_normed_vector"
  1549   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1550 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1551 
  1552 lemma LIM_offset_zero_cancel:
  1553   fixes a :: "'a::real_normed_vector"
  1554   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1555 by (drule_tac k="- a" in LIM_offset, simp)
  1556 
  1557 lemma LIM_offset_zero_iff:
  1558   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1559   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1560   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1561 
  1562 lemma LIM_zero:
  1563   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1564   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1565 unfolding tendsto_iff dist_norm by simp
  1566 
  1567 lemma LIM_zero_cancel:
  1568   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1569   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1570 unfolding tendsto_iff dist_norm by simp
  1571 
  1572 lemma LIM_zero_iff:
  1573   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1574   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1575 unfolding tendsto_iff dist_norm by simp
  1576 
  1577 lemma LIM_imp_LIM:
  1578   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1579   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1580   assumes f: "f -- a --> l"
  1581   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1582   shows "g -- a --> m"
  1583   by (rule metric_LIM_imp_LIM [OF f],
  1584     simp add: dist_norm le)
  1585 
  1586 lemma LIM_equal2:
  1587   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1588   assumes 1: "0 < R"
  1589   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1590   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1591 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1592 
  1593 lemma LIM_compose2:
  1594   fixes a :: "'a::real_normed_vector"
  1595   assumes f: "f -- a --> b"
  1596   assumes g: "g -- b --> c"
  1597   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1598   shows "(\<lambda>x. g (f x)) -- a --> c"
  1599 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1600 
  1601 lemma real_LIM_sandwich_zero:
  1602   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1603   assumes f: "f -- a --> 0"
  1604   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1605   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1606   shows "g -- a --> 0"
  1607 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1608   fix x assume x: "x \<noteq> a"
  1609   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1610   also have "g x \<le> f x" by (rule 2 [OF x])
  1611   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1612   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1613   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1614 qed
  1615 
  1616 
  1617 subsection {* Continuity *}
  1618 
  1619 lemma LIM_isCont_iff:
  1620   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1621   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1622 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1623 
  1624 lemma isCont_iff:
  1625   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1626   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1627 by (simp add: isCont_def LIM_isCont_iff)
  1628 
  1629 lemma isCont_LIM_compose2:
  1630   fixes a :: "'a::real_normed_vector"
  1631   assumes f [unfolded isCont_def]: "isCont f a"
  1632   assumes g: "g -- f a --> l"
  1633   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1634   shows "(\<lambda>x. g (f x)) -- a --> l"
  1635 by (rule LIM_compose2 [OF f g inj])
  1636 
  1637 
  1638 lemma isCont_norm [simp]:
  1639   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1640   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1641   by (fact continuous_norm)
  1642 
  1643 lemma isCont_rabs [simp]:
  1644   fixes f :: "'a::t2_space \<Rightarrow> real"
  1645   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1646   by (fact continuous_rabs)
  1647 
  1648 lemma isCont_add [simp]:
  1649   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1650   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1651   by (fact continuous_add)
  1652 
  1653 lemma isCont_minus [simp]:
  1654   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1655   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1656   by (fact continuous_minus)
  1657 
  1658 lemma isCont_diff [simp]:
  1659   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1660   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1661   by (fact continuous_diff)
  1662 
  1663 lemma isCont_mult [simp]:
  1664   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1665   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1666   by (fact continuous_mult)
  1667 
  1668 lemma (in bounded_linear) isCont:
  1669   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1670   by (fact continuous)
  1671 
  1672 lemma (in bounded_bilinear) isCont:
  1673   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1674   by (fact continuous)
  1675 
  1676 lemmas isCont_scaleR [simp] = 
  1677   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1678 
  1679 lemmas isCont_of_real [simp] =
  1680   bounded_linear.isCont [OF bounded_linear_of_real]
  1681 
  1682 lemma isCont_power [simp]:
  1683   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1684   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1685   by (fact continuous_power)
  1686 
  1687 lemma isCont_setsum [simp]:
  1688   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1689   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1690   by (auto intro: continuous_setsum)
  1691 
  1692 subsection {* Uniform Continuity *}
  1693 
  1694 definition
  1695   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1696   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1697 
  1698 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1699 by (simp add: isUCont_def isCont_def LIM_def, force)
  1700 
  1701 lemma isUCont_Cauchy:
  1702   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1703 unfolding isUCont_def
  1704 apply (rule metric_CauchyI)
  1705 apply (drule_tac x=e in spec, safe)
  1706 apply (drule_tac e=s in metric_CauchyD, safe)
  1707 apply (rule_tac x=M in exI, simp)
  1708 done
  1709 
  1710 lemma (in bounded_linear) isUCont: "isUCont f"
  1711 unfolding isUCont_def dist_norm
  1712 proof (intro allI impI)
  1713   fix r::real assume r: "0 < r"
  1714   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1715     using pos_bounded by fast
  1716   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1717   proof (rule exI, safe)
  1718     from r K show "0 < r / K" by simp
  1719   next
  1720     fix x y :: 'a
  1721     assume xy: "norm (x - y) < r / K"
  1722     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1723     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1724     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1725     finally show "norm (f x - f y) < r" .
  1726   qed
  1727 qed
  1728 
  1729 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1730 by (rule isUCont [THEN isUCont_Cauchy])
  1731 
  1732 lemma LIM_less_bound: 
  1733   fixes f :: "real \<Rightarrow> real"
  1734   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1735   shows "0 \<le> f x"
  1736 proof (rule tendsto_le_const)
  1737   show "(f ---> f x) (at_left x)"
  1738     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1739   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1740     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1741 qed simp
  1742 
  1743 
  1744 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1745 
  1746 lemma nested_sequence_unique:
  1747   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1748   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1749 proof -
  1750   have "incseq f" unfolding incseq_Suc_iff by fact
  1751   have "decseq g" unfolding decseq_Suc_iff by fact
  1752 
  1753   { fix n
  1754     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1755     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1756   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1757     using incseq_convergent[OF `incseq f`] by auto
  1758   moreover
  1759   { fix n
  1760     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1761     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1762   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1763     using decseq_convergent[OF `decseq g`] by auto
  1764   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1765   ultimately show ?thesis by auto
  1766 qed
  1767 
  1768 lemma Bolzano[consumes 1, case_names trans local]:
  1769   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1770   assumes [arith]: "a \<le> b"
  1771   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1772   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1773   shows "P a b"
  1774 proof -
  1775   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1776   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1777   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1778     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1779     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1780 
  1781   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1782 
  1783   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1784   proof (safe intro!: nested_sequence_unique)
  1785     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1786   next
  1787     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1788     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1789   qed fact
  1790   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1791   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1792     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1793 
  1794   show "P a b"
  1795   proof (rule ccontr)
  1796     assume "\<not> P a b" 
  1797     { fix n have "\<not> P (l n) (u n)"
  1798       proof (induct n)
  1799         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1800       qed (simp add: `\<not> P a b`) }
  1801     moreover
  1802     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1803         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1804       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1805         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1806       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1807       proof eventually_elim
  1808         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1809         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1810         with x show "P (l n) (u n)" by (rule d)
  1811       qed }
  1812     ultimately show False by simp
  1813   qed
  1814 qed
  1815 
  1816 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1817 proof (cases "a \<le> b", rule compactI)
  1818   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1819   def T == "{a .. b}"
  1820   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1821   proof (induct rule: Bolzano)
  1822     case (trans a b c)
  1823     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1824     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1825       by (auto simp: *)
  1826     with trans show ?case
  1827       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1828   next
  1829     case (local x)
  1830     then have "x \<in> \<Union>C" using C by auto
  1831     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1832     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1833       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1834     with `c \<in> C` show ?case
  1835       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1836   qed
  1837 qed simp
  1838 
  1839 
  1840 subsection {* Boundedness of continuous functions *}
  1841 
  1842 text{*By bisection, function continuous on closed interval is bounded above*}
  1843 
  1844 lemma isCont_eq_Ub:
  1845   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1846   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1847     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1848   using continuous_attains_sup[of "{a .. b}" f]
  1849   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1850 
  1851 lemma isCont_eq_Lb:
  1852   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1853   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1854     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1855   using continuous_attains_inf[of "{a .. b}" f]
  1856   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1857 
  1858 lemma isCont_bounded:
  1859   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1860   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1861   using isCont_eq_Ub[of a b f] by auto
  1862 
  1863 lemma isCont_has_Ub:
  1864   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1865   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1866     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1867   using isCont_eq_Ub[of a b f] by auto
  1868 
  1869 (*HOL style here: object-level formulations*)
  1870 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1871       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1872       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1873   by (blast intro: IVT)
  1874 
  1875 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1876       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1877       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1878   by (blast intro: IVT2)
  1879 
  1880 lemma isCont_Lb_Ub:
  1881   fixes f :: "real \<Rightarrow> real"
  1882   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1883   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1884                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1885 proof -
  1886   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1887     using isCont_eq_Ub[OF assms] by auto
  1888   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1889     using isCont_eq_Lb[OF assms] by auto
  1890   show ?thesis
  1891     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1892     apply (rule_tac x="f L" in exI)
  1893     apply (rule_tac x="f M" in exI)
  1894     apply (cases "L \<le> M")
  1895     apply (simp, metis order_trans)
  1896     apply (simp, metis order_trans)
  1897     done
  1898 qed
  1899 
  1900 
  1901 text{*Continuity of inverse function*}
  1902 
  1903 lemma isCont_inverse_function:
  1904   fixes f g :: "real \<Rightarrow> real"
  1905   assumes d: "0 < d"
  1906       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1907       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1908   shows "isCont g (f x)"
  1909 proof -
  1910   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1911 
  1912   have f: "continuous_on ?D f"
  1913     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1914   then have g: "continuous_on (f`?D) g"
  1915     using inj by (intro continuous_on_inv) auto
  1916 
  1917   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1918     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1919   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1920     by (rule continuous_on_subset)
  1921   moreover
  1922   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1923     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1924   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1925     by auto
  1926   ultimately
  1927   show ?thesis
  1928     by (simp add: continuous_on_eq_continuous_at)
  1929 qed
  1930 
  1931 lemma isCont_inverse_function2:
  1932   fixes f g :: "real \<Rightarrow> real" shows
  1933   "\<lbrakk>a < x; x < b;
  1934     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1935     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1936    \<Longrightarrow> isCont g (f x)"
  1937 apply (rule isCont_inverse_function
  1938        [where f=f and d="min (x - a) (b - x)"])
  1939 apply (simp_all add: abs_le_iff)
  1940 done
  1941 
  1942 (* need to rename second isCont_inverse *)
  1943 
  1944 lemma isCont_inv_fun:
  1945   fixes f g :: "real \<Rightarrow> real"
  1946   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1947          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1948       ==> isCont g (f x)"
  1949 by (rule isCont_inverse_function)
  1950 
  1951 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1952 lemma LIM_fun_gt_zero:
  1953   fixes f :: "real \<Rightarrow> real"
  1954   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1955 apply (drule (1) LIM_D, clarify)
  1956 apply (rule_tac x = s in exI)
  1957 apply (simp add: abs_less_iff)
  1958 done
  1959 
  1960 lemma LIM_fun_less_zero:
  1961   fixes f :: "real \<Rightarrow> real"
  1962   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1963 apply (drule LIM_D [where r="-l"], simp, clarify)
  1964 apply (rule_tac x = s in exI)
  1965 apply (simp add: abs_less_iff)
  1966 done
  1967 
  1968 lemma LIM_fun_not_zero:
  1969   fixes f :: "real \<Rightarrow> real"
  1970   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1971   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1972 
  1973 end
  1974