src/Pure/sign.ML
author blanchet
Mon May 19 23:43:53 2014 +0200 (2014-05-19)
changeset 57008 10f68b83b474
parent 56240 938c6c7e10eb
child 59841 2551ac44150e
permissions -rw-r--r--
use E 1.8's auto scheduler option
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val change_begin: theory -> theory
    11   val change_end: theory -> theory
    12   val change_end_local: Proof.context -> Proof.context
    13   val change_check: theory -> theory
    14   val syn_of: theory -> Syntax.syntax
    15   val tsig_of: theory -> Type.tsig
    16   val classes_of: theory -> Sorts.algebra
    17   val all_classes: theory -> class list
    18   val super_classes: theory -> class -> class list
    19   val minimize_sort: theory -> sort -> sort
    20   val complete_sort: theory -> sort -> sort
    21   val set_defsort: sort -> theory -> theory
    22   val defaultS: theory -> sort
    23   val subsort: theory -> sort * sort -> bool
    24   val of_sort: theory -> typ * sort -> bool
    25   val inter_sort: theory -> sort * sort -> sort
    26   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    27   val is_logtype: theory -> string -> bool
    28   val typ_instance: theory -> typ * typ -> bool
    29   val typ_equiv: theory -> typ * typ -> bool
    30   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    31   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    32   val consts_of: theory -> Consts.T
    33   val the_const_constraint: theory -> string -> typ
    34   val const_type: theory -> string -> typ option
    35   val the_const_type: theory -> string -> typ
    36   val declared_tyname: theory -> string -> bool
    37   val declared_const: theory -> string -> bool
    38   val naming_of: theory -> Name_Space.naming
    39   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    40   val restore_naming: theory -> theory -> theory
    41   val inherit_naming: theory -> Proof.context -> Context.generic
    42   val full_name: theory -> binding -> string
    43   val full_name_path: theory -> string -> binding -> string
    44   val full_bname: theory -> bstring -> string
    45   val full_bname_path: theory -> string -> bstring -> string
    46   val const_monomorphic: theory -> string -> bool
    47   val const_typargs: theory -> string * typ -> typ list
    48   val const_instance: theory -> string * typ list -> typ
    49   val mk_const: theory -> string * typ list -> term
    50   val class_space: theory -> Name_Space.T
    51   val type_space: theory -> Name_Space.T
    52   val const_space: theory -> Name_Space.T
    53   val intern_class: theory -> xstring -> string
    54   val intern_type: theory -> xstring -> string
    55   val intern_const: theory -> xstring -> string
    56   val class_alias: binding -> class -> theory -> theory
    57   val type_alias: binding -> string -> theory -> theory
    58   val const_alias: binding -> string -> theory -> theory
    59   val arity_number: theory -> string -> int
    60   val arity_sorts: theory -> string -> sort -> sort list
    61   val certify_class: theory -> class -> class
    62   val certify_sort: theory -> sort -> sort
    63   val certify_typ: theory -> typ -> typ
    64   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    65   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    66   val certify_term: theory -> term -> term * typ * int
    67   val cert_term: theory -> term -> term
    68   val cert_prop: theory -> term -> term
    69   val no_frees: Proof.context -> term -> term
    70   val no_vars: Proof.context -> term -> term
    71   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    72   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    73   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    74   val add_nonterminals_global: binding list -> theory -> theory
    75   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    76   val add_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    77   val add_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val del_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    81   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    82   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    83   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    84   val add_consts: (binding * typ * mixfix) list -> theory -> theory
    85   val add_consts_cmd: (binding * string * mixfix) list -> theory -> theory
    86   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    87   val revert_abbrev: string -> string -> theory -> theory
    88   val add_const_constraint: string * typ option -> theory -> theory
    89   val primitive_class: binding * class list -> theory -> theory
    90   val primitive_classrel: class * class -> theory -> theory
    91   val primitive_arity: arity -> theory -> theory
    92   val parse_ast_translation:
    93     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    94   val parse_translation:
    95     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    96   val print_translation:
    97     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    98   val typed_print_translation:
    99     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   100   val print_ast_translation:
   101     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   102   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   103   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val new_group: theory -> theory
   105   val reset_group: theory -> theory
   106   val add_path: string -> theory -> theory
   107   val root_path: theory -> theory
   108   val parent_path: theory -> theory
   109   val mandatory_path: string -> theory -> theory
   110   val qualified_path: bool -> binding -> theory -> theory
   111   val local_path: theory -> theory
   112   val hide_class: bool -> string -> theory -> theory
   113   val hide_type: bool -> string -> theory -> theory
   114   val hide_const: bool -> string -> theory -> theory
   115 end
   116 
   117 structure Sign: SIGN =
   118 struct
   119 
   120 (** datatype sign **)
   121 
   122 datatype sign = Sign of
   123  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   124   tsig: Type.tsig,              (*order-sorted signature of types*)
   125   consts: Consts.T};            (*polymorphic constants*)
   126 
   127 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   128 
   129 structure Data = Theory_Data_PP
   130 (
   131   type T = sign;
   132   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   133 
   134   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   135 
   136   fun merge pp (sign1, sign2) =
   137     let
   138       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   139       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   140 
   141       val syn = Syntax.merge_syntax (syn1, syn2);
   142       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   143       val consts = Consts.merge (consts1, consts2);
   144     in make_sign (syn, tsig, consts) end;
   145 );
   146 
   147 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   148 
   149 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   150 
   151 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   152 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   153 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   154 
   155 
   156 (* linear change discipline *)
   157 
   158 fun change_base begin = map_sign (fn (syn, tsig, consts) =>
   159   (syn, Type.change_base begin tsig, Consts.change_base begin consts));
   160 
   161 val change_begin = change_base true;
   162 val change_end = change_base false;
   163 
   164 fun change_end_local ctxt =
   165   Context.raw_transfer (change_end (Proof_Context.theory_of ctxt)) ctxt;
   166 
   167 fun change_check thy =
   168   if can change_end thy
   169   then raise Fail "Unfinished linear change of theory content" else thy;
   170 
   171 
   172 (* syntax *)
   173 
   174 val syn_of = #syn o rep_sg;
   175 
   176 
   177 (* type signature *)
   178 
   179 val tsig_of = #tsig o rep_sg;
   180 
   181 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   182 val all_classes = Sorts.all_classes o classes_of;
   183 val super_classes = Sorts.super_classes o classes_of;
   184 val minimize_sort = Sorts.minimize_sort o classes_of;
   185 val complete_sort = Sorts.complete_sort o classes_of;
   186 
   187 val set_defsort = map_tsig o Type.set_defsort;
   188 val defaultS = Type.defaultS o tsig_of;
   189 val subsort = Type.subsort o tsig_of;
   190 val of_sort = Type.of_sort o tsig_of;
   191 val inter_sort = Type.inter_sort o tsig_of;
   192 val witness_sorts = Type.witness_sorts o tsig_of;
   193 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   194 
   195 val typ_instance = Type.typ_instance o tsig_of;
   196 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   197 val typ_match = Type.typ_match o tsig_of;
   198 val typ_unify = Type.unify o tsig_of;
   199 
   200 
   201 (* polymorphic constants *)
   202 
   203 val consts_of = #consts o rep_sg;
   204 val the_const_constraint = Consts.the_constraint o consts_of;
   205 val the_const_type = #2 oo (Consts.the_const o consts_of);
   206 val const_type = try o the_const_type;
   207 val const_monomorphic = Consts.is_monomorphic o consts_of;
   208 val const_typargs = Consts.typargs o consts_of;
   209 val const_instance = Consts.instance o consts_of;
   210 
   211 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   212 
   213 fun declared_tyname ctxt c = can (Type.the_decl (tsig_of ctxt)) (c, Position.none);
   214 val declared_const = can o the_const_constraint;
   215 
   216 
   217 (* naming *)
   218 
   219 val naming_of = Name_Space.naming_of o Context.Theory;
   220 val map_naming = Context.theory_map o Name_Space.map_naming;
   221 val restore_naming = map_naming o K o naming_of;
   222 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   223 
   224 val full_name = Name_Space.full_name o naming_of;
   225 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   226 
   227 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   228 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   229 
   230 
   231 
   232 (** name spaces **)
   233 
   234 val class_space = Type.class_space o tsig_of;
   235 val type_space = Type.type_space o tsig_of;
   236 val const_space = Consts.space_of o consts_of;
   237 
   238 val intern_class = Name_Space.intern o class_space;
   239 val intern_type = Name_Space.intern o type_space;
   240 val intern_const = Name_Space.intern o const_space;
   241 
   242 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   243 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   244 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   245 
   246 
   247 
   248 (** certify entities **)    (*exception TYPE*)
   249 
   250 (* certify wrt. type signature *)
   251 
   252 val arity_number = Type.arity_number o tsig_of;
   253 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   254 
   255 val certify_class = Type.cert_class o tsig_of;
   256 val certify_sort = Type.cert_sort o tsig_of;
   257 val certify_typ = Type.cert_typ o tsig_of;
   258 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   259 
   260 
   261 (* certify term/prop *)
   262 
   263 local
   264 
   265 fun type_check pp tm =
   266   let
   267     fun err_appl bs t T u U =
   268       let
   269         val xs = map Free bs;           (*we do not rename here*)
   270         val t' = subst_bounds (xs, t);
   271         val u' = subst_bounds (xs, u);
   272         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   273       in raise TYPE (msg, [T, U], [t', u']) end;
   274 
   275     fun typ_of (_, Const (_, T)) = T
   276       | typ_of (_, Free  (_, T)) = T
   277       | typ_of (_, Var (_, T)) = T
   278       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   279           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   280       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   281       | typ_of (bs, t $ u) =
   282           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   283             (case T of
   284               Type ("fun", [T1, T2]) =>
   285                 if T1 = U then T2 else err_appl bs t T u U
   286             | _ => err_appl bs t T u U)
   287           end;
   288   in typ_of ([], tm) end;
   289 
   290 fun err msg = raise TYPE (msg, [], []);
   291 
   292 fun check_vars (t $ u) = (check_vars t; check_vars u)
   293   | check_vars (Abs (_, _, t)) = check_vars t
   294   | check_vars (Free (x, _)) =
   295       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   296   | check_vars (Var (xi as (_, i), _)) =
   297       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   298   | check_vars _ = ();
   299 
   300 in
   301 
   302 fun certify' prop pp do_expand consts thy tm =
   303   let
   304     val _ = check_vars tm;
   305     val tm' = Term.map_types (certify_typ thy) tm;
   306     val T = type_check pp tm';
   307     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   308     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   309   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   310 
   311 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   312 fun cert_term_abbrev thy =
   313   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   314 val cert_term = #1 oo certify_term;
   315 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   316 
   317 end;
   318 
   319 
   320 (* specifications *)
   321 
   322 fun no_variables kind add addT mk mkT ctxt tm =
   323   (case (add tm [], addT tm []) of
   324     ([], []) => tm
   325   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   326       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   327        Pretty.commas
   328         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   329 
   330 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   331 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   332 
   333 
   334 
   335 (** signature extension functions **)  (*exception ERROR/TYPE*)
   336 
   337 (* add type constructors *)
   338 
   339 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   340   let
   341     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   342     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   343     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   344   in (syn', tsig', consts) end);
   345 
   346 fun add_types_global types thy =
   347   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   348 
   349 
   350 (* add nonterminals *)
   351 
   352 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   353   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   354 
   355 fun add_nonterminals_global ns thy =
   356   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   357 
   358 
   359 (* add type abbreviations *)
   360 
   361 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   362   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   363 
   364 
   365 (* modify syntax *)
   366 
   367 fun gen_syntax change_gram parse_typ mode args thy =
   368   let
   369     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   370     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   371       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   372   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   373 
   374 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   375 
   376 val add_syntax = gen_add_syntax (K I);
   377 val add_syntax_cmd = gen_add_syntax Syntax.read_typ;
   378 val del_syntax = gen_syntax (Syntax.update_const_gram false) (K I);
   379 val del_syntax_cmd = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   380 
   381 fun type_notation add mode args =
   382   let
   383     fun type_syntax (Type (c, args), mx) =
   384           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   385       | type_syntax _ = NONE;
   386   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   387 
   388 fun notation add mode args thy =
   389   let
   390     fun const_syntax (Const (c, _), mx) =
   391           (case try (Consts.type_scheme (consts_of thy)) c of
   392             SOME T => SOME (Lexicon.mark_const c, T, mx)
   393           | NONE => NONE)
   394       | const_syntax _ = NONE;
   395   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   396 
   397 
   398 (* add constants *)
   399 
   400 local
   401 
   402 fun gen_add_consts prep_typ ctxt raw_args thy =
   403   let
   404     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   405     fun prep (b, raw_T, mx) =
   406       let
   407         val c = full_name thy b;
   408         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   409           cat_error msg ("in declaration of constant " ^ Binding.print b);
   410         val T' = Logic.varifyT_global T;
   411       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   412     val args = map prep raw_args;
   413   in
   414     thy
   415     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   416     |> add_syntax Syntax.mode_default (map #2 args)
   417     |> pair (map #3 args)
   418   end;
   419 
   420 in
   421 
   422 fun add_consts args thy =
   423   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   424 
   425 fun add_consts_cmd args thy =
   426   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   427 
   428 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   429 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   430 
   431 end;
   432 
   433 
   434 (* abbreviations *)
   435 
   436 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   437   let
   438     val ctxt = Syntax.init_pretty_global thy;
   439     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   440     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   441       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   442     val (res, consts') = consts_of thy
   443       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   444   in (res, thy |> map_consts (K consts')) end;
   445 
   446 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   447 
   448 
   449 (* add constraints *)
   450 
   451 fun add_const_constraint (c, opt_T) thy =
   452   let
   453     fun prepT raw_T =
   454       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   455       in cert_term thy (Const (c, T)); T end
   456       handle TYPE (msg, _, _) => error msg;
   457   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   458 
   459 
   460 (* primitive classes and arities *)
   461 
   462 fun primitive_class (bclass, classes) thy =
   463   thy
   464   |> map_sign (fn (syn, tsig, consts) =>
   465       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   466       in (syn, tsig', consts) end)
   467   |> add_consts [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   468 
   469 fun primitive_classrel arg thy =
   470   thy |> map_tsig (Type.add_classrel (Context.pretty_global thy) arg);
   471 
   472 fun primitive_arity arg thy =
   473   thy |> map_tsig (Type.add_arity (Context.pretty_global thy) arg);
   474 
   475 
   476 (* add translation functions *)
   477 
   478 local
   479 
   480 fun mk trs = map Syntax_Ext.mk_trfun trs;
   481 
   482 in
   483 
   484 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   485 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   486 fun print_translation tr's =
   487   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   488 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   489 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   490 
   491 end;
   492 
   493 
   494 (* translation rules *)
   495 
   496 val add_trrules = map_syn o Syntax.update_trrules;
   497 val del_trrules = map_syn o Syntax.remove_trrules;
   498 
   499 
   500 (* naming *)
   501 
   502 val new_group = map_naming Name_Space.new_group;
   503 val reset_group = map_naming Name_Space.reset_group;
   504 
   505 val add_path = map_naming o Name_Space.add_path;
   506 val root_path = map_naming Name_Space.root_path;
   507 val parent_path = map_naming Name_Space.parent_path;
   508 val mandatory_path = map_naming o Name_Space.mandatory_path;
   509 val qualified_path = map_naming oo Name_Space.qualified_path;
   510 
   511 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   512 
   513 
   514 (* hide names *)
   515 
   516 val hide_class = map_tsig oo Type.hide_class;
   517 val hide_type = map_tsig oo Type.hide_type;
   518 val hide_const = map_consts oo Consts.hide;
   519 
   520 end;