src/HOL/Hoare/Hoare_Logic_Abort.thy
author hoelzl
Thu Sep 02 10:14:32 2010 +0200 (2010-09-02)
changeset 39072 1030b1a166ef
parent 37591 d3daea901123
child 41959 b460124855b8
permissions -rw-r--r--
Add lessThan_Suc_eq_insert_0
     1 (*  Title:      HOL/Hoare/HoareAbort.thy
     2     Author:     Leonor Prensa Nieto & Tobias Nipkow
     3     Copyright   2003 TUM
     4 
     5 Like Hoare.thy, but with an Abort statement for modelling run time errors.
     6 *)
     7 
     8 theory Hoare_Logic_Abort
     9 imports Main
    10 uses ("hoare_tac.ML")
    11 begin
    12 
    13 types
    14     'a bexp = "'a set"
    15     'a assn = "'a set"
    16 
    17 datatype
    18  'a com = Basic "'a \<Rightarrow> 'a"
    19    | Abort
    20    | Seq "'a com" "'a com"               ("(_;/ _)"      [61,60] 60)
    21    | Cond "'a bexp" "'a com" "'a com"    ("(1IF _/ THEN _ / ELSE _/ FI)"  [0,0,0] 61)
    22    | While "'a bexp" "'a assn" "'a com"  ("(1WHILE _/ INV {_} //DO _ /OD)"  [0,0,0] 61)
    23 
    24 abbreviation annskip ("SKIP") where "SKIP == Basic id"
    25 
    26 types 'a sem = "'a option => 'a option => bool"
    27 
    28 inductive Sem :: "'a com \<Rightarrow> 'a sem"
    29 where
    30   "Sem (Basic f) None None"
    31 | "Sem (Basic f) (Some s) (Some (f s))"
    32 | "Sem Abort s None"
    33 | "Sem c1 s s'' \<Longrightarrow> Sem c2 s'' s' \<Longrightarrow> Sem (c1;c2) s s'"
    34 | "Sem (IF b THEN c1 ELSE c2 FI) None None"
    35 | "s \<in> b \<Longrightarrow> Sem c1 (Some s) s' \<Longrightarrow> Sem (IF b THEN c1 ELSE c2 FI) (Some s) s'"
    36 | "s \<notin> b \<Longrightarrow> Sem c2 (Some s) s' \<Longrightarrow> Sem (IF b THEN c1 ELSE c2 FI) (Some s) s'"
    37 | "Sem (While b x c) None None"
    38 | "s \<notin> b \<Longrightarrow> Sem (While b x c) (Some s) (Some s)"
    39 | "s \<in> b \<Longrightarrow> Sem c (Some s) s'' \<Longrightarrow> Sem (While b x c) s'' s' \<Longrightarrow>
    40    Sem (While b x c) (Some s) s'"
    41 
    42 inductive_cases [elim!]:
    43   "Sem (Basic f) s s'" "Sem (c1;c2) s s'"
    44   "Sem (IF b THEN c1 ELSE c2 FI) s s'"
    45 
    46 definition Valid :: "'a bexp \<Rightarrow> 'a com \<Rightarrow> 'a bexp \<Rightarrow> bool" where
    47   "Valid p c q == \<forall>s s'. Sem c s s' \<longrightarrow> s : Some ` p \<longrightarrow> s' : Some ` q"
    48 
    49 
    50 
    51 (** parse translations **)
    52 
    53 syntax
    54   "_assign"  :: "id => 'b => 'a com"        ("(2_ :=/ _)" [70,65] 61)
    55 
    56 syntax
    57   "_hoare_abort_vars" :: "[idts, 'a assn,'a com,'a assn] => bool"
    58                  ("VARS _// {_} // _ // {_}" [0,0,55,0] 50)
    59 syntax ("" output)
    60   "_hoare_abort"      :: "['a assn,'a com,'a assn] => bool"
    61                  ("{_} // _ // {_}" [0,55,0] 50)
    62 ML {*
    63 
    64 local
    65 fun free a = Free(a,dummyT)
    66 fun abs((a,T),body) =
    67   let val a = absfree(a, dummyT, body)
    68   in if T = Bound 0 then a else Const(Syntax.constrainAbsC,dummyT) $ a $ T end
    69 in
    70 
    71 fun mk_abstuple [x] body = abs (x, body)
    72   | mk_abstuple (x::xs) body =
    73       Syntax.const @{const_syntax prod_case} $ abs (x, mk_abstuple xs body);
    74 
    75 fun mk_fbody a e [x as (b,_)] = if a=b then e else free b
    76   | mk_fbody a e ((b,_)::xs) =
    77       Syntax.const @{const_syntax Pair} $ (if a=b then e else free b) $ mk_fbody a e xs;
    78 
    79 fun mk_fexp a e xs = mk_abstuple xs (mk_fbody a e xs)
    80 end
    81 *}
    82 
    83 (* bexp_tr & assn_tr *)
    84 (*all meta-variables for bexp except for TRUE are translated as if they
    85   were boolean expressions*)
    86 ML{*
    87 fun bexp_tr (Const ("TRUE", _)) xs = Syntax.const "TRUE"   (* FIXME !? *)
    88   | bexp_tr b xs = Syntax.const @{const_syntax Collect} $ mk_abstuple xs b;
    89 
    90 fun assn_tr r xs = Syntax.const @{const_syntax Collect} $ mk_abstuple xs r;
    91 *}
    92 (* com_tr *)
    93 ML{*
    94 fun com_tr (Const (@{syntax_const "_assign"},_) $ Free (a,_) $ e) xs =
    95       Syntax.const @{const_syntax Basic} $ mk_fexp a e xs
    96   | com_tr (Const (@{const_syntax Basic},_) $ f) xs = Syntax.const @{const_syntax Basic} $ f
    97   | com_tr (Const (@{const_syntax Seq},_) $ c1 $ c2) xs =
    98       Syntax.const @{const_syntax Seq} $ com_tr c1 xs $ com_tr c2 xs
    99   | com_tr (Const (@{const_syntax Cond},_) $ b $ c1 $ c2) xs =
   100       Syntax.const @{const_syntax Cond} $ bexp_tr b xs $ com_tr c1 xs $ com_tr c2 xs
   101   | com_tr (Const (@{const_syntax While},_) $ b $ I $ c) xs =
   102       Syntax.const @{const_syntax While} $ bexp_tr b xs $ assn_tr I xs $ com_tr c xs
   103   | com_tr t _ = t (* if t is just a Free/Var *)
   104 *}
   105 
   106 (* triple_tr *)  (* FIXME does not handle "_idtdummy" *)
   107 ML{*
   108 local
   109 
   110 fun var_tr (Free (a, _)) = (a, Bound 0) (* Bound 0 = dummy term *)
   111   | var_tr (Const (@{syntax_const "_constrain"}, _) $ Free (a, _) $ T) = (a, T);
   112 
   113 fun vars_tr (Const (@{syntax_const "_idts"}, _) $ idt $ vars) = var_tr idt :: vars_tr vars
   114   | vars_tr t = [var_tr t]
   115 
   116 in
   117 fun hoare_vars_tr [vars, pre, prg, post] =
   118       let val xs = vars_tr vars
   119       in Syntax.const @{const_syntax Valid} $
   120          assn_tr pre xs $ com_tr prg xs $ assn_tr post xs
   121       end
   122   | hoare_vars_tr ts = raise TERM ("hoare_vars_tr", ts);
   123 end
   124 *}
   125 
   126 parse_translation {* [(@{syntax_const "_hoare_abort_vars"}, hoare_vars_tr)] *}
   127 
   128 
   129 (*****************************************************************************)
   130 
   131 (*** print translations ***)
   132 ML{*
   133 fun dest_abstuple (Const (@{const_syntax prod_case},_) $ (Abs(v,_, body))) =
   134       subst_bound (Syntax.free v, dest_abstuple body)
   135   | dest_abstuple (Abs(v,_, body)) = subst_bound (Syntax.free v, body)
   136   | dest_abstuple trm = trm;
   137 
   138 fun abs2list (Const (@{const_syntax prod_case},_) $ (Abs(x,T,t))) = Free (x, T)::abs2list t
   139   | abs2list (Abs(x,T,t)) = [Free (x, T)]
   140   | abs2list _ = [];
   141 
   142 fun mk_ts (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) = mk_ts t
   143   | mk_ts (Abs(x,_,t)) = mk_ts t
   144   | mk_ts (Const (@{const_syntax Pair},_) $ a $ b) = a::(mk_ts b)
   145   | mk_ts t = [t];
   146 
   147 fun mk_vts (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) =
   148            ((Syntax.free x)::(abs2list t), mk_ts t)
   149   | mk_vts (Abs(x,_,t)) = ([Syntax.free x], [t])
   150   | mk_vts t = raise Match;
   151 
   152 fun find_ch [] i xs = (false, (Syntax.free "not_ch", Syntax.free "not_ch"))
   153   | find_ch ((v,t)::vts) i xs =
   154       if t = Bound i then find_ch vts (i-1) xs
   155       else (true, (v, subst_bounds (xs,t)));
   156 
   157 fun is_f (Const (@{const_syntax prod_case},_) $ (Abs(x,_,t))) = true
   158   | is_f (Abs(x,_,t)) = true
   159   | is_f t = false;
   160 *}
   161 
   162 (* assn_tr' & bexp_tr'*)
   163 ML{*
   164 fun assn_tr' (Const (@{const_syntax Collect},_) $ T) = dest_abstuple T
   165   | assn_tr' (Const (@{const_syntax inter},_) $ (Const (@{const_syntax Collect},_) $ T1) $
   166         (Const (@{const_syntax Collect},_) $ T2)) =
   167       Syntax.const @{const_syntax inter} $ dest_abstuple T1 $ dest_abstuple T2
   168   | assn_tr' t = t;
   169 
   170 fun bexp_tr' (Const (@{const_syntax Collect},_) $ T) = dest_abstuple T
   171   | bexp_tr' t = t;
   172 *}
   173 
   174 (*com_tr' *)
   175 ML{*
   176 fun mk_assign f =
   177   let val (vs, ts) = mk_vts f;
   178       val (ch, which) = find_ch (vs~~ts) ((length vs)-1) (rev vs)
   179   in
   180     if ch then Syntax.const @{syntax_const "_assign"} $ fst which $ snd which
   181     else Syntax.const @{const_syntax annskip}
   182   end;
   183 
   184 fun com_tr' (Const (@{const_syntax Basic},_) $ f) =
   185       if is_f f then mk_assign f else Syntax.const @{const_syntax Basic} $ f
   186   | com_tr' (Const (@{const_syntax Seq},_) $ c1 $ c2) =
   187       Syntax.const @{const_syntax Seq} $ com_tr' c1 $ com_tr' c2
   188   | com_tr' (Const (@{const_syntax Cond},_) $ b $ c1 $ c2) =
   189       Syntax.const @{const_syntax Cond} $ bexp_tr' b $ com_tr' c1 $ com_tr' c2
   190   | com_tr' (Const (@{const_syntax While},_) $ b $ I $ c) =
   191       Syntax.const @{const_syntax While} $ bexp_tr' b $ assn_tr' I $ com_tr' c
   192   | com_tr' t = t;
   193 
   194 fun spec_tr' [p, c, q] =
   195   Syntax.const @{syntax_const "_hoare_abort"} $ assn_tr' p $ com_tr' c $ assn_tr' q
   196 *}
   197 
   198 print_translation {* [(@{const_syntax Valid}, spec_tr')] *}
   199 
   200 (*** The proof rules ***)
   201 
   202 lemma SkipRule: "p \<subseteq> q \<Longrightarrow> Valid p (Basic id) q"
   203 by (auto simp:Valid_def)
   204 
   205 lemma BasicRule: "p \<subseteq> {s. f s \<in> q} \<Longrightarrow> Valid p (Basic f) q"
   206 by (auto simp:Valid_def)
   207 
   208 lemma SeqRule: "Valid P c1 Q \<Longrightarrow> Valid Q c2 R \<Longrightarrow> Valid P (c1;c2) R"
   209 by (auto simp:Valid_def)
   210 
   211 lemma CondRule:
   212  "p \<subseteq> {s. (s \<in> b \<longrightarrow> s \<in> w) \<and> (s \<notin> b \<longrightarrow> s \<in> w')}
   213   \<Longrightarrow> Valid w c1 q \<Longrightarrow> Valid w' c2 q \<Longrightarrow> Valid p (Cond b c1 c2) q"
   214 by (fastsimp simp:Valid_def image_def)
   215 
   216 lemma While_aux:
   217   assumes "Sem (WHILE b INV {i} DO c OD) s s'"
   218   shows "\<forall>s s'. Sem c s s' \<longrightarrow> s \<in> Some ` (I \<inter> b) \<longrightarrow> s' \<in> Some ` I \<Longrightarrow>
   219     s \<in> Some ` I \<Longrightarrow> s' \<in> Some ` (I \<inter> -b)"
   220   using assms
   221   by (induct "WHILE b INV {i} DO c OD" s s') auto
   222 
   223 lemma WhileRule:
   224  "p \<subseteq> i \<Longrightarrow> Valid (i \<inter> b) c i \<Longrightarrow> i \<inter> (-b) \<subseteq> q \<Longrightarrow> Valid p (While b i c) q"
   225 apply(simp add:Valid_def)
   226 apply(simp (no_asm) add:image_def)
   227 apply clarify
   228 apply(drule While_aux)
   229   apply assumption
   230  apply blast
   231 apply blast
   232 done
   233 
   234 lemma AbortRule: "p \<subseteq> {s. False} \<Longrightarrow> Valid p Abort q"
   235 by(auto simp:Valid_def)
   236 
   237 
   238 subsection {* Derivation of the proof rules and, most importantly, the VCG tactic *}
   239 
   240 lemma Compl_Collect: "-(Collect b) = {x. ~(b x)}"
   241   by blast
   242 
   243 use "hoare_tac.ML"
   244 
   245 method_setup vcg = {*
   246   Scan.succeed (fn ctxt => SIMPLE_METHOD' (hoare_tac ctxt (K all_tac))) *}
   247   "verification condition generator"
   248 
   249 method_setup vcg_simp = {*
   250   Scan.succeed (fn ctxt =>
   251     SIMPLE_METHOD' (hoare_tac ctxt (asm_full_simp_tac (simpset_of ctxt)))) *}
   252   "verification condition generator plus simplification"
   253 
   254 (* Special syntax for guarded statements and guarded array updates: *)
   255 
   256 syntax
   257   "_guarded_com" :: "bool \<Rightarrow> 'a com \<Rightarrow> 'a com"  ("(2_ \<rightarrow>/ _)" 71)
   258   "_array_update" :: "'a list \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a com"  ("(2_[_] :=/ _)" [70, 65] 61)
   259 translations
   260   "P \<rightarrow> c" == "IF P THEN c ELSE CONST Abort FI"
   261   "a[i] := v" => "(i < CONST length a) \<rightarrow> (a := CONST list_update a i v)"
   262   (* reverse translation not possible because of duplicate "a" *)
   263 
   264 text{* Note: there is no special syntax for guarded array access. Thus
   265 you must write @{text"j < length a \<rightarrow> a[i] := a!j"}. *}
   266 
   267 end