src/HOL/Rat.thy
author hoelzl
Wed Jun 18 07:31:12 2014 +0200 (2014-06-18)
changeset 57275 0ddb5b755cdc
parent 57136 653e56c6c963
child 57512 cc97b347b301
permissions -rw-r--r--
moved lemmas from the proof of the Central Limit Theorem by Jeremy Avigad and Luke Serafin
     1 (*  Title:  HOL/Rat.thy
     2     Author: Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* Rational numbers *}
     6 
     7 theory Rat
     8 imports GCD Archimedean_Field
     9 begin
    10 
    11 subsection {* Rational numbers as quotient *}
    12 
    13 subsubsection {* Construction of the type of rational numbers *}
    14 
    15 definition
    16   ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool" where
    17   "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    18 
    19 lemma ratrel_iff [simp]:
    20   "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    21   by (simp add: ratrel_def)
    22 
    23 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    24   by (auto intro!: one_neq_zero)
    25 
    26 lemma symp_ratrel: "symp ratrel"
    27   by (simp add: ratrel_def symp_def)
    28 
    29 lemma transp_ratrel: "transp ratrel"
    30 proof (rule transpI, unfold split_paired_all)
    31   fix a b a' b' a'' b'' :: int
    32   assume A: "ratrel (a, b) (a', b')"
    33   assume B: "ratrel (a', b') (a'', b'')"
    34   have "b' * (a * b'') = b'' * (a * b')" by simp
    35   also from A have "a * b' = a' * b" by auto
    36   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    37   also from B have "a' * b'' = a'' * b'" by auto
    38   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    39   finally have "b' * (a * b'') = b' * (a'' * b)" .
    40   moreover from B have "b' \<noteq> 0" by auto
    41   ultimately have "a * b'' = a'' * b" by simp
    42   with A B show "ratrel (a, b) (a'', b'')" by auto
    43 qed
    44 
    45 lemma part_equivp_ratrel: "part_equivp ratrel"
    46   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    47 
    48 quotient_type rat = "int \<times> int" / partial: "ratrel"
    49   morphisms Rep_Rat Abs_Rat
    50   by (rule part_equivp_ratrel)
    51 
    52 lemma Domainp_cr_rat [transfer_domain_rule]: "Domainp pcr_rat = (\<lambda>x. snd x \<noteq> 0)"
    53 by (simp add: rat.domain_eq)
    54 
    55 subsubsection {* Representation and basic operations *}
    56 
    57 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    58   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    59   by simp
    60 
    61 lemma eq_rat:
    62   shows "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    63   and "\<And>a. Fract a 0 = Fract 0 1"
    64   and "\<And>a c. Fract 0 a = Fract 0 c"
    65   by (transfer, simp)+
    66 
    67 lemma Rat_cases [case_names Fract, cases type: rat]:
    68   assumes "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    69   shows C
    70 proof -
    71   obtain a b :: int where "q = Fract a b" and "b \<noteq> 0"
    72     by transfer simp
    73   let ?a = "a div gcd a b"
    74   let ?b = "b div gcd a b"
    75   from `b \<noteq> 0` have "?b * gcd a b = b"
    76     by (simp add: dvd_div_mult_self)
    77   with `b \<noteq> 0` have "?b \<noteq> 0" by auto
    78   from `q = Fract a b` `b \<noteq> 0` `?b \<noteq> 0` have q: "q = Fract ?a ?b"
    79     by (simp add: eq_rat dvd_div_mult mult_commute [of a])
    80   from `b \<noteq> 0` have coprime: "coprime ?a ?b"
    81     by (auto intro: div_gcd_coprime_int)
    82   show C proof (cases "b > 0")
    83     case True
    84     note assms
    85     moreover note q
    86     moreover from True have "?b > 0" by (simp add: nonneg1_imp_zdiv_pos_iff)
    87     moreover note coprime
    88     ultimately show C .
    89   next
    90     case False
    91     note assms
    92     moreover have "q = Fract (- ?a) (- ?b)" unfolding q by transfer simp
    93     moreover from False `b \<noteq> 0` have "- ?b > 0" by (simp add: pos_imp_zdiv_neg_iff)
    94     moreover from coprime have "coprime (- ?a) (- ?b)" by simp
    95     ultimately show C .
    96   qed
    97 qed
    98 
    99 lemma Rat_induct [case_names Fract, induct type: rat]:
   100   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   101   shows "P q"
   102   using assms by (cases q) simp
   103 
   104 instantiation rat :: field_inverse_zero
   105 begin
   106 
   107 lift_definition zero_rat :: "rat" is "(0, 1)"
   108   by simp
   109 
   110 lift_definition one_rat :: "rat" is "(1, 1)"
   111   by simp
   112 
   113 lemma Zero_rat_def: "0 = Fract 0 1"
   114   by transfer simp
   115 
   116 lemma One_rat_def: "1 = Fract 1 1"
   117   by transfer simp
   118 
   119 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   120   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   121   by (clarsimp, simp add: distrib_right, simp add: mult_ac)
   122 
   123 lemma add_rat [simp]:
   124   assumes "b \<noteq> 0" and "d \<noteq> 0"
   125   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   126   using assms by transfer simp
   127 
   128 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   129   by simp
   130 
   131 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   132   by transfer simp
   133 
   134 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   135   by (cases "b = 0") (simp_all add: eq_rat)
   136 
   137 definition
   138   diff_rat_def: "q - r = q + - (r::rat)"
   139 
   140 lemma diff_rat [simp]:
   141   assumes "b \<noteq> 0" and "d \<noteq> 0"
   142   shows "Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   143   using assms by (simp add: diff_rat_def)
   144 
   145 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   146   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   147   by (simp add: mult_ac)
   148 
   149 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   150   by transfer simp
   151 
   152 lemma mult_rat_cancel:
   153   assumes "c \<noteq> 0"
   154   shows "Fract (c * a) (c * b) = Fract a b"
   155   using assms by transfer simp
   156 
   157 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   158   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   159   by (auto simp add: mult_commute)
   160 
   161 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   162   by transfer simp
   163 
   164 definition
   165   divide_rat_def: "q / r = q * inverse (r::rat)"
   166 
   167 lemma divide_rat [simp]: "Fract a b / Fract c d = Fract (a * d) (b * c)"
   168   by (simp add: divide_rat_def)
   169 
   170 instance proof
   171   fix q r s :: rat
   172   show "(q * r) * s = q * (r * s)"
   173     by transfer simp
   174   show "q * r = r * q"
   175     by transfer simp
   176   show "1 * q = q"
   177     by transfer simp
   178   show "(q + r) + s = q + (r + s)"
   179     by transfer (simp add: algebra_simps)
   180   show "q + r = r + q"
   181     by transfer simp
   182   show "0 + q = q"
   183     by transfer simp
   184   show "- q + q = 0"
   185     by transfer simp
   186   show "q - r = q + - r"
   187     by (fact diff_rat_def)
   188   show "(q + r) * s = q * s + r * s"
   189     by transfer (simp add: algebra_simps)
   190   show "(0::rat) \<noteq> 1"
   191     by transfer simp
   192   { assume "q \<noteq> 0" thus "inverse q * q = 1"
   193     by transfer simp }
   194   show "q / r = q * inverse r"
   195     by (fact divide_rat_def)
   196   show "inverse 0 = (0::rat)"
   197     by transfer simp
   198 qed
   199 
   200 end
   201 
   202 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   203   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   204 
   205 lemma of_int_rat: "of_int k = Fract k 1"
   206   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   207 
   208 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   209   by (rule of_nat_rat [symmetric])
   210 
   211 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   212   by (rule of_int_rat [symmetric])
   213 
   214 lemma rat_number_collapse:
   215   "Fract 0 k = 0"
   216   "Fract 1 1 = 1"
   217   "Fract (numeral w) 1 = numeral w"
   218   "Fract (- numeral w) 1 = - numeral w"
   219   "Fract (- 1) 1 = - 1"
   220   "Fract k 0 = 0"
   221   using Fract_of_int_eq [of "numeral w"]
   222   using Fract_of_int_eq [of "- numeral w"]
   223   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   224 
   225 lemma rat_number_expand:
   226   "0 = Fract 0 1"
   227   "1 = Fract 1 1"
   228   "numeral k = Fract (numeral k) 1"
   229   "- 1 = Fract (- 1) 1"
   230   "- numeral k = Fract (- numeral k) 1"
   231   by (simp_all add: rat_number_collapse)
   232 
   233 lemma Rat_cases_nonzero [case_names Fract 0]:
   234   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   235   assumes 0: "q = 0 \<Longrightarrow> C"
   236   shows C
   237 proof (cases "q = 0")
   238   case True then show C using 0 by auto
   239 next
   240   case False
   241   then obtain a b where "q = Fract a b" and "b > 0" and "coprime a b" by (cases q) auto
   242   with False have "0 \<noteq> Fract a b" by simp
   243   with `b > 0` have "a \<noteq> 0" by (simp add: Zero_rat_def eq_rat)
   244   with Fract `q = Fract a b` `b > 0` `coprime a b` show C by blast
   245 qed
   246 
   247 subsubsection {* Function @{text normalize} *}
   248 
   249 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   250 proof (cases "b = 0")
   251   case True then show ?thesis by (simp add: eq_rat)
   252 next
   253   case False
   254   moreover have "b div gcd a b * gcd a b = b"
   255     by (rule dvd_div_mult_self) simp
   256   ultimately have "b div gcd a b \<noteq> 0" by auto
   257   with False show ?thesis by (simp add: eq_rat dvd_div_mult mult_commute [of a])
   258 qed
   259 
   260 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int" where
   261   "normalize p = (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   262     else if snd p = 0 then (0, 1)
   263     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   264 
   265 lemma normalize_crossproduct:
   266   assumes "q \<noteq> 0" "s \<noteq> 0"
   267   assumes "normalize (p, q) = normalize (r, s)"
   268   shows "p * s = r * q"
   269 proof -
   270   have aux: "p * gcd r s = sgn (q * s) * r * gcd p q \<Longrightarrow> q * gcd r s = sgn (q * s) * s * gcd p q \<Longrightarrow> p * s = q * r"
   271   proof -
   272     assume "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   273     then have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) = (q * gcd r s) * (sgn (q * s) * r * gcd p q)" by simp
   274     with assms show "p * s = q * r" by (auto simp add: mult_ac sgn_times sgn_0_0)
   275   qed
   276   from assms show ?thesis
   277     by (auto simp add: normalize_def Let_def dvd_div_div_eq_mult mult_commute sgn_times split: if_splits intro: aux)
   278 qed
   279 
   280 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   281   by (auto simp add: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   282     split:split_if_asm)
   283 
   284 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   285   by (auto simp add: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   286     split:split_if_asm)
   287 
   288 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   289   by (auto simp add: normalize_def Let_def dvd_div_neg div_gcd_coprime_int
   290     split:split_if_asm)
   291 
   292 lemma normalize_stable [simp]:
   293   "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   294   by (simp add: normalize_def)
   295 
   296 lemma normalize_denom_zero [simp]:
   297   "normalize (p, 0) = (0, 1)"
   298   by (simp add: normalize_def)
   299 
   300 lemma normalize_negative [simp]:
   301   "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   302   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   303 
   304 text{*
   305   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   306 *}
   307 
   308 definition quotient_of :: "rat \<Rightarrow> int \<times> int" where
   309   "quotient_of x = (THE pair. x = Fract (fst pair) (snd pair) &
   310                    snd pair > 0 & coprime (fst pair) (snd pair))"
   311 
   312 lemma quotient_of_unique:
   313   "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   314 proof (cases r)
   315   case (Fract a b)
   316   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and> snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))" by auto
   317   then show ?thesis proof (rule ex1I)
   318     fix p
   319     obtain c d :: int where p: "p = (c, d)" by (cases p)
   320     assume "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   321     with p have Fract': "r = Fract c d" "d > 0" "coprime c d" by simp_all
   322     have "c = a \<and> d = b"
   323     proof (cases "a = 0")
   324       case True with Fract Fract' show ?thesis by (simp add: eq_rat)
   325     next
   326       case False
   327       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0" by (auto simp add: eq_rat)
   328       then have "c * b > 0 \<longleftrightarrow> a * d > 0" by auto
   329       with `b > 0` `d > 0` have "a > 0 \<longleftrightarrow> c > 0" by (simp add: zero_less_mult_iff)
   330       with `a \<noteq> 0` `c \<noteq> 0` have sgn: "sgn a = sgn c" by (auto simp add: not_less)
   331       from `coprime a b` `coprime c d` have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   332         by (simp add: coprime_crossproduct_int)
   333       with `b > 0` `d > 0` have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b" by simp
   334       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b" by (simp add: abs_sgn)
   335       with sgn * show ?thesis by (auto simp add: sgn_0_0)
   336     qed
   337     with p show "p = (a, b)" by simp
   338   qed
   339 qed
   340 
   341 lemma quotient_of_Fract [code]:
   342   "quotient_of (Fract a b) = normalize (a, b)"
   343 proof -
   344   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   345     by (rule sym) (auto intro: normalize_eq)
   346   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos)
   347     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   348   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   349     by (rule normalize_coprime) simp
   350   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   351   with quotient_of_unique have
   352     "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and> coprime (fst p) (snd p)) = normalize (a, b)"
   353     by (rule the1_equality)
   354   then show ?thesis by (simp add: quotient_of_def)
   355 qed
   356 
   357 lemma quotient_of_number [simp]:
   358   "quotient_of 0 = (0, 1)"
   359   "quotient_of 1 = (1, 1)"
   360   "quotient_of (numeral k) = (numeral k, 1)"
   361   "quotient_of (- 1) = (- 1, 1)"
   362   "quotient_of (- numeral k) = (- numeral k, 1)"
   363   by (simp_all add: rat_number_expand quotient_of_Fract)
   364 
   365 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   366   by (simp add: quotient_of_Fract normalize_eq)
   367 
   368 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   369   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   370 
   371 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   372   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   373 
   374 lemma quotient_of_inject:
   375   assumes "quotient_of a = quotient_of b"
   376   shows "a = b"
   377 proof -
   378   obtain p q r s where a: "a = Fract p q"
   379     and b: "b = Fract r s"
   380     and "q > 0" and "s > 0" by (cases a, cases b)
   381   with assms show ?thesis by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   382 qed
   383 
   384 lemma quotient_of_inject_eq:
   385   "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   386   by (auto simp add: quotient_of_inject)
   387 
   388 
   389 subsubsection {* Various *}
   390 
   391 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   392   by (simp add: Fract_of_int_eq [symmetric])
   393 
   394 lemma Fract_add_one: "n \<noteq> 0 ==> Fract (m + n) n = Fract m n + 1"
   395   by (simp add: rat_number_expand)
   396 
   397 lemma quotient_of_div:
   398   assumes r: "quotient_of r = (n,d)"
   399   shows "r = of_int n / of_int d"
   400 proof -
   401   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   402   have "r = Fract n d" by simp
   403   thus ?thesis using Fract_of_int_quotient by simp
   404 qed
   405 
   406 subsubsection {* The ordered field of rational numbers *}
   407 
   408 lift_definition positive :: "rat \<Rightarrow> bool"
   409   is "\<lambda>x. 0 < fst x * snd x"
   410 proof (clarsimp)
   411   fix a b c d :: int
   412   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   413   hence "a * d * b * d = c * b * b * d"
   414     by simp
   415   hence "a * b * d\<^sup>2 = c * d * b\<^sup>2"
   416     unfolding power2_eq_square by (simp add: mult_ac)
   417   hence "0 < a * b * d\<^sup>2 \<longleftrightarrow> 0 < c * d * b\<^sup>2"
   418     by simp
   419   thus "0 < a * b \<longleftrightarrow> 0 < c * d"
   420     using `b \<noteq> 0` and `d \<noteq> 0`
   421     by (simp add: zero_less_mult_iff)
   422 qed
   423 
   424 lemma positive_zero: "\<not> positive 0"
   425   by transfer simp
   426 
   427 lemma positive_add:
   428   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   429 apply transfer
   430 apply (simp add: zero_less_mult_iff)
   431 apply (elim disjE, simp_all add: add_pos_pos add_neg_neg
   432   mult_pos_neg mult_neg_pos mult_neg_neg)
   433 done
   434 
   435 lemma positive_mult:
   436   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   437 by transfer (drule (1) mult_pos_pos, simp add: mult_ac)
   438 
   439 lemma positive_minus:
   440   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   441 by transfer (force simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   442 
   443 instantiation rat :: linordered_field_inverse_zero
   444 begin
   445 
   446 definition
   447   "x < y \<longleftrightarrow> positive (y - x)"
   448 
   449 definition
   450   "x \<le> (y::rat) \<longleftrightarrow> x < y \<or> x = y"
   451 
   452 definition
   453   "abs (a::rat) = (if a < 0 then - a else a)"
   454 
   455 definition
   456   "sgn (a::rat) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   457 
   458 instance proof
   459   fix a b c :: rat
   460   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   461     by (rule abs_rat_def)
   462   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   463     unfolding less_eq_rat_def less_rat_def
   464     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   465   show "a \<le> a"
   466     unfolding less_eq_rat_def by simp
   467   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   468     unfolding less_eq_rat_def less_rat_def
   469     by (auto, drule (1) positive_add, simp add: algebra_simps)
   470   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   471     unfolding less_eq_rat_def less_rat_def
   472     by (auto, drule (1) positive_add, simp add: positive_zero)
   473   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   474     unfolding less_eq_rat_def less_rat_def by auto
   475   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   476     by (rule sgn_rat_def)
   477   show "a \<le> b \<or> b \<le> a"
   478     unfolding less_eq_rat_def less_rat_def
   479     by (auto dest!: positive_minus)
   480   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   481     unfolding less_rat_def
   482     by (drule (1) positive_mult, simp add: algebra_simps)
   483 qed
   484 
   485 end
   486 
   487 instantiation rat :: distrib_lattice
   488 begin
   489 
   490 definition
   491   "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   492 
   493 definition
   494   "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   495 
   496 instance proof
   497 qed (auto simp add: inf_rat_def sup_rat_def max_min_distrib2)
   498 
   499 end
   500 
   501 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   502   by transfer simp
   503 
   504 lemma less_rat [simp]:
   505   assumes "b \<noteq> 0" and "d \<noteq> 0"
   506   shows "Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   507   using assms unfolding less_rat_def
   508   by (simp add: positive_rat algebra_simps)
   509 
   510 lemma le_rat [simp]:
   511   assumes "b \<noteq> 0" and "d \<noteq> 0"
   512   shows "Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   513   using assms unfolding le_less by (simp add: eq_rat)
   514 
   515 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   516   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   517 
   518 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   519   unfolding Fract_of_int_eq
   520   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   521     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   522 
   523 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   524   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   525   shows "P q"
   526 proof (cases q)
   527   have step': "\<And>a b. b < 0 \<Longrightarrow> P (Fract a b)"
   528   proof -
   529     fix a::int and b::int
   530     assume b: "b < 0"
   531     hence "0 < -b" by simp
   532     hence "P (Fract (-a) (-b))" by (rule step)
   533     thus "P (Fract a b)" by (simp add: order_less_imp_not_eq [OF b])
   534   qed
   535   case (Fract a b)
   536   thus "P q" by (force simp add: linorder_neq_iff step step')
   537 qed
   538 
   539 lemma zero_less_Fract_iff:
   540   "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   541   by (simp add: Zero_rat_def zero_less_mult_iff)
   542 
   543 lemma Fract_less_zero_iff:
   544   "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   545   by (simp add: Zero_rat_def mult_less_0_iff)
   546 
   547 lemma zero_le_Fract_iff:
   548   "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   549   by (simp add: Zero_rat_def zero_le_mult_iff)
   550 
   551 lemma Fract_le_zero_iff:
   552   "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   553   by (simp add: Zero_rat_def mult_le_0_iff)
   554 
   555 lemma one_less_Fract_iff:
   556   "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   557   by (simp add: One_rat_def mult_less_cancel_right_disj)
   558 
   559 lemma Fract_less_one_iff:
   560   "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   561   by (simp add: One_rat_def mult_less_cancel_right_disj)
   562 
   563 lemma one_le_Fract_iff:
   564   "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   565   by (simp add: One_rat_def mult_le_cancel_right)
   566 
   567 lemma Fract_le_one_iff:
   568   "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   569   by (simp add: One_rat_def mult_le_cancel_right)
   570 
   571 
   572 subsubsection {* Rationals are an Archimedean field *}
   573 
   574 lemma rat_floor_lemma:
   575   shows "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   576 proof -
   577   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   578     by (cases "b = 0", simp, simp add: of_int_rat)
   579   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   580     unfolding Fract_of_int_quotient
   581     by (rule linorder_cases [of b 0]) (simp_all add: divide_nonpos_neg)
   582   ultimately show ?thesis by simp
   583 qed
   584 
   585 instance rat :: archimedean_field
   586 proof
   587   fix r :: rat
   588   show "\<exists>z. r \<le> of_int z"
   589   proof (induct r)
   590     case (Fract a b)
   591     have "Fract a b \<le> of_int (a div b + 1)"
   592       using rat_floor_lemma [of a b] by simp
   593     then show "\<exists>z. Fract a b \<le> of_int z" ..
   594   qed
   595 qed
   596 
   597 instantiation rat :: floor_ceiling
   598 begin
   599 
   600 definition [code del]:
   601   "floor (x::rat) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   602 
   603 instance proof
   604   fix x :: rat
   605   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   606     unfolding floor_rat_def using floor_exists1 by (rule theI')
   607 qed
   608 
   609 end
   610 
   611 lemma floor_Fract: "floor (Fract a b) = a div b"
   612   using rat_floor_lemma [of a b]
   613   by (simp add: floor_unique)
   614 
   615 
   616 subsection {* Linear arithmetic setup *}
   617 
   618 declaration {*
   619   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   620     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   621   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   622     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   623   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   624       @{thm True_implies_equals},
   625       @{thm distrib_left [where a = "numeral v" for v]},
   626       @{thm distrib_left [where a = "- numeral v" for v]},
   627       @{thm divide_1}, @{thm divide_zero_left},
   628       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   629       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   630       @{thm of_int_minus}, @{thm of_int_diff},
   631       @{thm of_int_of_nat_eq}]
   632   #> Lin_Arith.add_simprocs Numeral_Simprocs.field_divide_cancel_numeral_factor
   633   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat => rat"})
   634   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int => rat"}))
   635 *}
   636 
   637 
   638 subsection {* Embedding from Rationals to other Fields *}
   639 
   640 class field_char_0 = field + ring_char_0
   641 
   642 subclass (in linordered_field) field_char_0 ..
   643 
   644 context field_char_0
   645 begin
   646 
   647 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   648   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   649 apply (clarsimp simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   650 apply (simp only: of_int_mult [symmetric])
   651 done
   652 
   653 end
   654 
   655 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   656   by transfer simp
   657 
   658 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   659   by transfer simp
   660 
   661 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   662   by transfer simp
   663 
   664 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   665   by transfer (simp add: add_frac_eq)
   666 
   667 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   668   by transfer simp
   669 
   670 lemma of_rat_neg_one [simp]:
   671   "of_rat (- 1) = - 1"
   672   by (simp add: of_rat_minus)
   673 
   674 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   675   using of_rat_add [of a "- b"] by (simp add: of_rat_minus)
   676 
   677 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   678 apply transfer
   679 apply (simp add: divide_inverse nonzero_inverse_mult_distrib mult_ac)
   680 done
   681 
   682 lemma nonzero_of_rat_inverse:
   683   "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   684 apply (rule inverse_unique [symmetric])
   685 apply (simp add: of_rat_mult [symmetric])
   686 done
   687 
   688 lemma of_rat_inverse:
   689   "(of_rat (inverse a)::'a::{field_char_0, field_inverse_zero}) =
   690    inverse (of_rat a)"
   691 by (cases "a = 0", simp_all add: nonzero_of_rat_inverse)
   692 
   693 lemma nonzero_of_rat_divide:
   694   "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   695 by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   696 
   697 lemma of_rat_divide:
   698   "(of_rat (a / b)::'a::{field_char_0, field_inverse_zero})
   699    = of_rat a / of_rat b"
   700 by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   701 
   702 lemma of_rat_power:
   703   "(of_rat (a ^ n)::'a::field_char_0) = of_rat a ^ n"
   704 by (induct n) (simp_all add: of_rat_mult)
   705 
   706 lemma of_rat_eq_iff [simp]: "(of_rat a = of_rat b) = (a = b)"
   707 apply transfer
   708 apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   709 apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   710 done
   711 
   712 lemma of_rat_eq_0_iff [simp]: "(of_rat a = 0) = (a = 0)"
   713   using of_rat_eq_iff [of _ 0] by simp
   714 
   715 lemma zero_eq_of_rat_iff [simp]: "(0 = of_rat a) = (0 = a)"
   716   by simp
   717 
   718 lemma of_rat_eq_1_iff [simp]: "(of_rat a = 1) = (a = 1)"
   719   using of_rat_eq_iff [of _ 1] by simp
   720 
   721 lemma one_eq_of_rat_iff [simp]: "(1 = of_rat a) = (1 = a)"
   722   by simp
   723 
   724 lemma of_rat_less:
   725   "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   726 proof (induct r, induct s)
   727   fix a b c d :: int
   728   assume not_zero: "b > 0" "d > 0"
   729   then have "b * d > 0" by simp
   730   have of_int_divide_less_eq:
   731     "(of_int a :: 'a) / of_int b < of_int c / of_int d
   732       \<longleftrightarrow> (of_int a :: 'a) * of_int d < of_int c * of_int b"
   733     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   734   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d)
   735     \<longleftrightarrow> Fract a b < Fract c d"
   736     using not_zero `b * d > 0`
   737     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   738 qed
   739 
   740 lemma of_rat_less_eq:
   741   "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   742   unfolding le_less by (auto simp add: of_rat_less)
   743 
   744 lemma of_rat_le_0_iff [simp]: "((of_rat r :: 'a::linordered_field) \<le> 0) = (r \<le> 0)"
   745   using of_rat_less_eq [of r 0, where 'a='a] by simp
   746 
   747 lemma zero_le_of_rat_iff [simp]: "(0 \<le> (of_rat r :: 'a::linordered_field)) = (0 \<le> r)"
   748   using of_rat_less_eq [of 0 r, where 'a='a] by simp
   749 
   750 lemma of_rat_le_1_iff [simp]: "((of_rat r :: 'a::linordered_field) \<le> 1) = (r \<le> 1)"
   751   using of_rat_less_eq [of r 1] by simp
   752 
   753 lemma one_le_of_rat_iff [simp]: "(1 \<le> (of_rat r :: 'a::linordered_field)) = (1 \<le> r)"
   754   using of_rat_less_eq [of 1 r] by simp
   755 
   756 lemma of_rat_less_0_iff [simp]: "((of_rat r :: 'a::linordered_field) < 0) = (r < 0)"
   757   using of_rat_less [of r 0, where 'a='a] by simp
   758 
   759 lemma zero_less_of_rat_iff [simp]: "(0 < (of_rat r :: 'a::linordered_field)) = (0 < r)"
   760   using of_rat_less [of 0 r, where 'a='a] by simp
   761 
   762 lemma of_rat_less_1_iff [simp]: "((of_rat r :: 'a::linordered_field) < 1) = (r < 1)"
   763   using of_rat_less [of r 1] by simp
   764 
   765 lemma one_less_of_rat_iff [simp]: "(1 < (of_rat r :: 'a::linordered_field)) = (1 < r)"
   766   using of_rat_less [of 1 r] by simp
   767 
   768 lemma of_rat_eq_id [simp]: "of_rat = id"
   769 proof
   770   fix a
   771   show "of_rat a = id a"
   772   by (induct a)
   773      (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   774 qed
   775 
   776 text{*Collapse nested embeddings*}
   777 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   778 by (induct n) (simp_all add: of_rat_add)
   779 
   780 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   781 by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   782 
   783 lemma of_rat_numeral_eq [simp]:
   784   "of_rat (numeral w) = numeral w"
   785 using of_rat_of_int_eq [of "numeral w"] by simp
   786 
   787 lemma of_rat_neg_numeral_eq [simp]:
   788   "of_rat (- numeral w) = - numeral w"
   789 using of_rat_of_int_eq [of "- numeral w"] by simp
   790 
   791 lemmas zero_rat = Zero_rat_def
   792 lemmas one_rat = One_rat_def
   793 
   794 abbreviation
   795   rat_of_nat :: "nat \<Rightarrow> rat"
   796 where
   797   "rat_of_nat \<equiv> of_nat"
   798 
   799 abbreviation
   800   rat_of_int :: "int \<Rightarrow> rat"
   801 where
   802   "rat_of_int \<equiv> of_int"
   803 
   804 subsection {* The Set of Rational Numbers *}
   805 
   806 context field_char_0
   807 begin
   808 
   809 definition
   810   Rats  :: "'a set" where
   811   "Rats = range of_rat"
   812 
   813 notation (xsymbols)
   814   Rats  ("\<rat>")
   815 
   816 end
   817 
   818 lemma Rats_of_rat [simp]: "of_rat r \<in> Rats"
   819 by (simp add: Rats_def)
   820 
   821 lemma Rats_of_int [simp]: "of_int z \<in> Rats"
   822 by (subst of_rat_of_int_eq [symmetric], rule Rats_of_rat)
   823 
   824 lemma Rats_of_nat [simp]: "of_nat n \<in> Rats"
   825 by (subst of_rat_of_nat_eq [symmetric], rule Rats_of_rat)
   826 
   827 lemma Rats_number_of [simp]: "numeral w \<in> Rats"
   828 by (subst of_rat_numeral_eq [symmetric], rule Rats_of_rat)
   829 
   830 lemma Rats_0 [simp]: "0 \<in> Rats"
   831 apply (unfold Rats_def)
   832 apply (rule range_eqI)
   833 apply (rule of_rat_0 [symmetric])
   834 done
   835 
   836 lemma Rats_1 [simp]: "1 \<in> Rats"
   837 apply (unfold Rats_def)
   838 apply (rule range_eqI)
   839 apply (rule of_rat_1 [symmetric])
   840 done
   841 
   842 lemma Rats_add [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a + b \<in> Rats"
   843 apply (auto simp add: Rats_def)
   844 apply (rule range_eqI)
   845 apply (rule of_rat_add [symmetric])
   846 done
   847 
   848 lemma Rats_minus [simp]: "a \<in> Rats \<Longrightarrow> - a \<in> Rats"
   849 apply (auto simp add: Rats_def)
   850 apply (rule range_eqI)
   851 apply (rule of_rat_minus [symmetric])
   852 done
   853 
   854 lemma Rats_diff [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a - b \<in> Rats"
   855 apply (auto simp add: Rats_def)
   856 apply (rule range_eqI)
   857 apply (rule of_rat_diff [symmetric])
   858 done
   859 
   860 lemma Rats_mult [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a * b \<in> Rats"
   861 apply (auto simp add: Rats_def)
   862 apply (rule range_eqI)
   863 apply (rule of_rat_mult [symmetric])
   864 done
   865 
   866 lemma nonzero_Rats_inverse:
   867   fixes a :: "'a::field_char_0"
   868   shows "\<lbrakk>a \<in> Rats; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Rats"
   869 apply (auto simp add: Rats_def)
   870 apply (rule range_eqI)
   871 apply (erule nonzero_of_rat_inverse [symmetric])
   872 done
   873 
   874 lemma Rats_inverse [simp]:
   875   fixes a :: "'a::{field_char_0, field_inverse_zero}"
   876   shows "a \<in> Rats \<Longrightarrow> inverse a \<in> Rats"
   877 apply (auto simp add: Rats_def)
   878 apply (rule range_eqI)
   879 apply (rule of_rat_inverse [symmetric])
   880 done
   881 
   882 lemma nonzero_Rats_divide:
   883   fixes a b :: "'a::field_char_0"
   884   shows "\<lbrakk>a \<in> Rats; b \<in> Rats; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   885 apply (auto simp add: Rats_def)
   886 apply (rule range_eqI)
   887 apply (erule nonzero_of_rat_divide [symmetric])
   888 done
   889 
   890 lemma Rats_divide [simp]:
   891   fixes a b :: "'a::{field_char_0, field_inverse_zero}"
   892   shows "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   893 apply (auto simp add: Rats_def)
   894 apply (rule range_eqI)
   895 apply (rule of_rat_divide [symmetric])
   896 done
   897 
   898 lemma Rats_power [simp]:
   899   fixes a :: "'a::field_char_0"
   900   shows "a \<in> Rats \<Longrightarrow> a ^ n \<in> Rats"
   901 apply (auto simp add: Rats_def)
   902 apply (rule range_eqI)
   903 apply (rule of_rat_power [symmetric])
   904 done
   905 
   906 lemma Rats_cases [cases set: Rats]:
   907   assumes "q \<in> \<rat>"
   908   obtains (of_rat) r where "q = of_rat r"
   909 proof -
   910   from `q \<in> \<rat>` have "q \<in> range of_rat" unfolding Rats_def .
   911   then obtain r where "q = of_rat r" ..
   912   then show thesis ..
   913 qed
   914 
   915 lemma Rats_induct [case_names of_rat, induct set: Rats]:
   916   "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   917   by (rule Rats_cases) auto
   918 
   919 lemma Rats_infinite: "\<not> finite \<rat>"
   920   by (auto dest!: finite_imageD simp: inj_on_def infinite_UNIV_char_0 Rats_def)
   921 
   922 subsection {* Implementation of rational numbers as pairs of integers *}
   923 
   924 text {* Formal constructor *}
   925 
   926 definition Frct :: "int \<times> int \<Rightarrow> rat" where
   927   [simp]: "Frct p = Fract (fst p) (snd p)"
   928 
   929 lemma [code abstype]:
   930   "Frct (quotient_of q) = q"
   931   by (cases q) (auto intro: quotient_of_eq)
   932 
   933 
   934 text {* Numerals *}
   935 
   936 declare quotient_of_Fract [code abstract]
   937 
   938 definition of_int :: "int \<Rightarrow> rat"
   939 where
   940   [code_abbrev]: "of_int = Int.of_int"
   941 hide_const (open) of_int
   942 
   943 lemma quotient_of_int [code abstract]:
   944   "quotient_of (Rat.of_int a) = (a, 1)"
   945   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   946 
   947 lemma [code_unfold]:
   948   "numeral k = Rat.of_int (numeral k)"
   949   by (simp add: Rat.of_int_def)
   950 
   951 lemma [code_unfold]:
   952   "- numeral k = Rat.of_int (- numeral k)"
   953   by (simp add: Rat.of_int_def)
   954 
   955 lemma Frct_code_post [code_post]:
   956   "Frct (0, a) = 0"
   957   "Frct (a, 0) = 0"
   958   "Frct (1, 1) = 1"
   959   "Frct (numeral k, 1) = numeral k"
   960   "Frct (- numeral k, 1) = - numeral k"
   961   "Frct (1, numeral k) = 1 / numeral k"
   962   "Frct (1, - numeral k) = 1 / - numeral k"
   963   "Frct (numeral k, numeral l) = numeral k / numeral l"
   964   "Frct (numeral k, - numeral l) = numeral k / - numeral l"
   965   "Frct (- numeral k, numeral l) = - numeral k / numeral l"
   966   "Frct (- numeral k, - numeral l) = - numeral k / - numeral l"
   967   by (simp_all add: Fract_of_int_quotient)
   968 
   969 
   970 text {* Operations *}
   971 
   972 lemma rat_zero_code [code abstract]:
   973   "quotient_of 0 = (0, 1)"
   974   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   975 
   976 lemma rat_one_code [code abstract]:
   977   "quotient_of 1 = (1, 1)"
   978   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   979 
   980 lemma rat_plus_code [code abstract]:
   981   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   982      in normalize (a * d + b * c, c * d))"
   983   by (cases p, cases q) (simp add: quotient_of_Fract)
   984 
   985 lemma rat_uminus_code [code abstract]:
   986   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   987   by (cases p) (simp add: quotient_of_Fract)
   988 
   989 lemma rat_minus_code [code abstract]:
   990   "quotient_of (p - q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   991      in normalize (a * d - b * c, c * d))"
   992   by (cases p, cases q) (simp add: quotient_of_Fract)
   993 
   994 lemma rat_times_code [code abstract]:
   995   "quotient_of (p * q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   996      in normalize (a * b, c * d))"
   997   by (cases p, cases q) (simp add: quotient_of_Fract)
   998 
   999 lemma rat_inverse_code [code abstract]:
  1000   "quotient_of (inverse p) = (let (a, b) = quotient_of p
  1001     in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
  1002 proof (cases p)
  1003   case (Fract a b) then show ?thesis
  1004     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd_int.commute)
  1005 qed
  1006 
  1007 lemma rat_divide_code [code abstract]:
  1008   "quotient_of (p / q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
  1009      in normalize (a * d, c * b))"
  1010   by (cases p, cases q) (simp add: quotient_of_Fract)
  1011 
  1012 lemma rat_abs_code [code abstract]:
  1013   "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
  1014   by (cases p) (simp add: quotient_of_Fract)
  1015 
  1016 lemma rat_sgn_code [code abstract]:
  1017   "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
  1018 proof (cases p)
  1019   case (Fract a b) then show ?thesis
  1020   by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
  1021 qed
  1022 
  1023 lemma rat_floor_code [code]:
  1024   "floor p = (let (a, b) = quotient_of p in a div b)"
  1025 by (cases p) (simp add: quotient_of_Fract floor_Fract)
  1026 
  1027 instantiation rat :: equal
  1028 begin
  1029 
  1030 definition [code]:
  1031   "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
  1032 
  1033 instance proof
  1034 qed (simp add: equal_rat_def quotient_of_inject_eq)
  1035 
  1036 lemma rat_eq_refl [code nbe]:
  1037   "HOL.equal (r::rat) r \<longleftrightarrow> True"
  1038   by (rule equal_refl)
  1039 
  1040 end
  1041 
  1042 lemma rat_less_eq_code [code]:
  1043   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1044   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1045 
  1046 lemma rat_less_code [code]:
  1047   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1048   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1049 
  1050 lemma [code]:
  1051   "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1052   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1053 
  1054 
  1055 text {* Quickcheck *}
  1056 
  1057 definition (in term_syntax)
  1058   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> rat \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1059   [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1060 
  1061 notation fcomp (infixl "\<circ>>" 60)
  1062 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1063 
  1064 instantiation rat :: random
  1065 begin
  1066 
  1067 definition
  1068   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair (
  1069      let j = int_of_integer (integer_of_natural (denom + 1))
  1070      in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1071 
  1072 instance ..
  1073 
  1074 end
  1075 
  1076 no_notation fcomp (infixl "\<circ>>" 60)
  1077 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1078 
  1079 instantiation rat :: exhaustive
  1080 begin
  1081 
  1082 definition
  1083   "exhaustive_rat f d = Quickcheck_Exhaustive.exhaustive
  1084     (\<lambda>l. Quickcheck_Exhaustive.exhaustive (\<lambda>k. f (Fract k (int_of_integer (integer_of_natural l) + 1))) d) d"
  1085 
  1086 instance ..
  1087 
  1088 end
  1089 
  1090 instantiation rat :: full_exhaustive
  1091 begin
  1092 
  1093 definition
  1094   "full_exhaustive_rat f d = Quickcheck_Exhaustive.full_exhaustive (%(l, _). Quickcheck_Exhaustive.full_exhaustive (%k.
  1095      f (let j = int_of_integer (integer_of_natural l) + 1
  1096         in valterm_fract k (j, %_. Code_Evaluation.term_of j))) d) d"
  1097 
  1098 instance ..
  1099 
  1100 end
  1101 
  1102 instantiation rat :: partial_term_of
  1103 begin
  1104 
  1105 instance ..
  1106 
  1107 end
  1108 
  1109 lemma [code]:
  1110   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) == Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1111   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) ==
  1112      Code_Evaluation.App (Code_Evaluation.Const (STR ''Rat.Frct'')
  1113      (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1114         Typerep.Typerep (STR ''Rat.rat'') []])) (Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.Const (STR ''Product_Type.Pair'') (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]])) (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1115 by (rule partial_term_of_anything)+
  1116 
  1117 instantiation rat :: narrowing
  1118 begin
  1119 
  1120 definition
  1121   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.apply
  1122     (Quickcheck_Narrowing.cons (%nom denom. Fract nom denom)) narrowing) narrowing"
  1123 
  1124 instance ..
  1125 
  1126 end
  1127 
  1128 
  1129 subsection {* Setup for Nitpick *}
  1130 
  1131 declaration {*
  1132   Nitpick_HOL.register_frac_type @{type_name rat}
  1133    [(@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1134     (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1135     (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1136     (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1137     (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1138     (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1139     (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1140     (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1141     (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1142 *}
  1143 
  1144 lemmas [nitpick_unfold] = inverse_rat_inst.inverse_rat
  1145   one_rat_inst.one_rat ord_rat_inst.less_rat
  1146   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1147   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1148 
  1149 
  1150 subsection {* Float syntax *}
  1151 
  1152 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1153 
  1154 parse_translation {*
  1155   let
  1156     fun mk_number i =
  1157       let
  1158         fun mk 1 = Syntax.const @{const_syntax Num.One}
  1159           | mk i =
  1160               let
  1161                 val (q, r) = Integer.div_mod i 2;
  1162                 val bit = if r = 0 then @{const_syntax Num.Bit0} else @{const_syntax Num.Bit1};
  1163               in Syntax.const bit $ (mk q) end;
  1164       in
  1165         if i = 0 then Syntax.const @{const_syntax Groups.zero}
  1166         else if i > 0 then Syntax.const @{const_syntax Num.numeral} $ mk i
  1167         else
  1168           Syntax.const @{const_syntax Groups.uminus} $
  1169             (Syntax.const @{const_syntax Num.numeral} $ mk (~ i))
  1170       end;
  1171 
  1172     fun mk_frac str =
  1173       let
  1174         val {mant = i, exp = n} = Lexicon.read_float str;
  1175         val exp = Syntax.const @{const_syntax Power.power};
  1176         val ten = mk_number 10;
  1177         val exp10 = if n = 1 then ten else exp $ ten $ mk_number n;
  1178       in Syntax.const @{const_syntax divide} $ mk_number i $ exp10 end;
  1179 
  1180     fun float_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] = c $ float_tr [t] $ u
  1181       | float_tr [t as Const (str, _)] = mk_frac str
  1182       | float_tr ts = raise TERM ("float_tr", ts);
  1183   in [(@{syntax_const "_Float"}, K float_tr)] end
  1184 *}
  1185 
  1186 text{* Test: *}
  1187 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1188   by simp
  1189 
  1190 
  1191 subsection {* Hiding implementation details *}
  1192 
  1193 hide_const (open) normalize positive
  1194 
  1195 lifting_update rat.lifting
  1196 lifting_forget rat.lifting
  1197 
  1198 end
  1199