src/Pure/tctical.ML
author skalberg
Fri Jun 25 14:30:55 2004 +0200 (2004-06-25)
changeset 15006 107e4dfd3b96
parent 13664 cfe1dc32c2e5
child 15017 9ad392226da5
permissions -rw-r--r--
Merging the meta-simplifier with the Provers-simplifier. Next step:
make the simplification procedure simpset-aware.
     1 (*  Title:      tctical
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 
    14 signature TACTICAL =
    15 sig
    16   type tactic  (* = thm -> thm Seq.seq*)
    17   val all_tac           : tactic
    18   val ALLGOALS          : (int -> tactic) -> tactic
    19   val APPEND            : tactic * tactic -> tactic
    20   val APPEND'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val CHANGED           : tactic -> tactic
    22   val CHANGED_PROP      : tactic -> tactic
    23   val CHANGED_GOAL      : (int -> tactic) -> int -> tactic
    24   val COND              : (thm -> bool) -> tactic -> tactic -> tactic
    25   val DETERM            : tactic -> tactic
    26   val EVERY             : tactic list -> tactic
    27   val EVERY'            : ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1            : (int -> tactic) list -> tactic
    29   val FILTER            : (thm -> bool) -> tactic -> tactic
    30   val FIRST             : tactic list -> tactic
    31   val FIRST'            : ('a -> tactic) list -> 'a -> tactic
    32   val FIRST1            : (int -> tactic) list -> tactic
    33   val FIRSTGOAL         : (int -> tactic) -> tactic
    34   val INTLEAVE          : tactic * tactic -> tactic
    35   val INTLEAVE'         : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    36   val METAHYPS          : (thm list -> tactic) -> int -> tactic
    37   val no_tac            : tactic
    38   val ORELSE            : tactic * tactic -> tactic
    39   val ORELSE'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    40   val pause_tac         : tactic
    41   val print_tac         : string -> tactic
    42   val PRIMITIVE         : (thm -> thm) -> tactic
    43   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    44   val RANGE             : (int -> tactic) list -> int -> tactic
    45   val REPEAT            : tactic -> tactic
    46   val REPEAT1           : tactic -> tactic
    47   val REPEAT_FIRST      : (int -> tactic) -> tactic
    48   val REPEAT_SOME       : (int -> tactic) -> tactic
    49   val REPEAT_DETERM_N   : int -> tactic -> tactic
    50   val REPEAT_DETERM     : tactic -> tactic
    51   val REPEAT_DETERM1    : tactic -> tactic
    52   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    53   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    54   val DETERM_UNTIL      : (thm -> bool) -> tactic -> tactic
    55   val SELECT_GOAL       : tactic -> int -> tactic
    56   val SINGLE            : tactic -> thm -> thm option
    57   val SOMEGOAL          : (int -> tactic) -> tactic
    58   val strip_context     : term -> (string * typ) list * term list * term
    59   val SUBGOAL           : ((term*int) -> tactic) -> int -> tactic
    60   val suppress_tracing  : bool ref
    61   val THEN              : tactic * tactic -> tactic
    62   val THEN'             : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    63   val THEN_ALL_NEW      : (int -> tactic) * (int -> tactic) -> int -> tactic
    64   val REPEAT_ALL_NEW    : (int -> tactic) -> int -> tactic
    65   val THEN_ELSE         : tactic * (tactic*tactic) -> tactic
    66   val traced_tac        : (thm -> (thm * thm Seq.seq) option) -> tactic
    67   val tracify           : bool ref -> tactic -> tactic
    68   val trace_REPEAT      : bool ref
    69   val TRY               : tactic -> tactic
    70   val TRYALL            : (int -> tactic) -> tactic
    71 end;
    72 
    73 
    74 structure Tactical : TACTICAL =
    75 struct
    76 
    77 (**** Tactics ****)
    78 
    79 (*A tactic maps a proof tree to a sequence of proof trees:
    80     if length of sequence = 0 then the tactic does not apply;
    81     if length > 1 then backtracking on the alternatives can occur.*)
    82 
    83 type tactic = thm -> thm Seq.seq;
    84 
    85 
    86 (*** LCF-style tacticals ***)
    87 
    88 (*the tactical THEN performs one tactic followed by another*)
    89 fun (tac1 THEN tac2) st = Seq.flat (Seq.map tac2 (tac1 st));
    90 
    91 
    92 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    93   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    94   Does not backtrack to tac2 if tac1 was initially chosen. *)
    95 fun (tac1 ORELSE tac2) st =
    96     case Seq.pull(tac1 st) of
    97         None       => tac2 st
    98       | sequencecell => Seq.make(fn()=> sequencecell);
    99 
   100 
   101 (*The tactical APPEND combines the results of two tactics.
   102   Like ORELSE, but allows backtracking on both tac1 and tac2.
   103   The tactic tac2 is not applied until needed.*)
   104 fun (tac1 APPEND tac2) st =
   105   Seq.append(tac1 st,
   106                   Seq.make(fn()=> Seq.pull (tac2 st)));
   107 
   108 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   109 fun (tac1 INTLEAVE tac2) st =
   110     Seq.interleave(tac1 st,
   111                         Seq.make(fn()=> Seq.pull (tac2 st)));
   112 
   113 (*Conditional tactic.
   114         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   115         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   116 *)
   117 fun (tac THEN_ELSE (tac1, tac2)) st =
   118     case Seq.pull(tac st) of
   119         None    => tac2 st              (*failed; try tactic 2*)
   120       | seqcell => Seq.flat       (*succeeded; use tactic 1*)
   121                     (Seq.map tac1 (Seq.make(fn()=> seqcell)));
   122 
   123 
   124 (*Versions for combining tactic-valued functions, as in
   125      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   126 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   127 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   128 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   129 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   130 
   131 (*passes all proofs through unchanged;  identity of THEN*)
   132 fun all_tac st = Seq.single st;
   133 
   134 (*passes no proofs through;  identity of ORELSE and APPEND*)
   135 fun no_tac st  = Seq.empty;
   136 
   137 
   138 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   139 fun DETERM tac = Seq.DETERM tac;
   140 
   141 (*Conditional tactical: testfun controls which tactic to use next.
   142   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   143 fun COND testfun thenf elsef = (fn prf =>
   144     if testfun prf then  thenf prf   else  elsef prf);
   145 
   146 (*Do the tactic or else do nothing*)
   147 fun TRY tac = tac ORELSE all_tac;
   148 
   149 (*** List-oriented tactics ***)
   150 
   151 local
   152   (*This version of EVERY avoids backtracking over repeated states*)
   153 
   154   fun EVY (trail, []) st =
   155         Seq.make (fn()=> Some(st,
   156                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   157     | EVY (trail, tac::tacs) st =
   158           case Seq.pull(tac st) of
   159               None    => evyBack trail              (*failed: backtrack*)
   160             | Some(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   161   and evyBack [] = Seq.empty (*no alternatives*)
   162     | evyBack ((st',q,tacs)::trail) =
   163           case Seq.pull q of
   164               None        => evyBack trail
   165             | Some(st,q') => if eq_thm (st',st)
   166                              then evyBack ((st',q',tacs)::trail)
   167                              else EVY ((st,q',tacs)::trail, tacs) st
   168 in
   169 
   170 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   171 fun EVERY tacs = EVY ([], tacs);
   172 end;
   173 
   174 
   175 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   176 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   177 
   178 (*Apply every tactic to 1*)
   179 fun EVERY1 tacs = EVERY' tacs 1;
   180 
   181 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   182 fun FIRST tacs = foldr (op ORELSE) (tacs, no_tac);
   183 
   184 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   185 fun FIRST' tacs = foldr (op ORELSE') (tacs, K no_tac);
   186 
   187 (*Apply first tactic to 1*)
   188 fun FIRST1 tacs = FIRST' tacs 1;
   189 
   190 (*Apply tactics on consecutive subgoals*)
   191 fun RANGE [] _ = all_tac
   192   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   193 
   194 
   195 (*** Tracing tactics ***)
   196 
   197 (*Print the current proof state and pass it on.*)
   198 fun print_tac msg =
   199     (fn st =>
   200      (tracing msg;
   201       Display.print_goals (! Display.goals_limit) st; Seq.single st));
   202 
   203 (*Pause until a line is typed -- if non-empty then fail. *)
   204 fun pause_tac st =
   205   (tracing "** Press RETURN to continue:";
   206    if TextIO.inputLine TextIO.stdIn = "\n" then Seq.single st
   207    else (tracing "Goodbye";  Seq.empty));
   208 
   209 exception TRACE_EXIT of thm
   210 and TRACE_QUIT;
   211 
   212 (*Tracing flags*)
   213 val trace_REPEAT= ref false
   214 and suppress_tracing = ref false;
   215 
   216 (*Handle all tracing commands for current state and tactic *)
   217 fun exec_trace_command flag (tac, st) =
   218    case TextIO.inputLine(TextIO.stdIn) of
   219        "\n" => tac st
   220      | "f\n" => Seq.empty
   221      | "o\n" => (flag:=false;  tac st)
   222      | "s\n" => (suppress_tracing:=true;  tac st)
   223      | "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   224      | "quit\n" => raise TRACE_QUIT
   225      | _     => (tracing
   226 "Type RETURN to continue or...\n\
   227 \     f    - to fail here\n\
   228 \     o    - to switch tracing off\n\
   229 \     s    - to suppress tracing until next entry to a tactical\n\
   230 \     x    - to exit at this point\n\
   231 \     quit - to abort this tracing run\n\
   232 \** Well? "     ;  exec_trace_command flag (tac, st));
   233 
   234 
   235 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   236 fun tracify flag tac st =
   237   if !flag andalso not (!suppress_tracing)
   238            then (Display.print_goals (! Display.goals_limit) st;
   239                  tracing "** Press RETURN to continue:";
   240                  exec_trace_command flag (tac,st))
   241   else tac st;
   242 
   243 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   244 fun traced_tac seqf st =
   245     (suppress_tracing := false;
   246      Seq.make (fn()=> seqf st
   247                          handle TRACE_EXIT st' => Some(st', Seq.empty)));
   248 
   249 
   250 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   251   Forces repitition until predicate on state is fulfilled.*)
   252 fun DETERM_UNTIL p tac =
   253 let val tac = tracify trace_REPEAT tac
   254     fun drep st = if p st then Some (st, Seq.empty)
   255                           else (case Seq.pull(tac st) of
   256                                   None        => None
   257                                 | Some(st',_) => drep st')
   258 in  traced_tac drep  end;
   259 
   260 (*Deterministic REPEAT: only retains the first outcome;
   261   uses less space than REPEAT; tail recursive.
   262   If non-negative, n bounds the number of repetitions.*)
   263 fun REPEAT_DETERM_N n tac =
   264   let val tac = tracify trace_REPEAT tac
   265       fun drep 0 st = Some(st, Seq.empty)
   266         | drep n st =
   267            (case Seq.pull(tac st) of
   268                 None       => Some(st, Seq.empty)
   269               | Some(st',_) => drep (n-1) st')
   270   in  traced_tac (drep n)  end;
   271 
   272 (*Allows any number of repetitions*)
   273 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   274 
   275 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   276 fun REPEAT tac =
   277   let val tac = tracify trace_REPEAT tac
   278       fun rep qs st =
   279         case Seq.pull(tac st) of
   280             None       => Some(st, Seq.make(fn()=> repq qs))
   281           | Some(st',q) => rep (q::qs) st'
   282       and repq [] = None
   283         | repq(q::qs) = case Seq.pull q of
   284             None       => repq qs
   285           | Some(st,q) => rep (q::qs) st
   286   in  traced_tac (rep [])  end;
   287 
   288 (*Repeat 1 or more times*)
   289 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   290 fun REPEAT1 tac = tac THEN REPEAT tac;
   291 
   292 
   293 (** Filtering tacticals **)
   294 
   295 fun FILTER pred tac st = Seq.filter pred (tac st);
   296 
   297 (*Accept only next states that change the theorem somehow*)
   298 fun CHANGED tac st =
   299   let fun diff st' = not (Thm.eq_thm (st, st'));
   300   in Seq.filter diff (tac st) end;
   301 
   302 (*Accept only next states that change the theorem's prop field
   303   (changes to signature, hyps, etc. don't count)*)
   304 fun CHANGED_PROP tac st =
   305   let fun diff st' = not (Drule.eq_thm_prop (st, st'));
   306   in Seq.filter diff (tac st) end;
   307 
   308 
   309 (*** Tacticals based on subgoal numbering ***)
   310 
   311 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   312   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   313 fun ALLGOALS tac st =
   314   let fun doall 0 = all_tac
   315         | doall n = tac(n) THEN doall(n-1)
   316   in  doall(nprems_of st)st  end;
   317 
   318 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   319 fun SOMEGOAL tac st =
   320   let fun find 0 = no_tac
   321         | find n = tac(n) ORELSE find(n-1)
   322   in  find(nprems_of st)st  end;
   323 
   324 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   325   More appropriate than SOMEGOAL in some cases.*)
   326 fun FIRSTGOAL tac st =
   327   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   328   in  find(1, nprems_of st)st  end;
   329 
   330 (*Repeatedly solve some using tac. *)
   331 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   332 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   333 
   334 (*Repeatedly solve the first possible subgoal using tac. *)
   335 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   336 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   337 
   338 (*For n subgoals, tries to apply tac to n,...1  *)
   339 fun TRYALL tac = ALLGOALS (TRY o tac);
   340 
   341 
   342 (*Make a tactic for subgoal i, if there is one.  *)
   343 fun SUBGOAL goalfun i st = goalfun (List.nth(prems_of st, i-1),  i) st
   344                              handle Subscript => Seq.empty;
   345 
   346 (*Returns all states that have changed in subgoal i, counted from the LAST
   347   subgoal.  For stac, for example.*)
   348 fun CHANGED_GOAL tac i st =
   349     let val np = nprems_of st
   350         val d = np-i                 (*distance from END*)
   351         val t = List.nth(prems_of st, i-1)
   352         fun diff st' =
   353             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   354             orelse
   355              not (Pattern.aeconv (t,
   356                                   List.nth(prems_of st',
   357                                            nprems_of st' - d - 1)))
   358     in  Seq.filter diff (tac i st)  end
   359     handle Subscript => Seq.empty  (*no subgoal i*);
   360 
   361 fun (tac1 THEN_ALL_NEW tac2) i st =
   362   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   363 
   364 (*repeatedly dig into any emerging subgoals*)
   365 fun REPEAT_ALL_NEW tac =
   366   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   367 
   368 
   369 (*** SELECT_GOAL ***)
   370 
   371 (*Tactical for restricting the effect of a tactic to subgoal i.
   372   Works by making a new state from subgoal i, applying tac to it, and
   373   composing the resulting metathm with the original state.*)
   374 
   375 (*Does the work of SELECT_GOAL. *)
   376 fun select tac st i =
   377   let
   378     val thm = Drule.mk_triv_goal (adjust_maxidx (List.nth (cprems_of st, i-1)));
   379     fun restore th = Seq.hd (bicompose false (false, th, nprems_of th) 1
   380       (Thm.incr_indexes (#maxidx (rep_thm th) + 1) Drule.rev_triv_goal));
   381     fun next st' = bicompose false (false, restore st', nprems_of st') i st;
   382   in  Seq.flat (Seq.map next (tac thm))
   383   end;
   384 
   385 fun SELECT_GOAL tac i st =
   386   let val np = nprems_of st
   387   in  if 1<=i andalso i<=np then
   388           (*If only one subgoal, then just apply tactic*)
   389           if np=1 then tac st else select tac st i
   390       else Seq.empty
   391   end;
   392 
   393 
   394 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   395     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   396   Main difference from strip_assums concerns parameters:
   397     it replaces the bound variables by free variables.  *)
   398 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   399         strip_context_aux (params, H::Hs, B)
   400   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   401         let val (b,u) = variant_abs(a,T,t)
   402         in  strip_context_aux ((b,T)::params, Hs, u)  end
   403   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   404 
   405 fun strip_context A = strip_context_aux ([],[],A);
   406 
   407 
   408 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   409        METAHYPS (fn prems => tac prems) i
   410 
   411 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   412 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   413 "prems").  The parameters x1,...,xm become free variables.  If the
   414 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   415 then it is lifted back into the original context, yielding k subgoals.
   416 
   417 Replaces unknowns in the context by Frees having the prefix METAHYP_
   418 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   419 DOES NOT HANDLE TYPE UNKNOWNS.
   420 ****)
   421 
   422 local
   423 
   424   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   425     Instantiates distinct free variables by terms of same type.*)
   426   fun free_instantiate ctpairs =
   427       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   428 
   429   fun free_of s ((a,i), T) =
   430         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   431              T)
   432 
   433   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   434 in
   435 
   436 fun metahyps_aux_tac tacf (prem,i) state =
   437   let val {sign,maxidx,...} = rep_thm state
   438       val cterm = cterm_of sign
   439       (*find all vars in the hyps -- should find tvars also!*)
   440       val hyps_vars = foldr add_term_vars (Logic.strip_assums_hyp prem, [])
   441       val insts = map mk_inst hyps_vars
   442       (*replace the hyps_vars by Frees*)
   443       val prem' = subst_atomic insts prem
   444       val (params,hyps,concl) = strip_context prem'
   445       val fparams = map Free params
   446       val cparams = map cterm fparams
   447       and chyps = map cterm hyps
   448       val hypths = map assume chyps
   449       fun swap_ctpair (t,u) = (cterm u, cterm t)
   450       (*Subgoal variables: make Free; lift type over params*)
   451       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   452           if var mem concl_vars
   453           then (var, true, free_of "METAHYP2_" (v,T))
   454           else (var, false,
   455                 free_of "METAHYP2_" (v, map #2 params --->T))
   456       (*Instantiate subgoal vars by Free applied to params*)
   457       fun mk_ctpair (t,in_concl,u) =
   458           if in_concl then (cterm t,  cterm u)
   459           else (cterm t,  cterm (list_comb (u,fparams)))
   460       (*Restore Vars with higher type and index*)
   461       fun mk_subgoal_swap_ctpair
   462                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   463           if in_concl then (cterm u, cterm t)
   464           else (cterm u, cterm(Var((a, i+maxidx), U)))
   465       (*Embed B in the original context of params and hyps*)
   466       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   467       (*Strip the context using elimination rules*)
   468       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   469       (*A form of lifting that discharges assumptions.*)
   470       fun relift st =
   471         let val prop = #prop(rep_thm st)
   472             val subgoal_vars = (*Vars introduced in the subgoals*)
   473                   foldr add_term_vars (Logic.strip_imp_prems prop, [])
   474             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   475             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   476             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   477             val emBs = map (cterm o embed) (prems_of st')
   478             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   479         in  (*restore the unknowns to the hypotheses*)
   480             free_instantiate (map swap_ctpair insts @
   481                               map mk_subgoal_swap_ctpair subgoal_insts)
   482                 (*discharge assumptions from state in same order*)
   483                 (implies_intr_list emBs
   484                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   485         end
   486       val subprems = map (forall_elim_vars 0) hypths
   487       and st0 = trivial (cterm concl)
   488       (*function to replace the current subgoal*)
   489       fun next st = bicompose false (false, relift st, nprems_of st)
   490                     i state
   491   in  Seq.flat (Seq.map next (tacf subprems st0))
   492   end;
   493 end;
   494 
   495 fun METAHYPS tacf = SUBGOAL (metahyps_aux_tac tacf);
   496 
   497 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   498 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   499 
   500 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   501 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   502 
   503 (* Inverse (more or less) of PRIMITIVE *)
   504 fun SINGLE tacf = apsome fst o Seq.pull o tacf
   505 		  
   506 end;
   507 
   508 open Tactical;