src/Pure/axclass.ML
author paulson
Mon Dec 07 18:26:25 1998 +0100 (1998-12-07)
changeset 6019 0e55c2fb2ebb
parent 5685 1e5b4c66317f
child 6084 842b059e023f
permissions -rw-r--r--
tidying
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 User interfaces for axiomatic type classes.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val add_classrel_thms: thm list -> theory -> theory
    12   val add_arity_thms: thm list -> theory -> theory
    13   val add_axclass: bclass * xclass list -> (string * string) list
    14     -> theory -> theory
    15   val add_axclass_i: bclass * class list -> (string * term) list
    16     -> theory -> theory
    17   val add_inst_subclass: xclass * xclass -> string list -> thm list
    18     -> tactic option -> theory -> theory
    19   val add_inst_subclass_i: class * class -> string list -> thm list
    20     -> tactic option -> theory -> theory
    21   val add_inst_arity: xstring * xsort list * xclass list -> string list
    22     -> thm list -> tactic option -> theory -> theory
    23   val add_inst_arity_i: string * sort list * class list -> string list
    24     -> thm list -> tactic option -> theory -> theory
    25   val axclass_tac: theory -> thm list -> tactic
    26   val prove_subclass: theory -> class * class -> thm list
    27     -> tactic option -> thm
    28   val prove_arity: theory -> string * sort list * class -> thm list
    29     -> tactic option -> thm
    30   val goal_subclass: theory -> xclass * xclass -> thm list
    31   val goal_arity: theory -> xstring * xsort list * xclass -> thm list
    32 end;
    33 
    34 structure AxClass : AX_CLASS =
    35 struct
    36 
    37 
    38 (** utilities **)
    39 
    40 (* messages *)
    41 
    42 val quiet_mode = ref false;
    43 fun message s = if ! quiet_mode then () else writeln s;
    44 
    45 
    46 (* type vars *)
    47 
    48 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    49   | map_typ_frees f (TFree a) = f a
    50   | map_typ_frees _ a = a;
    51 
    52 val map_term_tfrees = map_term_types o map_typ_frees;
    53 
    54 fun aT S = TFree ("'a", S);
    55 
    56 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    57   | dest_varT (TVar xi_S) = xi_S
    58   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    59 
    60 
    61 (* get axioms and theorems *)
    62 
    63 fun get_ax thy name =
    64   Some (get_axiom thy name) handle THEORY _ => None;
    65 
    66 val get_axioms = mapfilter o get_ax;
    67 
    68 val is_def = Logic.is_equals o #prop o rep_thm;
    69 
    70 fun witnesses thy names thms =
    71   flat (map (PureThy.get_thms thy) names) @ thms @ filter is_def (map snd (axioms_of thy));
    72 
    73 
    74 
    75 (** abstract syntax operations **)
    76 
    77 (* subclass relations as terms *)
    78 
    79 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    80 
    81 fun dest_classrel tm =
    82   let
    83     fun err () = raise TERM ("dest_classrel", [tm]);
    84 
    85     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    86     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    87       handle TYPE _ => err ();
    88   in
    89     (c1, c2)
    90   end;
    91 
    92 
    93 (* arities as terms *)
    94 
    95 fun mk_arity (t, ss, c) =
    96   let
    97     val names = tl (variantlist (replicate (length ss + 1) "'", []));
    98     val tfrees = ListPair.map TFree (names, ss);
    99   in
   100     Logic.mk_inclass (Type (t, tfrees), c)
   101   end;
   102 
   103 fun dest_arity tm =
   104   let
   105     fun err () = raise TERM ("dest_arity", [tm]);
   106 
   107     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   108     val (t, tvars) =
   109       (case ty of
   110         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   111       | _ => err ());
   112     val ss =
   113       if null (gen_duplicates eq_fst tvars)
   114       then map snd tvars else err ();
   115   in
   116     (t, ss, c)
   117   end;
   118 
   119 
   120 
   121 (** add theorems as axioms **)
   122 
   123 fun prep_thm_axm thy thm =
   124   let
   125     fun err msg = raise THM ("prep_thm_axm: " ^ msg, 0, [thm]);
   126 
   127     val {sign, hyps, prop, ...} = rep_thm thm;
   128   in
   129     if not (Sign.subsig (sign, sign_of thy)) then
   130       err "theorem not of same theory"
   131     else if not (null (extra_shyps thm)) orelse not (null hyps) then
   132       err "theorem may not contain hypotheses"
   133     else prop
   134   end;
   135 
   136 (*theorems expressing class relations*)
   137 fun add_classrel_thms thms thy =
   138   let
   139     fun prep_thm thm =
   140       let
   141         val prop = prep_thm_axm thy thm;
   142         val (c1, c2) = dest_classrel prop handle TERM _ =>
   143           raise THM ("add_classrel_thms: theorem is not a class relation", 0, [thm]);
   144       in (c1, c2) end;
   145   in
   146     Theory.add_classrel (map prep_thm thms) thy
   147   end;
   148 
   149 (*theorems expressing arities*)
   150 fun add_arity_thms thms thy =
   151   let
   152     fun prep_thm thm =
   153       let
   154         val prop = prep_thm_axm thy thm;
   155         val (t, ss, c) = dest_arity prop handle TERM _ =>
   156           raise THM ("add_arity_thms: theorem is not an arity", 0, [thm]);
   157       in (t, ss, [c]) end;
   158   in
   159     Theory.add_arities (map prep_thm thms) thy
   160   end;
   161 
   162 
   163 
   164 (** add axiomatic type classes **)
   165 
   166 (* errors *)
   167 
   168 fun err_not_logic c =
   169   error ("Axiomatic class " ^ quote c ^ " not subclass of " ^ quote logicC);
   170 
   171 fun err_bad_axsort ax c =
   172   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   173 
   174 fun err_bad_tfrees ax =
   175   error ("More than one type variable in axiom " ^ quote ax);
   176 
   177 
   178 (* ext_axclass *)
   179 
   180 fun ext_axclass int prep_axm (raw_class, raw_super_classes) raw_axioms old_thy =
   181   let
   182     val old_sign = sign_of old_thy;
   183     val axioms = map (prep_axm old_sign) raw_axioms;
   184     val class = Sign.full_name old_sign raw_class;
   185 
   186     val thy =
   187       (if int then Theory.add_classes else Theory.add_classes_i)
   188         [(raw_class, raw_super_classes)] old_thy;
   189     val sign = sign_of thy;
   190     val super_classes =
   191       if int then map (Sign.intern_class sign) raw_super_classes
   192       else raw_super_classes;
   193 
   194 
   195     (* prepare abstract axioms *)
   196 
   197     fun abs_axm ax =
   198       if null (term_tfrees ax) then
   199         Logic.mk_implies (Logic.mk_inclass (aT logicS, class), ax)
   200       else map_term_tfrees (K (aT [class])) ax;
   201 
   202     val abs_axioms = map (apsnd abs_axm) axioms;
   203 
   204 
   205     (* prepare introduction orule *)
   206 
   207     val _ =
   208       if Sign.subsort sign ([class], logicS) then ()
   209       else err_not_logic class;
   210 
   211     fun axm_sort (name, ax) =
   212       (case term_tfrees ax of
   213         [] => []
   214       | [(_, S)] =>
   215           if Sign.subsort sign ([class], S) then S
   216           else err_bad_axsort name class
   217       | _ => err_bad_tfrees name);
   218 
   219     val axS = Sign.norm_sort sign (logicC :: flat (map axm_sort axioms))
   220 
   221     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   222     fun inclass c = Logic.mk_inclass (aT axS, c);
   223 
   224     val intro_axm = Logic.list_implies
   225       (map inclass super_classes @ map (int_axm o snd) axioms, inclass class);
   226   in
   227     thy
   228     |> PureThy.add_axioms_i (map Attribute.none ((raw_class ^ "I", intro_axm) :: abs_axioms))
   229   end;
   230 
   231 
   232 (* external interfaces *)
   233 
   234 val add_axclass = ext_axclass true read_axm;
   235 val add_axclass_i = ext_axclass false cert_axm;
   236 
   237 
   238 
   239 (** prove class relations and type arities **)
   240 
   241 (* class_axms *)
   242 
   243 fun class_axms thy =
   244   let
   245     val classes = Sign.classes (sign_of thy);
   246     val intros = map (fn c => c ^ "I") classes;
   247   in
   248     map (class_triv thy) classes @
   249     get_axioms thy intros
   250   end;
   251 
   252 
   253 (* axclass_tac *)
   254 
   255 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   256       try class_trivs first, then "cI" axioms
   257   (2) rewrite goals using user supplied definitions
   258   (3) repeatedly resolve goals with user supplied non-definitions*)
   259 
   260 fun axclass_tac thy thms =
   261   let
   262     val defs = filter is_def thms;
   263     val non_defs = filter_out is_def thms;
   264   in
   265     TRY (REPEAT_FIRST (resolve_tac (class_axms thy))) THEN
   266     TRY (rewrite_goals_tac defs) THEN
   267     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   268   end;
   269 
   270 
   271 (* provers *)
   272 
   273 fun prove term_of str_of thy sig_prop thms usr_tac =
   274   let
   275     val sign = sign_of thy;
   276     val goal = cterm_of sign (term_of sig_prop);
   277     val tac = axclass_tac thy thms THEN (if_none usr_tac all_tac);
   278   in
   279     prove_goalw_cterm [] goal (K [tac])
   280   end
   281   handle ERROR => error ("The error(s) above occurred while trying to prove "
   282     ^ quote (str_of (sign_of thy, sig_prop)));
   283 
   284 val prove_subclass =
   285   prove mk_classrel (fn (sg, c1_c2) => Sign.str_of_classrel sg c1_c2);
   286 
   287 val prove_arity =
   288   prove mk_arity (fn (sg, (t, Ss, c)) => Sign.str_of_arity sg (t, Ss, [c]));
   289 
   290 
   291 
   292 (** add proved subclass relations and arities **)
   293 
   294 fun intrn_classrel sg c1_c2 =
   295   pairself (Sign.intern_class sg) c1_c2;
   296 
   297 fun ext_inst_subclass int raw_c1_c2 names thms usr_tac thy =
   298   let
   299     val c1_c2 =
   300       if int then intrn_classrel (sign_of thy) raw_c1_c2
   301       else raw_c1_c2;
   302   in
   303     message ("Proving class inclusion " ^
   304       quote (Sign.str_of_classrel (sign_of thy) c1_c2) ^ " ...");
   305     add_classrel_thms
   306       [prove_subclass thy c1_c2 (witnesses thy names thms) usr_tac] thy
   307   end;
   308 
   309 
   310 fun intrn_arity sg intrn (t, Ss, x) =
   311   (Sign.intern_tycon sg t, map (Sign.intern_sort sg) Ss, intrn sg x);
   312 
   313 fun ext_inst_arity int (raw_t, raw_Ss, raw_cs) names thms usr_tac thy =
   314   let
   315     val sign = sign_of thy;
   316     val (t, Ss, cs) =
   317       if int then intrn_arity sign Sign.intern_sort (raw_t, raw_Ss, raw_cs)
   318       else (raw_t, raw_Ss, raw_cs);
   319     val wthms = witnesses thy names thms;
   320     fun prove c =
   321      (message ("Proving type arity " ^
   322         quote (Sign.str_of_arity sign (t, Ss, [c])) ^ " ...");
   323         prove_arity thy (t, Ss, c) wthms usr_tac);
   324   in
   325     add_arity_thms (map prove cs) thy
   326   end;
   327 
   328 val add_inst_subclass = ext_inst_subclass true;
   329 val add_inst_subclass_i = ext_inst_subclass false;
   330 val add_inst_arity = ext_inst_arity true;
   331 val add_inst_arity_i = ext_inst_arity false;
   332 
   333 
   334 (* make goals (for interactive use) *)
   335 
   336 fun mk_goal term_of thy sig_prop =
   337   goalw_cterm [] (cterm_of (sign_of thy) (term_of sig_prop));
   338 
   339 fun goal_subclass thy =
   340   mk_goal (mk_classrel o intrn_classrel (sign_of thy)) thy;
   341 
   342 fun goal_arity thy =
   343   mk_goal (mk_arity o intrn_arity (sign_of thy) Sign.intern_class) thy;
   344 
   345 
   346 end;