src/HOL/Finite_Set.thy
author hoelzl
Thu Sep 02 10:14:32 2010 +0200 (2010-09-02)
changeset 39072 1030b1a166ef
parent 38400 9bfcb1507c6b
child 39198 f967a16dfcdd
permissions -rw-r--r--
Add lessThan_Suc_eq_insert_0
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set => bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A ==> finite (insert a A)"
    18 
    19 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    20   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    21   shows "\<exists>a::'a. a \<notin> A"
    22 proof -
    23   from assms have "A \<noteq> UNIV" by blast
    24   thus ?thesis by blast
    25 qed
    26 
    27 lemma finite_induct [case_names empty insert, induct set: finite]:
    28   "finite F ==>
    29     P {} ==> (!!x F. finite F ==> x \<notin> F ==> P F ==> P (insert x F)) ==> P F"
    30   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    31 proof -
    32   assume "P {}" and
    33     insert: "!!x F. finite F ==> x \<notin> F ==> P F ==> P (insert x F)"
    34   assume "finite F"
    35   thus "P F"
    36   proof induct
    37     show "P {}" by fact
    38     fix x F assume F: "finite F" and P: "P F"
    39     show "P (insert x F)"
    40     proof cases
    41       assume "x \<in> F"
    42       hence "insert x F = F" by (rule insert_absorb)
    43       with P show ?thesis by (simp only:)
    44     next
    45       assume "x \<notin> F"
    46       from F this P show ?thesis by (rule insert)
    47     qed
    48   qed
    49 qed
    50 
    51 lemma finite_ne_induct[case_names singleton insert, consumes 2]:
    52 assumes fin: "finite F" shows "F \<noteq> {} \<Longrightarrow>
    53  \<lbrakk> \<And>x. P{x};
    54    \<And>x F. \<lbrakk> finite F; F \<noteq> {}; x \<notin> F; P F \<rbrakk> \<Longrightarrow> P (insert x F) \<rbrakk>
    55  \<Longrightarrow> P F"
    56 using fin
    57 proof induct
    58   case empty thus ?case by simp
    59 next
    60   case (insert x F)
    61   show ?case
    62   proof cases
    63     assume "F = {}"
    64     thus ?thesis using `P {x}` by simp
    65   next
    66     assume "F \<noteq> {}"
    67     thus ?thesis using insert by blast
    68   qed
    69 qed
    70 
    71 lemma finite_subset_induct [consumes 2, case_names empty insert]:
    72   assumes "finite F" and "F \<subseteq> A"
    73     and empty: "P {}"
    74     and insert: "!!a F. finite F ==> a \<in> A ==> a \<notin> F ==> P F ==> P (insert a F)"
    75   shows "P F"
    76 proof -
    77   from `finite F` and `F \<subseteq> A`
    78   show ?thesis
    79   proof induct
    80     show "P {}" by fact
    81   next
    82     fix x F
    83     assume "finite F" and "x \<notin> F" and
    84       P: "F \<subseteq> A ==> P F" and i: "insert x F \<subseteq> A"
    85     show "P (insert x F)"
    86     proof (rule insert)
    87       from i show "x \<in> A" by blast
    88       from i have "F \<subseteq> A" by blast
    89       with P show "P F" .
    90       show "finite F" by fact
    91       show "x \<notin> F" by fact
    92     qed
    93   qed
    94 qed
    95 
    96 
    97 text{* A finite choice principle. Does not need the SOME choice operator. *}
    98 lemma finite_set_choice:
    99   "finite A \<Longrightarrow> ALL x:A. (EX y. P x y) \<Longrightarrow> EX f. ALL x:A. P x (f x)"
   100 proof (induct set: finite)
   101   case empty thus ?case by simp
   102 next
   103   case (insert a A)
   104   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
   105   show ?case (is "EX f. ?P f")
   106   proof
   107     show "?P(%x. if x = a then b else f x)" using f ab by auto
   108   qed
   109 qed
   110 
   111 
   112 text{* Finite sets are the images of initial segments of natural numbers: *}
   113 
   114 lemma finite_imp_nat_seg_image_inj_on:
   115   assumes fin: "finite A" 
   116   shows "\<exists> (n::nat) f. A = f ` {i. i<n} & inj_on f {i. i<n}"
   117 using fin
   118 proof induct
   119   case empty
   120   show ?case  
   121   proof show "\<exists>f. {} = f ` {i::nat. i < 0} & inj_on f {i. i<0}" by simp 
   122   qed
   123 next
   124   case (insert a A)
   125   have notinA: "a \<notin> A" by fact
   126   from insert.hyps obtain n f
   127     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
   128   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
   129         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
   130     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
   131   thus ?case by blast
   132 qed
   133 
   134 lemma nat_seg_image_imp_finite:
   135   "!!f A. A = f ` {i::nat. i<n} \<Longrightarrow> finite A"
   136 proof (induct n)
   137   case 0 thus ?case by simp
   138 next
   139   case (Suc n)
   140   let ?B = "f ` {i. i < n}"
   141   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
   142   show ?case
   143   proof cases
   144     assume "\<exists>k<n. f n = f k"
   145     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   146     thus ?thesis using finB by simp
   147   next
   148     assume "\<not>(\<exists> k<n. f n = f k)"
   149     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   150     thus ?thesis using finB by simp
   151   qed
   152 qed
   153 
   154 lemma finite_conv_nat_seg_image:
   155   "finite A = (\<exists> (n::nat) f. A = f ` {i::nat. i<n})"
   156 by(blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   157 
   158 lemma finite_imp_inj_to_nat_seg:
   159 assumes "finite A"
   160 shows "EX f n::nat. f`A = {i. i<n} & inj_on f A"
   161 proof -
   162   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   163   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   164     by (auto simp:bij_betw_def)
   165   let ?f = "the_inv_into {i. i<n} f"
   166   have "inj_on ?f A & ?f ` A = {i. i<n}"
   167     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   168   thus ?thesis by blast
   169 qed
   170 
   171 lemma finite_Collect_less_nat[iff]: "finite{n::nat. n<k}"
   172 by(fastsimp simp: finite_conv_nat_seg_image)
   173 
   174 text {* Finiteness and set theoretic constructions *}
   175 
   176 lemma finite_UnI: "finite F ==> finite G ==> finite (F Un G)"
   177 by (induct set: finite) simp_all
   178 
   179 lemma finite_subset: "A \<subseteq> B ==> finite B ==> finite A"
   180   -- {* Every subset of a finite set is finite. *}
   181 proof -
   182   assume "finite B"
   183   thus "!!A. A \<subseteq> B ==> finite A"
   184   proof induct
   185     case empty
   186     thus ?case by simp
   187   next
   188     case (insert x F A)
   189     have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F ==> finite (A - {x})" by fact+
   190     show "finite A"
   191     proof cases
   192       assume x: "x \<in> A"
   193       with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   194       with r have "finite (A - {x})" .
   195       hence "finite (insert x (A - {x}))" ..
   196       also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   197       finally show ?thesis .
   198     next
   199       show "A \<subseteq> F ==> ?thesis" by fact
   200       assume "x \<notin> A"
   201       with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   202     qed
   203   qed
   204 qed
   205 
   206 lemma rev_finite_subset: "finite B ==> A \<subseteq> B ==> finite A"
   207 by (rule finite_subset)
   208 
   209 lemma finite_Un [iff]: "finite (F Un G) = (finite F & finite G)"
   210 by (blast intro: finite_subset [of _ "X Un Y", standard] finite_UnI)
   211 
   212 lemma finite_Collect_disjI[simp]:
   213   "finite{x. P x | Q x} = (finite{x. P x} & finite{x. Q x})"
   214 by(simp add:Collect_disj_eq)
   215 
   216 lemma finite_Int [simp, intro]: "finite F | finite G ==> finite (F Int G)"
   217   -- {* The converse obviously fails. *}
   218 by (blast intro: finite_subset)
   219 
   220 lemma finite_Collect_conjI [simp, intro]:
   221   "finite{x. P x} | finite{x. Q x} ==> finite{x. P x & Q x}"
   222   -- {* The converse obviously fails. *}
   223 by(simp add:Collect_conj_eq)
   224 
   225 lemma finite_Collect_le_nat[iff]: "finite{n::nat. n<=k}"
   226 by(simp add: le_eq_less_or_eq)
   227 
   228 lemma finite_insert [simp]: "finite (insert a A) = finite A"
   229   apply (subst insert_is_Un)
   230   apply (simp only: finite_Un, blast)
   231   done
   232 
   233 lemma finite_Union[simp, intro]:
   234  "\<lbrakk> finite A; !!M. M \<in> A \<Longrightarrow> finite M \<rbrakk> \<Longrightarrow> finite(\<Union>A)"
   235 by (induct rule:finite_induct) simp_all
   236 
   237 lemma finite_Inter[intro]: "EX A:M. finite(A) \<Longrightarrow> finite(Inter M)"
   238 by (blast intro: Inter_lower finite_subset)
   239 
   240 lemma finite_INT[intro]: "EX x:I. finite(A x) \<Longrightarrow> finite(INT x:I. A x)"
   241 by (blast intro: INT_lower finite_subset)
   242 
   243 lemma finite_empty_induct:
   244   assumes "finite A"
   245     and "P A"
   246     and "!!a A. finite A ==> a:A ==> P A ==> P (A - {a})"
   247   shows "P {}"
   248 proof -
   249   have "P (A - A)"
   250   proof -
   251     {
   252       fix c b :: "'a set"
   253       assume c: "finite c" and b: "finite b"
   254         and P1: "P b" and P2: "!!x y. finite y ==> x \<in> y ==> P y ==> P (y - {x})"
   255       have "c \<subseteq> b ==> P (b - c)"
   256         using c
   257       proof induct
   258         case empty
   259         from P1 show ?case by simp
   260       next
   261         case (insert x F)
   262         have "P (b - F - {x})"
   263         proof (rule P2)
   264           from _ b show "finite (b - F)" by (rule finite_subset) blast
   265           from insert show "x \<in> b - F" by simp
   266           from insert show "P (b - F)" by simp
   267         qed
   268         also have "b - F - {x} = b - insert x F" by (rule Diff_insert [symmetric])
   269         finally show ?case .
   270       qed
   271     }
   272     then show ?thesis by this (simp_all add: assms)
   273   qed
   274   then show ?thesis by simp
   275 qed
   276 
   277 lemma finite_Diff [simp]: "finite A ==> finite (A - B)"
   278 by (rule Diff_subset [THEN finite_subset])
   279 
   280 lemma finite_Diff2 [simp]:
   281   assumes "finite B" shows "finite (A - B) = finite A"
   282 proof -
   283   have "finite A \<longleftrightarrow> finite((A-B) Un (A Int B))" by(simp add: Un_Diff_Int)
   284   also have "\<dots> \<longleftrightarrow> finite(A-B)" using `finite B` by(simp)
   285   finally show ?thesis ..
   286 qed
   287 
   288 lemma finite_compl[simp]:
   289   "finite(A::'a set) \<Longrightarrow> finite(-A) = finite(UNIV::'a set)"
   290 by(simp add:Compl_eq_Diff_UNIV)
   291 
   292 lemma finite_Collect_not[simp]:
   293   "finite{x::'a. P x} \<Longrightarrow> finite{x. ~P x} = finite(UNIV::'a set)"
   294 by(simp add:Collect_neg_eq)
   295 
   296 lemma finite_Diff_insert [iff]: "finite (A - insert a B) = finite (A - B)"
   297   apply (subst Diff_insert)
   298   apply (case_tac "a : A - B")
   299    apply (rule finite_insert [symmetric, THEN trans])
   300    apply (subst insert_Diff, simp_all)
   301   done
   302 
   303 
   304 text {* Image and Inverse Image over Finite Sets *}
   305 
   306 lemma finite_imageI[simp]: "finite F ==> finite (h ` F)"
   307   -- {* The image of a finite set is finite. *}
   308   by (induct set: finite) simp_all
   309 
   310 lemma finite_image_set [simp]:
   311   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   312   by (simp add: image_Collect [symmetric])
   313 
   314 lemma finite_surj: "finite A ==> B <= f ` A ==> finite B"
   315   apply (frule finite_imageI)
   316   apply (erule finite_subset, assumption)
   317   done
   318 
   319 lemma finite_range_imageI:
   320     "finite (range g) ==> finite (range (%x. f (g x)))"
   321   apply (drule finite_imageI, simp add: range_composition)
   322   done
   323 
   324 lemma finite_imageD: "finite (f`A) ==> inj_on f A ==> finite A"
   325 proof -
   326   have aux: "!!A. finite (A - {}) = finite A" by simp
   327   fix B :: "'a set"
   328   assume "finite B"
   329   thus "!!A. f`A = B ==> inj_on f A ==> finite A"
   330     apply induct
   331      apply simp
   332     apply (subgoal_tac "EX y:A. f y = x & F = f ` (A - {y})")
   333      apply clarify
   334      apply (simp (no_asm_use) add: inj_on_def)
   335      apply (blast dest!: aux [THEN iffD1], atomize)
   336     apply (erule_tac V = "ALL A. ?PP (A)" in thin_rl)
   337     apply (frule subsetD [OF equalityD2 insertI1], clarify)
   338     apply (rule_tac x = xa in bexI)
   339      apply (simp_all add: inj_on_image_set_diff)
   340     done
   341 qed (rule refl)
   342 
   343 
   344 lemma inj_vimage_singleton: "inj f ==> f-`{a} \<subseteq> {THE x. f x = a}"
   345   -- {* The inverse image of a singleton under an injective function
   346          is included in a singleton. *}
   347   apply (auto simp add: inj_on_def)
   348   apply (blast intro: the_equality [symmetric])
   349   done
   350 
   351 lemma finite_vimageI: "[|finite F; inj h|] ==> finite (h -` F)"
   352   -- {* The inverse image of a finite set under an injective function
   353          is finite. *}
   354   apply (induct set: finite)
   355    apply simp_all
   356   apply (subst vimage_insert)
   357   apply (simp add: finite_subset [OF inj_vimage_singleton])
   358   done
   359 
   360 lemma finite_vimageD:
   361   assumes fin: "finite (h -` F)" and surj: "surj h"
   362   shows "finite F"
   363 proof -
   364   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   365   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   366   finally show "finite F" .
   367 qed
   368 
   369 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   370   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   371 
   372 
   373 text {* The finite UNION of finite sets *}
   374 
   375 lemma finite_UN_I: "finite A ==> (!!a. a:A ==> finite (B a)) ==> finite (UN a:A. B a)"
   376   by (induct set: finite) simp_all
   377 
   378 text {*
   379   Strengthen RHS to
   380   @{prop "((ALL x:A. finite (B x)) & finite {x. x:A & B x \<noteq> {}})"}?
   381 
   382   We'd need to prove
   383   @{prop "finite C ==> ALL A B. (UNION A B) <= C --> finite {x. x:A & B x \<noteq> {}}"}
   384   by induction. *}
   385 
   386 lemma finite_UN [simp]:
   387   "finite A ==> finite (UNION A B) = (ALL x:A. finite (B x))"
   388 by (blast intro: finite_UN_I finite_subset)
   389 
   390 lemma finite_Collect_bex[simp]: "finite A \<Longrightarrow>
   391   finite{x. EX y:A. Q x y} = (ALL y:A. finite{x. Q x y})"
   392 apply(subgoal_tac "{x. EX y:A. Q x y} = UNION A (%y. {x. Q x y})")
   393  apply auto
   394 done
   395 
   396 lemma finite_Collect_bounded_ex[simp]: "finite{y. P y} \<Longrightarrow>
   397   finite{x. EX y. P y & Q x y} = (ALL y. P y \<longrightarrow> finite{x. Q x y})"
   398 apply(subgoal_tac "{x. EX y. P y & Q x y} = UNION {y. P y} (%y. {x. Q x y})")
   399  apply auto
   400 done
   401 
   402 
   403 lemma finite_Plus: "[| finite A; finite B |] ==> finite (A <+> B)"
   404 by (simp add: Plus_def)
   405 
   406 lemma finite_PlusD: 
   407   fixes A :: "'a set" and B :: "'b set"
   408   assumes fin: "finite (A <+> B)"
   409   shows "finite A" "finite B"
   410 proof -
   411   have "Inl ` A \<subseteq> A <+> B" by auto
   412   hence "finite (Inl ` A :: ('a + 'b) set)" using fin by(rule finite_subset)
   413   thus "finite A" by(rule finite_imageD)(auto intro: inj_onI)
   414 next
   415   have "Inr ` B \<subseteq> A <+> B" by auto
   416   hence "finite (Inr ` B :: ('a + 'b) set)" using fin by(rule finite_subset)
   417   thus "finite B" by(rule finite_imageD)(auto intro: inj_onI)
   418 qed
   419 
   420 lemma finite_Plus_iff[simp]: "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   421 by(auto intro: finite_PlusD finite_Plus)
   422 
   423 lemma finite_Plus_UNIV_iff[simp]:
   424   "finite (UNIV :: ('a + 'b) set) =
   425   (finite (UNIV :: 'a set) & finite (UNIV :: 'b set))"
   426 by(subst UNIV_Plus_UNIV[symmetric])(rule finite_Plus_iff)
   427 
   428 
   429 text {* Sigma of finite sets *}
   430 
   431 lemma finite_SigmaI [simp]:
   432     "finite A ==> (!!a. a:A ==> finite (B a)) ==> finite (SIGMA a:A. B a)"
   433   by (unfold Sigma_def) (blast intro!: finite_UN_I)
   434 
   435 lemma finite_cartesian_product: "[| finite A; finite B |] ==>
   436     finite (A <*> B)"
   437   by (rule finite_SigmaI)
   438 
   439 lemma finite_Prod_UNIV:
   440     "finite (UNIV::'a set) ==> finite (UNIV::'b set) ==> finite (UNIV::('a * 'b) set)"
   441   apply (subgoal_tac "(UNIV:: ('a * 'b) set) = Sigma UNIV (%x. UNIV)")
   442    apply (erule ssubst)
   443    apply (erule finite_SigmaI, auto)
   444   done
   445 
   446 lemma finite_cartesian_productD1:
   447      "[| finite (A <*> B); B \<noteq> {} |] ==> finite A"
   448 apply (auto simp add: finite_conv_nat_seg_image) 
   449 apply (drule_tac x=n in spec) 
   450 apply (drule_tac x="fst o f" in spec) 
   451 apply (auto simp add: o_def) 
   452  prefer 2 apply (force dest!: equalityD2) 
   453 apply (drule equalityD1) 
   454 apply (rename_tac y x)
   455 apply (subgoal_tac "\<exists>k. k<n & f k = (x,y)") 
   456  prefer 2 apply force
   457 apply clarify
   458 apply (rule_tac x=k in image_eqI, auto)
   459 done
   460 
   461 lemma finite_cartesian_productD2:
   462      "[| finite (A <*> B); A \<noteq> {} |] ==> finite B"
   463 apply (auto simp add: finite_conv_nat_seg_image) 
   464 apply (drule_tac x=n in spec) 
   465 apply (drule_tac x="snd o f" in spec) 
   466 apply (auto simp add: o_def) 
   467  prefer 2 apply (force dest!: equalityD2) 
   468 apply (drule equalityD1)
   469 apply (rename_tac x y)
   470 apply (subgoal_tac "\<exists>k. k<n & f k = (x,y)") 
   471  prefer 2 apply force
   472 apply clarify
   473 apply (rule_tac x=k in image_eqI, auto)
   474 done
   475 
   476 
   477 text {* The powerset of a finite set *}
   478 
   479 lemma finite_Pow_iff [iff]: "finite (Pow A) = finite A"
   480 proof
   481   assume "finite (Pow A)"
   482   with _ have "finite ((%x. {x}) ` A)" by (rule finite_subset) blast
   483   thus "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   484 next
   485   assume "finite A"
   486   thus "finite (Pow A)"
   487     by induct (simp_all add: Pow_insert)
   488 qed
   489 
   490 lemma finite_Collect_subsets[simp,intro]: "finite A \<Longrightarrow> finite{B. B \<subseteq> A}"
   491 by(simp add: Pow_def[symmetric])
   492 
   493 
   494 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   495 by(blast intro: finite_subset[OF subset_Pow_Union])
   496 
   497 
   498 lemma finite_subset_image:
   499   assumes "finite B"
   500   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   501 using assms proof(induct)
   502   case empty thus ?case by simp
   503 next
   504   case insert thus ?case
   505     by (clarsimp simp del: image_insert simp add: image_insert[symmetric])
   506        blast
   507 qed
   508 
   509 
   510 subsection {* Class @{text finite}  *}
   511 
   512 class finite =
   513   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   514 begin
   515 
   516 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   517   by (rule subset_UNIV finite_UNIV finite_subset)+
   518 
   519 end
   520 
   521 lemma UNIV_unit [no_atp]:
   522   "UNIV = {()}" by auto
   523 
   524 instance unit :: finite proof
   525 qed (simp add: UNIV_unit)
   526 
   527 lemma UNIV_bool [no_atp]:
   528   "UNIV = {False, True}" by auto
   529 
   530 instance bool :: finite proof
   531 qed (simp add: UNIV_bool)
   532 
   533 instance prod :: (finite, finite) finite proof
   534 qed (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   535 
   536 lemma finite_option_UNIV [simp]:
   537   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   538   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   539 
   540 instance option :: (finite) finite proof
   541 qed (simp add: UNIV_option_conv)
   542 
   543 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   544   by (rule inj_onI, auto simp add: expand_set_eq expand_fun_eq)
   545 
   546 instance "fun" :: (finite, finite) finite
   547 proof
   548   show "finite (UNIV :: ('a => 'b) set)"
   549   proof (rule finite_imageD)
   550     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   551     have "range ?graph \<subseteq> Pow UNIV" by simp
   552     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   553       by (simp only: finite_Pow_iff finite)
   554     ultimately show "finite (range ?graph)"
   555       by (rule finite_subset)
   556     show "inj ?graph" by (rule inj_graph)
   557   qed
   558 qed
   559 
   560 instance sum :: (finite, finite) finite proof
   561 qed (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   562 
   563 
   564 subsection {* A basic fold functional for finite sets *}
   565 
   566 text {* The intended behaviour is
   567 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   568 if @{text f} is ``left-commutative'':
   569 *}
   570 
   571 locale fun_left_comm =
   572   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   573   assumes fun_left_comm: "f x (f y z) = f y (f x z)"
   574 begin
   575 
   576 text{* On a functional level it looks much nicer: *}
   577 
   578 lemma fun_comp_comm:  "f x \<circ> f y = f y \<circ> f x"
   579 by (simp add: fun_left_comm expand_fun_eq)
   580 
   581 end
   582 
   583 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   584 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   585   emptyI [intro]: "fold_graph f z {} z" |
   586   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   587       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   588 
   589 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   590 
   591 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   592   "fold f z A = (THE y. fold_graph f z A y)"
   593 
   594 text{*A tempting alternative for the definiens is
   595 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   596 It allows the removal of finiteness assumptions from the theorems
   597 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   598 The proofs become ugly. It is not worth the effort. (???) *}
   599 
   600 
   601 lemma Diff1_fold_graph:
   602   "fold_graph f z (A - {x}) y \<Longrightarrow> x \<in> A \<Longrightarrow> fold_graph f z A (f x y)"
   603 by (erule insert_Diff [THEN subst], rule fold_graph.intros, auto)
   604 
   605 lemma fold_graph_imp_finite: "fold_graph f z A x \<Longrightarrow> finite A"
   606 by (induct set: fold_graph) auto
   607 
   608 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   609 by (induct set: finite) auto
   610 
   611 
   612 subsubsection{*From @{const fold_graph} to @{term fold}*}
   613 
   614 context fun_left_comm
   615 begin
   616 
   617 lemma fold_graph_insertE_aux:
   618   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   619 proof (induct set: fold_graph)
   620   case (insertI x A y) show ?case
   621   proof (cases "x = a")
   622     assume "x = a" with insertI show ?case by auto
   623   next
   624     assume "x \<noteq> a"
   625     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   626       using insertI by auto
   627     have 1: "f x y = f a (f x y')"
   628       unfolding y by (rule fun_left_comm)
   629     have 2: "fold_graph f z (insert x A - {a}) (f x y')"
   630       using y' and `x \<noteq> a` and `x \<notin> A`
   631       by (simp add: insert_Diff_if fold_graph.insertI)
   632     from 1 2 show ?case by fast
   633   qed
   634 qed simp
   635 
   636 lemma fold_graph_insertE:
   637   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   638   obtains y where "v = f x y" and "fold_graph f z A y"
   639 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   640 
   641 lemma fold_graph_determ:
   642   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   643 proof (induct arbitrary: y set: fold_graph)
   644   case (insertI x A y v)
   645   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   646   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   647     by (rule fold_graph_insertE)
   648   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   649   with `v = f x y'` show "v = f x y" by simp
   650 qed fast
   651 
   652 lemma fold_equality:
   653   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   654 by (unfold fold_def) (blast intro: fold_graph_determ)
   655 
   656 lemma fold_graph_fold: "finite A \<Longrightarrow> fold_graph f z A (fold f z A)"
   657 unfolding fold_def
   658 apply (rule theI')
   659 apply (rule ex_ex1I)
   660 apply (erule finite_imp_fold_graph)
   661 apply (erule (1) fold_graph_determ)
   662 done
   663 
   664 text{* The base case for @{text fold}: *}
   665 
   666 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   667 by (unfold fold_def) blast
   668 
   669 text{* The various recursion equations for @{const fold}: *}
   670 
   671 lemma fold_insert [simp]:
   672   "finite A ==> x \<notin> A ==> fold f z (insert x A) = f x (fold f z A)"
   673 apply (rule fold_equality)
   674 apply (erule fold_graph.insertI)
   675 apply (erule fold_graph_fold)
   676 done
   677 
   678 lemma fold_fun_comm:
   679   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   680 proof (induct rule: finite_induct)
   681   case empty then show ?case by simp
   682 next
   683   case (insert y A) then show ?case
   684     by (simp add: fun_left_comm[of x])
   685 qed
   686 
   687 lemma fold_insert2:
   688   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   689 by (simp add: fold_fun_comm)
   690 
   691 lemma fold_rec:
   692 assumes "finite A" and "x \<in> A"
   693 shows "fold f z A = f x (fold f z (A - {x}))"
   694 proof -
   695   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   696   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   697   also have "\<dots> = f x (fold f z (A - {x}))"
   698     by (rule fold_insert) (simp add: `finite A`)+
   699   finally show ?thesis .
   700 qed
   701 
   702 lemma fold_insert_remove:
   703   assumes "finite A"
   704   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   705 proof -
   706   from `finite A` have "finite (insert x A)" by auto
   707   moreover have "x \<in> insert x A" by auto
   708   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   709     by (rule fold_rec)
   710   then show ?thesis by simp
   711 qed
   712 
   713 end
   714 
   715 text{* A simplified version for idempotent functions: *}
   716 
   717 locale fun_left_comm_idem = fun_left_comm +
   718   assumes fun_left_idem: "f x (f x z) = f x z"
   719 begin
   720 
   721 text{* The nice version: *}
   722 lemma fun_comp_idem : "f x o f x = f x"
   723 by (simp add: fun_left_idem expand_fun_eq)
   724 
   725 lemma fold_insert_idem:
   726   assumes fin: "finite A"
   727   shows "fold f z (insert x A) = f x (fold f z A)"
   728 proof cases
   729   assume "x \<in> A"
   730   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   731   then show ?thesis using assms by (simp add:fun_left_idem)
   732 next
   733   assume "x \<notin> A" then show ?thesis using assms by simp
   734 qed
   735 
   736 declare fold_insert[simp del] fold_insert_idem[simp]
   737 
   738 lemma fold_insert_idem2:
   739   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   740 by(simp add:fold_fun_comm)
   741 
   742 end
   743 
   744 
   745 subsubsection {* Expressing set operations via @{const fold} *}
   746 
   747 lemma (in fun_left_comm) fun_left_comm_apply:
   748   "fun_left_comm (\<lambda>x. f (g x))"
   749 proof
   750 qed (simp_all add: fun_left_comm)
   751 
   752 lemma (in fun_left_comm_idem) fun_left_comm_idem_apply:
   753   "fun_left_comm_idem (\<lambda>x. f (g x))"
   754   by (rule fun_left_comm_idem.intro, rule fun_left_comm_apply, unfold_locales)
   755     (simp_all add: fun_left_idem)
   756 
   757 lemma fun_left_comm_idem_insert:
   758   "fun_left_comm_idem insert"
   759 proof
   760 qed auto
   761 
   762 lemma fun_left_comm_idem_remove:
   763   "fun_left_comm_idem (\<lambda>x A. A - {x})"
   764 proof
   765 qed auto
   766 
   767 lemma (in semilattice_inf) fun_left_comm_idem_inf:
   768   "fun_left_comm_idem inf"
   769 proof
   770 qed (auto simp add: inf_left_commute)
   771 
   772 lemma (in semilattice_sup) fun_left_comm_idem_sup:
   773   "fun_left_comm_idem sup"
   774 proof
   775 qed (auto simp add: sup_left_commute)
   776 
   777 lemma union_fold_insert:
   778   assumes "finite A"
   779   shows "A \<union> B = fold insert B A"
   780 proof -
   781   interpret fun_left_comm_idem insert by (fact fun_left_comm_idem_insert)
   782   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   783 qed
   784 
   785 lemma minus_fold_remove:
   786   assumes "finite A"
   787   shows "B - A = fold (\<lambda>x A. A - {x}) B A"
   788 proof -
   789   interpret fun_left_comm_idem "\<lambda>x A. A - {x}" by (fact fun_left_comm_idem_remove)
   790   from `finite A` show ?thesis by (induct A arbitrary: B) auto
   791 qed
   792 
   793 context complete_lattice
   794 begin
   795 
   796 lemma inf_Inf_fold_inf:
   797   assumes "finite A"
   798   shows "inf B (Inf A) = fold inf B A"
   799 proof -
   800   interpret fun_left_comm_idem inf by (fact fun_left_comm_idem_inf)
   801   from `finite A` show ?thesis by (induct A arbitrary: B)
   802     (simp_all add: Inf_empty Inf_insert inf_commute fold_fun_comm)
   803 qed
   804 
   805 lemma sup_Sup_fold_sup:
   806   assumes "finite A"
   807   shows "sup B (Sup A) = fold sup B A"
   808 proof -
   809   interpret fun_left_comm_idem sup by (fact fun_left_comm_idem_sup)
   810   from `finite A` show ?thesis by (induct A arbitrary: B)
   811     (simp_all add: Sup_empty Sup_insert sup_commute fold_fun_comm)
   812 qed
   813 
   814 lemma Inf_fold_inf:
   815   assumes "finite A"
   816   shows "Inf A = fold inf top A"
   817   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   818 
   819 lemma Sup_fold_sup:
   820   assumes "finite A"
   821   shows "Sup A = fold sup bot A"
   822   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   823 
   824 lemma inf_INFI_fold_inf:
   825   assumes "finite A"
   826   shows "inf B (INFI A f) = fold (\<lambda>A. inf (f A)) B A" (is "?inf = ?fold") 
   827 proof (rule sym)
   828   interpret fun_left_comm_idem inf by (fact fun_left_comm_idem_inf)
   829   interpret fun_left_comm_idem "\<lambda>A. inf (f A)" by (fact fun_left_comm_idem_apply)
   830   from `finite A` show "?fold = ?inf"
   831   by (induct A arbitrary: B)
   832     (simp_all add: INFI_def Inf_empty Inf_insert inf_left_commute)
   833 qed
   834 
   835 lemma sup_SUPR_fold_sup:
   836   assumes "finite A"
   837   shows "sup B (SUPR A f) = fold (\<lambda>A. sup (f A)) B A" (is "?sup = ?fold") 
   838 proof (rule sym)
   839   interpret fun_left_comm_idem sup by (fact fun_left_comm_idem_sup)
   840   interpret fun_left_comm_idem "\<lambda>A. sup (f A)" by (fact fun_left_comm_idem_apply)
   841   from `finite A` show "?fold = ?sup"
   842   by (induct A arbitrary: B)
   843     (simp_all add: SUPR_def Sup_empty Sup_insert sup_left_commute)
   844 qed
   845 
   846 lemma INFI_fold_inf:
   847   assumes "finite A"
   848   shows "INFI A f = fold (\<lambda>A. inf (f A)) top A"
   849   using assms inf_INFI_fold_inf [of A top] by simp
   850 
   851 lemma SUPR_fold_sup:
   852   assumes "finite A"
   853   shows "SUPR A f = fold (\<lambda>A. sup (f A)) bot A"
   854   using assms sup_SUPR_fold_sup [of A bot] by simp
   855 
   856 end
   857 
   858 
   859 subsection {* The derived combinator @{text fold_image} *}
   860 
   861 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   862 where "fold_image f g = fold (%x y. f (g x) y)"
   863 
   864 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   865 by(simp add:fold_image_def)
   866 
   867 context ab_semigroup_mult
   868 begin
   869 
   870 lemma fold_image_insert[simp]:
   871 assumes "finite A" and "a \<notin> A"
   872 shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   873 proof -
   874   interpret I: fun_left_comm "%x y. (g x) * y"
   875     by unfold_locales (simp add: mult_ac)
   876   show ?thesis using assms by(simp add:fold_image_def)
   877 qed
   878 
   879 (*
   880 lemma fold_commute:
   881   "finite A ==> (!!z. x * (fold times g z A) = fold times g (x * z) A)"
   882   apply (induct set: finite)
   883    apply simp
   884   apply (simp add: mult_left_commute [of x])
   885   done
   886 
   887 lemma fold_nest_Un_Int:
   888   "finite A ==> finite B
   889     ==> fold times g (fold times g z B) A = fold times g (fold times g z (A Int B)) (A Un B)"
   890   apply (induct set: finite)
   891    apply simp
   892   apply (simp add: fold_commute Int_insert_left insert_absorb)
   893   done
   894 
   895 lemma fold_nest_Un_disjoint:
   896   "finite A ==> finite B ==> A Int B = {}
   897     ==> fold times g z (A Un B) = fold times g (fold times g z B) A"
   898   by (simp add: fold_nest_Un_Int)
   899 *)
   900 
   901 lemma fold_image_reindex:
   902 assumes fin: "finite A"
   903 shows "inj_on h A \<Longrightarrow> fold_image times g z (h`A) = fold_image times (g\<circ>h) z A"
   904 using fin by induct auto
   905 
   906 (*
   907 text{*
   908   Fusion theorem, as described in Graham Hutton's paper,
   909   A Tutorial on the Universality and Expressiveness of Fold,
   910   JFP 9:4 (355-372), 1999.
   911 *}
   912 
   913 lemma fold_fusion:
   914   assumes "ab_semigroup_mult g"
   915   assumes fin: "finite A"
   916     and hyp: "\<And>x y. h (g x y) = times x (h y)"
   917   shows "h (fold g j w A) = fold times j (h w) A"
   918 proof -
   919   class_interpret ab_semigroup_mult [g] by fact
   920   show ?thesis using fin hyp by (induct set: finite) simp_all
   921 qed
   922 *)
   923 
   924 lemma fold_image_cong:
   925   "finite A \<Longrightarrow>
   926   (!!x. x:A ==> g x = h x) ==> fold_image times g z A = fold_image times h z A"
   927 apply (subgoal_tac "ALL C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C")
   928  apply simp
   929 apply (erule finite_induct, simp)
   930 apply (simp add: subset_insert_iff, clarify)
   931 apply (subgoal_tac "finite C")
   932  prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   933 apply (subgoal_tac "C = insert x (C - {x})")
   934  prefer 2 apply blast
   935 apply (erule ssubst)
   936 apply (drule spec)
   937 apply (erule (1) notE impE)
   938 apply (simp add: Ball_def del: insert_Diff_single)
   939 done
   940 
   941 end
   942 
   943 context comm_monoid_mult
   944 begin
   945 
   946 lemma fold_image_1:
   947   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   948   apply (induct set: finite)
   949   apply simp by auto
   950 
   951 lemma fold_image_Un_Int:
   952   "finite A ==> finite B ==>
   953     fold_image times g 1 A * fold_image times g 1 B =
   954     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   955 by (induct set: finite) 
   956    (auto simp add: mult_ac insert_absorb Int_insert_left)
   957 
   958 lemma fold_image_Un_one:
   959   assumes fS: "finite S" and fT: "finite T"
   960   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   961   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   962 proof-
   963   have "fold_image op * f 1 (S \<inter> T) = 1" 
   964     apply (rule fold_image_1)
   965     using fS fT I0 by auto 
   966   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   967 qed
   968 
   969 corollary fold_Un_disjoint:
   970   "finite A ==> finite B ==> A Int B = {} ==>
   971    fold_image times g 1 (A Un B) =
   972    fold_image times g 1 A * fold_image times g 1 B"
   973 by (simp add: fold_image_Un_Int)
   974 
   975 lemma fold_image_UN_disjoint:
   976   "\<lbrakk> finite I; ALL i:I. finite (A i);
   977      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   978    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   979        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   980 apply (induct set: finite, simp, atomize)
   981 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   982  prefer 2 apply blast
   983 apply (subgoal_tac "A x Int UNION F A = {}")
   984  prefer 2 apply blast
   985 apply (simp add: fold_Un_disjoint)
   986 done
   987 
   988 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   989   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   990   fold_image times (split g) 1 (SIGMA x:A. B x)"
   991 apply (subst Sigma_def)
   992 apply (subst fold_image_UN_disjoint, assumption, simp)
   993  apply blast
   994 apply (erule fold_image_cong)
   995 apply (subst fold_image_UN_disjoint, simp, simp)
   996  apply blast
   997 apply simp
   998 done
   999 
  1000 lemma fold_image_distrib: "finite A \<Longrightarrow>
  1001    fold_image times (%x. g x * h x) 1 A =
  1002    fold_image times g 1 A *  fold_image times h 1 A"
  1003 by (erule finite_induct) (simp_all add: mult_ac)
  1004 
  1005 lemma fold_image_related: 
  1006   assumes Re: "R e e" 
  1007   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1008   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1009   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
  1010   using fS by (rule finite_subset_induct) (insert assms, auto)
  1011 
  1012 lemma  fold_image_eq_general:
  1013   assumes fS: "finite S"
  1014   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
  1015   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
  1016   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
  1017 proof-
  1018   from h f12 have hS: "h ` S = S'" by auto
  1019   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1020     from f12 h H  have "x = y" by auto }
  1021   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1022   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1023   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
  1024   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
  1025     using fold_image_reindex[OF fS hinj, of f2 e] .
  1026   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
  1027     by blast
  1028   finally show ?thesis ..
  1029 qed
  1030 
  1031 lemma fold_image_eq_general_inverses:
  1032   assumes fS: "finite S" 
  1033   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1034   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
  1035   shows "fold_image (op *) f e S = fold_image (op *) g e T"
  1036   (* metis solves it, but not yet available here *)
  1037   apply (rule fold_image_eq_general[OF fS, of T h g f e])
  1038   apply (rule ballI)
  1039   apply (frule kh)
  1040   apply (rule ex1I[])
  1041   apply blast
  1042   apply clarsimp
  1043   apply (drule hk) apply simp
  1044   apply (rule sym)
  1045   apply (erule conjunct1[OF conjunct2[OF hk]])
  1046   apply (rule ballI)
  1047   apply (drule  hk)
  1048   apply blast
  1049   done
  1050 
  1051 end
  1052 
  1053 
  1054 subsection {* A fold functional for non-empty sets *}
  1055 
  1056 text{* Does not require start value. *}
  1057 
  1058 inductive
  1059   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
  1060   for f :: "'a => 'a => 'a"
  1061 where
  1062   fold1Set_insertI [intro]:
  1063    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
  1064 
  1065 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
  1066   "fold1 f A == THE x. fold1Set f A x"
  1067 
  1068 lemma fold1Set_nonempty:
  1069   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
  1070 by(erule fold1Set.cases, simp_all)
  1071 
  1072 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
  1073 
  1074 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
  1075 
  1076 
  1077 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
  1078 by (blast elim: fold_graph.cases)
  1079 
  1080 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1081 by (unfold fold1_def) blast
  1082 
  1083 lemma finite_nonempty_imp_fold1Set:
  1084   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1085 apply (induct A rule: finite_induct)
  1086 apply (auto dest: finite_imp_fold_graph [of _ f])
  1087 done
  1088 
  1089 text{*First, some lemmas about @{const fold_graph}.*}
  1090 
  1091 context ab_semigroup_mult
  1092 begin
  1093 
  1094 lemma fun_left_comm: "fun_left_comm(op *)"
  1095 by unfold_locales (simp add: mult_ac)
  1096 
  1097 lemma fold_graph_insert_swap:
  1098 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1099 shows "fold_graph times z (insert b A) (z * y)"
  1100 proof -
  1101   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1102 from assms show ?thesis
  1103 proof (induct rule: fold_graph.induct)
  1104   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1105 next
  1106   case (insertI x A y)
  1107     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1108       using insertI by force  --{*how does @{term id} get unfolded?*}
  1109     thus ?case by (simp add: insert_commute mult_ac)
  1110 qed
  1111 qed
  1112 
  1113 lemma fold_graph_permute_diff:
  1114 assumes fold: "fold_graph times b A x"
  1115 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1116 using fold
  1117 proof (induct rule: fold_graph.induct)
  1118   case emptyI thus ?case by simp
  1119 next
  1120   case (insertI x A y)
  1121   have "a = x \<or> a \<in> A" using insertI by simp
  1122   thus ?case
  1123   proof
  1124     assume "a = x"
  1125     with insertI show ?thesis
  1126       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1127   next
  1128     assume ainA: "a \<in> A"
  1129     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1130       using insertI by force
  1131     moreover
  1132     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1133       using ainA insertI by blast
  1134     ultimately show ?thesis by simp
  1135   qed
  1136 qed
  1137 
  1138 lemma fold1_eq_fold:
  1139 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1140 proof -
  1141   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1142   from assms show ?thesis
  1143 apply (simp add: fold1_def fold_def)
  1144 apply (rule the_equality)
  1145 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1146 apply (rule sym, clarify)
  1147 apply (case_tac "Aa=A")
  1148  apply (best intro: fold_graph_determ)
  1149 apply (subgoal_tac "fold_graph times a A x")
  1150  apply (best intro: fold_graph_determ)
  1151 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1152  prefer 2 apply (blast elim: equalityE)
  1153 apply (auto dest: fold_graph_permute_diff [where a=a])
  1154 done
  1155 qed
  1156 
  1157 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1158 apply safe
  1159  apply simp
  1160  apply (drule_tac x=x in spec)
  1161  apply (drule_tac x="A-{x}" in spec, auto)
  1162 done
  1163 
  1164 lemma fold1_insert:
  1165   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1166   shows "fold1 times (insert x A) = x * fold1 times A"
  1167 proof -
  1168   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1169   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1170     by (auto simp add: nonempty_iff)
  1171   with A show ?thesis
  1172     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1173 qed
  1174 
  1175 end
  1176 
  1177 context ab_semigroup_idem_mult
  1178 begin
  1179 
  1180 lemma fun_left_comm_idem: "fun_left_comm_idem(op *)"
  1181 apply unfold_locales
  1182  apply (rule mult_left_commute)
  1183 apply (rule mult_left_idem)
  1184 done
  1185 
  1186 lemma fold1_insert_idem [simp]:
  1187   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1188   shows "fold1 times (insert x A) = x * fold1 times A"
  1189 proof -
  1190   interpret fun_left_comm_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1191     by (rule fun_left_comm_idem)
  1192   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1193     by (auto simp add: nonempty_iff)
  1194   show ?thesis
  1195   proof cases
  1196     assume "a = x"
  1197     thus ?thesis
  1198     proof cases
  1199       assume "A' = {}"
  1200       with prems show ?thesis by simp
  1201     next
  1202       assume "A' \<noteq> {}"
  1203       with prems show ?thesis
  1204         by (simp add: fold1_insert mult_assoc [symmetric])
  1205     qed
  1206   next
  1207     assume "a \<noteq> x"
  1208     with prems show ?thesis
  1209       by (simp add: insert_commute fold1_eq_fold)
  1210   qed
  1211 qed
  1212 
  1213 lemma hom_fold1_commute:
  1214 assumes hom: "!!x y. h (x * y) = h x * h y"
  1215 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1216 using N proof (induct rule: finite_ne_induct)
  1217   case singleton thus ?case by simp
  1218 next
  1219   case (insert n N)
  1220   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1221   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1222   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1223   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1224     using insert by(simp)
  1225   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1226   finally show ?case .
  1227 qed
  1228 
  1229 lemma fold1_eq_fold_idem:
  1230   assumes "finite A"
  1231   shows "fold1 times (insert a A) = fold times a A"
  1232 proof (cases "a \<in> A")
  1233   case False
  1234   with assms show ?thesis by (simp add: fold1_eq_fold)
  1235 next
  1236   interpret fun_left_comm_idem times by (fact fun_left_comm_idem)
  1237   case True then obtain b B
  1238     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1239   with assms have "finite B" by auto
  1240   then have "fold times a (insert a B) = fold times (a * a) B"
  1241     using `a \<notin> B` by (rule fold_insert2)
  1242   then show ?thesis
  1243     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1244 qed
  1245 
  1246 end
  1247 
  1248 
  1249 text{* Now the recursion rules for definitions: *}
  1250 
  1251 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1252 by simp
  1253 
  1254 lemma (in ab_semigroup_mult) fold1_insert_def:
  1255   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1256 by (simp add:fold1_insert)
  1257 
  1258 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1259   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1260 by simp
  1261 
  1262 subsubsection{* Determinacy for @{term fold1Set} *}
  1263 
  1264 (*Not actually used!!*)
  1265 (*
  1266 context ab_semigroup_mult
  1267 begin
  1268 
  1269 lemma fold_graph_permute:
  1270   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1271    ==> fold_graph times id a (insert b A) x"
  1272 apply (cases "a=b") 
  1273 apply (auto dest: fold_graph_permute_diff) 
  1274 done
  1275 
  1276 lemma fold1Set_determ:
  1277   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1278 proof (clarify elim!: fold1Set.cases)
  1279   fix A x B y a b
  1280   assume Ax: "fold_graph times id a A x"
  1281   assume By: "fold_graph times id b B y"
  1282   assume anotA:  "a \<notin> A"
  1283   assume bnotB:  "b \<notin> B"
  1284   assume eq: "insert a A = insert b B"
  1285   show "y=x"
  1286   proof cases
  1287     assume same: "a=b"
  1288     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1289     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1290   next
  1291     assume diff: "a\<noteq>b"
  1292     let ?D = "B - {a}"
  1293     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1294      and aB: "a \<in> B" and bA: "b \<in> A"
  1295       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1296     with aB bnotB By
  1297     have "fold_graph times id a (insert b ?D) y" 
  1298       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1299     moreover
  1300     have "fold_graph times id a (insert b ?D) x"
  1301       by (simp add: A [symmetric] Ax) 
  1302     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1303   qed
  1304 qed
  1305 
  1306 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1307   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1308 
  1309 end
  1310 *)
  1311 
  1312 declare
  1313   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1314   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1315   -- {* No more proofs involve these relations. *}
  1316 
  1317 subsubsection {* Lemmas about @{text fold1} *}
  1318 
  1319 context ab_semigroup_mult
  1320 begin
  1321 
  1322 lemma fold1_Un:
  1323 assumes A: "finite A" "A \<noteq> {}"
  1324 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1325        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1326 using A by (induct rule: finite_ne_induct)
  1327   (simp_all add: fold1_insert mult_assoc)
  1328 
  1329 lemma fold1_in:
  1330   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1331   shows "fold1 times A \<in> A"
  1332 using A
  1333 proof (induct rule:finite_ne_induct)
  1334   case singleton thus ?case by simp
  1335 next
  1336   case insert thus ?case using elem by (force simp add:fold1_insert)
  1337 qed
  1338 
  1339 end
  1340 
  1341 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1342 assumes A: "finite A" "A \<noteq> {}"
  1343 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1344        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1345 using A
  1346 proof(induct rule:finite_ne_induct)
  1347   case singleton thus ?case by simp
  1348 next
  1349   case insert thus ?case by (simp add: mult_assoc)
  1350 qed
  1351 
  1352 
  1353 subsection {* Locales as mini-packages for fold operations *}
  1354 
  1355 subsubsection {* The natural case *}
  1356 
  1357 locale folding =
  1358   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1359   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1360   assumes commute_comp: "f y \<circ> f x = f x \<circ> f y"
  1361   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1362 begin
  1363 
  1364 lemma empty [simp]:
  1365   "F {} = id"
  1366   by (simp add: eq_fold expand_fun_eq)
  1367 
  1368 lemma insert [simp]:
  1369   assumes "finite A" and "x \<notin> A"
  1370   shows "F (insert x A) = F A \<circ> f x"
  1371 proof -
  1372   interpret fun_left_comm f proof
  1373   qed (insert commute_comp, simp add: expand_fun_eq)
  1374   from fold_insert2 assms
  1375   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1376   with `finite A` show ?thesis by (simp add: eq_fold expand_fun_eq)
  1377 qed
  1378 
  1379 lemma remove:
  1380   assumes "finite A" and "x \<in> A"
  1381   shows "F A = F (A - {x}) \<circ> f x"
  1382 proof -
  1383   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1384     by (auto dest: mk_disjoint_insert)
  1385   moreover from `finite A` this have "finite B" by simp
  1386   ultimately show ?thesis by simp
  1387 qed
  1388 
  1389 lemma insert_remove:
  1390   assumes "finite A"
  1391   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1392   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1393 
  1394 lemma commute_left_comp:
  1395   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1396   by (simp add: o_assoc commute_comp)
  1397 
  1398 lemma commute_comp':
  1399   assumes "finite A"
  1400   shows "f x \<circ> F A = F A \<circ> f x"
  1401   using assms by (induct A)
  1402     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] commute_comp)
  1403 
  1404 lemma commute_left_comp':
  1405   assumes "finite A"
  1406   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1407   using assms by (simp add: o_assoc commute_comp')
  1408 
  1409 lemma commute_comp'':
  1410   assumes "finite A" and "finite B"
  1411   shows "F B \<circ> F A = F A \<circ> F B"
  1412   using assms by (induct A)
  1413     (simp_all add: o_assoc, simp add: o_assoc [symmetric] commute_comp')
  1414 
  1415 lemma commute_left_comp'':
  1416   assumes "finite A" and "finite B"
  1417   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1418   using assms by (simp add: o_assoc commute_comp'')
  1419 
  1420 lemmas commute_comps = o_assoc [symmetric] commute_comp commute_left_comp
  1421   commute_comp' commute_left_comp' commute_comp'' commute_left_comp''
  1422 
  1423 lemma union_inter:
  1424   assumes "finite A" and "finite B"
  1425   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1426   using assms by (induct A)
  1427     (simp_all del: o_apply add: insert_absorb Int_insert_left commute_comps,
  1428       simp add: o_assoc)
  1429 
  1430 lemma union:
  1431   assumes "finite A" and "finite B"
  1432   and "A \<inter> B = {}"
  1433   shows "F (A \<union> B) = F A \<circ> F B"
  1434 proof -
  1435   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1436   with `A \<inter> B = {}` show ?thesis by simp
  1437 qed
  1438 
  1439 end
  1440 
  1441 
  1442 subsubsection {* The natural case with idempotency *}
  1443 
  1444 locale folding_idem = folding +
  1445   assumes idem_comp: "f x \<circ> f x = f x"
  1446 begin
  1447 
  1448 lemma idem_left_comp:
  1449   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1450   by (simp add: o_assoc idem_comp)
  1451 
  1452 lemma in_comp_idem:
  1453   assumes "finite A" and "x \<in> A"
  1454   shows "F A \<circ> f x = F A"
  1455 using assms by (induct A)
  1456   (auto simp add: commute_comps idem_comp, simp add: commute_left_comp' [symmetric] commute_comp')
  1457 
  1458 lemma subset_comp_idem:
  1459   assumes "finite A" and "B \<subseteq> A"
  1460   shows "F A \<circ> F B = F A"
  1461 proof -
  1462   from assms have "finite B" by (blast dest: finite_subset)
  1463   then show ?thesis using `B \<subseteq> A` by (induct B)
  1464     (simp_all add: o_assoc in_comp_idem `finite A`)
  1465 qed
  1466 
  1467 declare insert [simp del]
  1468 
  1469 lemma insert_idem [simp]:
  1470   assumes "finite A"
  1471   shows "F (insert x A) = F A \<circ> f x"
  1472   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1473 
  1474 lemma union_idem:
  1475   assumes "finite A" and "finite B"
  1476   shows "F (A \<union> B) = F A \<circ> F B"
  1477 proof -
  1478   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1479   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1480   with assms show ?thesis by (simp add: union_inter)
  1481 qed
  1482 
  1483 end
  1484 
  1485 
  1486 subsubsection {* The image case with fixed function *}
  1487 
  1488 no_notation times (infixl "*" 70)
  1489 no_notation Groups.one ("1")
  1490 
  1491 locale folding_image_simple = comm_monoid +
  1492   fixes g :: "('b \<Rightarrow> 'a)"
  1493   fixes F :: "'b set \<Rightarrow> 'a"
  1494   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1495 begin
  1496 
  1497 lemma empty [simp]:
  1498   "F {} = 1"
  1499   by (simp add: eq_fold_g)
  1500 
  1501 lemma insert [simp]:
  1502   assumes "finite A" and "x \<notin> A"
  1503   shows "F (insert x A) = g x * F A"
  1504 proof -
  1505   interpret fun_left_comm "%x y. (g x) * y" proof
  1506   qed (simp add: ac_simps)
  1507   with assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1508     by (simp add: fold_image_def)
  1509   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1510 qed
  1511 
  1512 lemma remove:
  1513   assumes "finite A" and "x \<in> A"
  1514   shows "F A = g x * F (A - {x})"
  1515 proof -
  1516   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1517     by (auto dest: mk_disjoint_insert)
  1518   moreover from `finite A` this have "finite B" by simp
  1519   ultimately show ?thesis by simp
  1520 qed
  1521 
  1522 lemma insert_remove:
  1523   assumes "finite A"
  1524   shows "F (insert x A) = g x * F (A - {x})"
  1525   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1526 
  1527 lemma neutral:
  1528   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1529   shows "F A = 1"
  1530   using assms by (induct A) simp_all
  1531 
  1532 lemma union_inter:
  1533   assumes "finite A" and "finite B"
  1534   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1535 using assms proof (induct A)
  1536   case empty then show ?case by simp
  1537 next
  1538   case (insert x A) then show ?case
  1539     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1540 qed
  1541 
  1542 corollary union_inter_neutral:
  1543   assumes "finite A" and "finite B"
  1544   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1545   shows "F (A \<union> B) = F A * F B"
  1546   using assms by (simp add: union_inter [symmetric] neutral)
  1547 
  1548 corollary union_disjoint:
  1549   assumes "finite A" and "finite B"
  1550   assumes "A \<inter> B = {}"
  1551   shows "F (A \<union> B) = F A * F B"
  1552   using assms by (simp add: union_inter_neutral)
  1553 
  1554 end
  1555 
  1556 
  1557 subsubsection {* The image case with flexible function *}
  1558 
  1559 locale folding_image = comm_monoid +
  1560   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1561   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1562 
  1563 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1564 qed (fact eq_fold)
  1565 
  1566 context folding_image
  1567 begin
  1568 
  1569 lemma reindex: (* FIXME polymorhism *)
  1570   assumes "finite A" and "inj_on h A"
  1571   shows "F g (h ` A) = F (g \<circ> h) A"
  1572   using assms by (induct A) auto
  1573 
  1574 lemma cong:
  1575   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1576   shows "F g A = F h A"
  1577 proof -
  1578   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1579   apply - apply (erule finite_induct) apply simp
  1580   apply (simp add: subset_insert_iff, clarify)
  1581   apply (subgoal_tac "finite C")
  1582   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1583   apply (subgoal_tac "C = insert x (C - {x})")
  1584   prefer 2 apply blast
  1585   apply (erule ssubst)
  1586   apply (drule spec)
  1587   apply (erule (1) notE impE)
  1588   apply (simp add: Ball_def del: insert_Diff_single)
  1589   done
  1590   with assms show ?thesis by simp
  1591 qed
  1592 
  1593 lemma UNION_disjoint:
  1594   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1595   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1596   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1597 apply (insert assms)
  1598 apply (induct set: finite, simp, atomize)
  1599 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1600  prefer 2 apply blast
  1601 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1602  prefer 2 apply blast
  1603 apply (simp add: union_disjoint)
  1604 done
  1605 
  1606 lemma distrib:
  1607   assumes "finite A"
  1608   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1609   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1610 
  1611 lemma related: 
  1612   assumes Re: "R 1 1" 
  1613   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1614   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1615   shows "R (F h S) (F g S)"
  1616   using fS by (rule finite_subset_induct) (insert assms, auto)
  1617 
  1618 lemma eq_general:
  1619   assumes fS: "finite S"
  1620   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1621   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1622   shows "F f1 S = F f2 S'"
  1623 proof-
  1624   from h f12 have hS: "h ` S = S'" by blast
  1625   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1626     from f12 h H  have "x = y" by auto }
  1627   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1628   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1629   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1630   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1631   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1632     by blast
  1633   finally show ?thesis ..
  1634 qed
  1635 
  1636 lemma eq_general_inverses:
  1637   assumes fS: "finite S" 
  1638   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1639   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1640   shows "F j S = F g T"
  1641   (* metis solves it, but not yet available here *)
  1642   apply (rule eq_general [OF fS, of T h g j])
  1643   apply (rule ballI)
  1644   apply (frule kh)
  1645   apply (rule ex1I[])
  1646   apply blast
  1647   apply clarsimp
  1648   apply (drule hk) apply simp
  1649   apply (rule sym)
  1650   apply (erule conjunct1[OF conjunct2[OF hk]])
  1651   apply (rule ballI)
  1652   apply (drule hk)
  1653   apply blast
  1654   done
  1655 
  1656 end
  1657 
  1658 
  1659 subsubsection {* The image case with fixed function and idempotency *}
  1660 
  1661 locale folding_image_simple_idem = folding_image_simple +
  1662   assumes idem: "x * x = x"
  1663 
  1664 sublocale folding_image_simple_idem < semilattice proof
  1665 qed (fact idem)
  1666 
  1667 context folding_image_simple_idem
  1668 begin
  1669 
  1670 lemma in_idem:
  1671   assumes "finite A" and "x \<in> A"
  1672   shows "g x * F A = F A"
  1673   using assms by (induct A) (auto simp add: left_commute)
  1674 
  1675 lemma subset_idem:
  1676   assumes "finite A" and "B \<subseteq> A"
  1677   shows "F B * F A = F A"
  1678 proof -
  1679   from assms have "finite B" by (blast dest: finite_subset)
  1680   then show ?thesis using `B \<subseteq> A` by (induct B)
  1681     (auto simp add: assoc in_idem `finite A`)
  1682 qed
  1683 
  1684 declare insert [simp del]
  1685 
  1686 lemma insert_idem [simp]:
  1687   assumes "finite A"
  1688   shows "F (insert x A) = g x * F A"
  1689   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1690 
  1691 lemma union_idem:
  1692   assumes "finite A" and "finite B"
  1693   shows "F (A \<union> B) = F A * F B"
  1694 proof -
  1695   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1696   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1697   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1698 qed
  1699 
  1700 end
  1701 
  1702 
  1703 subsubsection {* The image case with flexible function and idempotency *}
  1704 
  1705 locale folding_image_idem = folding_image +
  1706   assumes idem: "x * x = x"
  1707 
  1708 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1709 qed (fact idem)
  1710 
  1711 
  1712 subsubsection {* The neutral-less case *}
  1713 
  1714 locale folding_one = abel_semigroup +
  1715   fixes F :: "'a set \<Rightarrow> 'a"
  1716   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1717 begin
  1718 
  1719 lemma singleton [simp]:
  1720   "F {x} = x"
  1721   by (simp add: eq_fold)
  1722 
  1723 lemma eq_fold':
  1724   assumes "finite A" and "x \<notin> A"
  1725   shows "F (insert x A) = fold (op *) x A"
  1726 proof -
  1727   interpret ab_semigroup_mult "op *" proof qed (simp_all add: ac_simps)
  1728   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1729 qed
  1730 
  1731 lemma insert [simp]:
  1732   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1733   shows "F (insert x A) = x * F A"
  1734 proof -
  1735   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1736   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1737   with `finite A` have "finite B" by simp
  1738   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1739   qed (simp_all add: expand_fun_eq ac_simps)
  1740   thm fold.commute_comp' [of B b, simplified expand_fun_eq, simplified]
  1741   from `finite B` fold.commute_comp' [of B x]
  1742     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1743   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: expand_fun_eq commute)
  1744   from `finite B` * fold.insert [of B b]
  1745     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1746   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: expand_fun_eq)
  1747   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1748 qed
  1749 
  1750 lemma remove:
  1751   assumes "finite A" and "x \<in> A"
  1752   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1753 proof -
  1754   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1755   with assms show ?thesis by simp
  1756 qed
  1757 
  1758 lemma insert_remove:
  1759   assumes "finite A"
  1760   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1761   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1762 
  1763 lemma union_disjoint:
  1764   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1765   shows "F (A \<union> B) = F A * F B"
  1766   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1767 
  1768 lemma union_inter:
  1769   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1770   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1771 proof -
  1772   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1773   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1774     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1775   next
  1776     case (insert x A) show ?case proof (cases "x \<in> B")
  1777       case True then have "B \<noteq> {}" by auto
  1778       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1779         (simp_all add: insert_absorb ac_simps union_disjoint)
  1780     next
  1781       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1782       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1783         by auto
  1784       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1785     qed
  1786   qed
  1787 qed
  1788 
  1789 lemma closed:
  1790   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1791   shows "F A \<in> A"
  1792 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1793   case singleton then show ?case by simp
  1794 next
  1795   case insert with elem show ?case by force
  1796 qed
  1797 
  1798 end
  1799 
  1800 
  1801 subsubsection {* The neutral-less case with idempotency *}
  1802 
  1803 locale folding_one_idem = folding_one +
  1804   assumes idem: "x * x = x"
  1805 
  1806 sublocale folding_one_idem < semilattice proof
  1807 qed (fact idem)
  1808 
  1809 context folding_one_idem
  1810 begin
  1811 
  1812 lemma in_idem:
  1813   assumes "finite A" and "x \<in> A"
  1814   shows "x * F A = F A"
  1815 proof -
  1816   from assms have "A \<noteq> {}" by auto
  1817   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1818 qed
  1819 
  1820 lemma subset_idem:
  1821   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1822   shows "F B * F A = F A"
  1823 proof -
  1824   from assms have "finite B" by (blast dest: finite_subset)
  1825   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1826     (simp_all add: assoc in_idem `finite A`)
  1827 qed
  1828 
  1829 lemma eq_fold_idem':
  1830   assumes "finite A"
  1831   shows "F (insert a A) = fold (op *) a A"
  1832 proof -
  1833   interpret ab_semigroup_idem_mult "op *" proof qed (simp_all add: ac_simps)
  1834   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1835 qed
  1836 
  1837 lemma insert_idem [simp]:
  1838   assumes "finite A" and "A \<noteq> {}"
  1839   shows "F (insert x A) = x * F A"
  1840 proof (cases "x \<in> A")
  1841   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1842 next
  1843   case True
  1844   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1845 qed
  1846   
  1847 lemma union_idem:
  1848   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1849   shows "F (A \<union> B) = F A * F B"
  1850 proof (cases "A \<inter> B = {}")
  1851   case True with assms show ?thesis by (simp add: union_disjoint)
  1852 next
  1853   case False
  1854   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1855   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1856   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1857 qed
  1858 
  1859 lemma hom_commute:
  1860   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1861   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1862 using N proof (induct rule: finite_ne_induct)
  1863   case singleton thus ?case by simp
  1864 next
  1865   case (insert n N)
  1866   then have "h (F (insert n N)) = h (n * F N)" by simp
  1867   also have "\<dots> = h n * h (F N)" by (rule hom)
  1868   also have "h (F N) = F (h ` N)" by(rule insert)
  1869   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1870     using insert by(simp)
  1871   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1872   finally show ?case .
  1873 qed
  1874 
  1875 end
  1876 
  1877 notation times (infixl "*" 70)
  1878 notation Groups.one ("1")
  1879 
  1880 
  1881 subsection {* Finite cardinality *}
  1882 
  1883 text {* This definition, although traditional, is ugly to work with:
  1884 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1885 But now that we have @{text fold_image} things are easy:
  1886 *}
  1887 
  1888 definition card :: "'a set \<Rightarrow> nat" where
  1889   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1890 
  1891 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1892 qed (simp add: card_def)
  1893 
  1894 lemma card_infinite [simp]:
  1895   "\<not> finite A \<Longrightarrow> card A = 0"
  1896   by (simp add: card_def)
  1897 
  1898 lemma card_empty:
  1899   "card {} = 0"
  1900   by (fact card.empty)
  1901 
  1902 lemma card_insert_disjoint:
  1903   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1904   by simp
  1905 
  1906 lemma card_insert_if:
  1907   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1908   by auto (simp add: card.insert_remove card.remove)
  1909 
  1910 lemma card_ge_0_finite:
  1911   "card A > 0 \<Longrightarrow> finite A"
  1912   by (rule ccontr) simp
  1913 
  1914 lemma card_0_eq [simp, no_atp]:
  1915   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1916   by (auto dest: mk_disjoint_insert)
  1917 
  1918 lemma finite_UNIV_card_ge_0:
  1919   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1920   by (rule ccontr) simp
  1921 
  1922 lemma card_eq_0_iff:
  1923   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1924   by auto
  1925 
  1926 lemma card_gt_0_iff:
  1927   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1928   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1929 
  1930 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1931 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1932 apply(simp del:insert_Diff_single)
  1933 done
  1934 
  1935 lemma card_Diff_singleton:
  1936   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1937 by (simp add: card_Suc_Diff1 [symmetric])
  1938 
  1939 lemma card_Diff_singleton_if:
  1940   "finite A ==> card (A-{x}) = (if x : A then card A - 1 else card A)"
  1941 by (simp add: card_Diff_singleton)
  1942 
  1943 lemma card_Diff_insert[simp]:
  1944 assumes "finite A" and "a:A" and "a ~: B"
  1945 shows "card(A - insert a B) = card(A - B) - 1"
  1946 proof -
  1947   have "A - insert a B = (A - B) - {a}" using assms by blast
  1948   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1949 qed
  1950 
  1951 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1952 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1953 
  1954 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1955 by (simp add: card_insert_if)
  1956 
  1957 lemma card_mono:
  1958   assumes "finite B" and "A \<subseteq> B"
  1959   shows "card A \<le> card B"
  1960 proof -
  1961   from assms have "finite A" by (auto intro: finite_subset)
  1962   then show ?thesis using assms proof (induct A arbitrary: B)
  1963     case empty then show ?case by simp
  1964   next
  1965     case (insert x A)
  1966     then have "x \<in> B" by simp
  1967     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1968     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1969     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1970   qed
  1971 qed
  1972 
  1973 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1974 apply (induct set: finite, simp, clarify)
  1975 apply (subgoal_tac "finite A & A - {x} <= F")
  1976  prefer 2 apply (blast intro: finite_subset, atomize)
  1977 apply (drule_tac x = "A - {x}" in spec)
  1978 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1979 apply (case_tac "card A", auto)
  1980 done
  1981 
  1982 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1983 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1984 apply (blast dest: card_seteq)
  1985 done
  1986 
  1987 lemma card_Un_Int: "finite A ==> finite B
  1988     ==> card A + card B = card (A Un B) + card (A Int B)"
  1989   by (fact card.union_inter [symmetric])
  1990 
  1991 lemma card_Un_disjoint: "finite A ==> finite B
  1992     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1993   by (fact card.union_disjoint)
  1994 
  1995 lemma card_Diff_subset:
  1996   assumes "finite B" and "B \<subseteq> A"
  1997   shows "card (A - B) = card A - card B"
  1998 proof (cases "finite A")
  1999   case False with assms show ?thesis by simp
  2000 next
  2001   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  2002 qed
  2003 
  2004 lemma card_Diff_subset_Int:
  2005   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  2006 proof -
  2007   have "A - B = A - A \<inter> B" by auto
  2008   thus ?thesis
  2009     by (simp add: card_Diff_subset AB) 
  2010 qed
  2011 
  2012 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  2013 apply (rule Suc_less_SucD)
  2014 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  2015 done
  2016 
  2017 lemma card_Diff2_less:
  2018   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  2019 apply (case_tac "x = y")
  2020  apply (simp add: card_Diff1_less del:card_Diff_insert)
  2021 apply (rule less_trans)
  2022  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  2023 done
  2024 
  2025 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  2026 apply (case_tac "x : A")
  2027  apply (simp_all add: card_Diff1_less less_imp_le)
  2028 done
  2029 
  2030 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  2031 by (erule psubsetI, blast)
  2032 
  2033 lemma insert_partition:
  2034   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  2035   \<Longrightarrow> x \<inter> \<Union> F = {}"
  2036 by auto
  2037 
  2038 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  2039   assumes fin: "finite A" 
  2040   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  2041   shows "P A"
  2042 using fin
  2043 proof (induct A taking: card rule: measure_induct_rule)
  2044   case (less A)
  2045   have fin: "finite A" by fact
  2046   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  2047   { fix B 
  2048     assume asm: "B \<subset> A"
  2049     from asm have "card B < card A" using psubset_card_mono fin by blast
  2050     moreover
  2051     from asm have "B \<subseteq> A" by auto
  2052     then have "finite B" using fin finite_subset by blast
  2053     ultimately 
  2054     have "P B" using ih by simp
  2055   }
  2056   with fin show "P A" using major by blast
  2057 qed
  2058 
  2059 text{* main cardinality theorem *}
  2060 lemma card_partition [rule_format]:
  2061   "finite C ==>
  2062      finite (\<Union> C) -->
  2063      (\<forall>c\<in>C. card c = k) -->
  2064      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2065      k * card(C) = card (\<Union> C)"
  2066 apply (erule finite_induct, simp)
  2067 apply (simp add: card_Un_disjoint insert_partition 
  2068        finite_subset [of _ "\<Union> (insert x F)"])
  2069 done
  2070 
  2071 lemma card_eq_UNIV_imp_eq_UNIV:
  2072   assumes fin: "finite (UNIV :: 'a set)"
  2073   and card: "card A = card (UNIV :: 'a set)"
  2074   shows "A = (UNIV :: 'a set)"
  2075 proof
  2076   show "A \<subseteq> UNIV" by simp
  2077   show "UNIV \<subseteq> A"
  2078   proof
  2079     fix x
  2080     show "x \<in> A"
  2081     proof (rule ccontr)
  2082       assume "x \<notin> A"
  2083       then have "A \<subset> UNIV" by auto
  2084       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2085       with card show False by simp
  2086     qed
  2087   qed
  2088 qed
  2089 
  2090 text{*The form of a finite set of given cardinality*}
  2091 
  2092 lemma card_eq_SucD:
  2093 assumes "card A = Suc k"
  2094 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2095 proof -
  2096   have fin: "finite A" using assms by (auto intro: ccontr)
  2097   moreover have "card A \<noteq> 0" using assms by auto
  2098   ultimately obtain b where b: "b \<in> A" by auto
  2099   show ?thesis
  2100   proof (intro exI conjI)
  2101     show "A = insert b (A-{b})" using b by blast
  2102     show "b \<notin> A - {b}" by blast
  2103     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2104       using assms b fin by(fastsimp dest:mk_disjoint_insert)+
  2105   qed
  2106 qed
  2107 
  2108 lemma card_Suc_eq:
  2109   "(card A = Suc k) =
  2110    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2111 apply(rule iffI)
  2112  apply(erule card_eq_SucD)
  2113 apply(auto)
  2114 apply(subst card_insert)
  2115  apply(auto intro:ccontr)
  2116 done
  2117 
  2118 lemma finite_fun_UNIVD2:
  2119   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2120   shows "finite (UNIV :: 'b set)"
  2121 proof -
  2122   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2123     by(rule finite_imageI)
  2124   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2125     by(rule UNIV_eq_I) auto
  2126   ultimately show "finite (UNIV :: 'b set)" by simp
  2127 qed
  2128 
  2129 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2130   unfolding UNIV_unit by simp
  2131 
  2132 
  2133 subsubsection {* Cardinality of image *}
  2134 
  2135 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2136 apply (induct set: finite)
  2137  apply simp
  2138 apply (simp add: le_SucI card_insert_if)
  2139 done
  2140 
  2141 lemma card_image:
  2142   assumes "inj_on f A"
  2143   shows "card (f ` A) = card A"
  2144 proof (cases "finite A")
  2145   case True then show ?thesis using assms by (induct A) simp_all
  2146 next
  2147   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2148   with False show ?thesis by simp
  2149 qed
  2150 
  2151 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2152 by(auto simp: card_image bij_betw_def)
  2153 
  2154 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2155 by (simp add: card_seteq card_image)
  2156 
  2157 lemma eq_card_imp_inj_on:
  2158   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2159 apply (induct rule:finite_induct)
  2160 apply simp
  2161 apply(frule card_image_le[where f = f])
  2162 apply(simp add:card_insert_if split:if_splits)
  2163 done
  2164 
  2165 lemma inj_on_iff_eq_card:
  2166   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2167 by(blast intro: card_image eq_card_imp_inj_on)
  2168 
  2169 
  2170 lemma card_inj_on_le:
  2171   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2172 apply (subgoal_tac "finite A") 
  2173  apply (force intro: card_mono simp add: card_image [symmetric])
  2174 apply (blast intro: finite_imageD dest: finite_subset) 
  2175 done
  2176 
  2177 lemma card_bij_eq:
  2178   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2179      finite A; finite B |] ==> card A = card B"
  2180 by (auto intro: le_antisym card_inj_on_le)
  2181 
  2182 
  2183 subsubsection {* Pigeonhole Principles *}
  2184 
  2185 lemma pigeonhole: "finite(A) \<Longrightarrow> card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2186 by (auto dest: card_image less_irrefl_nat)
  2187 
  2188 lemma pigeonhole_infinite:
  2189 assumes  "~ finite A" and "finite(f`A)"
  2190 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2191 proof -
  2192   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2193   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2194     case empty thus ?case by simp
  2195   next
  2196     case (insert b F)
  2197     show ?case
  2198     proof cases
  2199       assume "finite{a:A. f a = b}"
  2200       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2201       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2202       finally have "~ finite({a:A. f a \<noteq> b})" .
  2203       from insert(3)[OF _ this]
  2204       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2205     next
  2206       assume 1: "~finite{a:A. f a = b}"
  2207       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2208       thus ?thesis using 1 by blast
  2209     qed
  2210   qed
  2211   from this[OF assms(2,1)] show ?thesis .
  2212 qed
  2213 
  2214 lemma pigeonhole_infinite_rel:
  2215 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2216 shows "EX b:B. ~finite{a:A. R a b}"
  2217 proof -
  2218    let ?F = "%a. {b:B. R a b}"
  2219    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2220    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2221    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2222    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2223    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2224    { assume "finite{a:A. R a b0}"
  2225      then have "finite {a\<in>A. ?F a = ?F a0}"
  2226        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2227    }
  2228    with 1 `b0 : B` show ?thesis by blast
  2229 qed
  2230 
  2231 
  2232 subsubsection {* Cardinality of sums *}
  2233 
  2234 lemma card_Plus:
  2235   assumes "finite A" and "finite B"
  2236   shows "card (A <+> B) = card A + card B"
  2237 proof -
  2238   have "Inl`A \<inter> Inr`B = {}" by fast
  2239   with assms show ?thesis
  2240     unfolding Plus_def
  2241     by (simp add: card_Un_disjoint card_image)
  2242 qed
  2243 
  2244 lemma card_Plus_conv_if:
  2245   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2246   by (auto simp add: card_Plus)
  2247 
  2248 
  2249 subsubsection {* Cardinality of the Powerset *}
  2250 
  2251 lemma card_Pow: "finite A ==> card (Pow A) = Suc (Suc 0) ^ card A"  (* FIXME numeral 2 (!?) *)
  2252 apply (induct set: finite)
  2253  apply (simp_all add: Pow_insert)
  2254 apply (subst card_Un_disjoint, blast)
  2255   apply (blast intro: finite_imageI, blast)
  2256 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2257  apply (simp add: card_image Pow_insert)
  2258 apply (unfold inj_on_def)
  2259 apply (blast elim!: equalityE)
  2260 done
  2261 
  2262 text {* Relates to equivalence classes.  Based on a theorem of F. Kammüller.  *}
  2263 
  2264 lemma dvd_partition:
  2265   "finite (Union C) ==>
  2266     ALL c : C. k dvd card c ==>
  2267     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2268   k dvd card (Union C)"
  2269 apply(frule finite_UnionD)
  2270 apply(rotate_tac -1)
  2271 apply (induct set: finite, simp_all, clarify)
  2272 apply (subst card_Un_disjoint)
  2273    apply (auto simp add: disjoint_eq_subset_Compl)
  2274 done
  2275 
  2276 
  2277 subsubsection {* Relating injectivity and surjectivity *}
  2278 
  2279 lemma finite_surj_inj: "finite(A) \<Longrightarrow> A <= f`A \<Longrightarrow> inj_on f A"
  2280 apply(rule eq_card_imp_inj_on, assumption)
  2281 apply(frule finite_imageI)
  2282 apply(drule (1) card_seteq)
  2283  apply(erule card_image_le)
  2284 apply simp
  2285 done
  2286 
  2287 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2288 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2289 by (blast intro: finite_surj_inj subset_UNIV dest:surj_range)
  2290 
  2291 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2292 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2293 by(fastsimp simp:surj_def dest!: endo_inj_surj)
  2294 
  2295 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2296 proof
  2297   assume "finite(UNIV::nat set)"
  2298   with finite_UNIV_inj_surj[of Suc]
  2299   show False by simp (blast dest: Suc_neq_Zero surjD)
  2300 qed
  2301 
  2302 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2303 lemma infinite_UNIV_char_0[no_atp]:
  2304   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2305 proof
  2306   assume "finite (UNIV::'a set)"
  2307   with subset_UNIV have "finite (range of_nat::'a set)"
  2308     by (rule finite_subset)
  2309   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2310     by (simp add: inj_on_def)
  2311   ultimately have "finite (UNIV::nat set)"
  2312     by (rule finite_imageD)
  2313   then show "False"
  2314     by simp
  2315 qed
  2316 
  2317 end