src/HOL/Transcendental.thy
author nipkow
Fri Aug 28 18:52:41 2009 +0200 (2009-08-28)
changeset 32436 10cd49e0c067
parent 32047 c141f139ce26
child 32960 69916a850301
permissions -rw-r--r--
Turned "x <= y ==> sup x y = y" (and relatives) into simp rules
     1 (*  Title       : Transcendental.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998,1999 University of Cambridge
     4                   1999,2001 University of Edinburgh
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6 *)
     7 
     8 header{*Power Series, Transcendental Functions etc.*}
     9 
    10 theory Transcendental
    11 imports Fact Series Deriv NthRoot
    12 begin
    13 
    14 subsection {* Properties of Power Series *}
    15 
    16 lemma lemma_realpow_diff:
    17   fixes y :: "'a::monoid_mult"
    18   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    19 proof -
    20   assume "p \<le> n"
    21   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    22   thus ?thesis by (simp add: power_commutes)
    23 qed
    24 
    25 lemma lemma_realpow_diff_sumr:
    26   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    27      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =  
    28       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    29 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    30          del: setsum_op_ivl_Suc cong: strong_setsum_cong)
    31 
    32 lemma lemma_realpow_diff_sumr2:
    33   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    34      "x ^ (Suc n) - y ^ (Suc n) =  
    35       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    36 apply (induct n, simp)
    37 apply (simp del: setsum_op_ivl_Suc)
    38 apply (subst setsum_op_ivl_Suc)
    39 apply (subst lemma_realpow_diff_sumr)
    40 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    41 apply (subst mult_left_commute [where a="x - y"])
    42 apply (erule subst)
    43 apply (simp add: algebra_simps)
    44 done
    45 
    46 lemma lemma_realpow_rev_sumr:
    47      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =  
    48       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    49 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    50 apply (rule inj_onI, simp)
    51 apply auto
    52 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    53 done
    54 
    55 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    56 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    57 
    58 lemma powser_insidea:
    59   fixes x z :: "'a::{real_normed_field,banach}"
    60   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    61   assumes 2: "norm z < norm x"
    62   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    63 proof -
    64   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    65   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    66     by (rule summable_LIMSEQ_zero)
    67   hence "convergent (\<lambda>n. f n * x ^ n)"
    68     by (rule convergentI)
    69   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    70     by (simp add: Cauchy_convergent_iff)
    71   hence "Bseq (\<lambda>n. f n * x ^ n)"
    72     by (rule Cauchy_Bseq)
    73   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    74     by (simp add: Bseq_def, safe)
    75   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    76                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    77   proof (intro exI allI impI)
    78     fix n::nat assume "0 \<le> n"
    79     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    80           norm (f n * x ^ n) * norm (z ^ n)"
    81       by (simp add: norm_mult abs_mult)
    82     also have "\<dots> \<le> K * norm (z ^ n)"
    83       by (simp only: mult_right_mono 4 norm_ge_zero)
    84     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    85       by (simp add: x_neq_0)
    86     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    87       by (simp only: mult_assoc)
    88     finally show "norm (norm (f n * z ^ n)) \<le>
    89                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    90       by (simp add: mult_le_cancel_right x_neq_0)
    91   qed
    92   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    93   proof -
    94     from 2 have "norm (norm (z * inverse x)) < 1"
    95       using x_neq_0
    96       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    97     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    98       by (rule summable_geometric)
    99     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
   100       by (rule summable_mult)
   101     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   102       using x_neq_0
   103       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   104                     power_inverse norm_power mult_assoc)
   105   qed
   106   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   107     by (rule summable_comparison_test)
   108 qed
   109 
   110 lemma powser_inside:
   111   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   112      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]  
   113       ==> summable (%n. f(n) * (z ^ n))"
   114 by (rule powser_insidea [THEN summable_norm_cancel])
   115 
   116 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   117   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) = 
   118    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   119 proof (induct n)
   120   case (Suc n)
   121   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) = 
   122         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   123     using Suc.hyps unfolding One_nat_def by auto
   124   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   125   finally show ?case .
   126 qed auto
   127 
   128 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   129   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   130   unfolding sums_def
   131 proof (rule LIMSEQ_I)
   132   fix r :: real assume "0 < r"
   133   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   134   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   135 
   136   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   137   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   138     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }" 
   139       using sum_split_even_odd by auto
   140     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   141     moreover
   142     have "?SUM (2 * (m div 2)) = ?SUM m"
   143     proof (cases "even m")
   144       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   145     next
   146       case False hence "even (Suc m)" by auto
   147       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   148       have eq: "Suc (2 * (m div 2)) = m" by auto
   149       hence "even (2 * (m div 2))" using `odd m` by auto
   150       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   151       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   152       finally show ?thesis by auto
   153     qed
   154     ultimately have "(norm (?SUM m - x) < r)" by auto
   155   }
   156   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   157 qed
   158 
   159 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   160   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   161 proof -
   162   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   163   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   164       by (cases B) auto } note if_sum = this
   165   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   166   { 
   167     have "?s 0 = 0" by auto
   168     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   169     { fix B T E have "(if \<not> B then T else E) = (if B then E else T)" by auto } note if_eq = this
   170 
   171     have "?s sums y" using sums_if'[OF `f sums y`] .
   172     from this[unfolded sums_def, THEN LIMSEQ_Suc] 
   173     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   174       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   175                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   176                 even_Suc Suc_m1 if_eq .
   177   } from sums_add[OF g_sums this]
   178   show ?thesis unfolding if_sum .
   179 qed
   180 
   181 subsection {* Alternating series test / Leibniz formula *}
   182 
   183 lemma sums_alternating_upper_lower:
   184   fixes a :: "nat \<Rightarrow> real"
   185   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   186   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and> 
   187              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   188   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   189 proof -
   190   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   191 
   192   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   193   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   194   moreover
   195   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   196   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   197     unfolding One_nat_def by auto qed
   198   moreover
   199   have "\<forall> n. ?f n \<le> ?g n" 
   200   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   201     unfolding One_nat_def by auto qed
   202   moreover
   203   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   204   proof (rule LIMSEQ_I)
   205     fix r :: real assume "0 < r"
   206     with `a ----> 0`[THEN LIMSEQ_D] 
   207     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   208     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   209     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   210   qed
   211   ultimately
   212   show ?thesis by (rule lemma_nest_unique)
   213 qed 
   214 
   215 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   216   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   217   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   218   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   219   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   222   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   223 proof -
   224   let "?S n" = "(-1)^n * a n"
   225   let "?P n" = "\<Sum>i=0..<n. ?S i"
   226   let "?f n" = "?P (2 * n)"
   227   let "?g n" = "?P (2 * n + 1)"
   228   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   229     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   230   
   231   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   232   have "?Sa ----> l"
   233   proof (rule LIMSEQ_I)
   234     fix r :: real assume "0 < r"
   235 
   236     with `?f ----> l`[THEN LIMSEQ_D] 
   237     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   238 
   239     from `0 < r` `?g ----> l`[THEN LIMSEQ_D] 
   240     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   241 
   242     { fix n :: nat
   243       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   244       have "norm (?Sa n - l) < r"
   245       proof (cases "even n")
   246 	case True from even_nat_div_two_times_two[OF this]
   247 	have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   248 	with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   249 	from f[OF this]
   250 	show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   251       next
   252 	case False hence "even (n - 1)" using even_num_iff odd_pos by auto 
   253 	from even_nat_div_two_times_two[OF this]
   254 	have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   255 	hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   256 
   257 	from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   258 	from g[OF this]
   259 	show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   260       qed
   261     }
   262     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   263   qed
   264   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   265   thus "summable ?S" using summable_def by auto
   266 
   267   have "l = suminf ?S" using sums_unique[OF sums_l] .
   268 
   269   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   270   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   271   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   272   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   273 qed
   274 
   275 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   276   assumes a_zero: "a ----> 0" and "monoseq a"
   277   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   278   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   279   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   280   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   281   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   282 proof -
   283   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   284   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   285     case True
   286     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   287     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   288     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   289     from leibniz[OF mono]
   290     show ?thesis using `0 \<le> a 0` by auto
   291   next
   292     let ?a = "\<lambda> n. - a n"
   293     case False
   294     with monoseq_le[OF `monoseq a` `a ----> 0`]
   295     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   296     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   297     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   298     note monotone = this
   299     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   300     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   301     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   302     from this[THEN sums_minus]
   303     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   304     hence ?summable unfolding summable_def by auto
   305     moreover
   306     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   307     
   308     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   309     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   310 
   311     have ?pos using `0 \<le> ?a 0` by auto
   312     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   313     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   314     ultimately show ?thesis by auto
   315   qed
   316   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   317        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   318   show ?summable and ?pos and ?neg and ?f and ?g .
   319 qed
   320 
   321 subsection {* Term-by-Term Differentiability of Power Series *}
   322 
   323 definition
   324   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   325   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   326 
   327 text{*Lemma about distributing negation over it*}
   328 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   329 by (simp add: diffs_def)
   330 
   331 lemma sums_Suc_imp:
   332   assumes f: "f 0 = 0"
   333   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   334 unfolding sums_def
   335 apply (rule LIMSEQ_imp_Suc)
   336 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   337 apply (simp only: setsum_shift_bounds_Suc_ivl)
   338 done
   339 
   340 lemma diffs_equiv:
   341      "summable (%n. (diffs c)(n) * (x ^ n)) ==>  
   342       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums  
   343          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   344 unfolding diffs_def
   345 apply (drule summable_sums)
   346 apply (rule sums_Suc_imp, simp_all)
   347 done
   348 
   349 lemma lemma_termdiff1:
   350   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   351   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =  
   352    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   353 by(auto simp add: algebra_simps power_add [symmetric] cong: strong_setsum_cong)
   354 
   355 lemma sumr_diff_mult_const2:
   356   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   357 by (simp add: setsum_subtractf)
   358 
   359 lemma lemma_termdiff2:
   360   fixes h :: "'a :: {field}"
   361   assumes h: "h \<noteq> 0" shows
   362   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   363    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   364         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   365 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   366 apply (simp add: right_diff_distrib diff_divide_distrib h)
   367 apply (simp add: mult_assoc [symmetric])
   368 apply (cases "n", simp)
   369 apply (simp add: lemma_realpow_diff_sumr2 h
   370                  right_diff_distrib [symmetric] mult_assoc
   371             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   372 apply (subst lemma_realpow_rev_sumr)
   373 apply (subst sumr_diff_mult_const2)
   374 apply simp
   375 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   376 apply (rule setsum_cong [OF refl])
   377 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   378 apply (clarify)
   379 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   380             del: setsum_op_ivl_Suc power_Suc)
   381 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   382 apply (simp add: mult_ac)
   383 done
   384 
   385 lemma real_setsum_nat_ivl_bounded2:
   386   fixes K :: "'a::ordered_semidom"
   387   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   388   assumes K: "0 \<le> K"
   389   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   390 apply (rule order_trans [OF setsum_mono])
   391 apply (rule f, simp)
   392 apply (simp add: mult_right_mono K)
   393 done
   394 
   395 lemma lemma_termdiff3:
   396   fixes h z :: "'a::{real_normed_field}"
   397   assumes 1: "h \<noteq> 0"
   398   assumes 2: "norm z \<le> K"
   399   assumes 3: "norm (z + h) \<le> K"
   400   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   401           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   402 proof -
   403   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   404         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   405           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   406     apply (subst lemma_termdiff2 [OF 1])
   407     apply (subst norm_mult)
   408     apply (rule mult_commute)
   409     done
   410   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   411   proof (rule mult_right_mono [OF _ norm_ge_zero])
   412     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   413     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   414       apply (erule subst)
   415       apply (simp only: norm_mult norm_power power_add)
   416       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   417       done
   418     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   419               (z + h) ^ q * z ^ (n - 2 - q))
   420           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   421       apply (intro
   422          order_trans [OF norm_setsum]
   423          real_setsum_nat_ivl_bounded2
   424          mult_nonneg_nonneg
   425          zero_le_imp_of_nat
   426          zero_le_power K)
   427       apply (rule le_Kn, simp)
   428       done
   429   qed
   430   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   431     by (simp only: mult_assoc)
   432   finally show ?thesis .
   433 qed
   434 
   435 lemma lemma_termdiff4:
   436   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   437               'b::real_normed_vector"
   438   assumes k: "0 < (k::real)"
   439   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   440   shows "f -- 0 --> 0"
   441 unfolding LIM_eq diff_0_right
   442 proof (safe)
   443   let ?h = "of_real (k / 2)::'a"
   444   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   445   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   446   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   447   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   448 
   449   fix r::real assume r: "0 < r"
   450   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   451   proof (cases)
   452     assume "K = 0"
   453     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   454       by simp
   455     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   456   next
   457     assume K_neq_zero: "K \<noteq> 0"
   458     with zero_le_K have K: "0 < K" by simp
   459     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   460     proof (rule exI, safe)
   461       from k r K show "0 < min k (r * inverse K / 2)"
   462         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   463     next
   464       fix x::'a
   465       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   466       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   467         by simp_all
   468       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   469       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   470         by (rule mult_strict_left_mono)
   471       also have "\<dots> = r / 2"
   472         using K_neq_zero by simp
   473       also have "r / 2 < r"
   474         using r by simp
   475       finally show "norm (f x) < r" .
   476     qed
   477   qed
   478 qed
   479 
   480 lemma lemma_termdiff5:
   481   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   482               nat \<Rightarrow> 'b::banach"
   483   assumes k: "0 < (k::real)"
   484   assumes f: "summable f"
   485   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   486   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   487 proof (rule lemma_termdiff4 [OF k])
   488   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   489   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   490     by (simp add: le)
   491   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   492     by simp
   493   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   494     by (rule summable_mult2)
   495   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   496     by (rule summable_comparison_test)
   497   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   498     by (rule summable_norm)
   499   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   500     by (rule summable_le)
   501   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   502     by (rule suminf_mult2 [symmetric])
   503   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   504 qed
   505 
   506 
   507 text{* FIXME: Long proofs*}
   508 
   509 lemma termdiffs_aux:
   510   fixes x :: "'a::{real_normed_field,banach}"
   511   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   512   assumes 2: "norm x < norm K"
   513   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   514              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   515 proof -
   516   from dense [OF 2]
   517   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   518   from norm_ge_zero r1 have r: "0 < r"
   519     by (rule order_le_less_trans)
   520   hence r_neq_0: "r \<noteq> 0" by simp
   521   show ?thesis
   522   proof (rule lemma_termdiff5)
   523     show "0 < r - norm x" using r1 by simp
   524   next
   525     from r r2 have "norm (of_real r::'a) < norm K"
   526       by simp
   527     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   528       by (rule powser_insidea)
   529     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   530       using r
   531       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   532     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   533       by (rule diffs_equiv [THEN sums_summable])
   534     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   535       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   536       apply (rule ext)
   537       apply (simp add: diffs_def)
   538       apply (case_tac n, simp_all add: r_neq_0)
   539       done
   540     finally have "summable 
   541       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   542       by (rule diffs_equiv [THEN sums_summable])
   543     also have
   544       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   545            r ^ (n - Suc 0)) =
   546        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   547       apply (rule ext)
   548       apply (case_tac "n", simp)
   549       apply (case_tac "nat", simp)
   550       apply (simp add: r_neq_0)
   551       done
   552     finally show
   553       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   554   next
   555     fix h::'a and n::nat
   556     assume h: "h \<noteq> 0"
   557     assume "norm h < r - norm x"
   558     hence "norm x + norm h < r" by simp
   559     with norm_triangle_ineq have xh: "norm (x + h) < r"
   560       by (rule order_le_less_trans)
   561     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   562           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   563       apply (simp only: norm_mult mult_assoc)
   564       apply (rule mult_left_mono [OF _ norm_ge_zero])
   565       apply (simp (no_asm) add: mult_assoc [symmetric])
   566       apply (rule lemma_termdiff3)
   567       apply (rule h)
   568       apply (rule r1 [THEN order_less_imp_le])
   569       apply (rule xh [THEN order_less_imp_le])
   570       done
   571   qed
   572 qed
   573 
   574 lemma termdiffs:
   575   fixes K x :: "'a::{real_normed_field,banach}"
   576   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   577   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   578   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   579   assumes 4: "norm x < norm K"
   580   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   581 unfolding deriv_def
   582 proof (rule LIM_zero_cancel)
   583   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   584             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   585   proof (rule LIM_equal2)
   586     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   587   next
   588     fix h :: 'a
   589     assume "h \<noteq> 0"
   590     assume "norm (h - 0) < norm K - norm x"
   591     hence "norm x + norm h < norm K" by simp
   592     hence 5: "norm (x + h) < norm K"
   593       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   594     have A: "summable (\<lambda>n. c n * x ^ n)"
   595       by (rule powser_inside [OF 1 4])
   596     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   597       by (rule powser_inside [OF 1 5])
   598     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   599       by (rule powser_inside [OF 2 4])
   600     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   601              - (\<Sum>n. diffs c n * x ^ n) = 
   602           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   603       apply (subst sums_unique [OF diffs_equiv [OF C]])
   604       apply (subst suminf_diff [OF B A])
   605       apply (subst suminf_divide [symmetric])
   606       apply (rule summable_diff [OF B A])
   607       apply (subst suminf_diff)
   608       apply (rule summable_divide)
   609       apply (rule summable_diff [OF B A])
   610       apply (rule sums_summable [OF diffs_equiv [OF C]])
   611       apply (rule arg_cong [where f="suminf"], rule ext)
   612       apply (simp add: algebra_simps)
   613       done
   614   next
   615     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   616                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   617         by (rule termdiffs_aux [OF 3 4])
   618   qed
   619 qed
   620 
   621 
   622 subsection{* Some properties of factorials *}
   623 
   624 lemma real_of_nat_fact_not_zero [simp]: "real (fact (n::nat)) \<noteq> 0"
   625 by auto
   626 
   627 lemma real_of_nat_fact_gt_zero [simp]: "0 < real(fact (n::nat))"
   628 by auto
   629 
   630 lemma real_of_nat_fact_ge_zero [simp]: "0 \<le> real(fact (n::nat))"
   631 by simp
   632 
   633 lemma inv_real_of_nat_fact_gt_zero [simp]: "0 < inverse (real (fact (n::nat)))"
   634 by (auto simp add: positive_imp_inverse_positive)
   635 
   636 lemma inv_real_of_nat_fact_ge_zero [simp]: "0 \<le> inverse (real (fact (n::nat)))"
   637 by (auto intro: order_less_imp_le)
   638 
   639 subsection {* Derivability of power series *}
   640 
   641 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   642   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   643   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   644   and "summable (f' x0)"
   645   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   646   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   647   unfolding deriv_def
   648 proof (rule LIM_I)
   649   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   650 
   651   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3" 
   652     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   653 
   654   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3" 
   655     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   656 
   657   let ?N = "Suc (max N_L N_f')"
   658   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   659     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   660 
   661   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   662 
   663   let ?r = "r / (3 * real ?N)"
   664   have "0 < 3 * real ?N" by auto
   665   from divide_pos_pos[OF `0 < r` this]
   666   have "0 < ?r" .
   667 
   668   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   669   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   670 
   671   have "0 < S'" unfolding S'_def
   672   proof (rule iffD2[OF Min_gr_iff])
   673     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   674     proof (rule ballI)
   675       fix x assume "x \<in> ?s ` {0..<?N}"
   676       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   677       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def] 
   678       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   679       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   680       thus "0 < x" unfolding `x = ?s n` .
   681     qed
   682   qed auto
   683 
   684   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   685   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   686     by auto
   687 
   688   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   689     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   690     
   691     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   692     note div_smbl = summable_divide[OF diff_smbl]
   693     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   694     note ign = summable_ignore_initial_segment[where k="?N"]
   695     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   696     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   697     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   698 
   699     { fix n
   700       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>" 
   701 	using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   702       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   703     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   704     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   705     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   706     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   707 
   708     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   709     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   710     proof (rule setsum_strict_mono)
   711       fix n assume "n \<in> { 0 ..< ?N}"
   712       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   713       also have "S \<le> S'" using `S \<le> S'` .
   714       also have "S' \<le> ?s n" unfolding S'_def 
   715       proof (rule Min_le_iff[THEN iffD2])
   716 	have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   717 	thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   718       qed auto
   719       finally have "\<bar> x \<bar> < ?s n" .
   720 
   721       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   722       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   723       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   724       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   725     qed auto
   726     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   727     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   728     also have "\<dots> = r/3" by auto
   729     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   730 
   731     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   732     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> = 
   733                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   734     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   735     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   736     also have "\<dots> < r /3 + r/3 + r/3" 
   737       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3` by auto
   738     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   739       by auto
   740   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow> 
   741       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   742     unfolding real_norm_def diff_0_right by blast
   743 qed
   744 
   745 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   746   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   747   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   748   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   749   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   750 proof -
   751   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   752     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   753     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   754     proof (rule DERIV_series')
   755       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   756       proof -
   757 	have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   758 	hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   759 	have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   760 	from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   761       qed
   762       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   763 	show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   764 	proof -
   765 	  have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>" 
   766 	    unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   767 	  also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)" 
   768 	  proof (rule mult_left_mono)
   769 	    have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   770 	    also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   771 	    proof (rule setsum_mono)
   772 	      fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   773 	      { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   774 		hence "\<bar>x\<bar> \<le> R'"  by auto
   775 		hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   776 	      } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   777 	      have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   778 	      thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   779 	    qed
   780 	    also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   781 	    finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   782 	    show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   783 	  qed
   784 	  also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult real_mult_assoc[symmetric] by algebra
   785 	  finally show ?thesis .
   786 	qed }
   787       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   788 	  by (auto intro!: DERIV_intros simp del: power_Suc) }
   789       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   790 	have "summable (\<lambda> n. f n * x^n)"
   791 	proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   792 	  fix n
   793 	  have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   794 	  show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   795 	    by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   796 	qed
   797 	from this[THEN summable_mult2[where c=x], unfolded real_mult_assoc, unfolded real_mult_commute]
   798 	show "summable (?f x)" by auto }
   799       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   800       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   801     qed
   802   } note for_subinterval = this
   803   let ?R = "(R + \<bar>x0\<bar>) / 2"
   804   have "\<bar>x0\<bar> < ?R" using assms by auto
   805   hence "- ?R < x0"
   806   proof (cases "x0 < 0")
   807     case True
   808     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   809     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   810   next
   811     case False
   812     have "- ?R < 0" using assms by auto
   813     also have "\<dots> \<le> x0" using False by auto 
   814     finally show ?thesis .
   815   qed
   816   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   817   from for_subinterval[OF this]
   818   show ?thesis .
   819 qed
   820 
   821 subsection {* Exponential Function *}
   822 
   823 definition
   824   exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   825   "exp x = (\<Sum>n. x ^ n /\<^sub>R real (fact n))"
   826 
   827 lemma summable_exp_generic:
   828   fixes x :: "'a::{real_normed_algebra_1,banach}"
   829   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   830   shows "summable S"
   831 proof -
   832   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   833     unfolding S_def by (simp del: mult_Suc)
   834   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   835     using dense [OF zero_less_one] by fast
   836   obtain N :: nat where N: "norm x < real N * r"
   837     using reals_Archimedean3 [OF r0] by fast
   838   from r1 show ?thesis
   839   proof (rule ratio_test [rule_format])
   840     fix n :: nat
   841     assume n: "N \<le> n"
   842     have "norm x \<le> real N * r"
   843       using N by (rule order_less_imp_le)
   844     also have "real N * r \<le> real (Suc n) * r"
   845       using r0 n by (simp add: mult_right_mono)
   846     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   847       using norm_ge_zero by (rule mult_right_mono)
   848     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   849       by (rule order_trans [OF norm_mult_ineq])
   850     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   851       by (simp add: pos_divide_le_eq mult_ac)
   852     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   853       by (simp add: S_Suc norm_scaleR inverse_eq_divide)
   854   qed
   855 qed
   856 
   857 lemma summable_norm_exp:
   858   fixes x :: "'a::{real_normed_algebra_1,banach}"
   859   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   860 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   861   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   862     by (rule summable_exp_generic)
   863 next
   864   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   865     by (simp add: norm_scaleR norm_power_ineq)
   866 qed
   867 
   868 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   869 by (insert summable_exp_generic [where x=x], simp)
   870 
   871 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   872 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   873 
   874 
   875 lemma exp_fdiffs: 
   876       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   877 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   878          del: mult_Suc of_nat_Suc)
   879 
   880 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   881 by (simp add: diffs_def)
   882 
   883 lemma lemma_exp_ext: "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   884 by (auto intro!: ext simp add: exp_def)
   885 
   886 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   887 apply (simp add: exp_def)
   888 apply (subst lemma_exp_ext)
   889 apply (subgoal_tac "DERIV (\<lambda>u. \<Sum>n. of_real (inverse (real (fact n))) * u ^ n) x :> (\<Sum>n. diffs (\<lambda>n. of_real (inverse (real (fact n)))) n * x ^ n)")
   890 apply (rule_tac [2] K = "of_real (1 + norm x)" in termdiffs)
   891 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   892 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   893 apply (simp del: of_real_add)
   894 done
   895 
   896 lemma isCont_exp [simp]: "isCont exp x"
   897 by (rule DERIV_exp [THEN DERIV_isCont])
   898 
   899 
   900 subsubsection {* Properties of the Exponential Function *}
   901 
   902 lemma powser_zero:
   903   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   904   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   905 proof -
   906   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   907     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   908   thus ?thesis unfolding One_nat_def by simp
   909 qed
   910 
   911 lemma exp_zero [simp]: "exp 0 = 1"
   912 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   913 
   914 lemma setsum_cl_ivl_Suc2:
   915   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   916 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   917          del: setsum_cl_ivl_Suc)
   918 
   919 lemma exp_series_add:
   920   fixes x y :: "'a::{real_field}"
   921   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   922   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   923 proof (induct n)
   924   case 0
   925   show ?case
   926     unfolding S_def by simp
   927 next
   928   case (Suc n)
   929   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   930     unfolding S_def by (simp del: mult_Suc)
   931   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   932     by simp
   933 
   934   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   935     by (simp only: times_S)
   936   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   937     by (simp only: Suc)
   938   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   939                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   940     by (rule left_distrib)
   941   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   942                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   943     by (simp only: setsum_right_distrib mult_ac)
   944   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   945                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   946     by (simp add: times_S Suc_diff_le)
   947   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   948              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   949     by (subst setsum_cl_ivl_Suc2, simp)
   950   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   951              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   952     by (subst setsum_cl_ivl_Suc, simp)
   953   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   954              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   955              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   956     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   957               real_of_nat_add [symmetric], simp)
   958   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   959     by (simp only: scaleR_right.setsum)
   960   finally show
   961     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   962     by (simp add: scaleR_cancel_left del: setsum_cl_ivl_Suc)
   963 qed
   964 
   965 lemma exp_add: "exp (x + y) = exp x * exp y"
   966 unfolding exp_def
   967 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   968 
   969 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   970 by (rule exp_add [symmetric])
   971 
   972 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   973 unfolding exp_def
   974 apply (subst of_real.suminf)
   975 apply (rule summable_exp_generic)
   976 apply (simp add: scaleR_conv_of_real)
   977 done
   978 
   979 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   980 proof
   981   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   982   also assume "exp x = 0"
   983   finally show "False" by simp
   984 qed
   985 
   986 lemma exp_minus: "exp (- x) = inverse (exp x)"
   987 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   988 
   989 lemma exp_diff: "exp (x - y) = exp x / exp y"
   990   unfolding diff_minus divide_inverse
   991   by (simp add: exp_add exp_minus)
   992 
   993 
   994 subsubsection {* Properties of the Exponential Function on Reals *}
   995 
   996 text {* Comparisons of @{term "exp x"} with zero. *}
   997 
   998 text{*Proof: because every exponential can be seen as a square.*}
   999 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
  1000 proof -
  1001   have "0 \<le> exp (x/2) * exp (x/2)" by simp
  1002   thus ?thesis by (simp add: exp_add [symmetric])
  1003 qed
  1004 
  1005 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
  1006 by (simp add: order_less_le)
  1007 
  1008 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
  1009 by (simp add: not_less)
  1010 
  1011 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
  1012 by (simp add: not_le)
  1013 
  1014 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1015 by simp
  1016 
  1017 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1018 apply (induct "n")
  1019 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1020 done
  1021 
  1022 text {* Strict monotonicity of exponential. *}
  1023 
  1024 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1025 apply (drule order_le_imp_less_or_eq, auto)
  1026 apply (simp add: exp_def)
  1027 apply (rule real_le_trans)
  1028 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1029 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1030 done
  1031 
  1032 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1033 proof -
  1034   assume x: "0 < x"
  1035   hence "1 < 1 + x" by simp
  1036   also from x have "1 + x \<le> exp x"
  1037     by (simp add: exp_ge_add_one_self_aux)
  1038   finally show ?thesis .
  1039 qed
  1040 
  1041 lemma exp_less_mono:
  1042   fixes x y :: real
  1043   assumes "x < y" shows "exp x < exp y"
  1044 proof -
  1045   from `x < y` have "0 < y - x" by simp
  1046   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1047   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1048   thus "exp x < exp y" by simp
  1049 qed
  1050 
  1051 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1052 apply (simp add: linorder_not_le [symmetric])
  1053 apply (auto simp add: order_le_less exp_less_mono)
  1054 done
  1055 
  1056 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1057 by (auto intro: exp_less_mono exp_less_cancel)
  1058 
  1059 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1060 by (auto simp add: linorder_not_less [symmetric])
  1061 
  1062 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1063 by (simp add: order_eq_iff)
  1064 
  1065 text {* Comparisons of @{term "exp x"} with one. *}
  1066 
  1067 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1068   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1069 
  1070 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1071   using exp_less_cancel_iff [where x=x and y=0] by simp
  1072 
  1073 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1074   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1075 
  1076 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1077   using exp_le_cancel_iff [where x=x and y=0] by simp
  1078 
  1079 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1080   using exp_inj_iff [where x=x and y=0] by simp
  1081 
  1082 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1083 apply (rule IVT)
  1084 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1085 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)") 
  1086 apply simp
  1087 apply (rule exp_ge_add_one_self_aux, simp)
  1088 done
  1089 
  1090 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1091 apply (rule_tac x = 1 and y = y in linorder_cases)
  1092 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1093 apply (rule_tac [2] x = 0 in exI)
  1094 apply (frule_tac [3] real_inverse_gt_one)
  1095 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1096 apply (rule_tac x = "-x" in exI)
  1097 apply (simp add: exp_minus)
  1098 done
  1099 
  1100 
  1101 subsection {* Natural Logarithm *}
  1102 
  1103 definition
  1104   ln :: "real => real" where
  1105   "ln x = (THE u. exp u = x)"
  1106 
  1107 lemma ln_exp [simp]: "ln (exp x) = x"
  1108 by (simp add: ln_def)
  1109 
  1110 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1111 by (auto dest: exp_total)
  1112 
  1113 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1114 apply (rule iffI)
  1115 apply (erule subst, rule exp_gt_zero)
  1116 apply (erule exp_ln)
  1117 done
  1118 
  1119 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1120 by (erule subst, rule ln_exp)
  1121 
  1122 lemma ln_one [simp]: "ln 1 = 0"
  1123 by (rule ln_unique, simp)
  1124 
  1125 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1126 by (rule ln_unique, simp add: exp_add)
  1127 
  1128 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1129 by (rule ln_unique, simp add: exp_minus)
  1130 
  1131 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1132 by (rule ln_unique, simp add: exp_diff)
  1133 
  1134 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1135 by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1136 
  1137 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1138 by (subst exp_less_cancel_iff [symmetric], simp)
  1139 
  1140 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1141 by (simp add: linorder_not_less [symmetric])
  1142 
  1143 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1144 by (simp add: order_eq_iff)
  1145 
  1146 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1147 apply (rule exp_le_cancel_iff [THEN iffD1])
  1148 apply (simp add: exp_ge_add_one_self_aux)
  1149 done
  1150 
  1151 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1152 by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1153 
  1154 lemma ln_ge_zero [simp]:
  1155   assumes x: "1 \<le> x" shows "0 \<le> ln x"
  1156 proof -
  1157   have "0 < x" using x by arith
  1158   hence "exp 0 \<le> exp (ln x)"
  1159     by (simp add: x)
  1160   thus ?thesis by (simp only: exp_le_cancel_iff)
  1161 qed
  1162 
  1163 lemma ln_ge_zero_imp_ge_one:
  1164   assumes ln: "0 \<le> ln x" 
  1165       and x:  "0 < x"
  1166   shows "1 \<le> x"
  1167 proof -
  1168   from ln have "ln 1 \<le> ln x" by simp
  1169   thus ?thesis by (simp add: x del: ln_one) 
  1170 qed
  1171 
  1172 lemma ln_ge_zero_iff [simp]: "0 < x ==> (0 \<le> ln x) = (1 \<le> x)"
  1173 by (blast intro: ln_ge_zero ln_ge_zero_imp_ge_one)
  1174 
  1175 lemma ln_less_zero_iff [simp]: "0 < x ==> (ln x < 0) = (x < 1)"
  1176 by (insert ln_ge_zero_iff [of x], arith)
  1177 
  1178 lemma ln_gt_zero:
  1179   assumes x: "1 < x" shows "0 < ln x"
  1180 proof -
  1181   have "0 < x" using x by arith
  1182   hence "exp 0 < exp (ln x)" by (simp add: x)
  1183   thus ?thesis  by (simp only: exp_less_cancel_iff)
  1184 qed
  1185 
  1186 lemma ln_gt_zero_imp_gt_one:
  1187   assumes ln: "0 < ln x" 
  1188       and x:  "0 < x"
  1189   shows "1 < x"
  1190 proof -
  1191   from ln have "ln 1 < ln x" by simp
  1192   thus ?thesis by (simp add: x del: ln_one) 
  1193 qed
  1194 
  1195 lemma ln_gt_zero_iff [simp]: "0 < x ==> (0 < ln x) = (1 < x)"
  1196 by (blast intro: ln_gt_zero ln_gt_zero_imp_gt_one)
  1197 
  1198 lemma ln_eq_zero_iff [simp]: "0 < x ==> (ln x = 0) = (x = 1)"
  1199 by (insert ln_less_zero_iff [of x] ln_gt_zero_iff [of x], arith)
  1200 
  1201 lemma ln_less_zero: "[| 0 < x; x < 1 |] ==> ln x < 0"
  1202 by simp
  1203 
  1204 lemma exp_ln_eq: "exp u = x ==> ln x = u"
  1205 by auto
  1206 
  1207 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1208 apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1209 apply (rule isCont_inverse_function [where f=exp], simp_all)
  1210 done
  1211 
  1212 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1213 apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1214 apply (erule lemma_DERIV_subst [OF DERIV_exp exp_ln])
  1215 apply (simp_all add: abs_if isCont_ln)
  1216 done
  1217 
  1218 lemma ln_series: assumes "0 < x" and "x < 2"
  1219   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1220 proof -
  1221   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1222 
  1223   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1224   proof (rule DERIV_isconst3[where x=x])
  1225     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1226     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1227     have "1 / x = 1 / (1 - (1 - x))" by auto
  1228     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1229     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1230     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding real_divide_def by auto
  1231     moreover
  1232     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1233     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1234     proof (rule DERIV_power_series')
  1235       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1236       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1237 	show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1238           unfolding One_nat_def
  1239 	  by (auto simp del: power_mult_distrib simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1240       }
  1241     qed
  1242     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1243     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1244     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1245       by (rule DERIV_diff)
  1246     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1247   qed (auto simp add: assms)
  1248   thus ?thesis by (auto simp add: suminf_zero)
  1249 qed
  1250 
  1251 subsection {* Sine and Cosine *}
  1252 
  1253 definition
  1254   sin_coeff :: "nat \<Rightarrow> real" where
  1255   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1256 
  1257 definition
  1258   cos_coeff :: "nat \<Rightarrow> real" where
  1259   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1260 
  1261 definition
  1262   sin :: "real => real" where
  1263   "sin x = (\<Sum>n. sin_coeff n * x ^ n)"
  1264 
  1265 definition
  1266   cos :: "real => real" where
  1267   "cos x = (\<Sum>n. cos_coeff n * x ^ n)"
  1268 
  1269 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1270 unfolding sin_coeff_def
  1271 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1272 apply (rule_tac [2] summable_exp)
  1273 apply (rule_tac x = 0 in exI)
  1274 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1275 done
  1276 
  1277 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1278 unfolding cos_coeff_def
  1279 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1280 apply (rule_tac [2] summable_exp)
  1281 apply (rule_tac x = 0 in exI)
  1282 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1283 done
  1284 
  1285 lemma lemma_STAR_sin:
  1286      "(if even n then 0  
  1287        else -1 ^ ((n - Suc 0) div 2)/(real (fact n))) * 0 ^ n = 0"
  1288 by (induct "n", auto)
  1289 
  1290 lemma lemma_STAR_cos:
  1291      "0 < n -->  
  1292       -1 ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1293 by (induct "n", auto)
  1294 
  1295 lemma lemma_STAR_cos1:
  1296      "0 < n -->  
  1297       (-1) ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1298 by (induct "n", auto)
  1299 
  1300 lemma lemma_STAR_cos2:
  1301   "(\<Sum>n=1..<n. if even n then -1 ^ (n div 2)/(real (fact n)) *  0 ^ n 
  1302                          else 0) = 0"
  1303 apply (induct "n")
  1304 apply (case_tac [2] "n", auto)
  1305 done
  1306 
  1307 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1308 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1309 
  1310 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1311 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1312 
  1313 lemma sin_fdiffs: "diffs sin_coeff = cos_coeff"
  1314 unfolding sin_coeff_def cos_coeff_def
  1315 by (auto intro!: ext 
  1316          simp add: diffs_def divide_inverse real_of_nat_def of_nat_mult
  1317          simp del: mult_Suc of_nat_Suc)
  1318 
  1319 lemma sin_fdiffs2: "diffs sin_coeff n = cos_coeff n"
  1320 by (simp only: sin_fdiffs)
  1321 
  1322 lemma cos_fdiffs: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1323 unfolding sin_coeff_def cos_coeff_def
  1324 by (auto intro!: ext 
  1325          simp add: diffs_def divide_inverse odd_Suc_mult_two_ex real_of_nat_def of_nat_mult
  1326          simp del: mult_Suc of_nat_Suc)
  1327 
  1328 lemma cos_fdiffs2: "diffs cos_coeff n = - sin_coeff n"
  1329 by (simp only: cos_fdiffs)
  1330 
  1331 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1332 
  1333 lemma lemma_sin_minus: "- sin x = (\<Sum>n. - (sin_coeff n * x ^ n))"
  1334 by (auto intro!: sums_unique sums_minus sin_converges)
  1335 
  1336 lemma lemma_sin_ext: "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1337 by (auto intro!: ext simp add: sin_def)
  1338 
  1339 lemma lemma_cos_ext: "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1340 by (auto intro!: ext simp add: cos_def)
  1341 
  1342 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1343 apply (simp add: cos_def)
  1344 apply (subst lemma_sin_ext)
  1345 apply (auto simp add: sin_fdiffs2 [symmetric])
  1346 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1347 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs)
  1348 done
  1349 
  1350 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1351 apply (subst lemma_cos_ext)
  1352 apply (auto simp add: lemma_sin_minus cos_fdiffs2 [symmetric] minus_mult_left)
  1353 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1354 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs diffs_minus)
  1355 done
  1356 
  1357 lemma isCont_sin [simp]: "isCont sin x"
  1358 by (rule DERIV_sin [THEN DERIV_isCont])
  1359 
  1360 lemma isCont_cos [simp]: "isCont cos x"
  1361 by (rule DERIV_cos [THEN DERIV_isCont])
  1362 
  1363 
  1364 declare
  1365   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1366   DERIV_ln[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1367   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1368   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1369 
  1370 subsection {* Properties of Sine and Cosine *}
  1371 
  1372 lemma sin_zero [simp]: "sin 0 = 0"
  1373 unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1374 
  1375 lemma cos_zero [simp]: "cos 0 = 1"
  1376 unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1377 
  1378 lemma DERIV_sin_sin_mult [simp]:
  1379      "DERIV (%x. sin(x)*sin(x)) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1380 by (rule DERIV_mult, auto)
  1381 
  1382 lemma DERIV_sin_sin_mult2 [simp]:
  1383      "DERIV (%x. sin(x)*sin(x)) x :> 2 * cos(x) * sin(x)"
  1384 apply (cut_tac x = x in DERIV_sin_sin_mult)
  1385 apply (auto simp add: mult_assoc)
  1386 done
  1387 
  1388 lemma DERIV_sin_realpow2 [simp]:
  1389      "DERIV (%x. (sin x)\<twosuperior>) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1390 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1391 
  1392 lemma DERIV_sin_realpow2a [simp]:
  1393      "DERIV (%x. (sin x)\<twosuperior>) x :> 2 * cos(x) * sin(x)"
  1394 by (auto simp add: numeral_2_eq_2)
  1395 
  1396 lemma DERIV_cos_cos_mult [simp]:
  1397      "DERIV (%x. cos(x)*cos(x)) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1398 by (rule DERIV_mult, auto)
  1399 
  1400 lemma DERIV_cos_cos_mult2 [simp]:
  1401      "DERIV (%x. cos(x)*cos(x)) x :> -2 * cos(x) * sin(x)"
  1402 apply (cut_tac x = x in DERIV_cos_cos_mult)
  1403 apply (auto simp add: mult_ac)
  1404 done
  1405 
  1406 lemma DERIV_cos_realpow2 [simp]:
  1407      "DERIV (%x. (cos x)\<twosuperior>) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1408 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1409 
  1410 lemma DERIV_cos_realpow2a [simp]:
  1411      "DERIV (%x. (cos x)\<twosuperior>) x :> -2 * cos(x) * sin(x)"
  1412 by (auto simp add: numeral_2_eq_2)
  1413 
  1414 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1415 by auto
  1416 
  1417 lemma DERIV_cos_realpow2b: "DERIV (%x. (cos x)\<twosuperior>) x :> -(2 * cos(x) * sin(x))"
  1418   by (auto intro!: DERIV_intros)
  1419 
  1420 (* most useful *)
  1421 lemma DERIV_cos_cos_mult3 [simp]:
  1422      "DERIV (%x. cos(x)*cos(x)) x :> -(2 * cos(x) * sin(x))"
  1423   by (auto intro!: DERIV_intros)
  1424 
  1425 lemma DERIV_sin_circle_all: 
  1426      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :>  
  1427              (2*cos(x)*sin(x) - 2*cos(x)*sin(x))"
  1428   by (auto intro!: DERIV_intros)
  1429 
  1430 lemma DERIV_sin_circle_all_zero [simp]:
  1431      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1432 by (cut_tac DERIV_sin_circle_all, auto)
  1433 
  1434 lemma sin_cos_squared_add [simp]: "((sin x)\<twosuperior>) + ((cos x)\<twosuperior>) = 1"
  1435 apply (cut_tac x = x and y = 0 in DERIV_sin_circle_all_zero [THEN DERIV_isconst_all])
  1436 apply (auto simp add: numeral_2_eq_2)
  1437 done
  1438 
  1439 lemma sin_cos_squared_add2 [simp]: "((cos x)\<twosuperior>) + ((sin x)\<twosuperior>) = 1"
  1440 apply (subst add_commute)
  1441 apply (rule sin_cos_squared_add)
  1442 done
  1443 
  1444 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1445 apply (cut_tac x = x in sin_cos_squared_add2)
  1446 apply (simp add: power2_eq_square)
  1447 done
  1448 
  1449 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1450 apply (rule_tac a1 = "(cos x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1451 apply simp
  1452 done
  1453 
  1454 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1455 apply (rule_tac a1 = "(sin x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1456 apply simp
  1457 done
  1458 
  1459 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1460 by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1461 
  1462 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1463 apply (insert abs_sin_le_one [of x]) 
  1464 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1465 done
  1466 
  1467 lemma sin_le_one [simp]: "sin x \<le> 1"
  1468 apply (insert abs_sin_le_one [of x]) 
  1469 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1470 done
  1471 
  1472 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1473 by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1474 
  1475 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1476 apply (insert abs_cos_le_one [of x]) 
  1477 apply (simp add: abs_le_iff del: abs_cos_le_one) 
  1478 done
  1479 
  1480 lemma cos_le_one [simp]: "cos x \<le> 1"
  1481 apply (insert abs_cos_le_one [of x]) 
  1482 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1483 done
  1484 
  1485 lemma DERIV_fun_pow: "DERIV g x :> m ==>  
  1486       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1487 unfolding One_nat_def
  1488 apply (rule lemma_DERIV_subst)
  1489 apply (rule_tac f = "(%x. x ^ n)" in DERIV_chain2)
  1490 apply (rule DERIV_pow, auto)
  1491 done
  1492 
  1493 lemma DERIV_fun_exp:
  1494      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1495 apply (rule lemma_DERIV_subst)
  1496 apply (rule_tac f = exp in DERIV_chain2)
  1497 apply (rule DERIV_exp, auto)
  1498 done
  1499 
  1500 lemma DERIV_fun_sin:
  1501      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1502 apply (rule lemma_DERIV_subst)
  1503 apply (rule_tac f = sin in DERIV_chain2)
  1504 apply (rule DERIV_sin, auto)
  1505 done
  1506 
  1507 lemma DERIV_fun_cos:
  1508      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1509 apply (rule lemma_DERIV_subst)
  1510 apply (rule_tac f = cos in DERIV_chain2)
  1511 apply (rule DERIV_cos, auto)
  1512 done
  1513 
  1514 (* lemma *)
  1515 lemma lemma_DERIV_sin_cos_add:
  1516      "\<forall>x.  
  1517          DERIV (%x. (sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1518                (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2) x :> 0"
  1519   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1520 
  1521 lemma sin_cos_add [simp]:
  1522      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1523       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1524 apply (cut_tac y = 0 and x = x and y7 = y 
  1525        in lemma_DERIV_sin_cos_add [THEN DERIV_isconst_all])
  1526 apply (auto simp add: numeral_2_eq_2)
  1527 done
  1528 
  1529 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1530 apply (cut_tac x = x and y = y in sin_cos_add)
  1531 apply (simp del: sin_cos_add)
  1532 done
  1533 
  1534 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1535 apply (cut_tac x = x and y = y in sin_cos_add)
  1536 apply (simp del: sin_cos_add)
  1537 done
  1538 
  1539 lemma lemma_DERIV_sin_cos_minus:
  1540     "\<forall>x. DERIV (%x. (sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2) x :> 0"
  1541   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1542 
  1543 
  1544 lemma sin_cos_minus: 
  1545     "(sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2 = 0"
  1546 apply (cut_tac y = 0 and x = x 
  1547        in lemma_DERIV_sin_cos_minus [THEN DERIV_isconst_all])
  1548 apply simp
  1549 done
  1550 
  1551 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1552   using sin_cos_minus [where x=x] by simp
  1553 
  1554 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1555   using sin_cos_minus [where x=x] by simp
  1556 
  1557 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1558 by (simp add: diff_minus sin_add)
  1559 
  1560 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1561 by (simp add: sin_diff mult_commute)
  1562 
  1563 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1564 by (simp add: diff_minus cos_add)
  1565 
  1566 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1567 by (simp add: cos_diff mult_commute)
  1568 
  1569 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1570   using sin_add [where x=x and y=x] by simp
  1571 
  1572 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1573   using cos_add [where x=x and y=x]
  1574   by (simp add: power2_eq_square)
  1575 
  1576 
  1577 subsection {* The Constant Pi *}
  1578 
  1579 definition
  1580   pi :: "real" where
  1581   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1582 
  1583 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"}; 
  1584    hence define pi.*}
  1585 
  1586 lemma sin_paired:
  1587      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1)) 
  1588       sums  sin x"
  1589 proof -
  1590   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1591     unfolding sin_def
  1592     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp) 
  1593   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1594 qed
  1595 
  1596 text {* FIXME: This is a long, ugly proof! *}
  1597 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1598 apply (subgoal_tac 
  1599        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1600               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1)) 
  1601      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1602  prefer 2
  1603  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp) 
  1604 apply (rotate_tac 2)
  1605 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1606 unfolding One_nat_def
  1607 apply (auto simp del: fact_Suc)
  1608 apply (frule sums_unique)
  1609 apply (auto simp del: fact_Suc)
  1610 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1611 apply (auto simp del: fact_Suc)
  1612 apply (erule sums_summable)
  1613 apply (case_tac "m=0")
  1614 apply (simp (no_asm_simp))
  1615 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x") 
  1616 apply (simp only: mult_less_cancel_left, simp)  
  1617 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1618 apply (subgoal_tac "x*x < 2*3", simp) 
  1619 apply (rule mult_strict_mono)
  1620 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1621 apply (subst fact_Suc)
  1622 apply (subst fact_Suc)
  1623 apply (subst fact_Suc)
  1624 apply (subst fact_Suc)
  1625 apply (subst real_of_nat_mult)
  1626 apply (subst real_of_nat_mult)
  1627 apply (subst real_of_nat_mult)
  1628 apply (subst real_of_nat_mult)
  1629 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1630 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1631 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right) 
  1632 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1633 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right) 
  1634 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1635 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)") 
  1636 apply (erule ssubst)+
  1637 apply (auto simp del: fact_Suc)
  1638 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1639  prefer 2 apply (simp only: zero_less_power) 
  1640 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1641 apply (rule mult_strict_mono)
  1642 apply (simp_all (no_asm_simp))
  1643 done
  1644 
  1645 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1646 by (auto intro: sin_gt_zero)
  1647 
  1648 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1649 apply (cut_tac x = x in sin_gt_zero1)
  1650 apply (auto simp add: cos_squared_eq cos_double)
  1651 done
  1652 
  1653 lemma cos_paired:
  1654      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1655 proof -
  1656   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1657     unfolding cos_def
  1658     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp) 
  1659   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1660 qed
  1661 
  1662 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1663 by simp
  1664 
  1665 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1666 apply (cut_tac x = 2 in cos_paired)
  1667 apply (drule sums_minus)
  1668 apply (rule neg_less_iff_less [THEN iffD1]) 
  1669 apply (frule sums_unique, auto)
  1670 apply (rule_tac y =
  1671  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1672        in order_less_trans)
  1673 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1674 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1675 apply (rule sumr_pos_lt_pair)
  1676 apply (erule sums_summable, safe)
  1677 unfolding One_nat_def
  1678 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric] 
  1679             del: fact_Suc)
  1680 apply (rule real_mult_inverse_cancel2)
  1681 apply (rule real_of_nat_fact_gt_zero)+
  1682 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1683 apply (subst fact_lemma) 
  1684 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1685 apply (simp only: real_of_nat_mult)
  1686 apply (rule mult_strict_mono, force)
  1687   apply (rule_tac [3] real_of_nat_ge_zero)
  1688  prefer 2 apply force
  1689 apply (rule real_of_nat_less_iff [THEN iffD2])
  1690 apply (rule fact_less_mono_nat, auto)
  1691 done
  1692 
  1693 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1694 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1695 
  1696 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1697 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1698 apply (rule_tac [2] IVT2)
  1699 apply (auto intro: DERIV_isCont DERIV_cos)
  1700 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1701 apply (rule ccontr)
  1702 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1703 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1704 apply (drule_tac f = cos in Rolle)
  1705 apply (drule_tac [5] f = cos in Rolle)
  1706 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1707 apply (drule_tac y1 = xa in order_le_less_trans [THEN sin_gt_zero])
  1708 apply (assumption, rule_tac y=y in order_less_le_trans, simp_all) 
  1709 apply (drule_tac y1 = y in order_le_less_trans [THEN sin_gt_zero], assumption, simp_all) 
  1710 done
  1711 
  1712 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1713 by (simp add: pi_def)
  1714 
  1715 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1716 by (simp add: pi_half cos_is_zero [THEN theI'])
  1717 
  1718 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1719 apply (rule order_le_neq_trans)
  1720 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1721 apply (rule notI, drule arg_cong [where f=cos], simp)
  1722 done
  1723 
  1724 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1725 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1726 
  1727 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1728 apply (rule order_le_neq_trans)
  1729 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1730 apply (rule notI, drule arg_cong [where f=cos], simp)
  1731 done
  1732 
  1733 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1734 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1735 
  1736 lemma pi_gt_zero [simp]: "0 < pi"
  1737 by (insert pi_half_gt_zero, simp)
  1738 
  1739 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1740 by (rule pi_gt_zero [THEN order_less_imp_le])
  1741 
  1742 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1743 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1744 
  1745 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1746 by (simp add: linorder_not_less)
  1747 
  1748 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1749 by simp
  1750 
  1751 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1752 proof -
  1753   have "- (2 * pi) < 0" and "0 < pi" by auto
  1754   from order_less_trans[OF this] show ?thesis .
  1755 qed
  1756 
  1757 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1758 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1759 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1760 apply (simp add: power2_eq_square)
  1761 done
  1762 
  1763 lemma cos_pi [simp]: "cos pi = -1"
  1764 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1765 
  1766 lemma sin_pi [simp]: "sin pi = 0"
  1767 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1768 
  1769 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1770 by (simp add: diff_minus cos_add)
  1771 declare sin_cos_eq [symmetric, simp]
  1772 
  1773 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1774 by (simp add: cos_add)
  1775 declare minus_sin_cos_eq [symmetric, simp]
  1776 
  1777 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1778 by (simp add: diff_minus sin_add)
  1779 declare cos_sin_eq [symmetric, simp]
  1780 
  1781 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1782 by (simp add: sin_add)
  1783 
  1784 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1785 by (simp add: sin_add)
  1786 
  1787 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1788 by (simp add: cos_add)
  1789 
  1790 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1791 by (simp add: sin_add cos_double)
  1792 
  1793 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1794 by (simp add: cos_add cos_double)
  1795 
  1796 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1797 apply (induct "n")
  1798 apply (auto simp add: real_of_nat_Suc left_distrib)
  1799 done
  1800 
  1801 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1802 proof -
  1803   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1804   also have "... = -1 ^ n" by (rule cos_npi) 
  1805   finally show ?thesis .
  1806 qed
  1807 
  1808 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1809 apply (induct "n")
  1810 apply (auto simp add: real_of_nat_Suc left_distrib)
  1811 done
  1812 
  1813 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1814 by (simp add: mult_commute [of pi]) 
  1815 
  1816 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1817 by (simp add: cos_double)
  1818 
  1819 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1820 by simp
  1821 
  1822 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1823 apply (rule sin_gt_zero, assumption)
  1824 apply (rule order_less_trans, assumption)
  1825 apply (rule pi_half_less_two)
  1826 done
  1827 
  1828 lemma sin_less_zero: 
  1829   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1830 proof -
  1831   have "0 < sin (- x)" using prems by (simp only: sin_gt_zero2) 
  1832   thus ?thesis by simp
  1833 qed
  1834 
  1835 lemma pi_less_4: "pi < 4"
  1836 by (cut_tac pi_half_less_two, auto)
  1837 
  1838 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1839 apply (cut_tac pi_less_4)
  1840 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1841 apply (cut_tac cos_is_zero, safe)
  1842 apply (rename_tac y z)
  1843 apply (drule_tac x = y in spec)
  1844 apply (drule_tac x = "pi/2" in spec, simp) 
  1845 done
  1846 
  1847 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1848 apply (rule_tac x = x and y = 0 in linorder_cases)
  1849 apply (rule cos_minus [THEN subst])
  1850 apply (rule cos_gt_zero)
  1851 apply (auto intro: cos_gt_zero)
  1852 done
  1853  
  1854 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1855 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1856 apply (subgoal_tac "x = pi/2", auto) 
  1857 done
  1858 
  1859 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1860 apply (subst sin_cos_eq)
  1861 apply (rotate_tac 1)
  1862 apply (drule real_sum_of_halves [THEN ssubst])
  1863 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1864 done
  1865 
  1866 
  1867 lemma pi_ge_two: "2 \<le> pi"
  1868 proof (rule ccontr)
  1869   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1870   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1871   proof (cases "2 < 2 * pi")
  1872     case True with dense[OF `pi < 2`] show ?thesis by auto
  1873   next
  1874     case False have "pi < 2 * pi" by auto
  1875     from dense[OF this] and False show ?thesis by auto
  1876   qed
  1877   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1878   hence "0 < sin y" using sin_gt_zero by auto
  1879   moreover 
  1880   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1881   ultimately show False by auto
  1882 qed
  1883 
  1884 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1885 by (auto simp add: order_le_less sin_gt_zero_pi)
  1886 
  1887 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1888 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1889 apply (rule_tac [2] IVT2)
  1890 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1891 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1892 apply (rule ccontr, auto)
  1893 apply (drule_tac f = cos in Rolle)
  1894 apply (drule_tac [5] f = cos in Rolle)
  1895 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1896             dest!: DERIV_cos [THEN DERIV_unique] 
  1897             simp add: differentiable_def)
  1898 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1899 done
  1900 
  1901 lemma sin_total:
  1902      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1903 apply (rule ccontr)
  1904 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1905 apply (erule contrapos_np)
  1906 apply (simp del: minus_sin_cos_eq [symmetric])
  1907 apply (cut_tac y="-y" in cos_total, simp) apply simp 
  1908 apply (erule ex1E)
  1909 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1910 apply (simp (no_asm) add: add_assoc)
  1911 apply (rotate_tac 3)
  1912 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all) 
  1913 done
  1914 
  1915 lemma reals_Archimedean4:
  1916      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1917 apply (auto dest!: reals_Archimedean3)
  1918 apply (drule_tac x = x in spec, clarify) 
  1919 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1920  prefer 2 apply (erule LeastI) 
  1921 apply (case_tac "LEAST m::nat. x < real m * y", simp) 
  1922 apply (subgoal_tac "~ x < real nat * y")
  1923  prefer 2 apply (rule not_less_Least, simp, force)  
  1924 done
  1925 
  1926 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic 
  1927    now causes some unwanted re-arrangements of literals!   *)
  1928 lemma cos_zero_lemma:
  1929      "[| 0 \<le> x; cos x = 0 |] ==>  
  1930       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1931 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1932 apply (subgoal_tac "0 \<le> x - real n * pi & 
  1933                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1934 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1935  prefer 2 apply (simp add: cos_diff)
  1936 apply (simp add: cos_diff)
  1937 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1938 apply (rule_tac [2] cos_total, safe)
  1939 apply (drule_tac x = "x - real n * pi" in spec)
  1940 apply (drule_tac x = "pi/2" in spec)
  1941 apply (simp add: cos_diff)
  1942 apply (rule_tac x = "Suc (2 * n)" in exI)
  1943 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1944 done
  1945 
  1946 lemma sin_zero_lemma:
  1947      "[| 0 \<le> x; sin x = 0 |] ==>  
  1948       \<exists>n::nat. even n & x = real n * (pi/2)"
  1949 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1950  apply (clarify, rule_tac x = "n - 1" in exI)
  1951  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1952 apply (rule cos_zero_lemma)
  1953 apply (simp_all add: add_increasing)  
  1954 done
  1955 
  1956 
  1957 lemma cos_zero_iff:
  1958      "(cos x = 0) =  
  1959       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |    
  1960        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1961 apply (rule iffI)
  1962 apply (cut_tac linorder_linear [of 0 x], safe)
  1963 apply (drule cos_zero_lemma, assumption+)
  1964 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp) 
  1965 apply (force simp add: minus_equation_iff [of x]) 
  1966 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib) 
  1967 apply (auto simp add: cos_add)
  1968 done
  1969 
  1970 (* ditto: but to a lesser extent *)
  1971 lemma sin_zero_iff:
  1972      "(sin x = 0) =  
  1973       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |    
  1974        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1975 apply (rule iffI)
  1976 apply (cut_tac linorder_linear [of 0 x], safe)
  1977 apply (drule sin_zero_lemma, assumption+)
  1978 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1979 apply (force simp add: minus_equation_iff [of x]) 
  1980 apply (auto simp add: even_mult_two_ex)
  1981 done
  1982 
  1983 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1984   shows "cos x < cos y"
  1985 proof -
  1986   have "- (x - y) < 0" by (auto!)
  1987 
  1988   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1989   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1990   hence "0 < z" and "z < pi" by (auto!)
  1991   hence "0 < sin z" using sin_gt_zero_pi by auto
  1992   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1993   thus ?thesis by auto
  1994 qed
  1995 
  1996 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1997 proof (cases "y < x")
  1998   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1999 next
  2000   case False hence "y = x" using `y \<le> x` by auto
  2001   thus ?thesis by auto
  2002 qed
  2003 
  2004 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2005   shows "cos y < cos x"
  2006 proof -
  2007   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" by (auto!)
  2008   from cos_monotone_0_pi[OF this]
  2009   show ?thesis unfolding cos_minus .
  2010 qed
  2011 
  2012 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2013 proof (cases "y < x")
  2014   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2015 next
  2016   case False hence "y = x" using `y \<le> x` by auto
  2017   thus ?thesis by auto
  2018 qed
  2019 
  2020 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2021 proof -
  2022   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi" using pi_ge_two by (auto!)
  2023   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2024 qed
  2025 
  2026 subsection {* Tangent *}
  2027 
  2028 definition
  2029   tan :: "real => real" where
  2030   "tan x = (sin x)/(cos x)"
  2031 
  2032 lemma tan_zero [simp]: "tan 0 = 0"
  2033 by (simp add: tan_def)
  2034 
  2035 lemma tan_pi [simp]: "tan pi = 0"
  2036 by (simp add: tan_def)
  2037 
  2038 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2039 by (simp add: tan_def)
  2040 
  2041 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2042 by (simp add: tan_def minus_mult_left)
  2043 
  2044 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2045 by (simp add: tan_def)
  2046 
  2047 lemma lemma_tan_add1: 
  2048       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2049         ==> 1 - tan(x)*tan(y) = cos (x + y)/(cos x * cos y)"
  2050 apply (simp add: tan_def divide_inverse)
  2051 apply (auto simp del: inverse_mult_distrib 
  2052             simp add: inverse_mult_distrib [symmetric] mult_ac)
  2053 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2054 apply (auto simp del: inverse_mult_distrib 
  2055             simp add: mult_assoc left_diff_distrib cos_add)
  2056 done
  2057 
  2058 lemma add_tan_eq: 
  2059       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2060        ==> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2061 apply (simp add: tan_def)
  2062 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2063 apply (auto simp add: mult_assoc left_distrib)
  2064 apply (simp add: sin_add)
  2065 done
  2066 
  2067 lemma tan_add:
  2068      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]  
  2069       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2070 apply (simp (no_asm_simp) add: add_tan_eq lemma_tan_add1)
  2071 apply (simp add: tan_def)
  2072 done
  2073 
  2074 lemma tan_double:
  2075      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]  
  2076       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2077 apply (insert tan_add [of x x]) 
  2078 apply (simp add: mult_2 [symmetric])  
  2079 apply (auto simp add: numeral_2_eq_2)
  2080 done
  2081 
  2082 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2083 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi) 
  2084 
  2085 lemma tan_less_zero: 
  2086   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2087 proof -
  2088   have "0 < tan (- x)" using prems by (simp only: tan_gt_zero) 
  2089   thus ?thesis by simp
  2090 qed
  2091 
  2092 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  2093   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2094 proof -
  2095   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  2096   have "cos x \<noteq> 0" by auto
  2097 
  2098   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  2099 
  2100   have "tan x = (tan x + tan x) / 2" by auto
  2101   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  2102   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  2103   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  2104   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  2105   finally show ?thesis .
  2106 qed
  2107 
  2108 lemma lemma_DERIV_tan:
  2109      "cos x \<noteq> 0 ==> DERIV (%x. sin(x)/cos(x)) x :> inverse((cos x)\<twosuperior>)"
  2110   by (auto intro!: DERIV_intros simp add: field_simps numeral_2_eq_2)
  2111 
  2112 lemma DERIV_tan [simp]: "cos x \<noteq> 0 ==> DERIV tan x :> inverse((cos x)\<twosuperior>)"
  2113 by (auto dest: lemma_DERIV_tan simp add: tan_def [symmetric])
  2114 
  2115 lemma isCont_tan [simp]: "cos x \<noteq> 0 ==> isCont tan x"
  2116 by (rule DERIV_tan [THEN DERIV_isCont])
  2117 
  2118 lemma LIM_cos_div_sin [simp]: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2119 apply (subgoal_tac "(\<lambda>x. cos x * inverse (sin x)) -- pi * inverse 2 --> 0*1")
  2120 apply (simp add: divide_inverse [symmetric])
  2121 apply (rule LIM_mult)
  2122 apply (rule_tac [2] inverse_1 [THEN subst])
  2123 apply (rule_tac [2] LIM_inverse)
  2124 apply (simp_all add: divide_inverse [symmetric]) 
  2125 apply (simp_all only: isCont_def [symmetric] cos_pi_half [symmetric] sin_pi_half [symmetric]) 
  2126 apply (blast intro!: DERIV_isCont DERIV_sin DERIV_cos)+
  2127 done
  2128 
  2129 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2130 apply (cut_tac LIM_cos_div_sin)
  2131 apply (simp only: LIM_eq)
  2132 apply (drule_tac x = "inverse y" in spec, safe, force)
  2133 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2134 apply (rule_tac x = "(pi/2) - e" in exI)
  2135 apply (simp (no_asm_simp))
  2136 apply (drule_tac x = "(pi/2) - e" in spec)
  2137 apply (auto simp add: tan_def)
  2138 apply (rule inverse_less_iff_less [THEN iffD1])
  2139 apply (auto simp add: divide_inverse)
  2140 apply (rule real_mult_order) 
  2141 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2142 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute) 
  2143 done
  2144 
  2145 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2146 apply (frule order_le_imp_less_or_eq, safe)
  2147  prefer 2 apply force
  2148 apply (drule lemma_tan_total, safe)
  2149 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2150 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2151 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2152 apply (auto dest: cos_gt_zero)
  2153 done
  2154 
  2155 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2156 apply (cut_tac linorder_linear [of 0 y], safe)
  2157 apply (drule tan_total_pos)
  2158 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2159 apply (rule_tac [3] x = "-x" in exI)
  2160 apply (auto intro!: exI)
  2161 done
  2162 
  2163 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2164 apply (cut_tac y = y in lemma_tan_total1, auto)
  2165 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2166 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2167 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2168 apply (rule_tac [4] Rolle)
  2169 apply (rule_tac [2] Rolle)
  2170 apply (auto intro!: DERIV_tan DERIV_isCont exI 
  2171             simp add: differentiable_def)
  2172 txt{*Now, simulate TRYALL*}
  2173 apply (rule_tac [!] DERIV_tan asm_rl)
  2174 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2175 	    simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym]) 
  2176 done
  2177 
  2178 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2179   shows "tan y < tan x"
  2180 proof -
  2181   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2182   proof (rule allI, rule impI)
  2183     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2184     hence "-(pi/2) < x'" and "x' < pi/2" by (auto!)
  2185     from cos_gt_zero_pi[OF this]
  2186     have "cos x' \<noteq> 0" by auto
  2187     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2188   qed
  2189   from MVT2[OF `y < x` this] 
  2190   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2191   hence "- (pi / 2) < z" and "z < pi / 2" by (auto!)
  2192   hence "0 < cos z" using cos_gt_zero_pi by auto
  2193   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2194   have "0 < x - y" using `y < x` by auto
  2195   from real_mult_order[OF this inv_pos]
  2196   have "0 < tan x - tan y" unfolding tan_diff by auto
  2197   thus ?thesis by auto
  2198 qed
  2199 
  2200 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2201   shows "(y < x) = (tan y < tan x)"
  2202 proof
  2203   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2204 next
  2205   assume "tan y < tan x"
  2206   show "y < x"
  2207   proof (rule ccontr)
  2208     assume "\<not> y < x" hence "x \<le> y" by auto
  2209     hence "tan x \<le> tan y" 
  2210     proof (cases "x = y")
  2211       case True thus ?thesis by auto
  2212     next
  2213       case False hence "x < y" using `x \<le> y` by auto
  2214       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2215     qed
  2216     thus False using `tan y < tan x` by auto
  2217   qed
  2218 qed
  2219 
  2220 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2221 
  2222 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x" 
  2223   by (simp add: tan_def)
  2224 
  2225 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x" 
  2226 proof (induct n arbitrary: x)
  2227   case (Suc n)
  2228   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one real_add_mult_distrib by auto
  2229   show ?case unfolding split_pi_off using Suc by auto
  2230 qed auto
  2231 
  2232 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2233 proof (cases "0 \<le> i")
  2234   case True hence i_nat: "real i = real (nat i)" by auto
  2235   show ?thesis unfolding i_nat by auto
  2236 next
  2237   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2238   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2239   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2240   finally show ?thesis by auto
  2241 qed
  2242 
  2243 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2244   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2245 
  2246 subsection {* Inverse Trigonometric Functions *}
  2247 
  2248 definition
  2249   arcsin :: "real => real" where
  2250   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2251 
  2252 definition
  2253   arccos :: "real => real" where
  2254   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2255 
  2256 definition     
  2257   arctan :: "real => real" where
  2258   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2259 
  2260 lemma arcsin:
  2261      "[| -1 \<le> y; y \<le> 1 |]  
  2262       ==> -(pi/2) \<le> arcsin y &  
  2263            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2264 unfolding arcsin_def by (rule theI' [OF sin_total])
  2265 
  2266 lemma arcsin_pi:
  2267      "[| -1 \<le> y; y \<le> 1 |]  
  2268       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2269 apply (drule (1) arcsin)
  2270 apply (force intro: order_trans)
  2271 done
  2272 
  2273 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2274 by (blast dest: arcsin)
  2275       
  2276 lemma arcsin_bounded:
  2277      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2278 by (blast dest: arcsin)
  2279 
  2280 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2281 by (blast dest: arcsin)
  2282 
  2283 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2284 by (blast dest: arcsin)
  2285 
  2286 lemma arcsin_lt_bounded:
  2287      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2288 apply (frule order_less_imp_le)
  2289 apply (frule_tac y = y in order_less_imp_le)
  2290 apply (frule arcsin_bounded)
  2291 apply (safe, simp)
  2292 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2293 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2294 apply (drule_tac [!] f = sin in arg_cong, auto)
  2295 done
  2296 
  2297 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2298 apply (unfold arcsin_def)
  2299 apply (rule the1_equality)
  2300 apply (rule sin_total, auto)
  2301 done
  2302 
  2303 lemma arccos:
  2304      "[| -1 \<le> y; y \<le> 1 |]  
  2305       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2306 unfolding arccos_def by (rule theI' [OF cos_total])
  2307 
  2308 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2309 by (blast dest: arccos)
  2310       
  2311 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2312 by (blast dest: arccos)
  2313 
  2314 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2315 by (blast dest: arccos)
  2316 
  2317 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2318 by (blast dest: arccos)
  2319 
  2320 lemma arccos_lt_bounded:
  2321      "[| -1 < y; y < 1 |]  
  2322       ==> 0 < arccos y & arccos y < pi"
  2323 apply (frule order_less_imp_le)
  2324 apply (frule_tac y = y in order_less_imp_le)
  2325 apply (frule arccos_bounded, auto)
  2326 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2327 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2328 apply (drule_tac [!] f = cos in arg_cong, auto)
  2329 done
  2330 
  2331 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2332 apply (simp add: arccos_def)
  2333 apply (auto intro!: the1_equality cos_total)
  2334 done
  2335 
  2336 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2337 apply (simp add: arccos_def)
  2338 apply (auto intro!: the1_equality cos_total)
  2339 done
  2340 
  2341 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2342 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2343 apply (rule power2_eq_imp_eq)
  2344 apply (simp add: cos_squared_eq)
  2345 apply (rule cos_ge_zero)
  2346 apply (erule (1) arcsin_lbound)
  2347 apply (erule (1) arcsin_ubound)
  2348 apply simp
  2349 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2350 apply (rule power_mono, simp, simp)
  2351 done
  2352 
  2353 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2354 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2355 apply (rule power2_eq_imp_eq)
  2356 apply (simp add: sin_squared_eq)
  2357 apply (rule sin_ge_zero)
  2358 apply (erule (1) arccos_lbound)
  2359 apply (erule (1) arccos_ubound)
  2360 apply simp
  2361 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2362 apply (rule power_mono, simp, simp)
  2363 done
  2364 
  2365 lemma arctan [simp]:
  2366      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2367 unfolding arctan_def by (rule theI' [OF tan_total])
  2368 
  2369 lemma tan_arctan: "tan(arctan y) = y"
  2370 by auto
  2371 
  2372 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2373 by (auto simp only: arctan)
  2374 
  2375 lemma arctan_lbound: "- (pi/2) < arctan y"
  2376 by auto
  2377 
  2378 lemma arctan_ubound: "arctan y < pi/2"
  2379 by (auto simp only: arctan)
  2380 
  2381 lemma arctan_tan: 
  2382       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2383 apply (unfold arctan_def)
  2384 apply (rule the1_equality)
  2385 apply (rule tan_total, auto)
  2386 done
  2387 
  2388 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2389 by (insert arctan_tan [of 0], simp)
  2390 
  2391 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2392 apply (auto simp add: cos_zero_iff)
  2393 apply (case_tac "n")
  2394 apply (case_tac [3] "n")
  2395 apply (cut_tac [2] y = x in arctan_ubound)
  2396 apply (cut_tac [4] y = x in arctan_lbound) 
  2397 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2398 done
  2399 
  2400 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2401 apply (rule power_inverse [THEN subst])
  2402 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2403 apply (auto dest: field_power_not_zero
  2404         simp add: power_mult_distrib left_distrib power_divide tan_def 
  2405                   mult_assoc power_inverse [symmetric])
  2406 done
  2407 
  2408 lemma isCont_inverse_function2:
  2409   fixes f g :: "real \<Rightarrow> real" shows
  2410   "\<lbrakk>a < x; x < b;
  2411     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2412     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2413    \<Longrightarrow> isCont g (f x)"
  2414 apply (rule isCont_inverse_function
  2415        [where f=f and d="min (x - a) (b - x)"])
  2416 apply (simp_all add: abs_le_iff)
  2417 done
  2418 
  2419 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2420 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2421 apply (rule isCont_inverse_function2 [where f=sin])
  2422 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2423 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2424 apply (fast intro: arcsin_sin, simp)
  2425 done
  2426 
  2427 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2428 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2429 apply (rule isCont_inverse_function2 [where f=cos])
  2430 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2431 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2432 apply (fast intro: arccos_cos, simp)
  2433 done
  2434 
  2435 lemma isCont_arctan: "isCont arctan x"
  2436 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2437 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2438 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2439 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2440 apply (clarify, rule arctan_tan)
  2441 apply (erule (1) order_less_le_trans)
  2442 apply (erule (1) order_le_less_trans)
  2443 apply (clarify, rule isCont_tan)
  2444 apply (rule less_imp_neq [symmetric])
  2445 apply (rule cos_gt_zero_pi)
  2446 apply (erule (1) order_less_le_trans)
  2447 apply (erule (1) order_le_less_trans)
  2448 done
  2449 
  2450 lemma DERIV_arcsin:
  2451   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2452 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2453 apply (rule lemma_DERIV_subst [OF DERIV_sin])
  2454 apply (simp add: cos_arcsin)
  2455 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2456 apply (rule power_strict_mono, simp, simp, simp)
  2457 apply assumption
  2458 apply assumption
  2459 apply simp
  2460 apply (erule (1) isCont_arcsin)
  2461 done
  2462 
  2463 lemma DERIV_arccos:
  2464   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2465 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2466 apply (rule lemma_DERIV_subst [OF DERIV_cos])
  2467 apply (simp add: sin_arccos)
  2468 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2469 apply (rule power_strict_mono, simp, simp, simp)
  2470 apply assumption
  2471 apply assumption
  2472 apply simp
  2473 apply (erule (1) isCont_arccos)
  2474 done
  2475 
  2476 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2477 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2478 apply (rule lemma_DERIV_subst [OF DERIV_tan])
  2479 apply (rule cos_arctan_not_zero)
  2480 apply (simp add: power_inverse tan_sec [symmetric])
  2481 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2482 apply (simp add: add_pos_nonneg)
  2483 apply (simp, simp, simp, rule isCont_arctan)
  2484 done
  2485 
  2486 declare
  2487   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2488   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2489   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2490 
  2491 subsection {* More Theorems about Sin and Cos *}
  2492 
  2493 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2494 proof -
  2495   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2496   have nonneg: "0 \<le> ?c"
  2497     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2498   have "0 = cos (pi / 4 + pi / 4)"
  2499     by simp
  2500   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2501     by (simp only: cos_add power2_eq_square)
  2502   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2503     by (simp add: sin_squared_eq)
  2504   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2505     by (simp add: power_divide)
  2506   thus ?thesis
  2507     using nonneg by (rule power2_eq_imp_eq) simp
  2508 qed
  2509 
  2510 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2511 proof -
  2512   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2513   have pos_c: "0 < ?c"
  2514     by (rule cos_gt_zero, simp, simp)
  2515   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2516     by simp
  2517   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2518     by (simp only: cos_add sin_add)
  2519   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2520     by (simp add: algebra_simps power2_eq_square)
  2521   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2522     using pos_c by (simp add: sin_squared_eq power_divide)
  2523   thus ?thesis
  2524     using pos_c [THEN order_less_imp_le]
  2525     by (rule power2_eq_imp_eq) simp
  2526 qed
  2527 
  2528 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2529 proof -
  2530   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2531   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2532   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2533   finally show ?thesis .
  2534 qed
  2535 
  2536 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2537 proof -
  2538   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2539   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2540   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2541   finally show ?thesis .
  2542 qed
  2543 
  2544 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2545 apply (rule power2_eq_imp_eq)
  2546 apply (simp add: cos_squared_eq sin_60 power_divide)
  2547 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2548 done
  2549 
  2550 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2551 proof -
  2552   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2553   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2554   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2555   finally show ?thesis .
  2556 qed
  2557 
  2558 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2559 unfolding tan_def by (simp add: sin_30 cos_30)
  2560 
  2561 lemma tan_45: "tan (pi / 4) = 1"
  2562 unfolding tan_def by (simp add: sin_45 cos_45)
  2563 
  2564 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2565 unfolding tan_def by (simp add: sin_60 cos_60)
  2566 
  2567 text{*NEEDED??*}
  2568 lemma [simp]:
  2569      "sin (x + 1 / 2 * real (Suc m) * pi) =  
  2570       cos (x + 1 / 2 * real  (m) * pi)"
  2571 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib, auto)
  2572 
  2573 text{*NEEDED??*}
  2574 lemma [simp]:
  2575      "sin (x + real (Suc m) * pi / 2) =  
  2576       cos (x + real (m) * pi / 2)"
  2577 by (simp only: cos_add sin_add real_of_nat_Suc add_divide_distrib left_distrib, auto)
  2578 
  2579 lemma DERIV_sin_add [simp]: "DERIV (%x. sin (x + k)) xa :> cos (xa + k)"
  2580   by (auto intro!: DERIV_intros)
  2581 
  2582 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2583 proof -
  2584   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2585     by (auto simp add: algebra_simps sin_add)
  2586   thus ?thesis
  2587     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib 
  2588                   mult_commute [of pi])
  2589 qed
  2590 
  2591 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2592 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2593 
  2594 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2595 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2596 apply (subst cos_add, simp)
  2597 done
  2598 
  2599 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2600 by (auto simp add: mult_assoc)
  2601 
  2602 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2603 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2604 apply (subst sin_add, simp)
  2605 done
  2606 
  2607 (*NEEDED??*)
  2608 lemma [simp]:
  2609      "cos(x + 1 / 2 * real(Suc m) * pi) = -sin (x + 1 / 2 * real m * pi)"
  2610 apply (simp only: cos_add sin_add real_of_nat_Suc right_distrib left_distrib minus_mult_right, auto)
  2611 done
  2612 
  2613 (*NEEDED??*)
  2614 lemma [simp]: "cos (x + real(Suc m) * pi / 2) = -sin (x + real m * pi / 2)"
  2615 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib add_divide_distrib, auto)
  2616 
  2617 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2618 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2619 
  2620 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2621   by (auto intro!: DERIV_intros)
  2622 
  2623 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2624 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2625 
  2626 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2627 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2628 
  2629 subsection {* Machins formula *}
  2630 
  2631 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2632   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2633 proof -
  2634   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2635   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2636   have "z \<noteq> pi / 4" 
  2637   proof (rule ccontr)
  2638     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2639     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2640     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2641   qed
  2642   have "z \<noteq> - (pi / 4)"
  2643   proof (rule ccontr)
  2644     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2645     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2646     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2647   qed
  2648 
  2649   have "z < pi / 4"
  2650   proof (rule ccontr)
  2651     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2652     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2653     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`] 
  2654     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2655     thus False using `\<bar>x\<bar> < 1` by auto
  2656   qed
  2657   moreover 
  2658   have "-(pi / 4) < z"
  2659   proof (rule ccontr)
  2660     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2661     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2662     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2663     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2664     thus False using `\<bar>x\<bar> < 1` by auto
  2665   qed
  2666   ultimately show ?thesis using `tan z = x` by auto
  2667 qed
  2668 
  2669 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2670   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2671 proof -
  2672   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2673 
  2674   have "pi / 4 < pi / 2" by auto
  2675 
  2676   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2677   proof (cases "\<bar>x\<bar> < 1")
  2678     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2679     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2680     thus ?thesis by auto
  2681   next
  2682     case False
  2683     show ?thesis
  2684     proof (cases "x = 1")
  2685       case True hence "tan (pi/4) = x" using tan_45 by auto
  2686       moreover 
  2687       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2688       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2689       ultimately show ?thesis by blast
  2690     next
  2691       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2692       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2693       moreover 
  2694       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2695       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2696       ultimately show ?thesis by blast
  2697     qed
  2698   qed
  2699   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2700   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2701 
  2702   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2703   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2704   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2705 
  2706   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2707   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2708 
  2709   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2710   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2711   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2712   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2713 
  2714   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2715   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2716   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2717   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2718   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2719 qed
  2720 
  2721 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2722 
  2723 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2724 proof -
  2725   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2726   from arctan_add[OF less_imp_le[OF this] this]
  2727   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2728   moreover
  2729   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2730   from arctan_add[OF less_imp_le[OF this] this]
  2731   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2732   moreover 
  2733   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2734   from arctan_add[OF this]
  2735   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2736   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2737   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2738 qed
  2739 subsection {* Introducing the arcus tangens power series *}
  2740 
  2741 lemma monoseq_arctan_series: fixes x :: real
  2742   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2743 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2744 next
  2745   case False
  2746   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2747   show "monoseq ?a"
  2748   proof -
  2749     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2750       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2751       proof (rule mult_mono)
  2752 	show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2753 	show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2754 	show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2755 	show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2756       qed
  2757     } note mono = this
  2758     
  2759     show ?thesis
  2760     proof (cases "0 \<le> x")
  2761       case True from mono[OF this `x \<le> 1`, THEN allI]
  2762       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2763     next
  2764       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2765       from mono[OF this]
  2766       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2767       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2768     qed
  2769   qed
  2770 qed
  2771 
  2772 lemma zeroseq_arctan_series: fixes x :: real
  2773   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2774 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2775 next
  2776   case False
  2777   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2778   show "?a ----> 0"
  2779   proof (cases "\<bar>x\<bar> < 1")
  2780     case True hence "norm x < 1" by auto
  2781     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2782     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2783       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2784     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2785   next
  2786     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2787     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2788     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2789     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2790   qed
  2791 qed
  2792 
  2793 lemma summable_arctan_series: fixes x :: real and n :: nat
  2794   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2795   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2796 
  2797 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2798 proof -
  2799   from mult_mono1[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2800   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2801   thus ?thesis using zero_le_power2 by auto
  2802 qed 
  2803 
  2804 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2805   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2806 proof -
  2807   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2808 
  2809   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2810   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2811 
  2812   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2813     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2814       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2815     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2816   } note summable_Integral = this
  2817 
  2818   { fix f :: "nat \<Rightarrow> real"
  2819     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2820     proof
  2821       fix x :: real assume "f sums x" 
  2822       from sums_if[OF sums_zero this]
  2823       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2824     next
  2825       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2826       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2827       show "f sums x" unfolding sums_def by auto
  2828     qed
  2829     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2830   } note sums_even = this
  2831 
  2832   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2833     by auto
  2834 
  2835   { fix x :: real
  2836     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n = 
  2837       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2838       using n_even by auto
  2839     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto 
  2840     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2841       by auto
  2842   } note arctan_eq = this
  2843 
  2844   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2845   proof (rule DERIV_power_series')
  2846     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2847     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2848       hence "\<bar>x'\<bar> < 1" by auto
  2849 
  2850       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2851       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2852 	by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2853     }
  2854   qed auto
  2855   thus ?thesis unfolding Int_eq arctan_eq .
  2856 qed
  2857 
  2858 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2859   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2860 proof -
  2861   let "?c' x n" = "(-1)^n * x^(n*2)"
  2862 
  2863   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2864     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2865     from DERIV_arctan_series[OF this]
  2866     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2867   } note DERIV_arctan_suminf = this
  2868 
  2869   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2870   note arctan_series_borders = this
  2871 
  2872   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2873   proof -
  2874     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2875     hence "0 < r" and "-r < x" and "x < r" by auto
  2876 
  2877     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2878     proof -
  2879       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2880       hence "\<bar>x\<bar> < r" by auto
  2881       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2882       proof (rule DERIV_isconst2[of "a" "b"])
  2883 	show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2884 	have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2885 	proof (rule allI, rule impI)
  2886 	  fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2887 	  hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2888 	  have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2889 	  hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2890 	  hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2891 	  hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2892 	  have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2893 	    by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2894 	  from DERIV_add_minus[OF this DERIV_arctan]
  2895 	  show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2896 	qed
  2897 	hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2898 	thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2899 	show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2900       qed
  2901     qed
  2902     
  2903     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2904       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2905     
  2906     have "suminf (?c x) - arctan x = 0"
  2907     proof (cases "x = 0")
  2908       case True thus ?thesis using suminf_arctan_zero by auto
  2909     next
  2910       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2911       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2912 	by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric], auto simp add: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>`)
  2913       moreover
  2914       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2915 	by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"], auto simp add: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>`)
  2916       ultimately 
  2917       show ?thesis using suminf_arctan_zero by auto
  2918     qed
  2919     thus ?thesis by auto
  2920   qed } note when_less_one = this
  2921 
  2922   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2923   proof (cases "\<bar>x\<bar> < 1")
  2924     case True thus ?thesis by (rule when_less_one)
  2925   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2926     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2927     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2928     { fix n :: nat
  2929       have "0 < (1 :: real)" by auto
  2930       moreover
  2931       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2932 	from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2933 	note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2934 	have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2935 	hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2936         have "?diff x n \<le> ?a x n"
  2937 	proof (cases "even n")
  2938 	  case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2939 	  from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2940 	  from bounds[of m, unfolded this atLeastAtMost_iff]
  2941 	  have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2942 	  also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2943 	  also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2944 	  finally show ?thesis .
  2945 	next
  2946 	  case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2947 	  from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2948 	  hence m_plus: "2 * (m + 1) = n + 1" by auto
  2949 	  from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2950 	  have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2951 	  also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2952 	  also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2953 	  finally show ?thesis .
  2954 	qed
  2955         hence "0 \<le> ?a x n - ?diff x n" by auto
  2956       }
  2957       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2958       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2959 	unfolding real_diff_def divide_inverse
  2960 	by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2961       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2962       hence "?diff 1 n \<le> ?a 1 n" by auto
  2963     }
  2964     have "?a 1 ----> 0"
  2965       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2966       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2967     have "?diff 1 ----> 0"
  2968     proof (rule LIMSEQ_I)
  2969       fix r :: real assume "0 < r"
  2970       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2971       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2972 	have "norm (?diff 1 n - 0) < r" by auto }
  2973       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2974     qed
  2975     from this[unfolded LIMSEQ_rabs_zero real_diff_def add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2976     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2977     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2978     
  2979     show ?thesis
  2980     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2981       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2982       
  2983       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2984       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2985       
  2986       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2987     
  2988       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2989       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2990       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2991       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2992       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2993       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2994       finally show ?thesis using `x = -1` by auto
  2995     qed
  2996   qed
  2997 qed
  2998 
  2999 lemma arctan_half: fixes x :: real
  3000   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  3001 proof -
  3002   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  3003   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  3004 
  3005   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  3006   
  3007   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  3008   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  3009 
  3010   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  3011   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  3012   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  3013   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  3014 
  3015   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  3016   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  3017   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  3018   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3019   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3020 
  3021   have "arctan x = y" using arctan_tan low high y_eq by auto
  3022   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3023   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  3024   finally show ?thesis unfolding eq `tan y = x` .
  3025 qed
  3026 
  3027 lemma arctan_monotone: assumes "x < y"
  3028   shows "arctan x < arctan y"
  3029 proof -
  3030   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  3031   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  3032   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  3033   thus ?thesis
  3034     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  3035     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  3036 qed
  3037 
  3038 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3039 proof (cases "x = y") 
  3040   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  3041 qed auto
  3042 
  3043 lemma arctan_minus: "arctan (- x) = - arctan x" 
  3044 proof -
  3045   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3046   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto 
  3047 qed
  3048 
  3049 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3050 proof -
  3051   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3052   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  3053 
  3054   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  3055     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  3056     hence "x > 0" using `tan y = x` by auto
  3057 
  3058     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  3059     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  3060     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  3061     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  3062   } note pos_y = this
  3063 
  3064   show ?thesis
  3065   proof (cases "y > 0")
  3066     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  3067   next
  3068     case False hence "y \<le> 0" by auto
  3069     moreover have "y \<noteq> 0" 
  3070     proof (rule ccontr)
  3071       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  3072       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  3073       thus False using `x \<noteq> 0` by auto
  3074     qed
  3075     ultimately have "y < 0" by auto
  3076     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  3077     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  3078     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  3079     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  3080     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  3081     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  3082   qed
  3083 qed
  3084 
  3085 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3086 proof -
  3087   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  3088   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3089   finally show ?thesis by auto
  3090 qed
  3091 
  3092 subsection {* Existence of Polar Coordinates *}
  3093 
  3094 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3095 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3096 apply (simp add: abs_divide power_divide divide_le_eq not_sum_power2_lt_zero)
  3097 done
  3098 
  3099 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3100 by (simp add: abs_le_iff)
  3101 
  3102 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3103 by (simp add: sin_arccos abs_le_iff)
  3104 
  3105 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3106 
  3107 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3108 
  3109 lemma polar_ex1:
  3110      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3111 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3112 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3113 apply (simp add: cos_arccos_lemma1)
  3114 apply (simp add: sin_arccos_lemma1)
  3115 apply (simp add: power_divide)
  3116 apply (simp add: real_sqrt_mult [symmetric])
  3117 apply (simp add: right_diff_distrib)
  3118 done
  3119 
  3120 lemma polar_ex2:
  3121      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3122 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3123 apply (rule_tac x = r in exI)
  3124 apply (rule_tac x = "-a" in exI, simp)
  3125 done
  3126 
  3127 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3128 apply (rule_tac x=0 and y=y in linorder_cases)
  3129 apply (erule polar_ex1)
  3130 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3131 apply (erule polar_ex2)
  3132 done
  3133 
  3134 end