src/HOL/HOL.thy
author nipkow
Tue Sep 20 05:47:11 2011 +0200 (2011-09-20)
changeset 45014 0e847655b2d8
parent 44921 58eef4843641
child 45133 2214ba5bdfff
permissions -rw-r--r--
New proof method "induction" that gives induction hypotheses the name IH.
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Tools/intuitionistic.ML"
    16   "~~/src/Tools/project_rule.ML"
    17   "~~/src/Tools/cong_tac.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Tools/coherent.ML"
    24   "~~/src/Tools/eqsubst.ML"
    25   "~~/src/Provers/quantifier1.ML"
    26   ("Tools/simpdata.ML")
    27   "~~/src/Tools/atomize_elim.ML"
    28   "~~/src/Tools/induct.ML"
    29   ("~~/src/Tools/induction.ML")
    30   ("~~/src/Tools/induct_tacs.ML")
    31   ("Tools/recfun_codegen.ML")
    32   ("Tools/cnf_funcs.ML")
    33   "~~/src/Tools/subtyping.ML"
    34   "~~/src/Tools/case_product.ML"
    35 begin
    36 
    37 setup {* Intuitionistic.method_setup @{binding iprover} *}
    38 setup Subtyping.setup
    39 setup Case_Product.setup
    40 
    41 
    42 subsection {* Primitive logic *}
    43 
    44 subsubsection {* Core syntax *}
    45 
    46 classes type
    47 default_sort type
    48 setup {* Object_Logic.add_base_sort @{sort type} *}
    49 
    50 arities
    51   "fun" :: (type, type) type
    52   itself :: (type) type
    53 
    54 typedecl bool
    55 
    56 judgment
    57   Trueprop      :: "bool => prop"                   ("(_)" 5)
    58 
    59 consts
    60   True          :: bool
    61   False         :: bool
    62   Not           :: "bool => bool"                   ("~ _" [40] 40)
    63 
    64   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    65   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    66   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)
    67 
    68   eq            :: "['a, 'a] => bool"               (infixl "=" 50)
    69 
    70   The           :: "('a => bool) => 'a"
    71   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    72   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    73   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    74 
    75 
    76 subsubsection {* Additional concrete syntax *}
    77 
    78 notation (output)
    79   eq  (infix "=" 50)
    80 
    81 abbreviation
    82   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    83   "x ~= y == ~ (x = y)"
    84 
    85 notation (output)
    86   not_equal  (infix "~=" 50)
    87 
    88 notation (xsymbols)
    89   Not  ("\<not> _" [40] 40) and
    90   conj  (infixr "\<and>" 35) and
    91   disj  (infixr "\<or>" 30) and
    92   implies  (infixr "\<longrightarrow>" 25) and
    93   not_equal  (infix "\<noteq>" 50)
    94 
    95 notation (HTML output)
    96   Not  ("\<not> _" [40] 40) and
    97   conj  (infixr "\<and>" 35) and
    98   disj  (infixr "\<or>" 30) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 abbreviation (iff)
   102   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   103   "A <-> B == A = B"
   104 
   105 notation (xsymbols)
   106   iff  (infixr "\<longleftrightarrow>" 25)
   107 
   108 nonterminal letbinds and letbind
   109 nonterminal case_pat and case_syn and cases_syn
   110 
   111 syntax
   112   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   113 
   114   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   115   ""            :: "letbind => letbinds"                 ("_")
   116   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   117   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   118 
   119   "_case_syntax"      :: "['a, cases_syn] => 'b"              ("(case _ of/ _)" 10)
   120   "_case1"            :: "[case_pat, 'b] => case_syn"         ("(2_ =>/ _)" 10)
   121   ""                  :: "case_syn => cases_syn"              ("_")
   122   "_case2"            :: "[case_syn, cases_syn] => cases_syn" ("_/ | _")
   123   "_strip_positions"  :: "'a => case_pat"                     ("_")
   124 
   125 syntax (xsymbols)
   126   "_case1" :: "[case_pat, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   127 
   128 translations
   129   "THE x. P"              == "CONST The (%x. P)"
   130 
   131 print_translation {*
   132   [(@{const_syntax The}, fn [Abs abs] =>
   133       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   134       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   135 *}  -- {* To avoid eta-contraction of body *}
   136 
   137 notation (xsymbols)
   138   All  (binder "\<forall>" 10) and
   139   Ex  (binder "\<exists>" 10) and
   140   Ex1  (binder "\<exists>!" 10)
   141 
   142 notation (HTML output)
   143   All  (binder "\<forall>" 10) and
   144   Ex  (binder "\<exists>" 10) and
   145   Ex1  (binder "\<exists>!" 10)
   146 
   147 notation (HOL)
   148   All  (binder "! " 10) and
   149   Ex  (binder "? " 10) and
   150   Ex1  (binder "?! " 10)
   151 
   152 
   153 subsubsection {* Axioms and basic definitions *}
   154 
   155 axioms
   156   refl:           "t = (t::'a)"
   157   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   158   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   159     -- {*Extensionality is built into the meta-logic, and this rule expresses
   160          a related property.  It is an eta-expanded version of the traditional
   161          rule, and similar to the ABS rule of HOL*}
   162 
   163   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   164 
   165   impI:           "(P ==> Q) ==> P-->Q"
   166   mp:             "[| P-->Q;  P |] ==> Q"
   167 
   168 
   169 defs
   170   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   171   All_def:      "All(P)    == (P = (%x. True))"
   172   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   173   False_def:    "False     == (!P. P)"
   174   not_def:      "~ P       == P-->False"
   175   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   176   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   177   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   178 
   179 axioms
   180   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   181   True_or_False:  "(P=True) | (P=False)"
   182 
   183 finalconsts
   184   eq
   185   implies
   186   The
   187 
   188 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10) where
   189   "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   190 
   191 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b" where
   192   "Let s f \<equiv> f s"
   193 
   194 translations
   195   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   196   "let x = a in e"        == "CONST Let a (%x. e)"
   197 
   198 axiomatization
   199   undefined :: 'a
   200 
   201 class default =
   202   fixes default :: 'a
   203 
   204 
   205 subsection {* Fundamental rules *}
   206 
   207 subsubsection {* Equality *}
   208 
   209 lemma sym: "s = t ==> t = s"
   210   by (erule subst) (rule refl)
   211 
   212 lemma ssubst: "t = s ==> P s ==> P t"
   213   by (drule sym) (erule subst)
   214 
   215 lemma trans: "[| r=s; s=t |] ==> r=t"
   216   by (erule subst)
   217 
   218 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   219   by (rule trans [OF _ sym])
   220 
   221 lemma meta_eq_to_obj_eq: 
   222   assumes meq: "A == B"
   223   shows "A = B"
   224   by (unfold meq) (rule refl)
   225 
   226 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   227      (* a = b
   228         |   |
   229         c = d   *)
   230 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   231 apply (rule trans)
   232 apply (rule trans)
   233 apply (rule sym)
   234 apply assumption+
   235 done
   236 
   237 text {* For calculational reasoning: *}
   238 
   239 lemma forw_subst: "a = b ==> P b ==> P a"
   240   by (rule ssubst)
   241 
   242 lemma back_subst: "P a ==> a = b ==> P b"
   243   by (rule subst)
   244 
   245 
   246 subsubsection {* Congruence rules for application *}
   247 
   248 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   249 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   250 apply (erule subst)
   251 apply (rule refl)
   252 done
   253 
   254 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   255 lemma arg_cong: "x=y ==> f(x)=f(y)"
   256 apply (erule subst)
   257 apply (rule refl)
   258 done
   259 
   260 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   261 apply (erule ssubst)+
   262 apply (rule refl)
   263 done
   264 
   265 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   266 apply (erule subst)+
   267 apply (rule refl)
   268 done
   269 
   270 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   271 
   272 
   273 subsubsection {* Equality of booleans -- iff *}
   274 
   275 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   276   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   277 
   278 lemma iffD2: "[| P=Q; Q |] ==> P"
   279   by (erule ssubst)
   280 
   281 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   282   by (erule iffD2)
   283 
   284 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   285   by (drule sym) (rule iffD2)
   286 
   287 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   288   by (drule sym) (rule rev_iffD2)
   289 
   290 lemma iffE:
   291   assumes major: "P=Q"
   292     and minor: "[| P --> Q; Q --> P |] ==> R"
   293   shows R
   294   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   295 
   296 
   297 subsubsection {*True*}
   298 
   299 lemma TrueI: "True"
   300   unfolding True_def by (rule refl)
   301 
   302 lemma eqTrueI: "P ==> P = True"
   303   by (iprover intro: iffI TrueI)
   304 
   305 lemma eqTrueE: "P = True ==> P"
   306   by (erule iffD2) (rule TrueI)
   307 
   308 
   309 subsubsection {*Universal quantifier*}
   310 
   311 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   312   unfolding All_def by (iprover intro: ext eqTrueI assms)
   313 
   314 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   315 apply (unfold All_def)
   316 apply (rule eqTrueE)
   317 apply (erule fun_cong)
   318 done
   319 
   320 lemma allE:
   321   assumes major: "ALL x. P(x)"
   322     and minor: "P(x) ==> R"
   323   shows R
   324   by (iprover intro: minor major [THEN spec])
   325 
   326 lemma all_dupE:
   327   assumes major: "ALL x. P(x)"
   328     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   329   shows R
   330   by (iprover intro: minor major major [THEN spec])
   331 
   332 
   333 subsubsection {* False *}
   334 
   335 text {*
   336   Depends upon @{text spec}; it is impossible to do propositional
   337   logic before quantifiers!
   338 *}
   339 
   340 lemma FalseE: "False ==> P"
   341   apply (unfold False_def)
   342   apply (erule spec)
   343   done
   344 
   345 lemma False_neq_True: "False = True ==> P"
   346   by (erule eqTrueE [THEN FalseE])
   347 
   348 
   349 subsubsection {* Negation *}
   350 
   351 lemma notI:
   352   assumes "P ==> False"
   353   shows "~P"
   354   apply (unfold not_def)
   355   apply (iprover intro: impI assms)
   356   done
   357 
   358 lemma False_not_True: "False ~= True"
   359   apply (rule notI)
   360   apply (erule False_neq_True)
   361   done
   362 
   363 lemma True_not_False: "True ~= False"
   364   apply (rule notI)
   365   apply (drule sym)
   366   apply (erule False_neq_True)
   367   done
   368 
   369 lemma notE: "[| ~P;  P |] ==> R"
   370   apply (unfold not_def)
   371   apply (erule mp [THEN FalseE])
   372   apply assumption
   373   done
   374 
   375 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   376   by (erule notE [THEN notI]) (erule meta_mp)
   377 
   378 
   379 subsubsection {*Implication*}
   380 
   381 lemma impE:
   382   assumes "P-->Q" "P" "Q ==> R"
   383   shows "R"
   384 by (iprover intro: assms mp)
   385 
   386 (* Reduces Q to P-->Q, allowing substitution in P. *)
   387 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   388 by (iprover intro: mp)
   389 
   390 lemma contrapos_nn:
   391   assumes major: "~Q"
   392       and minor: "P==>Q"
   393   shows "~P"
   394 by (iprover intro: notI minor major [THEN notE])
   395 
   396 (*not used at all, but we already have the other 3 combinations *)
   397 lemma contrapos_pn:
   398   assumes major: "Q"
   399       and minor: "P ==> ~Q"
   400   shows "~P"
   401 by (iprover intro: notI minor major notE)
   402 
   403 lemma not_sym: "t ~= s ==> s ~= t"
   404   by (erule contrapos_nn) (erule sym)
   405 
   406 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   407   by (erule subst, erule ssubst, assumption)
   408 
   409 (*still used in HOLCF*)
   410 lemma rev_contrapos:
   411   assumes pq: "P ==> Q"
   412       and nq: "~Q"
   413   shows "~P"
   414 apply (rule nq [THEN contrapos_nn])
   415 apply (erule pq)
   416 done
   417 
   418 subsubsection {*Existential quantifier*}
   419 
   420 lemma exI: "P x ==> EX x::'a. P x"
   421 apply (unfold Ex_def)
   422 apply (iprover intro: allI allE impI mp)
   423 done
   424 
   425 lemma exE:
   426   assumes major: "EX x::'a. P(x)"
   427       and minor: "!!x. P(x) ==> Q"
   428   shows "Q"
   429 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   430 apply (iprover intro: impI [THEN allI] minor)
   431 done
   432 
   433 
   434 subsubsection {*Conjunction*}
   435 
   436 lemma conjI: "[| P; Q |] ==> P&Q"
   437 apply (unfold and_def)
   438 apply (iprover intro: impI [THEN allI] mp)
   439 done
   440 
   441 lemma conjunct1: "[| P & Q |] ==> P"
   442 apply (unfold and_def)
   443 apply (iprover intro: impI dest: spec mp)
   444 done
   445 
   446 lemma conjunct2: "[| P & Q |] ==> Q"
   447 apply (unfold and_def)
   448 apply (iprover intro: impI dest: spec mp)
   449 done
   450 
   451 lemma conjE:
   452   assumes major: "P&Q"
   453       and minor: "[| P; Q |] ==> R"
   454   shows "R"
   455 apply (rule minor)
   456 apply (rule major [THEN conjunct1])
   457 apply (rule major [THEN conjunct2])
   458 done
   459 
   460 lemma context_conjI:
   461   assumes "P" "P ==> Q" shows "P & Q"
   462 by (iprover intro: conjI assms)
   463 
   464 
   465 subsubsection {*Disjunction*}
   466 
   467 lemma disjI1: "P ==> P|Q"
   468 apply (unfold or_def)
   469 apply (iprover intro: allI impI mp)
   470 done
   471 
   472 lemma disjI2: "Q ==> P|Q"
   473 apply (unfold or_def)
   474 apply (iprover intro: allI impI mp)
   475 done
   476 
   477 lemma disjE:
   478   assumes major: "P|Q"
   479       and minorP: "P ==> R"
   480       and minorQ: "Q ==> R"
   481   shows "R"
   482 by (iprover intro: minorP minorQ impI
   483                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   484 
   485 
   486 subsubsection {*Classical logic*}
   487 
   488 lemma classical:
   489   assumes prem: "~P ==> P"
   490   shows "P"
   491 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   492 apply assumption
   493 apply (rule notI [THEN prem, THEN eqTrueI])
   494 apply (erule subst)
   495 apply assumption
   496 done
   497 
   498 lemmas ccontr = FalseE [THEN classical, standard]
   499 
   500 (*notE with premises exchanged; it discharges ~R so that it can be used to
   501   make elimination rules*)
   502 lemma rev_notE:
   503   assumes premp: "P"
   504       and premnot: "~R ==> ~P"
   505   shows "R"
   506 apply (rule ccontr)
   507 apply (erule notE [OF premnot premp])
   508 done
   509 
   510 (*Double negation law*)
   511 lemma notnotD: "~~P ==> P"
   512 apply (rule classical)
   513 apply (erule notE)
   514 apply assumption
   515 done
   516 
   517 lemma contrapos_pp:
   518   assumes p1: "Q"
   519       and p2: "~P ==> ~Q"
   520   shows "P"
   521 by (iprover intro: classical p1 p2 notE)
   522 
   523 
   524 subsubsection {*Unique existence*}
   525 
   526 lemma ex1I:
   527   assumes "P a" "!!x. P(x) ==> x=a"
   528   shows "EX! x. P(x)"
   529 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   530 
   531 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   532 lemma ex_ex1I:
   533   assumes ex_prem: "EX x. P(x)"
   534       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   535   shows "EX! x. P(x)"
   536 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   537 
   538 lemma ex1E:
   539   assumes major: "EX! x. P(x)"
   540       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   541   shows "R"
   542 apply (rule major [unfolded Ex1_def, THEN exE])
   543 apply (erule conjE)
   544 apply (iprover intro: minor)
   545 done
   546 
   547 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   548 apply (erule ex1E)
   549 apply (rule exI)
   550 apply assumption
   551 done
   552 
   553 
   554 subsubsection {*THE: definite description operator*}
   555 
   556 lemma the_equality:
   557   assumes prema: "P a"
   558       and premx: "!!x. P x ==> x=a"
   559   shows "(THE x. P x) = a"
   560 apply (rule trans [OF _ the_eq_trivial])
   561 apply (rule_tac f = "The" in arg_cong)
   562 apply (rule ext)
   563 apply (rule iffI)
   564  apply (erule premx)
   565 apply (erule ssubst, rule prema)
   566 done
   567 
   568 lemma theI:
   569   assumes "P a" and "!!x. P x ==> x=a"
   570   shows "P (THE x. P x)"
   571 by (iprover intro: assms the_equality [THEN ssubst])
   572 
   573 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   574 apply (erule ex1E)
   575 apply (erule theI)
   576 apply (erule allE)
   577 apply (erule mp)
   578 apply assumption
   579 done
   580 
   581 (*Easier to apply than theI: only one occurrence of P*)
   582 lemma theI2:
   583   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   584   shows "Q (THE x. P x)"
   585 by (iprover intro: assms theI)
   586 
   587 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   588 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   589            elim:allE impE)
   590 
   591 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   592 apply (rule the_equality)
   593 apply  assumption
   594 apply (erule ex1E)
   595 apply (erule all_dupE)
   596 apply (drule mp)
   597 apply  assumption
   598 apply (erule ssubst)
   599 apply (erule allE)
   600 apply (erule mp)
   601 apply assumption
   602 done
   603 
   604 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   605 apply (rule the_equality)
   606 apply (rule refl)
   607 apply (erule sym)
   608 done
   609 
   610 
   611 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   612 
   613 lemma disjCI:
   614   assumes "~Q ==> P" shows "P|Q"
   615 apply (rule classical)
   616 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   617 done
   618 
   619 lemma excluded_middle: "~P | P"
   620 by (iprover intro: disjCI)
   621 
   622 text {*
   623   case distinction as a natural deduction rule.
   624   Note that @{term "~P"} is the second case, not the first
   625 *}
   626 lemma case_split [case_names True False]:
   627   assumes prem1: "P ==> Q"
   628       and prem2: "~P ==> Q"
   629   shows "Q"
   630 apply (rule excluded_middle [THEN disjE])
   631 apply (erule prem2)
   632 apply (erule prem1)
   633 done
   634 
   635 (*Classical implies (-->) elimination. *)
   636 lemma impCE:
   637   assumes major: "P-->Q"
   638       and minor: "~P ==> R" "Q ==> R"
   639   shows "R"
   640 apply (rule excluded_middle [of P, THEN disjE])
   641 apply (iprover intro: minor major [THEN mp])+
   642 done
   643 
   644 (*This version of --> elimination works on Q before P.  It works best for
   645   those cases in which P holds "almost everywhere".  Can't install as
   646   default: would break old proofs.*)
   647 lemma impCE':
   648   assumes major: "P-->Q"
   649       and minor: "Q ==> R" "~P ==> R"
   650   shows "R"
   651 apply (rule excluded_middle [of P, THEN disjE])
   652 apply (iprover intro: minor major [THEN mp])+
   653 done
   654 
   655 (*Classical <-> elimination. *)
   656 lemma iffCE:
   657   assumes major: "P=Q"
   658       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   659   shows "R"
   660 apply (rule major [THEN iffE])
   661 apply (iprover intro: minor elim: impCE notE)
   662 done
   663 
   664 lemma exCI:
   665   assumes "ALL x. ~P(x) ==> P(a)"
   666   shows "EX x. P(x)"
   667 apply (rule ccontr)
   668 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   669 done
   670 
   671 
   672 subsubsection {* Intuitionistic Reasoning *}
   673 
   674 lemma impE':
   675   assumes 1: "P --> Q"
   676     and 2: "Q ==> R"
   677     and 3: "P --> Q ==> P"
   678   shows R
   679 proof -
   680   from 3 and 1 have P .
   681   with 1 have Q by (rule impE)
   682   with 2 show R .
   683 qed
   684 
   685 lemma allE':
   686   assumes 1: "ALL x. P x"
   687     and 2: "P x ==> ALL x. P x ==> Q"
   688   shows Q
   689 proof -
   690   from 1 have "P x" by (rule spec)
   691   from this and 1 show Q by (rule 2)
   692 qed
   693 
   694 lemma notE':
   695   assumes 1: "~ P"
   696     and 2: "~ P ==> P"
   697   shows R
   698 proof -
   699   from 2 and 1 have P .
   700   with 1 show R by (rule notE)
   701 qed
   702 
   703 lemma TrueE: "True ==> P ==> P" .
   704 lemma notFalseE: "~ False ==> P ==> P" .
   705 
   706 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   707   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   708   and [Pure.elim 2] = allE notE' impE'
   709   and [Pure.intro] = exI disjI2 disjI1
   710 
   711 lemmas [trans] = trans
   712   and [sym] = sym not_sym
   713   and [Pure.elim?] = iffD1 iffD2 impE
   714 
   715 use "Tools/hologic.ML"
   716 
   717 
   718 subsubsection {* Atomizing meta-level connectives *}
   719 
   720 axiomatization where
   721   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   722 
   723 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   724 proof
   725   assume "!!x. P x"
   726   then show "ALL x. P x" ..
   727 next
   728   assume "ALL x. P x"
   729   then show "!!x. P x" by (rule allE)
   730 qed
   731 
   732 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   733 proof
   734   assume r: "A ==> B"
   735   show "A --> B" by (rule impI) (rule r)
   736 next
   737   assume "A --> B" and A
   738   then show B by (rule mp)
   739 qed
   740 
   741 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   742 proof
   743   assume r: "A ==> False"
   744   show "~A" by (rule notI) (rule r)
   745 next
   746   assume "~A" and A
   747   then show False by (rule notE)
   748 qed
   749 
   750 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   751 proof
   752   assume "x == y"
   753   show "x = y" by (unfold `x == y`) (rule refl)
   754 next
   755   assume "x = y"
   756   then show "x == y" by (rule eq_reflection)
   757 qed
   758 
   759 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   760 proof
   761   assume conj: "A &&& B"
   762   show "A & B"
   763   proof (rule conjI)
   764     from conj show A by (rule conjunctionD1)
   765     from conj show B by (rule conjunctionD2)
   766   qed
   767 next
   768   assume conj: "A & B"
   769   show "A &&& B"
   770   proof -
   771     from conj show A ..
   772     from conj show B ..
   773   qed
   774 qed
   775 
   776 lemmas [symmetric, rulify] = atomize_all atomize_imp
   777   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   778 
   779 
   780 subsubsection {* Atomizing elimination rules *}
   781 
   782 setup AtomizeElim.setup
   783 
   784 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   785   by rule iprover+
   786 
   787 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   788   by rule iprover+
   789 
   790 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   791   by rule iprover+
   792 
   793 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   794 
   795 
   796 subsection {* Package setup *}
   797 
   798 subsubsection {* Sledgehammer setup *}
   799 
   800 text {*
   801 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   802 that are prolific (match too many equality or membership literals) and relate to
   803 seldom-used facts. Some duplicate other rules.
   804 *}
   805 
   806 ML {*
   807 structure No_ATPs = Named_Thms
   808 (
   809   val name = "no_atp"
   810   val description = "theorems that should be filtered out by Sledgehammer"
   811 )
   812 *}
   813 
   814 setup {* No_ATPs.setup *}
   815 
   816 
   817 subsubsection {* Classical Reasoner setup *}
   818 
   819 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   820   by (rule classical) iprover
   821 
   822 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   823   by (rule classical) iprover
   824 
   825 lemma thin_refl:
   826   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   827 
   828 ML {*
   829 structure Hypsubst = Hypsubst
   830 (
   831   val dest_eq = HOLogic.dest_eq
   832   val dest_Trueprop = HOLogic.dest_Trueprop
   833   val dest_imp = HOLogic.dest_imp
   834   val eq_reflection = @{thm eq_reflection}
   835   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   836   val imp_intr = @{thm impI}
   837   val rev_mp = @{thm rev_mp}
   838   val subst = @{thm subst}
   839   val sym = @{thm sym}
   840   val thin_refl = @{thm thin_refl};
   841 );
   842 open Hypsubst;
   843 
   844 structure Classical = Classical
   845 (
   846   val imp_elim = @{thm imp_elim}
   847   val not_elim = @{thm notE}
   848   val swap = @{thm swap}
   849   val classical = @{thm classical}
   850   val sizef = Drule.size_of_thm
   851   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   852 );
   853 
   854 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   855 open Basic_Classical;
   856 *}
   857 
   858 setup {*
   859   ML_Antiquote.value @{binding claset}
   860     (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())")
   861 *}
   862 
   863 setup Classical.setup
   864 
   865 setup {*
   866 let
   867   fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   868     | non_bool_eq _ = false;
   869   val hyp_subst_tac' =
   870     SUBGOAL (fn (goal, i) =>
   871       if Term.exists_Const non_bool_eq goal
   872       then Hypsubst.hyp_subst_tac i
   873       else no_tac);
   874 in
   875   Hypsubst.hypsubst_setup
   876   (*prevent substitution on bool*)
   877   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   878 end
   879 *}
   880 
   881 declare iffI [intro!]
   882   and notI [intro!]
   883   and impI [intro!]
   884   and disjCI [intro!]
   885   and conjI [intro!]
   886   and TrueI [intro!]
   887   and refl [intro!]
   888 
   889 declare iffCE [elim!]
   890   and FalseE [elim!]
   891   and impCE [elim!]
   892   and disjE [elim!]
   893   and conjE [elim!]
   894 
   895 declare ex_ex1I [intro!]
   896   and allI [intro!]
   897   and the_equality [intro]
   898   and exI [intro]
   899 
   900 declare exE [elim!]
   901   allE [elim]
   902 
   903 ML {* val HOL_cs = @{claset} *}
   904 
   905 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   906   apply (erule swap)
   907   apply (erule (1) meta_mp)
   908   done
   909 
   910 declare ex_ex1I [rule del, intro! 2]
   911   and ex1I [intro]
   912 
   913 declare ext [intro]
   914 
   915 lemmas [intro?] = ext
   916   and [elim?] = ex1_implies_ex
   917 
   918 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   919 lemma alt_ex1E [elim!]:
   920   assumes major: "\<exists>!x. P x"
   921       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   922   shows R
   923 apply (rule ex1E [OF major])
   924 apply (rule prem)
   925 apply (tactic {* ares_tac @{thms allI} 1 *})+
   926 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   927 apply iprover
   928 done
   929 
   930 ML {*
   931   structure Blast = Blast
   932   (
   933     structure Classical = Classical
   934     val Trueprop_const = dest_Const @{const Trueprop}
   935     val equality_name = @{const_name HOL.eq}
   936     val not_name = @{const_name Not}
   937     val notE = @{thm notE}
   938     val ccontr = @{thm ccontr}
   939     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   940   );
   941   val blast_tac = Blast.blast_tac;
   942 *}
   943 
   944 setup Blast.setup
   945 
   946 
   947 subsubsection {* Simplifier *}
   948 
   949 lemma eta_contract_eq: "(%s. f s) = f" ..
   950 
   951 lemma simp_thms:
   952   shows not_not: "(~ ~ P) = P"
   953   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   954   and
   955     "(P ~= Q) = (P = (~Q))"
   956     "(P | ~P) = True"    "(~P | P) = True"
   957     "(x = x) = True"
   958   and not_True_eq_False [code]: "(\<not> True) = False"
   959   and not_False_eq_True [code]: "(\<not> False) = True"
   960   and
   961     "(~P) ~= P"  "P ~= (~P)"
   962     "(True=P) = P"
   963   and eq_True: "(P = True) = P"
   964   and "(False=P) = (~P)"
   965   and eq_False: "(P = False) = (\<not> P)"
   966   and
   967     "(True --> P) = P"  "(False --> P) = True"
   968     "(P --> True) = True"  "(P --> P) = True"
   969     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   970     "(P & True) = P"  "(True & P) = P"
   971     "(P & False) = False"  "(False & P) = False"
   972     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   973     "(P & ~P) = False"    "(~P & P) = False"
   974     "(P | True) = True"  "(True | P) = True"
   975     "(P | False) = P"  "(False | P) = P"
   976     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   977     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   978   and
   979     "!!P. (EX x. x=t & P(x)) = P(t)"
   980     "!!P. (EX x. t=x & P(x)) = P(t)"
   981     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   982     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   983   by (blast, blast, blast, blast, blast, iprover+)
   984 
   985 lemma disj_absorb: "(A | A) = A"
   986   by blast
   987 
   988 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   989   by blast
   990 
   991 lemma conj_absorb: "(A & A) = A"
   992   by blast
   993 
   994 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   995   by blast
   996 
   997 lemma eq_ac:
   998   shows eq_commute: "(a=b) = (b=a)"
   999     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1000     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1001 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1002 
  1003 lemma conj_comms:
  1004   shows conj_commute: "(P&Q) = (Q&P)"
  1005     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1006 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1007 
  1008 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1009 
  1010 lemma disj_comms:
  1011   shows disj_commute: "(P|Q) = (Q|P)"
  1012     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1013 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1014 
  1015 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1016 
  1017 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1018 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1019 
  1020 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1021 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1022 
  1023 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1024 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1025 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1026 
  1027 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1028 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1029 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1030 
  1031 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1032 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1033 
  1034 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1035   by iprover
  1036 
  1037 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1038 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1039 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1040 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1041 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1042 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1043   by blast
  1044 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1045 
  1046 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1047 
  1048 
  1049 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1050   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1051   -- {* cases boil down to the same thing. *}
  1052   by blast
  1053 
  1054 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1055 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1056 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1057 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1058 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1059 
  1060 declare All_def [no_atp]
  1061 
  1062 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1063 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1064 
  1065 text {*
  1066   \medskip The @{text "&"} congruence rule: not included by default!
  1067   May slow rewrite proofs down by as much as 50\% *}
  1068 
  1069 lemma conj_cong:
  1070     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1071   by iprover
  1072 
  1073 lemma rev_conj_cong:
  1074     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1075   by iprover
  1076 
  1077 text {* The @{text "|"} congruence rule: not included by default! *}
  1078 
  1079 lemma disj_cong:
  1080     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1081   by blast
  1082 
  1083 
  1084 text {* \medskip if-then-else rules *}
  1085 
  1086 lemma if_True [code]: "(if True then x else y) = x"
  1087   by (unfold If_def) blast
  1088 
  1089 lemma if_False [code]: "(if False then x else y) = y"
  1090   by (unfold If_def) blast
  1091 
  1092 lemma if_P: "P ==> (if P then x else y) = x"
  1093   by (unfold If_def) blast
  1094 
  1095 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1096   by (unfold If_def) blast
  1097 
  1098 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1099   apply (rule case_split [of Q])
  1100    apply (simplesubst if_P)
  1101     prefer 3 apply (simplesubst if_not_P, blast+)
  1102   done
  1103 
  1104 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1105 by (simplesubst split_if, blast)
  1106 
  1107 lemmas if_splits [no_atp] = split_if split_if_asm
  1108 
  1109 lemma if_cancel: "(if c then x else x) = x"
  1110 by (simplesubst split_if, blast)
  1111 
  1112 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1113 by (simplesubst split_if, blast)
  1114 
  1115 lemma if_bool_eq_conj:
  1116 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1117   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1118   by (rule split_if)
  1119 
  1120 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1121   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1122   apply (simplesubst split_if, blast)
  1123   done
  1124 
  1125 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1126 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1127 
  1128 text {* \medskip let rules for simproc *}
  1129 
  1130 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1131   by (unfold Let_def)
  1132 
  1133 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1134   by (unfold Let_def)
  1135 
  1136 text {*
  1137   The following copy of the implication operator is useful for
  1138   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1139   its premise.
  1140 *}
  1141 
  1142 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1143   "simp_implies \<equiv> op ==>"
  1144 
  1145 lemma simp_impliesI:
  1146   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1147   shows "PROP P =simp=> PROP Q"
  1148   apply (unfold simp_implies_def)
  1149   apply (rule PQ)
  1150   apply assumption
  1151   done
  1152 
  1153 lemma simp_impliesE:
  1154   assumes PQ: "PROP P =simp=> PROP Q"
  1155   and P: "PROP P"
  1156   and QR: "PROP Q \<Longrightarrow> PROP R"
  1157   shows "PROP R"
  1158   apply (rule QR)
  1159   apply (rule PQ [unfolded simp_implies_def])
  1160   apply (rule P)
  1161   done
  1162 
  1163 lemma simp_implies_cong:
  1164   assumes PP' :"PROP P == PROP P'"
  1165   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1166   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1167 proof (unfold simp_implies_def, rule equal_intr_rule)
  1168   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1169   and P': "PROP P'"
  1170   from PP' [symmetric] and P' have "PROP P"
  1171     by (rule equal_elim_rule1)
  1172   then have "PROP Q" by (rule PQ)
  1173   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1174 next
  1175   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1176   and P: "PROP P"
  1177   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1178   then have "PROP Q'" by (rule P'Q')
  1179   with P'QQ' [OF P', symmetric] show "PROP Q"
  1180     by (rule equal_elim_rule1)
  1181 qed
  1182 
  1183 lemma uncurry:
  1184   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1185   shows "P \<and> Q \<longrightarrow> R"
  1186   using assms by blast
  1187 
  1188 lemma iff_allI:
  1189   assumes "\<And>x. P x = Q x"
  1190   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1191   using assms by blast
  1192 
  1193 lemma iff_exI:
  1194   assumes "\<And>x. P x = Q x"
  1195   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1196   using assms by blast
  1197 
  1198 lemma all_comm:
  1199   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1200   by blast
  1201 
  1202 lemma ex_comm:
  1203   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1204   by blast
  1205 
  1206 use "Tools/simpdata.ML"
  1207 ML {* open Simpdata *}
  1208 
  1209 setup {* Simplifier.map_simpset_global (K HOL_basic_ss) *}
  1210 
  1211 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1212 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1213 
  1214 setup {*
  1215   Simplifier.method_setup Splitter.split_modifiers
  1216   #> Splitter.setup
  1217   #> clasimp_setup
  1218   #> EqSubst.setup
  1219 *}
  1220 
  1221 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1222 
  1223 simproc_setup neq ("x = y") = {* fn _ =>
  1224 let
  1225   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1226   fun is_neq eq lhs rhs thm =
  1227     (case Thm.prop_of thm of
  1228       _ $ (Not $ (eq' $ l' $ r')) =>
  1229         Not = HOLogic.Not andalso eq' = eq andalso
  1230         r' aconv lhs andalso l' aconv rhs
  1231     | _ => false);
  1232   fun proc ss ct =
  1233     (case Thm.term_of ct of
  1234       eq $ lhs $ rhs =>
  1235         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1236           SOME thm => SOME (thm RS neq_to_EQ_False)
  1237         | NONE => NONE)
  1238      | _ => NONE);
  1239 in proc end;
  1240 *}
  1241 
  1242 simproc_setup let_simp ("Let x f") = {*
  1243 let
  1244   val (f_Let_unfold, x_Let_unfold) =
  1245     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1246     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1247   val (f_Let_folded, x_Let_folded) =
  1248     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1249     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1250   val g_Let_folded =
  1251     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1252     in cterm_of @{theory} g end;
  1253   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1254     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1255     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1256     | count_loose _ _ = 0;
  1257   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1258    case t
  1259     of Abs (_, _, t') => count_loose t' 0 <= 1
  1260      | _ => true;
  1261 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1262   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1263   else let (*Norbert Schirmer's case*)
  1264     val ctxt = Simplifier.the_context ss;
  1265     val thy = Proof_Context.theory_of ctxt;
  1266     val t = Thm.term_of ct;
  1267     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1268   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1269     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1270       if is_Free x orelse is_Bound x orelse is_Const x
  1271       then SOME @{thm Let_def}
  1272       else
  1273         let
  1274           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1275           val cx = cterm_of thy x;
  1276           val {T = xT, ...} = rep_cterm cx;
  1277           val cf = cterm_of thy f;
  1278           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1279           val (_ $ _ $ g) = prop_of fx_g;
  1280           val g' = abstract_over (x,g);
  1281         in (if (g aconv g')
  1282              then
  1283                 let
  1284                   val rl =
  1285                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1286                 in SOME (rl OF [fx_g]) end
  1287              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1288              else let
  1289                    val abs_g'= Abs (n,xT,g');
  1290                    val g'x = abs_g'$x;
  1291                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1292                    val rl = cterm_instantiate
  1293                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1294                               (g_Let_folded, cterm_of thy abs_g')]
  1295                              @{thm Let_folded};
  1296                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1297                  end)
  1298         end
  1299     | _ => NONE)
  1300   end
  1301 end *}
  1302 
  1303 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1304 proof
  1305   assume "True \<Longrightarrow> PROP P"
  1306   from this [OF TrueI] show "PROP P" .
  1307 next
  1308   assume "PROP P"
  1309   then show "PROP P" .
  1310 qed
  1311 
  1312 lemma ex_simps:
  1313   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1314   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1315   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1316   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1317   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1318   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1319   -- {* Miniscoping: pushing in existential quantifiers. *}
  1320   by (iprover | blast)+
  1321 
  1322 lemma all_simps:
  1323   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1324   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1325   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1326   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1327   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1328   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1329   -- {* Miniscoping: pushing in universal quantifiers. *}
  1330   by (iprover | blast)+
  1331 
  1332 lemmas [simp] =
  1333   triv_forall_equality (*prunes params*)
  1334   True_implies_equals  (*prune asms `True'*)
  1335   if_True
  1336   if_False
  1337   if_cancel
  1338   if_eq_cancel
  1339   imp_disjL
  1340   (*In general it seems wrong to add distributive laws by default: they
  1341     might cause exponential blow-up.  But imp_disjL has been in for a while
  1342     and cannot be removed without affecting existing proofs.  Moreover,
  1343     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1344     grounds that it allows simplification of R in the two cases.*)
  1345   conj_assoc
  1346   disj_assoc
  1347   de_Morgan_conj
  1348   de_Morgan_disj
  1349   imp_disj1
  1350   imp_disj2
  1351   not_imp
  1352   disj_not1
  1353   not_all
  1354   not_ex
  1355   cases_simp
  1356   the_eq_trivial
  1357   the_sym_eq_trivial
  1358   ex_simps
  1359   all_simps
  1360   simp_thms
  1361 
  1362 lemmas [cong] = imp_cong simp_implies_cong
  1363 lemmas [split] = split_if
  1364 
  1365 ML {* val HOL_ss = @{simpset} *}
  1366 
  1367 text {* Simplifies x assuming c and y assuming ~c *}
  1368 lemma if_cong:
  1369   assumes "b = c"
  1370       and "c \<Longrightarrow> x = u"
  1371       and "\<not> c \<Longrightarrow> y = v"
  1372   shows "(if b then x else y) = (if c then u else v)"
  1373   using assms by simp
  1374 
  1375 text {* Prevents simplification of x and y:
  1376   faster and allows the execution of functional programs. *}
  1377 lemma if_weak_cong [cong]:
  1378   assumes "b = c"
  1379   shows "(if b then x else y) = (if c then x else y)"
  1380   using assms by (rule arg_cong)
  1381 
  1382 text {* Prevents simplification of t: much faster *}
  1383 lemma let_weak_cong:
  1384   assumes "a = b"
  1385   shows "(let x = a in t x) = (let x = b in t x)"
  1386   using assms by (rule arg_cong)
  1387 
  1388 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1389 lemma eq_cong2:
  1390   assumes "u = u'"
  1391   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1392   using assms by simp
  1393 
  1394 lemma if_distrib:
  1395   "f (if c then x else y) = (if c then f x else f y)"
  1396   by simp
  1397 
  1398 text{*As a simplification rule, it replaces all function equalities by
  1399   first-order equalities.*}
  1400 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1401   by auto
  1402 
  1403 
  1404 subsubsection {* Generic cases and induction *}
  1405 
  1406 text {* Rule projections: *}
  1407 
  1408 ML {*
  1409 structure Project_Rule = Project_Rule
  1410 (
  1411   val conjunct1 = @{thm conjunct1}
  1412   val conjunct2 = @{thm conjunct2}
  1413   val mp = @{thm mp}
  1414 )
  1415 *}
  1416 
  1417 definition induct_forall where
  1418   "induct_forall P == \<forall>x. P x"
  1419 
  1420 definition induct_implies where
  1421   "induct_implies A B == A \<longrightarrow> B"
  1422 
  1423 definition induct_equal where
  1424   "induct_equal x y == x = y"
  1425 
  1426 definition induct_conj where
  1427   "induct_conj A B == A \<and> B"
  1428 
  1429 definition induct_true where
  1430   "induct_true == True"
  1431 
  1432 definition induct_false where
  1433   "induct_false == False"
  1434 
  1435 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1436   by (unfold atomize_all induct_forall_def)
  1437 
  1438 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1439   by (unfold atomize_imp induct_implies_def)
  1440 
  1441 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1442   by (unfold atomize_eq induct_equal_def)
  1443 
  1444 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1445   by (unfold atomize_conj induct_conj_def)
  1446 
  1447 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1448 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1449 lemmas induct_rulify' [symmetric, standard] = induct_atomize'
  1450 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1451 lemmas induct_rulify_fallback =
  1452   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1453   induct_true_def induct_false_def
  1454 
  1455 
  1456 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1457     induct_conj (induct_forall A) (induct_forall B)"
  1458   by (unfold induct_forall_def induct_conj_def) iprover
  1459 
  1460 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1461     induct_conj (induct_implies C A) (induct_implies C B)"
  1462   by (unfold induct_implies_def induct_conj_def) iprover
  1463 
  1464 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1465 proof
  1466   assume r: "induct_conj A B ==> PROP C" and A B
  1467   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1468 next
  1469   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1470   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1471 qed
  1472 
  1473 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1474 
  1475 lemma induct_trueI: "induct_true"
  1476   by (simp add: induct_true_def)
  1477 
  1478 text {* Method setup. *}
  1479 
  1480 ML {*
  1481 structure Induct = Induct
  1482 (
  1483   val cases_default = @{thm case_split}
  1484   val atomize = @{thms induct_atomize}
  1485   val rulify = @{thms induct_rulify'}
  1486   val rulify_fallback = @{thms induct_rulify_fallback}
  1487   val equal_def = @{thm induct_equal_def}
  1488   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1489     | dest_def _ = NONE
  1490   val trivial_tac = match_tac @{thms induct_trueI}
  1491 )
  1492 *}
  1493 
  1494 use "~~/src/Tools/induction.ML"
  1495 
  1496 setup {*
  1497   Induct.setup #> Induction.setup #>
  1498   Context.theory_map (Induct.map_simpset (fn ss => ss
  1499     setmksimps (fn ss => Simpdata.mksimps Simpdata.mksimps_pairs ss #>
  1500       map (Simplifier.rewrite_rule (map Thm.symmetric
  1501         @{thms induct_rulify_fallback})))
  1502     addsimprocs
  1503       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1504          ["induct_false ==> PROP P ==> PROP Q"]
  1505          (fn _ => fn _ =>
  1506             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1507                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1508               | _ => NONE)),
  1509        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1510          ["induct_conj P Q ==> PROP R"]
  1511          (fn _ => fn _ =>
  1512             (fn _ $ (_ $ P) $ _ =>
  1513                 let
  1514                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1515                         is_conj P andalso is_conj Q
  1516                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1517                     | is_conj @{const induct_true} = true
  1518                     | is_conj @{const induct_false} = true
  1519                     | is_conj _ = false
  1520                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1521               | _ => NONE))]))
  1522 *}
  1523 
  1524 text {* Pre-simplification of induction and cases rules *}
  1525 
  1526 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1527   unfolding induct_equal_def
  1528 proof
  1529   assume R: "!!x. x = t ==> PROP P x"
  1530   show "PROP P t" by (rule R [OF refl])
  1531 next
  1532   fix x assume "PROP P t" "x = t"
  1533   then show "PROP P x" by simp
  1534 qed
  1535 
  1536 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1537   unfolding induct_equal_def
  1538 proof
  1539   assume R: "!!x. t = x ==> PROP P x"
  1540   show "PROP P t" by (rule R [OF refl])
  1541 next
  1542   fix x assume "PROP P t" "t = x"
  1543   then show "PROP P x" by simp
  1544 qed
  1545 
  1546 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1547   unfolding induct_false_def induct_true_def
  1548   by (iprover intro: equal_intr_rule)
  1549 
  1550 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1551   unfolding induct_true_def
  1552 proof
  1553   assume R: "True \<Longrightarrow> PROP P"
  1554   from TrueI show "PROP P" by (rule R)
  1555 next
  1556   assume "PROP P"
  1557   then show "PROP P" .
  1558 qed
  1559 
  1560 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1561   unfolding induct_true_def
  1562   by (iprover intro: equal_intr_rule)
  1563 
  1564 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1565   unfolding induct_true_def
  1566   by (iprover intro: equal_intr_rule)
  1567 
  1568 lemma [induct_simp]: "induct_implies induct_true P == P"
  1569   by (simp add: induct_implies_def induct_true_def)
  1570 
  1571 lemma [induct_simp]: "(x = x) = True" 
  1572   by (rule simp_thms)
  1573 
  1574 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1575 
  1576 use "~~/src/Tools/induct_tacs.ML"
  1577 setup InductTacs.setup
  1578 
  1579 
  1580 subsubsection {* Coherent logic *}
  1581 
  1582 ML {*
  1583 structure Coherent = Coherent
  1584 (
  1585   val atomize_elimL = @{thm atomize_elimL}
  1586   val atomize_exL = @{thm atomize_exL}
  1587   val atomize_conjL = @{thm atomize_conjL}
  1588   val atomize_disjL = @{thm atomize_disjL}
  1589   val operator_names =
  1590     [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}]
  1591 );
  1592 *}
  1593 
  1594 setup Coherent.setup
  1595 
  1596 
  1597 subsubsection {* Reorienting equalities *}
  1598 
  1599 ML {*
  1600 signature REORIENT_PROC =
  1601 sig
  1602   val add : (term -> bool) -> theory -> theory
  1603   val proc : morphism -> simpset -> cterm -> thm option
  1604 end;
  1605 
  1606 structure Reorient_Proc : REORIENT_PROC =
  1607 struct
  1608   structure Data = Theory_Data
  1609   (
  1610     type T = ((term -> bool) * stamp) list;
  1611     val empty = [];
  1612     val extend = I;
  1613     fun merge data : T = Library.merge (eq_snd op =) data;
  1614   );
  1615   fun add m = Data.map (cons (m, stamp ()));
  1616   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1617 
  1618   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1619   fun proc phi ss ct =
  1620     let
  1621       val ctxt = Simplifier.the_context ss;
  1622       val thy = Proof_Context.theory_of ctxt;
  1623     in
  1624       case Thm.term_of ct of
  1625         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1626       | _ => NONE
  1627     end;
  1628 end;
  1629 *}
  1630 
  1631 
  1632 subsection {* Other simple lemmas and lemma duplicates *}
  1633 
  1634 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1635   by blast+
  1636 
  1637 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1638   apply (rule iffI)
  1639   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1640   apply (fast dest!: theI')
  1641   apply (fast intro: the1_equality [symmetric])
  1642   apply (erule ex1E)
  1643   apply (rule allI)
  1644   apply (rule ex1I)
  1645   apply (erule spec)
  1646   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1647   apply (erule impE)
  1648   apply (rule allI)
  1649   apply (case_tac "xa = x")
  1650   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1651   done
  1652 
  1653 lemmas eq_sym_conv = eq_commute
  1654 
  1655 lemma nnf_simps:
  1656   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1657   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1658   "(\<not> \<not>(P)) = P"
  1659 by blast+
  1660 
  1661 subsection {* Basic ML bindings *}
  1662 
  1663 ML {*
  1664 val FalseE = @{thm FalseE}
  1665 val Let_def = @{thm Let_def}
  1666 val TrueI = @{thm TrueI}
  1667 val allE = @{thm allE}
  1668 val allI = @{thm allI}
  1669 val all_dupE = @{thm all_dupE}
  1670 val arg_cong = @{thm arg_cong}
  1671 val box_equals = @{thm box_equals}
  1672 val ccontr = @{thm ccontr}
  1673 val classical = @{thm classical}
  1674 val conjE = @{thm conjE}
  1675 val conjI = @{thm conjI}
  1676 val conjunct1 = @{thm conjunct1}
  1677 val conjunct2 = @{thm conjunct2}
  1678 val disjCI = @{thm disjCI}
  1679 val disjE = @{thm disjE}
  1680 val disjI1 = @{thm disjI1}
  1681 val disjI2 = @{thm disjI2}
  1682 val eq_reflection = @{thm eq_reflection}
  1683 val ex1E = @{thm ex1E}
  1684 val ex1I = @{thm ex1I}
  1685 val ex1_implies_ex = @{thm ex1_implies_ex}
  1686 val exE = @{thm exE}
  1687 val exI = @{thm exI}
  1688 val excluded_middle = @{thm excluded_middle}
  1689 val ext = @{thm ext}
  1690 val fun_cong = @{thm fun_cong}
  1691 val iffD1 = @{thm iffD1}
  1692 val iffD2 = @{thm iffD2}
  1693 val iffI = @{thm iffI}
  1694 val impE = @{thm impE}
  1695 val impI = @{thm impI}
  1696 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1697 val mp = @{thm mp}
  1698 val notE = @{thm notE}
  1699 val notI = @{thm notI}
  1700 val not_all = @{thm not_all}
  1701 val not_ex = @{thm not_ex}
  1702 val not_iff = @{thm not_iff}
  1703 val not_not = @{thm not_not}
  1704 val not_sym = @{thm not_sym}
  1705 val refl = @{thm refl}
  1706 val rev_mp = @{thm rev_mp}
  1707 val spec = @{thm spec}
  1708 val ssubst = @{thm ssubst}
  1709 val subst = @{thm subst}
  1710 val sym = @{thm sym}
  1711 val trans = @{thm trans}
  1712 *}
  1713 
  1714 use "Tools/cnf_funcs.ML"
  1715 
  1716 subsection {* Code generator setup *}
  1717 
  1718 subsubsection {* SML code generator setup *}
  1719 
  1720 use "Tools/recfun_codegen.ML"
  1721 
  1722 setup {*
  1723   Codegen.setup
  1724   #> RecfunCodegen.setup
  1725   #> Codegen.map_unfold (K HOL_basic_ss)
  1726 *}
  1727 
  1728 types_code
  1729   "bool"  ("bool")
  1730 attach (term_of) {*
  1731 fun term_of_bool b = if b then HOLogic.true_const else HOLogic.false_const;
  1732 *}
  1733 attach (test) {*
  1734 fun gen_bool i =
  1735   let val b = one_of [false, true]
  1736   in (b, fn () => term_of_bool b) end;
  1737 *}
  1738   "prop"  ("bool")
  1739 attach (term_of) {*
  1740 fun term_of_prop b =
  1741   HOLogic.mk_Trueprop (if b then HOLogic.true_const else HOLogic.false_const);
  1742 *}
  1743 
  1744 consts_code
  1745   "Trueprop" ("(_)")
  1746   "True"    ("true")
  1747   "False"   ("false")
  1748   "Not"     ("Bool.not")
  1749   HOL.disj    ("(_ orelse/ _)")
  1750   HOL.conj    ("(_ andalso/ _)")
  1751   "If"      ("(if _/ then _/ else _)")
  1752 
  1753 setup {*
  1754 let
  1755 
  1756 fun eq_codegen thy mode defs dep thyname b t gr =
  1757     (case strip_comb t of
  1758        (Const (@{const_name HOL.eq}, Type (_, [Type ("fun", _), _])), _) => NONE
  1759      | (Const (@{const_name HOL.eq}, _), [t, u]) =>
  1760           let
  1761             val (pt, gr') = Codegen.invoke_codegen thy mode defs dep thyname false t gr;
  1762             val (pu, gr'') = Codegen.invoke_codegen thy mode defs dep thyname false u gr';
  1763             val (_, gr''') =
  1764               Codegen.invoke_tycodegen thy mode defs dep thyname false HOLogic.boolT gr'';
  1765           in
  1766             SOME (Codegen.parens
  1767               (Pretty.block [pt, Codegen.str " =", Pretty.brk 1, pu]), gr''')
  1768           end
  1769      | (t as Const (@{const_name HOL.eq}, _), ts) => SOME (Codegen.invoke_codegen
  1770          thy mode defs dep thyname b (Codegen.eta_expand t ts 2) gr)
  1771      | _ => NONE);
  1772 
  1773 in
  1774   Codegen.add_codegen "eq_codegen" eq_codegen
  1775 end
  1776 *}
  1777 
  1778 subsubsection {* Generic code generator preprocessor setup *}
  1779 
  1780 setup {*
  1781   Code_Preproc.map_pre (K HOL_basic_ss)
  1782   #> Code_Preproc.map_post (K HOL_basic_ss)
  1783   #> Code_Simp.map_ss (K HOL_basic_ss)
  1784 *}
  1785 
  1786 subsubsection {* Equality *}
  1787 
  1788 class equal =
  1789   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1790   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1791 begin
  1792 
  1793 lemma equal [code_unfold, code_inline del]: "equal = (op =)"
  1794   by (rule ext equal_eq)+
  1795 
  1796 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1797   unfolding equal by rule+
  1798 
  1799 lemma eq_equal: "(op =) \<equiv> equal"
  1800   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1801 
  1802 end
  1803 
  1804 declare eq_equal [symmetric, code_post]
  1805 declare eq_equal [code]
  1806 
  1807 setup {*
  1808   Code_Preproc.map_pre (fn simpset =>
  1809     simpset addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1810       (fn thy => fn _ =>
  1811         fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1812 *}
  1813 
  1814 
  1815 subsubsection {* Generic code generator foundation *}
  1816 
  1817 text {* Datatype @{typ bool} *}
  1818 
  1819 code_datatype True False
  1820 
  1821 lemma [code]:
  1822   shows "False \<and> P \<longleftrightarrow> False"
  1823     and "True \<and> P \<longleftrightarrow> P"
  1824     and "P \<and> False \<longleftrightarrow> False"
  1825     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1826 
  1827 lemma [code]:
  1828   shows "False \<or> P \<longleftrightarrow> P"
  1829     and "True \<or> P \<longleftrightarrow> True"
  1830     and "P \<or> False \<longleftrightarrow> P"
  1831     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1832 
  1833 lemma [code]:
  1834   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1835     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1836     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1837     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1838 
  1839 text {* More about @{typ prop} *}
  1840 
  1841 lemma [code nbe]:
  1842   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1843     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1844     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1845 
  1846 lemma Trueprop_code [code]:
  1847   "Trueprop True \<equiv> Code_Generator.holds"
  1848   by (auto intro!: equal_intr_rule holds)
  1849 
  1850 declare Trueprop_code [symmetric, code_post]
  1851 
  1852 text {* Equality *}
  1853 
  1854 declare simp_thms(6) [code nbe]
  1855 
  1856 instantiation itself :: (type) equal
  1857 begin
  1858 
  1859 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1860   "equal_itself x y \<longleftrightarrow> x = y"
  1861 
  1862 instance proof
  1863 qed (fact equal_itself_def)
  1864 
  1865 end
  1866 
  1867 lemma equal_itself_code [code]:
  1868   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1869   by (simp add: equal)
  1870 
  1871 setup {*
  1872   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1873 *}
  1874 
  1875 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1876 proof
  1877   assume "PROP ?ofclass"
  1878   show "PROP ?equal"
  1879     by (tactic {* ALLGOALS (rtac (Thm.unconstrainT @{thm eq_equal})) *})
  1880       (fact `PROP ?ofclass`)
  1881 next
  1882   assume "PROP ?equal"
  1883   show "PROP ?ofclass" proof
  1884   qed (simp add: `PROP ?equal`)
  1885 qed
  1886   
  1887 setup {*
  1888   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"})
  1889 *}
  1890 
  1891 setup {*
  1892   Nbe.add_const_alias @{thm equal_alias_cert}
  1893 *}
  1894 
  1895 text {* Cases *}
  1896 
  1897 lemma Let_case_cert:
  1898   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1899   shows "CASE x \<equiv> f x"
  1900   using assms by simp_all
  1901 
  1902 setup {*
  1903   Code.add_case @{thm Let_case_cert}
  1904   #> Code.add_undefined @{const_name undefined}
  1905 *}
  1906 
  1907 code_abort undefined
  1908 
  1909 
  1910 subsubsection {* Generic code generator target languages *}
  1911 
  1912 text {* type @{typ bool} *}
  1913 
  1914 code_type bool
  1915   (SML "bool")
  1916   (OCaml "bool")
  1917   (Haskell "Bool")
  1918   (Scala "Boolean")
  1919 
  1920 code_const True and False and Not and HOL.conj and HOL.disj and HOL.implies and If 
  1921   (SML "true" and "false" and "not"
  1922     and infixl 1 "andalso" and infixl 0 "orelse"
  1923     and "!(if (_)/ then (_)/ else true)"
  1924     and "!(if (_)/ then (_)/ else (_))")
  1925   (OCaml "true" and "false" and "not"
  1926     and infixl 3 "&&" and infixl 2 "||"
  1927     and "!(if (_)/ then (_)/ else true)"
  1928     and "!(if (_)/ then (_)/ else (_))")
  1929   (Haskell "True" and "False" and "not"
  1930     and infixr 3 "&&" and infixr 2 "||"
  1931     and "!(if (_)/ then (_)/ else True)"
  1932     and "!(if (_)/ then (_)/ else (_))")
  1933   (Scala "true" and "false" and "'! _"
  1934     and infixl 3 "&&" and infixl 1 "||"
  1935     and "!(if ((_))/ (_)/ else true)"
  1936     and "!(if ((_))/ (_)/ else (_))")
  1937 
  1938 code_reserved SML
  1939   bool true false not
  1940 
  1941 code_reserved OCaml
  1942   bool not
  1943 
  1944 code_reserved Scala
  1945   Boolean
  1946 
  1947 code_modulename SML Pure HOL
  1948 code_modulename OCaml Pure HOL
  1949 code_modulename Haskell Pure HOL
  1950 
  1951 text {* using built-in Haskell equality *}
  1952 
  1953 code_class equal
  1954   (Haskell "Eq")
  1955 
  1956 code_const "HOL.equal"
  1957   (Haskell infix 4 "==")
  1958 
  1959 code_const HOL.eq
  1960   (Haskell infix 4 "==")
  1961 
  1962 text {* undefined *}
  1963 
  1964 code_const undefined
  1965   (SML "!(raise/ Fail/ \"undefined\")")
  1966   (OCaml "failwith/ \"undefined\"")
  1967   (Haskell "error/ \"undefined\"")
  1968   (Scala "!error(\"undefined\")")
  1969 
  1970 subsubsection {* Evaluation and normalization by evaluation *}
  1971 
  1972 ML {*
  1973 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1974   (CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 (conv ctxt))) ctxt)
  1975     THEN' rtac TrueI)
  1976 *}
  1977 
  1978 method_setup eval = {*
  1979   Scan.succeed (gen_eval_method (Code_Runtime.dynamic_holds_conv o Proof_Context.theory_of))
  1980 *} "solve goal by evaluation"
  1981 
  1982 method_setup evaluation = {*
  1983   Scan.succeed (gen_eval_method Codegen.evaluation_conv)
  1984 *} "solve goal by evaluation"
  1985 
  1986 method_setup normalization = {*
  1987   Scan.succeed (fn ctxt => SIMPLE_METHOD'
  1988     (CHANGED_PROP o (CONVERSION (Nbe.dynamic_conv (Proof_Context.theory_of ctxt))
  1989       THEN' (fn k => TRY (rtac TrueI k)))))
  1990 *} "solve goal by normalization"
  1991 
  1992 
  1993 subsection {* Counterexample Search Units *}
  1994 
  1995 subsubsection {* Quickcheck *}
  1996 
  1997 quickcheck_params [size = 5, iterations = 50]
  1998 
  1999 
  2000 subsubsection {* Nitpick setup *}
  2001 
  2002 ML {*
  2003 structure Nitpick_Unfolds = Named_Thms
  2004 (
  2005   val name = "nitpick_unfold"
  2006   val description = "alternative definitions of constants as needed by Nitpick"
  2007 )
  2008 structure Nitpick_Simps = Named_Thms
  2009 (
  2010   val name = "nitpick_simp"
  2011   val description = "equational specification of constants as needed by Nitpick"
  2012 )
  2013 structure Nitpick_Psimps = Named_Thms
  2014 (
  2015   val name = "nitpick_psimp"
  2016   val description = "partial equational specification of constants as needed by Nitpick"
  2017 )
  2018 structure Nitpick_Choice_Specs = Named_Thms
  2019 (
  2020   val name = "nitpick_choice_spec"
  2021   val description = "choice specification of constants as needed by Nitpick"
  2022 )
  2023 *}
  2024 
  2025 setup {*
  2026   Nitpick_Unfolds.setup
  2027   #> Nitpick_Simps.setup
  2028   #> Nitpick_Psimps.setup
  2029   #> Nitpick_Choice_Specs.setup
  2030 *}
  2031 
  2032 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  2033         if_bool_eq_disj [no_atp]
  2034 
  2035 
  2036 subsection {* Preprocessing for the predicate compiler *}
  2037 
  2038 ML {*
  2039 structure Predicate_Compile_Alternative_Defs = Named_Thms
  2040 (
  2041   val name = "code_pred_def"
  2042   val description = "alternative definitions of constants for the Predicate Compiler"
  2043 )
  2044 structure Predicate_Compile_Inline_Defs = Named_Thms
  2045 (
  2046   val name = "code_pred_inline"
  2047   val description = "inlining definitions for the Predicate Compiler"
  2048 )
  2049 structure Predicate_Compile_Simps = Named_Thms
  2050 (
  2051   val name = "code_pred_simp"
  2052   val description = "simplification rules for the optimisations in the Predicate Compiler"
  2053 )
  2054 *}
  2055 
  2056 setup {*
  2057   Predicate_Compile_Alternative_Defs.setup
  2058   #> Predicate_Compile_Inline_Defs.setup
  2059   #> Predicate_Compile_Simps.setup
  2060 *}
  2061 
  2062 
  2063 subsection {* Legacy tactics and ML bindings *}
  2064 
  2065 ML {*
  2066 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2067 
  2068 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2069 local
  2070   fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  2071     | wrong_prem (Bound _) = true
  2072     | wrong_prem _ = false;
  2073   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2074 in
  2075   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2076   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2077 end;
  2078 
  2079 val all_conj_distrib = @{thm all_conj_distrib};
  2080 val all_simps = @{thms all_simps};
  2081 val atomize_not = @{thm atomize_not};
  2082 val case_split = @{thm case_split};
  2083 val cases_simp = @{thm cases_simp};
  2084 val choice_eq = @{thm choice_eq};
  2085 val cong = @{thm cong};
  2086 val conj_comms = @{thms conj_comms};
  2087 val conj_cong = @{thm conj_cong};
  2088 val de_Morgan_conj = @{thm de_Morgan_conj};
  2089 val de_Morgan_disj = @{thm de_Morgan_disj};
  2090 val disj_assoc = @{thm disj_assoc};
  2091 val disj_comms = @{thms disj_comms};
  2092 val disj_cong = @{thm disj_cong};
  2093 val eq_ac = @{thms eq_ac};
  2094 val eq_cong2 = @{thm eq_cong2}
  2095 val Eq_FalseI = @{thm Eq_FalseI};
  2096 val Eq_TrueI = @{thm Eq_TrueI};
  2097 val Ex1_def = @{thm Ex1_def};
  2098 val ex_disj_distrib = @{thm ex_disj_distrib};
  2099 val ex_simps = @{thms ex_simps};
  2100 val if_cancel = @{thm if_cancel};
  2101 val if_eq_cancel = @{thm if_eq_cancel};
  2102 val if_False = @{thm if_False};
  2103 val iff_conv_conj_imp = @{thm iff_conv_conj_imp};
  2104 val iff = @{thm iff};
  2105 val if_splits = @{thms if_splits};
  2106 val if_True = @{thm if_True};
  2107 val if_weak_cong = @{thm if_weak_cong};
  2108 val imp_all = @{thm imp_all};
  2109 val imp_cong = @{thm imp_cong};
  2110 val imp_conjL = @{thm imp_conjL};
  2111 val imp_conjR = @{thm imp_conjR};
  2112 val imp_conv_disj = @{thm imp_conv_disj};
  2113 val simp_implies_def = @{thm simp_implies_def};
  2114 val simp_thms = @{thms simp_thms};
  2115 val split_if = @{thm split_if};
  2116 val the1_equality = @{thm the1_equality};
  2117 val theI = @{thm theI};
  2118 val theI' = @{thm theI'};
  2119 val True_implies_equals = @{thm True_implies_equals};
  2120 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2121 
  2122 *}
  2123 
  2124 hide_const (open) eq equal
  2125 
  2126 end