src/HOL/Set.ML
author paulson
Thu Mar 02 10:26:22 2000 +0100 (2000-03-02)
changeset 8326 0e329578b0ef
parent 8053 37ebdaf3bb91
child 8839 31da5b9790c0
permissions -rw-r--r--
tidied the proofs of singleton_insert_inj_eq, singleton_insert_inj_eq' and
installed them by AddIffs, since they are an important special case of
equalityE.
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 bind_thm ("CollectE", make_elim CollectD);
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> ? x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(? x:A. P) = ((? x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (! x:A. P(x)) = (! x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (? x:A. P(x)) = (? x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("image", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   156 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   157 qed "contra_subsetD";
   158 
   159 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   160 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   161 qed "rev_contra_subsetD";
   162 
   163 (*Classical elimination rule*)
   164 val major::prems = Goalw [subset_def] 
   165     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   166 by (rtac (major RS ballE) 1);
   167 by (REPEAT (eresolve_tac prems 1));
   168 qed "subsetCE";
   169 
   170 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   171 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   172 
   173 AddSIs [subsetI];
   174 AddEs  [subsetD, subsetCE];
   175 
   176 Goal "A <= (A::'a set)";
   177 by (Fast_tac 1);
   178 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   179 
   180 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   181 by (Blast_tac 1);
   182 qed "subset_trans";
   183 
   184 
   185 section "Equality";
   186 
   187 (*Anti-symmetry of the subset relation*)
   188 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   189 by (rtac set_ext 1);
   190 by (blast_tac (claset() addIs [subsetD]) 1);
   191 qed "subset_antisym";
   192 val equalityI = subset_antisym;
   193 
   194 AddSIs [equalityI];
   195 
   196 (* Equality rules from ZF set theory -- are they appropriate here? *)
   197 Goal "A = B ==> A<=(B::'a set)";
   198 by (etac ssubst 1);
   199 by (rtac subset_refl 1);
   200 qed "equalityD1";
   201 
   202 Goal "A = B ==> B<=(A::'a set)";
   203 by (etac ssubst 1);
   204 by (rtac subset_refl 1);
   205 qed "equalityD2";
   206 
   207 val prems = Goal
   208     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   209 by (resolve_tac prems 1);
   210 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   211 qed "equalityE";
   212 
   213 val major::prems = Goal
   214     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   215 by (rtac (major RS equalityE) 1);
   216 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   217 qed "equalityCE";
   218 
   219 (*Lemma for creating induction formulae -- for "pattern matching" on p
   220   To make the induction hypotheses usable, apply "spec" or "bspec" to
   221   put universal quantifiers over the free variables in p. *)
   222 val prems = Goal 
   223     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   224 by (rtac mp 1);
   225 by (REPEAT (resolve_tac (refl::prems) 1));
   226 qed "setup_induction";
   227 
   228 Goal "A = B ==> (x : A) = (x : B)";
   229 by (Asm_simp_tac 1);
   230 qed "eqset_imp_iff";
   231 
   232 
   233 section "The universal set -- UNIV";
   234 
   235 Goalw [UNIV_def] "x : UNIV";
   236 by (rtac CollectI 1);
   237 by (rtac TrueI 1);
   238 qed "UNIV_I";
   239 
   240 Addsimps [UNIV_I];
   241 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   242 
   243 Goal "A <= UNIV";
   244 by (rtac subsetI 1);
   245 by (rtac UNIV_I 1);
   246 qed "subset_UNIV";
   247 
   248 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   249     because of their interaction with congruence rules. **)
   250 
   251 Goalw [Ball_def] "Ball UNIV P = All P";
   252 by (Simp_tac 1);
   253 qed "ball_UNIV";
   254 
   255 Goalw [Bex_def] "Bex UNIV P = Ex P";
   256 by (Simp_tac 1);
   257 qed "bex_UNIV";
   258 Addsimps [ball_UNIV, bex_UNIV];
   259 
   260 
   261 section "The empty set -- {}";
   262 
   263 Goalw [empty_def] "(c : {}) = False";
   264 by (Blast_tac 1) ;
   265 qed "empty_iff";
   266 
   267 Addsimps [empty_iff];
   268 
   269 Goal "a:{} ==> P";
   270 by (Full_simp_tac 1);
   271 qed "emptyE";
   272 
   273 AddSEs [emptyE];
   274 
   275 Goal "{} <= A";
   276 by (Blast_tac 1) ;
   277 qed "empty_subsetI";
   278 
   279 (*One effect is to delete the ASSUMPTION {} <= A*)
   280 AddIffs [empty_subsetI];
   281 
   282 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   283 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   284 qed "equals0I";
   285 
   286 (*Use for reasoning about disjointness: A Int B = {} *)
   287 Goal "A={} ==> a ~: A";
   288 by (Blast_tac 1) ;
   289 qed "equals0D";
   290 
   291 AddDs [equals0D, sym RS equals0D];
   292 
   293 Goalw [Ball_def] "Ball {} P = True";
   294 by (Simp_tac 1);
   295 qed "ball_empty";
   296 
   297 Goalw [Bex_def] "Bex {} P = False";
   298 by (Simp_tac 1);
   299 qed "bex_empty";
   300 Addsimps [ball_empty, bex_empty];
   301 
   302 Goal "UNIV ~= {}";
   303 by (blast_tac (claset() addEs [equalityE]) 1);
   304 qed "UNIV_not_empty";
   305 AddIffs [UNIV_not_empty];
   306 
   307 
   308 
   309 section "The Powerset operator -- Pow";
   310 
   311 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   312 by (Asm_simp_tac 1);
   313 qed "Pow_iff";
   314 
   315 AddIffs [Pow_iff]; 
   316 
   317 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   318 by (etac CollectI 1);
   319 qed "PowI";
   320 
   321 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   322 by (etac CollectD 1);
   323 qed "PowD";
   324 
   325 
   326 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   327 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   328 
   329 
   330 section "Set complement";
   331 
   332 Goalw [Compl_def] "(c : -A) = (c~:A)";
   333 by (Blast_tac 1);
   334 qed "Compl_iff";
   335 
   336 Addsimps [Compl_iff];
   337 
   338 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   339 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   340 qed "ComplI";
   341 
   342 (*This form, with negated conclusion, works well with the Classical prover.
   343   Negated assumptions behave like formulae on the right side of the notional
   344   turnstile...*)
   345 Goalw [Compl_def] "c : -A ==> c~:A";
   346 by (etac CollectD 1);
   347 qed "ComplD";
   348 
   349 val ComplE = make_elim ComplD;
   350 
   351 AddSIs [ComplI];
   352 AddSEs [ComplE];
   353 
   354 
   355 section "Binary union -- Un";
   356 
   357 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   358 by (Blast_tac 1);
   359 qed "Un_iff";
   360 Addsimps [Un_iff];
   361 
   362 Goal "c:A ==> c : A Un B";
   363 by (Asm_simp_tac 1);
   364 qed "UnI1";
   365 
   366 Goal "c:B ==> c : A Un B";
   367 by (Asm_simp_tac 1);
   368 qed "UnI2";
   369 
   370 (*Classical introduction rule: no commitment to A vs B*)
   371 
   372 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   373 by (Simp_tac 1);
   374 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   375 qed "UnCI";
   376 
   377 val major::prems = Goalw [Un_def]
   378     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   379 by (rtac (major RS CollectD RS disjE) 1);
   380 by (REPEAT (eresolve_tac prems 1));
   381 qed "UnE";
   382 
   383 AddSIs [UnCI];
   384 AddSEs [UnE];
   385 
   386 
   387 section "Binary intersection -- Int";
   388 
   389 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   390 by (Blast_tac 1);
   391 qed "Int_iff";
   392 Addsimps [Int_iff];
   393 
   394 Goal "[| c:A;  c:B |] ==> c : A Int B";
   395 by (Asm_simp_tac 1);
   396 qed "IntI";
   397 
   398 Goal "c : A Int B ==> c:A";
   399 by (Asm_full_simp_tac 1);
   400 qed "IntD1";
   401 
   402 Goal "c : A Int B ==> c:B";
   403 by (Asm_full_simp_tac 1);
   404 qed "IntD2";
   405 
   406 val [major,minor] = Goal
   407     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   408 by (rtac minor 1);
   409 by (rtac (major RS IntD1) 1);
   410 by (rtac (major RS IntD2) 1);
   411 qed "IntE";
   412 
   413 AddSIs [IntI];
   414 AddSEs [IntE];
   415 
   416 section "Set difference";
   417 
   418 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   419 by (Blast_tac 1);
   420 qed "Diff_iff";
   421 Addsimps [Diff_iff];
   422 
   423 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   424 by (Asm_simp_tac 1) ;
   425 qed "DiffI";
   426 
   427 Goal "c : A - B ==> c : A";
   428 by (Asm_full_simp_tac 1) ;
   429 qed "DiffD1";
   430 
   431 Goal "[| c : A - B;  c : B |] ==> P";
   432 by (Asm_full_simp_tac 1) ;
   433 qed "DiffD2";
   434 
   435 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   436 by (resolve_tac prems 1);
   437 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   438 qed "DiffE";
   439 
   440 AddSIs [DiffI];
   441 AddSEs [DiffE];
   442 
   443 
   444 section "Augmenting a set -- insert";
   445 
   446 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   447 by (Blast_tac 1);
   448 qed "insert_iff";
   449 Addsimps [insert_iff];
   450 
   451 Goal "a : insert a B";
   452 by (Simp_tac 1);
   453 qed "insertI1";
   454 
   455 Goal "!!a. a : B ==> a : insert b B";
   456 by (Asm_simp_tac 1);
   457 qed "insertI2";
   458 
   459 val major::prems = Goalw [insert_def]
   460     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   461 by (rtac (major RS UnE) 1);
   462 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   463 qed "insertE";
   464 
   465 (*Classical introduction rule*)
   466 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   467 by (Simp_tac 1);
   468 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   469 qed "insertCI";
   470 
   471 AddSIs [insertCI]; 
   472 AddSEs [insertE];
   473 
   474 Goal "A <= insert x B ==> A <= B & x ~: A | (? B'. A = insert x B' & B' <= B)";
   475 by (case_tac "x:A" 1);
   476 by  (Fast_tac 2);
   477 by (rtac disjI2 1);
   478 by (res_inst_tac [("x","A-{x}")] exI 1);
   479 by (Fast_tac 1);
   480 qed "subset_insertD";
   481 
   482 section "Singletons, using insert";
   483 
   484 Goal "a : {a}";
   485 by (rtac insertI1 1) ;
   486 qed "singletonI";
   487 
   488 Goal "b : {a} ==> b=a";
   489 by (Blast_tac 1);
   490 qed "singletonD";
   491 
   492 bind_thm ("singletonE", make_elim singletonD);
   493 
   494 Goal "(b : {a}) = (b=a)";
   495 by (Blast_tac 1);
   496 qed "singleton_iff";
   497 
   498 Goal "{a}={b} ==> a=b";
   499 by (blast_tac (claset() addEs [equalityE]) 1);
   500 qed "singleton_inject";
   501 
   502 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   503 AddSIs [singletonI];   
   504 AddSDs [singleton_inject];
   505 AddSEs [singletonE];
   506 
   507 Goal "{b} = insert a A = (a = b & A <= {b})";
   508 by (blast_tac (claset() addSEs [equalityE]) 1);
   509 qed "singleton_insert_inj_eq";
   510 
   511 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   512 by (blast_tac (claset() addSEs [equalityE]) 1);
   513 qed "singleton_insert_inj_eq'";
   514 
   515 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   516 
   517 Goal "A <= {x} ==> A={} | A = {x}";
   518 by (Fast_tac 1);
   519 qed "subset_singletonD";
   520 
   521 Goal "{x. x=a} = {a}";
   522 by (Blast_tac 1);
   523 qed "singleton_conv";
   524 Addsimps [singleton_conv];
   525 
   526 Goal "{x. a=x} = {a}";
   527 by (Blast_tac 1);
   528 qed "singleton_conv2";
   529 Addsimps [singleton_conv2];
   530 
   531 
   532 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   533 
   534 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   535 by (Blast_tac 1);
   536 qed "UN_iff";
   537 
   538 Addsimps [UN_iff];
   539 
   540 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   541 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   542 by Auto_tac;
   543 qed "UN_I";
   544 
   545 val major::prems = Goalw [UNION_def]
   546     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   547 by (rtac (major RS CollectD RS bexE) 1);
   548 by (REPEAT (ares_tac prems 1));
   549 qed "UN_E";
   550 
   551 AddIs  [UN_I];
   552 AddSEs [UN_E];
   553 
   554 val prems = Goalw [UNION_def]
   555     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   556 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   557 by (asm_simp_tac (simpset() addsimps prems) 1);
   558 qed "UN_cong";
   559 
   560 
   561 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   562 
   563 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   564 by Auto_tac;
   565 qed "INT_iff";
   566 
   567 Addsimps [INT_iff];
   568 
   569 val prems = Goalw [INTER_def]
   570     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   571 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   572 qed "INT_I";
   573 
   574 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   575 by Auto_tac;
   576 qed "INT_D";
   577 
   578 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   579 val major::prems = Goalw [INTER_def]
   580     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   581 by (rtac (major RS CollectD RS ballE) 1);
   582 by (REPEAT (eresolve_tac prems 1));
   583 qed "INT_E";
   584 
   585 AddSIs [INT_I];
   586 AddEs  [INT_D, INT_E];
   587 
   588 val prems = Goalw [INTER_def]
   589     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   590 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   591 by (asm_simp_tac (simpset() addsimps prems) 1);
   592 qed "INT_cong";
   593 
   594 
   595 section "Union";
   596 
   597 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   598 by (Blast_tac 1);
   599 qed "Union_iff";
   600 
   601 Addsimps [Union_iff];
   602 
   603 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   604 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   605 by Auto_tac;
   606 qed "UnionI";
   607 
   608 val major::prems = Goalw [Union_def]
   609     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   610 by (rtac (major RS UN_E) 1);
   611 by (REPEAT (ares_tac prems 1));
   612 qed "UnionE";
   613 
   614 AddIs  [UnionI];
   615 AddSEs [UnionE];
   616 
   617 
   618 section "Inter";
   619 
   620 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   621 by (Blast_tac 1);
   622 qed "Inter_iff";
   623 
   624 Addsimps [Inter_iff];
   625 
   626 val prems = Goalw [Inter_def]
   627     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   628 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   629 qed "InterI";
   630 
   631 (*A "destruct" rule -- every X in C contains A as an element, but
   632   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   633 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   634 by Auto_tac;
   635 qed "InterD";
   636 
   637 (*"Classical" elimination rule -- does not require proving X:C *)
   638 val major::prems = Goalw [Inter_def]
   639     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   640 by (rtac (major RS INT_E) 1);
   641 by (REPEAT (eresolve_tac prems 1));
   642 qed "InterE";
   643 
   644 AddSIs [InterI];
   645 AddEs  [InterD, InterE];
   646 
   647 
   648 (*** Image of a set under a function ***)
   649 
   650 (*Frequently b does not have the syntactic form of f(x).*)
   651 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   652 by (Blast_tac 1);
   653 qed "image_eqI";
   654 Addsimps [image_eqI];
   655 
   656 bind_thm ("imageI", refl RS image_eqI);
   657 
   658 (*This version's more effective when we already have the required x*)
   659 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   660 by (Blast_tac 1);
   661 qed "rev_image_eqI";
   662 
   663 (*The eta-expansion gives variable-name preservation.*)
   664 val major::prems = Goalw [image_def]
   665     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   666 by (rtac (major RS CollectD RS bexE) 1);
   667 by (REPEAT (ares_tac prems 1));
   668 qed "imageE";
   669 
   670 AddIs  [image_eqI];
   671 AddSEs [imageE]; 
   672 
   673 Goal "f``(A Un B) = f``A Un f``B";
   674 by (Blast_tac 1);
   675 qed "image_Un";
   676 
   677 Goal "(z : f``A) = (EX x:A. z = f x)";
   678 by (Blast_tac 1);
   679 qed "image_iff";
   680 
   681 (*This rewrite rule would confuse users if made default.*)
   682 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   683 by (Blast_tac 1);
   684 qed "image_subset_iff";
   685 
   686 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   687   many existing proofs.*)
   688 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   689 by (blast_tac (claset() addIs prems) 1);
   690 qed "image_subsetI";
   691 
   692 
   693 (*** Range of a function -- just a translation for image! ***)
   694 
   695 Goal "b=f(x) ==> b : range(f)";
   696 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   697 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   698 
   699 bind_thm ("rangeI", UNIV_I RS imageI);
   700 
   701 val [major,minor] = Goal 
   702     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   703 by (rtac (major RS imageE) 1);
   704 by (etac minor 1);
   705 qed "rangeE";
   706 
   707 
   708 (*** Set reasoning tools ***)
   709 
   710 
   711 (** Rewrite rules for boolean case-splitting: faster than 
   712 	addsplits[split_if]
   713 **)
   714 
   715 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   716 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   717 
   718 (*Split ifs on either side of the membership relation.
   719 	Not for Addsimps -- can cause goals to blow up!*)
   720 bind_thm ("split_if_mem1", 
   721     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   722 bind_thm ("split_if_mem2", 
   723     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   724 
   725 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   726 		  split_if_mem1, split_if_mem2];
   727 
   728 
   729 (*Each of these has ALREADY been added to simpset() above.*)
   730 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   731                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   732 
   733 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   734 
   735 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   736 
   737 Addsimps[subset_UNIV, subset_refl];
   738 
   739 
   740 (*** The 'proper subset' relation (<) ***)
   741 
   742 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   743 by (Blast_tac 1);
   744 qed "psubsetI";
   745 AddXIs [psubsetI];
   746 
   747 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   748 by Auto_tac;
   749 qed "psubset_insertD";
   750 
   751 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   752 
   753 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   754 
   755 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   756 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   757 qed "psubset_subset_trans";
   758 
   759 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   760 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   761 qed "subset_psubset_trans";
   762 
   763 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   764 by (Blast_tac 1);
   765 qed "psubset_imp_ex_mem";
   766 
   767 
   768 (* attributes *)
   769 
   770 local
   771 
   772 fun gen_rulify_prems x =
   773   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   774     rule_by_tactic (REPEAT (ALLGOALS (resolve_tac [allI, ballI, impI])))))) x;
   775 
   776 in
   777 
   778 val rulify_prems_attrib_setup =
   779  [Attrib.add_attributes
   780   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   781 
   782 end;