src/HOL/Nitpick.thy
author haftmann
Fri Feb 05 14:33:50 2010 +0100 (2010-02-05)
changeset 35028 108662d50512
parent 34982 7b8c366e34a2
child 35079 592edca1dfb3
permissions -rw-r--r--
more consistent naming of type classes involving orderings (and lattices) -- c.f. NEWS
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map SAT
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_mono.ML")
    17      ("Tools/Nitpick/nitpick_scope.ML")
    18      ("Tools/Nitpick/nitpick_peephole.ML")
    19      ("Tools/Nitpick/nitpick_rep.ML")
    20      ("Tools/Nitpick/nitpick_nut.ML")
    21      ("Tools/Nitpick/nitpick_kodkod.ML")
    22      ("Tools/Nitpick/nitpick_model.ML")
    23      ("Tools/Nitpick/nitpick.ML")
    24      ("Tools/Nitpick/nitpick_isar.ML")
    25      ("Tools/Nitpick/nitpick_tests.ML")
    26      ("Tools/Nitpick/minipick.ML")
    27 begin
    28 
    29 typedecl bisim_iterator
    30 
    31 axiomatization unknown :: 'a
    32            and is_unknown :: "'a \<Rightarrow> bool"
    33            and undefined_fast_The :: 'a
    34            and undefined_fast_Eps :: 'a
    35            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    36            and bisim_iterator_max :: bisim_iterator
    37            and Quot :: "'a \<Rightarrow> 'b"
    38            and quot_normal :: "'a \<Rightarrow> 'a"
    39            and NonStd :: "'a \<Rightarrow> 'b"
    40            and Tha :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    41 
    42 datatype ('a, 'b) pair_box = PairBox 'a 'b
    43 datatype ('a, 'b) fun_box = FunBox "('a \<Rightarrow> 'b)"
    44 
    45 typedecl unsigned_bit
    46 typedecl signed_bit
    47 typedecl \<xi>
    48 
    49 datatype 'a word = Word "('a set)"
    50 
    51 text {*
    52 Alternative definitions.
    53 *}
    54 
    55 lemma If_def [nitpick_def]:
    56 "(if P then Q else R) \<equiv> (P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R)"
    57 by (rule eq_reflection) (rule if_bool_eq_conj)
    58 
    59 lemma Ex1_def [nitpick_def]:
    60 "Ex1 P \<equiv> \<exists>x. P = {x}"
    61 apply (rule eq_reflection)
    62 apply (simp add: Ex1_def expand_set_eq)
    63 apply (rule iffI)
    64  apply (erule exE)
    65  apply (erule conjE)
    66  apply (rule_tac x = x in exI)
    67  apply (rule allI)
    68  apply (rename_tac y)
    69  apply (erule_tac x = y in allE)
    70 by (auto simp: mem_def)
    71 
    72 lemma rtrancl_def [nitpick_def]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    73 by simp
    74 
    75 lemma rtranclp_def [nitpick_def]:
    76 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    77 by (rule eq_reflection) (auto dest: rtranclpD)
    78 
    79 lemma tranclp_def [nitpick_def]:
    80 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    81 by (simp add: trancl_def Collect_def mem_def)
    82 
    83 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    84 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    85 
    86 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    87 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    88 
    89 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    90 
    91 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    92 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    93 
    94 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    95 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    96                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    97 
    98 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    99 "card' X \<equiv> length (SOME xs. set xs = X \<and> distinct xs)"
   100 
   101 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
   102 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
   103 
   104 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
   105 "fold_graph' f z {} z" |
   106 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
   107 
   108 text {*
   109 The following lemmas are not strictly necessary but they help the
   110 \textit{special\_level} optimization.
   111 *}
   112 
   113 lemma The_psimp [nitpick_psimp]:
   114 "P = {x} \<Longrightarrow> The P = x"
   115 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   116 
   117 lemma Eps_psimp [nitpick_psimp]:
   118 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   119 apply (case_tac "P (Eps P)")
   120  apply auto
   121 apply (erule contrapos_np)
   122 by (rule someI)
   123 
   124 lemma unit_case_def [nitpick_def]:
   125 "unit_case x u \<equiv> x"
   126 apply (subgoal_tac "u = ()")
   127  apply (simp only: unit.cases)
   128 by simp
   129 
   130 declare unit.cases [nitpick_simp del]
   131 
   132 lemma nat_case_def [nitpick_def]:
   133 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   134 apply (rule eq_reflection)
   135 by (case_tac n) auto
   136 
   137 declare nat.cases [nitpick_simp del]
   138 
   139 lemma list_size_simp [nitpick_simp]:
   140 "list_size f xs = (if xs = [] then 0
   141                    else Suc (f (hd xs) + list_size f (tl xs)))"
   142 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   143 by (case_tac xs) auto
   144 
   145 text {*
   146 Auxiliary definitions used to provide an alternative representation for
   147 @{text rat} and @{text real}.
   148 *}
   149 
   150 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   151 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   152 by auto
   153 termination
   154 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   155  apply auto
   156  apply (metis mod_less_divisor xt1(9))
   157 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   158 
   159 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   160 "nat_lcm x y = x * y div (nat_gcd x y)"
   161 
   162 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   163 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   164 
   165 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   166 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   167 
   168 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   169 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   170 
   171 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   172            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   173 
   174 definition zero_frac :: 'a where
   175 "zero_frac \<equiv> Abs_Frac (0, 1)"
   176 
   177 definition one_frac :: 'a where
   178 "one_frac \<equiv> Abs_Frac (1, 1)"
   179 
   180 definition num :: "'a \<Rightarrow> int" where
   181 "num \<equiv> fst o Rep_Frac"
   182 
   183 definition denom :: "'a \<Rightarrow> int" where
   184 "denom \<equiv> snd o Rep_Frac"
   185 
   186 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   187 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   188                               else if a = 0 \<or> b = 0 then (0, 1)
   189                               else let c = int_gcd a b in (a div c, b div c))"
   190 by pat_completeness auto
   191 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   192 
   193 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   194 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   195 
   196 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   197 [nitpick_simp]:
   198 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   199                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   200 
   201 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   202 [nitpick_simp]:
   203 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   204 
   205 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   206 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   207 
   208 definition number_of_frac :: "int \<Rightarrow> 'a" where
   209 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   210 
   211 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   212 "inverse_frac q \<equiv> frac (denom q) (num q)"
   213 
   214 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   215 [nitpick_simp]:
   216 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   217 
   218 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   219 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   220 
   221 (* While Nitpick normally avoids to unfold definitions for locales, it
   222    unfortunately needs to unfold them when dealing with the following built-in
   223    constants. A cleaner approach would be to change "Nitpick_HOL" and
   224    "Nitpick_Nut" so that they handle the unexpanded overloaded constants
   225    directly, but this is slightly more tricky to implement. *)
   226 lemmas [nitpick_def] = div_int_inst.div_int div_int_inst.mod_int
   227     div_nat_inst.div_nat div_nat_inst.mod_nat semilattice_inf_fun_inst.inf_fun
   228     minus_fun_inst.minus_fun minus_int_inst.minus_int minus_nat_inst.minus_nat
   229     one_int_inst.one_int one_nat_inst.one_nat ord_fun_inst.less_eq_fun
   230     ord_int_inst.less_eq_int ord_int_inst.less_int ord_nat_inst.less_eq_nat
   231     ord_nat_inst.less_nat plus_int_inst.plus_int plus_nat_inst.plus_nat
   232     times_int_inst.times_int times_nat_inst.times_nat uminus_int_inst.uminus_int
   233     semilattice_sup_fun_inst.sup_fun zero_int_inst.zero_int
   234     zero_nat_inst.zero_nat
   235 
   236 use "Tools/Nitpick/kodkod.ML"
   237 use "Tools/Nitpick/kodkod_sat.ML"
   238 use "Tools/Nitpick/nitpick_util.ML"
   239 use "Tools/Nitpick/nitpick_hol.ML"
   240 use "Tools/Nitpick/nitpick_mono.ML"
   241 use "Tools/Nitpick/nitpick_scope.ML"
   242 use "Tools/Nitpick/nitpick_peephole.ML"
   243 use "Tools/Nitpick/nitpick_rep.ML"
   244 use "Tools/Nitpick/nitpick_nut.ML"
   245 use "Tools/Nitpick/nitpick_kodkod.ML"
   246 use "Tools/Nitpick/nitpick_model.ML"
   247 use "Tools/Nitpick/nitpick.ML"
   248 use "Tools/Nitpick/nitpick_isar.ML"
   249 use "Tools/Nitpick/nitpick_tests.ML"
   250 use "Tools/Nitpick/minipick.ML"
   251 
   252 setup {* Nitpick_Isar.setup *}
   253 
   254 hide (open) const unknown is_unknown undefined_fast_The undefined_fast_Eps bisim 
   255     bisim_iterator_max Quot quot_normal NonStd Tha PairBox FunBox Word refl' wf'
   256     wf_wfrec wf_wfrec' wfrec' card' setsum' fold_graph' nat_gcd nat_lcm int_gcd
   257     int_lcm Frac Abs_Frac Rep_Frac zero_frac one_frac num denom norm_frac frac
   258     plus_frac times_frac uminus_frac number_of_frac inverse_frac less_eq_frac
   259     of_frac
   260 hide (open) type bisim_iterator pair_box fun_box unsigned_bit signed_bit \<xi> word
   261 hide (open) fact If_def Ex1_def rtrancl_def rtranclp_def tranclp_def refl'_def
   262     wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def fold_graph'_def
   263     The_psimp Eps_psimp unit_case_def nat_case_def list_size_simp nat_gcd_def
   264     nat_lcm_def int_gcd_def int_lcm_def Frac_def zero_frac_def one_frac_def
   265     num_def denom_def norm_frac_def frac_def plus_frac_def times_frac_def
   266     uminus_frac_def number_of_frac_def inverse_frac_def less_eq_frac_def
   267     of_frac_def
   268 
   269 end