src/HOL/Hilbert_Choice.thy
 author nipkow Fri Aug 28 18:52:41 2009 +0200 (2009-08-28) changeset 32436 10cd49e0c067 parent 31723 f5cafe803b55 child 32988 d1d4d7a08a66 permissions -rw-r--r--
Turned "x <= y ==> sup x y = y" (and relatives) into simp rules
```     1 (*  Title:      HOL/Hilbert_Choice.thy
```
```     2     Author:     Lawrence C Paulson
```
```     3     Copyright   2001  University of Cambridge
```
```     4 *)
```
```     5
```
```     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
```
```     7
```
```     8 theory Hilbert_Choice
```
```     9 imports Nat Wellfounded Plain
```
```    10 uses ("Tools/meson.ML") ("Tools/choice_specification.ML")
```
```    11 begin
```
```    12
```
```    13 subsection {* Hilbert's epsilon *}
```
```    14
```
```    15 axiomatization Eps :: "('a => bool) => 'a" where
```
```    16   someI: "P x ==> P (Eps P)"
```
```    17
```
```    18 syntax (epsilon)
```
```    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
```
```    20 syntax (HOL)
```
```    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
```
```    22 syntax
```
```    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
```
```    24 translations
```
```    25   "SOME x. P" == "CONST Eps (%x. P)"
```
```    26
```
```    27 print_translation {*
```
```    28 (* to avoid eta-contraction of body *)
```
```    29 [(@{const_syntax Eps}, fn [Abs abs] =>
```
```    30      let val (x,t) = atomic_abs_tr' abs
```
```    31      in Syntax.const "_Eps" \$ x \$ t end)]
```
```    32 *}
```
```    33
```
```    34 constdefs
```
```    35   inv :: "('a => 'b) => ('b => 'a)"
```
```    36   "inv(f :: 'a => 'b) == %y. SOME x. f x = y"
```
```    37
```
```    38   Inv :: "'a set => ('a => 'b) => ('b => 'a)"
```
```    39   "Inv A f == %x. SOME y. y \<in> A & f y = x"
```
```    40
```
```    41
```
```    42 subsection {*Hilbert's Epsilon-operator*}
```
```    43
```
```    44 text{*Easier to apply than @{text someI} if the witness comes from an
```
```    45 existential formula*}
```
```    46 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
```
```    47 apply (erule exE)
```
```    48 apply (erule someI)
```
```    49 done
```
```    50
```
```    51 text{*Easier to apply than @{text someI} because the conclusion has only one
```
```    52 occurrence of @{term P}.*}
```
```    53 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
```
```    54 by (blast intro: someI)
```
```    55
```
```    56 text{*Easier to apply than @{text someI2} if the witness comes from an
```
```    57 existential formula*}
```
```    58 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
```
```    59 by (blast intro: someI2)
```
```    60
```
```    61 lemma some_equality [intro]:
```
```    62      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
```
```    63 by (blast intro: someI2)
```
```    64
```
```    65 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
```
```    66 by (blast intro: some_equality)
```
```    67
```
```    68 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
```
```    69 by (blast intro: someI)
```
```    70
```
```    71 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
```
```    72 apply (rule some_equality)
```
```    73 apply (rule refl, assumption)
```
```    74 done
```
```    75
```
```    76 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
```
```    77 apply (rule some_equality)
```
```    78 apply (rule refl)
```
```    79 apply (erule sym)
```
```    80 done
```
```    81
```
```    82
```
```    83 subsection{*Axiom of Choice, Proved Using the Description Operator*}
```
```    84
```
```    85 text{*Used in @{text "Tools/meson.ML"}*}
```
```    86 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
```
```    87 by (fast elim: someI)
```
```    88
```
```    89 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
```
```    90 by (fast elim: someI)
```
```    91
```
```    92
```
```    93 subsection {*Function Inverse*}
```
```    94
```
```    95 lemma inv_id [simp]: "inv id = id"
```
```    96 by (simp add: inv_def id_def)
```
```    97
```
```    98 text{*A one-to-one function has an inverse.*}
```
```    99 lemma inv_f_f [simp]: "inj f ==> inv f (f x) = x"
```
```   100 by (simp add: inv_def inj_eq)
```
```   101
```
```   102 lemma inv_f_eq: "[| inj f;  f x = y |] ==> inv f y = x"
```
```   103 apply (erule subst)
```
```   104 apply (erule inv_f_f)
```
```   105 done
```
```   106
```
```   107 lemma inj_imp_inv_eq: "[| inj f; \<forall>x. f(g x) = x |] ==> inv f = g"
```
```   108 by (blast intro: ext inv_f_eq)
```
```   109
```
```   110 text{*But is it useful?*}
```
```   111 lemma inj_transfer:
```
```   112   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
```
```   113   shows "P x"
```
```   114 proof -
```
```   115   have "f x \<in> range f" by auto
```
```   116   hence "P(inv f (f x))" by (rule minor)
```
```   117   thus "P x" by (simp add: inv_f_f [OF injf])
```
```   118 qed
```
```   119
```
```   120
```
```   121 lemma inj_iff: "(inj f) = (inv f o f = id)"
```
```   122 apply (simp add: o_def expand_fun_eq)
```
```   123 apply (blast intro: inj_on_inverseI inv_f_f)
```
```   124 done
```
```   125
```
```   126 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
```
```   127 by (simp add: inj_iff)
```
```   128
```
```   129 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
```
```   130 by (simp add: o_assoc[symmetric])
```
```   131
```
```   132 lemma inv_image_cancel[simp]:
```
```   133   "inj f ==> inv f ` f ` S = S"
```
```   134 by (simp add: image_compose[symmetric])
```
```   135
```
```   136 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
```
```   137 by (blast intro: surjI inv_f_f)
```
```   138
```
```   139 lemma f_inv_f: "y \<in> range(f) ==> f(inv f y) = y"
```
```   140 apply (simp add: inv_def)
```
```   141 apply (fast intro: someI)
```
```   142 done
```
```   143
```
```   144 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
```
```   145 by (simp add: f_inv_f surj_range)
```
```   146
```
```   147 lemma inv_injective:
```
```   148   assumes eq: "inv f x = inv f y"
```
```   149       and x: "x: range f"
```
```   150       and y: "y: range f"
```
```   151   shows "x=y"
```
```   152 proof -
```
```   153   have "f (inv f x) = f (inv f y)" using eq by simp
```
```   154   thus ?thesis by (simp add: f_inv_f x y)
```
```   155 qed
```
```   156
```
```   157 lemma inj_on_inv: "A <= range(f) ==> inj_on (inv f) A"
```
```   158 by (fast intro: inj_onI elim: inv_injective injD)
```
```   159
```
```   160 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
```
```   161 by (simp add: inj_on_inv surj_range)
```
```   162
```
```   163 lemma surj_iff: "(surj f) = (f o inv f = id)"
```
```   164 apply (simp add: o_def expand_fun_eq)
```
```   165 apply (blast intro: surjI surj_f_inv_f)
```
```   166 done
```
```   167
```
```   168 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
```
```   169 apply (rule ext)
```
```   170 apply (drule_tac x = "inv f x" in spec)
```
```   171 apply (simp add: surj_f_inv_f)
```
```   172 done
```
```   173
```
```   174 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
```
```   175 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
```
```   176
```
```   177 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
```
```   178 apply (rule ext)
```
```   179 apply (auto simp add: inv_def)
```
```   180 done
```
```   181
```
```   182 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
```
```   183 apply (rule inv_equality)
```
```   184 apply (auto simp add: bij_def surj_f_inv_f)
```
```   185 done
```
```   186
```
```   187 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
```
```   188     f(True)=f(False)=True.  Then it's consistent with axiom someI that
```
```   189     inv f could be any function at all, including the identity function.
```
```   190     If inv f=id then inv f is a bijection, but inj f, surj(f) and
```
```   191     inv(inv f)=f all fail.
```
```   192 **)
```
```   193
```
```   194 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
```
```   195 apply (rule inv_equality)
```
```   196 apply (auto simp add: bij_def surj_f_inv_f)
```
```   197 done
```
```   198
```
```   199
```
```   200 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
```
```   201 by (simp add: image_eq_UN surj_f_inv_f)
```
```   202
```
```   203 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
```
```   204 by (simp add: image_eq_UN)
```
```   205
```
```   206 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
```
```   207 by (auto simp add: image_def)
```
```   208
```
```   209 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
```
```   210 apply auto
```
```   211 apply (force simp add: bij_is_inj)
```
```   212 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
```
```   213 done
```
```   214
```
```   215 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A"
```
```   216 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
```
```   217 apply (blast intro: bij_is_inj [THEN inv_f_f, symmetric])
```
```   218 done
```
```   219
```
```   220 lemma finite_fun_UNIVD1:
```
```   221   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
```
```   222   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
```
```   223   shows "finite (UNIV :: 'a set)"
```
```   224 proof -
```
```   225   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
```
```   226   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
```
```   227     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
```
```   228   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
```
```   229   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
```
```   230   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
```
```   231   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
```
```   232   proof (rule UNIV_eq_I)
```
```   233     fix x :: 'a
```
```   234     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_def)
```
```   235     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
```
```   236   qed
```
```   237   ultimately show "finite (UNIV :: 'a set)" by simp
```
```   238 qed
```
```   239
```
```   240 subsection {*Inverse of a PI-function (restricted domain)*}
```
```   241
```
```   242 lemma Inv_f_f: "[| inj_on f A;  x \<in> A |] ==> Inv A f (f x) = x"
```
```   243 apply (simp add: Inv_def inj_on_def)
```
```   244 apply (blast intro: someI2)
```
```   245 done
```
```   246
```
```   247 lemma f_Inv_f: "y \<in> f`A  ==> f (Inv A f y) = y"
```
```   248 apply (simp add: Inv_def)
```
```   249 apply (fast intro: someI2)
```
```   250 done
```
```   251
```
```   252 lemma Inv_injective:
```
```   253   assumes eq: "Inv A f x = Inv A f y"
```
```   254       and x: "x: f`A"
```
```   255       and y: "y: f`A"
```
```   256   shows "x=y"
```
```   257 proof -
```
```   258   have "f (Inv A f x) = f (Inv A f y)" using eq by simp
```
```   259   thus ?thesis by (simp add: f_Inv_f x y)
```
```   260 qed
```
```   261
```
```   262 lemma inj_on_Inv: "B <= f`A ==> inj_on (Inv A f) B"
```
```   263 apply (rule inj_onI)
```
```   264 apply (blast intro: inj_onI dest: Inv_injective injD)
```
```   265 done
```
```   266
```
```   267 lemma Inv_mem: "[| f ` A = B;  x \<in> B |] ==> Inv A f x \<in> A"
```
```   268 apply (simp add: Inv_def)
```
```   269 apply (fast intro: someI2)
```
```   270 done
```
```   271
```
```   272 lemma Inv_f_eq: "[| inj_on f A; f x = y; x \<in> A |] ==> Inv A f y = x"
```
```   273   apply (erule subst)
```
```   274   apply (erule Inv_f_f, assumption)
```
```   275   done
```
```   276
```
```   277 lemma Inv_comp:
```
```   278   "[| inj_on f (g ` A); inj_on g A; x \<in> f ` g ` A |] ==>
```
```   279   Inv A (f o g) x = (Inv A g o Inv (g ` A) f) x"
```
```   280   apply simp
```
```   281   apply (rule Inv_f_eq)
```
```   282     apply (fast intro: comp_inj_on)
```
```   283    apply (simp add: f_Inv_f Inv_mem)
```
```   284   apply (simp add: Inv_mem)
```
```   285   done
```
```   286
```
```   287 lemma bij_betw_Inv: "bij_betw f A B \<Longrightarrow> bij_betw (Inv A f) B A"
```
```   288   apply (auto simp add: bij_betw_def inj_on_Inv Inv_mem)
```
```   289   apply (simp add: image_compose [symmetric] o_def)
```
```   290   apply (simp add: image_def Inv_f_f)
```
```   291   done
```
```   292
```
```   293 subsection {*Other Consequences of Hilbert's Epsilon*}
```
```   294
```
```   295 text {*Hilbert's Epsilon and the @{term split} Operator*}
```
```   296
```
```   297 text{*Looping simprule*}
```
```   298 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
```
```   299   by simp
```
```   300
```
```   301 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
```
```   302   by (simp add: split_def)
```
```   303
```
```   304 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
```
```   305   by blast
```
```   306
```
```   307
```
```   308 text{*A relation is wellfounded iff it has no infinite descending chain*}
```
```   309 lemma wf_iff_no_infinite_down_chain:
```
```   310   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
```
```   311 apply (simp only: wf_eq_minimal)
```
```   312 apply (rule iffI)
```
```   313  apply (rule notI)
```
```   314  apply (erule exE)
```
```   315  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
```
```   316 apply (erule contrapos_np, simp, clarify)
```
```   317 apply (subgoal_tac "\<forall>n. nat_rec x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
```
```   318  apply (rule_tac x = "nat_rec x (%i y. @z. z:Q & (z,y) :r)" in exI)
```
```   319  apply (rule allI, simp)
```
```   320  apply (rule someI2_ex, blast, blast)
```
```   321 apply (rule allI)
```
```   322 apply (induct_tac "n", simp_all)
```
```   323 apply (rule someI2_ex, blast+)
```
```   324 done
```
```   325
```
```   326 lemma wf_no_infinite_down_chainE:
```
```   327   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
```
```   328 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
```
```   329
```
```   330
```
```   331 text{*A dynamically-scoped fact for TFL *}
```
```   332 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
```
```   333   by (blast intro: someI)
```
```   334
```
```   335
```
```   336 subsection {* Least value operator *}
```
```   337
```
```   338 constdefs
```
```   339   LeastM :: "['a => 'b::ord, 'a => bool] => 'a"
```
```   340   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
```
```   341
```
```   342 syntax
```
```   343   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
```
```   344 translations
```
```   345   "LEAST x WRT m. P" == "LeastM m (%x. P)"
```
```   346
```
```   347 lemma LeastMI2:
```
```   348   "P x ==> (!!y. P y ==> m x <= m y)
```
```   349     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
```
```   350     ==> Q (LeastM m P)"
```
```   351   apply (simp add: LeastM_def)
```
```   352   apply (rule someI2_ex, blast, blast)
```
```   353   done
```
```   354
```
```   355 lemma LeastM_equality:
```
```   356   "P k ==> (!!x. P x ==> m k <= m x)
```
```   357     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
```
```   358   apply (rule LeastMI2, assumption, blast)
```
```   359   apply (blast intro!: order_antisym)
```
```   360   done
```
```   361
```
```   362 lemma wf_linord_ex_has_least:
```
```   363   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
```
```   364     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
```
```   365   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
```
```   366   apply (drule_tac x = "m`Collect P" in spec, force)
```
```   367   done
```
```   368
```
```   369 lemma ex_has_least_nat:
```
```   370     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
```
```   371   apply (simp only: pred_nat_trancl_eq_le [symmetric])
```
```   372   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
```
```   373    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
```
```   374   done
```
```   375
```
```   376 lemma LeastM_nat_lemma:
```
```   377     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
```
```   378   apply (simp add: LeastM_def)
```
```   379   apply (rule someI_ex)
```
```   380   apply (erule ex_has_least_nat)
```
```   381   done
```
```   382
```
```   383 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1, standard]
```
```   384
```
```   385 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
```
```   386 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
```
```   387
```
```   388
```
```   389 subsection {* Greatest value operator *}
```
```   390
```
```   391 constdefs
```
```   392   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a"
```
```   393   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
```
```   394
```
```   395   Greatest :: "('a::ord => bool) => 'a"    (binder "GREATEST " 10)
```
```   396   "Greatest == GreatestM (%x. x)"
```
```   397
```
```   398 syntax
```
```   399   "_GreatestM" :: "[pttrn, 'a=>'b::ord, bool] => 'a"
```
```   400       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
```
```   401
```
```   402 translations
```
```   403   "GREATEST x WRT m. P" == "GreatestM m (%x. P)"
```
```   404
```
```   405 lemma GreatestMI2:
```
```   406   "P x ==> (!!y. P y ==> m y <= m x)
```
```   407     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
```
```   408     ==> Q (GreatestM m P)"
```
```   409   apply (simp add: GreatestM_def)
```
```   410   apply (rule someI2_ex, blast, blast)
```
```   411   done
```
```   412
```
```   413 lemma GreatestM_equality:
```
```   414  "P k ==> (!!x. P x ==> m x <= m k)
```
```   415     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
```
```   416   apply (rule_tac m = m in GreatestMI2, assumption, blast)
```
```   417   apply (blast intro!: order_antisym)
```
```   418   done
```
```   419
```
```   420 lemma Greatest_equality:
```
```   421   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
```
```   422   apply (simp add: Greatest_def)
```
```   423   apply (erule GreatestM_equality, blast)
```
```   424   done
```
```   425
```
```   426 lemma ex_has_greatest_nat_lemma:
```
```   427   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
```
```   428     ==> \<exists>y. P y & ~ (m y < m k + n)"
```
```   429   apply (induct n, force)
```
```   430   apply (force simp add: le_Suc_eq)
```
```   431   done
```
```   432
```
```   433 lemma ex_has_greatest_nat:
```
```   434   "P k ==> \<forall>y. P y --> m y < b
```
```   435     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
```
```   436   apply (rule ccontr)
```
```   437   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
```
```   438     apply (subgoal_tac  "m k <= b", auto)
```
```   439   done
```
```   440
```
```   441 lemma GreatestM_nat_lemma:
```
```   442   "P k ==> \<forall>y. P y --> m y < b
```
```   443     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
```
```   444   apply (simp add: GreatestM_def)
```
```   445   apply (rule someI_ex)
```
```   446   apply (erule ex_has_greatest_nat, assumption)
```
```   447   done
```
```   448
```
```   449 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1, standard]
```
```   450
```
```   451 lemma GreatestM_nat_le:
```
```   452   "P x ==> \<forall>y. P y --> m y < b
```
```   453     ==> (m x::nat) <= m (GreatestM m P)"
```
```   454   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
```
```   455   done
```
```   456
```
```   457
```
```   458 text {* \medskip Specialization to @{text GREATEST}. *}
```
```   459
```
```   460 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
```
```   461   apply (simp add: Greatest_def)
```
```   462   apply (rule GreatestM_natI, auto)
```
```   463   done
```
```   464
```
```   465 lemma Greatest_le:
```
```   466     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
```
```   467   apply (simp add: Greatest_def)
```
```   468   apply (rule GreatestM_nat_le, auto)
```
```   469   done
```
```   470
```
```   471
```
```   472 subsection {* The Meson proof procedure *}
```
```   473
```
```   474 subsubsection {* Negation Normal Form *}
```
```   475
```
```   476 text {* de Morgan laws *}
```
```   477
```
```   478 lemma meson_not_conjD: "~(P&Q) ==> ~P | ~Q"
```
```   479   and meson_not_disjD: "~(P|Q) ==> ~P & ~Q"
```
```   480   and meson_not_notD: "~~P ==> P"
```
```   481   and meson_not_allD: "!!P. ~(\<forall>x. P(x)) ==> \<exists>x. ~P(x)"
```
```   482   and meson_not_exD: "!!P. ~(\<exists>x. P(x)) ==> \<forall>x. ~P(x)"
```
```   483   by fast+
```
```   484
```
```   485 text {* Removal of @{text "-->"} and @{text "<->"} (positive and
```
```   486 negative occurrences) *}
```
```   487
```
```   488 lemma meson_imp_to_disjD: "P-->Q ==> ~P | Q"
```
```   489   and meson_not_impD: "~(P-->Q) ==> P & ~Q"
```
```   490   and meson_iff_to_disjD: "P=Q ==> (~P | Q) & (~Q | P)"
```
```   491   and meson_not_iffD: "~(P=Q) ==> (P | Q) & (~P | ~Q)"
```
```   492     -- {* Much more efficient than @{prop "(P & ~Q) | (Q & ~P)"} for computing CNF *}
```
```   493   and meson_not_refl_disj_D: "x ~= x | P ==> P"
```
```   494   by fast+
```
```   495
```
```   496
```
```   497 subsubsection {* Pulling out the existential quantifiers *}
```
```   498
```
```   499 text {* Conjunction *}
```
```   500
```
```   501 lemma meson_conj_exD1: "!!P Q. (\<exists>x. P(x)) & Q ==> \<exists>x. P(x) & Q"
```
```   502   and meson_conj_exD2: "!!P Q. P & (\<exists>x. Q(x)) ==> \<exists>x. P & Q(x)"
```
```   503   by fast+
```
```   504
```
```   505
```
```   506 text {* Disjunction *}
```
```   507
```
```   508 lemma meson_disj_exD: "!!P Q. (\<exists>x. P(x)) | (\<exists>x. Q(x)) ==> \<exists>x. P(x) | Q(x)"
```
```   509   -- {* DO NOT USE with forall-Skolemization: makes fewer schematic variables!! *}
```
```   510   -- {* With ex-Skolemization, makes fewer Skolem constants *}
```
```   511   and meson_disj_exD1: "!!P Q. (\<exists>x. P(x)) | Q ==> \<exists>x. P(x) | Q"
```
```   512   and meson_disj_exD2: "!!P Q. P | (\<exists>x. Q(x)) ==> \<exists>x. P | Q(x)"
```
```   513   by fast+
```
```   514
```
```   515
```
```   516 subsubsection {* Generating clauses for the Meson Proof Procedure *}
```
```   517
```
```   518 text {* Disjunctions *}
```
```   519
```
```   520 lemma meson_disj_assoc: "(P|Q)|R ==> P|(Q|R)"
```
```   521   and meson_disj_comm: "P|Q ==> Q|P"
```
```   522   and meson_disj_FalseD1: "False|P ==> P"
```
```   523   and meson_disj_FalseD2: "P|False ==> P"
```
```   524   by fast+
```
```   525
```
```   526
```
```   527 subsection{*Lemmas for Meson, the Model Elimination Procedure*}
```
```   528
```
```   529 text{* Generation of contrapositives *}
```
```   530
```
```   531 text{*Inserts negated disjunct after removing the negation; P is a literal.
```
```   532   Model elimination requires assuming the negation of every attempted subgoal,
```
```   533   hence the negated disjuncts.*}
```
```   534 lemma make_neg_rule: "~P|Q ==> ((~P==>P) ==> Q)"
```
```   535 by blast
```
```   536
```
```   537 text{*Version for Plaisted's "Postive refinement" of the Meson procedure*}
```
```   538 lemma make_refined_neg_rule: "~P|Q ==> (P ==> Q)"
```
```   539 by blast
```
```   540
```
```   541 text{*@{term P} should be a literal*}
```
```   542 lemma make_pos_rule: "P|Q ==> ((P==>~P) ==> Q)"
```
```   543 by blast
```
```   544
```
```   545 text{*Versions of @{text make_neg_rule} and @{text make_pos_rule} that don't
```
```   546 insert new assumptions, for ordinary resolution.*}
```
```   547
```
```   548 lemmas make_neg_rule' = make_refined_neg_rule
```
```   549
```
```   550 lemma make_pos_rule': "[|P|Q; ~P|] ==> Q"
```
```   551 by blast
```
```   552
```
```   553 text{* Generation of a goal clause -- put away the final literal *}
```
```   554
```
```   555 lemma make_neg_goal: "~P ==> ((~P==>P) ==> False)"
```
```   556 by blast
```
```   557
```
```   558 lemma make_pos_goal: "P ==> ((P==>~P) ==> False)"
```
```   559 by blast
```
```   560
```
```   561
```
```   562 subsubsection{* Lemmas for Forward Proof*}
```
```   563
```
```   564 text{*There is a similarity to congruence rules*}
```
```   565
```
```   566 (*NOTE: could handle conjunctions (faster?) by
```
```   567     nf(th RS conjunct2) RS (nf(th RS conjunct1) RS conjI) *)
```
```   568 lemma conj_forward: "[| P'&Q';  P' ==> P;  Q' ==> Q |] ==> P&Q"
```
```   569 by blast
```
```   570
```
```   571 lemma disj_forward: "[| P'|Q';  P' ==> P;  Q' ==> Q |] ==> P|Q"
```
```   572 by blast
```
```   573
```
```   574 (*Version of @{text disj_forward} for removal of duplicate literals*)
```
```   575 lemma disj_forward2:
```
```   576     "[| P'|Q';  P' ==> P;  [| Q'; P==>False |] ==> Q |] ==> P|Q"
```
```   577 apply blast
```
```   578 done
```
```   579
```
```   580 lemma all_forward: "[| \<forall>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<forall>x. P(x)"
```
```   581 by blast
```
```   582
```
```   583 lemma ex_forward: "[| \<exists>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<exists>x. P(x)"
```
```   584 by blast
```
```   585
```
```   586
```
```   587 subsection {* Meson package *}
```
```   588
```
```   589 use "Tools/meson.ML"
```
```   590
```
```   591 setup Meson.setup
```
```   592
```
```   593
```
```   594 subsection {* Specification package -- Hilbertized version *}
```
```   595
```
```   596 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
```
```   597   by (simp only: someI_ex)
```
```   598
```
```   599 use "Tools/choice_specification.ML"
```
```   600
```
```   601
```
```   602 end
```