src/HOL/Map.thy
author nipkow
Fri Jul 25 17:21:22 2003 +0200 (2003-07-25)
changeset 14134 0fdf5708c7a8
parent 14100 804be4c4b642
child 14180 d2e550609c40
permissions -rw-r--r--
Replaced \<leadsto> by \<rightharpoonup>
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map = List:
    12 
    13 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    14 translations (type) "a ~=> b " <= (type) "a => b option"
    15 
    16 consts
    17 chg_map	:: "('b => 'b) => 'a => ('a ~=> 'b) => ('a ~=> 'b)"
    18 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    19 map_image::"('b => 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixr "`>" 90)
    20 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_|'__" [90, 91] 90)
    21 dom	:: "('a ~=> 'b) => 'a set"
    22 ran	:: "('a ~=> 'b) => 'b set"
    23 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    24 map_upds:: "('a ~=> 'b) => 'a list => 'b list => 
    25 	    ('a ~=> 'b)"		 ("_/'(_[|->]_/')" [900,0,0]900)
    26 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    27 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    28 map_subst::"('a ~=> 'b) => 'b => 'b => 
    29 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    30 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    31 
    32 syntax
    33 empty	::  "'a ~=> 'b"
    34 map_upd	:: "('a ~=> 'b) => 'a => 'b => ('a ~=> 'b)"
    35 					 ("_/'(_/|->_')"   [900,0,0]900)
    36 
    37 syntax (xsymbols)
    38   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    39   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_\<lfloor>_" [90, 91] 90)
    40   map_upd   :: "('a ~=> 'b) => 'a      => 'b      => ('a ~=> 'b)"
    41 					  ("_/'(_/\<mapsto>/_')"  [900,0,0]900)
    42   map_upds  :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    43 				         ("_/'(_/[\<mapsto>]/_')" [900,0,0]900)
    44   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    45 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
    46   map_subst :: "('a ~=> 'b) => 'b => 'b => 
    47 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
    48  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    49 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    50 
    51 translations
    52   "empty"    => "_K None"
    53   "empty"    <= "%x. None"
    54 
    55   "m(a|->b)" == "m(a:=Some b)"
    56   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    57 
    58 defs
    59 chg_map_def:  "chg_map f a m == case m a of None => m | Some b => m(a|->f b)"
    60 
    61 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    62 map_image_def: "f`>m == option_map f o m"
    63 restrict_map_def: "m|_A == %x. if x : A then m x else None"
    64 
    65 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    66 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    67 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    68 
    69 dom_def: "dom(m) == {a. m a ~= None}"
    70 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    71 
    72 map_le_def: "m1 \<subseteq>\<^sub>m m2  ==  ALL a : dom m1. m1 a = m2 a"
    73 
    74 primrec
    75   "map_of [] = empty"
    76   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    77 
    78 
    79 subsection {* @{term empty} *}
    80 
    81 lemma empty_upd_none[simp]: "empty(x := None) = empty"
    82 apply (rule ext)
    83 apply (simp (no_asm))
    84 done
    85 
    86 
    87 (* FIXME: what is this sum_case nonsense?? *)
    88 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
    89 apply (rule ext)
    90 apply (simp (no_asm) split add: sum.split)
    91 done
    92 
    93 subsection {* @{term map_upd} *}
    94 
    95 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
    96 apply (rule ext)
    97 apply (simp (no_asm_simp))
    98 done
    99 
   100 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   101 apply safe
   102 apply (drule_tac x = "k" in fun_cong)
   103 apply (simp (no_asm_use))
   104 done
   105 
   106 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   107 by (drule fun_cong [of _ _ a], auto)
   108 
   109 lemma map_upd_Some_unfold: 
   110   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   111 by auto
   112 
   113 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   114 apply (unfold image_def)
   115 apply (simp (no_asm_use) add: full_SetCompr_eq)
   116 apply (rule finite_subset)
   117 prefer 2 apply (assumption)
   118 apply auto
   119 done
   120 
   121 
   122 (* FIXME: what is this sum_case nonsense?? *)
   123 subsection {* @{term sum_case} and @{term empty}/@{term map_upd} *}
   124 
   125 lemma sum_case_map_upd_empty[simp]:
   126  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   127 apply (rule ext)
   128 apply (simp (no_asm) split add: sum.split)
   129 done
   130 
   131 lemma sum_case_empty_map_upd[simp]:
   132  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   133 apply (rule ext)
   134 apply (simp (no_asm) split add: sum.split)
   135 done
   136 
   137 lemma sum_case_map_upd_map_upd[simp]:
   138  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   139 apply (rule ext)
   140 apply (simp (no_asm) split add: sum.split)
   141 done
   142 
   143 
   144 subsection {* @{term chg_map} *}
   145 
   146 lemma chg_map_new[simp]: "m a = None   ==> chg_map f a m = m"
   147 apply (unfold chg_map_def)
   148 apply auto
   149 done
   150 
   151 lemma chg_map_upd[simp]: "m a = Some b ==> chg_map f a m = m(a|->f b)"
   152 apply (unfold chg_map_def)
   153 apply auto
   154 done
   155 
   156 
   157 subsection {* @{term map_of} *}
   158 
   159 lemma map_of_SomeD [rule_format (no_asm)]: "map_of xs k = Some y --> (k,y):set xs"
   160 apply (induct_tac "xs")
   161 apply  auto
   162 done
   163 
   164 lemma map_of_mapk_SomeI [rule_format (no_asm)]: "inj f ==> map_of t k = Some x -->  
   165    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   166 apply (induct_tac "t")
   167 apply  (auto simp add: inj_eq)
   168 done
   169 
   170 lemma weak_map_of_SomeI [rule_format (no_asm)]: "(k, x) : set l --> (? x. map_of l k = Some x)"
   171 apply (induct_tac "l")
   172 apply  auto
   173 done
   174 
   175 lemma map_of_filter_in: 
   176 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   177 apply (rule mp)
   178 prefer 2 apply (assumption)
   179 apply (erule thin_rl)
   180 apply (induct_tac "xs")
   181 apply  auto
   182 done
   183 
   184 lemma finite_range_map_of: "finite (range (map_of l))"
   185 apply (induct_tac "l")
   186 apply  (simp_all (no_asm) add: image_constant)
   187 apply (rule finite_subset)
   188 prefer 2 apply (assumption)
   189 apply auto
   190 done
   191 
   192 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   193 apply (induct_tac "xs")
   194 apply auto
   195 done
   196 
   197 
   198 subsection {* @{term option_map} related *}
   199 
   200 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   201 apply (rule ext)
   202 apply (simp (no_asm))
   203 done
   204 
   205 lemma option_map_o_map_upd[simp]:
   206  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   207 apply (rule ext)
   208 apply (simp (no_asm))
   209 done
   210 
   211 
   212 subsection {* @{text "++"} *}
   213 
   214 lemma map_add_empty[simp]: "m ++ empty = m"
   215 apply (unfold map_add_def)
   216 apply (simp (no_asm))
   217 done
   218 
   219 lemma empty_map_add[simp]: "empty ++ m = m"
   220 apply (unfold map_add_def)
   221 apply (rule ext)
   222 apply (simp split add: option.split)
   223 done
   224 
   225 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   226 apply(rule ext)
   227 apply(simp add: map_add_def split:option.split)
   228 done
   229 
   230 lemma map_add_Some_iff: 
   231  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   232 apply (unfold map_add_def)
   233 apply (simp (no_asm) split add: option.split)
   234 done
   235 
   236 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   237 declare map_add_SomeD [dest!]
   238 
   239 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   240 apply (subst map_add_Some_iff)
   241 apply fast
   242 done
   243 
   244 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   245 apply (unfold map_add_def)
   246 apply (simp (no_asm) split add: option.split)
   247 done
   248 
   249 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   250 apply (unfold map_add_def)
   251 apply (rule ext)
   252 apply auto
   253 done
   254 
   255 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   256 apply (unfold map_add_def)
   257 apply (induct_tac "xs")
   258 apply (simp (no_asm))
   259 apply (rule ext)
   260 apply (simp (no_asm_simp) split add: option.split)
   261 done
   262 
   263 declare fun_upd_apply [simp del]
   264 lemma finite_range_map_of_map_add:
   265  "finite (range f) ==> finite (range (f ++ map_of l))"
   266 apply (induct_tac "l")
   267 apply  auto
   268 apply (erule finite_range_updI)
   269 done
   270 declare fun_upd_apply [simp]
   271 
   272 subsection {* @{term map_image} *}
   273 
   274 lemma map_image_empty [simp]: "f`>empty = empty" 
   275 by (auto simp: map_image_def empty_def)
   276 
   277 lemma map_image_upd [simp]: "f`>m(a|->b) = (f`>m)(a|->f b)" 
   278 apply (auto simp: map_image_def fun_upd_def)
   279 by (rule ext, auto)
   280 
   281 subsection {* @{term restrict_map} *}
   282 
   283 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m\<lfloor>A) x = m x"
   284 by (auto simp: restrict_map_def)
   285 
   286 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m\<lfloor>A) x = None"
   287 by (auto simp: restrict_map_def)
   288 
   289 lemma ran_restrictD: "y \<in> ran (m\<lfloor>A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   290 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   291 
   292 lemma dom_valF_restrict [simp]: "dom (m\<lfloor>A) = dom m \<inter> A"
   293 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   294 
   295 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)\<lfloor>(-{x}) = m\<lfloor>(-{x})"
   296 by (rule ext, auto simp: restrict_map_def)
   297 
   298 lemma restrict_restrict [simp]: "m\<lfloor>A\<lfloor>B = m\<lfloor>(A\<inter>B)"
   299 by (rule ext, auto simp: restrict_map_def)
   300 
   301 
   302 subsection {* @{term map_upds} *}
   303 
   304 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   305 by(simp add:map_upds_def)
   306 
   307 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   308 by(simp add:map_upds_def)
   309 
   310 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   311 by(simp add:map_upds_def)
   312 
   313 
   314 lemma map_upd_upds_conv_if: "!!x y ys f.
   315  (f(x|->y))(xs [|->] ys) =
   316  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   317                                   else (f(xs [|->] ys))(x|->y))"
   318 apply(induct xs)
   319  apply simp
   320 apply(case_tac ys)
   321  apply(auto split:split_if simp:fun_upd_twist)
   322 done
   323 
   324 lemma map_upds_twist [simp]:
   325  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   326 apply(insert set_take_subset)
   327 apply (fastsimp simp add: map_upd_upds_conv_if)
   328 done
   329 
   330 lemma map_upds_apply_nontin[simp]:
   331  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   332 apply(induct xs)
   333  apply simp
   334 apply(case_tac ys)
   335  apply(auto simp: map_upd_upds_conv_if)
   336 done
   337 
   338 subsection {* @{term map_upd_s} *}
   339 
   340 lemma map_upd_s_apply [simp]: 
   341   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   342 by (simp add: map_upd_s_def)
   343 
   344 lemma map_subst_apply [simp]: 
   345   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   346 by (simp add: map_subst_def)
   347 
   348 subsection {* @{term dom} *}
   349 
   350 lemma domI: "m a = Some b ==> a : dom m"
   351 apply (unfold dom_def)
   352 apply auto
   353 done
   354 (* declare domI [intro]? *)
   355 
   356 lemma domD: "a : dom m ==> ? b. m a = Some b"
   357 apply (unfold dom_def)
   358 apply auto
   359 done
   360 
   361 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   362 apply (unfold dom_def)
   363 apply auto
   364 done
   365 declare domIff [simp del]
   366 
   367 lemma dom_empty[simp]: "dom empty = {}"
   368 apply (unfold dom_def)
   369 apply (simp (no_asm))
   370 done
   371 
   372 lemma dom_fun_upd[simp]:
   373  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   374 by (simp add:dom_def) blast
   375 
   376 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   377 apply(induct xys)
   378 apply(auto simp del:fun_upd_apply)
   379 done
   380 
   381 lemma finite_dom_map_of: "finite (dom (map_of l))"
   382 apply (unfold dom_def)
   383 apply (induct_tac "l")
   384 apply (auto simp add: insert_Collect [symmetric])
   385 done
   386 
   387 lemma dom_map_upds[simp]:
   388  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   389 apply(induct xs)
   390  apply simp
   391 apply(case_tac ys)
   392  apply auto
   393 done
   394 
   395 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   396 apply (unfold dom_def)
   397 apply auto
   398 done
   399 
   400 lemma dom_overwrite[simp]:
   401  "dom(f(g|A)) = (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   402 by(auto simp add: dom_def overwrite_def)
   403 
   404 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   405 apply(rule ext)
   406 apply(fastsimp simp:map_add_def split:option.split)
   407 done
   408 
   409 subsection {* @{term ran} *}
   410 
   411 lemma ranI: "m a = Some b ==> b : ran m" 
   412 by (auto simp add: ran_def)
   413 (* declare ranI [intro]? *)
   414 
   415 lemma ran_empty[simp]: "ran empty = {}"
   416 apply (unfold ran_def)
   417 apply (simp (no_asm))
   418 done
   419 
   420 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   421 apply (unfold ran_def)
   422 apply auto
   423 apply (subgoal_tac "~ (aa = a) ")
   424 apply auto
   425 done
   426 
   427 subsection {* @{text "map_le"} *}
   428 
   429 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   430 by(simp add:map_le_def)
   431 
   432 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   433 by(fastsimp simp add:map_le_def)
   434 
   435 lemma map_le_upds[simp]:
   436  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   437 apply(induct as)
   438  apply simp
   439 apply(case_tac bs)
   440  apply auto
   441 done
   442 
   443 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   444   by (fastsimp simp add: map_le_def dom_def)
   445 
   446 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   447   by (simp add: map_le_def)
   448 
   449 lemma map_le_trans: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m h \<rbrakk> \<Longrightarrow> f \<subseteq>\<^sub>m h"
   450   apply (clarsimp simp add: map_le_def)
   451   apply (drule_tac x="a" in bspec, fastsimp)+
   452   apply assumption
   453 done
   454 
   455 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   456   apply (unfold map_le_def)
   457   apply (rule ext)
   458   apply (case_tac "x \<in> dom f")
   459     apply simp
   460   apply (case_tac "x \<in> dom g")
   461     apply simp
   462   apply fastsimp
   463 done
   464 
   465 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   466   by (fastsimp simp add: map_le_def)
   467 
   468 end