src/Pure/meta_simplifier.ML
author wenzelm
Thu Jul 08 19:33:51 2004 +0200 (2004-07-08)
changeset 15023 0e4689f411d5
parent 15011 35be762f58f9
child 15034 e1282c4b39be
permissions -rw-r--r--
major cleanup; got rid of obsolete meta_simpset;
     1 (*  Title:      Pure/meta_simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Stefan Berghofer
     4 
     5 Meta-level Simplification.
     6 *)
     7 
     8 infix 4
     9   addsimps delsimps addeqcongs deleqcongs addcongs delcongs addsimprocs delsimprocs
    10   setmksimps setmkcong setmksym setmkeqTrue settermless setsubgoaler
    11   setloop addloop delloop setSSolver addSSolver setSolver addSolver;
    12 
    13 signature BASIC_META_SIMPLIFIER =
    14 sig
    15   val debug_simp: bool ref
    16   val trace_simp: bool ref
    17   val simp_depth_limit: int ref
    18   type rrule
    19   type cong
    20   type solver
    21   val mk_solver: string -> (thm list -> int -> tactic) -> solver
    22   type simpset
    23   type proc
    24   val rep_ss: simpset ->
    25    {rules: rrule Net.net,
    26     prems: thm list,
    27     bounds: string list,
    28     depth: int} *
    29    {congs: (string * cong) list * string list,
    30     procs: proc Net.net,
    31     mk_rews:
    32      {mk: thm -> thm list,
    33       mk_cong: thm -> thm,
    34       mk_sym: thm -> thm option,
    35       mk_eq_True: thm -> thm option},
    36     termless: term * term -> bool,
    37     subgoal_tac: simpset -> int -> tactic,
    38     loop_tacs: (string * (int -> tactic)) list,
    39     solvers: solver list * solver list}
    40   val print_ss: simpset -> unit
    41   val empty_ss: simpset
    42   val merge_ss: simpset * simpset -> simpset
    43   type simproc
    44   val mk_simproc: string -> cterm list ->
    45     (Sign.sg -> simpset -> term -> thm option) -> simproc
    46   val add_prems: thm list -> simpset -> simpset
    47   val prems_of_ss: simpset -> thm list
    48   val addsimps: simpset * thm list -> simpset
    49   val delsimps: simpset * thm list -> simpset
    50   val addeqcongs: simpset * thm list -> simpset
    51   val deleqcongs: simpset * thm list -> simpset
    52   val addcongs: simpset * thm list -> simpset
    53   val delcongs: simpset * thm list -> simpset
    54   val addsimprocs: simpset * simproc list -> simpset
    55   val delsimprocs: simpset * simproc list -> simpset
    56   val setmksimps: simpset * (thm -> thm list) -> simpset
    57   val setmkcong: simpset * (thm -> thm) -> simpset
    58   val setmksym: simpset * (thm -> thm option) -> simpset
    59   val setmkeqTrue: simpset * (thm -> thm option) -> simpset
    60   val settermless: simpset * (term * term -> bool) -> simpset
    61   val setsubgoaler: simpset * (simpset -> int -> tactic) -> simpset
    62   val setloop: simpset * (int -> tactic) -> simpset
    63   val addloop: simpset * (string * (int -> tactic)) -> simpset
    64   val delloop: simpset * string -> simpset
    65   val setSSolver: simpset * solver -> simpset
    66   val addSSolver: simpset * solver -> simpset
    67   val setSolver: simpset * solver -> simpset
    68   val addSolver: simpset * solver -> simpset
    69   val generic_simp_tac: bool -> bool * bool * bool -> simpset -> int -> tactic
    70 end;
    71 
    72 signature META_SIMPLIFIER =
    73 sig
    74   include BASIC_META_SIMPLIFIER
    75   exception SIMPLIFIER of string * thm
    76   val dest_ss: simpset ->
    77     {simps: thm list, congs: thm list, procs: (string * cterm list) list}
    78   val clear_ss: simpset -> simpset
    79   exception SIMPROC_FAIL of string * exn
    80   val simproc_i: Sign.sg -> string -> term list
    81     -> (Sign.sg -> simpset -> term -> thm option) -> simproc
    82   val simproc: Sign.sg -> string -> string list
    83     -> (Sign.sg -> simpset -> term -> thm option) -> simproc
    84   val rewrite_cterm: bool * bool * bool ->
    85     (simpset -> thm -> thm option) -> simpset -> cterm -> thm
    86   val rewrite_aux: (simpset -> thm -> thm option) -> bool -> thm list -> cterm -> thm
    87   val simplify_aux: (simpset -> thm -> thm option) -> bool -> thm list -> thm -> thm
    88   val rewrite_term: Sign.sg -> thm list -> (term -> term option) list -> term -> term
    89   val rewrite_thm: bool * bool * bool ->
    90     (simpset -> thm -> thm option) -> simpset -> thm -> thm
    91   val rewrite_goals_rule_aux: (simpset -> thm -> thm option) -> thm list -> thm -> thm
    92   val rewrite_goal_rule: bool * bool * bool ->
    93     (simpset -> thm -> thm option) -> simpset -> int -> thm -> thm
    94   val asm_rewrite_goal_tac: bool * bool * bool ->
    95     (simpset -> tactic) -> simpset -> int -> tactic
    96   val simp_thm: bool * bool * bool -> simpset -> thm -> thm
    97   val simp_cterm: bool * bool * bool -> simpset -> cterm -> thm
    98 end;
    99 
   100 structure MetaSimplifier: META_SIMPLIFIER =
   101 struct
   102 
   103 
   104 (** diagnostics **)
   105 
   106 exception SIMPLIFIER of string * thm;
   107 
   108 val debug_simp = ref false;
   109 val trace_simp = ref false;
   110 val simp_depth = ref 0;
   111 val simp_depth_limit = ref 1000;
   112 
   113 local
   114 
   115 fun println a =
   116   tracing (case ! simp_depth of 0 => a | n => enclose "[" "]" (string_of_int n) ^ a);
   117 
   118 fun prnt warn a = if warn then warning a else println a;
   119 fun prtm warn a sg t = prnt warn (a ^ "\n" ^ Sign.string_of_term sg t);
   120 fun prctm warn a t = prnt warn (a ^ "\n" ^ Display.string_of_cterm t);
   121 
   122 in
   123 
   124 fun debug warn a = if ! debug_simp then prnt warn a else ();
   125 fun trace warn a = if ! trace_simp then prnt warn a else ();
   126 
   127 fun debug_term warn a sign t = if ! debug_simp then prtm warn a sign t else ();
   128 fun trace_term warn a sign t = if ! trace_simp then prtm warn a sign t else ();
   129 fun trace_cterm warn a ct = if ! trace_simp then prctm warn a ct else ();
   130 fun trace_thm a th = if ! trace_simp then prctm false a (Thm.cprop_of th) else ();
   131 
   132 fun trace_named_thm a (thm, name) =
   133   if ! trace_simp then
   134     prctm false (if name = "" then a else a ^ " " ^ quote name ^ ":") (Thm.cprop_of thm)
   135   else ();
   136 
   137 fun warn_thm a = prctm true a o Thm.cprop_of;
   138 
   139 end;
   140 
   141 
   142 
   143 (** datatype simpset **)
   144 
   145 (* rewrite rules *)
   146 
   147 type rrule = {thm: thm, name: string, lhs: term, elhs: cterm, fo: bool, perm: bool};
   148 
   149 (*thm: the rewrite rule;
   150   name: name of theorem from which rewrite rule was extracted;
   151   lhs: the left-hand side;
   152   elhs: the etac-contracted lhs;
   153   fo: use first-order matching;
   154   perm: the rewrite rule is permutative;
   155 
   156 Remarks:
   157   - elhs is used for matching,
   158     lhs only for preservation of bound variable names;
   159   - fo is set iff
   160     either elhs is first-order (no Var is applied),
   161       in which case fo-matching is complete,
   162     or elhs is not a pattern,
   163       in which case there is nothing better to do;*)
   164 
   165 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   166   Drule.eq_thm_prop (thm1, thm2);
   167 
   168 
   169 (* congruences *)
   170 
   171 type cong = {thm: thm, lhs: cterm};
   172 
   173 fun eq_cong ({thm = thm1, ...}: cong, {thm = thm2, ...}: cong) =
   174   Drule.eq_thm_prop (thm1, thm2);
   175 
   176 
   177 (* solvers *)
   178 
   179 datatype solver =
   180   Solver of
   181    {name: string,
   182     solver: thm list -> int -> tactic,
   183     id: stamp};
   184 
   185 fun mk_solver name solver = Solver {name = name, solver = solver, id = stamp ()};
   186 
   187 fun solver ths (Solver {solver = tacf, ...}) = tacf ths;
   188 
   189 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   190 val merge_solvers = gen_merge_lists eq_solver;
   191 
   192 
   193 (* simplification sets and procedures *)
   194 
   195 (*A simpset contains data required during conversion:
   196     rules: discrimination net of rewrite rules;
   197     prems: current premises;
   198     bounds: names of bound variables already used
   199       (for generating new names when rewriting under lambda abstractions);
   200     depth: depth of conditional rewriting;
   201     congs: association list of congruence rules and
   202            a list of `weak' congruence constants.
   203            A congruence is `weak' if it avoids normalization of some argument.
   204     procs: discrimination net of simplification procedures
   205       (functions that prove rewrite rules on the fly);
   206     mk_rews:
   207       mk: turn simplification thms into rewrite rules;
   208       mk_cong: prepare congruence rules;
   209       mk_sym: turn == around;
   210       mk_eq_True: turn P into P == True;
   211     termless: relation for ordered rewriting;*)
   212 
   213 type mk_rews =
   214  {mk: thm -> thm list,
   215   mk_cong: thm -> thm,
   216   mk_sym: thm -> thm option,
   217   mk_eq_True: thm -> thm option};
   218 
   219 datatype simpset =
   220   Simpset of
   221    {rules: rrule Net.net,
   222     prems: thm list,
   223     bounds: string list,
   224     depth: int} *
   225    {congs: (string * cong) list * string list,
   226     procs: proc Net.net,
   227     mk_rews: mk_rews,
   228     termless: term * term -> bool,
   229     subgoal_tac: simpset -> int -> tactic,
   230     loop_tacs: (string * (int -> tactic)) list,
   231     solvers: solver list * solver list}
   232 and proc =
   233   Proc of
   234    {name: string,
   235     lhs: cterm,
   236     proc: Sign.sg -> simpset -> term -> thm option,
   237     id: stamp};
   238 
   239 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = (id1 = id2);
   240 
   241 fun rep_ss (Simpset args) = args;
   242 
   243 fun make_ss1 (rules, prems, bounds, depth) =
   244   {rules = rules, prems = prems, bounds = bounds, depth = depth};
   245 
   246 fun map_ss1 f {rules, prems, bounds, depth} =
   247   make_ss1 (f (rules, prems, bounds, depth));
   248 
   249 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   250   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   251     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   252 
   253 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   254   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   255 
   256 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   257 
   258 fun map_simpset f (Simpset ({rules, prems, bounds, depth},
   259     {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers})) =
   260   make_simpset (f ((rules, prems, bounds, depth),
   261     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers)));
   262 
   263 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   264 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   265 
   266 
   267 (* print simpsets *)
   268 
   269 fun dest_ss (Simpset ({rules, ...}, {congs = (congs, _), procs, ...})) =
   270   {simps = map (fn (_, {thm, ...}) => thm) (Net.dest rules),
   271    congs = map (fn (_, {thm, ...}) => thm) congs,
   272    procs =
   273      map (fn (_, Proc {name, lhs, id, ...}) => ((name, lhs), id)) (Net.dest procs)
   274      |> partition_eq eq_snd
   275      |> map (fn ps => (#1 (#1 (hd ps)), map (#2 o #1) ps))
   276      |> Library.sort_wrt #1};
   277 
   278 fun print_ss ss =
   279   let
   280     val {simps, procs, congs} = dest_ss ss;
   281 
   282     val pretty_thms = map Display.pretty_thm;
   283     fun pretty_proc (name, lhss) =
   284       Pretty.big_list (name ^ ":") (map Display.pretty_cterm lhss);
   285   in
   286     [Pretty.big_list "simplification rules:" (pretty_thms simps),
   287       Pretty.big_list "simplification procedures:" (map pretty_proc procs),
   288       Pretty.big_list "congruences:" (pretty_thms congs)]
   289     |> Pretty.chunks |> Pretty.writeln
   290   end;
   291 
   292 
   293 (* empty simpsets *)
   294 
   295 local
   296 
   297 fun init_ss mk_rews termless subgoal_tac solvers =
   298   make_simpset ((Net.empty, [], [], 0),
   299     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   300 
   301 val basic_mk_rews: mk_rews =
   302  {mk = fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   303   mk_cong = I,
   304   mk_sym = Some o Drule.symmetric_fun,
   305   mk_eq_True = K None};
   306 
   307 in
   308 
   309 val empty_ss = init_ss basic_mk_rews Term.termless (K (K no_tac)) ([], []);
   310 
   311 fun clear_ss (Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   312   init_ss mk_rews termless subgoal_tac solvers;
   313 
   314 end;
   315 
   316 
   317 (* merge simpsets *)            (*NOTE: ignores some fields of 2nd simpset*)
   318 
   319 fun merge_ss (ss1, ss2) =
   320   let
   321     val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, depth},
   322      {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   323       loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   324     val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, depth = _},
   325      {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   326       loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   327 
   328     val rules' = Net.merge (rules1, rules2, eq_rrule);
   329     val prems' = gen_merge_lists Drule.eq_thm_prop prems1 prems2;
   330     val bounds' = merge_lists bounds1 bounds2;
   331     val congs' = gen_merge_lists (eq_cong o pairself #2) congs1 congs2;
   332     val weak' = merge_lists weak1 weak2;
   333     val procs' = Net.merge (procs1, procs2, eq_proc);
   334     val loop_tacs' = merge_alists loop_tacs1 loop_tacs2;
   335     val unsafe_solvers' = merge_solvers unsafe_solvers1 unsafe_solvers2;
   336     val solvers' = merge_solvers solvers1 solvers2;
   337   in
   338     make_simpset ((rules', prems', bounds', depth), ((congs', weak'), procs',
   339       mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   340   end;
   341 
   342 
   343 (* simprocs *)
   344 
   345 exception SIMPROC_FAIL of string * exn;
   346 
   347 datatype simproc = Simproc of proc list;
   348 
   349 fun mk_simproc name lhss proc =
   350   let val id = stamp () in
   351     Simproc (lhss |> map (fn lhs =>
   352       Proc {name = name, lhs = lhs, proc = proc, id = id}))
   353   end;
   354 
   355 fun simproc_i sg name = mk_simproc name o map (Thm.cterm_of sg o Logic.varify);
   356 fun simproc sg name = simproc_i sg name o map (Sign.simple_read_term sg TypeInfer.logicT);
   357 
   358 
   359 
   360 (** simpset operations **)
   361 
   362 (* bounds and prems *)
   363 
   364 fun add_bound b = map_simpset1 (fn (rules, prems, bounds, depth) =>
   365   (rules, prems, b :: bounds, depth));
   366 
   367 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, depth) =>
   368   (rules, ths @ prems, bounds, depth));
   369 
   370 fun prems_of_ss (Simpset ({prems, ...}, _)) = prems;
   371 
   372 
   373 (* addsimps *)
   374 
   375 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   376   let
   377     val fo = Pattern.first_order (term_of elhs) orelse not (Pattern.pattern (term_of elhs))
   378   in {thm = thm, name = name, lhs = lhs, elhs = elhs, fo = fo, perm = perm} end;
   379 
   380 fun insert_rrule quiet (ss, rrule as {thm, name, lhs, elhs, perm}) =
   381  (trace_named_thm "Adding rewrite rule" (thm, name);
   382   ss |> map_simpset1 (fn (rules, prems, bounds, depth) =>
   383     let
   384       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   385       val rules' = Net.insert_term ((term_of elhs, rrule2), rules, eq_rrule);
   386     in (rules', prems, bounds, depth) end)
   387   handle Net.INSERT =>
   388     (if quiet then () else warn_thm "Ignoring duplicate rewrite rule:" thm; ss));
   389 
   390 fun vperm (Var _, Var _) = true
   391   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   392   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   393   | vperm (t, u) = (t = u);
   394 
   395 fun var_perm (t, u) =
   396   vperm (t, u) andalso eq_set (term_varnames t, term_varnames u);
   397 
   398 (* FIXME: it seems that the conditions on extra variables are too liberal if
   399 prems are nonempty: does solving the prems really guarantee instantiation of
   400 all its Vars? Better: a dynamic check each time a rule is applied.
   401 *)
   402 fun rewrite_rule_extra_vars prems elhs erhs =
   403   not (term_varnames erhs subset foldl add_term_varnames (term_varnames elhs, prems))
   404   orelse
   405   not (term_tvars erhs subset (term_tvars elhs union List.concat (map term_tvars prems)));
   406 
   407 (*simple test for looping rewrite rules and stupid orientations*)
   408 fun reorient sign prems lhs rhs =
   409   rewrite_rule_extra_vars prems lhs rhs
   410     orelse
   411   is_Var (head_of lhs)
   412     orelse
   413   exists (apl (lhs, Logic.occs)) (rhs :: prems)
   414     orelse
   415   null prems andalso Pattern.matches (Sign.tsig_of sign) (lhs, rhs)
   416     (*the condition "null prems" is necessary because conditional rewrites
   417       with extra variables in the conditions may terminate although
   418       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   419     orelse
   420   is_Const lhs andalso not (is_Const rhs);
   421 
   422 fun decomp_simp thm =
   423   let
   424     val {sign, prop, ...} = Thm.rep_thm thm;
   425     val prems = Logic.strip_imp_prems prop;
   426     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   427     val (lhs, rhs) = Drule.dest_equals concl handle TERM _ =>
   428       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   429     val (_, elhs) = Drule.dest_equals (Thm.cprop_of (Thm.eta_conversion lhs));
   430     val elhs = if elhs = lhs then lhs else elhs;  (*share identical copies*)
   431     val erhs = Pattern.eta_contract (term_of rhs);
   432     val perm =
   433       var_perm (term_of elhs, erhs) andalso
   434       not (term_of elhs aconv erhs) andalso
   435       not (is_Var (term_of elhs));
   436   in (sign, prems, term_of lhs, elhs, term_of rhs, perm) end;
   437 
   438 fun decomp_simp' thm =
   439   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   440     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   441     else (lhs, rhs)
   442   end;
   443 
   444 fun mk_eq_True (Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   445   (case mk_eq_True thm of
   446     None => []
   447   | Some eq_True =>
   448       let val (_, _, lhs, elhs, _, _) = decomp_simp eq_True
   449       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   450 
   451 (*create the rewrite rule and possibly also the eq_True variant,
   452   in case there are extra vars on the rhs*)
   453 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   454   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   455     if term_varnames rhs subset term_varnames lhs andalso
   456       term_tvars rhs subset term_tvars lhs then [rrule]
   457     else mk_eq_True ss (thm2, name) @ [rrule]
   458   end;
   459 
   460 fun mk_rrule ss (thm, name) =
   461   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   462     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   463     else
   464       (*weak test for loops*)
   465       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   466       then mk_eq_True ss (thm, name)
   467       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   468   end;
   469 
   470 fun orient_rrule ss (thm, name) =
   471   let val (sign, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   472     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   473     else if reorient sign prems lhs rhs then
   474       if reorient sign prems rhs lhs
   475       then mk_eq_True ss (thm, name)
   476       else
   477         let val Simpset (_, {mk_rews = {mk_sym, ...}, ...}) = ss in
   478           (case mk_sym thm of
   479             None => []
   480           | Some thm' =>
   481               let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   482               in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   483         end
   484     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   485   end;
   486 
   487 fun extract_rews (Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   488   flat (map (fn thm => map (rpair (Thm.name_of_thm thm)) (mk thm)) thms);
   489 
   490 fun orient_comb_simps comb mk_rrule (ss, thms) =
   491   let
   492     val rews = extract_rews (ss, thms);
   493     val rrules = flat (map mk_rrule rews);
   494   in foldl comb (ss, rrules) end;
   495 
   496 fun extract_safe_rrules (ss, thm) =
   497   flat (map (orient_rrule ss) (extract_rews (ss, [thm])));
   498 
   499 (*add rewrite rules explicitly; do not reorient!*)
   500 fun ss addsimps thms =
   501   orient_comb_simps (insert_rrule false) (mk_rrule ss) (ss, thms);
   502 
   503 
   504 (* delsimps *)
   505 
   506 fun del_rrule (ss, rrule as {thm, elhs, ...}) =
   507   ss |> map_simpset1 (fn (rules, prems, bounds, depth) =>
   508     (Net.delete_term ((term_of elhs, rrule), rules, eq_rrule), prems, bounds, depth))
   509   handle Net.DELETE => (warn_thm "Rewrite rule not in simpset:" thm; ss);
   510 
   511 fun ss delsimps thms =
   512   orient_comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   513 
   514 
   515 (* congs *)
   516 
   517 fun cong_name (Const (a, _)) = Some a
   518   | cong_name (Free (a, _)) = Some ("Free: " ^ a)
   519   | cong_name _ = None;
   520 
   521 local
   522 
   523 fun is_full_cong_prems [] [] = true
   524   | is_full_cong_prems [] _ = false
   525   | is_full_cong_prems (p :: prems) varpairs =
   526       (case Logic.strip_assums_concl p of
   527         Const ("==", _) $ lhs $ rhs =>
   528           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   529             is_Var x andalso forall is_Bound xs andalso
   530             null (findrep xs) andalso xs = ys andalso
   531             (x, y) mem varpairs andalso
   532             is_full_cong_prems prems (varpairs \ (x, y))
   533           end
   534       | _ => false);
   535 
   536 fun is_full_cong thm =
   537   let
   538     val prems = prems_of thm and concl = concl_of thm;
   539     val (lhs, rhs) = Logic.dest_equals concl;
   540     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   541   in
   542     f = g andalso null (findrep (xs @ ys)) andalso length xs = length ys andalso
   543     is_full_cong_prems prems (xs ~~ ys)
   544   end;
   545 
   546 fun add_cong (ss, thm) = ss |>
   547   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   548     let
   549       val (lhs, _) = Drule.dest_equals (Drule.strip_imp_concl (Thm.cprop_of thm))
   550         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   551     (*val lhs = Pattern.eta_contract lhs;*)
   552       val a = the (cong_name (head_of (term_of lhs))) handle Library.OPTION =>
   553         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   554       val (alist, weak) = congs;
   555       val alist2 = overwrite_warn (alist, (a, {lhs = lhs, thm = thm}))
   556         ("Overwriting congruence rule for " ^ quote a);
   557       val weak2 = if is_full_cong thm then weak else a :: weak;
   558     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   559 
   560 fun del_cong (ss, thm) = ss |>
   561   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   562     let
   563       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm) handle TERM _ =>
   564         raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   565     (*val lhs = Pattern.eta_contract lhs;*)
   566       val a = the (cong_name (head_of lhs)) handle Library.OPTION =>
   567         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   568       val (alist, _) = congs;
   569       val alist2 = filter (fn (x, _) => x <> a) alist;
   570       val weak2 = alist2 |> mapfilter (fn (a, {thm, ...}) =>
   571         if is_full_cong thm then None else Some a);
   572     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   573 
   574 fun mk_cong (Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f;
   575 
   576 in
   577 
   578 val (op addeqcongs) = foldl add_cong;
   579 val (op deleqcongs) = foldl del_cong;
   580 
   581 fun ss addcongs congs = ss addeqcongs map (mk_cong ss) congs;
   582 fun ss delcongs congs = ss deleqcongs map (mk_cong ss) congs;
   583 
   584 end;
   585 
   586 
   587 (* simprocs *)
   588 
   589 local
   590 
   591 fun add_proc (ss, proc as Proc {name, lhs, ...}) =
   592  (trace_cterm false ("Adding simplification procedure " ^ quote name ^ " for") lhs;
   593   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   594     (congs, Net.insert_term ((term_of lhs, proc), procs, eq_proc),
   595       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   596   handle Net.INSERT =>
   597     (warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   598 
   599 fun del_proc (ss, proc as Proc {name, lhs, ...}) =
   600   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   601     (congs, Net.delete_term ((term_of lhs, proc), procs, eq_proc),
   602       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   603   handle Net.DELETE =>
   604     (warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   605 
   606 in
   607 
   608 val (op addsimprocs) = foldl (fn (ss, Simproc procs) => foldl add_proc (ss, procs));
   609 val (op delsimprocs) = foldl (fn (ss, Simproc procs) => foldl del_proc (ss, procs));
   610 
   611 end;
   612 
   613 
   614 (* mk_rews *)
   615 
   616 local
   617 
   618 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True},
   619       termless, subgoal_tac, loop_tacs, solvers) =>
   620   let val (mk', mk_cong', mk_sym', mk_eq_True') = f (mk, mk_cong, mk_sym, mk_eq_True) in
   621     (congs, procs, {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True'},
   622       termless, subgoal_tac, loop_tacs, solvers)
   623   end);
   624 
   625 in
   626 
   627 fun ss setmksimps mk = ss |> map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True) =>
   628   (mk, mk_cong, mk_sym, mk_eq_True));
   629 
   630 fun ss setmkcong mk_cong = ss |> map_mk_rews (fn (mk, _, mk_sym, mk_eq_True) =>
   631   (mk, mk_cong, mk_sym, mk_eq_True));
   632 
   633 fun ss setmksym mk_sym = ss |> map_mk_rews (fn (mk, mk_cong, _, mk_eq_True) =>
   634   (mk, mk_cong, mk_sym, mk_eq_True));
   635 
   636 fun ss setmkeqTrue mk_eq_True = ss |> map_mk_rews (fn (mk, mk_cong, mk_sym, _) =>
   637   (mk, mk_cong, mk_sym, mk_eq_True));
   638 
   639 end;
   640 
   641 
   642 (* termless *)
   643 
   644 fun ss settermless termless = ss |>
   645   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   646    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   647 
   648 
   649 (* tactics *)
   650 
   651 fun ss setsubgoaler subgoal_tac = ss |>
   652   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   653    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   654 
   655 fun ss setloop tac = ss |>
   656   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   657    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   658 
   659 fun ss addloop (name, tac) = ss |>
   660   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   661     (congs, procs, mk_rews, termless, subgoal_tac,
   662       overwrite_warn (loop_tacs, (name, tac)) ("Overwriting looper " ^ quote name),
   663       solvers));
   664 
   665 fun ss delloop name = ss |>
   666   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   667     let val (del, rest) = partition (fn (n, _) => n = name) loop_tacs in
   668       if null del then warning ("No such looper in simpset: " ^ quote name) else ();
   669       (congs, procs, mk_rews, termless, subgoal_tac, rest, solvers)
   670     end);
   671 
   672 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   673   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   674     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   675 
   676 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   677   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   678     subgoal_tac, loop_tacs, (unsafe_solvers, merge_solvers solvers [solver])));
   679 
   680 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   681   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   682     subgoal_tac, loop_tacs, ([solver], solvers)));
   683 
   684 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   685   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   686     subgoal_tac, loop_tacs, (merge_solvers unsafe_solvers [solver], solvers)));
   687 
   688 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   689   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   690   subgoal_tac, loop_tacs, (solvers, solvers)));
   691 
   692 
   693 
   694 (** rewriting **)
   695 
   696 (*
   697   Uses conversions, see:
   698     L C Paulson, A higher-order implementation of rewriting,
   699     Science of Computer Programming 3 (1983), pages 119-149.
   700 *)
   701 
   702 val dest_eq = Drule.dest_equals o Thm.cprop_of;
   703 val lhs_of = #1 o dest_eq;
   704 val rhs_of = #2 o dest_eq;
   705 
   706 fun check_conv msg thm thm' =
   707   let
   708     val thm'' = transitive thm (transitive
   709       (symmetric (Drule.beta_eta_conversion (lhs_of thm'))) thm')
   710   in if msg then trace_thm "SUCCEEDED" thm' else (); Some thm'' end
   711   handle THM _ =>
   712     let val {sign, prop = _ $ _ $ prop0, ...} = Thm.rep_thm thm in
   713       trace_thm "Proved wrong thm (Check subgoaler?)" thm';
   714       trace_term false "Should have proved:" sign prop0;
   715       None
   716     end;
   717 
   718 
   719 (* mk_procrule *)
   720 
   721 fun mk_procrule thm =
   722   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   723     if rewrite_rule_extra_vars prems lhs rhs
   724     then (warn_thm "Extra vars on rhs:" thm; [])
   725     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   726   end;
   727 
   728 
   729 (* rewritec: conversion to apply the meta simpset to a term *)
   730 
   731 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   732   normalized terms by carrying around the rhs of the rewrite rule just
   733   applied. This is called the `skeleton'. It is decomposed in parallel
   734   with the term. Once a Var is encountered, the corresponding term is
   735   already in normal form.
   736   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   737 
   738 val skel0 = Bound 0;
   739 
   740 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   741   The latter may happen iff there are weak congruence rules for constants
   742   in the lhs.*)
   743 
   744 fun uncond_skel ((_, weak), (lhs, rhs)) =
   745   if null weak then rhs  (*optimization*)
   746   else if exists_Const (fn (c, _) => c mem weak) lhs then skel0
   747   else rhs;
   748 
   749 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   750   Otherwise those vars may become instantiated with unnormalized terms
   751   while the premises are solved.*)
   752 
   753 fun cond_skel (args as (congs, (lhs, rhs))) =
   754   if term_varnames rhs subset term_varnames lhs then uncond_skel args
   755   else skel0;
   756 
   757 fun incr_depth ss =
   758   let
   759     val ss' = ss |> map_simpset1 (fn (rules, prems, bounds, depth) =>
   760       (rules, prems, bounds, depth + 1));
   761     val Simpset ({depth = depth', ...}, _) = ss';
   762   in
   763     if depth' > ! simp_depth_limit
   764     then (warning "simp_depth_limit exceeded - giving up"; None)
   765     else
   766      (if depth' mod 10 = 0
   767       then warning ("Simplification depth " ^ string_of_int depth')
   768       else ();
   769       Some ss')
   770   end;
   771 
   772 (*
   773   Rewriting -- we try in order:
   774     (1) beta reduction
   775     (2) unconditional rewrite rules
   776     (3) conditional rewrite rules
   777     (4) simplification procedures
   778 
   779   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   780 *)
   781 
   782 fun rewritec (prover, signt, maxt) ss t =
   783   let
   784     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   785     val eta_thm = Thm.eta_conversion t;
   786     val eta_t' = rhs_of eta_thm;
   787     val eta_t = term_of eta_t';
   788     val tsigt = Sign.tsig_of signt;
   789     fun rew {thm, name, lhs, elhs, fo, perm} =
   790       let
   791         val {sign, prop, maxidx, ...} = rep_thm thm;
   792         val _ = if Sign.subsig (sign, signt) then ()
   793                 else (warn_thm "Ignoring rewrite rule from different theory:" thm;
   794                       raise Pattern.MATCH);
   795         val (rthm, elhs') = if maxt = ~1 then (thm, elhs)
   796           else (Thm.incr_indexes (maxt+1) thm, Thm.cterm_incr_indexes (maxt+1) elhs);
   797         val insts = if fo then Thm.cterm_first_order_match (elhs', eta_t')
   798                           else Thm.cterm_match (elhs', eta_t');
   799         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   800         val prop' = Thm.prop_of thm';
   801         val unconditional = (Logic.count_prems (prop',0) = 0);
   802         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   803       in
   804         if perm andalso not (termless (rhs', lhs'))
   805         then (trace_named_thm "Cannot apply permutative rewrite rule" (thm, name);
   806               trace_thm "Term does not become smaller:" thm'; None)
   807         else (trace_named_thm "Applying instance of rewrite rule" (thm, name);
   808            if unconditional
   809            then
   810              (trace_thm "Rewriting:" thm';
   811               let val lr = Logic.dest_equals prop;
   812                   val Some thm'' = check_conv false eta_thm thm'
   813               in Some (thm'', uncond_skel (congs, lr)) end)
   814            else
   815              (trace_thm "Trying to rewrite:" thm';
   816               case incr_depth ss of
   817                 None => (trace_thm "FAILED - reached depth limit" thm'; None)
   818               | Some ss' =>
   819               (case prover ss' thm' of
   820                 None => (trace_thm "FAILED" thm'; None)
   821               | Some thm2 =>
   822                   (case check_conv true eta_thm thm2 of
   823                      None => None |
   824                      Some thm2' =>
   825                        let val concl = Logic.strip_imp_concl prop
   826                            val lr = Logic.dest_equals concl
   827                        in Some (thm2', cond_skel (congs, lr)) end))))
   828       end
   829 
   830     fun rews [] = None
   831       | rews (rrule :: rrules) =
   832           let val opt = rew rrule handle Pattern.MATCH => None
   833           in case opt of None => rews rrules | some => some end;
   834 
   835     fun sort_rrules rrs = let
   836       fun is_simple({thm, ...}:rrule) = case Thm.prop_of thm of
   837                                       Const("==",_) $ _ $ _ => true
   838                                       | _                   => false
   839       fun sort []        (re1,re2) = re1 @ re2
   840         | sort (rr::rrs) (re1,re2) = if is_simple rr
   841                                      then sort rrs (rr::re1,re2)
   842                                      else sort rrs (re1,rr::re2)
   843     in sort rrs ([],[]) end
   844 
   845     fun proc_rews [] = None
   846       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   847           if Pattern.matches tsigt (Thm.term_of lhs, Thm.term_of t) then
   848             (debug_term false ("Trying procedure " ^ quote name ^ " on:") signt eta_t;
   849              case transform_failure (curry SIMPROC_FAIL name)
   850                  (fn () => proc signt ss eta_t) () of
   851                None => (debug false "FAILED"; proc_rews ps)
   852              | Some raw_thm =>
   853                  (trace_thm ("Procedure " ^ quote name ^ " produced rewrite rule:") raw_thm;
   854                   (case rews (mk_procrule raw_thm) of
   855                     None => (trace_cterm true ("IGNORED result of simproc " ^ quote name ^
   856                       " -- does not match") t; proc_rews ps)
   857                   | some => some)))
   858           else proc_rews ps;
   859   in case eta_t of
   860        Abs _ $ _ => Some (transitive eta_thm
   861          (beta_conversion false eta_t'), skel0)
   862      | _ => (case rews (sort_rrules (Net.match_term rules eta_t)) of
   863                None => proc_rews (Net.match_term procs eta_t)
   864              | some => some)
   865   end;
   866 
   867 
   868 (* conversion to apply a congruence rule to a term *)
   869 
   870 fun congc (prover,signt,maxt) {thm=cong,lhs=lhs} t =
   871   let val sign = Thm.sign_of_thm cong
   872       val _ = if Sign.subsig (sign, signt) then ()
   873                  else error("Congruence rule from different theory")
   874       val rthm = if maxt = ~1 then cong else Thm.incr_indexes (maxt+1) cong;
   875       val rlhs = fst (Drule.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   876       val insts = Thm.cterm_match (rlhs, t)
   877       (* Pattern.match can raise Pattern.MATCH;
   878          is handled when congc is called *)
   879       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
   880       val unit = trace_thm "Applying congruence rule:" thm';
   881       fun err (msg, thm) = (trace_thm msg thm; None)
   882   in case prover thm' of
   883        None => err ("Congruence proof failed.  Could not prove", thm')
   884      | Some thm2 => (case check_conv true (Drule.beta_eta_conversion t) thm2 of
   885           None => err ("Congruence proof failed.  Should not have proved", thm2)
   886         | Some thm2' =>
   887             if op aconv (pairself term_of (dest_equals (cprop_of thm2')))
   888             then None else Some thm2')
   889   end;
   890 
   891 val (cA, (cB, cC)) =
   892   apsnd dest_equals (dest_implies (hd (cprems_of Drule.imp_cong)));
   893 
   894 fun transitive1 None None = None
   895   | transitive1 (Some thm1) None = Some thm1
   896   | transitive1 None (Some thm2) = Some thm2
   897   | transitive1 (Some thm1) (Some thm2) = Some (transitive thm1 thm2)
   898 
   899 fun transitive2 thm = transitive1 (Some thm);
   900 fun transitive3 thm = transitive1 thm o Some;
   901 
   902 fun bottomc ((simprem, useprem, mutsimp), prover, sign, maxidx) =
   903   let
   904     fun botc skel ss t =
   905           if is_Var skel then None
   906           else
   907           (case subc skel ss t of
   908              some as Some thm1 =>
   909                (case rewritec (prover, sign, maxidx) ss (rhs_of thm1) of
   910                   Some (thm2, skel2) =>
   911                     transitive2 (transitive thm1 thm2)
   912                       (botc skel2 ss (rhs_of thm2))
   913                 | None => some)
   914            | None =>
   915                (case rewritec (prover, sign, maxidx) ss t of
   916                   Some (thm2, skel2) => transitive2 thm2
   917                     (botc skel2 ss (rhs_of thm2))
   918                 | None => None))
   919 
   920     and try_botc ss t =
   921           (case botc skel0 ss t of
   922              Some trec1 => trec1 | None => (reflexive t))
   923 
   924     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
   925        (case term_of t0 of
   926            Abs (a, T, t) =>
   927              let
   928                  val b = variant bounds a;
   929                  val (v, t') = Thm.dest_abs (Some ("." ^ b)) t0;
   930                  val ss' = add_bound b ss;
   931                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
   932              in case botc skel' ss' t' of
   933                   Some thm => Some (abstract_rule a v thm)
   934                 | None => None
   935              end
   936          | t $ _ => (case t of
   937              Const ("==>", _) $ _  => impc t0 ss
   938            | Abs _ =>
   939                let val thm = beta_conversion false t0
   940                in case subc skel0 ss (rhs_of thm) of
   941                     None => Some thm
   942                   | Some thm' => Some (transitive thm thm')
   943                end
   944            | _  =>
   945                let fun appc () =
   946                      let
   947                        val (tskel, uskel) = case skel of
   948                            tskel $ uskel => (tskel, uskel)
   949                          | _ => (skel0, skel0);
   950                        val (ct, cu) = Thm.dest_comb t0
   951                      in
   952                      (case botc tskel ss ct of
   953                         Some thm1 =>
   954                           (case botc uskel ss cu of
   955                              Some thm2 => Some (combination thm1 thm2)
   956                            | None => Some (combination thm1 (reflexive cu)))
   957                       | None =>
   958                           (case botc uskel ss cu of
   959                              Some thm1 => Some (combination (reflexive ct) thm1)
   960                            | None => None))
   961                      end
   962                    val (h, ts) = strip_comb t
   963                in case cong_name h of
   964                     Some a =>
   965                       (case assoc_string (fst congs, a) of
   966                          None => appc ()
   967                        | Some cong =>
   968   (*post processing: some partial applications h t1 ... tj, j <= length ts,
   969     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
   970                           (let
   971                              val thm = congc (prover ss, sign, maxidx) cong t0;
   972                              val t = if_none (apsome rhs_of thm) t0;
   973                              val (cl, cr) = Thm.dest_comb t
   974                              val dVar = Var(("", 0), dummyT)
   975                              val skel =
   976                                list_comb (h, replicate (length ts) dVar)
   977                            in case botc skel ss cl of
   978                                 None => thm
   979                               | Some thm' => transitive3 thm
   980                                   (combination thm' (reflexive cr))
   981                            end handle TERM _ => error "congc result"
   982                                     | Pattern.MATCH => appc ()))
   983                   | _ => appc ()
   984                end)
   985          | _ => None)
   986 
   987     and impc ct ss =
   988       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
   989 
   990     and rules_of_prem ss prem =
   991       if maxidx_of_term (term_of prem) <> ~1
   992       then (trace_cterm true
   993         "Cannot add premise as rewrite rule because it contains (type) unknowns:" prem; ([], None))
   994       else
   995         let val asm = assume prem
   996         in (extract_safe_rrules (ss, asm), Some asm) end
   997 
   998     and add_rrules (rrss, asms) ss =
   999       foldl (insert_rrule true) (ss, flat rrss) |> add_prems (mapfilter I asms)
  1000 
  1001     and disch r (prem, eq) =
  1002       let
  1003         val (lhs, rhs) = dest_eq eq;
  1004         val eq' = implies_elim (Thm.instantiate
  1005           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1006           (implies_intr prem eq)
  1007       in if not r then eq' else
  1008         let
  1009           val (prem', concl) = dest_implies lhs;
  1010           val (prem'', _) = dest_implies rhs
  1011         in transitive (transitive
  1012           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1013              Drule.swap_prems_eq) eq')
  1014           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1015              Drule.swap_prems_eq)
  1016         end
  1017       end
  1018 
  1019     and rebuild [] _ _ _ _ eq = eq
  1020       | rebuild (prem :: prems) concl (rrs :: rrss) (asm :: asms) ss eq =
  1021           let
  1022             val ss' = add_rrules (rev rrss, rev asms) ss;
  1023             val concl' =
  1024               Drule.mk_implies (prem, if_none (apsome rhs_of eq) concl);
  1025             val dprem = apsome (curry (disch false) prem)
  1026           in case rewritec (prover, sign, maxidx) ss' concl' of
  1027               None => rebuild prems concl' rrss asms ss (dprem eq)
  1028             | Some (eq', _) => transitive2 (foldl (disch false o swap)
  1029                   (the (transitive3 (dprem eq) eq'), prems))
  1030                 (mut_impc0 (rev prems) (rhs_of eq') (rev rrss) (rev asms) ss)
  1031           end
  1032 
  1033     and mut_impc0 prems concl rrss asms ss =
  1034       let
  1035         val prems' = strip_imp_prems concl;
  1036         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1037       in mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1038         (asms @ asms') [] [] [] [] ss ~1 ~1
  1039       end
  1040 
  1041     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1042         transitive1 (foldl (fn (eq2, (eq1, prem)) => transitive1 eq1
  1043             (apsome (curry (disch false) prem) eq2)) (None, eqns ~~ prems'))
  1044           (if changed > 0 then
  1045              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1046                [] [] [] [] ss ~1 changed
  1047            else rebuild prems' concl rrss' asms' ss
  1048              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1049 
  1050       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1051           prems' rrss' asms' eqns ss changed k =
  1052         case (if k = 0 then None else botc skel0 (add_rrules
  1053           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1054             None => mut_impc prems concl rrss asms (prem :: prems')
  1055               (rrs :: rrss') (asm :: asms') (None :: eqns) ss changed
  1056               (if k = 0 then 0 else k - 1)
  1057           | Some eqn =>
  1058             let
  1059               val prem' = rhs_of eqn;
  1060               val tprems = map term_of prems;
  1061               val i = 1 + foldl Int.max (~1, map (fn p =>
  1062                 find_index_eq p tprems) (#hyps (rep_thm eqn)));
  1063               val (rrs', asm') = rules_of_prem ss prem'
  1064             in mut_impc prems concl rrss asms (prem' :: prems')
  1065               (rrs' :: rrss') (asm' :: asms') (Some (foldr (disch true)
  1066                 (take (i, prems), Drule.imp_cong' eqn (reflexive (Drule.list_implies
  1067                   (drop (i, prems), concl))))) :: eqns) ss (length prems') ~1
  1068             end
  1069 
  1070      (*legacy code - only for backwards compatibility*)
  1071      and nonmut_impc ct ss =
  1072        let val (prem, conc) = dest_implies ct;
  1073            val thm1 = if simprem then botc skel0 ss prem else None;
  1074            val prem1 = if_none (apsome rhs_of thm1) prem;
  1075            val ss1 = if not useprem then ss else add_rrules
  1076              (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1077        in (case botc skel0 ss1 conc of
  1078            None => (case thm1 of
  1079                None => None
  1080              | Some thm1' => Some (Drule.imp_cong' thm1' (reflexive conc)))
  1081          | Some thm2 =>
  1082            let val thm2' = disch false (prem1, thm2)
  1083            in (case thm1 of
  1084                None => Some thm2'
  1085              | Some thm1' =>
  1086                  Some (transitive (Drule.imp_cong' thm1' (reflexive conc)) thm2'))
  1087            end)
  1088        end
  1089 
  1090  in try_botc end;
  1091 
  1092 
  1093 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1094 
  1095 (*
  1096   Parameters:
  1097     mode = (simplify A,
  1098             use A in simplifying B,
  1099             use prems of B (if B is again a meta-impl.) to simplify A)
  1100            when simplifying A ==> B
  1101     prover: how to solve premises in conditional rewrites and congruences
  1102 *)
  1103 
  1104 fun rewrite_cterm mode prover ss ct =
  1105   let
  1106     val Simpset ({depth, ...}, _) = ss;
  1107     val {sign, t, maxidx, ...} = Thm.rep_cterm ct;
  1108   in
  1109     trace_cterm false "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:" ct;
  1110     simp_depth := depth;
  1111     bottomc (mode, prover, sign, maxidx) ss ct
  1112   end handle THM (s, _, thms) =>
  1113     error ("Exception THM was raised in simplifier:\n" ^ s ^ "\n" ^
  1114       Pretty.string_of (Display.pretty_thms thms));
  1115 
  1116 (*Rewrite a cterm*)
  1117 fun rewrite_aux _ _ [] = (fn ct => Thm.reflexive ct)
  1118   | rewrite_aux prover full thms =
  1119       rewrite_cterm (full, false, false) prover (empty_ss addsimps thms);
  1120 
  1121 (*Rewrite a theorem*)
  1122 fun simplify_aux _ _ [] = (fn th => th)
  1123   | simplify_aux prover full thms =
  1124       Drule.fconv_rule (rewrite_cterm (full, false, false) prover (empty_ss addsimps thms));
  1125 
  1126 (*simple term rewriting -- no proof*)
  1127 fun rewrite_term sg rules procs =
  1128   Pattern.rewrite_term (Sign.tsig_of sg) (map decomp_simp' rules) procs;
  1129 
  1130 fun rewrite_thm mode prover ss = Drule.fconv_rule (rewrite_cterm mode prover ss);
  1131 
  1132 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
  1133 fun rewrite_goals_rule_aux _ []   th = th
  1134   | rewrite_goals_rule_aux prover thms th =
  1135       Drule.fconv_rule (Drule.goals_conv (K true) (rewrite_cterm (true, true, false) prover
  1136         (empty_ss addsimps thms))) th;
  1137 
  1138 (*Rewrite the subgoal of a proof state (represented by a theorem)*)
  1139 fun rewrite_goal_rule mode prover ss i thm =
  1140   if 0 < i  andalso  i <= nprems_of thm
  1141   then Drule.fconv_rule (Drule.goals_conv (fn j => j=i) (rewrite_cterm mode prover ss)) thm
  1142   else raise THM("rewrite_goal_rule",i,[thm]);
  1143 
  1144 (*Rewrite subgoal i only.  SELECT_GOAL avoids inefficiencies in goals_conv.*)
  1145 fun asm_rewrite_goal_tac mode prover_tac ss =
  1146   SELECT_GOAL
  1147     (PRIMITIVE (rewrite_goal_rule mode (SINGLE o prover_tac) ss 1));
  1148 
  1149 
  1150 
  1151 (** simplification tactics and rules **)
  1152 
  1153 fun solve_all_tac solvers ss =
  1154   let
  1155     val Simpset (_, {subgoal_tac, ...}) = ss;
  1156     val solve_tac = subgoal_tac (set_solvers solvers ss) THEN_ALL_NEW (K no_tac);
  1157   in DEPTH_SOLVE (solve_tac 1) end;
  1158 
  1159 (*NOTE: may instantiate unknowns that appear also in other subgoals*)
  1160 fun generic_simp_tac safe mode ss =
  1161   let
  1162     val Simpset ({prems, ...}, {loop_tacs, solvers = (unsafe_solvers, solvers), ...}) = ss;
  1163     val loop_tac = FIRST' (map #2 loop_tacs);
  1164     val solve_tac = FIRST' (map (solver prems) (if safe then solvers else unsafe_solvers));
  1165 
  1166     fun simp_loop_tac i =
  1167       asm_rewrite_goal_tac mode (solve_all_tac unsafe_solvers) ss i THEN
  1168       (solve_tac i ORELSE TRY ((loop_tac THEN_ALL_NEW simp_loop_tac) i));
  1169   in simp_loop_tac end;
  1170 
  1171 fun simp rew mode ss thm =
  1172   let
  1173     val Simpset (_, {solvers = (unsafe_solvers, _), ...}) = ss;
  1174     val tacf = solve_all_tac unsafe_solvers;
  1175     fun prover s th = apsome #1 (Seq.pull (tacf s th));
  1176   in rew mode prover ss thm end;
  1177 
  1178 val simp_thm = simp rewrite_thm;
  1179 val simp_cterm = simp rewrite_cterm;
  1180 
  1181 end;
  1182 
  1183 structure BasicMetaSimplifier: BASIC_META_SIMPLIFIER = MetaSimplifier;
  1184 open BasicMetaSimplifier;