src/HOL/Auth/Message.thy
author wenzelm
Wed Mar 19 22:50:42 2008 +0100 (2008-03-19)
changeset 26342 0f65fa163304
parent 24122 fc7f857d33c8
child 26807 4cd176ea28dc
permissions -rw-r--r--
more antiquotations;
     1 (*  Title:      HOL/Auth/Message
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 Datatypes of agents and messages;
     7 Inductive relations "parts", "analz" and "synth"
     8 *)
     9 
    10 header{*Theory of Agents and Messages for Security Protocols*}
    11 
    12 theory Message imports Main begin
    13 
    14 (*Needed occasionally with spy_analz_tac, e.g. in analz_insert_Key_newK*)
    15 lemma [simp] : "A \<union> (B \<union> A) = B \<union> A"
    16 by blast
    17 
    18 types 
    19   key = nat
    20 
    21 consts
    22   all_symmetric :: bool        --{*true if all keys are symmetric*}
    23   invKey        :: "key=>key"  --{*inverse of a symmetric key*}
    24 
    25 specification (invKey)
    26   invKey [simp]: "invKey (invKey K) = K"
    27   invKey_symmetric: "all_symmetric --> invKey = id"
    28     by (rule exI [of _ id], auto)
    29 
    30 
    31 text{*The inverse of a symmetric key is itself; that of a public key
    32       is the private key and vice versa*}
    33 
    34 constdefs
    35   symKeys :: "key set"
    36   "symKeys == {K. invKey K = K}"
    37 
    38 datatype  --{*We allow any number of friendly agents*}
    39   agent = Server | Friend nat | Spy
    40 
    41 datatype
    42      msg = Agent  agent	    --{*Agent names*}
    43          | Number nat       --{*Ordinary integers, timestamps, ...*}
    44          | Nonce  nat       --{*Unguessable nonces*}
    45          | Key    key       --{*Crypto keys*}
    46 	 | Hash   msg       --{*Hashing*}
    47 	 | MPair  msg msg   --{*Compound messages*}
    48 	 | Crypt  key msg   --{*Encryption, public- or shared-key*}
    49 
    50 
    51 text{*Concrete syntax: messages appear as {|A,B,NA|}, etc...*}
    52 syntax
    53   "@MTuple"      :: "['a, args] => 'a * 'b"       ("(2{|_,/ _|})")
    54 
    55 syntax (xsymbols)
    56   "@MTuple"      :: "['a, args] => 'a * 'b"       ("(2\<lbrace>_,/ _\<rbrace>)")
    57 
    58 translations
    59   "{|x, y, z|}"   == "{|x, {|y, z|}|}"
    60   "{|x, y|}"      == "MPair x y"
    61 
    62 
    63 constdefs
    64   HPair :: "[msg,msg] => msg"                       ("(4Hash[_] /_)" [0, 1000])
    65     --{*Message Y paired with a MAC computed with the help of X*}
    66     "Hash[X] Y == {| Hash{|X,Y|}, Y|}"
    67 
    68   keysFor :: "msg set => key set"
    69     --{*Keys useful to decrypt elements of a message set*}
    70   "keysFor H == invKey ` {K. \<exists>X. Crypt K X \<in> H}"
    71 
    72 
    73 subsubsection{*Inductive Definition of All Parts" of a Message*}
    74 
    75 inductive_set
    76   parts :: "msg set => msg set"
    77   for H :: "msg set"
    78   where
    79     Inj [intro]:               "X \<in> H ==> X \<in> parts H"
    80   | Fst:         "{|X,Y|}   \<in> parts H ==> X \<in> parts H"
    81   | Snd:         "{|X,Y|}   \<in> parts H ==> Y \<in> parts H"
    82   | Body:        "Crypt K X \<in> parts H ==> X \<in> parts H"
    83 
    84 
    85 text{*Monotonicity*}
    86 lemma parts_mono: "G \<subseteq> H ==> parts(G) \<subseteq> parts(H)"
    87 apply auto
    88 apply (erule parts.induct) 
    89 apply (blast dest: parts.Fst parts.Snd parts.Body)+
    90 done
    91 
    92 
    93 text{*Equations hold because constructors are injective.*}
    94 lemma Friend_image_eq [simp]: "(Friend x \<in> Friend`A) = (x:A)"
    95 by auto
    96 
    97 lemma Key_image_eq [simp]: "(Key x \<in> Key`A) = (x\<in>A)"
    98 by auto
    99 
   100 lemma Nonce_Key_image_eq [simp]: "(Nonce x \<notin> Key`A)"
   101 by auto
   102 
   103 
   104 subsubsection{*Inverse of keys *}
   105 
   106 lemma invKey_eq [simp]: "(invKey K = invKey K') = (K=K')"
   107 apply safe
   108 apply (drule_tac f = invKey in arg_cong, simp)
   109 done
   110 
   111 
   112 subsection{*keysFor operator*}
   113 
   114 lemma keysFor_empty [simp]: "keysFor {} = {}"
   115 by (unfold keysFor_def, blast)
   116 
   117 lemma keysFor_Un [simp]: "keysFor (H \<union> H') = keysFor H \<union> keysFor H'"
   118 by (unfold keysFor_def, blast)
   119 
   120 lemma keysFor_UN [simp]: "keysFor (\<Union>i\<in>A. H i) = (\<Union>i\<in>A. keysFor (H i))"
   121 by (unfold keysFor_def, blast)
   122 
   123 text{*Monotonicity*}
   124 lemma keysFor_mono: "G \<subseteq> H ==> keysFor(G) \<subseteq> keysFor(H)"
   125 by (unfold keysFor_def, blast)
   126 
   127 lemma keysFor_insert_Agent [simp]: "keysFor (insert (Agent A) H) = keysFor H"
   128 by (unfold keysFor_def, auto)
   129 
   130 lemma keysFor_insert_Nonce [simp]: "keysFor (insert (Nonce N) H) = keysFor H"
   131 by (unfold keysFor_def, auto)
   132 
   133 lemma keysFor_insert_Number [simp]: "keysFor (insert (Number N) H) = keysFor H"
   134 by (unfold keysFor_def, auto)
   135 
   136 lemma keysFor_insert_Key [simp]: "keysFor (insert (Key K) H) = keysFor H"
   137 by (unfold keysFor_def, auto)
   138 
   139 lemma keysFor_insert_Hash [simp]: "keysFor (insert (Hash X) H) = keysFor H"
   140 by (unfold keysFor_def, auto)
   141 
   142 lemma keysFor_insert_MPair [simp]: "keysFor (insert {|X,Y|} H) = keysFor H"
   143 by (unfold keysFor_def, auto)
   144 
   145 lemma keysFor_insert_Crypt [simp]: 
   146     "keysFor (insert (Crypt K X) H) = insert (invKey K) (keysFor H)"
   147 by (unfold keysFor_def, auto)
   148 
   149 lemma keysFor_image_Key [simp]: "keysFor (Key`E) = {}"
   150 by (unfold keysFor_def, auto)
   151 
   152 lemma Crypt_imp_invKey_keysFor: "Crypt K X \<in> H ==> invKey K \<in> keysFor H"
   153 by (unfold keysFor_def, blast)
   154 
   155 
   156 subsection{*Inductive relation "parts"*}
   157 
   158 lemma MPair_parts:
   159      "[| {|X,Y|} \<in> parts H;        
   160          [| X \<in> parts H; Y \<in> parts H |] ==> P |] ==> P"
   161 by (blast dest: parts.Fst parts.Snd) 
   162 
   163 declare MPair_parts [elim!]  parts.Body [dest!]
   164 text{*NB These two rules are UNSAFE in the formal sense, as they discard the
   165      compound message.  They work well on THIS FILE.  
   166   @{text MPair_parts} is left as SAFE because it speeds up proofs.
   167   The Crypt rule is normally kept UNSAFE to avoid breaking up certificates.*}
   168 
   169 lemma parts_increasing: "H \<subseteq> parts(H)"
   170 by blast
   171 
   172 lemmas parts_insertI = subset_insertI [THEN parts_mono, THEN subsetD, standard]
   173 
   174 lemma parts_empty [simp]: "parts{} = {}"
   175 apply safe
   176 apply (erule parts.induct, blast+)
   177 done
   178 
   179 lemma parts_emptyE [elim!]: "X\<in> parts{} ==> P"
   180 by simp
   181 
   182 text{*WARNING: loops if H = {Y}, therefore must not be repeated!*}
   183 lemma parts_singleton: "X\<in> parts H ==> \<exists>Y\<in>H. X\<in> parts {Y}"
   184 by (erule parts.induct, blast+)
   185 
   186 
   187 subsubsection{*Unions *}
   188 
   189 lemma parts_Un_subset1: "parts(G) \<union> parts(H) \<subseteq> parts(G \<union> H)"
   190 by (intro Un_least parts_mono Un_upper1 Un_upper2)
   191 
   192 lemma parts_Un_subset2: "parts(G \<union> H) \<subseteq> parts(G) \<union> parts(H)"
   193 apply (rule subsetI)
   194 apply (erule parts.induct, blast+)
   195 done
   196 
   197 lemma parts_Un [simp]: "parts(G \<union> H) = parts(G) \<union> parts(H)"
   198 by (intro equalityI parts_Un_subset1 parts_Un_subset2)
   199 
   200 lemma parts_insert: "parts (insert X H) = parts {X} \<union> parts H"
   201 apply (subst insert_is_Un [of _ H])
   202 apply (simp only: parts_Un)
   203 done
   204 
   205 text{*TWO inserts to avoid looping.  This rewrite is better than nothing.
   206   Not suitable for Addsimps: its behaviour can be strange.*}
   207 lemma parts_insert2:
   208      "parts (insert X (insert Y H)) = parts {X} \<union> parts {Y} \<union> parts H"
   209 apply (simp add: Un_assoc)
   210 apply (simp add: parts_insert [symmetric])
   211 done
   212 
   213 lemma parts_UN_subset1: "(\<Union>x\<in>A. parts(H x)) \<subseteq> parts(\<Union>x\<in>A. H x)"
   214 by (intro UN_least parts_mono UN_upper)
   215 
   216 lemma parts_UN_subset2: "parts(\<Union>x\<in>A. H x) \<subseteq> (\<Union>x\<in>A. parts(H x))"
   217 apply (rule subsetI)
   218 apply (erule parts.induct, blast+)
   219 done
   220 
   221 lemma parts_UN [simp]: "parts(\<Union>x\<in>A. H x) = (\<Union>x\<in>A. parts(H x))"
   222 by (intro equalityI parts_UN_subset1 parts_UN_subset2)
   223 
   224 text{*Added to simplify arguments to parts, analz and synth.
   225   NOTE: the UN versions are no longer used!*}
   226 
   227 
   228 text{*This allows @{text blast} to simplify occurrences of 
   229   @{term "parts(G\<union>H)"} in the assumption.*}
   230 lemmas in_parts_UnE = parts_Un [THEN equalityD1, THEN subsetD, THEN UnE] 
   231 declare in_parts_UnE [elim!]
   232 
   233 
   234 lemma parts_insert_subset: "insert X (parts H) \<subseteq> parts(insert X H)"
   235 by (blast intro: parts_mono [THEN [2] rev_subsetD])
   236 
   237 subsubsection{*Idempotence and transitivity *}
   238 
   239 lemma parts_partsD [dest!]: "X\<in> parts (parts H) ==> X\<in> parts H"
   240 by (erule parts.induct, blast+)
   241 
   242 lemma parts_idem [simp]: "parts (parts H) = parts H"
   243 by blast
   244 
   245 lemma parts_subset_iff [simp]: "(parts G \<subseteq> parts H) = (G \<subseteq> parts H)"
   246 apply (rule iffI)
   247 apply (iprover intro: subset_trans parts_increasing)  
   248 apply (frule parts_mono, simp) 
   249 done
   250 
   251 lemma parts_trans: "[| X\<in> parts G;  G \<subseteq> parts H |] ==> X\<in> parts H"
   252 by (drule parts_mono, blast)
   253 
   254 text{*Cut*}
   255 lemma parts_cut:
   256      "[| Y\<in> parts (insert X G);  X\<in> parts H |] ==> Y\<in> parts (G \<union> H)" 
   257 by (blast intro: parts_trans) 
   258 
   259 
   260 lemma parts_cut_eq [simp]: "X\<in> parts H ==> parts (insert X H) = parts H"
   261 by (force dest!: parts_cut intro: parts_insertI)
   262 
   263 
   264 subsubsection{*Rewrite rules for pulling out atomic messages *}
   265 
   266 lemmas parts_insert_eq_I = equalityI [OF subsetI parts_insert_subset]
   267 
   268 
   269 lemma parts_insert_Agent [simp]:
   270      "parts (insert (Agent agt) H) = insert (Agent agt) (parts H)"
   271 apply (rule parts_insert_eq_I) 
   272 apply (erule parts.induct, auto) 
   273 done
   274 
   275 lemma parts_insert_Nonce [simp]:
   276      "parts (insert (Nonce N) H) = insert (Nonce N) (parts H)"
   277 apply (rule parts_insert_eq_I) 
   278 apply (erule parts.induct, auto) 
   279 done
   280 
   281 lemma parts_insert_Number [simp]:
   282      "parts (insert (Number N) H) = insert (Number N) (parts H)"
   283 apply (rule parts_insert_eq_I) 
   284 apply (erule parts.induct, auto) 
   285 done
   286 
   287 lemma parts_insert_Key [simp]:
   288      "parts (insert (Key K) H) = insert (Key K) (parts H)"
   289 apply (rule parts_insert_eq_I) 
   290 apply (erule parts.induct, auto) 
   291 done
   292 
   293 lemma parts_insert_Hash [simp]:
   294      "parts (insert (Hash X) H) = insert (Hash X) (parts H)"
   295 apply (rule parts_insert_eq_I) 
   296 apply (erule parts.induct, auto) 
   297 done
   298 
   299 lemma parts_insert_Crypt [simp]:
   300      "parts (insert (Crypt K X) H) = insert (Crypt K X) (parts (insert X H))"
   301 apply (rule equalityI)
   302 apply (rule subsetI)
   303 apply (erule parts.induct, auto)
   304 apply (blast intro: parts.Body)
   305 done
   306 
   307 lemma parts_insert_MPair [simp]:
   308      "parts (insert {|X,Y|} H) =  
   309           insert {|X,Y|} (parts (insert X (insert Y H)))"
   310 apply (rule equalityI)
   311 apply (rule subsetI)
   312 apply (erule parts.induct, auto)
   313 apply (blast intro: parts.Fst parts.Snd)+
   314 done
   315 
   316 lemma parts_image_Key [simp]: "parts (Key`N) = Key`N"
   317 apply auto
   318 apply (erule parts.induct, auto)
   319 done
   320 
   321 
   322 text{*In any message, there is an upper bound N on its greatest nonce.*}
   323 lemma msg_Nonce_supply: "\<exists>N. \<forall>n. N\<le>n --> Nonce n \<notin> parts {msg}"
   324 apply (induct_tac "msg")
   325 apply (simp_all (no_asm_simp) add: exI parts_insert2)
   326  txt{*MPair case: blast works out the necessary sum itself!*}
   327  prefer 2 apply auto apply (blast elim!: add_leE)
   328 txt{*Nonce case*}
   329 apply (rule_tac x = "N + Suc nat" in exI, auto) 
   330 done
   331 
   332 
   333 subsection{*Inductive relation "analz"*}
   334 
   335 text{*Inductive definition of "analz" -- what can be broken down from a set of
   336     messages, including keys.  A form of downward closure.  Pairs can
   337     be taken apart; messages decrypted with known keys.  *}
   338 
   339 inductive_set
   340   analz :: "msg set => msg set"
   341   for H :: "msg set"
   342   where
   343     Inj [intro,simp] :    "X \<in> H ==> X \<in> analz H"
   344   | Fst:     "{|X,Y|} \<in> analz H ==> X \<in> analz H"
   345   | Snd:     "{|X,Y|} \<in> analz H ==> Y \<in> analz H"
   346   | Decrypt [dest]: 
   347              "[|Crypt K X \<in> analz H; Key(invKey K): analz H|] ==> X \<in> analz H"
   348 
   349 
   350 text{*Monotonicity; Lemma 1 of Lowe's paper*}
   351 lemma analz_mono: "G\<subseteq>H ==> analz(G) \<subseteq> analz(H)"
   352 apply auto
   353 apply (erule analz.induct) 
   354 apply (auto dest: analz.Fst analz.Snd) 
   355 done
   356 
   357 text{*Making it safe speeds up proofs*}
   358 lemma MPair_analz [elim!]:
   359      "[| {|X,Y|} \<in> analz H;        
   360              [| X \<in> analz H; Y \<in> analz H |] ==> P   
   361           |] ==> P"
   362 by (blast dest: analz.Fst analz.Snd)
   363 
   364 lemma analz_increasing: "H \<subseteq> analz(H)"
   365 by blast
   366 
   367 lemma analz_subset_parts: "analz H \<subseteq> parts H"
   368 apply (rule subsetI)
   369 apply (erule analz.induct, blast+)
   370 done
   371 
   372 lemmas analz_into_parts = analz_subset_parts [THEN subsetD, standard]
   373 
   374 lemmas not_parts_not_analz = analz_subset_parts [THEN contra_subsetD, standard]
   375 
   376 
   377 lemma parts_analz [simp]: "parts (analz H) = parts H"
   378 apply (rule equalityI)
   379 apply (rule analz_subset_parts [THEN parts_mono, THEN subset_trans], simp)
   380 apply (blast intro: analz_increasing [THEN parts_mono, THEN subsetD])
   381 done
   382 
   383 lemma analz_parts [simp]: "analz (parts H) = parts H"
   384 apply auto
   385 apply (erule analz.induct, auto)
   386 done
   387 
   388 lemmas analz_insertI = subset_insertI [THEN analz_mono, THEN [2] rev_subsetD, standard]
   389 
   390 subsubsection{*General equational properties *}
   391 
   392 lemma analz_empty [simp]: "analz{} = {}"
   393 apply safe
   394 apply (erule analz.induct, blast+)
   395 done
   396 
   397 text{*Converse fails: we can analz more from the union than from the 
   398   separate parts, as a key in one might decrypt a message in the other*}
   399 lemma analz_Un: "analz(G) \<union> analz(H) \<subseteq> analz(G \<union> H)"
   400 by (intro Un_least analz_mono Un_upper1 Un_upper2)
   401 
   402 lemma analz_insert: "insert X (analz H) \<subseteq> analz(insert X H)"
   403 by (blast intro: analz_mono [THEN [2] rev_subsetD])
   404 
   405 subsubsection{*Rewrite rules for pulling out atomic messages *}
   406 
   407 lemmas analz_insert_eq_I = equalityI [OF subsetI analz_insert]
   408 
   409 lemma analz_insert_Agent [simp]:
   410      "analz (insert (Agent agt) H) = insert (Agent agt) (analz H)"
   411 apply (rule analz_insert_eq_I) 
   412 apply (erule analz.induct, auto) 
   413 done
   414 
   415 lemma analz_insert_Nonce [simp]:
   416      "analz (insert (Nonce N) H) = insert (Nonce N) (analz H)"
   417 apply (rule analz_insert_eq_I) 
   418 apply (erule analz.induct, auto) 
   419 done
   420 
   421 lemma analz_insert_Number [simp]:
   422      "analz (insert (Number N) H) = insert (Number N) (analz H)"
   423 apply (rule analz_insert_eq_I) 
   424 apply (erule analz.induct, auto) 
   425 done
   426 
   427 lemma analz_insert_Hash [simp]:
   428      "analz (insert (Hash X) H) = insert (Hash X) (analz H)"
   429 apply (rule analz_insert_eq_I) 
   430 apply (erule analz.induct, auto) 
   431 done
   432 
   433 text{*Can only pull out Keys if they are not needed to decrypt the rest*}
   434 lemma analz_insert_Key [simp]: 
   435     "K \<notin> keysFor (analz H) ==>   
   436           analz (insert (Key K) H) = insert (Key K) (analz H)"
   437 apply (unfold keysFor_def)
   438 apply (rule analz_insert_eq_I) 
   439 apply (erule analz.induct, auto) 
   440 done
   441 
   442 lemma analz_insert_MPair [simp]:
   443      "analz (insert {|X,Y|} H) =  
   444           insert {|X,Y|} (analz (insert X (insert Y H)))"
   445 apply (rule equalityI)
   446 apply (rule subsetI)
   447 apply (erule analz.induct, auto)
   448 apply (erule analz.induct)
   449 apply (blast intro: analz.Fst analz.Snd)+
   450 done
   451 
   452 text{*Can pull out enCrypted message if the Key is not known*}
   453 lemma analz_insert_Crypt:
   454      "Key (invKey K) \<notin> analz H 
   455       ==> analz (insert (Crypt K X) H) = insert (Crypt K X) (analz H)"
   456 apply (rule analz_insert_eq_I) 
   457 apply (erule analz.induct, auto) 
   458 
   459 done
   460 
   461 lemma lemma1: "Key (invKey K) \<in> analz H ==>   
   462                analz (insert (Crypt K X) H) \<subseteq>  
   463                insert (Crypt K X) (analz (insert X H))"
   464 apply (rule subsetI)
   465 apply (erule_tac x = x in analz.induct, auto)
   466 done
   467 
   468 lemma lemma2: "Key (invKey K) \<in> analz H ==>   
   469                insert (Crypt K X) (analz (insert X H)) \<subseteq>  
   470                analz (insert (Crypt K X) H)"
   471 apply auto
   472 apply (erule_tac x = x in analz.induct, auto)
   473 apply (blast intro: analz_insertI analz.Decrypt)
   474 done
   475 
   476 lemma analz_insert_Decrypt:
   477      "Key (invKey K) \<in> analz H ==>   
   478                analz (insert (Crypt K X) H) =  
   479                insert (Crypt K X) (analz (insert X H))"
   480 by (intro equalityI lemma1 lemma2)
   481 
   482 text{*Case analysis: either the message is secure, or it is not! Effective,
   483 but can cause subgoals to blow up! Use with @{text "split_if"}; apparently
   484 @{text "split_tac"} does not cope with patterns such as @{term"analz (insert
   485 (Crypt K X) H)"} *} 
   486 lemma analz_Crypt_if [simp]:
   487      "analz (insert (Crypt K X) H) =                 
   488           (if (Key (invKey K) \<in> analz H)                 
   489            then insert (Crypt K X) (analz (insert X H))  
   490            else insert (Crypt K X) (analz H))"
   491 by (simp add: analz_insert_Crypt analz_insert_Decrypt)
   492 
   493 
   494 text{*This rule supposes "for the sake of argument" that we have the key.*}
   495 lemma analz_insert_Crypt_subset:
   496      "analz (insert (Crypt K X) H) \<subseteq>   
   497            insert (Crypt K X) (analz (insert X H))"
   498 apply (rule subsetI)
   499 apply (erule analz.induct, auto)
   500 done
   501 
   502 
   503 lemma analz_image_Key [simp]: "analz (Key`N) = Key`N"
   504 apply auto
   505 apply (erule analz.induct, auto)
   506 done
   507 
   508 
   509 subsubsection{*Idempotence and transitivity *}
   510 
   511 lemma analz_analzD [dest!]: "X\<in> analz (analz H) ==> X\<in> analz H"
   512 by (erule analz.induct, blast+)
   513 
   514 lemma analz_idem [simp]: "analz (analz H) = analz H"
   515 by blast
   516 
   517 lemma analz_subset_iff [simp]: "(analz G \<subseteq> analz H) = (G \<subseteq> analz H)"
   518 apply (rule iffI)
   519 apply (iprover intro: subset_trans analz_increasing)  
   520 apply (frule analz_mono, simp) 
   521 done
   522 
   523 lemma analz_trans: "[| X\<in> analz G;  G \<subseteq> analz H |] ==> X\<in> analz H"
   524 by (drule analz_mono, blast)
   525 
   526 text{*Cut; Lemma 2 of Lowe*}
   527 lemma analz_cut: "[| Y\<in> analz (insert X H);  X\<in> analz H |] ==> Y\<in> analz H"
   528 by (erule analz_trans, blast)
   529 
   530 (*Cut can be proved easily by induction on
   531    "Y: analz (insert X H) ==> X: analz H --> Y: analz H"
   532 *)
   533 
   534 text{*This rewrite rule helps in the simplification of messages that involve
   535   the forwarding of unknown components (X).  Without it, removing occurrences
   536   of X can be very complicated. *}
   537 lemma analz_insert_eq: "X\<in> analz H ==> analz (insert X H) = analz H"
   538 by (blast intro: analz_cut analz_insertI)
   539 
   540 
   541 text{*A congruence rule for "analz" *}
   542 
   543 lemma analz_subset_cong:
   544      "[| analz G \<subseteq> analz G'; analz H \<subseteq> analz H' |] 
   545       ==> analz (G \<union> H) \<subseteq> analz (G' \<union> H')"
   546 apply simp
   547 apply (iprover intro: conjI subset_trans analz_mono Un_upper1 Un_upper2) 
   548 done
   549 
   550 lemma analz_cong:
   551      "[| analz G = analz G'; analz H = analz H' |] 
   552       ==> analz (G \<union> H) = analz (G' \<union> H')"
   553 by (intro equalityI analz_subset_cong, simp_all) 
   554 
   555 lemma analz_insert_cong:
   556      "analz H = analz H' ==> analz(insert X H) = analz(insert X H')"
   557 by (force simp only: insert_def intro!: analz_cong)
   558 
   559 text{*If there are no pairs or encryptions then analz does nothing*}
   560 lemma analz_trivial:
   561      "[| \<forall>X Y. {|X,Y|} \<notin> H;  \<forall>X K. Crypt K X \<notin> H |] ==> analz H = H"
   562 apply safe
   563 apply (erule analz.induct, blast+)
   564 done
   565 
   566 text{*These two are obsolete (with a single Spy) but cost little to prove...*}
   567 lemma analz_UN_analz_lemma:
   568      "X\<in> analz (\<Union>i\<in>A. analz (H i)) ==> X\<in> analz (\<Union>i\<in>A. H i)"
   569 apply (erule analz.induct)
   570 apply (blast intro: analz_mono [THEN [2] rev_subsetD])+
   571 done
   572 
   573 lemma analz_UN_analz [simp]: "analz (\<Union>i\<in>A. analz (H i)) = analz (\<Union>i\<in>A. H i)"
   574 by (blast intro: analz_UN_analz_lemma analz_mono [THEN [2] rev_subsetD])
   575 
   576 
   577 subsection{*Inductive relation "synth"*}
   578 
   579 text{*Inductive definition of "synth" -- what can be built up from a set of
   580     messages.  A form of upward closure.  Pairs can be built, messages
   581     encrypted with known keys.  Agent names are public domain.
   582     Numbers can be guessed, but Nonces cannot be.  *}
   583 
   584 inductive_set
   585   synth :: "msg set => msg set"
   586   for H :: "msg set"
   587   where
   588     Inj    [intro]:   "X \<in> H ==> X \<in> synth H"
   589   | Agent  [intro]:   "Agent agt \<in> synth H"
   590   | Number [intro]:   "Number n  \<in> synth H"
   591   | Hash   [intro]:   "X \<in> synth H ==> Hash X \<in> synth H"
   592   | MPair  [intro]:   "[|X \<in> synth H;  Y \<in> synth H|] ==> {|X,Y|} \<in> synth H"
   593   | Crypt  [intro]:   "[|X \<in> synth H;  Key(K) \<in> H|] ==> Crypt K X \<in> synth H"
   594 
   595 text{*Monotonicity*}
   596 lemma synth_mono: "G\<subseteq>H ==> synth(G) \<subseteq> synth(H)"
   597   by (auto, erule synth.induct, auto)  
   598 
   599 text{*NO @{text Agent_synth}, as any Agent name can be synthesized.  
   600   The same holds for @{term Number}*}
   601 inductive_cases Nonce_synth [elim!]: "Nonce n \<in> synth H"
   602 inductive_cases Key_synth   [elim!]: "Key K \<in> synth H"
   603 inductive_cases Hash_synth  [elim!]: "Hash X \<in> synth H"
   604 inductive_cases MPair_synth [elim!]: "{|X,Y|} \<in> synth H"
   605 inductive_cases Crypt_synth [elim!]: "Crypt K X \<in> synth H"
   606 
   607 
   608 lemma synth_increasing: "H \<subseteq> synth(H)"
   609 by blast
   610 
   611 subsubsection{*Unions *}
   612 
   613 text{*Converse fails: we can synth more from the union than from the 
   614   separate parts, building a compound message using elements of each.*}
   615 lemma synth_Un: "synth(G) \<union> synth(H) \<subseteq> synth(G \<union> H)"
   616 by (intro Un_least synth_mono Un_upper1 Un_upper2)
   617 
   618 lemma synth_insert: "insert X (synth H) \<subseteq> synth(insert X H)"
   619 by (blast intro: synth_mono [THEN [2] rev_subsetD])
   620 
   621 subsubsection{*Idempotence and transitivity *}
   622 
   623 lemma synth_synthD [dest!]: "X\<in> synth (synth H) ==> X\<in> synth H"
   624 by (erule synth.induct, blast+)
   625 
   626 lemma synth_idem: "synth (synth H) = synth H"
   627 by blast
   628 
   629 lemma synth_subset_iff [simp]: "(synth G \<subseteq> synth H) = (G \<subseteq> synth H)"
   630 apply (rule iffI)
   631 apply (iprover intro: subset_trans synth_increasing)  
   632 apply (frule synth_mono, simp add: synth_idem) 
   633 done
   634 
   635 lemma synth_trans: "[| X\<in> synth G;  G \<subseteq> synth H |] ==> X\<in> synth H"
   636 by (drule synth_mono, blast)
   637 
   638 text{*Cut; Lemma 2 of Lowe*}
   639 lemma synth_cut: "[| Y\<in> synth (insert X H);  X\<in> synth H |] ==> Y\<in> synth H"
   640 by (erule synth_trans, blast)
   641 
   642 lemma Agent_synth [simp]: "Agent A \<in> synth H"
   643 by blast
   644 
   645 lemma Number_synth [simp]: "Number n \<in> synth H"
   646 by blast
   647 
   648 lemma Nonce_synth_eq [simp]: "(Nonce N \<in> synth H) = (Nonce N \<in> H)"
   649 by blast
   650 
   651 lemma Key_synth_eq [simp]: "(Key K \<in> synth H) = (Key K \<in> H)"
   652 by blast
   653 
   654 lemma Crypt_synth_eq [simp]:
   655      "Key K \<notin> H ==> (Crypt K X \<in> synth H) = (Crypt K X \<in> H)"
   656 by blast
   657 
   658 
   659 lemma keysFor_synth [simp]: 
   660     "keysFor (synth H) = keysFor H \<union> invKey`{K. Key K \<in> H}"
   661 by (unfold keysFor_def, blast)
   662 
   663 
   664 subsubsection{*Combinations of parts, analz and synth *}
   665 
   666 lemma parts_synth [simp]: "parts (synth H) = parts H \<union> synth H"
   667 apply (rule equalityI)
   668 apply (rule subsetI)
   669 apply (erule parts.induct)
   670 apply (blast intro: synth_increasing [THEN parts_mono, THEN subsetD] 
   671                     parts.Fst parts.Snd parts.Body)+
   672 done
   673 
   674 lemma analz_analz_Un [simp]: "analz (analz G \<union> H) = analz (G \<union> H)"
   675 apply (intro equalityI analz_subset_cong)+
   676 apply simp_all
   677 done
   678 
   679 lemma analz_synth_Un [simp]: "analz (synth G \<union> H) = analz (G \<union> H) \<union> synth G"
   680 apply (rule equalityI)
   681 apply (rule subsetI)
   682 apply (erule analz.induct)
   683 prefer 5 apply (blast intro: analz_mono [THEN [2] rev_subsetD])
   684 apply (blast intro: analz.Fst analz.Snd analz.Decrypt)+
   685 done
   686 
   687 lemma analz_synth [simp]: "analz (synth H) = analz H \<union> synth H"
   688 apply (cut_tac H = "{}" in analz_synth_Un)
   689 apply (simp (no_asm_use))
   690 done
   691 
   692 
   693 subsubsection{*For reasoning about the Fake rule in traces *}
   694 
   695 lemma parts_insert_subset_Un: "X\<in> G ==> parts(insert X H) \<subseteq> parts G \<union> parts H"
   696 by (rule subset_trans [OF parts_mono parts_Un_subset2], blast)
   697 
   698 text{*More specifically for Fake.  Very occasionally we could do with a version
   699   of the form  @{term"parts{X} \<subseteq> synth (analz H) \<union> parts H"} *}
   700 lemma Fake_parts_insert:
   701      "X \<in> synth (analz H) ==>  
   702       parts (insert X H) \<subseteq> synth (analz H) \<union> parts H"
   703 apply (drule parts_insert_subset_Un)
   704 apply (simp (no_asm_use))
   705 apply blast
   706 done
   707 
   708 lemma Fake_parts_insert_in_Un:
   709      "[|Z \<in> parts (insert X H);  X: synth (analz H)|] 
   710       ==> Z \<in>  synth (analz H) \<union> parts H";
   711 by (blast dest: Fake_parts_insert  [THEN subsetD, dest])
   712 
   713 text{*@{term H} is sometimes @{term"Key ` KK \<union> spies evs"}, so can't put 
   714   @{term "G=H"}.*}
   715 lemma Fake_analz_insert:
   716      "X\<in> synth (analz G) ==>  
   717       analz (insert X H) \<subseteq> synth (analz G) \<union> analz (G \<union> H)"
   718 apply (rule subsetI)
   719 apply (subgoal_tac "x \<in> analz (synth (analz G) \<union> H) ")
   720 prefer 2 apply (blast intro: analz_mono [THEN [2] rev_subsetD] analz_mono [THEN synth_mono, THEN [2] rev_subsetD])
   721 apply (simp (no_asm_use))
   722 apply blast
   723 done
   724 
   725 lemma analz_conj_parts [simp]:
   726      "(X \<in> analz H & X \<in> parts H) = (X \<in> analz H)"
   727 by (blast intro: analz_subset_parts [THEN subsetD])
   728 
   729 lemma analz_disj_parts [simp]:
   730      "(X \<in> analz H | X \<in> parts H) = (X \<in> parts H)"
   731 by (blast intro: analz_subset_parts [THEN subsetD])
   732 
   733 text{*Without this equation, other rules for synth and analz would yield
   734   redundant cases*}
   735 lemma MPair_synth_analz [iff]:
   736      "({|X,Y|} \<in> synth (analz H)) =  
   737       (X \<in> synth (analz H) & Y \<in> synth (analz H))"
   738 by blast
   739 
   740 lemma Crypt_synth_analz:
   741      "[| Key K \<in> analz H;  Key (invKey K) \<in> analz H |]  
   742        ==> (Crypt K X \<in> synth (analz H)) = (X \<in> synth (analz H))"
   743 by blast
   744 
   745 
   746 lemma Hash_synth_analz [simp]:
   747      "X \<notin> synth (analz H)  
   748       ==> (Hash{|X,Y|} \<in> synth (analz H)) = (Hash{|X,Y|} \<in> analz H)"
   749 by blast
   750 
   751 
   752 subsection{*HPair: a combination of Hash and MPair*}
   753 
   754 subsubsection{*Freeness *}
   755 
   756 lemma Agent_neq_HPair: "Agent A ~= Hash[X] Y"
   757 by (unfold HPair_def, simp)
   758 
   759 lemma Nonce_neq_HPair: "Nonce N ~= Hash[X] Y"
   760 by (unfold HPair_def, simp)
   761 
   762 lemma Number_neq_HPair: "Number N ~= Hash[X] Y"
   763 by (unfold HPair_def, simp)
   764 
   765 lemma Key_neq_HPair: "Key K ~= Hash[X] Y"
   766 by (unfold HPair_def, simp)
   767 
   768 lemma Hash_neq_HPair: "Hash Z ~= Hash[X] Y"
   769 by (unfold HPair_def, simp)
   770 
   771 lemma Crypt_neq_HPair: "Crypt K X' ~= Hash[X] Y"
   772 by (unfold HPair_def, simp)
   773 
   774 lemmas HPair_neqs = Agent_neq_HPair Nonce_neq_HPair Number_neq_HPair 
   775                     Key_neq_HPair Hash_neq_HPair Crypt_neq_HPair
   776 
   777 declare HPair_neqs [iff]
   778 declare HPair_neqs [symmetric, iff]
   779 
   780 lemma HPair_eq [iff]: "(Hash[X'] Y' = Hash[X] Y) = (X' = X & Y'=Y)"
   781 by (simp add: HPair_def)
   782 
   783 lemma MPair_eq_HPair [iff]:
   784      "({|X',Y'|} = Hash[X] Y) = (X' = Hash{|X,Y|} & Y'=Y)"
   785 by (simp add: HPair_def)
   786 
   787 lemma HPair_eq_MPair [iff]:
   788      "(Hash[X] Y = {|X',Y'|}) = (X' = Hash{|X,Y|} & Y'=Y)"
   789 by (auto simp add: HPair_def)
   790 
   791 
   792 subsubsection{*Specialized laws, proved in terms of those for Hash and MPair *}
   793 
   794 lemma keysFor_insert_HPair [simp]: "keysFor (insert (Hash[X] Y) H) = keysFor H"
   795 by (simp add: HPair_def)
   796 
   797 lemma parts_insert_HPair [simp]: 
   798     "parts (insert (Hash[X] Y) H) =  
   799      insert (Hash[X] Y) (insert (Hash{|X,Y|}) (parts (insert Y H)))"
   800 by (simp add: HPair_def)
   801 
   802 lemma analz_insert_HPair [simp]: 
   803     "analz (insert (Hash[X] Y) H) =  
   804      insert (Hash[X] Y) (insert (Hash{|X,Y|}) (analz (insert Y H)))"
   805 by (simp add: HPair_def)
   806 
   807 lemma HPair_synth_analz [simp]:
   808      "X \<notin> synth (analz H)  
   809     ==> (Hash[X] Y \<in> synth (analz H)) =  
   810         (Hash {|X, Y|} \<in> analz H & Y \<in> synth (analz H))"
   811 by (simp add: HPair_def)
   812 
   813 
   814 text{*We do NOT want Crypt... messages broken up in protocols!!*}
   815 declare parts.Body [rule del]
   816 
   817 
   818 text{*Rewrites to push in Key and Crypt messages, so that other messages can
   819     be pulled out using the @{text analz_insert} rules*}
   820 ML
   821 {*
   822 fun insComm x y = inst "x" x (inst "y" y insert_commute);
   823 
   824 bind_thms ("pushKeys",
   825            map (insComm "Key ?K") 
   826                    ["Agent ?C", "Nonce ?N", "Number ?N", 
   827 		    "Hash ?X", "MPair ?X ?Y", "Crypt ?X ?K'"]);
   828 
   829 bind_thms ("pushCrypts",
   830            map (insComm "Crypt ?X ?K") 
   831                      ["Agent ?C", "Nonce ?N", "Number ?N", 
   832 		      "Hash ?X'", "MPair ?X' ?Y"]);
   833 *}
   834 
   835 text{*Cannot be added with @{text "[simp]"} -- messages should not always be
   836   re-ordered. *}
   837 lemmas pushes = pushKeys pushCrypts
   838 
   839 
   840 subsection{*Tactics useful for many protocol proofs*}
   841 ML
   842 {*
   843 structure Message =
   844 struct
   845 
   846 (*Prove base case (subgoal i) and simplify others.  A typical base case
   847   concerns  Crypt K X \<notin> Key`shrK`bad  and cannot be proved by rewriting
   848   alone.*)
   849 fun prove_simple_subgoals_tac i = 
   850     CLASIMPSET' (fn (cs, ss) => force_tac (cs, ss addsimps [@{thm image_eq_UN}])) i THEN
   851     ALLGOALS (SIMPSET' asm_simp_tac)
   852 
   853 (*Analysis of Fake cases.  Also works for messages that forward unknown parts,
   854   but this application is no longer necessary if analz_insert_eq is used.
   855   Abstraction over i is ESSENTIAL: it delays the dereferencing of claset
   856   DEPENDS UPON "X" REFERRING TO THE FRADULENT MESSAGE *)
   857 
   858 (*Apply rules to break down assumptions of the form
   859   Y \<in> parts(insert X H)  and  Y \<in> analz(insert X H)
   860 *)
   861 val Fake_insert_tac = 
   862     dresolve_tac [impOfSubs @{thm Fake_analz_insert},
   863                   impOfSubs @{thm Fake_parts_insert}] THEN'
   864     eresolve_tac [asm_rl, @{thm synth.Inj}];
   865 
   866 fun Fake_insert_simp_tac ss i = 
   867     REPEAT (Fake_insert_tac i) THEN asm_full_simp_tac ss i;
   868 
   869 fun atomic_spy_analz_tac (cs,ss) = SELECT_GOAL
   870     (Fake_insert_simp_tac ss 1
   871      THEN
   872      IF_UNSOLVED (Blast.depth_tac
   873 		  (cs addIs [@{thm analz_insertI},
   874 				   impOfSubs @{thm analz_subset_parts}]) 4 1))
   875 
   876 (*The explicit claset and simpset arguments help it work with Isar*)
   877 fun gen_spy_analz_tac (cs,ss) i =
   878   DETERM
   879    (SELECT_GOAL
   880      (EVERY 
   881       [  (*push in occurrences of X...*)
   882        (REPEAT o CHANGED)
   883            (res_inst_tac [("x1","X")] (insert_commute RS ssubst) 1),
   884        (*...allowing further simplifications*)
   885        simp_tac ss 1,
   886        REPEAT (FIRSTGOAL (resolve_tac [allI,impI,notI,conjI,iffI])),
   887        DEPTH_SOLVE (atomic_spy_analz_tac (cs,ss) 1)]) i)
   888 
   889 val spy_analz_tac = CLASIMPSET' gen_spy_analz_tac;
   890 
   891 end
   892 *}
   893 
   894 text{*By default only @{text o_apply} is built-in.  But in the presence of
   895 eta-expansion this means that some terms displayed as @{term "f o g"} will be
   896 rewritten, and others will not!*}
   897 declare o_def [simp]
   898 
   899 
   900 lemma Crypt_notin_image_Key [simp]: "Crypt K X \<notin> Key ` A"
   901 by auto
   902 
   903 lemma Hash_notin_image_Key [simp] :"Hash X \<notin> Key ` A"
   904 by auto
   905 
   906 lemma synth_analz_mono: "G\<subseteq>H ==> synth (analz(G)) \<subseteq> synth (analz(H))"
   907 by (iprover intro: synth_mono analz_mono) 
   908 
   909 lemma Fake_analz_eq [simp]:
   910      "X \<in> synth(analz H) ==> synth (analz (insert X H)) = synth (analz H)"
   911 apply (drule Fake_analz_insert[of _ _ "H"])
   912 apply (simp add: synth_increasing[THEN Un_absorb2])
   913 apply (drule synth_mono)
   914 apply (simp add: synth_idem)
   915 apply (rule equalityI)
   916 apply (simp add: );
   917 apply (rule synth_analz_mono, blast)   
   918 done
   919 
   920 text{*Two generalizations of @{text analz_insert_eq}*}
   921 lemma gen_analz_insert_eq [rule_format]:
   922      "X \<in> analz H ==> ALL G. H \<subseteq> G --> analz (insert X G) = analz G";
   923 by (blast intro: analz_cut analz_insertI analz_mono [THEN [2] rev_subsetD])
   924 
   925 lemma synth_analz_insert_eq [rule_format]:
   926      "X \<in> synth (analz H) 
   927       ==> ALL G. H \<subseteq> G --> (Key K \<in> analz (insert X G)) = (Key K \<in> analz G)";
   928 apply (erule synth.induct) 
   929 apply (simp_all add: gen_analz_insert_eq subset_trans [OF _ subset_insertI]) 
   930 done
   931 
   932 lemma Fake_parts_sing:
   933      "X \<in> synth (analz H) ==> parts{X} \<subseteq> synth (analz H) \<union> parts H";
   934 apply (rule subset_trans) 
   935  apply (erule_tac [2] Fake_parts_insert)
   936 apply (rule parts_mono, blast)
   937 done
   938 
   939 lemmas Fake_parts_sing_imp_Un = Fake_parts_sing [THEN [2] rev_subsetD]
   940 
   941 method_setup spy_analz = {*
   942     Method.ctxt_args (fn ctxt =>
   943         Method.SIMPLE_METHOD (Message.gen_spy_analz_tac (local_clasimpset_of ctxt) 1)) *}
   944     "for proving the Fake case when analz is involved"
   945 
   946 method_setup atomic_spy_analz = {*
   947     Method.ctxt_args (fn ctxt =>
   948         Method.SIMPLE_METHOD (Message.atomic_spy_analz_tac (local_clasimpset_of ctxt) 1)) *}
   949     "for debugging spy_analz"
   950 
   951 method_setup Fake_insert_simp = {*
   952     Method.ctxt_args (fn ctxt =>
   953         Method.SIMPLE_METHOD (Message.Fake_insert_simp_tac (local_simpset_of ctxt) 1)) *}
   954     "for debugging spy_analz"
   955 
   956 end