src/Pure/tactical.ML
author blanchet
Mon May 19 23:43:53 2014 +0200 (2014-05-19)
changeset 57008 10f68b83b474
parent 56493 1f660d858a75
child 59582 0fbed69ff081
permissions -rw-r--r--
use E 1.8's auto scheduler option
     1 (*  Title:      Pure/tactical.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Tacticals.
     5 *)
     6 
     7 infix 1 THEN THEN' THEN_ALL_NEW;
     8 infix 0 ORELSE APPEND ORELSE' APPEND';
     9 infix 0 THEN_ELSE;
    10 
    11 signature TACTICAL =
    12 sig
    13   type tactic = thm -> thm Seq.seq
    14   val THEN: tactic * tactic -> tactic
    15   val ORELSE: tactic * tactic -> tactic
    16   val APPEND: tactic * tactic -> tactic
    17   val THEN_ELSE: tactic * (tactic*tactic) -> tactic
    18   val THEN': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    19   val ORELSE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    20   val APPEND': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val all_tac: tactic
    22   val no_tac: tactic
    23   val DETERM: tactic -> tactic
    24   val COND: (thm -> bool) -> tactic -> tactic -> tactic
    25   val TRY: tactic -> tactic
    26   val EVERY: tactic list -> tactic
    27   val EVERY': ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1: (int -> tactic) list -> tactic
    29   val FIRST: tactic list -> tactic
    30   val FIRST': ('a -> tactic) list -> 'a -> tactic
    31   val FIRST1: (int -> tactic) list -> tactic
    32   val RANGE: (int -> tactic) list -> int -> tactic
    33   val print_tac: Proof.context -> string -> tactic
    34   val pause_tac: tactic
    35   val trace_REPEAT: bool Unsynchronized.ref
    36   val suppress_tracing: bool Unsynchronized.ref
    37   val tracify: bool Unsynchronized.ref -> tactic -> tactic
    38   val traced_tac: (thm -> (thm * thm Seq.seq) option) -> tactic
    39   val REPEAT_DETERM_N: int -> tactic -> tactic
    40   val REPEAT_DETERM: tactic -> tactic
    41   val REPEAT: tactic -> tactic
    42   val REPEAT_DETERM1: tactic -> tactic
    43   val REPEAT1: tactic -> tactic
    44   val FILTER: (thm -> bool) -> tactic -> tactic
    45   val CHANGED: tactic -> tactic
    46   val CHANGED_PROP: tactic -> tactic
    47   val ALLGOALS: (int -> tactic) -> tactic
    48   val SOMEGOAL: (int -> tactic) -> tactic
    49   val FIRSTGOAL: (int -> tactic) -> tactic
    50   val HEADGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    51   val REPEAT_SOME: (int -> tactic) -> tactic
    52   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    53   val REPEAT_FIRST: (int -> tactic) -> tactic
    54   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    55   val TRYALL: (int -> tactic) -> tactic
    56   val CSUBGOAL: ((cterm * int) -> tactic) -> int -> tactic
    57   val SUBGOAL: ((term * int) -> tactic) -> int -> tactic
    58   val ASSERT_SUBGOAL: (int -> tactic) -> int -> tactic
    59   val CHANGED_GOAL: (int -> tactic) -> int -> tactic
    60   val SOLVED': (int -> tactic) -> int -> tactic
    61   val THEN_ALL_NEW: (int -> tactic) * (int -> tactic) -> int -> tactic
    62   val REPEAT_ALL_NEW: (int -> tactic) -> int -> tactic
    63   val PRIMSEQ: (thm -> thm Seq.seq) -> tactic
    64   val PRIMITIVE: (thm -> thm) -> tactic
    65   val SINGLE: tactic -> thm -> thm option
    66   val CONVERSION: conv -> int -> tactic
    67 end;
    68 
    69 structure Tactical : TACTICAL =
    70 struct
    71 
    72 (**** Tactics ****)
    73 
    74 (*A tactic maps a proof tree to a sequence of proof trees:
    75     if length of sequence = 0 then the tactic does not apply;
    76     if length > 1 then backtracking on the alternatives can occur.*)
    77 
    78 type tactic = thm -> thm Seq.seq;
    79 
    80 
    81 (*** LCF-style tacticals ***)
    82 
    83 (*the tactical THEN performs one tactic followed by another*)
    84 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    85 
    86 
    87 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    88   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    89   Does not backtrack to tac2 if tac1 was initially chosen. *)
    90 fun (tac1 ORELSE tac2) st =
    91     case Seq.pull(tac1 st) of
    92         NONE       => tac2 st
    93       | sequencecell => Seq.make(fn()=> sequencecell);
    94 
    95 
    96 (*The tactical APPEND combines the results of two tactics.
    97   Like ORELSE, but allows backtracking on both tac1 and tac2.
    98   The tactic tac2 is not applied until needed.*)
    99 fun (tac1 APPEND tac2) st =
   100   Seq.append (tac1 st) (Seq.make(fn()=> Seq.pull (tac2 st)));
   101 
   102 (*Conditional tactic.
   103         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   104         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   105 *)
   106 fun (tac THEN_ELSE (tac1, tac2)) st =
   107     case Seq.pull(tac st) of
   108         NONE    => tac2 st                                   (*failed; try tactic 2*)
   109       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   110 
   111 
   112 (*Versions for combining tactic-valued functions, as in
   113      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   114 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   115 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   116 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   117 
   118 (*passes all proofs through unchanged;  identity of THEN*)
   119 fun all_tac st = Seq.single st;
   120 
   121 (*passes no proofs through;  identity of ORELSE and APPEND*)
   122 fun no_tac st  = Seq.empty;
   123 
   124 
   125 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   126 fun DETERM tac = Seq.DETERM tac;
   127 
   128 (*Conditional tactical: testfun controls which tactic to use next.
   129   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   130 fun COND testfun thenf elsef = (fn prf =>
   131     if testfun prf then  thenf prf   else  elsef prf);
   132 
   133 (*Do the tactic or else do nothing*)
   134 fun TRY tac = tac ORELSE all_tac;
   135 
   136 (*** List-oriented tactics ***)
   137 
   138 local
   139   (*This version of EVERY avoids backtracking over repeated states*)
   140 
   141   fun EVY (trail, []) st =
   142         Seq.make (fn()=> SOME(st,
   143                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   144     | EVY (trail, tac::tacs) st =
   145           case Seq.pull(tac st) of
   146               NONE    => evyBack trail              (*failed: backtrack*)
   147             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   148   and evyBack [] = Seq.empty (*no alternatives*)
   149     | evyBack ((st',q,tacs)::trail) =
   150           case Seq.pull q of
   151               NONE        => evyBack trail
   152             | SOME(st,q') => if Thm.eq_thm (st',st)
   153                              then evyBack ((st',q',tacs)::trail)
   154                              else EVY ((st,q',tacs)::trail, tacs) st
   155 in
   156 
   157 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   158 fun EVERY tacs = EVY ([], tacs);
   159 end;
   160 
   161 
   162 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   163 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   164 
   165 (*Apply every tactic to 1*)
   166 fun EVERY1 tacs = EVERY' tacs 1;
   167 
   168 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   169 fun FIRST tacs = fold_rev (curry op ORELSE) tacs no_tac;
   170 
   171 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   172 fun FIRST' tacs = fold_rev (curry op ORELSE') tacs (K no_tac);
   173 
   174 (*Apply first tactic to 1*)
   175 fun FIRST1 tacs = FIRST' tacs 1;
   176 
   177 (*Apply tactics on consecutive subgoals*)
   178 fun RANGE [] _ = all_tac
   179   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   180 
   181 
   182 (*** Tracing tactics ***)
   183 
   184 (*Print the current proof state and pass it on.*)
   185 fun print_tac ctxt msg st =
   186  (tracing (msg ^ "\n" ^ Pretty.string_of (Pretty.chunks (Goal_Display.pretty_goals ctxt st)));
   187   Seq.single st);
   188 
   189 (*Pause until a line is typed -- if non-empty then fail. *)
   190 fun pause_tac st =
   191   (tracing "** Press RETURN to continue:";
   192    if TextIO.inputLine TextIO.stdIn = SOME "\n" then Seq.single st
   193    else (tracing "Goodbye";  Seq.empty));
   194 
   195 exception TRACE_EXIT of thm
   196 and TRACE_QUIT;
   197 
   198 (*Tracing flags*)
   199 val trace_REPEAT= Unsynchronized.ref false
   200 and suppress_tracing = Unsynchronized.ref false;
   201 
   202 (*Handle all tracing commands for current state and tactic *)
   203 fun exec_trace_command flag (tac, st) =
   204    case TextIO.inputLine TextIO.stdIn of
   205        SOME "\n" => tac st
   206      | SOME "f\n" => Seq.empty
   207      | SOME "o\n" => (flag := false;  tac st)
   208      | SOME "s\n" => (suppress_tracing := true;  tac st)
   209      | SOME "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   210      | SOME "quit\n" => raise TRACE_QUIT
   211      | _     => (tracing
   212 "Type RETURN to continue or...\n\
   213 \     f    - to fail here\n\
   214 \     o    - to switch tracing off\n\
   215 \     s    - to suppress tracing until next entry to a tactical\n\
   216 \     x    - to exit at this point\n\
   217 \     quit - to abort this tracing run\n\
   218 \** Well? "     ;  exec_trace_command flag (tac, st));
   219 
   220 
   221 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   222 fun tracify flag tac st =
   223   if !flag andalso not (!suppress_tracing) then
   224     (tracing (Pretty.string_of (Pretty.chunks
   225         (Goal_Display.pretty_goals (Syntax.init_pretty_global (Thm.theory_of_thm st)) st @
   226           [Pretty.str "** Press RETURN to continue:"])));
   227      exec_trace_command flag (tac, st))
   228   else tac st;
   229 
   230 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   231 fun traced_tac seqf st =
   232     (suppress_tracing := false;
   233      Seq.make (fn()=> seqf st
   234                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   235 
   236 
   237 (*Deterministic REPEAT: only retains the first outcome;
   238   uses less space than REPEAT; tail recursive.
   239   If non-negative, n bounds the number of repetitions.*)
   240 fun REPEAT_DETERM_N n tac =
   241   let val tac = tracify trace_REPEAT tac
   242       fun drep 0 st = SOME(st, Seq.empty)
   243         | drep n st =
   244            (case Seq.pull(tac st) of
   245                 NONE       => SOME(st, Seq.empty)
   246               | SOME(st',_) => drep (n-1) st')
   247   in  traced_tac (drep n)  end;
   248 
   249 (*Allows any number of repetitions*)
   250 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   251 
   252 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   253 fun REPEAT tac =
   254   let val tac = tracify trace_REPEAT tac
   255       fun rep qs st =
   256         case Seq.pull(tac st) of
   257             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   258           | SOME(st',q) => rep (q::qs) st'
   259       and repq [] = NONE
   260         | repq(q::qs) = case Seq.pull q of
   261             NONE       => repq qs
   262           | SOME(st,q) => rep (q::qs) st
   263   in  traced_tac (rep [])  end;
   264 
   265 (*Repeat 1 or more times*)
   266 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   267 fun REPEAT1 tac = tac THEN REPEAT tac;
   268 
   269 
   270 (** Filtering tacticals **)
   271 
   272 fun FILTER pred tac st = Seq.filter pred (tac st);
   273 
   274 (*Accept only next states that change the theorem somehow*)
   275 fun CHANGED tac st =
   276   let fun diff st' = not (Thm.eq_thm (st, st'));
   277   in Seq.filter diff (tac st) end;
   278 
   279 (*Accept only next states that change the theorem's prop field
   280   (changes to signature, hyps, etc. don't count)*)
   281 fun CHANGED_PROP tac st =
   282   let fun diff st' = not (Thm.eq_thm_prop (st, st'));
   283   in Seq.filter diff (tac st) end;
   284 
   285 
   286 (*** Tacticals based on subgoal numbering ***)
   287 
   288 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   289   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   290 fun ALLGOALS tac st =
   291   let fun doall 0 = all_tac
   292         | doall n = tac(n) THEN doall(n-1)
   293   in  doall(nprems_of st)st  end;
   294 
   295 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   296 fun SOMEGOAL tac st =
   297   let fun find 0 = no_tac
   298         | find n = tac(n) ORELSE find(n-1)
   299   in  find(nprems_of st)st  end;
   300 
   301 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   302   More appropriate than SOMEGOAL in some cases.*)
   303 fun FIRSTGOAL tac st =
   304   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   305   in  find(1, nprems_of st)st  end;
   306 
   307 (*First subgoal only.*)
   308 fun HEADGOAL tac = tac 1;
   309 
   310 (*Repeatedly solve some using tac. *)
   311 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   312 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   313 
   314 (*Repeatedly solve the first possible subgoal using tac. *)
   315 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   316 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   317 
   318 (*For n subgoals, tries to apply tac to n,...1  *)
   319 fun TRYALL tac = ALLGOALS (TRY o tac);
   320 
   321 
   322 (*Make a tactic for subgoal i, if there is one.  *)
   323 fun CSUBGOAL goalfun i st =
   324   (case SOME (Thm.cprem_of st i) handle THM _ => NONE of
   325     SOME goal => goalfun (goal, i) st
   326   | NONE => Seq.empty);
   327 
   328 fun SUBGOAL goalfun =
   329   CSUBGOAL (fn (goal, i) => goalfun (Thm.term_of goal, i));
   330 
   331 fun ASSERT_SUBGOAL (tac: int -> tactic) i st = (Logic.get_goal (Thm.prop_of st) i; tac i st);
   332 
   333 (*Returns all states that have changed in subgoal i, counted from the LAST
   334   subgoal.  For stac, for example.*)
   335 fun CHANGED_GOAL tac i st =
   336   SUBGOAL (fn (t, _) =>
   337     let
   338       val np = Thm.nprems_of st;
   339       val d = np - i;  (*distance from END*)
   340       fun diff st' =
   341         Thm.nprems_of st' - d <= 0 orelse  (*the subgoal no longer exists*)
   342         not (Envir.aeconv (t, Thm.term_of (Thm.cprem_of st' (Thm.nprems_of st' - d))));
   343     in Seq.filter diff o tac i end) i st;
   344 
   345 (*Returns all states where some subgoals have been solved.  For
   346   subgoal-based tactics this means subgoal i has been solved
   347   altogether -- no new subgoals have emerged.*)
   348 fun SOLVED' tac i st =
   349   tac i st |> Seq.filter (fn st' => nprems_of st' < nprems_of st);
   350 
   351 (*Apply second tactic to all subgoals emerging from the first --
   352   following usual convention for subgoal-based tactics.*)
   353 fun (tac1 THEN_ALL_NEW tac2) i st =
   354   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   355 
   356 (*Repeatedly dig into any emerging subgoals.*)
   357 fun REPEAT_ALL_NEW tac =
   358   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   359 
   360 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   361 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   362 
   363 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   364 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   365 
   366 (*Inverse (more or less) of PRIMITIVE*)
   367 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   368 
   369 (*Conversions as tactics*)
   370 fun CONVERSION cv i st = Seq.single (Conv.gconv_rule cv i st)
   371   handle THM _ => Seq.empty
   372     | CTERM _ => Seq.empty
   373     | TERM _ => Seq.empty
   374     | TYPE _ => Seq.empty;
   375 
   376 end;
   377 
   378 open Tactical;