src/ZF/ZF.thy
author wenzelm
Tue Jul 31 19:40:22 2007 +0200 (2007-07-31)
changeset 24091 109f19a13872
parent 23168 fcdd4346fa6b
child 24826 78e6a3cea367
permissions -rw-r--r--
added Tools/lin_arith.ML;
     1 (*  Title:      ZF/ZF.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Martin D Coen, CU Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 *)
     6 
     7 header{*Zermelo-Fraenkel Set Theory*}
     8 
     9 theory ZF imports FOL begin
    10 
    11 ML {* reset eta_contract *}
    12 
    13 global
    14 
    15 typedecl i
    16 arities  i :: "term"
    17 
    18 consts
    19 
    20   "0"         :: "i"                  ("0")   --{*the empty set*}
    21   Pow         :: "i => i"                     --{*power sets*}
    22   Inf         :: "i"                          --{*infinite set*}
    23 
    24 text {*Bounded Quantifiers *}
    25 consts
    26   Ball   :: "[i, i => o] => o"
    27   Bex   :: "[i, i => o] => o"
    28 
    29 text {*General Union and Intersection *}
    30 consts
    31   Union :: "i => i"
    32   Inter :: "i => i"
    33 
    34 text {*Variations on Replacement *}
    35 consts
    36   PrimReplace :: "[i, [i, i] => o] => i"
    37   Replace     :: "[i, [i, i] => o] => i"
    38   RepFun      :: "[i, i => i] => i"
    39   Collect     :: "[i, i => o] => i"
    40 
    41 text{*Definite descriptions -- via Replace over the set "1"*}
    42 consts
    43   The         :: "(i => o) => i"      (binder "THE " 10)
    44   If          :: "[o, i, i] => i"     ("(if (_)/ then (_)/ else (_))" [10] 10)
    45 
    46 syntax
    47   old_if      :: "[o, i, i] => i"   ("if '(_,_,_')")
    48 
    49 translations
    50   "if(P,a,b)" => "If(P,a,b)"
    51 
    52 
    53 text {*Finite Sets *}
    54 consts
    55   Upair :: "[i, i] => i"
    56   cons  :: "[i, i] => i"
    57   succ  :: "i => i"
    58 
    59 text {*Ordered Pairing *}
    60 consts
    61   Pair  :: "[i, i] => i"
    62   fst   :: "i => i"
    63   snd   :: "i => i"
    64   split :: "[[i, i] => 'a, i] => 'a::{}"  --{*for pattern-matching*}
    65 
    66 text {*Sigma and Pi Operators *}
    67 consts
    68   Sigma :: "[i, i => i] => i"
    69   Pi    :: "[i, i => i] => i"
    70 
    71 text {*Relations and Functions *}
    72 consts
    73   "domain"    :: "i => i"
    74   range       :: "i => i"
    75   field       :: "i => i"
    76   converse    :: "i => i"
    77   relation    :: "i => o"        --{*recognizes sets of pairs*}
    78   function    :: "i => o"        --{*recognizes functions; can have non-pairs*}
    79   Lambda      :: "[i, i => i] => i"
    80   restrict    :: "[i, i] => i"
    81 
    82 text {*Infixes in order of decreasing precedence *}
    83 consts
    84 
    85   "``"        :: "[i, i] => i"    (infixl 90) --{*image*}
    86   "-``"       :: "[i, i] => i"    (infixl 90) --{*inverse image*}
    87   "`"         :: "[i, i] => i"    (infixl 90) --{*function application*}
    88 (*"*"         :: "[i, i] => i"    (infixr 80) [virtual] Cartesian product*)
    89   "Int"       :: "[i, i] => i"    (infixl 70) --{*binary intersection*}
    90   "Un"        :: "[i, i] => i"    (infixl 65) --{*binary union*}
    91   "-"         :: "[i, i] => i"    (infixl 65) --{*set difference*}
    92 (*"->"        :: "[i, i] => i"    (infixr 60) [virtual] function spac\<epsilon>*)
    93   "<="        :: "[i, i] => o"    (infixl 50) --{*subset relation*}
    94   ":"         :: "[i, i] => o"    (infixl 50) --{*membership relation*}
    95 (*"~:"        :: "[i, i] => o"    (infixl 50) (*negated membership relation*)*)
    96 
    97 
    98 nonterminals "is" patterns
    99 
   100 syntax
   101   ""          :: "i => is"                   ("_")
   102   "@Enum"     :: "[i, is] => is"             ("_,/ _")
   103   "~:"        :: "[i, i] => o"               (infixl 50)
   104   "@Finset"   :: "is => i"                   ("{(_)}")
   105   "@Tuple"    :: "[i, is] => i"              ("<(_,/ _)>")
   106   "@Collect"  :: "[pttrn, i, o] => i"        ("(1{_: _ ./ _})")
   107   "@Replace"  :: "[pttrn, pttrn, i, o] => i" ("(1{_ ./ _: _, _})")
   108   "@RepFun"   :: "[i, pttrn, i] => i"        ("(1{_ ./ _: _})" [51,0,51])
   109   "@INTER"    :: "[pttrn, i, i] => i"        ("(3INT _:_./ _)" 10)
   110   "@UNION"    :: "[pttrn, i, i] => i"        ("(3UN _:_./ _)" 10)
   111   "@PROD"     :: "[pttrn, i, i] => i"        ("(3PROD _:_./ _)" 10)
   112   "@SUM"      :: "[pttrn, i, i] => i"        ("(3SUM _:_./ _)" 10)
   113   "->"        :: "[i, i] => i"               (infixr 60)
   114   "*"         :: "[i, i] => i"               (infixr 80)
   115   "@lam"      :: "[pttrn, i, i] => i"        ("(3lam _:_./ _)" 10)
   116   "@Ball"     :: "[pttrn, i, o] => o"        ("(3ALL _:_./ _)" 10)
   117   "@Bex"      :: "[pttrn, i, o] => o"        ("(3EX _:_./ _)" 10)
   118 
   119   (** Patterns -- extends pre-defined type "pttrn" used in abstractions **)
   120 
   121   "@pattern"  :: "patterns => pttrn"         ("<_>")
   122   ""          :: "pttrn => patterns"         ("_")
   123   "@patterns" :: "[pttrn, patterns] => patterns"  ("_,/_")
   124 
   125 translations
   126   "x ~: y"      == "~ (x : y)"
   127   "{x, xs}"     == "cons(x, {xs})"
   128   "{x}"         == "cons(x, 0)"
   129   "{x:A. P}"    == "Collect(A, %x. P)"
   130   "{y. x:A, Q}" == "Replace(A, %x y. Q)"
   131   "{b. x:A}"    == "RepFun(A, %x. b)"
   132   "INT x:A. B"  == "Inter({B. x:A})"
   133   "UN x:A. B"   == "Union({B. x:A})"
   134   "PROD x:A. B" => "Pi(A, %x. B)"
   135   "SUM x:A. B"  => "Sigma(A, %x. B)"
   136   "A -> B"      => "Pi(A, %_. B)"
   137   "A * B"       => "Sigma(A, %_. B)"
   138   "lam x:A. f"  == "Lambda(A, %x. f)"
   139   "ALL x:A. P"  == "Ball(A, %x. P)"
   140   "EX x:A. P"   == "Bex(A, %x. P)"
   141 
   142   "<x, y, z>"   == "<x, <y, z>>"
   143   "<x, y>"      == "Pair(x, y)"
   144   "%<x,y,zs>.b" == "split(%x <y,zs>.b)"
   145   "%<x,y>.b"    == "split(%x y. b)"
   146 
   147 
   148 syntax (xsymbols)
   149   "op *"      :: "[i, i] => i"               (infixr "\<times>" 80)
   150   "op Int"    :: "[i, i] => i"    	     (infixl "\<inter>" 70)
   151   "op Un"     :: "[i, i] => i"    	     (infixl "\<union>" 65)
   152   "op ->"     :: "[i, i] => i"               (infixr "\<rightarrow>" 60)
   153   "op <="     :: "[i, i] => o"    	     (infixl "\<subseteq>" 50)
   154   "op :"      :: "[i, i] => o"    	     (infixl "\<in>" 50)
   155   "op ~:"     :: "[i, i] => o"               (infixl "\<notin>" 50)
   156   "@Collect"  :: "[pttrn, i, o] => i"        ("(1{_ \<in> _ ./ _})")
   157   "@Replace"  :: "[pttrn, pttrn, i, o] => i" ("(1{_ ./ _ \<in> _, _})")
   158   "@RepFun"   :: "[i, pttrn, i] => i"        ("(1{_ ./ _ \<in> _})" [51,0,51])
   159   "@UNION"    :: "[pttrn, i, i] => i"        ("(3\<Union>_\<in>_./ _)" 10)
   160   "@INTER"    :: "[pttrn, i, i] => i"        ("(3\<Inter>_\<in>_./ _)" 10)
   161   Union       :: "i =>i"                     ("\<Union>_" [90] 90)
   162   Inter       :: "i =>i"                     ("\<Inter>_" [90] 90)
   163   "@PROD"     :: "[pttrn, i, i] => i"        ("(3\<Pi>_\<in>_./ _)" 10)
   164   "@SUM"      :: "[pttrn, i, i] => i"        ("(3\<Sigma>_\<in>_./ _)" 10)
   165   "@lam"      :: "[pttrn, i, i] => i"        ("(3\<lambda>_\<in>_./ _)" 10)
   166   "@Ball"     :: "[pttrn, i, o] => o"        ("(3\<forall>_\<in>_./ _)" 10)
   167   "@Bex"      :: "[pttrn, i, o] => o"        ("(3\<exists>_\<in>_./ _)" 10)
   168   "@Tuple"    :: "[i, is] => i"              ("\<langle>(_,/ _)\<rangle>")
   169   "@pattern"  :: "patterns => pttrn"         ("\<langle>_\<rangle>")
   170 
   171 syntax (HTML output)
   172   "op *"      :: "[i, i] => i"               (infixr "\<times>" 80)
   173   "op Int"    :: "[i, i] => i"    	     (infixl "\<inter>" 70)
   174   "op Un"     :: "[i, i] => i"    	     (infixl "\<union>" 65)
   175   "op <="     :: "[i, i] => o"    	     (infixl "\<subseteq>" 50)
   176   "op :"      :: "[i, i] => o"    	     (infixl "\<in>" 50)
   177   "op ~:"     :: "[i, i] => o"               (infixl "\<notin>" 50)
   178   "@Collect"  :: "[pttrn, i, o] => i"        ("(1{_ \<in> _ ./ _})")
   179   "@Replace"  :: "[pttrn, pttrn, i, o] => i" ("(1{_ ./ _ \<in> _, _})")
   180   "@RepFun"   :: "[i, pttrn, i] => i"        ("(1{_ ./ _ \<in> _})" [51,0,51])
   181   "@UNION"    :: "[pttrn, i, i] => i"        ("(3\<Union>_\<in>_./ _)" 10)
   182   "@INTER"    :: "[pttrn, i, i] => i"        ("(3\<Inter>_\<in>_./ _)" 10)
   183   Union       :: "i =>i"                     ("\<Union>_" [90] 90)
   184   Inter       :: "i =>i"                     ("\<Inter>_" [90] 90)
   185   "@PROD"     :: "[pttrn, i, i] => i"        ("(3\<Pi>_\<in>_./ _)" 10)
   186   "@SUM"      :: "[pttrn, i, i] => i"        ("(3\<Sigma>_\<in>_./ _)" 10)
   187   "@lam"      :: "[pttrn, i, i] => i"        ("(3\<lambda>_\<in>_./ _)" 10)
   188   "@Ball"     :: "[pttrn, i, o] => o"        ("(3\<forall>_\<in>_./ _)" 10)
   189   "@Bex"      :: "[pttrn, i, o] => o"        ("(3\<exists>_\<in>_./ _)" 10)
   190   "@Tuple"    :: "[i, is] => i"              ("\<langle>(_,/ _)\<rangle>")
   191   "@pattern"  :: "patterns => pttrn"         ("\<langle>_\<rangle>")
   192 
   193 
   194 finalconsts
   195   0 Pow Inf Union PrimReplace 
   196   "op :"
   197 
   198 defs 
   199 (*don't try to use constdefs: the declaration order is tightly constrained*)
   200 
   201   (* Bounded Quantifiers *)
   202   Ball_def:      "Ball(A, P) == \<forall>x. x\<in>A --> P(x)"
   203   Bex_def:       "Bex(A, P) == \<exists>x. x\<in>A & P(x)"
   204 
   205   subset_def:    "A <= B == \<forall>x\<in>A. x\<in>B"
   206 
   207 
   208 local
   209 
   210 axioms
   211 
   212   (* ZF axioms -- see Suppes p.238
   213      Axioms for Union, Pow and Replace state existence only,
   214      uniqueness is derivable using extensionality. *)
   215 
   216   extension:     "A = B <-> A <= B & B <= A"
   217   Union_iff:     "A \<in> Union(C) <-> (\<exists>B\<in>C. A\<in>B)"
   218   Pow_iff:       "A \<in> Pow(B) <-> A <= B"
   219 
   220   (*We may name this set, though it is not uniquely defined.*)
   221   infinity:      "0\<in>Inf & (\<forall>y\<in>Inf. succ(y): Inf)"
   222 
   223   (*This formulation facilitates case analysis on A.*)
   224   foundation:    "A=0 | (\<exists>x\<in>A. \<forall>y\<in>x. y~:A)"
   225 
   226   (*Schema axiom since predicate P is a higher-order variable*)
   227   replacement:   "(\<forall>x\<in>A. \<forall>y z. P(x,y) & P(x,z) --> y=z) ==>
   228                          b \<in> PrimReplace(A,P) <-> (\<exists>x\<in>A. P(x,b))"
   229 
   230 
   231 defs
   232 
   233   (* Derived form of replacement, restricting P to its functional part.
   234      The resulting set (for functional P) is the same as with
   235      PrimReplace, but the rules are simpler. *)
   236 
   237   Replace_def:  "Replace(A,P) == PrimReplace(A, %x y. (EX!z. P(x,z)) & P(x,y))"
   238 
   239   (* Functional form of replacement -- analgous to ML's map functional *)
   240 
   241   RepFun_def:   "RepFun(A,f) == {y . x\<in>A, y=f(x)}"
   242 
   243   (* Separation and Pairing can be derived from the Replacement
   244      and Powerset Axioms using the following definitions. *)
   245 
   246   Collect_def:  "Collect(A,P) == {y . x\<in>A, x=y & P(x)}"
   247 
   248   (*Unordered pairs (Upair) express binary union/intersection and cons;
   249     set enumerations translate as {a,...,z} = cons(a,...,cons(z,0)...)*)
   250 
   251   Upair_def: "Upair(a,b) == {y. x\<in>Pow(Pow(0)), (x=0 & y=a) | (x=Pow(0) & y=b)}"
   252   cons_def:  "cons(a,A) == Upair(a,a) Un A"
   253   succ_def:  "succ(i) == cons(i, i)"
   254 
   255   (* Difference, general intersection, binary union and small intersection *)
   256 
   257   Diff_def:      "A - B    == { x\<in>A . ~(x\<in>B) }"
   258   Inter_def:     "Inter(A) == { x\<in>Union(A) . \<forall>y\<in>A. x\<in>y}"
   259   Un_def:        "A Un  B  == Union(Upair(A,B))"
   260   Int_def:      "A Int B  == Inter(Upair(A,B))"
   261 
   262   (* definite descriptions *)
   263   the_def:      "The(P)    == Union({y . x \<in> {0}, P(y)})"
   264   if_def:       "if(P,a,b) == THE z. P & z=a | ~P & z=b"
   265 
   266   (* this "symmetric" definition works better than {{a}, {a,b}} *)
   267   Pair_def:     "<a,b>  == {{a,a}, {a,b}}"
   268   fst_def:      "fst(p) == THE a. \<exists>b. p=<a,b>"
   269   snd_def:      "snd(p) == THE b. \<exists>a. p=<a,b>"
   270   split_def:    "split(c) == %p. c(fst(p), snd(p))"
   271   Sigma_def:    "Sigma(A,B) == \<Union>x\<in>A. \<Union>y\<in>B(x). {<x,y>}"
   272 
   273   (* Operations on relations *)
   274 
   275   (*converse of relation r, inverse of function*)
   276   converse_def: "converse(r) == {z. w\<in>r, \<exists>x y. w=<x,y> & z=<y,x>}"
   277 
   278   domain_def:   "domain(r) == {x. w\<in>r, \<exists>y. w=<x,y>}"
   279   range_def:    "range(r) == domain(converse(r))"
   280   field_def:    "field(r) == domain(r) Un range(r)"
   281   relation_def: "relation(r) == \<forall>z\<in>r. \<exists>x y. z = <x,y>"
   282   function_def: "function(r) ==
   283 		    \<forall>x y. <x,y>:r --> (\<forall>y'. <x,y'>:r --> y=y')"
   284   image_def:    "r `` A  == {y : range(r) . \<exists>x\<in>A. <x,y> : r}"
   285   vimage_def:   "r -`` A == converse(r)``A"
   286 
   287   (* Abstraction, application and Cartesian product of a family of sets *)
   288 
   289   lam_def:      "Lambda(A,b) == {<x,b(x)> . x\<in>A}"
   290   apply_def:    "f`a == Union(f``{a})"
   291   Pi_def:       "Pi(A,B)  == {f\<in>Pow(Sigma(A,B)). A<=domain(f) & function(f)}"
   292 
   293   (* Restrict the relation r to the domain A *)
   294   restrict_def: "restrict(r,A) == {z : r. \<exists>x\<in>A. \<exists>y. z = <x,y>}"
   295 
   296 (* Pattern-matching and 'Dependent' type operators *)
   297 
   298 print_translation {*
   299   [("Pi",    dependent_tr' ("@PROD", "op ->")),
   300    ("Sigma", dependent_tr' ("@SUM", "op *"))];
   301 *}
   302 
   303 subsection {* Substitution*}
   304 
   305 (*Useful examples:  singletonI RS subst_elem,  subst_elem RSN (2,IntI) *)
   306 lemma subst_elem: "[| b\<in>A;  a=b |] ==> a\<in>A"
   307 by (erule ssubst, assumption)
   308 
   309 
   310 subsection{*Bounded universal quantifier*}
   311 
   312 lemma ballI [intro!]: "[| !!x. x\<in>A ==> P(x) |] ==> \<forall>x\<in>A. P(x)"
   313 by (simp add: Ball_def)
   314 
   315 lemmas strip = impI allI ballI
   316 
   317 lemma bspec [dest?]: "[| \<forall>x\<in>A. P(x);  x: A |] ==> P(x)"
   318 by (simp add: Ball_def)
   319 
   320 (*Instantiates x first: better for automatic theorem proving?*)
   321 lemma rev_ballE [elim]: 
   322     "[| \<forall>x\<in>A. P(x);  x~:A ==> Q;  P(x) ==> Q |] ==> Q"
   323 by (simp add: Ball_def, blast) 
   324 
   325 lemma ballE: "[| \<forall>x\<in>A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q"
   326 by blast
   327 
   328 (*Used in the datatype package*)
   329 lemma rev_bspec: "[| x: A;  \<forall>x\<in>A. P(x) |] ==> P(x)"
   330 by (simp add: Ball_def)
   331 
   332 (*Trival rewrite rule;   (\<forall>x\<in>A.P)<->P holds only if A is nonempty!*)
   333 lemma ball_triv [simp]: "(\<forall>x\<in>A. P) <-> ((\<exists>x. x\<in>A) --> P)"
   334 by (simp add: Ball_def)
   335 
   336 (*Congruence rule for rewriting*)
   337 lemma ball_cong [cong]:
   338     "[| A=A';  !!x. x\<in>A' ==> P(x) <-> P'(x) |] ==> (\<forall>x\<in>A. P(x)) <-> (\<forall>x\<in>A'. P'(x))"
   339 by (simp add: Ball_def)
   340 
   341 lemma atomize_ball:
   342     "(!!x. x \<in> A ==> P(x)) == Trueprop (\<forall>x\<in>A. P(x))"
   343   by (simp only: Ball_def atomize_all atomize_imp)
   344 
   345 lemmas [symmetric, rulify] = atomize_ball
   346   and [symmetric, defn] = atomize_ball
   347 
   348 
   349 subsection{*Bounded existential quantifier*}
   350 
   351 lemma bexI [intro]: "[| P(x);  x: A |] ==> \<exists>x\<in>A. P(x)"
   352 by (simp add: Bex_def, blast)
   353 
   354 (*The best argument order when there is only one x\<in>A*)
   355 lemma rev_bexI: "[| x\<in>A;  P(x) |] ==> \<exists>x\<in>A. P(x)"
   356 by blast
   357 
   358 (*Not of the general form for such rules; ~\<exists>has become ALL~ *)
   359 lemma bexCI: "[| \<forall>x\<in>A. ~P(x) ==> P(a);  a: A |] ==> \<exists>x\<in>A. P(x)"
   360 by blast
   361 
   362 lemma bexE [elim!]: "[| \<exists>x\<in>A. P(x);  !!x. [| x\<in>A; P(x) |] ==> Q |] ==> Q"
   363 by (simp add: Bex_def, blast)
   364 
   365 (*We do not even have (\<exists>x\<in>A. True) <-> True unless A is nonempty!!*)
   366 lemma bex_triv [simp]: "(\<exists>x\<in>A. P) <-> ((\<exists>x. x\<in>A) & P)"
   367 by (simp add: Bex_def)
   368 
   369 lemma bex_cong [cong]:
   370     "[| A=A';  !!x. x\<in>A' ==> P(x) <-> P'(x) |] 
   371      ==> (\<exists>x\<in>A. P(x)) <-> (\<exists>x\<in>A'. P'(x))"
   372 by (simp add: Bex_def cong: conj_cong)
   373 
   374 
   375 
   376 subsection{*Rules for subsets*}
   377 
   378 lemma subsetI [intro!]:
   379     "(!!x. x\<in>A ==> x\<in>B) ==> A <= B"
   380 by (simp add: subset_def) 
   381 
   382 (*Rule in Modus Ponens style [was called subsetE] *)
   383 lemma subsetD [elim]: "[| A <= B;  c\<in>A |] ==> c\<in>B"
   384 apply (unfold subset_def)
   385 apply (erule bspec, assumption)
   386 done
   387 
   388 (*Classical elimination rule*)
   389 lemma subsetCE [elim]:
   390     "[| A <= B;  c~:A ==> P;  c\<in>B ==> P |] ==> P"
   391 by (simp add: subset_def, blast) 
   392 
   393 (*Sometimes useful with premises in this order*)
   394 lemma rev_subsetD: "[| c\<in>A; A<=B |] ==> c\<in>B"
   395 by blast
   396 
   397 lemma contra_subsetD: "[| A <= B; c ~: B |] ==> c ~: A"
   398 by blast
   399 
   400 lemma rev_contra_subsetD: "[| c ~: B;  A <= B |] ==> c ~: A"
   401 by blast
   402 
   403 lemma subset_refl [simp]: "A <= A"
   404 by blast
   405 
   406 lemma subset_trans: "[| A<=B;  B<=C |] ==> A<=C"
   407 by blast
   408 
   409 (*Useful for proving A<=B by rewriting in some cases*)
   410 lemma subset_iff: 
   411      "A<=B <-> (\<forall>x. x\<in>A --> x\<in>B)"
   412 apply (unfold subset_def Ball_def)
   413 apply (rule iff_refl)
   414 done
   415 
   416 
   417 subsection{*Rules for equality*}
   418 
   419 (*Anti-symmetry of the subset relation*)
   420 lemma equalityI [intro]: "[| A <= B;  B <= A |] ==> A = B"
   421 by (rule extension [THEN iffD2], rule conjI) 
   422 
   423 
   424 lemma equality_iffI: "(!!x. x\<in>A <-> x\<in>B) ==> A = B"
   425 by (rule equalityI, blast+)
   426 
   427 lemmas equalityD1 = extension [THEN iffD1, THEN conjunct1, standard]
   428 lemmas equalityD2 = extension [THEN iffD1, THEN conjunct2, standard]
   429 
   430 lemma equalityE: "[| A = B;  [| A<=B; B<=A |] ==> P |]  ==>  P"
   431 by (blast dest: equalityD1 equalityD2) 
   432 
   433 lemma equalityCE:
   434     "[| A = B;  [| c\<in>A; c\<in>B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P"
   435 by (erule equalityE, blast) 
   436 
   437 
   438 subsection{*Rules for Replace -- the derived form of replacement*}
   439 
   440 lemma Replace_iff: 
   441     "b : {y. x\<in>A, P(x,y)}  <->  (\<exists>x\<in>A. P(x,b) & (\<forall>y. P(x,y) --> y=b))"
   442 apply (unfold Replace_def)
   443 apply (rule replacement [THEN iff_trans], blast+)
   444 done
   445 
   446 (*Introduction; there must be a unique y such that P(x,y), namely y=b. *)
   447 lemma ReplaceI [intro]: 
   448     "[| P(x,b);  x: A;  !!y. P(x,y) ==> y=b |] ==>  
   449      b : {y. x\<in>A, P(x,y)}"
   450 by (rule Replace_iff [THEN iffD2], blast) 
   451 
   452 (*Elimination; may asssume there is a unique y such that P(x,y), namely y=b. *)
   453 lemma ReplaceE: 
   454     "[| b : {y. x\<in>A, P(x,y)};   
   455         !!x. [| x: A;  P(x,b);  \<forall>y. P(x,y)-->y=b |] ==> R  
   456      |] ==> R"
   457 by (rule Replace_iff [THEN iffD1, THEN bexE], simp+)
   458 
   459 (*As above but without the (generally useless) 3rd assumption*)
   460 lemma ReplaceE2 [elim!]: 
   461     "[| b : {y. x\<in>A, P(x,y)};   
   462         !!x. [| x: A;  P(x,b) |] ==> R  
   463      |] ==> R"
   464 by (erule ReplaceE, blast) 
   465 
   466 lemma Replace_cong [cong]:
   467     "[| A=B;  !!x y. x\<in>B ==> P(x,y) <-> Q(x,y) |] ==>  
   468      Replace(A,P) = Replace(B,Q)"
   469 apply (rule equality_iffI) 
   470 apply (simp add: Replace_iff) 
   471 done
   472 
   473 
   474 subsection{*Rules for RepFun*}
   475 
   476 lemma RepFunI: "a \<in> A ==> f(a) : {f(x). x\<in>A}"
   477 by (simp add: RepFun_def Replace_iff, blast)
   478 
   479 (*Useful for coinduction proofs*)
   480 lemma RepFun_eqI [intro]: "[| b=f(a);  a \<in> A |] ==> b : {f(x). x\<in>A}"
   481 apply (erule ssubst)
   482 apply (erule RepFunI)
   483 done
   484 
   485 lemma RepFunE [elim!]:
   486     "[| b : {f(x). x\<in>A};   
   487         !!x.[| x\<in>A;  b=f(x) |] ==> P |] ==>  
   488      P"
   489 by (simp add: RepFun_def Replace_iff, blast) 
   490 
   491 lemma RepFun_cong [cong]: 
   492     "[| A=B;  !!x. x\<in>B ==> f(x)=g(x) |] ==> RepFun(A,f) = RepFun(B,g)"
   493 by (simp add: RepFun_def)
   494 
   495 lemma RepFun_iff [simp]: "b : {f(x). x\<in>A} <-> (\<exists>x\<in>A. b=f(x))"
   496 by (unfold Bex_def, blast)
   497 
   498 lemma triv_RepFun [simp]: "{x. x\<in>A} = A"
   499 by blast
   500 
   501 
   502 subsection{*Rules for Collect -- forming a subset by separation*}
   503 
   504 (*Separation is derivable from Replacement*)
   505 lemma separation [simp]: "a : {x\<in>A. P(x)} <-> a\<in>A & P(a)"
   506 by (unfold Collect_def, blast)
   507 
   508 lemma CollectI [intro!]: "[| a\<in>A;  P(a) |] ==> a : {x\<in>A. P(x)}"
   509 by simp
   510 
   511 lemma CollectE [elim!]: "[| a : {x\<in>A. P(x)};  [| a\<in>A; P(a) |] ==> R |] ==> R"
   512 by simp
   513 
   514 lemma CollectD1: "a : {x\<in>A. P(x)} ==> a\<in>A"
   515 by (erule CollectE, assumption)
   516 
   517 lemma CollectD2: "a : {x\<in>A. P(x)} ==> P(a)"
   518 by (erule CollectE, assumption)
   519 
   520 lemma Collect_cong [cong]:
   521     "[| A=B;  !!x. x\<in>B ==> P(x) <-> Q(x) |]  
   522      ==> Collect(A, %x. P(x)) = Collect(B, %x. Q(x))"
   523 by (simp add: Collect_def)
   524 
   525 
   526 subsection{*Rules for Unions*}
   527 
   528 declare Union_iff [simp]
   529 
   530 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   531 lemma UnionI [intro]: "[| B: C;  A: B |] ==> A: Union(C)"
   532 by (simp, blast)
   533 
   534 lemma UnionE [elim!]: "[| A \<in> Union(C);  !!B.[| A: B;  B: C |] ==> R |] ==> R"
   535 by (simp, blast)
   536 
   537 
   538 subsection{*Rules for Unions of families*}
   539 (* \<Union>x\<in>A. B(x) abbreviates Union({B(x). x\<in>A}) *)
   540 
   541 lemma UN_iff [simp]: "b : (\<Union>x\<in>A. B(x)) <-> (\<exists>x\<in>A. b \<in> B(x))"
   542 by (simp add: Bex_def, blast)
   543 
   544 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   545 lemma UN_I: "[| a: A;  b: B(a) |] ==> b: (\<Union>x\<in>A. B(x))"
   546 by (simp, blast)
   547 
   548 
   549 lemma UN_E [elim!]: 
   550     "[| b : (\<Union>x\<in>A. B(x));  !!x.[| x: A;  b: B(x) |] ==> R |] ==> R"
   551 by blast 
   552 
   553 lemma UN_cong: 
   554     "[| A=B;  !!x. x\<in>B ==> C(x)=D(x) |] ==> (\<Union>x\<in>A. C(x)) = (\<Union>x\<in>B. D(x))"
   555 by simp 
   556 
   557 
   558 (*No "Addcongs [UN_cong]" because \<Union>is a combination of constants*)
   559 
   560 (* UN_E appears before UnionE so that it is tried first, to avoid expensive
   561   calls to hyp_subst_tac.  Cannot include UN_I as it is unsafe: would enlarge
   562   the search space.*)
   563 
   564 
   565 subsection{*Rules for the empty set*}
   566 
   567 (*The set {x\<in>0. False} is empty; by foundation it equals 0 
   568   See Suppes, page 21.*)
   569 lemma not_mem_empty [simp]: "a ~: 0"
   570 apply (cut_tac foundation)
   571 apply (best dest: equalityD2)
   572 done
   573 
   574 lemmas emptyE [elim!] = not_mem_empty [THEN notE, standard]
   575 
   576 
   577 lemma empty_subsetI [simp]: "0 <= A"
   578 by blast 
   579 
   580 lemma equals0I: "[| !!y. y\<in>A ==> False |] ==> A=0"
   581 by blast
   582 
   583 lemma equals0D [dest]: "A=0 ==> a ~: A"
   584 by blast
   585 
   586 declare sym [THEN equals0D, dest]
   587 
   588 lemma not_emptyI: "a\<in>A ==> A ~= 0"
   589 by blast
   590 
   591 lemma not_emptyE:  "[| A ~= 0;  !!x. x\<in>A ==> R |] ==> R"
   592 by blast
   593 
   594 
   595 subsection{*Rules for Inter*}
   596 
   597 (*Not obviously useful for proving InterI, InterD, InterE*)
   598 lemma Inter_iff: "A \<in> Inter(C) <-> (\<forall>x\<in>C. A: x) & C\<noteq>0"
   599 by (simp add: Inter_def Ball_def, blast)
   600 
   601 (* Intersection is well-behaved only if the family is non-empty! *)
   602 lemma InterI [intro!]: 
   603     "[| !!x. x: C ==> A: x;  C\<noteq>0 |] ==> A \<in> Inter(C)"
   604 by (simp add: Inter_iff)
   605 
   606 (*A "destruct" rule -- every B in C contains A as an element, but
   607   A\<in>B can hold when B\<in>C does not!  This rule is analogous to "spec". *)
   608 lemma InterD [elim]: "[| A \<in> Inter(C);  B \<in> C |] ==> A \<in> B"
   609 by (unfold Inter_def, blast)
   610 
   611 (*"Classical" elimination rule -- does not require exhibiting B\<in>C *)
   612 lemma InterE [elim]: 
   613     "[| A \<in> Inter(C);  B~:C ==> R;  A\<in>B ==> R |] ==> R"
   614 by (simp add: Inter_def, blast) 
   615   
   616 
   617 subsection{*Rules for Intersections of families*}
   618 
   619 (* \<Inter>x\<in>A. B(x) abbreviates Inter({B(x). x\<in>A}) *)
   620 
   621 lemma INT_iff: "b : (\<Inter>x\<in>A. B(x)) <-> (\<forall>x\<in>A. b \<in> B(x)) & A\<noteq>0"
   622 by (force simp add: Inter_def)
   623 
   624 lemma INT_I: "[| !!x. x: A ==> b: B(x);  A\<noteq>0 |] ==> b: (\<Inter>x\<in>A. B(x))"
   625 by blast
   626 
   627 lemma INT_E: "[| b : (\<Inter>x\<in>A. B(x));  a: A |] ==> b \<in> B(a)"
   628 by blast
   629 
   630 lemma INT_cong:
   631     "[| A=B;  !!x. x\<in>B ==> C(x)=D(x) |] ==> (\<Inter>x\<in>A. C(x)) = (\<Inter>x\<in>B. D(x))"
   632 by simp
   633 
   634 (*No "Addcongs [INT_cong]" because \<Inter>is a combination of constants*)
   635 
   636 
   637 subsection{*Rules for Powersets*}
   638 
   639 lemma PowI: "A <= B ==> A \<in> Pow(B)"
   640 by (erule Pow_iff [THEN iffD2])
   641 
   642 lemma PowD: "A \<in> Pow(B)  ==>  A<=B"
   643 by (erule Pow_iff [THEN iffD1])
   644 
   645 declare Pow_iff [iff]
   646 
   647 lemmas Pow_bottom = empty_subsetI [THEN PowI] (* 0 \<in> Pow(B) *)
   648 lemmas Pow_top = subset_refl [THEN PowI] (* A \<in> Pow(A) *)
   649 
   650 
   651 subsection{*Cantor's Theorem: There is no surjection from a set to its powerset.*}
   652 
   653 (*The search is undirected.  Allowing redundant introduction rules may 
   654   make it diverge.  Variable b represents ANY map, such as
   655   (lam x\<in>A.b(x)): A->Pow(A). *)
   656 lemma cantor: "\<exists>S \<in> Pow(A). \<forall>x\<in>A. b(x) ~= S"
   657 by (best elim!: equalityCE del: ReplaceI RepFun_eqI)
   658 
   659 ML
   660 {*
   661 val lam_def = thm "lam_def";
   662 val domain_def = thm "domain_def";
   663 val range_def = thm "range_def";
   664 val image_def = thm "image_def";
   665 val vimage_def = thm "vimage_def";
   666 val field_def = thm "field_def";
   667 val Inter_def = thm "Inter_def";
   668 val Ball_def = thm "Ball_def";
   669 val Bex_def = thm "Bex_def";
   670 
   671 val ballI = thm "ballI";
   672 val bspec = thm "bspec";
   673 val rev_ballE = thm "rev_ballE";
   674 val ballE = thm "ballE";
   675 val rev_bspec = thm "rev_bspec";
   676 val ball_triv = thm "ball_triv";
   677 val ball_cong = thm "ball_cong";
   678 val bexI = thm "bexI";
   679 val rev_bexI = thm "rev_bexI";
   680 val bexCI = thm "bexCI";
   681 val bexE = thm "bexE";
   682 val bex_triv = thm "bex_triv";
   683 val bex_cong = thm "bex_cong";
   684 val subst_elem = thm "subst_elem";
   685 val subsetI = thm "subsetI";
   686 val subsetD = thm "subsetD";
   687 val subsetCE = thm "subsetCE";
   688 val rev_subsetD = thm "rev_subsetD";
   689 val contra_subsetD = thm "contra_subsetD";
   690 val rev_contra_subsetD = thm "rev_contra_subsetD";
   691 val subset_refl = thm "subset_refl";
   692 val subset_trans = thm "subset_trans";
   693 val subset_iff = thm "subset_iff";
   694 val equalityI = thm "equalityI";
   695 val equality_iffI = thm "equality_iffI";
   696 val equalityD1 = thm "equalityD1";
   697 val equalityD2 = thm "equalityD2";
   698 val equalityE = thm "equalityE";
   699 val equalityCE = thm "equalityCE";
   700 val Replace_iff = thm "Replace_iff";
   701 val ReplaceI = thm "ReplaceI";
   702 val ReplaceE = thm "ReplaceE";
   703 val ReplaceE2 = thm "ReplaceE2";
   704 val Replace_cong = thm "Replace_cong";
   705 val RepFunI = thm "RepFunI";
   706 val RepFun_eqI = thm "RepFun_eqI";
   707 val RepFunE = thm "RepFunE";
   708 val RepFun_cong = thm "RepFun_cong";
   709 val RepFun_iff = thm "RepFun_iff";
   710 val triv_RepFun = thm "triv_RepFun";
   711 val separation = thm "separation";
   712 val CollectI = thm "CollectI";
   713 val CollectE = thm "CollectE";
   714 val CollectD1 = thm "CollectD1";
   715 val CollectD2 = thm "CollectD2";
   716 val Collect_cong = thm "Collect_cong";
   717 val UnionI = thm "UnionI";
   718 val UnionE = thm "UnionE";
   719 val UN_iff = thm "UN_iff";
   720 val UN_I = thm "UN_I";
   721 val UN_E = thm "UN_E";
   722 val UN_cong = thm "UN_cong";
   723 val Inter_iff = thm "Inter_iff";
   724 val InterI = thm "InterI";
   725 val InterD = thm "InterD";
   726 val InterE = thm "InterE";
   727 val INT_iff = thm "INT_iff";
   728 val INT_I = thm "INT_I";
   729 val INT_E = thm "INT_E";
   730 val INT_cong = thm "INT_cong";
   731 val PowI = thm "PowI";
   732 val PowD = thm "PowD";
   733 val Pow_bottom = thm "Pow_bottom";
   734 val Pow_top = thm "Pow_top";
   735 val not_mem_empty = thm "not_mem_empty";
   736 val emptyE = thm "emptyE";
   737 val empty_subsetI = thm "empty_subsetI";
   738 val equals0I = thm "equals0I";
   739 val equals0D = thm "equals0D";
   740 val not_emptyI = thm "not_emptyI";
   741 val not_emptyE = thm "not_emptyE";
   742 val cantor = thm "cantor";
   743 *}
   744 
   745 (*Functions for ML scripts*)
   746 ML
   747 {*
   748 (*Converts A<=B to x\<in>A ==> x\<in>B*)
   749 fun impOfSubs th = th RSN (2, rev_subsetD);
   750 
   751 (*Takes assumptions \<forall>x\<in>A.P(x) and a\<in>A; creates assumption P(a)*)
   752 val ball_tac = dtac bspec THEN' assume_tac
   753 *}
   754 
   755 end
   756