src/Pure/global_theory.ML
author blanchet
Mon May 19 23:43:53 2014 +0200 (2014-05-19)
changeset 57008 10f68b83b474
parent 56161 300f613060b0
child 57887 44354c99d754
permissions -rw-r--r--
use E 1.8's auto scheduler option
     1 (*  Title:      Pure/global_theory.ML
     2     Author:     Makarius
     3 
     4 Global theory content: stored facts.
     5 *)
     6 
     7 signature GLOBAL_THEORY =
     8 sig
     9   val facts_of: theory -> Facts.T
    10   val check_fact: theory -> xstring * Position.T -> string
    11   val intern_fact: theory -> xstring -> string
    12   val defined_fact: theory -> string -> bool
    13   val hide_fact: bool -> string -> theory -> theory
    14   val get_thms: theory -> xstring -> thm list
    15   val get_thm: theory -> xstring -> thm
    16   val all_thms_of: theory -> bool -> (string * thm) list
    17   val map_facts: ('a -> 'b) -> ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    18   val burrow_fact: ('a list -> 'b list) -> ('a list * 'c) list -> ('b list * 'c) list
    19   val burrow_facts: ('a list -> 'b list) ->
    20     ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    21   val name_multi: string -> 'a list -> (string * 'a) list
    22   val name_thm: bool -> bool -> string -> thm -> thm
    23   val name_thms: bool -> bool -> string -> thm list -> thm list
    24   val name_thmss: bool -> string -> (thm list * 'a) list -> (thm list * 'a) list
    25   val store_thms: binding * thm list -> theory -> thm list * theory
    26   val store_thm: binding * thm -> theory -> thm * theory
    27   val store_thm_open: binding * thm -> theory -> thm * theory
    28   val add_thms: ((binding * thm) * attribute list) list -> theory -> thm list * theory
    29   val add_thm: (binding * thm) * attribute list -> theory -> thm * theory
    30   val add_thmss: ((binding * thm list) * attribute list) list -> theory -> thm list list * theory
    31   val add_thms_dynamic: binding * (Context.generic -> thm list) -> theory -> theory
    32   val note_thmss: string -> (Thm.binding * (thm list * attribute list) list) list
    33     -> theory -> (string * thm list) list * theory
    34   val add_defs: bool -> ((binding * term) * attribute list) list ->
    35     theory -> thm list * theory
    36   val add_defs_unchecked: bool -> ((binding * term) * attribute list) list ->
    37     theory -> thm list * theory
    38   val add_defs_cmd: bool -> ((binding * string) * attribute list) list ->
    39     theory -> thm list * theory
    40   val add_defs_unchecked_cmd: bool -> ((binding * string) * attribute list) list ->
    41     theory -> thm list * theory
    42 end;
    43 
    44 structure Global_Theory: GLOBAL_THEORY =
    45 struct
    46 
    47 (** theory data **)
    48 
    49 structure Data = Theory_Data
    50 (
    51   type T = Facts.T;
    52   val empty = Facts.empty;
    53   val extend = I;
    54   val merge = Facts.merge;
    55 );
    56 
    57 val facts_of = Data.get;
    58 
    59 fun check_fact thy = Facts.check (Context.Theory thy) (facts_of thy);
    60 val intern_fact = Facts.intern o facts_of;
    61 val defined_fact = Facts.defined o facts_of;
    62 
    63 fun hide_fact fully name = Data.map (Facts.hide fully name);
    64 
    65 
    66 (* retrieve theorems *)
    67 
    68 fun get_thms thy xname =
    69   #2 (Facts.retrieve (Context.Theory thy) (facts_of thy) (xname, Position.none));
    70 
    71 fun get_thm thy xname =
    72   Facts.the_single (xname, Position.none) (get_thms thy xname);
    73 
    74 fun all_thms_of thy verbose =
    75   let
    76     val facts = facts_of thy;
    77     fun add (name, ths) =
    78       if not verbose andalso Facts.is_concealed facts name then I
    79       else append (map (`(Thm.get_name_hint)) ths);
    80   in Facts.fold_static add facts [] end;
    81 
    82 
    83 
    84 (** store theorems **)
    85 
    86 (* fact specifications *)
    87 
    88 fun map_facts f = map (apsnd (map (apfst (map f))));
    89 fun burrow_fact f = split_list #>> burrow f #> op ~~;
    90 fun burrow_facts f = split_list ##> burrow (burrow_fact f) #> op ~~;
    91 
    92 
    93 (* naming *)
    94 
    95 fun name_multi name [x] = [(name, x)]
    96   | name_multi "" xs = map (pair "") xs
    97   | name_multi name xs = map_index (fn (i, x) => (name ^ "_" ^ string_of_int (i + 1), x)) xs;
    98 
    99 fun name_thm pre official name thm = thm
   100   |> (if not official orelse pre andalso Thm.derivation_name thm <> "" then I
   101       else Thm.name_derivation name)
   102   |> (if name = "" orelse pre andalso Thm.has_name_hint thm then I
   103       else Thm.put_name_hint name);
   104 
   105 fun name_thms pre official name xs =
   106   map (uncurry (name_thm pre official)) (name_multi name xs);
   107 
   108 fun name_thmss official name fact =
   109   burrow_fact (name_thms true official name) fact;
   110 
   111 
   112 (* enter_thms *)
   113 
   114 fun register_proofs thms thy = (thms, Thm.register_proofs thms thy);
   115 
   116 fun enter_thms pre_name post_name app_att (b, thms) thy =
   117   if Binding.is_empty b
   118   then app_att thms thy |-> register_proofs
   119   else
   120     let
   121       val name = Sign.full_name thy b;
   122       val (thms', thy') = app_att (pre_name name thms) thy |>> post_name name |-> register_proofs;
   123       val thms'' = map (Thm.transfer thy') thms';
   124       val thy'' = thy' |> Data.map
   125         (Facts.add_static (Context.Theory thy') {strict = true, index = false} (b, thms'') #> snd);
   126     in (thms'', thy'') end;
   127 
   128 
   129 (* store_thm(s) *)
   130 
   131 fun store_thms (b, thms) =
   132   enter_thms (name_thms true true) (name_thms false true) pair (b, thms);
   133 
   134 fun store_thm (b, th) = store_thms (b, [th]) #>> the_single;
   135 
   136 fun store_thm_open (b, th) =
   137   enter_thms (name_thms true false) (name_thms false false) pair (b, [th]) #>> the_single;
   138 
   139 
   140 (* add_thms(s) *)
   141 
   142 fun add_thms_atts pre_name ((b, thms), atts) =
   143   enter_thms pre_name (name_thms false true) (fold_map (Thm.theory_attributes atts)) (b, thms);
   144 
   145 fun gen_add_thmss pre_name =
   146   fold_map (add_thms_atts pre_name);
   147 
   148 fun gen_add_thms pre_name args =
   149   apfst (map hd) o gen_add_thmss pre_name (map (apfst (apsnd single)) args);
   150 
   151 val add_thmss = gen_add_thmss (name_thms true true);
   152 val add_thms = gen_add_thms (name_thms true true);
   153 val add_thm = yield_singleton add_thms;
   154 
   155 
   156 (* add_thms_dynamic *)
   157 
   158 fun add_thms_dynamic (b, f) thy = thy
   159   |> Data.map (Facts.add_dynamic (Context.Theory thy) (b, f) #> snd);
   160 
   161 
   162 (* note_thmss *)
   163 
   164 fun note_thmss kind = fold_map (fn ((b, more_atts), facts) => fn thy =>
   165   let
   166     val name = Sign.full_name thy b;
   167     fun app (ths, atts) =
   168       fold_map (Thm.theory_attributes (surround (Thm.kind kind) (atts @ more_atts))) ths;
   169     val (thms, thy') =
   170       enter_thms (name_thmss true) (name_thms false true) (apfst flat oo fold_map app)
   171         (b, facts) thy;
   172   in ((name, thms), thy') end);
   173 
   174 
   175 (* store axioms as theorems *)
   176 
   177 local
   178 
   179 fun no_read _ (_, t) = t;
   180 
   181 fun read ctxt (b, str) =
   182   Syntax.read_prop ctxt str handle ERROR msg =>
   183     cat_error msg ("The error(s) above occurred in definition " ^ Binding.print b);
   184 
   185 fun add prep unchecked overloaded = fold_map (fn ((b, raw_prop), atts) => fn thy =>
   186   let
   187     val ctxt = Syntax.init_pretty_global thy;
   188     val prop = prep ctxt (b, raw_prop);
   189     val ((_, def), thy') = Thm.add_def ctxt unchecked overloaded (b, prop) thy;
   190     val thm = def
   191       |> Thm.forall_intr_frees
   192       |> Thm.forall_elim_vars 0
   193       |> Thm.varifyT_global;
   194   in yield_singleton (gen_add_thms (K I)) ((b, thm), atts) thy' end);
   195 
   196 in
   197 
   198 val add_defs = add no_read false;
   199 val add_defs_unchecked = add no_read true;
   200 val add_defs_cmd = add read false;
   201 val add_defs_unchecked_cmd = add read true;
   202 
   203 end;
   204 
   205 end;