src/HOL/SetInterval.thy
author nipkow
Fri Aug 28 18:52:41 2009 +0200 (2009-08-28)
changeset 32436 10cd49e0c067
parent 32408 a1a85b0a26f7
child 32456 341c83339aeb
permissions -rw-r--r--
Turned "x <= y ==> sup x y = y" (and relatives) into simp rules
     1 (*  Title:      HOL/SetInterval.thy
     2     Author:     Tobias Nipkow and Clemens Ballarin
     3                 Additions by Jeremy Avigad in March 2004
     4     Copyright   2000  TU Muenchen
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory SetInterval
    12 imports Int
    13 begin
    14 
    15 context ord
    16 begin
    17 definition
    18   lessThan    :: "'a => 'a set"	("(1{..<_})") where
    19   "{..<u} == {x. x < u}"
    20 
    21 definition
    22   atMost      :: "'a => 'a set"	("(1{.._})") where
    23   "{..u} == {x. x \<le> u}"
    24 
    25 definition
    26   greaterThan :: "'a => 'a set"	("(1{_<..})") where
    27   "{l<..} == {x. l<x}"
    28 
    29 definition
    30   atLeast     :: "'a => 'a set"	("(1{_..})") where
    31   "{l..} == {x. l\<le>x}"
    32 
    33 definition
    34   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    35   "{l<..<u} == {l<..} Int {..<u}"
    36 
    37 definition
    38   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    39   "{l..<u} == {l..} Int {..<u}"
    40 
    41 definition
    42   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    43   "{l<..u} == {l<..} Int {..u}"
    44 
    45 definition
    46   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    47   "{l..u} == {l..} Int {..u}"
    48 
    49 end
    50 
    51 
    52 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    53 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    54 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    55 
    56 syntax
    57   "@UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    58   "@UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    59   "@INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    60   "@INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    61 
    62 syntax (xsymbols)
    63   "@UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    64   "@UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    65   "@INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    66   "@INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    67 
    68 syntax (latex output)
    69   "@UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" 10)
    70   "@UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" 10)
    71   "@INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" 10)
    72   "@INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" 10)
    73 
    74 translations
    75   "UN i<=n. A"  == "UN i:{..n}. A"
    76   "UN i<n. A"   == "UN i:{..<n}. A"
    77   "INT i<=n. A" == "INT i:{..n}. A"
    78   "INT i<n. A"  == "INT i:{..<n}. A"
    79 
    80 
    81 subsection {* Various equivalences *}
    82 
    83 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    84 by (simp add: lessThan_def)
    85 
    86 lemma Compl_lessThan [simp]:
    87     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    88 apply (auto simp add: lessThan_def atLeast_def)
    89 done
    90 
    91 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    92 by auto
    93 
    94 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    95 by (simp add: greaterThan_def)
    96 
    97 lemma Compl_greaterThan [simp]:
    98     "!!k:: 'a::linorder. -greaterThan k = atMost k"
    99   by (auto simp add: greaterThan_def atMost_def)
   100 
   101 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   102 apply (subst Compl_greaterThan [symmetric])
   103 apply (rule double_complement)
   104 done
   105 
   106 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   107 by (simp add: atLeast_def)
   108 
   109 lemma Compl_atLeast [simp]:
   110     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   111   by (auto simp add: lessThan_def atLeast_def)
   112 
   113 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   114 by (simp add: atMost_def)
   115 
   116 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   117 by (blast intro: order_antisym)
   118 
   119 
   120 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   121 
   122 lemma atLeast_subset_iff [iff]:
   123      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   124 by (blast intro: order_trans)
   125 
   126 lemma atLeast_eq_iff [iff]:
   127      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   128 by (blast intro: order_antisym order_trans)
   129 
   130 lemma greaterThan_subset_iff [iff]:
   131      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   132 apply (auto simp add: greaterThan_def)
   133  apply (subst linorder_not_less [symmetric], blast)
   134 done
   135 
   136 lemma greaterThan_eq_iff [iff]:
   137      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   138 apply (rule iffI)
   139  apply (erule equalityE)
   140  apply simp_all
   141 done
   142 
   143 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   144 by (blast intro: order_trans)
   145 
   146 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   147 by (blast intro: order_antisym order_trans)
   148 
   149 lemma lessThan_subset_iff [iff]:
   150      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   151 apply (auto simp add: lessThan_def)
   152  apply (subst linorder_not_less [symmetric], blast)
   153 done
   154 
   155 lemma lessThan_eq_iff [iff]:
   156      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   157 apply (rule iffI)
   158  apply (erule equalityE)
   159  apply simp_all
   160 done
   161 
   162 
   163 subsection {*Two-sided intervals*}
   164 
   165 context ord
   166 begin
   167 
   168 lemma greaterThanLessThan_iff [simp,noatp]:
   169   "(i : {l<..<u}) = (l < i & i < u)"
   170 by (simp add: greaterThanLessThan_def)
   171 
   172 lemma atLeastLessThan_iff [simp,noatp]:
   173   "(i : {l..<u}) = (l <= i & i < u)"
   174 by (simp add: atLeastLessThan_def)
   175 
   176 lemma greaterThanAtMost_iff [simp,noatp]:
   177   "(i : {l<..u}) = (l < i & i <= u)"
   178 by (simp add: greaterThanAtMost_def)
   179 
   180 lemma atLeastAtMost_iff [simp,noatp]:
   181   "(i : {l..u}) = (l <= i & i <= u)"
   182 by (simp add: atLeastAtMost_def)
   183 
   184 text {* The above four lemmas could be declared as iffs. Unfortunately this
   185 breaks many proofs. Since it only helps blast, it is better to leave well
   186 alone *}
   187 
   188 end
   189 
   190 subsubsection{* Emptyness, singletons, subset *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastatMost_empty[simp]:
   196   "b < a \<Longrightarrow> {a..b} = {}"
   197 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   198 
   199 lemma atLeastatMost_empty_iff[simp]:
   200   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   201 by auto (blast intro: order_trans)
   202 
   203 lemma atLeastatMost_empty_iff2[simp]:
   204   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   205 by auto (blast intro: order_trans)
   206 
   207 lemma atLeastLessThan_empty[simp]:
   208   "b <= a \<Longrightarrow> {a..<b} = {}"
   209 by(auto simp: atLeastLessThan_def)
   210 
   211 lemma atLeastLessThan_empty_iff[simp]:
   212   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   213 by auto (blast intro: le_less_trans)
   214 
   215 lemma atLeastLessThan_empty_iff2[simp]:
   216   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   217 by auto (blast intro: le_less_trans)
   218 
   219 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   220 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   221 
   222 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   223 by auto (blast intro: less_le_trans)
   224 
   225 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   226 by auto (blast intro: less_le_trans)
   227 
   228 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   229 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   230 
   231 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   232 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   233 
   234 lemma atLeastatMost_subset_iff[simp]:
   235   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   236 unfolding atLeastAtMost_def atLeast_def atMost_def
   237 by (blast intro: order_trans)
   238 
   239 lemma atLeastatMost_psubset_iff:
   240   "{a..b} < {c..d} \<longleftrightarrow>
   241    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   242 by(simp add: psubset_eq expand_set_eq less_le_not_le)(blast intro: order_trans)
   243 
   244 end
   245 
   246 lemma (in linorder) atLeastLessThan_subset_iff:
   247   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   248 apply (auto simp:subset_eq Ball_def)
   249 apply(frule_tac x=a in spec)
   250 apply(erule_tac x=d in allE)
   251 apply (simp add: less_imp_le)
   252 done
   253 
   254 subsection {* Intervals of natural numbers *}
   255 
   256 subsubsection {* The Constant @{term lessThan} *}
   257 
   258 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   259 by (simp add: lessThan_def)
   260 
   261 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   262 by (simp add: lessThan_def less_Suc_eq, blast)
   263 
   264 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   265 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   266 
   267 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   268 by blast
   269 
   270 subsubsection {* The Constant @{term greaterThan} *}
   271 
   272 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   273 apply (simp add: greaterThan_def)
   274 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   275 done
   276 
   277 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   278 apply (simp add: greaterThan_def)
   279 apply (auto elim: linorder_neqE)
   280 done
   281 
   282 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   283 by blast
   284 
   285 subsubsection {* The Constant @{term atLeast} *}
   286 
   287 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   288 by (unfold atLeast_def UNIV_def, simp)
   289 
   290 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   291 apply (simp add: atLeast_def)
   292 apply (simp add: Suc_le_eq)
   293 apply (simp add: order_le_less, blast)
   294 done
   295 
   296 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   297   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   298 
   299 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   300 by blast
   301 
   302 subsubsection {* The Constant @{term atMost} *}
   303 
   304 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   305 by (simp add: atMost_def)
   306 
   307 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   308 apply (simp add: atMost_def)
   309 apply (simp add: less_Suc_eq order_le_less, blast)
   310 done
   311 
   312 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   313 by blast
   314 
   315 subsubsection {* The Constant @{term atLeastLessThan} *}
   316 
   317 text{*The orientation of the following 2 rules is tricky. The lhs is
   318 defined in terms of the rhs.  Hence the chosen orientation makes sense
   319 in this theory --- the reverse orientation complicates proofs (eg
   320 nontermination). But outside, when the definition of the lhs is rarely
   321 used, the opposite orientation seems preferable because it reduces a
   322 specific concept to a more general one. *}
   323 
   324 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   325 by(simp add:lessThan_def atLeastLessThan_def)
   326 
   327 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   328 by(simp add:atMost_def atLeastAtMost_def)
   329 
   330 declare atLeast0LessThan[symmetric, code_unfold]
   331         atLeast0AtMost[symmetric, code_unfold]
   332 
   333 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   334 by (simp add: atLeastLessThan_def)
   335 
   336 subsubsection {* Intervals of nats with @{term Suc} *}
   337 
   338 text{*Not a simprule because the RHS is too messy.*}
   339 lemma atLeastLessThanSuc:
   340     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   341 by (auto simp add: atLeastLessThan_def)
   342 
   343 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   344 by (auto simp add: atLeastLessThan_def)
   345 (*
   346 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   347 by (induct k, simp_all add: atLeastLessThanSuc)
   348 
   349 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   350 by (auto simp add: atLeastLessThan_def)
   351 *)
   352 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   353   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   354 
   355 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   356   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   357     greaterThanAtMost_def)
   358 
   359 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   360   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   361     greaterThanLessThan_def)
   362 
   363 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   364 by (auto simp add: atLeastAtMost_def)
   365 
   366 subsubsection {* Image *}
   367 
   368 lemma image_add_atLeastAtMost:
   369   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   370 proof
   371   show "?A \<subseteq> ?B" by auto
   372 next
   373   show "?B \<subseteq> ?A"
   374   proof
   375     fix n assume a: "n : ?B"
   376     hence "n - k : {i..j}" by auto
   377     moreover have "n = (n - k) + k" using a by auto
   378     ultimately show "n : ?A" by blast
   379   qed
   380 qed
   381 
   382 lemma image_add_atLeastLessThan:
   383   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   384 proof
   385   show "?A \<subseteq> ?B" by auto
   386 next
   387   show "?B \<subseteq> ?A"
   388   proof
   389     fix n assume a: "n : ?B"
   390     hence "n - k : {i..<j}" by auto
   391     moreover have "n = (n - k) + k" using a by auto
   392     ultimately show "n : ?A" by blast
   393   qed
   394 qed
   395 
   396 corollary image_Suc_atLeastAtMost[simp]:
   397   "Suc ` {i..j} = {Suc i..Suc j}"
   398 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   399 
   400 corollary image_Suc_atLeastLessThan[simp]:
   401   "Suc ` {i..<j} = {Suc i..<Suc j}"
   402 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   403 
   404 lemma image_add_int_atLeastLessThan:
   405     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   406   apply (auto simp add: image_def)
   407   apply (rule_tac x = "x - l" in bexI)
   408   apply auto
   409   done
   410 
   411 
   412 subsubsection {* Finiteness *}
   413 
   414 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   415   by (induct k) (simp_all add: lessThan_Suc)
   416 
   417 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   418   by (induct k) (simp_all add: atMost_Suc)
   419 
   420 lemma finite_greaterThanLessThan [iff]:
   421   fixes l :: nat shows "finite {l<..<u}"
   422 by (simp add: greaterThanLessThan_def)
   423 
   424 lemma finite_atLeastLessThan [iff]:
   425   fixes l :: nat shows "finite {l..<u}"
   426 by (simp add: atLeastLessThan_def)
   427 
   428 lemma finite_greaterThanAtMost [iff]:
   429   fixes l :: nat shows "finite {l<..u}"
   430 by (simp add: greaterThanAtMost_def)
   431 
   432 lemma finite_atLeastAtMost [iff]:
   433   fixes l :: nat shows "finite {l..u}"
   434 by (simp add: atLeastAtMost_def)
   435 
   436 text {* A bounded set of natural numbers is finite. *}
   437 lemma bounded_nat_set_is_finite:
   438   "(ALL i:N. i < (n::nat)) ==> finite N"
   439 apply (rule finite_subset)
   440  apply (rule_tac [2] finite_lessThan, auto)
   441 done
   442 
   443 text {* A set of natural numbers is finite iff it is bounded. *}
   444 lemma finite_nat_set_iff_bounded:
   445   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   446 proof
   447   assume f:?F  show ?B
   448     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   449 next
   450   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   451 qed
   452 
   453 lemma finite_nat_set_iff_bounded_le:
   454   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   455 apply(simp add:finite_nat_set_iff_bounded)
   456 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   457 done
   458 
   459 lemma finite_less_ub:
   460      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   461 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   462 
   463 text{* Any subset of an interval of natural numbers the size of the
   464 subset is exactly that interval. *}
   465 
   466 lemma subset_card_intvl_is_intvl:
   467   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   468 proof cases
   469   assume "finite A"
   470   thus "PROP ?P"
   471   proof(induct A rule:finite_linorder_max_induct)
   472     case empty thus ?case by auto
   473   next
   474     case (insert A b)
   475     moreover hence "b ~: A" by auto
   476     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   477       using `b ~: A` insert by fastsimp+
   478     ultimately show ?case by auto
   479   qed
   480 next
   481   assume "~finite A" thus "PROP ?P" by simp
   482 qed
   483 
   484 
   485 subsubsection {* Cardinality *}
   486 
   487 lemma card_lessThan [simp]: "card {..<u} = u"
   488   by (induct u, simp_all add: lessThan_Suc)
   489 
   490 lemma card_atMost [simp]: "card {..u} = Suc u"
   491   by (simp add: lessThan_Suc_atMost [THEN sym])
   492 
   493 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   494   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   495   apply (erule ssubst, rule card_lessThan)
   496   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   497   apply (erule subst)
   498   apply (rule card_image)
   499   apply (simp add: inj_on_def)
   500   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   501   apply (rule_tac x = "x - l" in exI)
   502   apply arith
   503   done
   504 
   505 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   506   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   507 
   508 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   509   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   510 
   511 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   512   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   513 
   514 lemma ex_bij_betw_nat_finite:
   515   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   516 apply(drule finite_imp_nat_seg_image_inj_on)
   517 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   518 done
   519 
   520 lemma ex_bij_betw_finite_nat:
   521   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   522 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   523 
   524 lemma finite_same_card_bij:
   525   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   526 apply(drule ex_bij_betw_finite_nat)
   527 apply(drule ex_bij_betw_nat_finite)
   528 apply(auto intro!:bij_betw_trans)
   529 done
   530 
   531 lemma ex_bij_betw_nat_finite_1:
   532   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   533 by (rule finite_same_card_bij) auto
   534 
   535 
   536 subsection {* Intervals of integers *}
   537 
   538 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   539   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   540 
   541 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   542   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   543 
   544 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   545     "{l+1..<u} = {l<..<u::int}"
   546   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   547 
   548 subsubsection {* Finiteness *}
   549 
   550 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   551     {(0::int)..<u} = int ` {..<nat u}"
   552   apply (unfold image_def lessThan_def)
   553   apply auto
   554   apply (rule_tac x = "nat x" in exI)
   555   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   556   done
   557 
   558 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   559   apply (case_tac "0 \<le> u")
   560   apply (subst image_atLeastZeroLessThan_int, assumption)
   561   apply (rule finite_imageI)
   562   apply auto
   563   done
   564 
   565 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   566   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   567   apply (erule subst)
   568   apply (rule finite_imageI)
   569   apply (rule finite_atLeastZeroLessThan_int)
   570   apply (rule image_add_int_atLeastLessThan)
   571   done
   572 
   573 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   574   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   575 
   576 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   577   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   578 
   579 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   580   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   581 
   582 
   583 subsubsection {* Cardinality *}
   584 
   585 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   586   apply (case_tac "0 \<le> u")
   587   apply (subst image_atLeastZeroLessThan_int, assumption)
   588   apply (subst card_image)
   589   apply (auto simp add: inj_on_def)
   590   done
   591 
   592 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   593   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   594   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   595   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   596   apply (erule subst)
   597   apply (rule card_image)
   598   apply (simp add: inj_on_def)
   599   apply (rule image_add_int_atLeastLessThan)
   600   done
   601 
   602 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   603 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   604 apply (auto simp add: algebra_simps)
   605 done
   606 
   607 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   608 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   609 
   610 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   611 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   612 
   613 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   614 proof -
   615   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   616   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   617 qed
   618 
   619 lemma card_less:
   620 assumes zero_in_M: "0 \<in> M"
   621 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   622 proof -
   623   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   624   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   625 qed
   626 
   627 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   628 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - Suc 0"])
   629 apply simp
   630 apply fastsimp
   631 apply auto
   632 apply (rule inj_on_diff_nat)
   633 apply auto
   634 apply (case_tac x)
   635 apply auto
   636 apply (case_tac xa)
   637 apply auto
   638 apply (case_tac xa)
   639 apply auto
   640 done
   641 
   642 lemma card_less_Suc:
   643   assumes zero_in_M: "0 \<in> M"
   644     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   645 proof -
   646   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   647   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   648     by (auto simp only: insert_Diff)
   649   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   650   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   651     apply (subst card_insert)
   652     apply simp_all
   653     apply (subst b)
   654     apply (subst card_less_Suc2[symmetric])
   655     apply simp_all
   656     done
   657   with c show ?thesis by simp
   658 qed
   659 
   660 
   661 subsection {*Lemmas useful with the summation operator setsum*}
   662 
   663 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   664 
   665 subsubsection {* Disjoint Unions *}
   666 
   667 text {* Singletons and open intervals *}
   668 
   669 lemma ivl_disj_un_singleton:
   670   "{l::'a::linorder} Un {l<..} = {l..}"
   671   "{..<u} Un {u::'a::linorder} = {..u}"
   672   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   673   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   674   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   675   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   676 by auto
   677 
   678 text {* One- and two-sided intervals *}
   679 
   680 lemma ivl_disj_un_one:
   681   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   682   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   683   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   684   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   685   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   686   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   687   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   688   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   689 by auto
   690 
   691 text {* Two- and two-sided intervals *}
   692 
   693 lemma ivl_disj_un_two:
   694   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   695   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   696   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   697   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   698   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   699   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   700   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   701   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   702 by auto
   703 
   704 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   705 
   706 subsubsection {* Disjoint Intersections *}
   707 
   708 text {* Singletons and open intervals *}
   709 
   710 lemma ivl_disj_int_singleton:
   711   "{l::'a::order} Int {l<..} = {}"
   712   "{..<u} Int {u} = {}"
   713   "{l} Int {l<..<u} = {}"
   714   "{l<..<u} Int {u} = {}"
   715   "{l} Int {l<..u} = {}"
   716   "{l..<u} Int {u} = {}"
   717   by simp+
   718 
   719 text {* One- and two-sided intervals *}
   720 
   721 lemma ivl_disj_int_one:
   722   "{..l::'a::order} Int {l<..<u} = {}"
   723   "{..<l} Int {l..<u} = {}"
   724   "{..l} Int {l<..u} = {}"
   725   "{..<l} Int {l..u} = {}"
   726   "{l<..u} Int {u<..} = {}"
   727   "{l<..<u} Int {u..} = {}"
   728   "{l..u} Int {u<..} = {}"
   729   "{l..<u} Int {u..} = {}"
   730   by auto
   731 
   732 text {* Two- and two-sided intervals *}
   733 
   734 lemma ivl_disj_int_two:
   735   "{l::'a::order<..<m} Int {m..<u} = {}"
   736   "{l<..m} Int {m<..<u} = {}"
   737   "{l..<m} Int {m..<u} = {}"
   738   "{l..m} Int {m<..<u} = {}"
   739   "{l<..<m} Int {m..u} = {}"
   740   "{l<..m} Int {m<..u} = {}"
   741   "{l..<m} Int {m..u} = {}"
   742   "{l..m} Int {m<..u} = {}"
   743   by auto
   744 
   745 lemmas ivl_disj_int = ivl_disj_int_singleton ivl_disj_int_one ivl_disj_int_two
   746 
   747 subsubsection {* Some Differences *}
   748 
   749 lemma ivl_diff[simp]:
   750  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   751 by(auto)
   752 
   753 
   754 subsubsection {* Some Subset Conditions *}
   755 
   756 lemma ivl_subset [simp,noatp]:
   757  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   758 apply(auto simp:linorder_not_le)
   759 apply(rule ccontr)
   760 apply(insert linorder_le_less_linear[of i n])
   761 apply(clarsimp simp:linorder_not_le)
   762 apply(fastsimp)
   763 done
   764 
   765 
   766 subsection {* Summation indexed over intervals *}
   767 
   768 syntax
   769   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   770   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   771   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   772   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   773 syntax (xsymbols)
   774   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   775   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   776   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   777   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   778 syntax (HTML output)
   779   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   780   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   781   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   782   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   783 syntax (latex_sum output)
   784   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   785  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   786   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   787  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   788   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   789  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   790   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   791  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   792 
   793 translations
   794   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
   795   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
   796   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
   797   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
   798 
   799 text{* The above introduces some pretty alternative syntaxes for
   800 summation over intervals:
   801 \begin{center}
   802 \begin{tabular}{lll}
   803 Old & New & \LaTeX\\
   804 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   805 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   806 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   807 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   808 \end{tabular}
   809 \end{center}
   810 The left column shows the term before introduction of the new syntax,
   811 the middle column shows the new (default) syntax, and the right column
   812 shows a special syntax. The latter is only meaningful for latex output
   813 and has to be activated explicitly by setting the print mode to
   814 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   815 antiquotations). It is not the default \LaTeX\ output because it only
   816 works well with italic-style formulae, not tt-style.
   817 
   818 Note that for uniformity on @{typ nat} it is better to use
   819 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   820 not provide all lemmas available for @{term"{m..<n}"} also in the
   821 special form for @{term"{..<n}"}. *}
   822 
   823 text{* This congruence rule should be used for sums over intervals as
   824 the standard theorem @{text[source]setsum_cong} does not work well
   825 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   826 the context. *}
   827 
   828 lemma setsum_ivl_cong:
   829  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   830  setsum f {a..<b} = setsum g {c..<d}"
   831 by(rule setsum_cong, simp_all)
   832 
   833 (* FIXME why are the following simp rules but the corresponding eqns
   834 on intervals are not? *)
   835 
   836 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   837 by (simp add:atMost_Suc add_ac)
   838 
   839 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   840 by (simp add:lessThan_Suc add_ac)
   841 
   842 lemma setsum_cl_ivl_Suc[simp]:
   843   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   844 by (auto simp:add_ac atLeastAtMostSuc_conv)
   845 
   846 lemma setsum_op_ivl_Suc[simp]:
   847   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   848 by (auto simp:add_ac atLeastLessThanSuc)
   849 (*
   850 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   851     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   852 by (auto simp:add_ac atLeastAtMostSuc_conv)
   853 *)
   854 
   855 lemma setsum_head:
   856   fixes n :: nat
   857   assumes mn: "m <= n" 
   858   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   859 proof -
   860   from mn
   861   have "{m..n} = {m} \<union> {m<..n}"
   862     by (auto intro: ivl_disj_un_singleton)
   863   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   864     by (simp add: atLeast0LessThan)
   865   also have "\<dots> = ?rhs" by simp
   866   finally show ?thesis .
   867 qed
   868 
   869 lemma setsum_head_Suc:
   870   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
   871 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
   872 
   873 lemma setsum_head_upt_Suc:
   874   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
   875 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
   876 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
   877 done
   878 
   879 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
   880   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
   881 proof-
   882   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
   883   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
   884     atLeastSucAtMost_greaterThanAtMost)
   885 qed
   886 
   887 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   888   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   889 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   890 
   891 lemma setsum_diff_nat_ivl:
   892 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   893 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   894   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   895 using setsum_add_nat_ivl [of m n p f,symmetric]
   896 apply (simp add: add_ac)
   897 done
   898 
   899 lemma setsum_natinterval_difff:
   900   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
   901   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
   902           (if m <= n then f m - f(n + 1) else 0)"
   903 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
   904 
   905 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
   906 
   907 lemma setsum_setsum_restrict:
   908   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
   909   by (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
   910      (rule setsum_commute)
   911 
   912 lemma setsum_image_gen: assumes fS: "finite S"
   913   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   914 proof-
   915   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
   916   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
   917     by simp
   918   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   919     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
   920   finally show ?thesis .
   921 qed
   922 
   923 lemma setsum_multicount_gen:
   924   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
   925   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
   926 proof-
   927   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
   928   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
   929     using assms(3) by auto
   930   finally show ?thesis .
   931 qed
   932 
   933 lemma setsum_multicount:
   934   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
   935   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
   936 proof-
   937   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
   938   also have "\<dots> = ?r" by(simp add: setsum_constant mult_commute)
   939   finally show ?thesis by auto
   940 qed
   941 
   942 
   943 subsection{* Shifting bounds *}
   944 
   945 lemma setsum_shift_bounds_nat_ivl:
   946   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   947 by (induct "n", auto simp:atLeastLessThanSuc)
   948 
   949 lemma setsum_shift_bounds_cl_nat_ivl:
   950   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   951 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   952 apply (simp add:image_add_atLeastAtMost o_def)
   953 done
   954 
   955 corollary setsum_shift_bounds_cl_Suc_ivl:
   956   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   957 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
   958 
   959 corollary setsum_shift_bounds_Suc_ivl:
   960   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   961 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
   962 
   963 lemma setsum_shift_lb_Suc0_0:
   964   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
   965 by(simp add:setsum_head_Suc)
   966 
   967 lemma setsum_shift_lb_Suc0_0_upt:
   968   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
   969 apply(cases k)apply simp
   970 apply(simp add:setsum_head_upt_Suc)
   971 done
   972 
   973 subsection {* The formula for geometric sums *}
   974 
   975 lemma geometric_sum:
   976   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
   977   (x ^ n - 1) / (x - 1::'a::{field})"
   978 by (induct "n") (simp_all add:field_simps power_Suc)
   979 
   980 subsection {* The formula for arithmetic sums *}
   981 
   982 lemma gauss_sum:
   983   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
   984    of_nat n*((of_nat n)+1)"
   985 proof (induct n)
   986   case 0
   987   show ?case by simp
   988 next
   989   case (Suc n)
   990   then show ?case by (simp add: algebra_simps)
   991 qed
   992 
   993 theorem arith_series_general:
   994   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   995   of_nat n * (a + (a + of_nat(n - 1)*d))"
   996 proof cases
   997   assume ngt1: "n > 1"
   998   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
   999   have
  1000     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1001      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1002     by (rule setsum_addf)
  1003   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1004   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1005     unfolding One_nat_def
  1006     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1007   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
  1008     by (simp add: left_distrib right_distrib)
  1009   also from ngt1 have "{1..<n} = {1..n - 1}"
  1010     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1011   also from ngt1
  1012   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
  1013     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1014        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1015   finally show ?thesis by (simp add: algebra_simps)
  1016 next
  1017   assume "\<not>(n > 1)"
  1018   hence "n = 1 \<or> n = 0" by auto
  1019   thus ?thesis by (auto simp: algebra_simps)
  1020 qed
  1021 
  1022 lemma arith_series_nat:
  1023   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1024 proof -
  1025   have
  1026     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1027     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1028     by (rule arith_series_general)
  1029   thus ?thesis
  1030     unfolding One_nat_def by (auto simp add: of_nat_id)
  1031 qed
  1032 
  1033 lemma arith_series_int:
  1034   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1035   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1036 proof -
  1037   have
  1038     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1039     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1040     by (rule arith_series_general)
  1041   thus ?thesis by simp
  1042 qed
  1043 
  1044 lemma sum_diff_distrib:
  1045   fixes P::"nat\<Rightarrow>nat"
  1046   shows
  1047   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1048   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1049 proof (induct n)
  1050   case 0 show ?case by simp
  1051 next
  1052   case (Suc n)
  1053 
  1054   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1055   let ?rhs = "\<Sum>x<n. P x - Q x"
  1056 
  1057   from Suc have "?lhs = ?rhs" by simp
  1058   moreover
  1059   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1060   moreover
  1061   from Suc have
  1062     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1063     by (subst diff_diff_left[symmetric],
  1064         subst diff_add_assoc2)
  1065        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1066   ultimately
  1067   show ?case by simp
  1068 qed
  1069 
  1070 subsection {* Products indexed over intervals *}
  1071 
  1072 syntax
  1073   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1074   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1075   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1076   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1077 syntax (xsymbols)
  1078   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1079   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1080   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1081   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1082 syntax (HTML output)
  1083   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1084   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1085   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1086   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1087 syntax (latex_prod output)
  1088   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1089  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1090   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1091  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1092   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1093  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1094   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1095  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1096 
  1097 translations
  1098   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1099   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1100   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1101   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1102 
  1103 end