src/HOL/Hoare/Hoare_Logic.thy
author hoelzl
Thu Sep 02 10:14:32 2010 +0200 (2010-09-02)
changeset 39072 1030b1a166ef
parent 38353 d98baa2cf589
child 41959 b460124855b8
permissions -rw-r--r--
Add lessThan_Suc_eq_insert_0
     1 (*  Title:      HOL/Hoare/Hoare.thy
     2     Author:     Leonor Prensa Nieto & Tobias Nipkow
     3     Copyright   1998 TUM
     4 
     5 Sugared semantic embedding of Hoare logic.
     6 Strictly speaking a shallow embedding (as implemented by Norbert Galm
     7 following Mike Gordon) would suffice. Maybe the datatype com comes in useful
     8 later.
     9 *)
    10 
    11 theory Hoare_Logic
    12 imports Main
    13 uses ("hoare_tac.ML")
    14 begin
    15 
    16 types
    17     'a bexp = "'a set"
    18     'a assn = "'a set"
    19 
    20 datatype
    21  'a com = Basic "'a \<Rightarrow> 'a"
    22    | Seq "'a com" "'a com"               ("(_;/ _)"      [61,60] 60)
    23    | Cond "'a bexp" "'a com" "'a com"    ("(1IF _/ THEN _ / ELSE _/ FI)"  [0,0,0] 61)
    24    | While "'a bexp" "'a assn" "'a com"  ("(1WHILE _/ INV {_} //DO _ /OD)"  [0,0,0] 61)
    25 
    26 abbreviation annskip ("SKIP") where "SKIP == Basic id"
    27 
    28 types 'a sem = "'a => 'a => bool"
    29 
    30 inductive Sem :: "'a com \<Rightarrow> 'a sem"
    31 where
    32   "Sem (Basic f) s (f s)"
    33 | "Sem c1 s s'' \<Longrightarrow> Sem c2 s'' s' \<Longrightarrow> Sem (c1;c2) s s'"
    34 | "s \<in> b \<Longrightarrow> Sem c1 s s' \<Longrightarrow> Sem (IF b THEN c1 ELSE c2 FI) s s'"
    35 | "s \<notin> b \<Longrightarrow> Sem c2 s s' \<Longrightarrow> Sem (IF b THEN c1 ELSE c2 FI) s s'"
    36 | "s \<notin> b \<Longrightarrow> Sem (While b x c) s s"
    37 | "s \<in> b \<Longrightarrow> Sem c s s'' \<Longrightarrow> Sem (While b x c) s'' s' \<Longrightarrow>
    38    Sem (While b x c) s s'"
    39 
    40 inductive_cases [elim!]:
    41   "Sem (Basic f) s s'" "Sem (c1;c2) s s'"
    42   "Sem (IF b THEN c1 ELSE c2 FI) s s'"
    43 
    44 definition Valid :: "'a bexp \<Rightarrow> 'a com \<Rightarrow> 'a bexp \<Rightarrow> bool"
    45   where "Valid p c q \<longleftrightarrow> (!s s'. Sem c s s' --> s : p --> s' : q)"
    46 
    47 
    48 
    49 (** parse translations **)
    50 
    51 syntax
    52   "_assign"  :: "id => 'b => 'a com"        ("(2_ :=/ _)" [70,65] 61)
    53 
    54 syntax
    55  "_hoare_vars" :: "[idts, 'a assn,'a com,'a assn] => bool"
    56                  ("VARS _// {_} // _ // {_}" [0,0,55,0] 50)
    57 syntax ("" output)
    58  "_hoare"      :: "['a assn,'a com,'a assn] => bool"
    59                  ("{_} // _ // {_}" [0,55,0] 50)
    60 ML {*
    61 
    62 local
    63 
    64 fun abs((a,T),body) =
    65   let val a = absfree(a, dummyT, body)
    66   in if T = Bound 0 then a else Const(Syntax.constrainAbsC,dummyT) $ a $ T end
    67 in
    68 
    69 fun mk_abstuple [x] body = abs (x, body)
    70   | mk_abstuple (x::xs) body =
    71       Syntax.const @{const_syntax prod_case} $ abs (x, mk_abstuple xs body);
    72 
    73 fun mk_fbody a e [x as (b,_)] = if a=b then e else Syntax.free b
    74   | mk_fbody a e ((b,_)::xs) =
    75       Syntax.const @{const_syntax Pair} $ (if a=b then e else Syntax.free b) $ mk_fbody a e xs;
    76 
    77 fun mk_fexp a e xs = mk_abstuple xs (mk_fbody a e xs)
    78 end
    79 *}
    80 
    81 (* bexp_tr & assn_tr *)
    82 (*all meta-variables for bexp except for TRUE are translated as if they
    83   were boolean expressions*)
    84 ML{*
    85 fun bexp_tr (Const ("TRUE", _)) xs = Syntax.const "TRUE"   (* FIXME !? *)
    86   | bexp_tr b xs = Syntax.const @{const_syntax Collect} $ mk_abstuple xs b;
    87 
    88 fun assn_tr r xs = Syntax.const @{const_syntax Collect} $ mk_abstuple xs r;
    89 *}
    90 (* com_tr *)
    91 ML{*
    92 fun com_tr (Const(@{syntax_const "_assign"},_) $ Free (a,_) $ e) xs =
    93       Syntax.const @{const_syntax Basic} $ mk_fexp a e xs
    94   | com_tr (Const (@{const_syntax Basic},_) $ f) xs = Syntax.const @{const_syntax Basic} $ f
    95   | com_tr (Const (@{const_syntax Seq},_) $ c1 $ c2) xs =
    96       Syntax.const @{const_syntax Seq} $ com_tr c1 xs $ com_tr c2 xs
    97   | com_tr (Const (@{const_syntax Cond},_) $ b $ c1 $ c2) xs =
    98       Syntax.const @{const_syntax Cond} $ bexp_tr b xs $ com_tr c1 xs $ com_tr c2 xs
    99   | com_tr (Const (@{const_syntax While},_) $ b $ I $ c) xs =
   100       Syntax.const @{const_syntax While} $ bexp_tr b xs $ assn_tr I xs $ com_tr c xs
   101   | com_tr t _ = t (* if t is just a Free/Var *)
   102 *}
   103 
   104 (* triple_tr *)    (* FIXME does not handle "_idtdummy" *)
   105 ML{*
   106 local
   107 
   108 fun var_tr(Free(a,_)) = (a,Bound 0) (* Bound 0 = dummy term *)
   109   | var_tr(Const (@{syntax_const "_constrain"}, _) $ (Free (a,_)) $ T) = (a,T);
   110 
   111 fun vars_tr (Const (@{syntax_const "_idts"}, _) $ idt $ vars) = var_tr idt :: vars_tr vars
   112   | vars_tr t = [var_tr t]
   113 
   114 in
   115 fun hoare_vars_tr [vars, pre, prg, post] =
   116       let val xs = vars_tr vars
   117       in Syntax.const @{const_syntax Valid} $
   118          assn_tr pre xs $ com_tr prg xs $ assn_tr post xs
   119       end
   120   | hoare_vars_tr ts = raise TERM ("hoare_vars_tr", ts);
   121 end
   122 *}
   123 
   124 parse_translation {* [(@{syntax_const "_hoare_vars"}, hoare_vars_tr)] *}
   125 
   126 
   127 (*****************************************************************************)
   128 
   129 (*** print translations ***)
   130 ML{*
   131 fun dest_abstuple (Const (@{const_syntax prod_case},_) $ (Abs(v,_, body))) =
   132                             subst_bound (Syntax.free v, dest_abstuple body)
   133   | dest_abstuple (Abs(v,_, body)) = subst_bound (Syntax.free v, body)
   134   | dest_abstuple trm = trm;
   135 
   136 fun abs2list (Const (@{const_syntax prod_case},_) $ (Abs(x,T,t))) = Free (x, T)::abs2list t
   137   | abs2list (Abs(x,T,t)) = [Free (x, T)]
   138   | abs2list _ = [];
   139 
   140 fun mk_ts (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) = mk_ts t
   141   | mk_ts (Abs(x,_,t)) = mk_ts t
   142   | mk_ts (Const (@{const_syntax Pair},_) $ a $ b) = a::(mk_ts b)
   143   | mk_ts t = [t];
   144 
   145 fun mk_vts (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) =
   146            ((Syntax.free x)::(abs2list t), mk_ts t)
   147   | mk_vts (Abs(x,_,t)) = ([Syntax.free x], [t])
   148   | mk_vts t = raise Match;
   149 
   150 fun find_ch [] i xs = (false, (Syntax.free "not_ch", Syntax.free "not_ch"))
   151   | find_ch ((v,t)::vts) i xs =
   152       if t = Bound i then find_ch vts (i-1) xs
   153       else (true, (v, subst_bounds (xs, t)));
   154 
   155 fun is_f (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) = true
   156   | is_f (Abs(x,_,t)) = true
   157   | is_f t = false;
   158 *}
   159 
   160 (* assn_tr' & bexp_tr'*)
   161 ML{*
   162 fun assn_tr' (Const (@{const_syntax Collect},_) $ T) = dest_abstuple T
   163   | assn_tr' (Const (@{const_syntax inter}, _) $
   164         (Const (@{const_syntax Collect},_) $ T1) $ (Const (@{const_syntax Collect},_) $ T2)) =
   165       Syntax.const @{const_syntax inter} $ dest_abstuple T1 $ dest_abstuple T2
   166   | assn_tr' t = t;
   167 
   168 fun bexp_tr' (Const (@{const_syntax Collect},_) $ T) = dest_abstuple T
   169   | bexp_tr' t = t;
   170 *}
   171 
   172 (*com_tr' *)
   173 ML{*
   174 fun mk_assign f =
   175   let val (vs, ts) = mk_vts f;
   176       val (ch, which) = find_ch (vs~~ts) ((length vs)-1) (rev vs)
   177   in
   178     if ch then Syntax.const @{syntax_const "_assign"} $ fst which $ snd which
   179     else Syntax.const @{const_syntax annskip}
   180   end;
   181 
   182 fun com_tr' (Const (@{const_syntax Basic},_) $ f) =
   183       if is_f f then mk_assign f
   184       else Syntax.const @{const_syntax Basic} $ f
   185   | com_tr' (Const (@{const_syntax Seq},_) $ c1 $ c2) =
   186       Syntax.const @{const_syntax Seq} $ com_tr' c1 $ com_tr' c2
   187   | com_tr' (Const (@{const_syntax Cond},_) $ b $ c1 $ c2) =
   188       Syntax.const @{const_syntax Cond} $ bexp_tr' b $ com_tr' c1 $ com_tr' c2
   189   | com_tr' (Const (@{const_syntax While},_) $ b $ I $ c) =
   190       Syntax.const @{const_syntax While} $ bexp_tr' b $ assn_tr' I $ com_tr' c
   191   | com_tr' t = t;
   192 
   193 fun spec_tr' [p, c, q] =
   194   Syntax.const @{syntax_const "_hoare"} $ assn_tr' p $ com_tr' c $ assn_tr' q
   195 *}
   196 
   197 print_translation {* [(@{const_syntax Valid}, spec_tr')] *}
   198 
   199 lemma SkipRule: "p \<subseteq> q \<Longrightarrow> Valid p (Basic id) q"
   200 by (auto simp:Valid_def)
   201 
   202 lemma BasicRule: "p \<subseteq> {s. f s \<in> q} \<Longrightarrow> Valid p (Basic f) q"
   203 by (auto simp:Valid_def)
   204 
   205 lemma SeqRule: "Valid P c1 Q \<Longrightarrow> Valid Q c2 R \<Longrightarrow> Valid P (c1;c2) R"
   206 by (auto simp:Valid_def)
   207 
   208 lemma CondRule:
   209  "p \<subseteq> {s. (s \<in> b \<longrightarrow> s \<in> w) \<and> (s \<notin> b \<longrightarrow> s \<in> w')}
   210   \<Longrightarrow> Valid w c1 q \<Longrightarrow> Valid w' c2 q \<Longrightarrow> Valid p (Cond b c1 c2) q"
   211 by (auto simp:Valid_def)
   212 
   213 lemma While_aux:
   214   assumes "Sem (WHILE b INV {i} DO c OD) s s'"
   215   shows "\<forall>s s'. Sem c s s' \<longrightarrow> s \<in> I \<and> s \<in> b \<longrightarrow> s' \<in> I \<Longrightarrow>
   216     s \<in> I \<Longrightarrow> s' \<in> I \<and> s' \<notin> b"
   217   using assms
   218   by (induct "WHILE b INV {i} DO c OD" s s') auto
   219 
   220 lemma WhileRule:
   221  "p \<subseteq> i \<Longrightarrow> Valid (i \<inter> b) c i \<Longrightarrow> i \<inter> (-b) \<subseteq> q \<Longrightarrow> Valid p (While b i c) q"
   222 apply (clarsimp simp:Valid_def)
   223 apply(drule While_aux)
   224   apply assumption
   225  apply blast
   226 apply blast
   227 done
   228 
   229 
   230 lemma Compl_Collect: "-(Collect b) = {x. ~(b x)}"
   231   by blast
   232 
   233 lemmas AbortRule = SkipRule  -- "dummy version"
   234 use "hoare_tac.ML"
   235 
   236 method_setup vcg = {*
   237   Scan.succeed (fn ctxt => SIMPLE_METHOD' (hoare_tac ctxt (K all_tac))) *}
   238   "verification condition generator"
   239 
   240 method_setup vcg_simp = {*
   241   Scan.succeed (fn ctxt =>
   242     SIMPLE_METHOD' (hoare_tac ctxt (asm_full_simp_tac (simpset_of ctxt)))) *}
   243   "verification condition generator plus simplification"
   244 
   245 end