src/HOL/Nat.thy
author wenzelm
Wed Mar 04 19:53:18 2015 +0100 (2015-03-04)
changeset 59582 0fbed69ff081
parent 59000 6eb0725503fc
child 59815 cce82e360c2f
permissions -rw-r--r--
tuned signature -- prefer qualified names;
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 section {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 
    16 named_theorems arith "arith facts -- only ground formulas"
    17 ML_file "Tools/arith_data.ML"
    18 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    19 
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef nat = "{n. Nat n}"
    39   morphisms Rep_Nat Abs_Nat
    40   using Nat.Zero_RepI by auto
    41 
    42 lemma Nat_Rep_Nat:
    43   "Nat (Rep_Nat n)"
    44   using Rep_Nat by simp
    45 
    46 lemma Nat_Abs_Nat_inverse:
    47   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    48   using Abs_Nat_inverse by simp
    49 
    50 lemma Nat_Abs_Nat_inject:
    51   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    52   using Abs_Nat_inject by simp
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 definition Suc :: "nat \<Rightarrow> nat" where
    65   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    66 
    67 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    68   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    74   by (rule iffI, rule Suc_Rep_inject) simp_all
    75 
    76 lemma nat_induct0:
    77   fixes n
    78   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    79   shows "P n"
    80 using assms
    81 apply (unfold Zero_nat_def Suc_def)
    82 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    83 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    84 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    85 done
    86 
    87 free_constructors case_nat for
    88     "0 \<Colon> nat"
    89   | Suc pred
    90 where
    91   "pred (0 \<Colon> nat) = (0 \<Colon> nat)"
    92     apply atomize_elim
    93     apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    94    apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI Suc_Rep_inject'
    95      Rep_Nat_inject)
    96   apply (simp only: Suc_not_Zero)
    97   done
    98 
    99 -- {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   100 setup {* Sign.mandatory_path "old" *}
   101 
   102 old_rep_datatype "0 \<Colon> nat" Suc
   103   apply (erule nat_induct0, assumption)
   104  apply (rule nat.inject)
   105 apply (rule nat.distinct(1))
   106 done
   107 
   108 setup {* Sign.parent_path *}
   109 
   110 -- {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   111 setup {* Sign.mandatory_path "nat" *}
   112 
   113 declare
   114   old.nat.inject[iff del]
   115   old.nat.distinct(1)[simp del, induct_simp del]
   116 
   117 lemmas induct = old.nat.induct
   118 lemmas inducts = old.nat.inducts
   119 lemmas rec = old.nat.rec
   120 lemmas simps = nat.inject nat.distinct nat.case nat.rec
   121 
   122 setup {* Sign.parent_path *}
   123 
   124 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   125   "rec_nat \<equiv> old.rec_nat"
   126 
   127 declare nat.sel[code del]
   128 
   129 hide_const (open) Nat.pred -- {* hide everything related to the selector *}
   130 hide_fact
   131   nat.case_eq_if
   132   nat.collapse
   133   nat.expand
   134   nat.sel
   135   nat.exhaust_sel
   136   nat.split_sel
   137   nat.split_sel_asm
   138 
   139 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   140   -- {* for backward compatibility -- names of variables differ *}
   141   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   142 by (rule old.nat.exhaust)
   143 
   144 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   145   -- {* for backward compatibility -- names of variables differ *}
   146   fixes n
   147   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   148   shows "P n"
   149 using assms by (rule nat.induct)
   150 
   151 hide_fact
   152   nat_exhaust
   153   nat_induct0
   154 
   155 ML {*
   156 val nat_basic_lfp_sugar =
   157   let
   158     val ctr_sugar = the (Ctr_Sugar.ctr_sugar_of_global @{theory} @{type_name nat});
   159     val recx = Logic.varify_types_global @{term rec_nat};
   160     val C = body_type (fastype_of recx);
   161   in
   162     {T = HOLogic.natT, fp_res_index = 0, C = C, fun_arg_Tsss = [[], [[HOLogic.natT, C]]],
   163      ctr_sugar = ctr_sugar, recx = recx, rec_thms = @{thms nat.rec}}
   164   end;
   165 *}
   166 
   167 setup {*
   168 let
   169   fun basic_lfp_sugars_of _ [@{typ nat}] _ _ ctxt =
   170       ([], [0], [nat_basic_lfp_sugar], [], [], TrueI (*dummy*), [], false, ctxt)
   171     | basic_lfp_sugars_of bs arg_Ts callers callssss ctxt =
   172       BNF_LFP_Rec_Sugar.default_basic_lfp_sugars_of bs arg_Ts callers callssss ctxt;
   173 in
   174   BNF_LFP_Rec_Sugar.register_lfp_rec_extension
   175     {nested_simps = [], is_new_datatype = K (K true), basic_lfp_sugars_of = basic_lfp_sugars_of,
   176      rewrite_nested_rec_call = NONE}
   177 end
   178 *}
   179 
   180 text {* Injectiveness and distinctness lemmas *}
   181 
   182 lemma inj_Suc[simp]: "inj_on Suc N"
   183   by (simp add: inj_on_def)
   184 
   185 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   186 by (rule notE, rule Suc_not_Zero)
   187 
   188 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   189 by (rule Suc_neq_Zero, erule sym)
   190 
   191 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   192 by (rule inj_Suc [THEN injD])
   193 
   194 lemma n_not_Suc_n: "n \<noteq> Suc n"
   195 by (induct n) simp_all
   196 
   197 lemma Suc_n_not_n: "Suc n \<noteq> n"
   198 by (rule not_sym, rule n_not_Suc_n)
   199 
   200 text {* A special form of induction for reasoning
   201   about @{term "m < n"} and @{term "m - n"} *}
   202 
   203 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   204     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   205   apply (rule_tac x = m in spec)
   206   apply (induct n)
   207   prefer 2
   208   apply (rule allI)
   209   apply (induct_tac x, iprover+)
   210   done
   211 
   212 
   213 subsection {* Arithmetic operators *}
   214 
   215 instantiation nat :: comm_monoid_diff
   216 begin
   217 
   218 primrec plus_nat where
   219   add_0:      "0 + n = (n\<Colon>nat)"
   220 | add_Suc:  "Suc m + n = Suc (m + n)"
   221 
   222 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   223   by (induct m) simp_all
   224 
   225 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   226   by (induct m) simp_all
   227 
   228 declare add_0 [code]
   229 
   230 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   231   by simp
   232 
   233 primrec minus_nat where
   234   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   235 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   236 
   237 declare diff_Suc [simp del]
   238 
   239 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   240   by (induct n) (simp_all add: diff_Suc)
   241 
   242 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   243   by (induct n) (simp_all add: diff_Suc)
   244 
   245 instance proof
   246   fix n m q :: nat
   247   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   248   show "n + m = m + n" by (induct n) simp_all
   249   show "0 + n = n" by simp
   250   show "n - 0 = n" by simp
   251   show "0 - n = 0" by simp
   252   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   253   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   254 qed
   255 
   256 end
   257 
   258 hide_fact (open) add_0 add_0_right diff_0
   259 
   260 instantiation nat :: comm_semiring_1_cancel
   261 begin
   262 
   263 definition
   264   One_nat_def [simp]: "1 = Suc 0"
   265 
   266 primrec times_nat where
   267   mult_0:     "0 * n = (0\<Colon>nat)"
   268 | mult_Suc: "Suc m * n = n + (m * n)"
   269 
   270 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   271   by (induct m) simp_all
   272 
   273 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   274   by (induct m) (simp_all add: add.left_commute)
   275 
   276 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   277   by (induct m) (simp_all add: add.assoc)
   278 
   279 instance proof
   280   fix n m q :: nat
   281   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   282   show "1 * n = n" unfolding One_nat_def by simp
   283   show "n * m = m * n" by (induct n) simp_all
   284   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   285   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   286   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   287 qed
   288 
   289 end
   290 
   291 subsubsection {* Addition *}
   292 
   293 lemma nat_add_left_cancel:
   294   fixes k m n :: nat
   295   shows "k + m = k + n \<longleftrightarrow> m = n"
   296   by (fact add_left_cancel)
   297 
   298 lemma nat_add_right_cancel:
   299   fixes k m n :: nat
   300   shows "m + k = n + k \<longleftrightarrow> m = n"
   301   by (fact add_right_cancel)
   302 
   303 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   304 
   305 lemma add_is_0 [iff]:
   306   fixes m n :: nat
   307   shows "(m + n = 0) = (m = 0 & n = 0)"
   308   by (cases m) simp_all
   309 
   310 lemma add_is_1:
   311   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   312   by (cases m) simp_all
   313 
   314 lemma one_is_add:
   315   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   316   by (rule trans, rule eq_commute, rule add_is_1)
   317 
   318 lemma add_eq_self_zero:
   319   fixes m n :: nat
   320   shows "m + n = m \<Longrightarrow> n = 0"
   321   by (induct m) simp_all
   322 
   323 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   324   apply (induct k)
   325    apply simp
   326   apply(drule comp_inj_on[OF _ inj_Suc])
   327   apply (simp add:o_def)
   328   done
   329 
   330 lemma Suc_eq_plus1: "Suc n = n + 1"
   331   unfolding One_nat_def by simp
   332 
   333 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   334   unfolding One_nat_def by simp
   335 
   336 
   337 subsubsection {* Difference *}
   338 
   339 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   340   by (fact diff_cancel)
   341 
   342 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   343   by (fact diff_diff_add)
   344 
   345 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   346   by (simp add: diff_diff_left)
   347 
   348 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   349   by (fact diff_right_commute)
   350 
   351 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   352   by (fact add_diff_cancel_left')
   353 
   354 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   355   by (fact add_diff_cancel_right')
   356 
   357 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   358   by (fact comm_monoid_diff_class.add_diff_cancel_left)
   359 
   360 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   361   by (fact add_diff_cancel_right)
   362 
   363 lemma diff_add_0: "n - (n + m) = (0::nat)"
   364   by (fact diff_add_zero)
   365 
   366 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   367   unfolding One_nat_def by simp
   368 
   369 text {* Difference distributes over multiplication *}
   370 
   371 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   372 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   373 
   374 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   375 by (simp add: diff_mult_distrib mult.commute [of k])
   376   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   377 
   378 
   379 subsubsection {* Multiplication *}
   380 
   381 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   382   by (fact distrib_left)
   383 
   384 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   385   by (induct m) auto
   386 
   387 lemmas nat_distrib =
   388   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   389 
   390 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   391   apply (induct m)
   392    apply simp
   393   apply (induct n)
   394    apply auto
   395   done
   396 
   397 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   398   apply (rule trans)
   399   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   400   done
   401 
   402 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   403   unfolding One_nat_def by (rule mult_eq_1_iff)
   404 
   405 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   406   unfolding One_nat_def by (rule one_eq_mult_iff)
   407 
   408 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   409 proof -
   410   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   411   proof (induct n arbitrary: m)
   412     case 0 then show "m = 0" by simp
   413   next
   414     case (Suc n) then show "m = Suc n"
   415       by (cases m) (simp_all add: eq_commute [of "0"])
   416   qed
   417   then show ?thesis by auto
   418 qed
   419 
   420 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   421   by (simp add: mult.commute)
   422 
   423 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   424   by (subst mult_cancel1) simp
   425 
   426 
   427 subsection {* Orders on @{typ nat} *}
   428 
   429 subsubsection {* Operation definition *}
   430 
   431 instantiation nat :: linorder
   432 begin
   433 
   434 primrec less_eq_nat where
   435   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   436 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   437 
   438 declare less_eq_nat.simps [simp del]
   439 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   440 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   441 
   442 definition less_nat where
   443   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   444 
   445 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   446   by (simp add: less_eq_nat.simps(2))
   447 
   448 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   449   unfolding less_eq_Suc_le ..
   450 
   451 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   452   by (induct n) (simp_all add: less_eq_nat.simps(2))
   453 
   454 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   455   by (simp add: less_eq_Suc_le)
   456 
   457 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   458   by simp
   459 
   460 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   461   by (simp add: less_eq_Suc_le)
   462 
   463 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   464   by (simp add: less_eq_Suc_le)
   465 
   466 lemma Suc_less_eq2: "Suc n < m \<longleftrightarrow> (\<exists>m'. m = Suc m' \<and> n < m')"
   467   by (cases m) auto
   468 
   469 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   470   by (induct m arbitrary: n)
   471     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   472 
   473 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   474   by (cases n) (auto intro: le_SucI)
   475 
   476 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   477   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   478 
   479 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   480   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   481 
   482 instance
   483 proof
   484   fix n m :: nat
   485   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   486   proof (induct n arbitrary: m)
   487     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   488   next
   489     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   490   qed
   491 next
   492   fix n :: nat show "n \<le> n" by (induct n) simp_all
   493 next
   494   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   495   then show "n = m"
   496     by (induct n arbitrary: m)
   497       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   498 next
   499   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   500   then show "n \<le> q"
   501   proof (induct n arbitrary: m q)
   502     case 0 show ?case by simp
   503   next
   504     case (Suc n) then show ?case
   505       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   506         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   507         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   508   qed
   509 next
   510   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   511     by (induct n arbitrary: m)
   512       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   513 qed
   514 
   515 end
   516 
   517 instantiation nat :: order_bot
   518 begin
   519 
   520 definition bot_nat :: nat where
   521   "bot_nat = 0"
   522 
   523 instance proof
   524 qed (simp add: bot_nat_def)
   525 
   526 end
   527 
   528 instance nat :: no_top
   529   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   530 
   531 
   532 subsubsection {* Introduction properties *}
   533 
   534 lemma lessI [iff]: "n < Suc n"
   535   by (simp add: less_Suc_eq_le)
   536 
   537 lemma zero_less_Suc [iff]: "0 < Suc n"
   538   by (simp add: less_Suc_eq_le)
   539 
   540 
   541 subsubsection {* Elimination properties *}
   542 
   543 lemma less_not_refl: "~ n < (n::nat)"
   544   by (rule order_less_irrefl)
   545 
   546 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   547   by (rule not_sym) (rule less_imp_neq) 
   548 
   549 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   550   by (rule less_imp_neq)
   551 
   552 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   553   by (rule notE, rule less_not_refl)
   554 
   555 lemma less_zeroE: "(n::nat) < 0 ==> R"
   556   by (rule notE) (rule not_less0)
   557 
   558 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   559   unfolding less_Suc_eq_le le_less ..
   560 
   561 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   562   by (simp add: less_Suc_eq)
   563 
   564 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   565   unfolding One_nat_def by (rule less_Suc0)
   566 
   567 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   568   by simp
   569 
   570 text {* "Less than" is antisymmetric, sort of *}
   571 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   572   unfolding not_less less_Suc_eq_le by (rule antisym)
   573 
   574 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   575   by (rule linorder_neq_iff)
   576 
   577 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   578   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   579   shows "P n m"
   580   apply (rule less_linear [THEN disjE])
   581   apply (erule_tac [2] disjE)
   582   apply (erule lessCase)
   583   apply (erule sym [THEN eqCase])
   584   apply (erule major)
   585   done
   586 
   587 
   588 subsubsection {* Inductive (?) properties *}
   589 
   590 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   591   unfolding less_eq_Suc_le [of m] le_less by simp 
   592 
   593 lemma lessE:
   594   assumes major: "i < k"
   595   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   596   shows P
   597 proof -
   598   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   599     unfolding less_eq_Suc_le by (induct k) simp_all
   600   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   601     by (clarsimp simp add: less_le)
   602   with p1 p2 show P by auto
   603 qed
   604 
   605 lemma less_SucE: assumes major: "m < Suc n"
   606   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   607   apply (rule major [THEN lessE])
   608   apply (rule eq, blast)
   609   apply (rule less, blast)
   610   done
   611 
   612 lemma Suc_lessE: assumes major: "Suc i < k"
   613   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   614   apply (rule major [THEN lessE])
   615   apply (erule lessI [THEN minor])
   616   apply (erule Suc_lessD [THEN minor], assumption)
   617   done
   618 
   619 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   620   by simp
   621 
   622 lemma less_trans_Suc:
   623   assumes le: "i < j" shows "j < k ==> Suc i < k"
   624   apply (induct k, simp_all)
   625   apply (insert le)
   626   apply (simp add: less_Suc_eq)
   627   apply (blast dest: Suc_lessD)
   628   done
   629 
   630 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   631 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   632   unfolding not_less less_Suc_eq_le ..
   633 
   634 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   635   unfolding not_le Suc_le_eq ..
   636 
   637 text {* Properties of "less than or equal" *}
   638 
   639 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   640   unfolding less_Suc_eq_le .
   641 
   642 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   643   unfolding not_le less_Suc_eq_le ..
   644 
   645 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   646   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   647 
   648 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   649   by (drule le_Suc_eq [THEN iffD1], iprover+)
   650 
   651 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   652   unfolding Suc_le_eq .
   653 
   654 text {* Stronger version of @{text Suc_leD} *}
   655 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   656   unfolding Suc_le_eq .
   657 
   658 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   659   unfolding less_eq_Suc_le by (rule Suc_leD)
   660 
   661 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   662 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   663 
   664 
   665 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   666 
   667 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   668   unfolding le_less .
   669 
   670 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   671   by (rule le_less)
   672 
   673 text {* Useful with @{text blast}. *}
   674 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   675   by auto
   676 
   677 lemma le_refl: "n \<le> (n::nat)"
   678   by simp
   679 
   680 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   681   by (rule order_trans)
   682 
   683 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   684   by (rule antisym)
   685 
   686 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   687   by (rule less_le)
   688 
   689 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   690   unfolding less_le ..
   691 
   692 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   693   by (rule linear)
   694 
   695 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   696 
   697 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   698   unfolding less_Suc_eq_le by auto
   699 
   700 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   701   unfolding not_less by (rule le_less_Suc_eq)
   702 
   703 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   704 
   705 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   706 by (cases n) simp_all
   707 
   708 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   709 by (cases n) simp_all
   710 
   711 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   712 by (cases n) simp_all
   713 
   714 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   715 by (cases n) simp_all
   716 
   717 text {* This theorem is useful with @{text blast} *}
   718 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   719 by (rule neq0_conv[THEN iffD1], iprover)
   720 
   721 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   722 by (fast intro: not0_implies_Suc)
   723 
   724 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   725 using neq0_conv by blast
   726 
   727 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   728 by (induct m') simp_all
   729 
   730 text {* Useful in certain inductive arguments *}
   731 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   732 by (cases m) simp_all
   733 
   734 
   735 subsubsection {* Monotonicity of Addition *}
   736 
   737 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   738 by (simp add: diff_Suc split: nat.split)
   739 
   740 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   741 unfolding One_nat_def by (rule Suc_pred)
   742 
   743 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   744 by (induct k) simp_all
   745 
   746 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   747 by (induct k) simp_all
   748 
   749 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   750 by(auto dest:gr0_implies_Suc)
   751 
   752 text {* strict, in 1st argument *}
   753 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   754 by (induct k) simp_all
   755 
   756 text {* strict, in both arguments *}
   757 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   758   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   759   apply (induct j, simp_all)
   760   done
   761 
   762 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   763 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   764   apply (induct n)
   765   apply (simp_all add: order_le_less)
   766   apply (blast elim!: less_SucE
   767                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   768   done
   769 
   770 lemma le_Suc_ex: "(k::nat) \<le> l \<Longrightarrow> (\<exists>n. l = k + n)"
   771   by (auto simp: less_Suc_eq_le[symmetric] dest: less_imp_Suc_add)
   772 
   773 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   774 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   775 apply(auto simp: gr0_conv_Suc)
   776 apply (induct_tac m)
   777 apply (simp_all add: add_less_mono)
   778 done
   779 
   780 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   781 instance nat :: linordered_semidom
   782 proof
   783   show "0 < (1::nat)" by simp
   784   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   785   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   786 qed
   787 
   788 instance nat :: semiring_no_zero_divisors
   789 proof
   790   fix m n :: nat
   791   show "m \<noteq> 0 \<Longrightarrow> n \<noteq> 0 \<Longrightarrow> m * n \<noteq> 0" by simp
   792 qed
   793 
   794 
   795 subsubsection {* @{term min} and @{term max} *}
   796 
   797 lemma mono_Suc: "mono Suc"
   798 by (rule monoI) simp
   799 
   800 lemma min_0L [simp]: "min 0 n = (0::nat)"
   801 by (rule min_absorb1) simp
   802 
   803 lemma min_0R [simp]: "min n 0 = (0::nat)"
   804 by (rule min_absorb2) simp
   805 
   806 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   807 by (simp add: mono_Suc min_of_mono)
   808 
   809 lemma min_Suc1:
   810    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   811 by (simp split: nat.split)
   812 
   813 lemma min_Suc2:
   814    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   815 by (simp split: nat.split)
   816 
   817 lemma max_0L [simp]: "max 0 n = (n::nat)"
   818 by (rule max_absorb2) simp
   819 
   820 lemma max_0R [simp]: "max n 0 = (n::nat)"
   821 by (rule max_absorb1) simp
   822 
   823 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   824 by (simp add: mono_Suc max_of_mono)
   825 
   826 lemma max_Suc1:
   827    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   828 by (simp split: nat.split)
   829 
   830 lemma max_Suc2:
   831    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   832 by (simp split: nat.split)
   833 
   834 lemma nat_mult_min_left:
   835   fixes m n q :: nat
   836   shows "min m n * q = min (m * q) (n * q)"
   837   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   838 
   839 lemma nat_mult_min_right:
   840   fixes m n q :: nat
   841   shows "m * min n q = min (m * n) (m * q)"
   842   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   843 
   844 lemma nat_add_max_left:
   845   fixes m n q :: nat
   846   shows "max m n + q = max (m + q) (n + q)"
   847   by (simp add: max_def)
   848 
   849 lemma nat_add_max_right:
   850   fixes m n q :: nat
   851   shows "m + max n q = max (m + n) (m + q)"
   852   by (simp add: max_def)
   853 
   854 lemma nat_mult_max_left:
   855   fixes m n q :: nat
   856   shows "max m n * q = max (m * q) (n * q)"
   857   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   858 
   859 lemma nat_mult_max_right:
   860   fixes m n q :: nat
   861   shows "m * max n q = max (m * n) (m * q)"
   862   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   863 
   864 
   865 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   866 
   867 text {* Complete induction, aka course-of-values induction *}
   868 
   869 instance nat :: wellorder proof
   870   fix P and n :: nat
   871   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   872   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   873   proof (induct n)
   874     case (0 n)
   875     have "P 0" by (rule step) auto
   876     thus ?case using 0 by auto
   877   next
   878     case (Suc m n)
   879     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   880     thus ?case
   881     proof
   882       assume "n \<le> m" thus "P n" by (rule Suc(1))
   883     next
   884       assume n: "n = Suc m"
   885       show "P n"
   886         by (rule step) (rule Suc(1), simp add: n le_simps)
   887     qed
   888   qed
   889   then show "P n" by auto
   890 qed
   891 
   892 
   893 lemma Least_eq_0[simp]: "P(0::nat) \<Longrightarrow> Least P = 0"
   894 by (rule Least_equality[OF _ le0])
   895 
   896 lemma Least_Suc:
   897      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   898   apply (cases n, auto)
   899   apply (frule LeastI)
   900   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   901   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   902   apply (erule_tac [2] Least_le)
   903   apply (cases "LEAST x. P x", auto)
   904   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   905   apply (blast intro: order_antisym)
   906   done
   907 
   908 lemma Least_Suc2:
   909    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   910   apply (erule (1) Least_Suc [THEN ssubst])
   911   apply simp
   912   done
   913 
   914 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   915   apply (cases n)
   916    apply blast
   917   apply (rule_tac x="LEAST k. P(k)" in exI)
   918   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   919   done
   920 
   921 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   922   unfolding One_nat_def
   923   apply (cases n)
   924    apply blast
   925   apply (frule (1) ex_least_nat_le)
   926   apply (erule exE)
   927   apply (case_tac k)
   928    apply simp
   929   apply (rename_tac k1)
   930   apply (rule_tac x=k1 in exI)
   931   apply (auto simp add: less_eq_Suc_le)
   932   done
   933 
   934 lemma nat_less_induct:
   935   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   936   using assms less_induct by blast
   937 
   938 lemma measure_induct_rule [case_names less]:
   939   fixes f :: "'a \<Rightarrow> nat"
   940   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   941   shows "P a"
   942 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   943 
   944 text {* old style induction rules: *}
   945 lemma measure_induct:
   946   fixes f :: "'a \<Rightarrow> nat"
   947   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   948   by (rule measure_induct_rule [of f P a]) iprover
   949 
   950 lemma full_nat_induct:
   951   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   952   shows "P n"
   953   by (rule less_induct) (auto intro: step simp:le_simps)
   954 
   955 text{*An induction rule for estabilishing binary relations*}
   956 lemma less_Suc_induct:
   957   assumes less:  "i < j"
   958      and  step:  "!!i. P i (Suc i)"
   959      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   960   shows "P i j"
   961 proof -
   962   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   963   have "P i (Suc (i + k))"
   964   proof (induct k)
   965     case 0
   966     show ?case by (simp add: step)
   967   next
   968     case (Suc k)
   969     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   970     hence "i < Suc (i + k)" by (simp add: add.commute)
   971     from trans[OF this lessI Suc step]
   972     show ?case by simp
   973   qed
   974   thus "P i j" by (simp add: j)
   975 qed
   976 
   977 text {* The method of infinite descent, frequently used in number theory.
   978 Provided by Roelof Oosterhuis.
   979 $P(n)$ is true for all $n\in\mathbb{N}$ if
   980 \begin{itemize}
   981   \item case ``0'': given $n=0$ prove $P(n)$,
   982   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   983         a smaller integer $m$ such that $\neg P(m)$.
   984 \end{itemize} *}
   985 
   986 text{* A compact version without explicit base case: *}
   987 lemma infinite_descent:
   988   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   989 by (induct n rule: less_induct) auto
   990 
   991 lemma infinite_descent0[case_names 0 smaller]: 
   992   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   993 by (rule infinite_descent) (case_tac "n>0", auto)
   994 
   995 text {*
   996 Infinite descent using a mapping to $\mathbb{N}$:
   997 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   998 \begin{itemize}
   999 \item case ``0'': given $V(x)=0$ prove $P(x)$,
  1000 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
  1001 \end{itemize}
  1002 NB: the proof also shows how to use the previous lemma. *}
  1003 
  1004 corollary infinite_descent0_measure [case_names 0 smaller]:
  1005   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
  1006     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
  1007   shows "P x"
  1008 proof -
  1009   obtain n where "n = V x" by auto
  1010   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
  1011   proof (induct n rule: infinite_descent0)
  1012     case 0 -- "i.e. $V(x) = 0$"
  1013     with A0 show "P x" by auto
  1014   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
  1015     case (smaller n)
  1016     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
  1017     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
  1018     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
  1019     then show ?case by auto
  1020   qed
  1021   ultimately show "P x" by auto
  1022 qed
  1023 
  1024 text{* Again, without explicit base case: *}
  1025 lemma infinite_descent_measure:
  1026 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
  1027 proof -
  1028   from assms obtain n where "n = V x" by auto
  1029   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1030   proof (induct n rule: infinite_descent, auto)
  1031     fix x assume "\<not> P x"
  1032     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1033   qed
  1034   ultimately show "P x" by auto
  1035 qed
  1036 
  1037 text {* A [clumsy] way of lifting @{text "<"}
  1038   monotonicity to @{text "\<le>"} monotonicity *}
  1039 lemma less_mono_imp_le_mono:
  1040   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1041 by (simp add: order_le_less) (blast)
  1042 
  1043 
  1044 text {* non-strict, in 1st argument *}
  1045 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1046 by (rule add_right_mono)
  1047 
  1048 text {* non-strict, in both arguments *}
  1049 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1050 by (rule add_mono)
  1051 
  1052 lemma le_add2: "n \<le> ((m + n)::nat)"
  1053 by (insert add_right_mono [of 0 m n], simp)
  1054 
  1055 lemma le_add1: "n \<le> ((n + m)::nat)"
  1056 by (simp add: add.commute, rule le_add2)
  1057 
  1058 lemma less_add_Suc1: "i < Suc (i + m)"
  1059 by (rule le_less_trans, rule le_add1, rule lessI)
  1060 
  1061 lemma less_add_Suc2: "i < Suc (m + i)"
  1062 by (rule le_less_trans, rule le_add2, rule lessI)
  1063 
  1064 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1065 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1066 
  1067 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1068 by (rule le_trans, assumption, rule le_add1)
  1069 
  1070 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1071 by (rule le_trans, assumption, rule le_add2)
  1072 
  1073 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1074 by (rule less_le_trans, assumption, rule le_add1)
  1075 
  1076 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1077 by (rule less_le_trans, assumption, rule le_add2)
  1078 
  1079 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1080 apply (rule le_less_trans [of _ "i+j"])
  1081 apply (simp_all add: le_add1)
  1082 done
  1083 
  1084 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1085 apply (rule notI)
  1086 apply (drule add_lessD1)
  1087 apply (erule less_irrefl [THEN notE])
  1088 done
  1089 
  1090 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1091 by (simp add: add.commute)
  1092 
  1093 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1094 apply (rule order_trans [of _ "m+k"])
  1095 apply (simp_all add: le_add1)
  1096 done
  1097 
  1098 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1099 apply (simp add: add.commute)
  1100 apply (erule add_leD1)
  1101 done
  1102 
  1103 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1104 by (blast dest: add_leD1 add_leD2)
  1105 
  1106 text {* needs @{text "!!k"} for @{text ac_simps} to work *}
  1107 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1108 by (force simp del: add_Suc_right
  1109     simp add: less_iff_Suc_add add_Suc_right [symmetric] ac_simps)
  1110 
  1111 
  1112 subsubsection {* More results about difference *}
  1113 
  1114 text {* Addition is the inverse of subtraction:
  1115   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1116 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1117 by (induct m n rule: diff_induct) simp_all
  1118 
  1119 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1120 by (simp add: add_diff_inverse linorder_not_less)
  1121 
  1122 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1123 by (simp add: add.commute)
  1124 
  1125 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1126 by (induct m n rule: diff_induct) simp_all
  1127 
  1128 lemma diff_less_Suc: "m - n < Suc m"
  1129 apply (induct m n rule: diff_induct)
  1130 apply (erule_tac [3] less_SucE)
  1131 apply (simp_all add: less_Suc_eq)
  1132 done
  1133 
  1134 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1135 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1136 
  1137 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1138   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1139 
  1140 instance nat :: ordered_cancel_comm_monoid_diff
  1141 proof
  1142   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1143 qed
  1144 
  1145 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1146 by (rule le_less_trans, rule diff_le_self)
  1147 
  1148 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1149 by (cases n) (auto simp add: le_simps)
  1150 
  1151 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1152 by (induct j k rule: diff_induct) simp_all
  1153 
  1154 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1155 by (simp add: add.commute diff_add_assoc)
  1156 
  1157 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1158 by (auto simp add: diff_add_inverse2)
  1159 
  1160 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1161 by (induct m n rule: diff_induct) simp_all
  1162 
  1163 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1164 by (rule iffD2, rule diff_is_0_eq)
  1165 
  1166 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1167 by (induct m n rule: diff_induct) simp_all
  1168 
  1169 lemma less_imp_add_positive:
  1170   assumes "i < j"
  1171   shows "\<exists>k::nat. 0 < k & i + k = j"
  1172 proof
  1173   from assms show "0 < j - i & i + (j - i) = j"
  1174     by (simp add: order_less_imp_le)
  1175 qed
  1176 
  1177 text {* a nice rewrite for bounded subtraction *}
  1178 lemma nat_minus_add_max:
  1179   fixes n m :: nat
  1180   shows "n - m + m = max n m"
  1181     by (simp add: max_def not_le order_less_imp_le)
  1182 
  1183 lemma nat_diff_split:
  1184   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1185     -- {* elimination of @{text -} on @{text nat} *}
  1186 by (cases "a < b")
  1187   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1188     not_less le_less dest!: add_eq_self_zero add_eq_self_zero[OF sym])
  1189 
  1190 lemma nat_diff_split_asm:
  1191   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1192     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1193 by (auto split: nat_diff_split)
  1194 
  1195 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1196   by simp
  1197 
  1198 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1199   unfolding One_nat_def by (cases m) simp_all
  1200 
  1201 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1202   unfolding One_nat_def by (cases m) simp_all
  1203 
  1204 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1205   unfolding One_nat_def by (cases n) simp_all
  1206 
  1207 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1208   unfolding One_nat_def by (cases m) simp_all
  1209 
  1210 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1211   by (fact Let_def)
  1212 
  1213 
  1214 subsubsection {* Monotonicity of multiplication *}
  1215 
  1216 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1217 by (simp add: mult_right_mono)
  1218 
  1219 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1220 by (simp add: mult_left_mono)
  1221 
  1222 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1223 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1224 by (simp add: mult_mono)
  1225 
  1226 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1227 by (simp add: mult_strict_right_mono)
  1228 
  1229 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1230       there are no negative numbers.*}
  1231 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1232   apply (induct m)
  1233    apply simp
  1234   apply (case_tac n)
  1235    apply simp_all
  1236   done
  1237 
  1238 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1239   apply (induct m)
  1240    apply simp
  1241   apply (case_tac n)
  1242    apply simp_all
  1243   done
  1244 
  1245 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1246   apply (safe intro!: mult_less_mono1)
  1247   apply (cases k, auto)
  1248   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1249   apply (blast intro: mult_le_mono1)
  1250   done
  1251 
  1252 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1253 by (simp add: mult.commute [of k])
  1254 
  1255 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1256 by (simp add: linorder_not_less [symmetric], auto)
  1257 
  1258 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1259 by (simp add: linorder_not_less [symmetric], auto)
  1260 
  1261 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1262 by (subst mult_less_cancel1) simp
  1263 
  1264 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1265 by (subst mult_le_cancel1) simp
  1266 
  1267 lemma le_square: "m \<le> m * (m::nat)"
  1268   by (cases m) (auto intro: le_add1)
  1269 
  1270 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1271   by (cases m) (auto intro: le_add1)
  1272 
  1273 text {* Lemma for @{text gcd} *}
  1274 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1275   apply (drule sym)
  1276   apply (rule disjCI)
  1277   apply (rule nat_less_cases, erule_tac [2] _)
  1278    apply (drule_tac [2] mult_less_mono2)
  1279     apply (auto)
  1280   done
  1281 
  1282 lemma mono_times_nat:
  1283   fixes n :: nat
  1284   assumes "n > 0"
  1285   shows "mono (times n)"
  1286 proof
  1287   fix m q :: nat
  1288   assume "m \<le> q"
  1289   with assms show "n * m \<le> n * q" by simp
  1290 qed
  1291 
  1292 text {* the lattice order on @{typ nat} *}
  1293 
  1294 instantiation nat :: distrib_lattice
  1295 begin
  1296 
  1297 definition
  1298   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1299 
  1300 definition
  1301   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1302 
  1303 instance by intro_classes
  1304   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1305     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1306 
  1307 end
  1308 
  1309 
  1310 subsection {* Natural operation of natural numbers on functions *}
  1311 
  1312 text {*
  1313   We use the same logical constant for the power operations on
  1314   functions and relations, in order to share the same syntax.
  1315 *}
  1316 
  1317 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1318 
  1319 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1320   "f ^^ n \<equiv> compow n f"
  1321 
  1322 notation (latex output)
  1323   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1324 
  1325 notation (HTML output)
  1326   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1327 
  1328 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1329 
  1330 overloading
  1331   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1332 begin
  1333 
  1334 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1335   "funpow 0 f = id"
  1336 | "funpow (Suc n) f = f o funpow n f"
  1337 
  1338 end
  1339 
  1340 lemma funpow_Suc_right:
  1341   "f ^^ Suc n = f ^^ n \<circ> f"
  1342 proof (induct n)
  1343   case 0 then show ?case by simp
  1344 next
  1345   fix n
  1346   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1347   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1348     by (simp add: o_assoc)
  1349 qed
  1350 
  1351 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1352 
  1353 text {* for code generation *}
  1354 
  1355 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1356   funpow_code_def [code_abbrev]: "funpow = compow"
  1357 
  1358 lemma [code]:
  1359   "funpow (Suc n) f = f o funpow n f"
  1360   "funpow 0 f = id"
  1361   by (simp_all add: funpow_code_def)
  1362 
  1363 hide_const (open) funpow
  1364 
  1365 lemma funpow_add:
  1366   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1367   by (induct m) simp_all
  1368 
  1369 lemma funpow_mult:
  1370   fixes f :: "'a \<Rightarrow> 'a"
  1371   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1372   by (induct n) (simp_all add: funpow_add)
  1373 
  1374 lemma funpow_swap1:
  1375   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1376 proof -
  1377   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1378   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1379   also have "\<dots> = (f ^^ n) (f x)" by simp
  1380   finally show ?thesis .
  1381 qed
  1382 
  1383 lemma comp_funpow:
  1384   fixes f :: "'a \<Rightarrow> 'a"
  1385   shows "comp f ^^ n = comp (f ^^ n)"
  1386   by (induct n) simp_all
  1387 
  1388 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1389   by (induct n) simp_all
  1390 
  1391 lemma id_funpow[simp]: "id ^^ n = id"
  1392   by (induct n) simp_all
  1393 
  1394 lemma funpow_mono:
  1395   fixes f :: "'a \<Rightarrow> ('a::lattice)"
  1396   shows "mono f \<Longrightarrow> A \<le> B \<Longrightarrow> (f ^^ n) A \<le> (f ^^ n) B"
  1397   by (induct n arbitrary: A B)
  1398      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right mono_def)
  1399 
  1400 subsection {* Kleene iteration *}
  1401 
  1402 lemma Kleene_iter_lpfp:
  1403 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1404 proof(induction k)
  1405   case 0 show ?case by simp
  1406 next
  1407   case Suc
  1408   from monoD[OF assms(1) Suc] assms(2)
  1409   show ?case by simp
  1410 qed
  1411 
  1412 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1413 shows "lfp f = (f^^k) bot"
  1414 proof(rule antisym)
  1415   show "lfp f \<le> (f^^k) bot"
  1416   proof(rule lfp_lowerbound)
  1417     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1418   qed
  1419 next
  1420   show "(f^^k) bot \<le> lfp f"
  1421     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1422 qed
  1423 
  1424 
  1425 subsection {* Embedding of the naturals into any @{text semiring_1}: @{term of_nat} *}
  1426 
  1427 context semiring_1
  1428 begin
  1429 
  1430 definition of_nat :: "nat \<Rightarrow> 'a" where
  1431   "of_nat n = (plus 1 ^^ n) 0"
  1432 
  1433 lemma of_nat_simps [simp]:
  1434   shows of_nat_0: "of_nat 0 = 0"
  1435     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1436   by (simp_all add: of_nat_def)
  1437 
  1438 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1439   by (simp add: of_nat_def)
  1440 
  1441 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1442   by (induct m) (simp_all add: ac_simps)
  1443 
  1444 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1445   by (induct m) (simp_all add: ac_simps distrib_right)
  1446 
  1447 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1448   "of_nat_aux inc 0 i = i"
  1449 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1450 
  1451 lemma of_nat_code:
  1452   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1453 proof (induct n)
  1454   case 0 then show ?case by simp
  1455 next
  1456   case (Suc n)
  1457   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1458     by (induct n) simp_all
  1459   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1460     by simp
  1461   with Suc show ?case by (simp add: add.commute)
  1462 qed
  1463 
  1464 end
  1465 
  1466 declare of_nat_code [code]
  1467 
  1468 text{*Class for unital semirings with characteristic zero.
  1469  Includes non-ordered rings like the complex numbers.*}
  1470 
  1471 class semiring_char_0 = semiring_1 +
  1472   assumes inj_of_nat: "inj of_nat"
  1473 begin
  1474 
  1475 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1476   by (auto intro: inj_of_nat injD)
  1477 
  1478 text{*Special cases where either operand is zero*}
  1479 
  1480 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1481   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1482 
  1483 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1484   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1485 
  1486 end
  1487 
  1488 context linordered_semidom
  1489 begin
  1490 
  1491 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1492   by (induct n) simp_all
  1493 
  1494 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1495   by (simp add: not_less)
  1496 
  1497 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1498   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1499 
  1500 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1501   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1502 
  1503 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1504   by simp
  1505 
  1506 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1507   by simp
  1508 
  1509 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1510 
  1511 subclass semiring_char_0 proof
  1512 qed (auto intro!: injI simp add: eq_iff)
  1513 
  1514 text{*Special cases where either operand is zero*}
  1515 
  1516 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1517   by (rule of_nat_le_iff [of _ 0, simplified])
  1518 
  1519 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1520   by (rule of_nat_less_iff [of 0, simplified])
  1521 
  1522 end
  1523 
  1524 context ring_1
  1525 begin
  1526 
  1527 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1528 by (simp add: algebra_simps of_nat_add [symmetric])
  1529 
  1530 end
  1531 
  1532 context linordered_idom
  1533 begin
  1534 
  1535 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1536   unfolding abs_if by auto
  1537 
  1538 end
  1539 
  1540 lemma of_nat_id [simp]: "of_nat n = n"
  1541   by (induct n) simp_all
  1542 
  1543 lemma of_nat_eq_id [simp]: "of_nat = id"
  1544   by (auto simp add: fun_eq_iff)
  1545 
  1546 
  1547 subsection {* The set of natural numbers *}
  1548 
  1549 context semiring_1
  1550 begin
  1551 
  1552 definition Nats  :: "'a set" where
  1553   "Nats = range of_nat"
  1554 
  1555 notation (xsymbols)
  1556   Nats  ("\<nat>")
  1557 
  1558 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1559   by (simp add: Nats_def)
  1560 
  1561 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1562 apply (simp add: Nats_def)
  1563 apply (rule range_eqI)
  1564 apply (rule of_nat_0 [symmetric])
  1565 done
  1566 
  1567 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1568 apply (simp add: Nats_def)
  1569 apply (rule range_eqI)
  1570 apply (rule of_nat_1 [symmetric])
  1571 done
  1572 
  1573 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1574 apply (auto simp add: Nats_def)
  1575 apply (rule range_eqI)
  1576 apply (rule of_nat_add [symmetric])
  1577 done
  1578 
  1579 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1580 apply (auto simp add: Nats_def)
  1581 apply (rule range_eqI)
  1582 apply (rule of_nat_mult [symmetric])
  1583 done
  1584 
  1585 lemma Nats_cases [cases set: Nats]:
  1586   assumes "x \<in> \<nat>"
  1587   obtains (of_nat) n where "x = of_nat n"
  1588   unfolding Nats_def
  1589 proof -
  1590   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1591   then obtain n where "x = of_nat n" ..
  1592   then show thesis ..
  1593 qed
  1594 
  1595 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1596   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1597   by (rule Nats_cases) auto
  1598 
  1599 end
  1600 
  1601 
  1602 subsection {* Further arithmetic facts concerning the natural numbers *}
  1603 
  1604 lemma subst_equals:
  1605   assumes 1: "t = s" and 2: "u = t"
  1606   shows "u = s"
  1607   using 2 1 by (rule trans)
  1608 
  1609 ML_file "Tools/nat_arith.ML"
  1610 
  1611 simproc_setup nateq_cancel_sums
  1612   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1613   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1614 
  1615 simproc_setup natless_cancel_sums
  1616   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1617   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1618 
  1619 simproc_setup natle_cancel_sums
  1620   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1621   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1622 
  1623 simproc_setup natdiff_cancel_sums
  1624   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1625   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1626 
  1627 ML_file "Tools/lin_arith.ML"
  1628 setup {* Lin_Arith.global_setup *}
  1629 declaration {* K Lin_Arith.setup *}
  1630 
  1631 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1632   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (Thm.term_of ct) *}
  1633 (* Because of this simproc, the arithmetic solver is really only
  1634 useful to detect inconsistencies among the premises for subgoals which are
  1635 *not* themselves (in)equalities, because the latter activate
  1636 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1637 solver all the time rather than add the additional check. *)
  1638 
  1639 
  1640 lemmas [arith_split] = nat_diff_split split_min split_max
  1641 
  1642 context order
  1643 begin
  1644 
  1645 lemma lift_Suc_mono_le:
  1646   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1647   shows "f n \<le> f n'"
  1648 proof (cases "n < n'")
  1649   case True
  1650   then show ?thesis
  1651     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1652 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1653 
  1654 lemma lift_Suc_antimono_le:
  1655   assumes mono: "\<And>n. f n \<ge> f (Suc n)" and "n \<le> n'"
  1656   shows "f n \<ge> f n'"
  1657 proof (cases "n < n'")
  1658   case True
  1659   then show ?thesis
  1660     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1661 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1662 
  1663 lemma lift_Suc_mono_less:
  1664   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1665   shows "f n < f n'"
  1666 using `n < n'`
  1667 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1668 
  1669 lemma lift_Suc_mono_less_iff:
  1670   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1671   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1672     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1673 
  1674 end
  1675 
  1676 lemma mono_iff_le_Suc:
  1677   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1678   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1679 
  1680 lemma antimono_iff_le_Suc:
  1681   "antimono f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1682   unfolding antimono_def by (auto intro: lift_Suc_antimono_le [of f])
  1683 
  1684 lemma mono_nat_linear_lb:
  1685   fixes f :: "nat \<Rightarrow> nat"
  1686   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1687   shows "f m + k \<le> f (m + k)"
  1688 proof (induct k)
  1689   case 0 then show ?case by simp
  1690 next
  1691   case (Suc k)
  1692   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1693   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1694     by (simp add: Suc_le_eq)
  1695   finally show ?case by simp
  1696 qed
  1697 
  1698 
  1699 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1700 
  1701 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1702 by arith
  1703 
  1704 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1705 by arith
  1706 
  1707 lemma less_diff_conv2:
  1708   fixes j k i :: nat
  1709   assumes "k \<le> j"
  1710   shows "j - k < i \<longleftrightarrow> j < i + k"
  1711   using assms by arith
  1712 
  1713 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1714 by arith
  1715 
  1716 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1717   by (fact le_diff_conv2) -- {* FIXME delete *}
  1718 
  1719 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1720 by arith
  1721 
  1722 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1723   by (fact le_add_diff) -- {* FIXME delete *}
  1724 
  1725 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1726   second premise n\<le>m*)
  1727 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1728 by arith
  1729 
  1730 text {* Simplification of relational expressions involving subtraction *}
  1731 
  1732 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1733 by (simp split add: nat_diff_split)
  1734 
  1735 hide_fact (open) diff_diff_eq
  1736 
  1737 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1738 by (auto split add: nat_diff_split)
  1739 
  1740 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1741 by (auto split add: nat_diff_split)
  1742 
  1743 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1744 by (auto split add: nat_diff_split)
  1745 
  1746 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1747 
  1748 (* Monotonicity of subtraction in first argument *)
  1749 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1750 by (simp split add: nat_diff_split)
  1751 
  1752 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1753 by (simp split add: nat_diff_split)
  1754 
  1755 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1756 by (simp split add: nat_diff_split)
  1757 
  1758 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1759 by (simp split add: nat_diff_split)
  1760 
  1761 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1762 by auto
  1763 
  1764 lemma inj_on_diff_nat: 
  1765   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1766   shows "inj_on (\<lambda>n. n - k) N"
  1767 proof (rule inj_onI)
  1768   fix x y
  1769   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1770   with k_le_n have "x - k + k = y - k + k" by auto
  1771   with a k_le_n show "x = y" by auto
  1772 qed
  1773 
  1774 text{*Rewriting to pull differences out*}
  1775 
  1776 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1777 by arith
  1778 
  1779 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1780 by arith
  1781 
  1782 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1783 by arith
  1784 
  1785 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1786 by simp
  1787 
  1788 (*The others are
  1789       i - j - k = i - (j + k),
  1790       k \<le> j ==> j - k + i = j + i - k,
  1791       k \<le> j ==> i + (j - k) = i + j - k *)
  1792 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1793 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1794 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1795 
  1796 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1797 Least_Suc}, since there appears to be no need.*}
  1798 
  1799 text{*Lemmas for ex/Factorization*}
  1800 
  1801 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1802 by (cases m) auto
  1803 
  1804 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1805 by (cases m) auto
  1806 
  1807 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1808 by (cases m) auto
  1809 
  1810 text {* Specialized induction principles that work "backwards": *}
  1811 
  1812 lemma inc_induct[consumes 1, case_names base step]:
  1813   assumes less: "i \<le> j"
  1814   assumes base: "P j"
  1815   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1816   shows "P i"
  1817   using less step
  1818 proof (induct d\<equiv>"j - i" arbitrary: i)
  1819   case (0 i)
  1820   hence "i = j" by simp
  1821   with base show ?case by simp
  1822 next
  1823   case (Suc d n)
  1824   hence "n \<le> n" "n < j" "P (Suc n)"
  1825     by simp_all
  1826   then show "P n" by fact
  1827 qed
  1828 
  1829 lemma strict_inc_induct[consumes 1, case_names base step]:
  1830   assumes less: "i < j"
  1831   assumes base: "!!i. j = Suc i ==> P i"
  1832   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1833   shows "P i"
  1834   using less
  1835 proof (induct d=="j - i - 1" arbitrary: i)
  1836   case (0 i)
  1837   with `i < j` have "j = Suc i" by simp
  1838   with base show ?case by simp
  1839 next
  1840   case (Suc d i)
  1841   hence "i < j" "P (Suc i)"
  1842     by simp_all
  1843   thus "P i" by (rule step)
  1844 qed
  1845 
  1846 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1847   using inc_induct[of "k - i" k P, simplified] by blast
  1848 
  1849 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1850   using inc_induct[of 0 k P] by blast
  1851 
  1852 text {* Further induction rule similar to @{thm inc_induct} *}
  1853 
  1854 lemma dec_induct[consumes 1, case_names base step]:
  1855   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1856   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1857 
  1858 subsection \<open> Monotonicity of funpow \<close>
  1859 
  1860 lemma funpow_increasing:
  1861   fixes f :: "'a \<Rightarrow> ('a::{lattice, order_top})"
  1862   shows "m \<le> n \<Longrightarrow> mono f \<Longrightarrow> (f ^^ n) \<top> \<le> (f ^^ m) \<top>"
  1863   by (induct rule: inc_induct)
  1864      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right
  1865            intro: order_trans[OF _ funpow_mono])
  1866 
  1867 lemma funpow_decreasing:
  1868   fixes f :: "'a \<Rightarrow> ('a::{lattice, order_bot})"
  1869   shows "m \<le> n \<Longrightarrow> mono f \<Longrightarrow> (f ^^ m) \<bottom> \<le> (f ^^ n) \<bottom>"
  1870   by (induct rule: dec_induct)
  1871      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right
  1872            intro: order_trans[OF _ funpow_mono])
  1873 
  1874 lemma mono_funpow:
  1875   fixes Q :: "('i \<Rightarrow> 'a::{lattice, order_bot}) \<Rightarrow> ('i \<Rightarrow> 'a)"
  1876   shows "mono Q \<Longrightarrow> mono (\<lambda>i. (Q ^^ i) \<bottom>)"
  1877   by (auto intro!: funpow_decreasing simp: mono_def)
  1878 
  1879 subsection {* The divides relation on @{typ nat} *}
  1880 
  1881 instance nat :: semiring_dvd
  1882 proof
  1883   fix m n q :: nat
  1884   show "m dvd q * m + n \<longleftrightarrow> m dvd n" (is "?P \<longleftrightarrow> ?Q")
  1885   proof
  1886     assume ?Q then show ?P by simp
  1887   next
  1888     assume ?P then obtain d where *: "q * m + n = m * d" ..
  1889     show ?Q
  1890     proof (cases "n = 0")
  1891       case True then show ?Q by simp
  1892     next
  1893       case False
  1894       with * have "q * m < m * d"
  1895         using less_add_eq_less [of 0 n "q * m" "m * d"] by simp
  1896       then have "q \<le> d" by (auto intro: ccontr simp add: mult.commute [of m])
  1897       with * [symmetric] have "n = m * (d - q)"
  1898         by (simp add: diff_mult_distrib2 mult.commute [of m])
  1899       then show ?Q ..
  1900     qed
  1901   qed
  1902   assume "m dvd n + q" and "m dvd n"
  1903   show "m dvd q"
  1904   proof -
  1905     from `m dvd n` obtain d where "n = m * d" ..
  1906     moreover from `m dvd n + q` obtain e where "n + q = m * e" ..
  1907     ultimately have *: "m * d + q = m * e" by simp
  1908     show "m dvd q"
  1909     proof (cases "q = 0")
  1910       case True then show ?thesis by simp
  1911     next
  1912       case False
  1913       with * have "m * d < m * e"
  1914         using less_add_eq_less [of 0 q "m * d" "m * e"] by simp
  1915       then have "d \<le> e" by (auto intro: ccontr)
  1916       with * have "q = m * (e - d)"
  1917         by (simp add: diff_mult_distrib2)
  1918       then show ?thesis ..
  1919     qed
  1920   qed
  1921 qed
  1922 
  1923 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1924 unfolding dvd_def by simp
  1925 
  1926 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1927 by (simp add: dvd_def)
  1928 
  1929 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1930 by (simp add: dvd_def)
  1931 
  1932 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1933   unfolding dvd_def
  1934   by (force dest: mult_eq_self_implies_10 simp add: mult.assoc)
  1935 
  1936 text {* @{term "op dvd"} is a partial order *}
  1937 
  1938 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1939   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1940 
  1941 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1942 unfolding dvd_def
  1943 by (blast intro: diff_mult_distrib2 [symmetric])
  1944 
  1945 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1946   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1947   apply (blast intro: dvd_add)
  1948   done
  1949 
  1950 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1951 by (drule_tac m = m in dvd_diff_nat, auto)
  1952 
  1953 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1954   unfolding dvd_def
  1955   apply (erule exE)
  1956   apply (simp add: ac_simps)
  1957   done
  1958 
  1959 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1960   apply auto
  1961    apply (subgoal_tac "m*n dvd m*1")
  1962    apply (drule dvd_mult_cancel, auto)
  1963   done
  1964 
  1965 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1966   apply (subst mult.commute)
  1967   apply (erule dvd_mult_cancel1)
  1968   done
  1969 
  1970 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1971 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1972 
  1973 lemma nat_dvd_not_less:
  1974   fixes m n :: nat
  1975   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1976 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1977 
  1978 lemma less_eq_dvd_minus:
  1979   fixes m n :: nat
  1980   assumes "m \<le> n"
  1981   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1982 proof -
  1983   from assms have "n = m + (n - m)" by simp
  1984   then obtain q where "n = m + q" ..
  1985   then show ?thesis by (simp add: add.commute [of m])
  1986 qed
  1987 
  1988 lemma dvd_minus_self:
  1989   fixes m n :: nat
  1990   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1991   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1992 
  1993 lemma dvd_minus_add:
  1994   fixes m n q r :: nat
  1995   assumes "q \<le> n" "q \<le> r * m"
  1996   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1997 proof -
  1998   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1999     using dvd_add_times_triv_left_iff [of m r] by simp
  2000   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  2001   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  2002   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add.commute)
  2003   finally show ?thesis .
  2004 qed
  2005 
  2006 
  2007 subsection {* Aliases *}
  2008 
  2009 lemma nat_mult_1: "(1::nat) * n = n"
  2010   by (fact mult_1_left)
  2011  
  2012 lemma nat_mult_1_right: "n * (1::nat) = n"
  2013   by (fact mult_1_right)
  2014 
  2015 
  2016 subsection {* Size of a datatype value *}
  2017 
  2018 class size =
  2019   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  2020 
  2021 instantiation nat :: size
  2022 begin
  2023 
  2024 definition size_nat where
  2025   [simp, code]: "size (n \<Colon> nat) = n"
  2026 
  2027 instance ..
  2028 
  2029 end
  2030 
  2031 
  2032 subsection {* Code module namespace *}
  2033 
  2034 code_identifier
  2035   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  2036 
  2037 hide_const (open) of_nat_aux
  2038 
  2039 end